m4/stdint.m4

   1 # stdint.m4 serial 48
   2 dnl Copyright (C) 2001-2016 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Paul Eggert and Bruno Haible.
   8 dnl Test whether <stdint.h> is supported or must be substituted.
   9
  10 AC_DEFUN_ONCE([gl_STDINT_H],
  11 [
  12   AC_PREREQ([2.59])dnl
  13
  14   AC_REQUIRE([gl_LIMITS_H])
  15
  16   dnl Check for long long int and unsigned long long int.
  17   AC_REQUIRE([AC_TYPE_LONG_LONG_INT])
  18   if test $ac_cv_type_long_long_int = yes; then
  19     HAVE_LONG_LONG_INT=1
  20   else
  21     HAVE_LONG_LONG_INT=0
  22   fi
  23   AC_SUBST([HAVE_LONG_LONG_INT])
  24   AC_REQUIRE([AC_TYPE_UNSIGNED_LONG_LONG_INT])
  25   if test $ac_cv_type_unsigned_long_long_int = yes; then
  26     HAVE_UNSIGNED_LONG_LONG_INT=1
  27   else
  28     HAVE_UNSIGNED_LONG_LONG_INT=0
  29   fi
  30   AC_SUBST([HAVE_UNSIGNED_LONG_LONG_INT])
  31
  32   dnl Check for <wchar.h>, in the same way as gl_WCHAR_H does.
  33   AC_CHECK_HEADERS_ONCE([wchar.h])
  34   if test $ac_cv_header_wchar_h = yes; then
  35     HAVE_WCHAR_H=1
  36   else
  37     HAVE_WCHAR_H=0
  38   fi
  39   AC_SUBST([HAVE_WCHAR_H])
  40
  41   dnl Check for <inttypes.h>.
  42   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_inttypes_h.
  43   if test $ac_cv_header_inttypes_h = yes; then
  44     HAVE_INTTYPES_H=1
  45   else
  46     HAVE_INTTYPES_H=0
  47   fi
  48   AC_SUBST([HAVE_INTTYPES_H])
  49
  50   dnl Check for <sys/types.h>.
  51   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_sys_types_h.
  52   if test $ac_cv_header_sys_types_h = yes; then
  53     HAVE_SYS_TYPES_H=1
  54   else
  55     HAVE_SYS_TYPES_H=0
  56   fi
  57   AC_SUBST([HAVE_SYS_TYPES_H])
  58
  59   gl_CHECK_NEXT_HEADERS([stdint.h])
  60   if test $ac_cv_header_stdint_h = yes; then
  61     HAVE_STDINT_H=1
  62   else
  63     HAVE_STDINT_H=0
  64   fi
  65   AC_SUBST([HAVE_STDINT_H])
  66
  67   dnl Now see whether we need a substitute <stdint.h>.
  68   if test $ac_cv_header_stdint_h = yes; then
  69     AC_CACHE_CHECK([whether stdint.h conforms to C99],
  70       [gl_cv_header_working_stdint_h],
  71       [gl_cv_header_working_stdint_h=no
  72        AC_COMPILE_IFELSE([
  73          AC_LANG_PROGRAM([[
  74 #define _GL_JUST_INCLUDE_SYSTEM_STDINT_H 1 /* work if build isn't clean */
  75 #define __STDC_CONSTANT_MACROS 1
  76 #define __STDC_LIMIT_MACROS 1
  77 #include <stdint.h>
  78 /* Dragonfly defines WCHAR_MIN, WCHAR_MAX only in <wchar.h>.  */
  79 #if !(defined WCHAR_MIN && defined WCHAR_MAX)
  80 #error "WCHAR_MIN, WCHAR_MAX not defined in <stdint.h>"
  81 #endif
  82 ]
  83 gl_STDINT_INCLUDES
  84 [
  85 #ifdef INT8_MAX
  86 int8_t a1 = INT8_MAX;
  87 int8_t a1min = INT8_MIN;
  88 #endif
  89 #ifdef INT16_MAX
  90 int16_t a2 = INT16_MAX;
  91 int16_t a2min = INT16_MIN;
  92 #endif
  93 #ifdef INT32_MAX
  94 int32_t a3 = INT32_MAX;
  95 int32_t a3min = INT32_MIN;
  96 #endif
  97 #ifdef INT64_MAX
  98 int64_t a4 = INT64_MAX;
  99 int64_t a4min = INT64_MIN;
 100 #endif
 101 #ifdef UINT8_MAX
 102 uint8_t b1 = UINT8_MAX;
 103 #else
 104 typedef int b1[(unsigned char) -1 != 255 ? 1 : -1];
 105 #endif
 106 #ifdef UINT16_MAX
 107 uint16_t b2 = UINT16_MAX;
 108 #endif
 109 #ifdef UINT32_MAX
 110 uint32_t b3 = UINT32_MAX;
 111 #endif
 112 #ifdef UINT64_MAX
 113 uint64_t b4 = UINT64_MAX;
 114 #endif
 115 int_least8_t c1 = INT8_C (0x7f);
 116 int_least8_t c1max = INT_LEAST8_MAX;
 117 int_least8_t c1min = INT_LEAST8_MIN;
 118 int_least16_t c2 = INT16_C (0x7fff);
 119 int_least16_t c2max = INT_LEAST16_MAX;
 120 int_least16_t c2min = INT_LEAST16_MIN;
 121 int_least32_t c3 = INT32_C (0x7fffffff);
 122 int_least32_t c3max = INT_LEAST32_MAX;
 123 int_least32_t c3min = INT_LEAST32_MIN;
 124 int_least64_t c4 = INT64_C (0x7fffffffffffffff);
 125 int_least64_t c4max = INT_LEAST64_MAX;
 126 int_least64_t c4min = INT_LEAST64_MIN;
 127 uint_least8_t d1 = UINT8_C (0xff);
 128 uint_least8_t d1max = UINT_LEAST8_MAX;
 129 uint_least16_t d2 = UINT16_C (0xffff);
 130 uint_least16_t d2max = UINT_LEAST16_MAX;
 131 uint_least32_t d3 = UINT32_C (0xffffffff);
 132 uint_least32_t d3max = UINT_LEAST32_MAX;
 133 uint_least64_t d4 = UINT64_C (0xffffffffffffffff);
 134 uint_least64_t d4max = UINT_LEAST64_MAX;
 135 int_fast8_t e1 = INT_FAST8_MAX;
 136 int_fast8_t e1min = INT_FAST8_MIN;
 137 int_fast16_t e2 = INT_FAST16_MAX;
 138 int_fast16_t e2min = INT_FAST16_MIN;
 139 int_fast32_t e3 = INT_FAST32_MAX;
 140 int_fast32_t e3min = INT_FAST32_MIN;
 141 int_fast64_t e4 = INT_FAST64_MAX;
 142 int_fast64_t e4min = INT_FAST64_MIN;
 143 uint_fast8_t f1 = UINT_FAST8_MAX;
 144 uint_fast16_t f2 = UINT_FAST16_MAX;
 145 uint_fast32_t f3 = UINT_FAST32_MAX;
 146 uint_fast64_t f4 = UINT_FAST64_MAX;
 147 #ifdef INTPTR_MAX
 148 intptr_t g = INTPTR_MAX;
 149 intptr_t gmin = INTPTR_MIN;
 150 #endif
 151 #ifdef UINTPTR_MAX
 152 uintptr_t h = UINTPTR_MAX;
 153 #endif
 154 intmax_t i = INTMAX_MAX;
 155 uintmax_t j = UINTMAX_MAX;
 156
 157 /* Check that SIZE_MAX has the correct type, if possible.  */
 158 #if 201112 <= __STDC_VERSION__
 159 int k = _Generic (SIZE_MAX, size_t: 0);
 160 #elif (2 <= __GNUC__ || defined __IBM__TYPEOF__ \
 161        || (0x5110 <= __SUNPRO_C && !__STDC__))
 162 extern size_t k;
 163 extern __typeof__ (SIZE_MAX) k;
 164 #endif
 165
 166 #include <limits.h> /* for CHAR_BIT */
 167 #define TYPE_MINIMUM(t) \
 168   ((t) ((t) 0 < (t) -1 ? (t) 0 : ~ TYPE_MAXIMUM (t)))
 169 #define TYPE_MAXIMUM(t) \
 170   ((t) ((t) 0 < (t) -1 \
 171         ? (t) -1 \
 172         : ((((t) 1 << (sizeof (t) * CHAR_BIT - 2)) - 1) * 2 + 1)))
 173 struct s {
 174   int check_PTRDIFF:
 175       PTRDIFF_MIN == TYPE_MINIMUM (ptrdiff_t)
 176       && PTRDIFF_MAX == TYPE_MAXIMUM (ptrdiff_t)
 177       ? 1 : -1;
 178   /* Detect bug in FreeBSD 6.0 / ia64.  */
 179   int check_SIG_ATOMIC:
 180       SIG_ATOMIC_MIN == TYPE_MINIMUM (sig_atomic_t)
 181       && SIG_ATOMIC_MAX == TYPE_MAXIMUM (sig_atomic_t)
 182       ? 1 : -1;
 183   int check_SIZE: SIZE_MAX == TYPE_MAXIMUM (size_t) ? 1 : -1;
 184   int check_WCHAR:
 185       WCHAR_MIN == TYPE_MINIMUM (wchar_t)
 186       && WCHAR_MAX == TYPE_MAXIMUM (wchar_t)
 187       ? 1 : -1;
 188   /* Detect bug in mingw.  */
 189   int check_WINT:
 190       WINT_MIN == TYPE_MINIMUM (wint_t)
 191       && WINT_MAX == TYPE_MAXIMUM (wint_t)
 192       ? 1 : -1;
 193
 194   /* Detect bugs in glibc 2.4 and Solaris 10 stdint.h, among others.  */
 195   int check_UINT8_C:
 196         (-1 < UINT8_C (0)) == (-1 < (uint_least8_t) 0) ? 1 : -1;
 197   int check_UINT16_C:
 198         (-1 < UINT16_C (0)) == (-1 < (uint_least16_t) 0) ? 1 : -1;
 199
 200   /* Detect bugs in OpenBSD 3.9 stdint.h.  */
 201 #ifdef UINT8_MAX
 202   int check_uint8: (uint8_t) -1 == UINT8_MAX ? 1 : -1;
 203 #endif
 204 #ifdef UINT16_MAX
 205   int check_uint16: (uint16_t) -1 == UINT16_MAX ? 1 : -1;
 206 #endif
 207 #ifdef UINT32_MAX
 208   int check_uint32: (uint32_t) -1 == UINT32_MAX ? 1 : -1;
 209 #endif
 210 #ifdef UINT64_MAX
 211   int check_uint64: (uint64_t) -1 == UINT64_MAX ? 1 : -1;
 212 #endif
 213   int check_uint_least8: (uint_least8_t) -1 == UINT_LEAST8_MAX ? 1 : -1;
 214   int check_uint_least16: (uint_least16_t) -1 == UINT_LEAST16_MAX ? 1 : -1;
 215   int check_uint_least32: (uint_least32_t) -1 == UINT_LEAST32_MAX ? 1 : -1;
 216   int check_uint_least64: (uint_least64_t) -1 == UINT_LEAST64_MAX ? 1 : -1;
 217   int check_uint_fast8: (uint_fast8_t) -1 == UINT_FAST8_MAX ? 1 : -1;
 218   int check_uint_fast16: (uint_fast16_t) -1 == UINT_FAST16_MAX ? 1 : -1;
 219   int check_uint_fast32: (uint_fast32_t) -1 == UINT_FAST32_MAX ? 1 : -1;
 220   int check_uint_fast64: (uint_fast64_t) -1 == UINT_FAST64_MAX ? 1 : -1;
 221   int check_uintptr: (uintptr_t) -1 == UINTPTR_MAX ? 1 : -1;
 222   int check_uintmax: (uintmax_t) -1 == UINTMAX_MAX ? 1 : -1;
 223   int check_size: (size_t) -1 == SIZE_MAX ? 1 : -1;
 224 };
 225          ]])],
 226          [dnl Determine whether the various *_MIN, *_MAX macros are usable
 227           dnl in preprocessor expression. We could do it by compiling a test
 228           dnl program for each of these macros. It is faster to run a program
 229           dnl that inspects the macro expansion.
 230           dnl This detects a bug on HP-UX 11.23/ia64.
 231           AC_RUN_IFELSE([
 232             AC_LANG_PROGRAM([[
 233 #define _GL_JUST_INCLUDE_SYSTEM_STDINT_H 1 /* work if build isn't clean */
 234 #define __STDC_CONSTANT_MACROS 1
 235 #define __STDC_LIMIT_MACROS 1
 236 #include <stdint.h>
 237 ]
 238 gl_STDINT_INCLUDES
 239 [
 240 #include <stdio.h>
 241 #include <string.h>
 242 #define MVAL(macro) MVAL1(macro)
 243 #define MVAL1(expression) #expression
 244 static const char *macro_values[] =
 245   {
 246 #ifdef INT8_MAX
 247     MVAL (INT8_MAX),
 248 #endif
 249 #ifdef INT16_MAX
 250     MVAL (INT16_MAX),
 251 #endif
 252 #ifdef INT32_MAX
 253     MVAL (INT32_MAX),
 254 #endif
 255 #ifdef INT64_MAX
 256     MVAL (INT64_MAX),
 257 #endif
 258 #ifdef UINT8_MAX
 259     MVAL (UINT8_MAX),
 260 #endif
 261 #ifdef UINT16_MAX
 262     MVAL (UINT16_MAX),
 263 #endif
 264 #ifdef UINT32_MAX
 265     MVAL (UINT32_MAX),
 266 #endif
 267 #ifdef UINT64_MAX
 268     MVAL (UINT64_MAX),
 269 #endif
 270     NULL
 271   };
 272 ]], [[
 273   const char **mv;
 274   for (mv = macro_values; *mv != NULL; mv++)
 275     {
 276       const char *value = *mv;
 277       /* Test whether it looks like a cast expression.  */
 278       if (strncmp (value, "((unsigned int)"/*)*/, 15) == 0
 279           || strncmp (value, "((unsigned short)"/*)*/, 17) == 0
 280           || strncmp (value, "((unsigned char)"/*)*/, 16) == 0
 281           || strncmp (value, "((int)"/*)*/, 6) == 0
 282           || strncmp (value, "((signed short)"/*)*/, 15) == 0
 283           || strncmp (value, "((signed char)"/*)*/, 14) == 0)
 284         return mv - macro_values + 1;
 285     }
 286   return 0;
 287 ]])],
 288               [gl_cv_header_working_stdint_h=yes],
 289               [],
 290               [dnl When cross-compiling, assume it works.
 291                gl_cv_header_working_stdint_h=yes
 292               ])
 293          ])
 294       ])
 295   fi
 296
 297   HAVE_C99_STDINT_H=0
 298   HAVE_SYS_BITYPES_H=0
 299   HAVE_SYS_INTTYPES_H=0
 300   STDINT_H=stdint.h
 301   if test "$gl_cv_header_working_stdint_h" = yes; then
 302     HAVE_C99_STDINT_H=1
 303     dnl Now see whether the system <stdint.h> works without
 304     dnl __STDC_CONSTANT_MACROS/__STDC_LIMIT_MACROS defined.
 305     AC_CACHE_CHECK([whether stdint.h predates C++11],
 306       [gl_cv_header_stdint_predates_cxx11_h],
 307       [gl_cv_header_stdint_predates_cxx11_h=yes
 308        AC_COMPILE_IFELSE([
 309          AC_LANG_PROGRAM([[
 310 #define _GL_JUST_INCLUDE_SYSTEM_STDINT_H 1 /* work if build isn't clean */
 311 #include <stdint.h>
 312 ]
 313 gl_STDINT_INCLUDES
 314 [
 315 intmax_t im = INTMAX_MAX;
 316 int32_t i32 = INT32_C (0x7fffffff);
 317          ]])],
 318          [gl_cv_header_stdint_predates_cxx11_h=no])])
 319
 320     if test "$gl_cv_header_stdint_predates_cxx11_h" = yes; then
 321       AC_DEFINE([__STDC_CONSTANT_MACROS], [1],
 322                 [Define to 1 if the system <stdint.h> predates C++11.])
 323       AC_DEFINE([__STDC_LIMIT_MACROS], [1],
 324                 [Define to 1 if the system <stdint.h> predates C++11.])
 325     fi
 326     AC_CACHE_CHECK([whether stdint.h has UINTMAX_WIDTH etc.],
 327       [gl_cv_header_stdint_width],
 328       [gl_cv_header_stdint_width=no
 329        AC_COMPILE_IFELSE(
 330          [AC_LANG_PROGRAM([[
 331             /* Work if build is not clean.  */
 332             #define _GL_JUST_INCLUDE_SYSTEM_STDINT_H 1
 333             #ifndef __STDC_WANT_IEC_60559_BFP_EXT__
 334              #define __STDC_WANT_IEC_60559_BFP_EXT__ 1
 335             #endif
 336             #include <stdint.h>
 337             ]gl_STDINT_INCLUDES[
 338             int iw = UINTMAX_WIDTH;
 339             ]])],
 340          [gl_cv_header_stdint_width=yes])])
 341     if test "$gl_cv_header_stdint_width" = yes; then
 342       STDINT_H=
 343     fi
 344   else
 345     dnl Check for <sys/inttypes.h>, and for
 346     dnl <sys/bitypes.h> (used in Linux libc4 >= 4.6.7 and libc5).
 347     AC_CHECK_HEADERS([sys/inttypes.h sys/bitypes.h])
 348     if test $ac_cv_header_sys_inttypes_h = yes; then
 349       HAVE_SYS_INTTYPES_H=1
 350     fi
 351     if test $ac_cv_header_sys_bitypes_h = yes; then
 352       HAVE_SYS_BITYPES_H=1
 353     fi
 354     gl_STDINT_TYPE_PROPERTIES
 355   fi
 356
 357   # The substitute stdint.h needs the substitute limit.h's _GL_INTEGER_WIDTH.
 358   LIMITS_H=limits.h
 359   AM_CONDITIONAL([GL_GENERATE_LIMITS_H], [test -n "$LIMITS_H"])
 360
 361   AC_SUBST([HAVE_C99_STDINT_H])
 362   AC_SUBST([HAVE_SYS_BITYPES_H])
 363   AC_SUBST([HAVE_SYS_INTTYPES_H])
 364   AC_SUBST([STDINT_H])
 365   AM_CONDITIONAL([GL_GENERATE_STDINT_H], [test -n "$STDINT_H"])
 366 ])
 367
 368 dnl gl_STDINT_BITSIZEOF(TYPES, INCLUDES)
 369 dnl Determine the size of each of the given types in bits.
 370 AC_DEFUN([gl_STDINT_BITSIZEOF],
 371 [
 372   dnl Use a shell loop, to avoid bloating configure, and
 373   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 374   dnl   config.h.in,
 375   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 376   m4_foreach_w([gltype], [$1],
 377     [AH_TEMPLATE([BITSIZEOF_]m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]),
 378        [Define to the number of bits in type ']gltype['.])])
 379   for gltype in $1 ; do
 380     AC_CACHE_CHECK([for bit size of $gltype], [gl_cv_bitsizeof_${gltype}],
 381       [AC_COMPUTE_INT([result], [sizeof ($gltype) * CHAR_BIT],
 382          [$2
 383 #include <limits.h>], [result=unknown])
 384        eval gl_cv_bitsizeof_${gltype}=\$result
 385       ])
 386     eval result=\$gl_cv_bitsizeof_${gltype}
 387     if test $result = unknown; then
 388       dnl Use a nonempty default, because some compilers, such as IRIX 5 cc,
 389       dnl do a syntax check even on unused #if conditions and give an error
 390       dnl on valid C code like this:
 391       dnl   #if 0
 392       dnl   # if  > 32
 393       dnl   # endif
 394       dnl   #endif
 395       result=0
 396     fi
 397     GLTYPE=`echo "$gltype" | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 398     AC_DEFINE_UNQUOTED([BITSIZEOF_${GLTYPE}], [$result])
 399     eval BITSIZEOF_${GLTYPE}=\$result
 400   done
 401   m4_foreach_w([gltype], [$1],
 402     [AC_SUBST([BITSIZEOF_]m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]))])
 403 ])
 404
 405 dnl gl_CHECK_TYPES_SIGNED(TYPES, INCLUDES)
 406 dnl Determine the signedness of each of the given types.
 407 dnl Define HAVE_SIGNED_TYPE if type is signed.
 408 AC_DEFUN([gl_CHECK_TYPES_SIGNED],
 409 [
 410   dnl Use a shell loop, to avoid bloating configure, and
 411   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 412   dnl   config.h.in,
 413   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 414   m4_foreach_w([gltype], [$1],
 415     [AH_TEMPLATE([HAVE_SIGNED_]m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]),
 416        [Define to 1 if ']gltype[' is a signed integer type.])])
 417   for gltype in $1 ; do
 418     AC_CACHE_CHECK([whether $gltype is signed], [gl_cv_type_${gltype}_signed],
 419       [AC_COMPILE_IFELSE(
 420          [AC_LANG_PROGRAM([$2[
 421             int verify[2 * (($gltype) -1 < ($gltype) 0) - 1];]])],
 422          result=yes, result=no)
 423        eval gl_cv_type_${gltype}_signed=\$result
 424       ])
 425     eval result=\$gl_cv_type_${gltype}_signed
 426     GLTYPE=`echo $gltype | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 427     if test "$result" = yes; then
 428       AC_DEFINE_UNQUOTED([HAVE_SIGNED_${GLTYPE}], [1])
 429       eval HAVE_SIGNED_${GLTYPE}=1
 430     else
 431       eval HAVE_SIGNED_${GLTYPE}=0
 432     fi
 433   done
 434   m4_foreach_w([gltype], [$1],
 435     [AC_SUBST([HAVE_SIGNED_]m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]))])
 436 ])
 437
 438 dnl gl_INTEGER_TYPE_SUFFIX(TYPES, INCLUDES)
 439 dnl Determine the suffix to use for integer constants of the given types.
 440 dnl Define t_SUFFIX for each such type.
 441 AC_DEFUN([gl_INTEGER_TYPE_SUFFIX],
 442 [
 443   dnl Use a shell loop, to avoid bloating configure, and
 444   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 445   dnl   config.h.in,
 446   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 447   m4_foreach_w([gltype], [$1],
 448     [AH_TEMPLATE(m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_])[_SUFFIX],
 449        [Define to l, ll, u, ul, ull, etc., as suitable for
 450         constants of type ']gltype['.])])
 451   for gltype in $1 ; do
 452     AC_CACHE_CHECK([for $gltype integer literal suffix],
 453       [gl_cv_type_${gltype}_suffix],
 454       [eval gl_cv_type_${gltype}_suffix=no
 455        eval result=\$gl_cv_type_${gltype}_signed
 456        if test "$result" = yes; then
 457          glsufu=
 458        else
 459          glsufu=u
 460        fi
 461        for glsuf in "$glsufu" ${glsufu}l ${glsufu}ll ${glsufu}i64; do
 462          case $glsuf in
 463            '')  gltype1='int';;
 464            l)   gltype1='long int';;
 465            ll)  gltype1='long long int';;
 466            i64) gltype1='__int64';;
 467            u)   gltype1='unsigned int';;
 468            ul)  gltype1='unsigned long int';;
 469            ull) gltype1='unsigned long long int';;
 470            ui64)gltype1='unsigned __int64';;
 471          esac
 472          AC_COMPILE_IFELSE(
 473            [AC_LANG_PROGRAM([$2[
 474               extern $gltype foo;
 475               extern $gltype1 foo;]])],
 476            [eval gl_cv_type_${gltype}_suffix=\$glsuf])
 477          eval result=\$gl_cv_type_${gltype}_suffix
 478          test "$result" != no && break
 479        done])
 480     GLTYPE=`echo $gltype | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 481     eval result=\$gl_cv_type_${gltype}_suffix
 482     test "$result" = no && result=
 483     eval ${GLTYPE}_SUFFIX=\$result
 484     AC_DEFINE_UNQUOTED([${GLTYPE}_SUFFIX], [$result])
 485   done
 486   m4_foreach_w([gltype], [$1],
 487     [AC_SUBST(m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_])[_SUFFIX])])
 488 ])
 489
 490 dnl gl_STDINT_INCLUDES
 491 AC_DEFUN([gl_STDINT_INCLUDES],
 492 [[
 493   /* BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be
 494      included before <wchar.h>.  */
 495   #include <stddef.h>
 496   #include <signal.h>
 497   #if HAVE_WCHAR_H
 498   # include <stdio.h>
 499   # include <time.h>
 500   # include <wchar.h>
 501   #endif
 502 ]])
 503
 504 dnl gl_STDINT_TYPE_PROPERTIES
 505 dnl Compute HAVE_SIGNED_t, BITSIZEOF_t and t_SUFFIX, for all the types t
 506 dnl of interest to stdint.in.h.
 507 AC_DEFUN([gl_STDINT_TYPE_PROPERTIES],
 508 [
 509   AC_REQUIRE([gl_MULTIARCH])
 510   if test $APPLE_UNIVERSAL_BUILD = 0; then
 511     gl_STDINT_BITSIZEOF([ptrdiff_t size_t],
 512       [gl_STDINT_INCLUDES])
 513   fi
 514   gl_STDINT_BITSIZEOF([sig_atomic_t wchar_t wint_t],
 515     [gl_STDINT_INCLUDES])
 516   gl_CHECK_TYPES_SIGNED([sig_atomic_t wchar_t wint_t],
 517     [gl_STDINT_INCLUDES])
 518   gl_cv_type_ptrdiff_t_signed=yes
 519   gl_cv_type_size_t_signed=no
 520   if test $APPLE_UNIVERSAL_BUILD = 0; then
 521     gl_INTEGER_TYPE_SUFFIX([ptrdiff_t size_t],
 522       [gl_STDINT_INCLUDES])
 523   fi
 524   gl_INTEGER_TYPE_SUFFIX([sig_atomic_t wchar_t wint_t],
 525     [gl_STDINT_INCLUDES])
 526
 527   dnl If wint_t is smaller than 'int', it cannot satisfy the ISO C 99
 528   dnl requirement that wint_t is "unchanged by default argument promotions".
 529   dnl In this case gnulib's <wchar.h> and <wctype.h> override wint_t.
 530   dnl Set the variable BITSIZEOF_WINT_T accordingly.
 531   if test $BITSIZEOF_WINT_T -lt 32; then
 532     BITSIZEOF_WINT_T=32
 533   fi
 534 ])
 535
 536 dnl Autoconf >= 2.61 has AC_COMPUTE_INT built-in.
 537 dnl Remove this when we can assume autoconf >= 2.61.
 538 m4_ifdef([AC_COMPUTE_INT], [], [
 539   AC_DEFUN([AC_COMPUTE_INT], [_AC_COMPUTE_INT([$2],[$1],[$3],[$4])])
 540 ])