lisp/ibuf-ext.el

   1 ;;; ibuf-ext.el --- extensions for ibuffer
   2
   3 ;; Copyright (C) 2000, 2001, 2002 Free Software Foundation, Inc.
   4
   5 ;; Author: Colin Walters <walters@verbum.org>
   6 ;; Maintainer: John Paul Wallington <jpw@gnu.org>
   7 ;; Created: 2 Dec 2001
   8 ;; Keywords: buffer, convenience
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; This program is free software; you can redistribute it and/or
  13 ;; modify it under the terms of the GNU General Public License as
  14 ;; published by the Free Software Foundation; either version 2, or (at
  15 ;; your option) any later version.
  16
  17 ;; This program is distributed in the hope that it will be useful, but
  18 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20 ;; General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with this program ; see the file COPYING.  If not, write to
  24 ;; the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; These functions should be automatically loaded when called, but you
  30 ;; can explicity (require 'ibuf-ext) in your ~/.emacs to have them
  31 ;; preloaded.
  32
  33 ;;; Code:
  34
  35 (require 'ibuffer)
  36
  37 (eval-when-compile
  38   (require 'derived)
  39   (require 'ibuf-macs)
  40   (require 'cl))
  41
  42 ;;; Utility functions
  43 (defun ibuffer-delete-alist (key alist)
  44   "Delete all entries in ALIST that have a key equal to KEY."
  45   (let (entry)
  46     (while (setq entry (assoc key alist))
  47       (setq alist (delete entry alist)))
  48     alist))
  49
  50 ;; borrowed from Gnus
  51 (defun ibuffer-remove-duplicates (list)
  52   "Return a copy of LIST with duplicate elements removed."
  53   (let ((new nil)
  54         (tail list))
  55     (while tail
  56       (or (member (car tail) new)
  57           (setq new (cons (car tail) new)))
  58       (setq tail (cdr tail)))
  59     (nreverse new)))
  60
  61 (defun ibuffer-split-list (ibuffer-split-list-fn ibuffer-split-list-elts)
  62   (let ((hip-crowd nil)
  63         (lamers nil))
  64     (dolist (ibuffer-split-list-elt ibuffer-split-list-elts)
  65       (if (funcall ibuffer-split-list-fn ibuffer-split-list-elt)
  66           (push ibuffer-split-list-elt hip-crowd)
  67         (push ibuffer-split-list-elt lamers)))
  68     ;; Too bad Emacs Lisp doesn't have multiple values.
  69     (list (nreverse hip-crowd) (nreverse lamers))))
  70
  71 (defcustom ibuffer-never-show-predicates nil
  72   "A list of predicates (a regexp or function) for buffers not to display.
  73 If a regexp, then it will be matched against the buffer's name.
  74 If a function, it will be called with the buffer as an argument, and
  75 should return non-nil if this buffer should not be shown."
  76   :type '(repeat (choice regexp function))
  77   :group 'ibuffer)
  78
  79 (defcustom ibuffer-always-show-predicates nil
  80   "A list of predicates (a regexp or function) for buffers to always display.
  81 If a regexp, then it will be matched against the buffer's name.
  82 If a function, it will be called with the buffer as an argument, and
  83 should return non-nil if this buffer should be shown.
  84 Note that buffers matching one of these predicates will be shown
  85 regardless of any active filters in this buffer."
  86   :type '(repeat (choice regexp function))
  87   :group 'ibuffer)
  88
  89 (defvar ibuffer-tmp-hide-regexps nil
  90   "A list of regexps which should match buffer names to not show.")
  91
  92 (defvar ibuffer-tmp-show-regexps nil
  93   "A list of regexps which should match buffer names to always show.")
  94
  95 (defvar ibuffer-auto-mode nil
  96   "If non-nil, Ibuffer auto-mode should be enabled for this buffer.
  97 Do not set this variable directly!  Use the function
  98 `ibuffer-auto-mode' instead.")
  99
 100 (defvar ibuffer-auto-buffers-changed nil)
 101
 102 (defcustom ibuffer-saved-filters '(("gnus"
 103                                     ((or (mode . message-mode)
 104                                          (mode . mail-mode)
 105                                          (mode . gnus-group-mode)
 106                                          (mode . gnus-summary-mode)
 107                                          (mode . gnus-article-mode))))
 108                                    ("programming"
 109                                     ((or (mode . emacs-lisp-mode)
 110                                          (mode . cperl-mode)
 111                                          (mode . c-mode)
 112                                          (mode . java-mode)
 113                                          (mode . idl-mode)
 114                                          (mode . lisp-mode)))))
 115
 116   "An alist of filter qualifiers to switch between.
 117
 118 This variable should look like ((\"STRING\" QUALIFIERS)
 119                                 (\"STRING\" QUALIFIERS) ...), where
 120 QUALIFIERS is a list of the same form as
 121 `ibuffer-filtering-qualifiers'.
 122 See also the variables `ibuffer-filtering-qualifiers',
 123 `ibuffer-filtering-alist', and the functions
 124 `ibuffer-switch-to-saved-filters', `ibuffer-save-filters'."
 125   :type '(repeat sexp)
 126   :group 'ibuffer)
 127
 128 (defvar ibuffer-filtering-qualifiers nil
 129   "A list like (SYMBOL . QUALIFIER) which filters the current buffer list.
 130 See also `ibuffer-filtering-alist'.")
 131
 132 ;; This is now frobbed by `define-ibuffer-filter'.
 133 (defvar ibuffer-filtering-alist nil
 134   "An alist of (SYMBOL DESCRIPTION FUNCTION) which describes a filter.
 135
 136 You most likely do not want to modify this variable directly; see
 137 `define-ibuffer-filter'.
 138
 139 SYMBOL is the symbolic name of the filter.  DESCRIPTION is used when
 140 displaying information to the user.  FUNCTION is given a buffer and
 141 the value of the qualifier, and returns non-nil if and only if the
 142 buffer should be displayed.")
 143
 144 (defcustom ibuffer-filter-format-alist nil
 145   "An alist which has special formats used when a filter is active.
 146 The contents of this variable should look like:
 147  ((FILTER (FORMAT FORMAT ...)) (FILTER (FORMAT FORMAT ...)) ...)
 148
 149 For example, suppose that when you add a filter for buffers whose
 150 major mode is `emacs-lisp-mode', you only want to see the mark and the
 151 name of the buffer.  You could accomplish that by adding:
 152  (mode ((mark \" \" name)))
 153 to this variable."
 154   :type '(repeat (list :tag "Association" (symbol :tag "Filter")
 155                        (list :tag "Formats" (repeat (sexp :tag "Format")))))
 156   :group 'ibuffer)
 157
 158 (defvar ibuffer-cached-filter-formats nil)
 159 (defvar ibuffer-compiled-filter-formats nil)
 160
 161 (defvar ibuffer-filter-groups nil
 162   "A list like ((\"NAME\" ((SYMBOL . QUALIFIER) ...) ...) which groups buffers.
 163 The SYMBOL should be one from `ibuffer-filtering-alist'.
 164 The QUALIFIER should be the same as QUALIFIER in
 165 `ibuffer-filtering-qualifiers'.")
 166
 167 (defcustom ibuffer-show-empty-filter-groups t
 168   "If non-nil, then show the names of filter groups which are empty."
 169   :type 'boolean
 170   :group 'ibuffer)
 171
 172 (defcustom ibuffer-saved-filter-groups nil
 173   "An alist of filtering groups to switch between.
 174
 175 This variable should look like ((\"STRING\" QUALIFIERS)
 176                                 (\"STRING\" QUALIFIERS) ...), where
 177 QUALIFIERS is a list of the same form as
 178 `ibuffer-filtering-qualifiers'.
 179
 180 See also the variables `ibuffer-filter-groups',
 181 `ibuffer-filtering-qualifiers', `ibuffer-filtering-alist', and the
 182 functions `ibuffer-switch-to-saved-filter-group',
 183 `ibuffer-save-filter-group'."
 184   :type '(repeat sexp)
 185   :group 'ibuffer)
 186
 187 (defvar ibuffer-hidden-filter-groups nil
 188   "A list of filtering groups which are currently hidden.")
 189
 190 (defvar ibuffer-filter-group-kill-ring nil)
 191
 192 (defcustom ibuffer-old-time 72
 193   "The number of hours before a buffer is considered \"old\"."
 194   :type '(choice (const :tag "72 hours (3 days)" 72)
 195                  (const :tag "48 hours (2 days)" 48)
 196                  (const :tag "24 hours (1 day)" 24)
 197                  (integer :tag "hours"))
 198   :group 'ibuffer)
 199
 200 (defcustom ibuffer-save-with-custom t
 201   "If non-nil, then use Custom to save interactively changed variables.
 202 Currently, this only applies to `ibuffer-saved-filters' and
 203 `ibuffer-saved-filter-groups'."
 204   :type 'boolean
 205   :group 'ibuffer)
 206
 207 (defun ibuffer-ext-visible-p (buf all &optional ibuffer-buf)
 208   (or
 209    (ibuffer-buf-matches-predicates buf ibuffer-tmp-show-regexps)
 210    (and (not
 211          (or
 212           (ibuffer-buf-matches-predicates buf ibuffer-tmp-hide-regexps)
 213           (ibuffer-buf-matches-predicates buf ibuffer-never-show-predicates)))
 214         (or all
 215             (not
 216              (ibuffer-buf-matches-predicates buf ibuffer-maybe-show-predicates)))
 217         (or ibuffer-view-ibuffer
 218             (and ibuffer-buf
 219                  (not (eq ibuffer-buf buf))))
 220         (or
 221          (ibuffer-included-in-filters-p buf ibuffer-filtering-qualifiers)
 222          (ibuffer-buf-matches-predicates buf ibuffer-always-show-predicates)))))
 223
 224 (defun ibuffer-auto-update-changed ()
 225   (when ibuffer-auto-buffers-changed
 226     (setq ibuffer-auto-buffers-changed nil)
 227     (mapcar #'(lambda (buf)
 228                 (ignore-errors
 229                   (with-current-buffer buf
 230                     (when (and ibuffer-auto-mode
 231                                (eq major-mode 'ibuffer-mode))
 232                       (ibuffer-update nil t)))))
 233             (buffer-list))))
 234
 235 ;;;###autoload
 236 (defun ibuffer-auto-mode (&optional arg)
 237   "Toggle use of Ibuffer's auto-update facility.
 238 With numeric ARG, enable auto-update if and only if ARG is positive."
 239   (interactive)
 240   (unless (eq major-mode 'ibuffer-mode)
 241     (error "This buffer is not in Ibuffer mode"))
 242   (set (make-local-variable 'ibuffer-auto-mode)
 243        (if arg
 244            (plusp arg)
 245          (not ibuffer-auto-mode)))
 246   (defadvice get-buffer-create (after ibuffer-notify-create activate)
 247     (setq ibuffer-auto-buffers-changed t))
 248   (defadvice kill-buffer (after ibuffer-notify-kill activate)
 249     (setq ibuffer-auto-buffers-changed t))
 250   (add-hook 'post-command-hook 'ibuffer-auto-update-changed)
 251   (ibuffer-update-mode-name))
 252
 253 ;;;###autoload
 254 (defun ibuffer-mouse-filter-by-mode (event)
 255   "Enable or disable filtering by the major mode chosen via mouse."
 256   (interactive "e")
 257   (ibuffer-interactive-filter-by-mode event))
 258
 259 ;;;###autoload
 260 (defun ibuffer-interactive-filter-by-mode (event-or-point)
 261   "Enable or disable filtering by the major mode at point."
 262   (interactive "d")
 263   (if (eventp event-or-point)
 264       (mouse-set-point event-or-point)
 265     (goto-char event-or-point))
 266   (let ((buf (ibuffer-current-buffer)))
 267     (if (assq 'mode ibuffer-filtering-qualifiers)
 268         (setq ibuffer-filtering-qualifiers
 269               (ibuffer-delete-alist 'mode ibuffer-filtering-qualifiers))
 270       (ibuffer-push-filter (cons 'mode
 271                                 (with-current-buffer buf
 272                                   major-mode)))))
 273   (ibuffer-update nil t))
 274
 275 ;;;###autoload
 276 (defun ibuffer-mouse-toggle-filter-group (event)
 277   "Toggle the display status of the filter group chosen with the mouse."
 278   (interactive "e")
 279   (ibuffer-toggle-filter-group-1 (save-excursion
 280                                    (mouse-set-point event)
 281                                    (point))))
 282
 283 ;;;###autoload
 284 (defun ibuffer-toggle-filter-group ()
 285   "Toggle the display status of the filter group on this line."
 286   (interactive)
 287   (ibuffer-toggle-filter-group-1 (point)))
 288
 289 (defun ibuffer-toggle-filter-group-1 (posn)
 290   (let ((name (get-text-property posn 'ibuffer-filter-group-name)))
 291     (unless (stringp name)
 292       (error "No filtering group name present"))
 293     (if (member name ibuffer-hidden-filter-groups)
 294         (setq ibuffer-hidden-filter-groups
 295               (delete name ibuffer-hidden-filter-groups))
 296       (push name ibuffer-hidden-filter-groups))
 297     (ibuffer-update nil t)))
 298
 299 ;;;###autoload
 300 (defun ibuffer-forward-filter-group (&optional count)
 301   "Move point forwards by COUNT filtering groups."
 302   (interactive "P")
 303   (unless count
 304     (setq count 1))
 305   (when (> count 0)
 306     (when (get-text-property (point) 'ibuffer-filter-group-name)
 307       (goto-char (next-single-property-change
 308                   (point) 'ibuffer-filter-group-name
 309                   nil (point-max))))
 310     (goto-char (next-single-property-change
 311                 (point) 'ibuffer-filter-group-name
 312                 nil (point-max)))
 313     (ibuffer-forward-filter-group (1- count)))
 314   (ibuffer-forward-line 0))
 315
 316 ;;;###autoload
 317 (defun ibuffer-backward-filter-group (&optional count)
 318   "Move point backwards by COUNT filtering groups."
 319   (interactive "P")
 320   (unless count
 321     (setq count 1))
 322   (when (> count 0)
 323     (when (get-text-property (point) 'ibuffer-filter-group-name)
 324       (goto-char (previous-single-property-change
 325                   (point) 'ibuffer-filter-group-name
 326                   nil (point-min))))
 327     (goto-char (previous-single-property-change
 328                 (point) 'ibuffer-filter-group-name
 329                 nil (point-min)))
 330     (ibuffer-backward-filter-group (1- count)))
 331   (when (= (point) (point-min))
 332     (goto-char (point-max))
 333     (ibuffer-backward-filter-group 1))
 334   (ibuffer-forward-line 0))
 335
 336 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe "ibuf-ext.el")
 337 (define-ibuffer-op shell-command-pipe (command)
 338   "Pipe the contents of each marked buffer to shell command COMMAND."
 339   (:interactive "sPipe to shell command: "
 340    :opstring "Shell command executed on"
 341    :modifier-p nil)
 342   (shell-command-on-region
 343    (point-min) (point-max) command
 344    (get-buffer-create "* ibuffer-shell-output*")))
 345
 346 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe-replace "ibuf-ext.el")
 347 (define-ibuffer-op shell-command-pipe-replace (command)
 348   "Replace the contents of marked buffers with output of pipe to COMMAND."
 349   (:interactive "sPipe to shell command (replace): "
 350    :opstring "Buffer contents replaced in"
 351    :active-opstring "replace buffer contents in"
 352    :dangerous t
 353    :modifier-p t)
 354   (with-current-buffer buf
 355     (shell-command-on-region (point-min) (point-max)
 356                              command nil t)))
 357
 358 ;;;###autoload (autoload 'ibuffer-do-shell-command-file "ibuf-ext.el")
 359 (define-ibuffer-op shell-command-file (command)
 360   "Run shell command COMMAND separately on files of marked buffers."
 361   (:interactive "sShell command on buffer's file: "
 362    :opstring "Shell command executed on"
 363    :modifier-p nil)
 364   (shell-command (concat command " "
 365                          (shell-quote-argument
 366                           (if buffer-file-name
 367                               buffer-file-name
 368                             (make-temp-file
 369                              (substring (buffer-name) 0 (min 10 (length (buffer-name))))))))))
 370
 371 ;;;###autoload (autoload 'ibuffer-do-eval "ibuf-ext.el")
 372 (define-ibuffer-op eval (form)
 373   "Evaluate FORM in each of the buffers.
 374 Does not display the buffer during evaluation. See
 375 `ibuffer-do-view-and-eval' for that."
 376   (:interactive "xEval in buffers (form): "
 377    :opstring "evaluated in"
 378    :modifier-p :maybe)
 379   (eval form))
 380
 381 ;;;###autoload (autoload 'ibuffer-do-view-and-eval "ibuf-ext.el")
 382 (define-ibuffer-op view-and-eval (form)
 383   "Evaluate FORM while displaying each of the marked buffers.
 384 To evaluate a form without viewing the buffer, see `ibuffer-do-eval'."
 385   (:interactive "xEval viewing buffers (form): "
 386    :opstring "evaluated in"
 387    :complex t
 388    :modifier-p :maybe)
 389   (let ((ibuffer-buf (current-buffer)))
 390     (unwind-protect
 391         (progn
 392           (switch-to-buffer buf)
 393           (eval form))
 394       (switch-to-buffer ibuffer-buf))))
 395
 396 ;;;###autoload (autoload 'ibuffer-do-rename-uniquely "ibuf-ext.el")
 397 (define-ibuffer-op rename-uniquely ()
 398   "Rename marked buffers as with `rename-uniquely'."
 399   (:opstring "renamed"
 400    :modifier-p t)
 401   (rename-uniquely))
 402
 403 ;;;###autoload (autoload 'ibuffer-do-revert "ibuf-ext.el")
 404 (define-ibuffer-op revert ()
 405   "Revert marked buffers as with `revert-buffer'."
 406   (:dangerous t
 407    :opstring "reverted"
 408    :active-opstring "revert"
 409    :modifier-p :maybe)
 410   (revert-buffer t t))
 411
 412 ;;;###autoload (autoload 'ibuffer-do-replace-regexp "ibuf-ext.el")
 413 (define-ibuffer-op replace-regexp (from-str to-str)
 414   "Perform a `replace-regexp' in marked buffers."
 415   (:interactive
 416    (let* ((from-str (read-from-minibuffer "Replace regexp: "))
 417           (to-str (read-from-minibuffer (concat "Replace " from-str
 418                                                 " with: "))))
 419      (list from-str to-str))
 420    :opstring "replaced in"
 421    :complex t
 422    :modifier-p :maybe)
 423   (save-window-excursion
 424     (switch-to-buffer buf)
 425     (save-excursion
 426       (goto-char (point-min))
 427       (let ((case-fold-search ibuffer-case-fold-search))
 428         (while (re-search-forward from-str nil t)
 429           (replace-match to-str))))
 430     t))
 431
 432 ;;;###autoload (autoload 'ibuffer-do-query-replace "ibuf-ext.el")
 433 (define-ibuffer-op query-replace (&rest args)
 434   "Perform a `query-replace' in marked buffers."
 435   (:interactive
 436    (query-replace-read-args "Query replace" t t)
 437    :opstring "replaced in"
 438    :complex t
 439    :modifier-p :maybe)
 440   (save-window-excursion
 441     (switch-to-buffer buf)
 442     (save-excursion
 443       (let ((case-fold-search ibuffer-case-fold-search))
 444         (goto-char (point-min))
 445         (apply #'query-replace args)))
 446     t))
 447
 448 ;;;###autoload (autoload 'ibuffer-do-query-replace-regexp "ibuf-ext.el")
 449 (define-ibuffer-op query-replace-regexp (&rest args)
 450   "Perform a `query-replace-regexp' in marked buffers."
 451   (:interactive
 452    (query-replace-read-args "Query replace regexp" t t)
 453    :opstring "replaced in"
 454    :complex t
 455    :modifier-p :maybe)
 456   (save-window-excursion
 457     (switch-to-buffer buf)
 458     (save-excursion
 459       (let ((case-fold-search ibuffer-case-fold-search))
 460         (goto-char (point-min))
 461         (apply #'query-replace-regexp args)))
 462     t))
 463
 464 ;;;###autoload (autoload 'ibuffer-do-print "ibuf-ext.el")
 465 (define-ibuffer-op print ()
 466   "Print marked buffers as with `print-buffer'."
 467   (:opstring "printed"
 468    :modifier-p nil)
 469   (print-buffer))
 470
 471 ;;;###autoload
 472 (defun ibuffer-included-in-filters-p (buf filters)
 473   (not
 474    (memq nil ;; a filter will return nil if it failed
 475          (mapcar
 476           ;; filter should be like (TYPE . QUALIFIER), or
 477           ;; (or (TYPE . QUALIFIER) (TYPE . QUALIFIER) ...)
 478           #'(lambda (qual)
 479               (ibuffer-included-in-filter-p buf qual))
 480           filters))))
 481
 482 (defun ibuffer-included-in-filter-p (buf filter)
 483   (if (eq (car filter) 'not)
 484       (not (ibuffer-included-in-filter-p-1 buf (cdr filter)))
 485     (ibuffer-included-in-filter-p-1 buf filter)))
 486
 487 (defun ibuffer-included-in-filter-p-1 (buf filter)
 488   (not
 489    (not
 490     (case (car filter)
 491       (or
 492        (memq t (mapcar #'(lambda (x)
 493                            (ibuffer-included-in-filter-p buf x))
 494                        (cdr filter))))
 495       (saved
 496        (let ((data
 497               (assoc (cdr filter)
 498                      ibuffer-saved-filters)))
 499          (unless data
 500            (ibuffer-filter-disable)
 501            (error "Unknown saved filter %s" (cdr filter)))
 502          (ibuffer-included-in-filters-p buf (cadr data))))
 503       (t
 504        (let ((filterdat (assq (car filter)
 505                               ibuffer-filtering-alist)))
 506          ;; filterdat should be like (TYPE DESCRIPTION FUNC)
 507          ;; just a sanity check
 508         (unless filterdat
 509           (ibuffer-filter-disable)
 510           (error "Undefined filter %s" (car filter)))
 511         (not
 512          (not
 513           (funcall (caddr filterdat)
 514                    buf
 515                    (cdr filter))))))))))
 516
 517 (defun ibuffer-generate-filter-groups (bmarklist)
 518   (let ((filter-group-alist (append ibuffer-filter-groups
 519                                        (list (cons "Default" nil)))))
 520 ;;     (dolist (hidden ibuffer-hidden-filter-groups)
 521 ;;       (setq filter-group-alist (ibuffer-delete-alist
 522 ;;                                 hidden filter-group-alist)))
 523     (let ((vec (make-vector (length filter-group-alist) nil))
 524           (i 0))
 525       (dolist (filtergroup filter-group-alist)
 526         (let ((filterset (cdr filtergroup)))
 527           (multiple-value-bind (hip-crowd lamers)
 528               (ibuffer-split-list (lambda (bufmark)
 529                                     (ibuffer-included-in-filters-p (car bufmark)
 530                                                                    filterset))
 531                                   bmarklist)
 532             (aset vec i hip-crowd)
 533             (incf i)
 534             (setq bmarklist lamers))))
 535       (let ((ret nil))
 536         (dotimes (j i ret)
 537           (push (cons (car (nth j filter-group-alist))
 538                       (aref vec j))
 539                 ret))))))
 540
 541 ;;;###autoload
 542 (defun ibuffer-filters-to-filter-group (name)
 543   "Make the current filters into a filtering group."
 544   (interactive "sName for filtering group: ")
 545   (when (null ibuffer-filtering-qualifiers)
 546     (error "No filters in effect"))
 547   (push (cons name ibuffer-filtering-qualifiers) ibuffer-filter-groups)
 548   (ibuffer-filter-disable))
 549
 550 ;;;###autoload
 551 (defun ibuffer-set-filter-groups-by-mode ()
 552   "Set the current filter groups to filter by mode."
 553   (interactive)
 554   (setq ibuffer-filter-groups
 555         (mapcar (lambda (mode)
 556                   (cons (format "%s" mode) `((mode . ,mode))))
 557                 (let ((modes
 558                        (ibuffer-remove-duplicates
 559                         (mapcar (lambda (buf) (with-current-buffer buf major-mode))
 560                                 (buffer-list)))))
 561                   (if ibuffer-view-ibuffer
 562                       modes
 563                     (delq 'ibuffer-mode modes)))))
 564   (ibuffer-update nil t))
 565
 566 ;;;###autoload
 567 (defun ibuffer-pop-filter-group ()
 568   "Remove the first filter group."
 569   (interactive)
 570   (when (null ibuffer-filter-groups)
 571     (error "No filter groups active"))
 572   (setq ibuffer-hidden-filter-groups
 573         (delete (pop ibuffer-filter-groups)
 574                 ibuffer-hidden-filter-groups))
 575   (ibuffer-update nil t))
 576
 577 (defun ibuffer-read-filter-group-name (msg &optional nodefault noerror)
 578   (when (and (not noerror) (null ibuffer-filter-groups))
 579     (error "No filter groups active"))
 580   (let ((groups (mapcar #'car ibuffer-filter-groups)))
 581     (completing-read msg (if nodefault
 582                              groups
 583                            (cons "Default" groups))
 584                      nil t)))
 585
 586 ;;;###autoload
 587 (defun ibuffer-decompose-filter-group (group)
 588   "Decompose the filter group GROUP into active filters."
 589   (interactive (list (ibuffer-read-filter-group-name "Decompose filter group: " t)))
 590   (let ((data (cdr (assoc group ibuffer-filter-groups))))
 591     (setq ibuffer-filter-groups (ibuffer-delete-alist
 592                                  group ibuffer-filter-groups)
 593           ibuffer-filtering-qualifiers data))
 594   (ibuffer-update nil t))
 595
 596 ;;;###autoload
 597 (defun ibuffer-clear-filter-groups ()
 598   "Remove all filter groups."
 599   (interactive)
 600   (setq ibuffer-filter-groups nil
 601         ibuffer-hidden-filter-groups nil)
 602   (ibuffer-update nil t))
 603
 604 (defun ibuffer-current-filter-groups-with-position ()
 605   (save-excursion
 606     (goto-char (point-min))
 607     (let ((pos nil)
 608           (result nil))
 609       (while (and (not (eobp))
 610                   (setq pos (next-single-property-change
 611                              (point) 'ibuffer-filter-group-name)))
 612         (goto-char pos)
 613         (push (cons (get-text-property (point) 'ibuffer-filter-group-name)
 614                     pos)
 615               result)
 616         (goto-char (next-single-property-change
 617                     pos 'ibuffer-filter-group-name)))
 618       (nreverse result))))
 619
 620 ;;;###autoload
 621 (defun ibuffer-jump-to-filter-group (name)
 622   "Move point to the filter group whose name is NAME."
 623   (interactive (list (ibuffer-read-filter-group-name "Jump to filter group: ")))
 624   (ibuffer-aif (assoc name (ibuffer-current-filter-groups-with-position))
 625       (goto-char (cdr it))
 626     (error "No filter group with name %s" name)))
 627
 628 ;;;###autoload
 629 (defun ibuffer-kill-filter-group (name)
 630   "Kill the filter group named NAME.
 631 The group will be added to `ibuffer-filter-group-kill-ring'."
 632   (interactive (list (ibuffer-read-filter-group-name "Kill filter group: " t)))
 633   (when (equal name "Default")
 634     (error "Can't kill default filter group"))
 635   (ibuffer-aif (assoc name ibuffer-filter-groups)
 636       (progn
 637         (push (copy-tree it) ibuffer-filter-group-kill-ring)
 638         (setq ibuffer-filter-groups (ibuffer-delete-alist
 639                                      name ibuffer-filter-groups))
 640         (setq ibuffer-hidden-filter-groups
 641               (delete name ibuffer-hidden-filter-groups)))
 642     (error "No filter group with name \"%s\"" name))
 643   (ibuffer-update nil t))
 644
 645 ;;;###autoload
 646 (defun ibuffer-kill-line (&optional arg)
 647   "Kill the filter group at point.
 648 See also `ibuffer-kill-filter-group'."
 649   (interactive "P")
 650   (ibuffer-aif (save-excursion
 651                  (ibuffer-forward-line 0)
 652                  (get-text-property (point) 'ibuffer-filter-group-name))
 653       (progn
 654         (ibuffer-kill-filter-group it))
 655       (funcall (if (interactive-p) #'call-interactively #'funcall)
 656                #'kill-line arg)))
 657
 658 (defun ibuffer-insert-filter-group-before (newgroup group)
 659   (let* ((found nil)
 660          (pos (let ((groups (mapcar #'car ibuffer-filter-groups))
 661                     (res 0))
 662                 (while groups
 663                   (if (equal (car groups) group)
 664                       (setq found t
 665                             groups nil)
 666                     (incf res)
 667                     (setq groups (cdr groups))))
 668                 res)))
 669     (cond ((not found)
 670            (setq ibuffer-filter-groups (nconc ibuffer-filter-groups (list newgroup))))
 671           ((zerop pos)
 672            (push newgroup ibuffer-filter-groups))
 673           (t
 674            (let ((cell (nthcdr pos ibuffer-filter-groups)))
 675              (setf (cdr cell) (cons (car cell) (cdr cell)))
 676              (setf (car cell) newgroup))))))
 677
 678 ;;;###autoload
 679 (defun ibuffer-yank ()
 680   "Yank the last killed filter group before group at point."
 681   (interactive)
 682   (ibuffer-yank-filter-group
 683    (or (get-text-property (point) 'ibuffer-filter-group-name)
 684        (get-text-property (point) 'ibuffer-filter-group)
 685        (error "No filter group at point"))))
 686
 687 ;;;###autoload
 688 (defun ibuffer-yank-filter-group (name)
 689   "Yank the last killed filter group before group named NAME."
 690   (interactive (list (ibuffer-read-filter-group-name
 691                         "Yank filter group before group: ")))
 692   (unless ibuffer-filter-group-kill-ring
 693     (error "The Ibuffer filter group kill-ring is empty"))
 694   (save-excursion
 695     (ibuffer-forward-line 0)
 696     (ibuffer-insert-filter-group-before (pop ibuffer-filter-group-kill-ring)
 697                                         name))
 698   (ibuffer-update nil t))
 699
 700 ;;;###autoload
 701 (defun ibuffer-save-filter-groups (name groups)
 702   "Save all active filter groups GROUPS as NAME.
 703 They are added to `ibuffer-saved-filter-groups'.  Interactively,
 704 prompt for NAME, and use the current filters."
 705   (interactive
 706    (if (null ibuffer-filter-groups)
 707        (error "No filter groups active")
 708      (list
 709       (read-from-minibuffer "Save current filter groups as: ")
 710       ibuffer-filter-groups)))
 711   (ibuffer-aif (assoc name ibuffer-saved-filter-groups)
 712       (setcdr it groups)
 713     (push (cons name groups) ibuffer-saved-filter-groups))
 714   (ibuffer-maybe-save-stuff)
 715   (ibuffer-update-mode-name))
 716
 717 ;;;###autoload
 718 (defun ibuffer-delete-saved-filter-groups (name)
 719   "Delete saved filter groups with NAME.
 720 They are removed from `ibuffer-saved-filter-groups'."
 721   (interactive
 722    (list
 723     (if (null ibuffer-saved-filter-groups)
 724         (error "No saved filter groups")
 725       (completing-read "Delete saved filter group: "
 726                        ibuffer-saved-filter-groups nil t))))
 727   (setq ibuffer-saved-filter-groups
 728         (ibuffer-delete-alist name ibuffer-saved-filter-groups))
 729   (ibuffer-maybe-save-stuff)
 730   (ibuffer-update nil t))
 731
 732 ;;;###autoload
 733 (defun ibuffer-switch-to-saved-filter-groups (name)
 734   "Set this buffer's filter groups to saved version with NAME.
 735 The value from `ibuffer-saved-filters' is used.
 736 If prefix argument ADD is non-nil, then add the saved filters instead
 737 of replacing the current filters."
 738   (interactive
 739    (list
 740     (if (null ibuffer-saved-filter-groups)
 741         (error "No saved filters")
 742       (completing-read "Switch to saved filter group: "
 743                        ibuffer-saved-filter-groups nil t))))
 744   (setq ibuffer-filter-groups (cdr (assoc name ibuffer-saved-filter-groups))
 745         ibuffer-hidden-filter-groups nil)
 746   (ibuffer-update nil t))
 747
 748 ;;;###autoload
 749 (defun ibuffer-filter-disable ()
 750   "Disable all filters currently in effect in this buffer."
 751   (interactive)
 752   (setq ibuffer-filtering-qualifiers nil)
 753   (ibuffer-update nil t))
 754
 755 ;;;###autoload
 756 (defun ibuffer-pop-filter ()
 757   "Remove the top filter in this buffer."
 758   (interactive)
 759   (when (null ibuffer-filtering-qualifiers)
 760     (error "No filters in effect"))
 761   (pop ibuffer-filtering-qualifiers)
 762   (ibuffer-update nil t))
 763
 764 (defun ibuffer-push-filter (qualifier)
 765   "Add QUALIFIER to `ibuffer-filtering-qualifiers'."
 766   (push qualifier ibuffer-filtering-qualifiers))
 767
 768 ;;;###autoload
 769 (defun ibuffer-decompose-filter ()
 770   "Separate the top compound filter (OR, NOT, or SAVED) in this buffer.
 771
 772 This means that the topmost filter on the filtering stack, which must
 773 be a complex filter like (OR [name: foo] [mode: bar-mode]), will be
 774 turned into two separate filters [name: foo] and [mode: bar-mode]."
 775   (interactive)
 776   (when (null ibuffer-filtering-qualifiers)
 777     (error "No filters in effect"))
 778   (let ((lim (pop ibuffer-filtering-qualifiers)))
 779     (case (car lim)
 780       (or
 781        (setq ibuffer-filtering-qualifiers (append
 782                                           (cdr lim)
 783                                           ibuffer-filtering-qualifiers)))
 784       (saved
 785        (let ((data
 786               (assoc (cdr lim)
 787                      ibuffer-saved-filters)))
 788          (unless data
 789            (ibuffer-filter-disable)
 790            (error "Unknown saved filter %s" (cdr lim)))
 791          (setq ibuffer-filtering-qualifiers (append
 792                                             (cadr data)
 793                                             ibuffer-filtering-qualifiers))))
 794       (not
 795        (push (cdr lim)
 796              ibuffer-filtering-qualifiers))
 797       (t
 798        (error "Filter type %s is not compound" (car lim)))))
 799   (ibuffer-update nil t))
 800
 801 ;;;###autoload
 802 (defun ibuffer-exchange-filters ()
 803   "Exchange the top two filters on the stack in this buffer."
 804   (interactive)
 805   (when (< (length ibuffer-filtering-qualifiers)
 806            2)
 807     (error "Need two filters to exchange"))
 808   (let ((first (pop ibuffer-filtering-qualifiers))
 809         (second (pop ibuffer-filtering-qualifiers)))
 810     (push first ibuffer-filtering-qualifiers)
 811     (push second ibuffer-filtering-qualifiers))
 812   (ibuffer-update nil t))
 813
 814 ;;;###autoload
 815 (defun ibuffer-negate-filter ()
 816   "Negate the sense of the top filter in the current buffer."
 817   (interactive)
 818   (when (null ibuffer-filtering-qualifiers)
 819     (error "No filters in effect"))
 820   (let ((lim (pop ibuffer-filtering-qualifiers)))
 821     (push (if (eq (car lim) 'not)
 822               (cdr lim)
 823             (cons 'not lim))
 824           ibuffer-filtering-qualifiers))
 825   (ibuffer-update nil t))
 826
 827 ;;;###autoload
 828 (defun ibuffer-or-filter (&optional reverse)
 829   "Replace the top two filters in this buffer with their logical OR.
 830 If optional argument REVERSE is non-nil, instead break the top OR
 831 filter into parts."
 832   (interactive "P")
 833   (if reverse
 834       (progn
 835         (when (or (null ibuffer-filtering-qualifiers)
 836                   (not (eq 'or (caar ibuffer-filtering-qualifiers))))
 837           (error "Top filter is not an OR"))
 838         (let ((lim (pop ibuffer-filtering-qualifiers)))
 839           (setq ibuffer-filtering-qualifiers (nconc (cdr lim) ibuffer-filtering-qualifiers))))
 840     (when (< (length ibuffer-filtering-qualifiers) 2)
 841       (error "Need two filters to OR"))
 842     ;; If the second filter is an OR, just add to it.
 843     (let ((first (pop ibuffer-filtering-qualifiers))
 844           (second (pop ibuffer-filtering-qualifiers)))
 845       (if (eq 'or (car second))
 846           (push (nconc (list 'or first) (cdr second)) ibuffer-filtering-qualifiers)
 847         (push (list 'or first second)
 848               ibuffer-filtering-qualifiers))))
 849   (ibuffer-update nil t))
 850
 851 (defun ibuffer-maybe-save-stuff ()
 852   (when ibuffer-save-with-custom
 853     (if (fboundp 'customize-save-variable)
 854         (progn
 855           (customize-save-variable 'ibuffer-saved-filters
 856                                    ibuffer-saved-filters)
 857           (customize-save-variable 'ibuffer-saved-filter-groups
 858                                    ibuffer-saved-filter-groups))
 859       (message "Not saved permanently: Customize not available"))))
 860
 861 ;;;###autoload
 862 (defun ibuffer-save-filters (name filters)
 863   "Save FILTERS in this buffer with name NAME in `ibuffer-saved-filters'.
 864 Interactively, prompt for NAME, and use the current filters."
 865   (interactive
 866    (if (null ibuffer-filtering-qualifiers)
 867        (error "No filters currently in effect")
 868      (list
 869       (read-from-minibuffer "Save current filters as: ")
 870       ibuffer-filtering-qualifiers)))
 871   (ibuffer-aif (assoc name ibuffer-saved-filters)
 872       (setcdr it filters)
 873     (push (list name filters) ibuffer-saved-filters))
 874   (ibuffer-maybe-save-stuff)
 875   (ibuffer-update-mode-name))
 876
 877 ;;;###autoload
 878 (defun ibuffer-delete-saved-filters (name)
 879   "Delete saved filters with NAME from `ibuffer-saved-filters'."
 880   (interactive
 881    (list
 882     (if (null ibuffer-saved-filters)
 883         (error "No saved filters")
 884       (completing-read "Delete saved filters: "
 885                        ibuffer-saved-filters nil t))))
 886   (setq ibuffer-saved-filters
 887         (ibuffer-delete-alist name ibuffer-saved-filters))
 888   (ibuffer-maybe-save-stuff)
 889   (ibuffer-update nil t))
 890
 891 ;;;###autoload
 892 (defun ibuffer-add-saved-filters (name)
 893   "Add saved filters from `ibuffer-saved-filters' to this buffer's filters."
 894   (interactive
 895    (list
 896     (if (null ibuffer-saved-filters)
 897         (error "No saved filters")
 898       (completing-read "Add saved filters: "
 899                        ibuffer-saved-filters nil t))))
 900   (push (cons 'saved name) ibuffer-filtering-qualifiers)
 901   (ibuffer-update nil t))
 902
 903 ;;;###autoload
 904 (defun ibuffer-switch-to-saved-filters (name)
 905   "Set this buffer's filters to filters with NAME from `ibuffer-saved-filters'.
 906 If prefix argument ADD is non-nil, then add the saved filters instead
 907 of replacing the current filters."
 908   (interactive
 909    (list
 910     (if (null ibuffer-saved-filters)
 911         (error "No saved filters")
 912       (completing-read "Switch to saved filters: "
 913                        ibuffer-saved-filters nil t))))
 914   (setq ibuffer-filtering-qualifiers (list (cons 'saved name)))
 915   (ibuffer-update nil t))
 916
 917 (defun ibuffer-format-filter-group-data (filter)
 918   (if (equal filter "Default")
 919       ""
 920     (concat "Filter:" (mapconcat #'ibuffer-format-qualifier
 921                                  (cdr (assq filter ibuffer-filter-groups))
 922                                  " "))))
 923
 924 (defun ibuffer-format-qualifier (qualifier)
 925   (if (eq (car-safe qualifier) 'not)
 926       (concat " [NOT" (ibuffer-format-qualifier-1 (cdr qualifier)) "]")
 927     (ibuffer-format-qualifier-1 qualifier)))
 928
 929 (defun ibuffer-format-qualifier-1 (qualifier)
 930   (case (car qualifier)
 931     (saved
 932      (concat " [filter: " (cdr qualifier) "]"))
 933     (or
 934      (concat " [OR" (mapconcat #'ibuffer-format-qualifier
 935                                (cdr qualifier) "") "]"))
 936     (t
 937      (let ((type (assq (car qualifier) ibuffer-filtering-alist)))
 938        (unless qualifier
 939          (error "Ibuffer: bad qualifier %s" qualifier))
 940        (concat " [" (cadr type) ": " (format "%s]" (cdr qualifier)))))))
 941
 942
 943 (defun ibuffer-list-buffer-modes ()
 944   "Create an alist of buffer modes currently in use.
 945 The list returned will be of the form (\"MODE-NAME\" . MODE-SYMBOL)."
 946   (let ((bufs (buffer-list))
 947         (modes)
 948         (this-mode))
 949     (while bufs
 950       (setq this-mode
 951             (with-current-buffer
 952                 (car bufs)
 953               major-mode)
 954             bufs (cdr bufs))
 955       (add-to-list
 956        'modes
 957        `(,(symbol-name this-mode) .
 958          ,this-mode)))
 959     modes))
 960
 961
 962 ;;; Extra operation definitions
 963
 964 ;;;###autoload (autoload 'ibuffer-filter-by-mode "ibuf-ext.el")
 965 (define-ibuffer-filter mode
 966   "Toggle current view to buffers with major mode QUALIFIER."
 967   (:description "major mode"
 968    :reader
 969    (intern
 970     (completing-read "Filter by major mode: " obarray
 971                      #'(lambda (e)
 972                          (string-match "-mode$"
 973                                        (symbol-name e)))
 974                      t
 975                      (let ((buf (ibuffer-current-buffer)))
 976                        (if (and buf (buffer-live-p buf))
 977                            (with-current-buffer buf
 978                              (symbol-name major-mode))
 979                          "")))))
 980   (eq qualifier (with-current-buffer buf major-mode)))
 981
 982 ;;;###autoload (autoload 'ibuffer-filter-by-used-mode "ibuf-ext.el")
 983 (define-ibuffer-filter used-mode
 984   "Toggle current view to buffers with major mode QUALIFIER.
 985 Called interactively, this function allows selection of modes
 986 currently used by buffers."
 987   (:description "major mode in use"
 988                 :reader
 989                 (intern
 990                  (completing-read "Filter by major mode: "
 991                                   (ibuffer-list-buffer-modes)
 992                                   nil
 993                                   t
 994                                   (let ((buf (ibuffer-current-buffer)))
 995                                     (if (and buf (buffer-live-p buf))
 996                                         (with-current-buffer buf
 997                                           (symbol-name major-mode))
 998                                       "")))))
 999   (eq qualifier (with-current-buffer buf major-mode)))
1000
1001 ;;;###autoload (autoload 'ibuffer-filter-by-name "ibuf-ext.el")
1002 (define-ibuffer-filter name
1003   "Toggle current view to buffers with name matching QUALIFIER."
1004   (:description "buffer name"
1005    :reader (read-from-minibuffer "Filter by name (regexp): "))
1006   (string-match qualifier (buffer-name buf)))
1007
1008 ;;;###autoload (autoload 'ibuffer-filter-by-filename "ibuf-ext.el")
1009 (define-ibuffer-filter filename
1010   "Toggle current view to buffers with filename matching QUALIFIER."
1011   (:description "filename"
1012    :reader (read-from-minibuffer "Filter by filename (regexp): "))
1013   (ibuffer-awhen (buffer-file-name buf)
1014     (string-match qualifier it)))
1015
1016 ;;;###autoload (autoload 'ibuffer-filter-by-size-gt  "ibuf-ext.el")
1017 (define-ibuffer-filter size-gt
1018   "Toggle current view to buffers with size greater than QUALIFIER."
1019   (:description "size greater than"
1020    :reader
1021    (string-to-number (read-from-minibuffer "Filter by size greater than: ")))
1022   (> (with-current-buffer buf (buffer-size))
1023      qualifier))
1024
1025 ;;;###autoload (autoload 'ibuffer-filter-by-size-lt  "ibuf-ext.el")
1026 (define-ibuffer-filter size-lt
1027    "Toggle current view to buffers with size less than QUALIFIER."
1028   (:description "size less than"
1029    :reader
1030    (string-to-number (read-from-minibuffer "Filter by size less than: ")))
1031   (< (with-current-buffer buf (buffer-size))
1032      qualifier))
1033
1034 ;;;###autoload (autoload 'ibuffer-filter-by-content "ibuf-ext.el")
1035 (define-ibuffer-filter content
1036    "Toggle current view to buffers whose contents match QUALIFIER."
1037   (:description "content"
1038    :reader (read-from-minibuffer "Filter by content (regexp): "))
1039   (with-current-buffer buf
1040     (save-excursion
1041       (goto-char (point-min))
1042       (re-search-forward qualifier nil t))))
1043
1044 ;;;###autoload (autoload 'ibuffer-filter-by-predicate "ibuf-ext.el")
1045 (define-ibuffer-filter predicate
1046    "Toggle current view to buffers for which QUALIFIER returns non-nil."
1047   (:description "predicate"
1048    :reader (read-minibuffer "Filter by predicate (form): "))
1049   (with-current-buffer buf
1050     (eval qualifier)))
1051
1052 ;;; Sorting
1053
1054 ;;;###autoload
1055 (defun ibuffer-toggle-sorting-mode ()
1056   "Toggle the current sorting mode.
1057 Default sorting modes are:
1058  Recency - the last time the buffer was viewed
1059  Name - the name of the buffer
1060  Major Mode - the name of the major mode of the buffer
1061  Size - the size of the buffer"
1062   (interactive)
1063   (let ((modes (mapcar 'car ibuffer-sorting-functions-alist)))
1064     (add-to-list 'modes 'recency)
1065     (setq modes (sort modes 'string-lessp))
1066     (let ((next (or (car-safe (cdr-safe (memq ibuffer-sorting-mode modes)))
1067                     (car modes))))
1068       (setq ibuffer-sorting-mode next)
1069       (message "Sorting by %s" next)))
1070   (ibuffer-redisplay t))
1071
1072 ;;;###autoload
1073 (defun ibuffer-invert-sorting ()
1074   "Toggle whether or not sorting is in reverse order."
1075   (interactive)
1076   (setq ibuffer-sorting-reversep (not ibuffer-sorting-reversep))
1077   (message "Sorting order %s"
1078            (if ibuffer-sorting-reversep
1079                "reversed"
1080              "normal"))
1081   (ibuffer-redisplay t))
1082
1083 ;;;###autoload (autoload 'ibuffer-do-sort-by-major-mode "ibuf-ext.el")
1084 (define-ibuffer-sorter major-mode
1085   "Sort the buffers by major modes.
1086 Ordering is lexicographic."
1087   (:description "major mode")
1088   (string-lessp (downcase
1089                  (symbol-name (with-current-buffer
1090                                   (car a)
1091                                 major-mode)))
1092                 (downcase
1093                  (symbol-name (with-current-buffer
1094                                   (car b)
1095                                 major-mode)))))
1096
1097 ;;;###autoload (autoload 'ibuffer-do-sort-by-mode-name "ibuf-ext.el")
1098 (define-ibuffer-sorter mode-name
1099   "Sort the buffers by their mode name.
1100 Ordering is lexicographic."
1101   (:description "major mode name")
1102   (string-lessp (downcase
1103                   (with-current-buffer
1104                       (car a)
1105                     mode-name))
1106                 (downcase
1107                  (with-current-buffer
1108                      (car b)
1109                    mode-name))))
1110
1111 ;;;###autoload (autoload 'ibuffer-do-sort-by-alphabetic "ibuf-ext.el")
1112 (define-ibuffer-sorter alphabetic
1113   "Sort the buffers by their names.
1114 Ordering is lexicographic."
1115   (:description "buffer name")
1116   (string-lessp
1117    (buffer-name (car a))
1118    (buffer-name (car b))))
1119
1120 ;;;###autoload (autoload 'ibuffer-do-sort-by-size "ibuf-ext.el")
1121 (define-ibuffer-sorter size
1122  "Sort the buffers by their size."
1123   (:description "size")
1124   (< (with-current-buffer (car a)
1125        (buffer-size))
1126      (with-current-buffer (car b)
1127        (buffer-size))))
1128
1129 ;;; Functions to emulate bs.el
1130
1131 ;;;###autoload
1132 (defun ibuffer-bs-show ()
1133   "Emulate `bs-show' from the bs.el package."
1134   (interactive)
1135   (ibuffer t "*Ibuffer-bs*" '((filename . ".*")) nil t)
1136   (define-key (current-local-map) "a" 'ibuffer-bs-toggle-all))
1137
1138 (defun ibuffer-bs-toggle-all ()
1139   "Emulate `bs-toggle-show-all' from the bs.el package."
1140   (interactive)
1141   (if ibuffer-filtering-qualifiers
1142       (ibuffer-pop-filter)
1143     (progn (ibuffer-push-filter '(filename . ".*"))
1144            (ibuffer-update nil t))))
1145
1146 ;;; Handy functions
1147
1148 ;;;###autoload
1149 (defun ibuffer-add-to-tmp-hide (regexp)
1150   "Add REGEXP to `ibuffer-tmp-hide-regexps'.
1151 This means that buffers whose name matches REGEXP will not be shown
1152 for this Ibuffer session."
1153   (interactive
1154    (list
1155     (read-from-minibuffer "Never show buffers matching: "
1156                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1157   (push regexp ibuffer-tmp-hide-regexps))
1158
1159 ;;;###autoload
1160 (defun ibuffer-add-to-tmp-show (regexp)
1161   "Add REGEXP to `ibuffer-tmp-show-regexps'.
1162 This means that buffers whose name matches REGEXP will always be shown
1163 for this Ibuffer session."
1164   (interactive
1165    (list
1166     (read-from-minibuffer "Always show buffers matching: "
1167                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1168   (push regexp ibuffer-tmp-show-regexps))
1169
1170 ;;;###autoload
1171 (defun ibuffer-forward-next-marked (&optional count mark direction)
1172   "Move forward by COUNT marked buffers (default 1).
1173
1174 If MARK is non-nil, it should be a character denoting the type of mark
1175 to move by.  The default is `ibuffer-marked-char'.
1176
1177 If DIRECTION is non-nil, it should be an integer; negative integers
1178 mean move backwards, non-negative integers mean move forwards."
1179   (interactive "P")
1180   (unless count
1181     (setq count 1))
1182   (unless mark
1183     (setq mark ibuffer-marked-char))
1184   (unless direction
1185     (setq direction 1))
1186   ;; Skip the title
1187   (ibuffer-forward-line 0)
1188   (let ((opos (point))
1189         curmark)
1190     (ibuffer-forward-line direction)
1191     (while (not (or (= (point) opos)
1192                     (eq (setq curmark (ibuffer-current-mark))
1193                         mark)))
1194       (ibuffer-forward-line direction))
1195     (when (and (= (point) opos)
1196                (not (eq (ibuffer-current-mark) mark)))
1197       (error "No buffers with mark %c" mark))))
1198
1199 ;;;###autoload
1200 (defun ibuffer-backwards-next-marked (&optional count mark)
1201    "Move backwards by COUNT marked buffers (default 1).
1202
1203 If MARK is non-nil, it should be a character denoting the type of mark
1204 to move by.  The default is `ibuffer-marked-char'."
1205    (interactive "P")
1206    (ibuffer-forward-next-marked count mark -1))
1207
1208 ;;;###autoload
1209 (defun ibuffer-do-kill-lines ()
1210   "Hide all of the currently marked lines."
1211   (interactive)
1212   (if (= (ibuffer-count-marked-lines) 0)
1213       (message "No buffers marked; use 'm' to mark a buffer")
1214     (let ((count
1215            (ibuffer-map-marked-lines
1216             #'(lambda (buf mark)
1217                 'kill))))
1218       (message "Killed %s lines" count))))
1219
1220 ;;;###autoload
1221 (defun ibuffer-jump-to-buffer (name)
1222   "Move point to the buffer whose name is NAME."
1223   (interactive (list nil))
1224   (let ((table (mapcar #'(lambda (x)
1225                            (cons (buffer-name (car x))
1226                                  (caddr x)))
1227                        (ibuffer-current-state-list t))))
1228     (when (null table)
1229       (error "No buffers!"))
1230     (when (interactive-p)
1231       (setq name (completing-read "Jump to buffer: " table nil t)))
1232     (ibuffer-aif (assoc name table)
1233         (goto-char (cdr it))
1234       (error "No buffer with name %s" name))))
1235
1236 ;;;###autoload
1237 (defun ibuffer-diff-with-file ()
1238   "View the differences between this buffer and its associated file.
1239 This requires the external program \"diff\" to be in your `exec-path'."
1240   (interactive)
1241   (let ((buf (ibuffer-current-buffer)))
1242     (unless (buffer-live-p buf)
1243       (error "Buffer %s has been killed" buf))
1244     (diff-buffer-with-file buf)))
1245
1246 ;;;###autoload
1247 (defun ibuffer-copy-filename-as-kill (&optional arg)
1248   "Copy filenames of marked buffers into the kill ring.
1249
1250 The names are separated by a space.
1251 If a buffer has no filename, it is ignored.
1252
1253 With no prefix arg, use the filename sans its directory of each marked file.
1254 With a zero prefix arg, use the complete filename of each marked file.
1255 With \\[universal-argument], use the filename of each marked file relative
1256 to `ibuffer-default-directory' iff non-nil, otherwise `default-directory'.
1257
1258 You can then feed the file name(s) to other commands with \\[yank]."
1259   (interactive "p")
1260   (if (zerop (ibuffer-count-marked-lines))
1261       (message "No buffers marked; use 'm' to mark a buffer")
1262     (let ((ibuffer-copy-filename-as-kill-result "")
1263           (type (cond ((zerop arg)
1264                        'full)
1265                       ((= arg 4)
1266                        'relative)
1267                       (t
1268                        'name))))
1269       (ibuffer-map-marked-lines
1270        #'(lambda (buf mark)
1271            (setq ibuffer-copy-filename-as-kill-result
1272                  (concat ibuffer-copy-filename-as-kill-result
1273                          (let ((name (buffer-file-name buf)))
1274                            (if name
1275                                (case type
1276                                  (full
1277                                   name)
1278                                  (relative
1279                                   (file-relative-name
1280                                    name (or ibuffer-default-directory
1281                                             default-directory)))
1282                                  (t
1283                                   (file-name-nondirectory name)))
1284                              ""))
1285                          " "))))
1286       (kill-new ibuffer-copy-filename-as-kill-result))))
1287
1288 (defun ibuffer-mark-on-buffer (func &optional ibuffer-mark-on-buffer-mark group)
1289   (let ((count
1290          (ibuffer-map-lines
1291           #'(lambda (buf mark)
1292               (when (funcall func buf)
1293                 (ibuffer-set-mark-1 (or ibuffer-mark-on-buffer-mark
1294                                         ibuffer-marked-char))
1295                 t))
1296           nil
1297           group)))
1298     (ibuffer-redisplay t)
1299     (message "Marked %s buffers" count)))
1300
1301 ;;;###autoload
1302 (defun ibuffer-mark-by-name-regexp (regexp)
1303   "Mark all buffers whose name matches REGEXP."
1304   (interactive "sMark by name (regexp): ")
1305   (ibuffer-mark-on-buffer
1306    #'(lambda (buf)
1307        (string-match regexp (buffer-name buf)))))
1308
1309 ;;;###autoload
1310 (defun ibuffer-mark-by-mode-regexp (regexp)
1311   "Mark all buffers whose major mode matches REGEXP."
1312   (interactive "sMark by major mode (regexp): ")
1313   (ibuffer-mark-on-buffer
1314    #'(lambda (buf)
1315        (with-current-buffer buf
1316          (string-match regexp mode-name)))))
1317
1318 ;;;###autoload
1319 (defun ibuffer-mark-by-file-name-regexp (regexp)
1320   "Mark all buffers whose file name matches REGEXP."
1321   (interactive "sMark by file name (regexp): ")
1322   (ibuffer-mark-on-buffer
1323    #'(lambda (buf)
1324        (let ((name (or (buffer-file-name buf)
1325                        (with-current-buffer buf
1326                          (and
1327                           (boundp 'dired-directory)
1328                           (stringp dired-directory)
1329                           dired-directory)))))
1330          (when name
1331            (string-match regexp name))))))
1332
1333 ;;;###autoload
1334 (defun ibuffer-mark-by-mode (mode)
1335   "Mark all buffers whose major mode equals MODE."
1336   (interactive
1337    (list (intern (completing-read "Mark by major mode: " obarray
1338                                   #'(lambda (e)
1339                                       ;; kind of a hack...
1340                                       (and (fboundp e)
1341                                            (string-match "-mode$"
1342                                                          (symbol-name e))))
1343                                   t
1344                                   (let ((buf (ibuffer-current-buffer)))
1345                                     (if (and buf (buffer-live-p buf))
1346                                         (with-current-buffer buf
1347                                           (cons (symbol-name major-mode)
1348                                                 0))
1349                                       ""))))))
1350   (ibuffer-mark-on-buffer
1351    #'(lambda (buf)
1352        (with-current-buffer buf
1353          (eq major-mode mode)))))
1354
1355 ;;;###autoload
1356 (defun ibuffer-mark-modified-buffers ()
1357   "Mark all modified buffers."
1358   (interactive)
1359   (ibuffer-mark-on-buffer
1360    #'(lambda (buf) (buffer-modified-p buf))))
1361
1362 ;;;###autoload
1363 (defun ibuffer-mark-unsaved-buffers ()
1364   "Mark all modified buffers that have an associated file."
1365   (interactive)
1366   (ibuffer-mark-on-buffer
1367    #'(lambda (buf) (and (with-current-buffer buf buffer-file-name)
1368                         (buffer-modified-p buf)))))
1369
1370 ;;;###autoload
1371 (defun ibuffer-mark-dissociated-buffers ()
1372   "Mark all buffers whose associated file does not exist."
1373   (interactive)
1374   (ibuffer-mark-on-buffer
1375    #'(lambda (buf)
1376        (with-current-buffer buf
1377          (or
1378           (and buffer-file-name
1379                (not (file-exists-p buffer-file-name)))
1380           (and (eq major-mode 'dired-mode)
1381                (boundp 'dired-directory)
1382                (stringp dired-directory)
1383                (not (file-exists-p (file-name-directory dired-directory)))))))))
1384
1385 ;;;###autoload
1386 (defun ibuffer-mark-help-buffers ()
1387   "Mark buffers like *Help*, *Apropos*, *Info*."
1388   (interactive)
1389   (ibuffer-mark-on-buffer
1390    #'(lambda (buf)
1391        (with-current-buffer buf
1392          (memq major-mode ibuffer-help-buffer-modes)))))
1393
1394 ;;;###autoload
1395 (defun ibuffer-mark-old-buffers ()
1396   "Mark buffers which have not been viewed in `ibuffer-old-time' days."
1397   (interactive)
1398   (ibuffer-mark-on-buffer
1399    #'(lambda (buf)
1400        (with-current-buffer buf
1401          ;; hacked from midnight.el
1402          (when buffer-display-time
1403            (let* ((tm (current-time))
1404                   (now (+ (* (float (ash 1 16)) (car tm))
1405                           (float (cadr tm)) (* 0.0000001 (caddr tm))))
1406                   (then (+ (* (float (ash 1 16))
1407                               (car buffer-display-time))
1408                            (float (cadr buffer-display-time))
1409                            (* 0.0000001 (caddr buffer-display-time)))))
1410              (> (- now then) (* 60 60 ibuffer-old-time))))))))
1411
1412 ;;;###autoload
1413 (defun ibuffer-mark-special-buffers ()
1414   "Mark all buffers whose name begins and ends with '*'."
1415   (interactive)
1416   (ibuffer-mark-on-buffer
1417    #'(lambda (buf) (string-match "^\\*.+\\*$"
1418                                  (buffer-name buf)))))
1419
1420 ;;;###autoload
1421 (defun ibuffer-mark-read-only-buffers ()
1422   "Mark all read-only buffers."
1423   (interactive)
1424   (ibuffer-mark-on-buffer
1425    #'(lambda (buf)
1426        (with-current-buffer buf
1427          buffer-read-only))))
1428
1429 ;;;###autoload
1430 (defun ibuffer-mark-dired-buffers ()
1431   "Mark all `dired' buffers."
1432   (interactive)
1433   (ibuffer-mark-on-buffer
1434    #'(lambda (buf)
1435        (with-current-buffer buf
1436          (eq major-mode 'dired-mode)))))
1437
1438 ;;;###autoload
1439 (defun ibuffer-do-occur (regexp &optional nlines)
1440   "View lines which match REGEXP in all marked buffers.
1441 Optional argument NLINES says how many lines of context to display: it
1442 defaults to one."
1443   (interactive (occur-read-primary-args))
1444   (if (or (not (integerp nlines))
1445           (< nlines 0))
1446       (setq nlines 0))
1447   (when (zerop (ibuffer-count-marked-lines))
1448     (ibuffer-set-mark ibuffer-marked-char))
1449   (let ((ibuffer-do-occur-bufs nil))
1450     ;; Accumulate a list of marked buffers
1451     (ibuffer-map-marked-lines
1452      #'(lambda (buf mark)
1453          (push buf ibuffer-do-occur-bufs)))
1454     (occur-1 regexp nlines ibuffer-do-occur-bufs)))
1455
1456 (provide 'ibuf-ext)
1457
1458 ;;; ibuf-ext.el ends here