lisp/net/tramp-gw.el

   1 ;;; tramp-gw.el --- Tramp utility functions for HTTP tunnels and SOCKS gateways
   2
   3 ;; Copyright (C) 2007-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Michael Albinus <michael.albinus@gmx.de>
   6 ;; Keywords: comm, processes
   7 ;; Package: tramp
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Access functions for HTTP tunnels and SOCKS gateways from Tramp.
  27 ;; SOCKS functionality is implemented by socks.el from the w3 package.
  28 ;; HTTP tunnels are partly implemented in socks.el and url-http.el;
  29 ;; both implementations are not complete.  Therefore, it is
  30 ;; implemented in this package.
  31
  32 ;;; Code:
  33
  34 (require 'tramp)
  35
  36 ;; Pacify byte-compiler.
  37 (eval-when-compile
  38   (require 'cl)
  39   (require 'custom))
  40 (defvar socks-noproxy)
  41
  42 ;; We don't add the following methods to `tramp-methods', in order to
  43 ;; exclude them from file name completion.
  44
  45 ;; Define HTTP tunnel method ...
  46 ;;;###tramp-autoload
  47 (defconst tramp-gw-tunnel-method "tunnel"
  48   "Method to connect HTTP gateways.")
  49
  50 ;; ... and port.
  51 (defconst tramp-gw-default-tunnel-port 8080
  52   "Default port for HTTP gateways.")
  53
  54 ;; Define SOCKS method ...
  55 ;;;###tramp-autoload
  56 (defconst tramp-gw-socks-method "socks"
  57   "Method to connect SOCKS servers.")
  58
  59 ;; ... and port.
  60 (defconst tramp-gw-default-socks-port 1080
  61   "Default port for SOCKS servers.")
  62
  63 ;; Autoload the socks library.  It is used only when we access a SOCKS server.
  64 (autoload 'socks-open-network-stream "socks")
  65 (defvar socks-username (user-login-name))
  66 (defvar socks-server
  67   (list "Default server" "socks" tramp-gw-default-socks-port 5))
  68
  69 ;; Add a default for `tramp-default-user-alist'.  Default is the local user.
  70 ;;;###tramp-autoload
  71 (add-to-list
  72  'tramp-default-user-alist
  73  (list (concat "\\`"
  74                (regexp-opt (list tramp-gw-tunnel-method tramp-gw-socks-method))
  75                "\\'")
  76        nil (user-login-name)))
  77
  78 ;; Internal file name functions and variables.
  79
  80 (defvar tramp-gw-vector nil
  81   "Keeps the remote host identification.  Needed for Tramp messages.")
  82
  83 (defvar tramp-gw-gw-vector nil
  84   "Current gateway identification vector.")
  85
  86 (defvar tramp-gw-gw-proc nil
  87   "Current gateway process.")
  88
  89 ;; This variable keeps the listening process, in order to reuse it for
  90 ;; new processes.
  91 (defvar tramp-gw-aux-proc nil
  92   "Process listening on local port, as mediation between SSH and the gateway.")
  93
  94 (defun tramp-gw-gw-proc-sentinel (proc _event)
  95   "Delete auxiliary process when we are deleted."
  96   (unless (memq (process-status proc) '(run open))
  97     (tramp-message
  98      tramp-gw-vector 4 "Deleting auxiliary process `%s'" tramp-gw-gw-proc)
  99     (let* ((tramp-verbose 0)
 100            (p (tramp-get-connection-property proc "process" nil)))
 101       (when (processp p) (delete-process p)))))
 102
 103 (defun tramp-gw-aux-proc-sentinel (proc _event)
 104   "Activate the different filters for involved gateway and auxiliary processes."
 105   (when (memq (process-status proc) '(run open))
 106     ;; A new process has been spawned from `tramp-gw-aux-proc'.
 107     (tramp-message
 108      tramp-gw-vector 4
 109      "Opening auxiliary process `%s', speaking with process `%s'"
 110      proc tramp-gw-gw-proc)
 111     (set-process-query-on-exit-flag proc nil)
 112     ;; We don't want debug messages, because the corresponding debug
 113     ;; buffer might be undecided.
 114     (let ((tramp-verbose 0))
 115       (tramp-set-connection-property tramp-gw-gw-proc "process" proc)
 116       (tramp-set-connection-property proc "process" tramp-gw-gw-proc))
 117     ;; Set the process-filter functions for both processes.
 118     (set-process-filter proc 'tramp-gw-process-filter)
 119     (set-process-filter tramp-gw-gw-proc 'tramp-gw-process-filter)
 120     ;; There might be already some output from the gateway process.
 121     (with-current-buffer (process-buffer tramp-gw-gw-proc)
 122       (unless (= (point-min) (point-max))
 123         (let ((s (buffer-string)))
 124           (delete-region (point) (point-max))
 125           (tramp-gw-process-filter tramp-gw-gw-proc s))))))
 126
 127 (defun tramp-gw-process-filter (proc string)
 128   "Resend the string to the other pocess."
 129   (let ((tramp-verbose 0))
 130     ;; The other process might have been stopped already.  We don't
 131     ;; want to be interrupted then.
 132     (ignore-errors
 133       (process-send-string
 134        (tramp-get-connection-property proc "process" nil) string))))
 135
 136 ;;;###tramp-autoload
 137 (defun tramp-gw-open-connection (vec gw-vec target-vec)
 138   "Open a remote connection to VEC (see `tramp-file-name' structure).
 139 Take GW-VEC as SOCKS or HTTP gateway, i.e. its method must be a
 140 gateway method.  TARGET-VEC identifies where to connect to via
 141 the gateway, it can be different from VEC when there are more
 142 hops to be applied.
 143
 144 It returns a string like \"localhost#port\", which must be used
 145 instead of the host name declared in TARGET-VEC."
 146
 147   ;; Remember vectors for property retrieval.
 148   (setq tramp-gw-vector vec
 149         tramp-gw-gw-vector gw-vec)
 150
 151   ;; Start listening auxiliary process.
 152   (unless (and (processp tramp-gw-aux-proc)
 153                (memq (process-status tramp-gw-aux-proc) '(listen)))
 154     (let ((aux-vec
 155            (vector "aux" (tramp-file-name-user gw-vec)
 156                    (tramp-file-name-host gw-vec) nil nil)))
 157       (setq tramp-gw-aux-proc
 158             (make-network-process
 159              :name (tramp-buffer-name aux-vec) :buffer nil :host 'local
 160              :server t :noquery t :service t :coding 'binary))
 161       (set-process-sentinel tramp-gw-aux-proc 'tramp-gw-aux-proc-sentinel)
 162       (set-process-query-on-exit-flag tramp-gw-aux-proc nil)
 163       (tramp-message
 164        vec 4 "Opening auxiliary process `%s', listening on port %d"
 165        tramp-gw-aux-proc (process-contact tramp-gw-aux-proc :service))))
 166
 167   (let* ((gw-method
 168           (intern
 169            (tramp-find-method
 170             (tramp-file-name-method gw-vec)
 171             (tramp-file-name-user gw-vec)
 172             (tramp-file-name-host gw-vec))))
 173          (socks-username
 174           (tramp-find-user
 175            (tramp-file-name-method gw-vec)
 176            (tramp-file-name-user gw-vec)
 177            (tramp-file-name-host gw-vec)))
 178          ;; Declare the SOCKS server to be used.
 179          (socks-server
 180           (list "Tramp temporary socks server list"
 181                 ;; Host name.
 182                 (tramp-file-name-real-host gw-vec)
 183                 ;; Port number.
 184                 (or (tramp-file-name-port gw-vec)
 185                     (case gw-method
 186                       (tunnel tramp-gw-default-tunnel-port)
 187                       (socks tramp-gw-default-socks-port)))
 188                 ;; Type.  We support only http and socks5, NO socks4.
 189                 ;; 'http could be used when HTTP tunnel works in socks.el.
 190                 5))
 191          ;; The function to be called.
 192          (socks-function
 193           (case gw-method
 194             (tunnel 'tramp-gw-open-network-stream)
 195             (socks 'socks-open-network-stream)))
 196          socks-noproxy)
 197
 198     ;; Open SOCKS process.
 199     (setq tramp-gw-gw-proc
 200           (funcall
 201            socks-function
 202            (let ((tramp-verbose 0)) (tramp-get-connection-name gw-vec))
 203            (let ((tramp-verbose 0)) (tramp-get-connection-buffer gw-vec))
 204            (tramp-file-name-real-host target-vec)
 205            (tramp-file-name-port target-vec)))
 206     (set-process-sentinel tramp-gw-gw-proc 'tramp-gw-gw-proc-sentinel)
 207     (set-process-coding-system tramp-gw-gw-proc 'binary 'binary)
 208     (set-process-query-on-exit-flag tramp-gw-gw-proc nil)
 209     (tramp-message
 210      vec 4 "Opened %s process `%s'"
 211      (case gw-method ('tunnel "HTTP tunnel") ('socks "SOCKS"))
 212      tramp-gw-gw-proc)
 213
 214     ;; Return the new host for gateway access.
 215     (format "localhost#%d" (process-contact tramp-gw-aux-proc :service))))
 216
 217 (defun tramp-gw-open-network-stream (name buffer host service)
 218   "Open stream to proxy server HOST:SERVICE.
 219 Resulting process has name NAME and buffer BUFFER.  If
 220 authentication is requested from proxy server, provide it."
 221   (let ((command (format (concat
 222                           "CONNECT %s:%d HTTP/1.1\r\n"
 223                           "Host: %s:%d\r\n"
 224                           "Connection: keep-alive\r\n"
 225                           "User-Agent: Tramp/%s\r\n")
 226                          host service host service tramp-version))
 227         (authentication "")
 228         (first t)
 229         found proc)
 230
 231     (while (not found)
 232       ;; Clean up.
 233       (when (processp proc) (delete-process proc))
 234       (with-current-buffer buffer (erase-buffer))
 235       ;; Open network stream.
 236       (setq proc (open-network-stream
 237                   name buffer (nth 1 socks-server) (nth 2 socks-server)))
 238       (set-process-coding-system proc 'binary 'binary)
 239       (set-process-query-on-exit-flag proc nil)
 240       ;; Send CONNECT command.
 241       (process-send-string proc (format "%s%s\r\n" command authentication))
 242       (tramp-message
 243        tramp-gw-vector 6 "\n%s"
 244        (format
 245         "%s%s\r\n" command
 246         (replace-regexp-in-string ;; no password in trace!
 247          "Basic [^\r\n]+" "Basic xxxxx" authentication t)))
 248       (with-current-buffer buffer
 249         ;; Trap errors to be traced in the right trace buffer.  Often,
 250         ;; proxies have a timeout of 60".  We wait 65" in order to
 251         ;; receive an answer this case.
 252         (ignore-errors
 253           (let ((tramp-verbose 0))
 254             (tramp-wait-for-regexp proc 65 "\r?\n\r?\n")))
 255         ;; Check return code.
 256         (goto-char (point-min))
 257         (narrow-to-region
 258          (point-min)
 259          (or (search-forward-regexp "\r?\n\r?\n" nil t) (point-max)))
 260         (tramp-message tramp-gw-vector 6 "\n%s" (buffer-string))
 261         (goto-char (point-min))
 262         (search-forward-regexp "^HTTP/[1-9]\\.[0-9]" nil t)
 263         (case (condition-case nil (read (current-buffer)) (error))
 264           ;; Connected.
 265           (200 (setq found t))
 266           ;; We need basic authentication.
 267           (401 (setq authentication (tramp-gw-basic-authentication nil first)))
 268           ;; Access forbidden.
 269           (403 (tramp-error-with-buffer
 270                 (current-buffer) tramp-gw-vector 'file-error
 271                 "Connection to %s:%d forbidden." host service))
 272           ;; Target host not found.
 273           (404 (tramp-error-with-buffer
 274                 (current-buffer) tramp-gw-vector 'file-error
 275                 "Host %s not found." host))
 276           ;; We need basic proxy authentication.
 277           (407 (setq authentication (tramp-gw-basic-authentication t first)))
 278           ;; Connection failed.
 279           (503 (tramp-error-with-buffer
 280                 (current-buffer) tramp-gw-vector 'file-error
 281                 "Connection to %s:%d failed." host service))
 282           ;; That doesn't work at all.
 283           (t (tramp-error-with-buffer
 284               (current-buffer) tramp-gw-vector 'file-error
 285               "Access to HTTP server %s:%d failed."
 286               (nth 1 socks-server) (nth 2 socks-server))))
 287         ;; Remove HTTP headers.
 288         (delete-region (point-min) (point-max))
 289         (widen)
 290         (setq first nil)))
 291     ;; Return the process.
 292     proc))
 293
 294 (defun tramp-gw-basic-authentication (proxy pw-cache)
 295   "Return authentication header for CONNECT, based on server request.
 296 PROXY is an indication whether we need a Proxy-Authorization header
 297 or an Authorization header.  If PW-CACHE is non-nil, check for
 298 password in password cache.  This is done for the first try only."
 299
 300   ;; `tramp-current-*' must be set for `tramp-read-passwd'.
 301   (let ((tramp-current-method (tramp-file-name-method tramp-gw-gw-vector))
 302         (tramp-current-user (tramp-file-name-user tramp-gw-gw-vector))
 303         (tramp-current-host (tramp-file-name-host tramp-gw-gw-vector)))
 304     (unless pw-cache (tramp-clear-passwd tramp-gw-gw-vector))
 305     ;; We are already in the right buffer.
 306     (tramp-message
 307      tramp-gw-vector 5 "%s required"
 308      (if proxy "Proxy authentication" "Authentication"))
 309     ;; Search for request header.  We accept only basic authentication.
 310     (goto-char (point-min))
 311     (search-forward-regexp
 312      "^\\(Proxy\\|WWW\\)-Authenticate:\\s-*Basic\\s-+realm=")
 313     ;; Return authentication string.
 314     (format
 315      "%s: Basic %s\r\n"
 316      (if proxy "Proxy-Authorization" "Authorization")
 317      (base64-encode-string
 318       (format
 319        "%s:%s"
 320        socks-username
 321        (tramp-read-passwd
 322         nil
 323         (format
 324          "Password for %s@[%s]: " socks-username (read (current-buffer)))))))))
 325
 326 (add-hook 'tramp-unload-hook
 327           (lambda ()
 328             (unload-feature 'tramp-gw 'force)))
 329
 330 (provide 'tramp-gw)
 331
 332 ;;; TODO:
 333
 334 ;; * Provide descriptive Commentary.
 335 ;; * Enable it for several gateway processes in parallel.
 336
 337 ;;; tramp-gw.el ends here