lisp/progmodes/which-func.el

   1 ;;; which-func.el --- print current function in mode line
   2
   3 ;; Copyright (C) 1994, 1997, 1998, 2001, 2002, 2003, 2004, 2005, 2006
   4 ;;   2007, 2008, 2009, 2010  Free Software Foundation, Inc.
   5
   6 ;; Author:   Alex Rezinsky <alexr@msil.sps.mot.com>
   7 ;;           (doesn't seem to be responsive any more)
   8 ;; Keywords: mode-line, imenu, tools
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This package prints name of function where your current point is
  28 ;; located in mode line. It assumes that you work with imenu package
  29 ;; and imenu--index-alist is up to date.
  30
  31 ;; KNOWN BUGS
  32 ;; ----------
  33 ;; Really this package shows not "function where the current point is
  34 ;; located now", but "nearest function which defined above the current
  35 ;; point". So if your current point is located after end of function
  36 ;; FOO but before begin of function BAR, FOO will be displayed in mode
  37 ;; line.
  38 ;; - if two windows display the same buffer, both windows
  39 ;;   show the same `which-func' information.
  40
  41 ;; TODO LIST
  42 ;; ---------
  43 ;;     1. Dependence on imenu package should be removed.  Separate
  44 ;; function determination mechanism should be used to determine the end
  45 ;; of a function as well as the beginning of a function.
  46 ;;     2. This package should be realized with the help of overlay
  47 ;; properties instead of imenu--index-alist variable.
  48
  49 ;;; History:
  50
  51 ;; THANKS TO
  52 ;; ---------
  53 ;; Per Abrahamsen   <abraham@iesd.auc.dk>
  54 ;;     Some ideas (inserting  in mode-line,  using of post-command  hook
  55 ;;     and toggling this  mode) have  been   borrowed from  his  package
  56 ;;     column.el
  57 ;; Peter Eisenhauer <pipe@fzi.de>
  58 ;;     Bug fixing in case nested indexes.
  59 ;; Terry Tateyama   <ttt@ursa0.cs.utah.edu>
  60 ;;     Suggestion to use find-file-hook for first imenu
  61 ;;     index building.
  62
  63 ;;; Code:
  64
  65 ;; Variables for customization
  66 ;; ---------------------------
  67 ;;
  68 (defvar which-func-unknown "???"
  69   "String to display in the mode line when current function is unknown.")
  70
  71 (defgroup which-func nil
  72   "Mode to display the current function name in the modeline."
  73   :group 'tools
  74   :version "20.3")
  75
  76 (defcustom which-func-modes
  77   '(emacs-lisp-mode c-mode c++-mode perl-mode cperl-mode python-mode
  78                     makefile-mode sh-mode fortran-mode f90-mode ada-mode
  79                     diff-mode)
  80   "List of major modes for which Which Function mode should be used.
  81 For other modes it is disabled.  If this is equal to t,
  82 then Which Function mode is enabled in any major mode that supports it."
  83   :group 'which-func
  84   :type '(choice (const :tag "All modes" t)
  85                  (repeat (symbol :tag "Major mode"))))
  86
  87 (defcustom which-func-non-auto-modes nil
  88   "List of major modes where Which Function mode is inactive till Imenu is used.
  89 This means that Which Function mode won't really do anything
  90 until you use Imenu, in these modes.  Note that files
  91 larger than `which-func-maxout' behave in this way too;
  92 Which Function mode doesn't do anything until you use Imenu."
  93   :group 'which-func
  94   :type '(repeat (symbol :tag "Major mode")))
  95
  96 (defcustom which-func-maxout 500000
  97   "Don't automatically compute the Imenu menu if buffer is this big or bigger.
  98 Zero means compute the Imenu menu regardless of size."
  99   :group 'which-func
 100   :type 'integer)
 101
 102 (defvar which-func-keymap
 103   (let ((map (make-sparse-keymap)))
 104     (define-key map [mode-line mouse-1] 'beginning-of-defun)
 105     (define-key map [mode-line mouse-2]
 106       (lambda ()
 107         (interactive)
 108         (if (eq (point-min) 1)
 109             (narrow-to-defun)
 110           (widen))))
 111     (define-key map [mode-line mouse-3] 'end-of-defun)
 112     map)
 113   "Keymap to display on mode line which-func.")
 114
 115 (defface which-func
 116   ;; Whether `font-lock-function-name-face' is an appropriate face to
 117   ;; inherit depends on the mode-line face; define several variants based
 118   ;; on the default mode-line face.
 119   '(;; The default mode-line face on a high-color display is a relatively
 120     ;; light color ("grey75"), and only the light-background variant of
 121     ;; `font-lock-function-name-face' is visible against it.
 122     (((class color) (min-colors 88) (background light))
 123      :inherit font-lock-function-name-face)
 124     ;; The default mode-line face on other display types is inverse-video;
 125     ;; it seems that only in the dark-background case is
 126     ;; `font-lock-function-name-face' visible against it.
 127     (((class grayscale mono) (background dark))
 128      :inherit font-lock-function-name-face)
 129     (((class color) (background light))
 130      :inherit font-lock-function-name-face)
 131     ;; If none of the above cases, use an explicit color chosen to contrast
 132     ;; well with the default mode-line face.
 133     (((class color) (min-colors 88) (background dark))
 134      :foreground "Blue1")
 135     (((background dark))
 136      :foreground "Blue1")
 137     (t
 138      :foreground "LightSkyBlue"))
 139   "Face used to highlight mode line function names."
 140   :group 'which-func)
 141
 142 (defcustom which-func-format
 143   `("["
 144     (:propertize which-func-current
 145                  local-map ,which-func-keymap
 146                  face which-func
 147                  ;;mouse-face highlight ; currently not evaluated :-(
 148                  help-echo "mouse-1: go to beginning, mouse-2: toggle rest visibility, mouse-3: go to end")
 149     "]")
 150   "Format for displaying the function in the mode line."
 151   :group 'which-func
 152   :type 'sexp)
 153 ;;;###autoload (put 'which-func-format 'risky-local-variable t)
 154
 155 (defvar which-func-imenu-joiner-function #'last
 156   "Function to join together multiple levels of imenu nomenclature.
 157 Called with a single argument, a list of strings giving the names
 158 of the menus we had to traverse to get to the item.  Returns a
 159 single string, the new name of the item.")
 160
 161 (defvar which-func-cleanup-function nil
 162   "Function to transform a string before displaying it in the mode line.
 163 The function is called with one argument, the string to display.
 164 Its return value is displayed in the modeline.
 165 If nil, no function is called.  The default value is nil.
 166
 167 This feature can be useful if Imenu is set up to make more
 168 detailed entries (e.g., containing the argument list of a function),
 169 and you want to simplify them for the mode line
 170 \(e.g., removing the parameter list to just have the function name.)")
 171
 172 ;;; Code, nothing to customize below here
 173 ;;; -------------------------------------
 174 ;;;
 175 (require 'imenu)
 176
 177 (defvar which-func-table (make-hash-table :test 'eq :weakness 'key))
 178
 179 (defconst which-func-current
 180   '(:eval (gethash (selected-window) which-func-table which-func-unknown)))
 181 ;;;###autoload (put 'which-func-current 'risky-local-variable t)
 182
 183 (defvar which-func-mode nil
 184   "Non-nil means display current function name in mode line.
 185 This makes a difference only if `which-function-mode' is non-nil.")
 186 (make-variable-buffer-local 'which-func-mode)
 187 ;;(put 'which-func-mode 'permanent-local t)
 188
 189 (add-hook 'find-file-hook 'which-func-ff-hook t)
 190
 191 (defun which-func-ff-hook ()
 192   "File find hook for Which Function mode.
 193 It creates the Imenu index for the buffer, if necessary."
 194   (setq which-func-mode
 195         (and which-function-mode
 196              (or (eq which-func-modes t)
 197                  (member major-mode which-func-modes))))
 198
 199   (condition-case nil
 200       (if (and which-func-mode
 201                (not (member major-mode which-func-non-auto-modes))
 202                (or (null which-func-maxout)
 203                    (< buffer-saved-size which-func-maxout)
 204                    (= which-func-maxout 0)))
 205           (setq imenu--index-alist
 206                 (save-excursion (funcall imenu-create-index-function))))
 207     (error
 208      (setq which-func-mode nil))))
 209
 210 (defun which-func-update ()
 211   ;; "Update the Which-Function mode display for all windows."
 212   ;; (walk-windows 'which-func-update-1 nil 'visible))
 213   (which-func-update-1 (selected-window)))
 214
 215 (defun which-func-update-1 (window)
 216   "Update the Which Function mode display for window WINDOW."
 217   (with-selected-window window
 218     (when which-func-mode
 219       (condition-case info
 220           (let ((current (which-function)))
 221             (unless (equal current (gethash window which-func-table))
 222               (puthash window current which-func-table)
 223               (force-mode-line-update)))
 224         (error
 225          (setq which-func-mode nil)
 226          (error "Error in which-func-update: %s" info))))))
 227
 228 ;;;###autoload
 229 (defalias 'which-func-mode 'which-function-mode)
 230
 231 (defvar which-func-update-timer nil)
 232
 233 ;; This is the name people would normally expect.
 234 ;;;###autoload
 235 (define-minor-mode which-function-mode
 236   "Toggle Which Function mode, globally.
 237 When Which Function mode is enabled, the current function name is
 238 continuously displayed in the mode line, in certain major modes.
 239
 240 With prefix ARG, turn Which Function mode on if arg is positive,
 241 and off otherwise."
 242   :global t :group 'which-func
 243   (if which-function-mode
 244       ;;Turn it on
 245       (progn
 246         (setq which-func-update-timer
 247               (run-with-idle-timer idle-update-delay t 'which-func-update))
 248         (dolist (buf (buffer-list))
 249           (with-current-buffer buf
 250             (setq which-func-mode
 251                   (or (eq which-func-modes t)
 252                       (member major-mode which-func-modes))))))
 253     ;; Turn it off
 254     (when (timerp which-func-update-timer)
 255       (cancel-timer which-func-update-timer))
 256     (setq which-func-update-timer nil)
 257     (dolist (buf (buffer-list))
 258       (with-current-buffer buf (setq which-func-mode nil)))))
 259
 260 (defvar which-function-imenu-failed nil
 261   "Locally t in a buffer if `imenu--make-index-alist' found nothing there.")
 262
 263 (defvar which-func-functions nil
 264   "List of functions for `which-function' to call with no arguments.
 265 It calls them sequentially, and if any returns non-nil,
 266 `which-function' uses that name and stops looking for the name.")
 267
 268 (defun which-function ()
 269   "Return current function name based on point.
 270 Uses `which-func-functions', `imenu--index-alist'
 271 or `add-log-current-defun-function'.
 272 If no function name is found, return nil."
 273   (let ((name
 274          ;; Try the `which-func-functions' functions first.
 275          (run-hook-with-args-until-success 'which-func-functions)))
 276
 277     ;; If Imenu is loaded, try to make an index alist with it.
 278     (when (and (null name)
 279                (boundp 'imenu--index-alist) (null imenu--index-alist)
 280                (null which-function-imenu-failed))
 281       (imenu--make-index-alist t)
 282       (unless imenu--index-alist
 283         (make-local-variable 'which-function-imenu-failed)
 284         (setq which-function-imenu-failed t)))
 285     ;; If we have an index alist, use it.
 286     (when (and (null name)
 287                (boundp 'imenu--index-alist) imenu--index-alist)
 288       (let ((alist imenu--index-alist)
 289             (minoffset (point-max))
 290             offset pair mark imstack namestack)
 291         ;; Elements of alist are either ("name" . marker), or
 292         ;; ("submenu" ("name" . marker) ... ). The list can be
 293         ;; arbitrarily nested.
 294         (while (or alist imstack)
 295           (if alist
 296               (progn
 297                 (setq pair (car-safe alist)
 298                       alist (cdr-safe alist))
 299
 300                 (cond ((atom pair))     ; skip anything not a cons
 301
 302                       ((imenu--subalist-p pair)
 303                        (setq imstack   (cons alist imstack)
 304                              namestack (cons (car pair) namestack)
 305                              alist     (cdr pair)))
 306
 307                       ((number-or-marker-p (setq mark (cdr pair)))
 308                        (if (>= (setq offset (- (point) mark)) 0)
 309                            (if (< offset minoffset) ; find the closest item
 310                                (setq minoffset offset
 311                                      name (funcall
 312                                            which-func-imenu-joiner-function
 313                                            (reverse (cons (car pair)
 314                                                           namestack)))))))))
 315             (setq alist     (car imstack)
 316                   namestack (cdr namestack)
 317                   imstack   (cdr imstack))))))
 318
 319     ;; Try using add-log support.
 320     (when (and (null name) (boundp 'add-log-current-defun-function)
 321                add-log-current-defun-function)
 322       (setq name (funcall add-log-current-defun-function)))
 323     ;; Filter the name if requested.
 324     (when name
 325       (if which-func-cleanup-function
 326           (funcall which-func-cleanup-function name)
 327         name))))
 328
 329 (provide 'which-func)
 330
 331 ;; arch-tag: fa8a55c7-bfe3-4ffc-95ab-01bf21796827
 332 ;;; which-func.el ends here