lisp/image.el

   1 ;;; image.el --- image API
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: multimedia
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28
  29 (defgroup image ()
  30   "Image support."
  31   :group 'multimedia)
  32
  33
  34 (defconst image-type-header-regexps
  35   `(("\\`/[\t\n\r ]*\\*.*XPM.\\*/" . xpm)
  36     ("\\`P[1-6][[:space:]]+\\(?:#.*[[:space:]]+\\)*[0-9]+[[:space:]]+[0-9]+" . pbm)
  37     ("\\`GIF8[79]a" . gif)
  38     ("\\`\x89PNG\r\n\x1a\n" . png)
  39     ("\\`[\t\n\r ]*#define \\([a-z0-9_]+\\)_width [0-9]+\n\
  40 #define \\1_height [0-9]+\n\\(\
  41 #define \\1_x_hot [0-9]+\n\
  42 #define \\1_y_hot [0-9]+\n\\)?\
  43 static \\(unsigned \\)?char \\1_bits" . xbm)
  44     ("\\`\\(?:MM\0\\*\\|II\\*\0\\)" . tiff)
  45     ("\\`[\t\n\r ]*%!PS" . postscript)
  46     ("\\`\xff\xd8" . (image-jpeg-p . jpeg))
  47     (,(let* ((incomment-re "\\(?:[^-]\\|-[^-]\\)")
  48              (comment-re (concat "\\(?:!--" incomment-re "*-->[ \t\r\n]*<\\)")))
  49         (concat "\\(?:<\\?xml[ \t\r\n]+[^>]*>\\)?[ \t\r\n]*<"
  50                 comment-re "*"
  51                 "\\(?:!DOCTYPE[ \t\r\n]+[^>]*>[ \t\r\n]*<[ \t\r\n]*" comment-re "*\\)?"
  52                 "[Ss][Vv][Gg]"))
  53      . svg)
  54     )
  55   "Alist of (REGEXP . IMAGE-TYPE) pairs used to auto-detect image types.
  56 When the first bytes of an image file match REGEXP, it is assumed to
  57 be of image type IMAGE-TYPE if IMAGE-TYPE is a symbol.  If not a symbol,
  58 IMAGE-TYPE must be a pair (PREDICATE . TYPE).  PREDICATE is called
  59 with one argument, a string containing the image data.  If PREDICATE returns
  60 a non-nil value, TYPE is the image's type.")
  61
  62 (defconst image-type-file-name-regexps
  63   '(("\\.png\\'" . png)
  64     ("\\.gif\\'" . gif)
  65     ("\\.jpe?g\\'" . jpeg)
  66     ("\\.bmp\\'" . bmp)
  67     ("\\.xpm\\'" . xpm)
  68     ("\\.pbm\\'" . pbm)
  69     ("\\.xbm\\'" . xbm)
  70     ("\\.ps\\'" . postscript)
  71     ("\\.tiff?\\'" . tiff)
  72     ("\\.svgz?\\'" . svg)
  73     )
  74   "Alist of (REGEXP . IMAGE-TYPE) pairs used to identify image files.
  75 When the name of an image file match REGEXP, it is assumed to
  76 be of image type IMAGE-TYPE.")
  77
  78 ;; We rely on `auto-mode-alist' to detect xbm and xpm files, instead
  79 ;; of content autodetection.  Their contents are just C code, so it is
  80 ;; easy to generate false matches.
  81 (defvar image-type-auto-detectable
  82   '((pbm . t)
  83     (xbm . nil)
  84     (bmp . maybe)
  85     (gif . maybe)
  86     (png . maybe)
  87     (xpm . nil)
  88     (jpeg . maybe)
  89     (tiff . maybe)
  90     (svg . maybe)
  91     (postscript . nil))
  92   "Alist of (IMAGE-TYPE . AUTODETECT) pairs used to auto-detect image files.
  93 \(See `image-type-auto-detected-p').
  94
  95 AUTODETECT can be
  96  - t      always auto-detect.
  97  - nil    never auto-detect.
  98  - maybe  auto-detect only if the image type is available
  99             (see `image-type-available-p').")
 100
 101 (defvar image-load-path nil
 102   "List of locations in which to search for image files.
 103 If an element is a string, it defines a directory to search.
 104 If an element is a variable symbol whose value is a string, that
 105 value defines a directory to search.
 106 If an element is a variable symbol whose value is a list, the
 107 value is used as a list of directories to search.")
 108
 109 (eval-at-startup
 110  (setq image-load-path
 111        (list (file-name-as-directory (expand-file-name "images" data-directory))
 112              'data-directory 'load-path)))
 113
 114
 115 (defun image-load-path-for-library (library image &optional path no-error)
 116   "Return a suitable search path for images used by LIBRARY.
 117
 118 It searches for IMAGE in `image-load-path' (excluding
 119 \"`data-directory'/images\") and `load-path', followed by a path
 120 suitable for LIBRARY, which includes \"../../etc/images\" and
 121 \"../etc/images\" relative to the library file itself, and then
 122 in \"`data-directory'/images\".
 123
 124 Then this function returns a list of directories which contains
 125 first the directory in which IMAGE was found, followed by the
 126 value of `load-path'.  If PATH is given, it is used instead of
 127 `load-path'.
 128
 129 If NO-ERROR is non-nil and a suitable path can't be found, don't
 130 signal an error.  Instead, return a list of directories as before,
 131 except that nil appears in place of the image directory.
 132
 133 Here is an example that uses a common idiom to provide
 134 compatibility with versions of Emacs that lack the variable
 135 `image-load-path':
 136
 137     ;; Shush compiler.
 138     (defvar image-load-path)
 139
 140     (let* ((load-path (image-load-path-for-library \"mh-e\" \"mh-logo.xpm\"))
 141            (image-load-path (cons (car load-path)
 142                                   (when (boundp 'image-load-path)
 143                                     image-load-path))))
 144       (mh-tool-bar-folder-buttons-init))"
 145   (unless library (error "No library specified"))
 146   (unless image   (error "No image specified"))
 147   (let (image-directory image-directory-load-path)
 148     ;; Check for images in image-load-path or load-path.
 149     (let ((img image)
 150           (dir (or
 151                 ;; Images in image-load-path.
 152                 (image-search-load-path image)
 153                 ;; Images in load-path.
 154                 (locate-library image)))
 155           parent)
 156       ;; Since the image might be in a nested directory (for
 157       ;; example, mail/attach.pbm), adjust `image-directory'
 158       ;; accordingly.
 159       (when dir
 160         (setq dir (file-name-directory dir))
 161         (while (setq parent (file-name-directory img))
 162           (setq img (directory-file-name parent)
 163                 dir (expand-file-name "../" dir))))
 164       (setq image-directory-load-path dir))
 165
 166     ;; If `image-directory-load-path' isn't Emacs' image directory,
 167     ;; it's probably a user preference, so use it. Then use a
 168     ;; relative setting if possible; otherwise, use
 169     ;; `image-directory-load-path'.
 170     (cond
 171      ;; User-modified image-load-path?
 172      ((and image-directory-load-path
 173            (not (equal image-directory-load-path
 174                        (file-name-as-directory
 175                         (expand-file-name "images" data-directory)))))
 176       (setq image-directory image-directory-load-path))
 177      ;; Try relative setting.
 178      ((let (library-name d1ei d2ei)
 179         ;; First, find library in the load-path.
 180         (setq library-name (locate-library library))
 181         (if (not library-name)
 182             (error "Cannot find library %s in load-path" library))
 183         ;; And then set image-directory relative to that.
 184         (setq
 185          ;; Go down 2 levels.
 186          d2ei (file-name-as-directory
 187                (expand-file-name
 188                 (concat (file-name-directory library-name) "../../etc/images")))
 189          ;; Go down 1 level.
 190          d1ei (file-name-as-directory
 191                (expand-file-name
 192                 (concat (file-name-directory library-name) "../etc/images"))))
 193         (setq image-directory
 194               ;; Set it to nil if image is not found.
 195               (cond ((file-exists-p (expand-file-name image d2ei)) d2ei)
 196                     ((file-exists-p (expand-file-name image d1ei)) d1ei)))))
 197      ;; Use Emacs' image directory.
 198      (image-directory-load-path
 199       (setq image-directory image-directory-load-path))
 200      (no-error
 201       (message "Could not find image %s for library %s" image library))
 202      (t
 203       (error "Could not find image %s for library %s" image library)))
 204
 205     ;; Return an augmented `path' or `load-path'.
 206     (nconc (list image-directory)
 207            (delete image-directory (copy-sequence (or path load-path))))))
 208
 209
 210 (defun image-jpeg-p (data)
 211   "Value is non-nil if DATA, a string, consists of JFIF image data.
 212 We accept the tag Exif because that is the same format."
 213   (setq data (ignore-errors (string-to-unibyte data)))
 214   (when (and data (string-match-p "\\`\xff\xd8" data))
 215     (catch 'jfif
 216       (let ((len (length data)) (i 2))
 217         (while (< i len)
 218           (when (/= (aref data i) #xff)
 219             (throw 'jfif nil))
 220           (setq i (1+ i))
 221           (when (>= (+ i 2) len)
 222             (throw 'jfif nil))
 223           (let ((nbytes (+ (lsh (aref data (+ i 1)) 8)
 224                            (aref data (+ i 2))))
 225                 (code (aref data i)))
 226             (when (and (>= code #xe0) (<= code #xef))
 227               ;; APP0 LEN1 LEN2 "JFIF\0"
 228               (throw 'jfif
 229                      (string-match-p "JFIF\\|Exif"
 230                                      (substring data i (min (+ i nbytes) len)))))
 231             (setq i (+ i 1 nbytes))))))))
 232
 233
 234 ;;;###autoload
 235 (defun image-type-from-data (data)
 236   "Determine the image type from image data DATA.
 237 Value is a symbol specifying the image type or nil if type cannot
 238 be determined."
 239   (let ((types image-type-header-regexps)
 240         type)
 241     (while types
 242       (let ((regexp (car (car types)))
 243             (image-type (cdr (car types))))
 244         (if (or (and (symbolp image-type)
 245                      (string-match-p regexp data))
 246                 (and (consp image-type)
 247                      (funcall (car image-type) data)
 248                      (setq image-type (cdr image-type))))
 249             (setq type image-type
 250                   types nil)
 251           (setq types (cdr types)))))
 252     type))
 253
 254
 255 ;;;###autoload
 256 (defun image-type-from-buffer ()
 257   "Determine the image type from data in the current buffer.
 258 Value is a symbol specifying the image type or nil if type cannot
 259 be determined."
 260   (let ((types image-type-header-regexps)
 261         type
 262         (opoint (point)))
 263     (goto-char (point-min))
 264     (while types
 265       (let ((regexp (car (car types)))
 266             (image-type (cdr (car types)))
 267             data)
 268         (if (or (and (symbolp image-type)
 269                      (looking-at-p regexp))
 270                 (and (consp image-type)
 271                      (funcall (car image-type)
 272                               (or data
 273                                   (setq data
 274                                         (buffer-substring
 275                                          (point-min)
 276                                          (min (point-max)
 277                                               (+ (point-min) 256))))))
 278                      (setq image-type (cdr image-type))))
 279             (setq type image-type
 280                   types nil)
 281           (setq types (cdr types)))))
 282     (goto-char opoint)
 283     type))
 284
 285
 286 ;;;###autoload
 287 (defun image-type-from-file-header (file)
 288   "Determine the type of image file FILE from its first few bytes.
 289 Value is a symbol specifying the image type, or nil if type cannot
 290 be determined."
 291   (unless (or (file-readable-p file)
 292               (file-name-absolute-p file))
 293     (setq file (image-search-load-path file)))
 294   (and file
 295        (file-readable-p file)
 296        (with-temp-buffer
 297          (set-buffer-multibyte nil)
 298          (insert-file-contents-literally file nil 0 256)
 299          (image-type-from-buffer))))
 300
 301
 302 ;;;###autoload
 303 (defun image-type-from-file-name (file)
 304   "Determine the type of image file FILE from its name.
 305 Value is a symbol specifying the image type, or nil if type cannot
 306 be determined."
 307   (assoc-default file image-type-file-name-regexps 'string-match-p))
 308
 309
 310 ;;;###autoload
 311 (defun image-type (source &optional type data-p)
 312   "Determine and return image type.
 313 SOURCE is an image file name or image data.
 314 Optional TYPE is a symbol describing the image type.  If TYPE is omitted
 315 or nil, try to determine the image type from its first few bytes
 316 of image data.  If that doesn't work, and SOURCE is a file name,
 317 use its file extension as image type.
 318 Optional DATA-P non-nil means SOURCE is a string containing image data."
 319   (when (and (not data-p) (not (stringp source)))
 320     (error "Invalid image file name `%s'" source))
 321   (unless type
 322     (setq type (if data-p
 323                    (image-type-from-data source)
 324                  (or (image-type-from-file-header source)
 325                      (image-type-from-file-name source))))
 326     (or type (error "Cannot determine image type")))
 327   (or (memq type (and (boundp 'image-types) image-types))
 328       (error "Invalid image type `%s'" type))
 329   type)
 330
 331
 332 (defvar image-library-alist)
 333
 334 ;;;###autoload
 335 (defun image-type-available-p (type)
 336   "Return non-nil if image type TYPE is available.
 337 Image types are symbols like `xbm' or `jpeg'."
 338   (and (fboundp 'init-image-library)
 339        (init-image-library type image-library-alist)))
 340
 341
 342 ;;;###autoload
 343 (defun image-type-auto-detected-p ()
 344   "Return t if the current buffer contains an auto-detectable image.
 345 This function is intended to be used from `magic-fallback-mode-alist'.
 346
 347 The buffer is considered to contain an auto-detectable image if
 348 its beginning matches an image type in `image-type-header-regexps',
 349 and that image type is present in `image-type-auto-detectable' with a
 350 non-nil value.  If that value is non-nil, but not t, then the image type
 351 must be available."
 352   (let* ((type (image-type-from-buffer))
 353          (auto (and type (cdr (assq type image-type-auto-detectable)))))
 354     (and auto
 355          (or (eq auto t) (image-type-available-p type)))))
 356
 357
 358 ;;;###autoload
 359 (defun create-image (file-or-data &optional type data-p &rest props)
 360   "Create an image.
 361 FILE-OR-DATA is an image file name or image data.
 362 Optional TYPE is a symbol describing the image type.  If TYPE is omitted
 363 or nil, try to determine the image type from its first few bytes
 364 of image data.  If that doesn't work, and FILE-OR-DATA is a file name,
 365 use its file extension as image type.
 366 Optional DATA-P non-nil means FILE-OR-DATA is a string containing image data.
 367 Optional PROPS are additional image attributes to assign to the image,
 368 like, e.g. `:mask MASK'.
 369 Value is the image created, or nil if images of type TYPE are not supported.
 370
 371 Images should not be larger than specified by `max-image-size'.
 372
 373 Image file names that are not absolute are searched for in the
 374 \"images\" sub-directory of `data-directory' and
 375 `x-bitmap-file-path' (in that order)."
 376   ;; It is x_find_image_file in image.c that sets the search path.
 377   (setq type (image-type file-or-data type data-p))
 378   (when (image-type-available-p type)
 379     (append (list 'image :type type (if data-p :data :file) file-or-data)
 380             props)))
 381
 382
 383 ;;;###autoload
 384 (defun put-image (image pos &optional string area)
 385   "Put image IMAGE in front of POS in the current buffer.
 386 IMAGE must be an image created with `create-image' or `defimage'.
 387 IMAGE is displayed by putting an overlay into the current buffer with a
 388 `before-string' STRING that has a `display' property whose value is the
 389 image.  STRING is defaulted if you omit it.
 390 POS may be an integer or marker.
 391 AREA is where to display the image.  AREA nil or omitted means
 392 display it in the text area, a value of `left-margin' means
 393 display it in the left marginal area, a value of `right-margin'
 394 means display it in the right marginal area."
 395   (unless string (setq string "x"))
 396   (let ((buffer (current-buffer)))
 397     (unless (eq (car-safe image) 'image)
 398       (error "Not an image: %s" image))
 399     (unless (or (null area) (memq area '(left-margin right-margin)))
 400       (error "Invalid area %s" area))
 401     (setq string (copy-sequence string))
 402     (let ((overlay (make-overlay pos pos buffer))
 403           (prop (if (null area) image (list (list 'margin area) image))))
 404       (put-text-property 0 (length string) 'display prop string)
 405       (overlay-put overlay 'put-image t)
 406       (overlay-put overlay 'before-string string))))
 407
 408
 409 ;;;###autoload
 410 (defun insert-image (image &optional string area slice)
 411   "Insert IMAGE into current buffer at point.
 412 IMAGE is displayed by inserting STRING into the current buffer
 413 with a `display' property whose value is the image.  STRING is
 414 defaulted if you omit it.
 415 AREA is where to display the image.  AREA nil or omitted means
 416 display it in the text area, a value of `left-margin' means
 417 display it in the left marginal area, a value of `right-margin'
 418 means display it in the right marginal area.
 419 SLICE specifies slice of IMAGE to insert.  SLICE nil or omitted
 420 means insert whole image.  SLICE is a list (X Y WIDTH HEIGHT)
 421 specifying the X and Y positions and WIDTH and HEIGHT of image area
 422 to insert.  A float value 0.0 - 1.0 means relative to the width or
 423 height of the image; integer values are taken as pixel values."
 424   ;; Use a space as least likely to cause trouble when it's a hidden
 425   ;; character in the buffer.
 426   (unless string (setq string " "))
 427   (unless (eq (car-safe image) 'image)
 428     (error "Not an image: %s" image))
 429   (unless (or (null area) (memq area '(left-margin right-margin)))
 430     (error "Invalid area %s" area))
 431   (if area
 432       (setq image (list (list 'margin area) image))
 433     ;; Cons up a new spec equal but not eq to `image' so that
 434     ;; inserting it twice in a row (adjacently) displays two copies of
 435     ;; the image.  Don't try to avoid this by looking at the display
 436     ;; properties on either side so that we DTRT more often with
 437     ;; cut-and-paste.  (Yanking killed image text next to another copy
 438     ;; of it loses anyway.)
 439     (setq image (cons 'image (cdr image))))
 440   (let ((start (point)))
 441     (insert string)
 442     (add-text-properties start (point)
 443                          `(display ,(if slice
 444                                         (list (cons 'slice slice) image)
 445                                       image) rear-nonsticky (display)))))
 446
 447
 448 ;;;###autoload
 449 (defun insert-sliced-image (image &optional string area rows cols)
 450   "Insert IMAGE into current buffer at point.
 451 IMAGE is displayed by inserting STRING into the current buffer
 452 with a `display' property whose value is the image.  STRING is
 453 defaulted if you omit it.
 454 AREA is where to display the image.  AREA nil or omitted means
 455 display it in the text area, a value of `left-margin' means
 456 display it in the left marginal area, a value of `right-margin'
 457 means display it in the right marginal area.
 458 The image is automatically split into ROWS x COLS slices."
 459   (unless string (setq string " "))
 460   (unless (eq (car-safe image) 'image)
 461     (error "Not an image: %s" image))
 462   (unless (or (null area) (memq area '(left-margin right-margin)))
 463     (error "Invalid area %s" area))
 464   (if area
 465       (setq image (list (list 'margin area) image))
 466     ;; Cons up a new spec equal but not eq to `image' so that
 467     ;; inserting it twice in a row (adjacently) displays two copies of
 468     ;; the image.  Don't try to avoid this by looking at the display
 469     ;; properties on either side so that we DTRT more often with
 470     ;; cut-and-paste.  (Yanking killed image text next to another copy
 471     ;; of it loses anyway.)
 472     (setq image (cons 'image (cdr image))))
 473   (let ((x 0.0) (dx (/ 1.0001 (or cols 1)))
 474          (y 0.0) (dy (/ 1.0001 (or rows 1))))
 475     (while (< y 1.0)
 476       (while (< x 1.0)
 477         (let ((start (point)))
 478           (insert string)
 479           (add-text-properties start (point)
 480                                `(display ,(list (list 'slice x y dx dy) image)
 481                                          rear-nonsticky (display)))
 482           (setq x (+ x dx))))
 483       (setq x 0.0
 484             y (+ y dy))
 485       (insert (propertize "\n" 'line-height t)))))
 486
 487
 488
 489 ;;;###autoload
 490 (defun remove-images (start end &optional buffer)
 491   "Remove images between START and END in BUFFER.
 492 Remove only images that were put in BUFFER with calls to `put-image'.
 493 BUFFER nil or omitted means use the current buffer."
 494   (unless buffer
 495     (setq buffer (current-buffer)))
 496   (let ((overlays (overlays-in start end)))
 497     (while overlays
 498       (let ((overlay (car overlays)))
 499         (when (overlay-get overlay 'put-image)
 500           (delete-overlay overlay)))
 501       (setq overlays (cdr overlays)))))
 502
 503 (defun image-search-load-path (file &optional path)
 504   (unless path
 505     (setq path image-load-path))
 506   (let (element found filename)
 507     (while (and (not found) (consp path))
 508       (setq element (car path))
 509       (cond
 510        ((stringp element)
 511         (setq found
 512               (file-readable-p
 513                (setq filename (expand-file-name file element)))))
 514        ((and (symbolp element) (boundp element))
 515         (setq element (symbol-value element))
 516         (cond
 517          ((stringp element)
 518           (setq found
 519                 (file-readable-p
 520                  (setq filename (expand-file-name file element)))))
 521          ((consp element)
 522           (if (setq filename (image-search-load-path file element))
 523               (setq found t))))))
 524       (setq path (cdr path)))
 525     (if found filename)))
 526
 527 ;;;###autoload
 528 (defun find-image (specs)
 529   "Find an image, choosing one of a list of image specifications.
 530
 531 SPECS is a list of image specifications.
 532
 533 Each image specification in SPECS is a property list.  The contents of
 534 a specification are image type dependent.  All specifications must at
 535 least contain the properties `:type TYPE' and either `:file FILE' or
 536 `:data DATA', where TYPE is a symbol specifying the image type,
 537 e.g. `xbm', FILE is the file to load the image from, and DATA is a
 538 string containing the actual image data.  The specification whose TYPE
 539 is supported, and FILE exists, is used to construct the image
 540 specification to be returned.  Return nil if no specification is
 541 satisfied.
 542
 543 The image is looked for in `image-load-path'.
 544
 545 Image files should not be larger than specified by `max-image-size'."
 546   (let (image)
 547     (while (and specs (null image))
 548       (let* ((spec (car specs))
 549              (type (plist-get spec :type))
 550              (data (plist-get spec :data))
 551              (file (plist-get spec :file))
 552              found)
 553         (when (image-type-available-p type)
 554           (cond ((stringp file)
 555                  (if (setq found (image-search-load-path file))
 556                      (setq image
 557                            (cons 'image (plist-put (copy-sequence spec)
 558                                                    :file found)))))
 559                 ((not (null data))
 560                  (setq image (cons 'image spec)))))
 561         (setq specs (cdr specs))))
 562     image))
 563
 564
 565 ;;;###autoload
 566 (defmacro defimage (symbol specs &optional doc)
 567   "Define SYMBOL as an image.
 568
 569 SPECS is a list of image specifications.  DOC is an optional
 570 documentation string.
 571
 572 Each image specification in SPECS is a property list.  The contents of
 573 a specification are image type dependent.  All specifications must at
 574 least contain the properties `:type TYPE' and either `:file FILE' or
 575 `:data DATA', where TYPE is a symbol specifying the image type,
 576 e.g. `xbm', FILE is the file to load the image from, and DATA is a
 577 string containing the actual image data.  The first image
 578 specification whose TYPE is supported, and FILE exists, is used to
 579 define SYMBOL.
 580
 581 Example:
 582
 583    (defimage test-image ((:type xpm :file \"~/test1.xpm\")
 584                          (:type xbm :file \"~/test1.xbm\")))"
 585   (declare (doc-string 3))
 586   `(defvar ,symbol (find-image ',specs) ,doc))
 587
 588
 589 (provide 'image)
 590
 591 ;; arch-tag: 8e76a07b-eb48-4f3e-a7a0-1a7ba9f096b3
 592 ;;; image.el ends here