lisp/hexl.el

   1 ;;; hexl.el --- edit a file in a hex dump format using the hexl filter -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 1989, 1994, 1998, 2001-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Keith Gabryelski <ag@wheaties.ai.mit.edu>
   6 ;; Maintainer: FSF
   7 ;; Keywords: data
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This package implements a major mode for editing binary files.  It uses
  27 ;; a program called hexl, supplied with the GNU Emacs distribution, that
  28 ;; can filter a binary into an editable format or from the format back into
  29 ;; binary.  For full instructions, invoke `hexl-mode' on an empty buffer and
  30 ;; do M-x `describe-mode'.
  31 ;;
  32 ;; NOTE: Remember to change `hexl-program' or `hexl-options' if needed.
  33 ;;
  34 ;; Currently hexl only supports big endian hex output with 16 bit
  35 ;; grouping.
  36 ;;
  37 ;; -iso in `hexl-options' will allow iso characters to display in the
  38 ;; ASCII region of the screen (if your Emacs supports this) instead of
  39 ;; changing them to dots.
  40
  41 ;;; Code:
  42
  43 (require 'eldoc)
  44 (eval-when-compile (require 'cl))
  45
  46 ;;
  47 ;; vars here
  48 ;;
  49
  50 (defgroup hexl nil
  51   "Edit a file in a hex dump format using the hexl filter."
  52   :group 'data)
  53
  54
  55 (defcustom hexl-program "hexl"
  56   "The program that will hexlify and dehexlify its stdin.
  57 `hexl-program' will always be concatenated with `hexl-options'
  58 and \"-de\" when dehexlifying a buffer."
  59   :type 'string
  60   :group 'hexl)
  61
  62 (defcustom hexl-iso ""
  63   "If your Emacs can handle ISO characters, this should be set to
  64 \"-iso\" otherwise it should be \"\"."
  65   :type 'string
  66   :group 'hexl)
  67
  68 (defcustom hexl-options (format "-hex %s" hexl-iso)
  69   "Space separated options to `hexl-program' that suit your needs.
  70 Quoting cannot be used, so the arguments cannot themselves contain spaces."
  71   :type 'string
  72   :group 'hexl)
  73
  74 (defcustom hexl-follow-ascii t
  75   "If non-nil then highlight the ASCII character corresponding to point."
  76   :type 'boolean
  77   :group 'hexl
  78   :version "20.3")
  79
  80 (defcustom hexl-mode-hook '(hexl-follow-line hexl-activate-ruler)
  81   "Normal hook run when entering Hexl mode."
  82   :type 'hook
  83   :options '(hexl-follow-line hexl-activate-ruler turn-on-eldoc-mode)
  84   :group 'hexl)
  85
  86 (defface hexl-address-region
  87   '((t (:inherit header-line)))
  88   "Face used in address area of hexl-mode buffer."
  89   :group 'hexl)
  90
  91 (defface hexl-ascii-region
  92   '((t (:inherit header-line)))
  93   "Face used in ascii area of hexl-mode buffer."
  94   :group 'hexl)
  95
  96 (defvar hexl-max-address 0
  97   "Maximum offset into hexl buffer.")
  98
  99 (defvar hexl-mode-map
 100   (let ((map (make-keymap)))
 101     ;; Make all self-inserting keys go through hexl-self-insert-command,
 102     ;; because we need to convert them to unibyte characters before
 103     ;; inserting them into the buffer.
 104     (define-key map [remap self-insert-command] 'hexl-self-insert-command)
 105
 106     (define-key map "\C-m" 'hexl-self-insert-command)
 107     (define-key map [left] 'hexl-backward-char)
 108     (define-key map [right] 'hexl-forward-char)
 109     (define-key map [up] 'hexl-previous-line)
 110     (define-key map [down] 'hexl-next-line)
 111     (define-key map [M-left] 'hexl-backward-short)
 112     (define-key map [?\e left] 'hexl-backward-short)
 113     (define-key map [M-right] 'hexl-forward-short)
 114     (define-key map [?\e right] 'hexl-forward-short)
 115     (define-key map [next] 'hexl-scroll-up)
 116     (define-key map [prior] 'hexl-scroll-down)
 117     (define-key map [home] 'hexl-beginning-of-line)
 118     (define-key map [end] 'hexl-end-of-line)
 119     (define-key map [C-home] 'hexl-beginning-of-buffer)
 120     (define-key map [C-end] 'hexl-end-of-buffer)
 121     (define-key map [deletechar] 'undefined)
 122     (define-key map [deleteline] 'undefined)
 123     (define-key map [insertline] 'undefined)
 124     (define-key map [S-delete] 'undefined)
 125     (define-key map "\177" 'undefined)
 126
 127     (define-key map "\C-a" 'hexl-beginning-of-line)
 128     (define-key map "\C-b" 'hexl-backward-char)
 129     (define-key map "\C-d" 'undefined)
 130     (define-key map "\C-e" 'hexl-end-of-line)
 131     (define-key map "\C-f" 'hexl-forward-char)
 132
 133     (if (not (memq (key-binding (char-to-string help-char))
 134                    '(help-command ehelp-command)))
 135         (define-key map (char-to-string help-char) 'undefined))
 136
 137     (define-key map "\C-k" 'undefined)
 138     (define-key map "\C-n" 'hexl-next-line)
 139     (define-key map "\C-o" 'undefined)
 140     (define-key map "\C-p" 'hexl-previous-line)
 141     (define-key map "\C-q" 'hexl-quoted-insert)
 142     (define-key map "\C-t" 'undefined)
 143     (define-key map "\C-v" 'hexl-scroll-up)
 144     (define-key map "\C-w" 'undefined)
 145     (define-key map "\C-y" 'undefined)
 146
 147     (fset 'hexl-ESC-prefix (copy-keymap 'ESC-prefix))
 148     (define-key map "\e" 'hexl-ESC-prefix)
 149     (define-key map "\e\C-a" 'hexl-beginning-of-512b-page)
 150     (define-key map "\e\C-b" 'hexl-backward-short)
 151     (define-key map "\e\C-d" 'hexl-insert-decimal-char)
 152     (define-key map "\e\C-e" 'hexl-end-of-512b-page)
 153     (define-key map "\e\C-f" 'hexl-forward-short)
 154     (define-key map "\e\C-i" 'undefined)
 155     (define-key map "\e\C-j" 'undefined)
 156     (define-key map "\e\C-k" 'undefined)
 157     (define-key map "\e\C-o" 'hexl-insert-octal-char)
 158     (define-key map "\e\C-q" 'undefined)
 159     (define-key map "\e\C-t" 'undefined)
 160     (define-key map "\e\C-x" 'hexl-insert-hex-char)
 161     (define-key map "\eb" 'hexl-backward-word)
 162     (define-key map "\ec" 'undefined)
 163     (define-key map "\ed" 'undefined)
 164     (define-key map "\ef" 'hexl-forward-word)
 165     (define-key map "\eg" 'hexl-goto-hex-address)
 166     (define-key map "\ei" 'undefined)
 167     (define-key map "\ej" 'hexl-goto-address)
 168     (define-key map "\ek" 'undefined)
 169     (define-key map "\el" 'undefined)
 170     (define-key map "\eq" 'undefined)
 171     (define-key map "\es" 'undefined)
 172     (define-key map "\et" 'undefined)
 173     (define-key map "\eu" 'undefined)
 174     (define-key map "\ev" 'hexl-scroll-down)
 175     (define-key map "\ey" 'undefined)
 176     (define-key map "\ez" 'undefined)
 177     (define-key map "\e<" 'hexl-beginning-of-buffer)
 178     (define-key map "\e>" 'hexl-end-of-buffer)
 179
 180     (fset 'hexl-C-c-prefix (copy-keymap mode-specific-map))
 181     (define-key map "\C-c" 'hexl-C-c-prefix)
 182     (define-key map "\C-c\C-c" 'hexl-mode-exit)
 183
 184     (fset 'hexl-C-x-prefix (copy-keymap 'Control-X-prefix))
 185     (define-key map "\C-x" 'hexl-C-x-prefix)
 186     (define-key map "\C-x[" 'hexl-beginning-of-1k-page)
 187     (define-key map "\C-x]" 'hexl-end-of-1k-page)
 188     (define-key map "\C-x\C-p" 'undefined)
 189     (define-key map "\C-x\C-s" 'hexl-save-buffer)
 190     (define-key map "\C-x\C-t" 'undefined)
 191     map))
 192
 193 ;; Variable declarations for suppressing warnings from the byte-compiler.
 194 (defvar ruler-mode)
 195 (defvar ruler-mode-ruler-function)
 196 (defvar hl-line-mode)
 197 (defvar hl-line-range-function)
 198 (defvar hl-line-face)
 199
 200 ;; Variables where the original values are stored to.
 201 (defvar hexl-mode--old-var-vals ())
 202 (make-variable-buffer-local 'hexl-mode--old-var-vals)
 203
 204 (defvar hexl-ascii-overlay nil
 205   "Overlay used to highlight ASCII element corresponding to current point.")
 206 (make-variable-buffer-local 'hexl-ascii-overlay)
 207
 208 (defvar hexl-font-lock-keywords
 209   '(("^\\([0-9a-f]+:\\).\\{40\\}  \\(.+$\\)"
 210      ;; "^\\([0-9a-f]+:\\).+  \\(.+$\\)"
 211      (1 'hexl-address-region t t)
 212      (2 'hexl-ascii-region t t)))
 213   "Font lock keywords used in `hexl-mode'.")
 214
 215 ;; routines
 216
 217 (put 'hexl-mode 'mode-class 'special)
 218
 219
 220 (defun hexl-mode--minor-mode-p (var)
 221   (memq var '(ruler-mode hl-line-mode)))
 222
 223 (defun hexl-mode--setq-local (var val)
 224   ;; `var' can be either a symbol or a pair, in which case the `car'
 225   ;; is the getter function and the `cdr' is the corresponding setter.
 226   (unless (or (member var hexl-mode--old-var-vals)
 227               (assoc var hexl-mode--old-var-vals))
 228     (push (if (or (consp var) (boundp var))
 229               (cons var
 230                     (if (consp var) (funcall (car var)) (symbol-value var)))
 231             var)
 232           hexl-mode--old-var-vals))
 233   (cond
 234    ((consp var) (funcall (cdr var) val))
 235    ((hexl-mode--minor-mode-p var) (funcall var (if val 1 -1)))
 236    (t (set (make-local-variable var) val))))
 237
 238 ;;;###autoload
 239 (defun hexl-mode (&optional arg)
 240   "\\<hexl-mode-map>A mode for editing binary files in hex dump format.
 241 This is not an ordinary major mode; it alters some aspects
 242 of the current mode's behavior, but not all; also, you can exit
 243 Hexl mode and return to the previous mode using `hexl-mode-exit'.
 244
 245 This function automatically converts a buffer into the hexl format
 246 using the function `hexlify-buffer'.
 247
 248 Each line in the buffer has an \"address\" (displayed in hexadecimal)
 249 representing the offset into the file that the characters on this line
 250 are at and 16 characters from the file (displayed as hexadecimal
 251 values grouped every 16 bits) and as their ASCII values.
 252
 253 If any of the characters (displayed as ASCII characters) are
 254 unprintable (control or meta characters) they will be replaced as
 255 periods.
 256
 257 If `hexl-mode' is invoked with an argument the buffer is assumed to be
 258 in hexl format.
 259
 260 A sample format:
 261
 262   HEX ADDR: 0001 0203 0405 0607 0809 0a0b 0c0d 0e0f     ASCII-TEXT
 263   --------  ---- ---- ---- ---- ---- ---- ---- ----  ----------------
 264   00000000: 5468 6973 2069 7320 6865 786c 2d6d 6f64  This is hexl-mod
 265   00000010: 652e 2020 4561 6368 206c 696e 6520 7265  e.  Each line re
 266   00000020: 7072 6573 656e 7473 2031 3620 6279 7465  presents 16 byte
 267   00000030: 7320 6173 2068 6578 6164 6563 696d 616c  s as hexadecimal
 268   00000040: 2041 5343 4949 0a61 6e64 2070 7269 6e74   ASCII.and print
 269   00000050: 6162 6c65 2041 5343 4949 2063 6861 7261  able ASCII chara
 270   00000060: 6374 6572 732e 2020 416e 7920 636f 6e74  cters.  Any cont
 271   00000070: 726f 6c20 6f72 206e 6f6e 2d41 5343 4949  rol or non-ASCII
 272   00000080: 2063 6861 7261 6374 6572 730a 6172 6520   characters.are
 273   00000090: 6469 7370 6c61 7965 6420 6173 2070 6572  displayed as per
 274   000000a0: 696f 6473 2069 6e20 7468 6520 7072 696e  iods in the prin
 275   000000b0: 7461 626c 6520 6368 6172 6163 7465 7220  table character
 276   000000c0: 7265 6769 6f6e 2e0a                      region..
 277
 278 Movement is as simple as movement in a normal Emacs text buffer.  Most
 279 cursor movement bindings are the same (ie. Use \\[hexl-backward-char], \\[hexl-forward-char], \\[hexl-next-line], and \\[hexl-previous-line]
 280 to move the cursor left, right, down, and up).
 281
 282 Advanced cursor movement commands (ala \\[hexl-beginning-of-line], \\[hexl-end-of-line], \\[hexl-beginning-of-buffer], and \\[hexl-end-of-buffer]) are
 283 also supported.
 284
 285 There are several ways to change text in hexl mode:
 286
 287 ASCII characters (character between space (0x20) and tilde (0x7E)) are
 288 bound to self-insert so you can simply type the character and it will
 289 insert itself (actually overstrike) into the buffer.
 290
 291 \\[hexl-quoted-insert] followed by another keystroke allows you to insert the key even if
 292 it isn't bound to self-insert.  An octal number can be supplied in place
 293 of another key to insert the octal number's ASCII representation.
 294
 295 \\[hexl-insert-hex-char] will insert a given hexadecimal value (if it is between 0 and 0xFF)
 296 into the buffer at the current point.
 297
 298 \\[hexl-insert-octal-char] will insert a given octal value (if it is between 0 and 0377)
 299 into the buffer at the current point.
 300
 301 \\[hexl-insert-decimal-char] will insert a given decimal value (if it is between 0 and 255)
 302 into the buffer at the current point.
 303
 304 \\[hexl-mode-exit] will exit hexl-mode.
 305
 306 Note: saving the file with any of the usual Emacs commands
 307 will actually convert it back to binary format while saving.
 308
 309 You can use \\[hexl-find-file] to visit a file in Hexl mode.
 310
 311 \\[describe-bindings] for advanced commands."
 312   (interactive "p")
 313   (unless (eq major-mode 'hexl-mode)
 314     (let ((modified (buffer-modified-p))
 315           (inhibit-read-only t)
 316           (original-point (- (point) (point-min))))
 317       (and (eobp) (not (bobp))
 318            (setq original-point (1- original-point)))
 319       ;; If `hexl-mode' is invoked with an argument the buffer is assumed to
 320       ;; be in hexl format.
 321       (when (memq arg '(1 nil))
 322         ;; If the buffer's EOL type is -dos, we need to account for
 323         ;; extra CR characters added when hexlify-buffer writes the
 324         ;; buffer to a file.
 325         ;; FIXME: This doesn't take into account multibyte coding systems.
 326         (when (eq (coding-system-eol-type buffer-file-coding-system) 1)
 327           (setq original-point (+ (count-lines (point-min) (point))
 328                                   original-point))
 329           (or (bolp) (setq original-point (1- original-point))))
 330         (hexlify-buffer)
 331         (restore-buffer-modified-p modified))
 332       (set (make-local-variable 'hexl-max-address)
 333            (let* ((full-lines (/ (buffer-size) 68))
 334                   (last-line (% (buffer-size) 68))
 335                   (last-line-bytes (% last-line 52)))
 336              (+ last-line-bytes (* full-lines 16) -1)))
 337       (condition-case nil
 338           (hexl-goto-address original-point)
 339         (error nil)))
 340
 341     ;; We do not turn off the old major mode; instead we just
 342     ;; override most of it.  That way, we can restore it perfectly.
 343
 344     (hexl-mode--setq-local '(current-local-map . use-local-map) hexl-mode-map)
 345
 346     (hexl-mode--setq-local 'mode-name "Hexl")
 347     (hexl-mode--setq-local 'isearch-search-fun-function
 348                            'hexl-isearch-search-function)
 349     (hexl-mode--setq-local 'major-mode 'hexl-mode)
 350
 351     (hexl-mode--setq-local '(syntax-table . set-syntax-table)
 352                            (standard-syntax-table))
 353
 354     (add-hook 'write-contents-functions 'hexl-save-buffer nil t)
 355
 356     (hexl-mode--setq-local 'require-final-newline nil)
 357
 358
 359     (hexl-mode--setq-local 'font-lock-defaults '(hexl-font-lock-keywords t))
 360
 361     (hexl-mode--setq-local 'revert-buffer-function
 362                            #'hexl-revert-buffer-function)
 363     (add-hook 'change-major-mode-hook 'hexl-maybe-dehexlify-buffer nil t)
 364
 365     ;; Set a callback function for eldoc.
 366     (hexl-mode--setq-local 'eldoc-documentation-function
 367                            #'hexl-print-current-point-info)
 368     (eldoc-add-command-completions "hexl-")
 369     (eldoc-remove-command "hexl-save-buffer"
 370                           "hexl-current-address")
 371
 372     (if hexl-follow-ascii (hexl-follow-ascii 1)))
 373   (run-mode-hooks 'hexl-mode-hook))
 374
 375
 376 (defun hexl-isearch-search-function ()
 377   (if (and (not isearch-regexp) (not isearch-word))
 378       (lambda (string &optional bound noerror count)
 379         (funcall
 380          (if isearch-forward 're-search-forward 're-search-backward)
 381          (let ((textre
 382                 (if (> (length string) 80)
 383                     (regexp-quote string)
 384                   (mapconcat (lambda (c) (regexp-quote (string c))) string
 385                              "\\(?:\n\\(?:[:a-f0-9]+ \\)+ \\)?"))))
 386            (if (string-match "\\` ?\\([a-f0-9]+ \\)*[a-f0-9]+ ?\\'" string)
 387                (concat textre "\\|"
 388                        (mapconcat 'regexp-quote (split-string string " ")
 389                                   " \\(?: .+\n[a-f0-9]+: \\)?"))
 390              textre))
 391          bound noerror count))
 392     (let ((isearch-search-fun-function nil))
 393       (isearch-search-fun))))
 394
 395 (defvar hexl-in-save-buffer nil)
 396
 397 (defun hexl-save-buffer ()
 398   "Save a hexl format buffer as binary in visited file if modified."
 399   (interactive)
 400   (if hexl-in-save-buffer nil
 401     (restore-buffer-modified-p
 402      (if (buffer-modified-p)
 403          (let ((buf (generate-new-buffer " hexl"))
 404                (name (buffer-name))
 405                (start (point-min))
 406                (end (point-max))
 407                modified)
 408            (with-current-buffer buf
 409              (insert-buffer-substring name start end)
 410              (set-buffer name)
 411              (dehexlify-buffer)
 412              ;; Prevent infinite recursion.
 413              (let ((hexl-in-save-buffer t))
 414                (save-buffer))
 415              (setq modified (buffer-modified-p))
 416              (delete-region (point-min) (point-max))
 417              (insert-buffer-substring buf start end)
 418              (kill-buffer buf)
 419              modified))
 420        (message "(No changes need to be saved)")
 421        nil))
 422     ;; Return t to indicate we have saved t
 423     t))
 424
 425 ;;;###autoload
 426 (defun hexl-find-file (filename)
 427   "Edit file FILENAME as a binary file in hex dump format.
 428 Switch to a buffer visiting file FILENAME, creating one if none exists,
 429 and edit the file in `hexl-mode'."
 430   (interactive
 431    (list
 432     (let ((completion-ignored-extensions nil))
 433       (read-file-name "Filename: " nil nil 'ret-must-match))))
 434   ;; Ignore the user's setting of default major-mode.
 435   (letf (((default-value 'major-mode) 'fundamental-mode))
 436     (find-file-literally filename))
 437   (if (not (eq major-mode 'hexl-mode))
 438       (hexl-mode)))
 439
 440 (defun hexl-revert-buffer-function (_ignore-auto _noconfirm)
 441   (let ((coding-system-for-read 'no-conversion)
 442         revert-buffer-function)
 443     ;; Call the original `revert-buffer' without code conversion; also
 444     ;; prevent it from changing the major mode to normal-mode, which
 445     ;; calls `set-auto-mode'.
 446     (revert-buffer nil nil t)
 447     ;; A couple of hacks are necessary here:
 448     ;; 1. change the major-mode to one other than hexl-mode since the
 449     ;; function `hexl-mode' does nothing if the current major-mode is
 450     ;; already hexl-mode.
 451     ;; 2. reset change-major-mode-hook in case that `hexl-mode'
 452     ;; previously added hexl-maybe-dehexlify-buffer to it.
 453     (remove-hook 'change-major-mode-hook 'hexl-maybe-dehexlify-buffer t)
 454     (setq major-mode 'fundamental-mode)
 455     (hexl-mode)))
 456
 457 (defun hexl-mode-exit (&optional arg)
 458   "Exit Hexl mode, returning to previous mode.
 459 With arg, don't unhexlify buffer."
 460   (interactive "p")
 461   (if (or (eq arg 1) (not arg))
 462       (let ((modified (buffer-modified-p))
 463             (inhibit-read-only t)
 464             (original-point (1+ (hexl-current-address))))
 465         (dehexlify-buffer)
 466         (remove-hook 'write-contents-functions 'hexl-save-buffer t)
 467         (restore-buffer-modified-p modified)
 468         (goto-char original-point)
 469         ;; Maybe adjust point for the removed CR characters.
 470         (when (eq (coding-system-eol-type buffer-file-coding-system) 1)
 471           (setq original-point (- original-point
 472                                   (count-lines (point-min) (point))))
 473           (or (bobp) (setq original-point (1+ original-point))))
 474         (goto-char original-point)))
 475
 476   (remove-hook 'change-major-mode-hook 'hexl-maybe-dehexlify-buffer t)
 477   (remove-hook 'post-command-hook 'hexl-follow-ascii-find t)
 478   (setq hexl-ascii-overlay nil)
 479
 480   (let ((mms ()))
 481     (dolist (varval hexl-mode--old-var-vals)
 482       (let* ((bound (consp varval))
 483              (var (if bound (car varval) varval))
 484              (val (cdr-safe varval)))
 485         (cond
 486          ((consp var) (funcall (cdr var) val))
 487          ((hexl-mode--minor-mode-p var) (push (cons var val) mms))
 488          (bound (set (make-local-variable var) val))
 489          (t (kill-local-variable var)))))
 490     (kill-local-variable 'hexl-mode--old-var-vals)
 491     ;; Enable/disable minor modes.  Do it after having reset the other vars,
 492     ;; since some of them may affect the minor modes.
 493     (dolist (mm mms)
 494       (funcall (car mm) (if (cdr mm) 1 -1))))
 495
 496   (force-mode-line-update))
 497
 498 (defun hexl-maybe-dehexlify-buffer ()
 499   "Convert a hexl format buffer to binary.
 500 Ask the user for confirmation."
 501   (if (y-or-n-p "Convert contents back to binary format? ")
 502       (let ((modified (buffer-modified-p))
 503             (inhibit-read-only t)
 504             (original-point (1+ (hexl-current-address))))
 505         (dehexlify-buffer)
 506         (remove-hook 'write-contents-functions 'hexl-save-buffer t)
 507         (restore-buffer-modified-p modified)
 508         (goto-char original-point))))
 509
 510 (defun hexl-current-address (&optional validate)
 511   "Return current hexl-address."
 512   (interactive)
 513   (let ((current-column (- (% (- (point) (point-min) -1) 68) 11))
 514         (hexl-address 0))
 515     (if (< current-column 0)
 516         (if validate
 517             (error "Point is not on a character in the file")
 518           (setq current-column 0)))
 519     (setq hexl-address
 520           (+ (* (/ (- (point) (point-min) -1) 68) 16)
 521              (if (>= current-column 41)
 522                  (- current-column 41)
 523                (/ (- current-column  (/ current-column 5)) 2))))
 524     (when (called-interactively-p 'interactive)
 525       (message "Current address is %d/0x%08x" hexl-address hexl-address))
 526     hexl-address))
 527
 528 (defun hexl-print-current-point-info ()
 529   "Return current hexl-address in string.
 530 This function is intended to be used as eldoc callback."
 531   (let ((addr (hexl-current-address)))
 532     (format "Current address is %d/0x%08x" addr addr)))
 533
 534 (defun hexl-address-to-marker (address)
 535   "Return buffer position for ADDRESS."
 536   (interactive "nAddress: ")
 537   (+ (* (/ address 16) 68) 10 (point-min) (/ (* (% address 16) 5) 2)))
 538
 539 (defun hexl-goto-address (address)
 540   "Go to hexl-mode (decimal) address ADDRESS.
 541 Signal error if ADDRESS is out of range."
 542   (interactive "nAddress: ")
 543   (if (or (< address 0) (> address hexl-max-address))
 544       (error "Out of hexl region"))
 545   (goto-char (hexl-address-to-marker address)))
 546
 547 (defun hexl-goto-hex-address (hex-address)
 548   "Go to hexl-mode address (hex string) HEX-ADDRESS.
 549 Signal error if HEX-ADDRESS is out of range."
 550   (interactive "sHex Address: ")
 551   (hexl-goto-address (hexl-hex-string-to-integer hex-address)))
 552
 553 (defun hexl-hex-string-to-integer (hex-string)
 554   "Return decimal integer for HEX-STRING."
 555   (interactive "sHex number: ")
 556   (let ((hex-num 0))
 557     (while (not (equal hex-string ""))
 558       (setq hex-num (+ (* hex-num 16)
 559                        (hexl-hex-char-to-integer (string-to-char hex-string))))
 560       (setq hex-string (substring hex-string 1)))
 561     hex-num))
 562
 563 (defun hexl-octal-string-to-integer (octal-string)
 564   "Return decimal integer for OCTAL-STRING."
 565   (interactive "sOctal number: ")
 566   (let ((oct-num 0))
 567     (while (not (equal octal-string ""))
 568       (setq oct-num (+ (* oct-num 8)
 569                        (hexl-oct-char-to-integer
 570                         (string-to-char octal-string))))
 571       (setq octal-string (substring octal-string 1)))
 572     oct-num))
 573
 574 ;; move point functions
 575
 576 (defun hexl-backward-char (arg)
 577   "Move to left ARG bytes (right if ARG negative) in hexl-mode."
 578   (interactive "p")
 579   (hexl-goto-address (- (hexl-current-address) arg)))
 580
 581 (defun hexl-forward-char (arg)
 582   "Move to right ARG bytes (left if ARG negative) in hexl-mode."
 583   (interactive "p")
 584   (hexl-goto-address (+ (hexl-current-address) arg)))
 585
 586 (defun hexl-backward-short (arg)
 587   "Move to left ARG shorts (right if ARG negative) in hexl-mode."
 588   (interactive "p")
 589   (hexl-goto-address (let ((address (hexl-current-address)))
 590                        (if (< arg 0)
 591                            (progn
 592                              (setq arg (- arg))
 593                              (while (> arg 0)
 594                                (setq address
 595                                      (if (> address hexl-max-address)
 596                                          (progn
 597                                            (message "End of buffer.")
 598                                            hexl-max-address)
 599                                        (if (equal address (logior address 3))
 600                                            (+ address 4)
 601                                          (logior address 3))))
 602                                (setq arg (1- arg)))
 603                              (setq address
 604                                    (if (> address hexl-max-address)
 605                                        (progn
 606                                          (message "End of buffer.")
 607                                          hexl-max-address)
 608                                      (logior address 3))))
 609                          (while (> arg 0)
 610                            (if (not (equal address (logand address -4)))
 611                                (setq address (logand address -4))
 612                              (if (not (equal address 0))
 613                                  (setq address (- address 4))
 614                                (message "Beginning of buffer.")))
 615                            (setq arg (1- arg))))
 616                        address)))
 617
 618 (defun hexl-forward-short (arg)
 619   "Move to right ARG shorts (left if ARG negative) in hexl-mode."
 620   (interactive "p")
 621   (hexl-backward-short (- arg)))
 622
 623 (defun hexl-backward-word (arg)
 624   "Move to left ARG words (right if ARG negative) in hexl-mode."
 625   (interactive "p")
 626   (hexl-goto-address (let ((address (hexl-current-address)))
 627                        (if (< arg 0)
 628                            (progn
 629                              (setq arg (- arg))
 630                              (while (> arg 0)
 631                                (setq address
 632                                      (if (> address hexl-max-address)
 633                                          (progn
 634                                            (message "End of buffer.")
 635                                            hexl-max-address)
 636                                        (if (equal address (logior address 7))
 637                                            (+ address 8)
 638                                          (logior address 7))))
 639                                (setq arg (1- arg)))
 640                              (setq address
 641                                    (if (> address hexl-max-address)
 642                                        (progn
 643                                          (message "End of buffer.")
 644                                          hexl-max-address)
 645                                      (logior address 7))))
 646                          (while (> arg 0)
 647                            (if (not (equal address (logand address -8)))
 648                                (setq address (logand address -8))
 649                              (if (not (equal address 0))
 650                                  (setq address (- address 8))
 651                                (message "Beginning of buffer.")))
 652                            (setq arg (1- arg))))
 653                        address)))
 654
 655 (defun hexl-forward-word (arg)
 656   "Move to right ARG words (left if ARG negative) in hexl-mode."
 657   (interactive "p")
 658   (hexl-backward-word (- arg)))
 659
 660 (defun hexl-previous-line (arg)
 661   "Move vertically up ARG lines [16 bytes] (down if ARG negative) in hexl-mode.
 662 If there is no byte at the target address move to the last byte in that line."
 663   (interactive "p")
 664   (hexl-next-line (- arg)))
 665
 666 (defun hexl-next-line (arg)
 667   "Move vertically down ARG lines [16 bytes] (up if ARG negative) in hexl-mode.
 668 If there is no byte at the target address move to the last byte in that line."
 669   (interactive "p")
 670   (hexl-goto-address (let ((address (+ (hexl-current-address) (* arg 16))))
 671                        (if (and (< arg 0) (< address 0))
 672                                 (progn (message "Out of hexl region.")
 673                                        (setq address
 674                                              (% (hexl-current-address) 16)))
 675                          (if (and (> address hexl-max-address)
 676                                   (< (% hexl-max-address 16) (% address 16)))
 677                              (setq address hexl-max-address)
 678                            (if (> address hexl-max-address)
 679                                (progn (message "Out of hexl region.")
 680                                       (setq
 681                                        address
 682                                        (+ (logand hexl-max-address -16)
 683                                           (% (hexl-current-address) 16)))))))
 684                        address)))
 685
 686 (defun hexl-beginning-of-buffer (arg)
 687   "Move to the beginning of the hexl buffer.
 688 Leaves `hexl-mark' at previous position.
 689 With prefix arg N, puts point N bytes of the way from the true beginning."
 690   (interactive "p")
 691   (push-mark (point))
 692   (hexl-goto-address (+ 0 (1- arg))))
 693
 694 (defun hexl-end-of-buffer (arg)
 695   "Go to `hexl-max-address' minus ARG."
 696   (interactive "p")
 697   (push-mark (point))
 698   (hexl-goto-address (- hexl-max-address (1- arg))))
 699
 700 (defun hexl-beginning-of-line ()
 701   "Goto beginning of line in hexl mode."
 702   (interactive)
 703   (goto-char (+ (* (/ (point) 68) 68) 11)))
 704
 705 (defun hexl-end-of-line ()
 706   "Goto end of line in hexl mode."
 707   (interactive)
 708   (hexl-goto-address (let ((address (logior (hexl-current-address) 15)))
 709                        (if (> address hexl-max-address)
 710                            (setq address hexl-max-address))
 711                        address)))
 712
 713 (defun hexl-scroll-down (arg)
 714   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG."
 715   (interactive "P")
 716   (setq arg (if (null arg)
 717                 (1- (window-height))
 718               (prefix-numeric-value arg)))
 719   (hexl-scroll-up (- arg)))
 720
 721 (defun hexl-scroll-up (arg)
 722   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG.
 723 If there's no byte at the target address, move to the first or last line."
 724   (interactive "P")
 725   (setq arg (if (null arg)
 726                 (1- (window-height))
 727               (prefix-numeric-value arg)))
 728   (let* ((movement (* arg 16))
 729          (address (hexl-current-address))
 730          (dest (+ address movement)))
 731     (cond
 732      ;; If possible, try to stay at the same offset from the beginning
 733      ;; of the 16-byte group, even if we move to the first or last
 734      ;; group.
 735      ((and (> dest hexl-max-address)
 736            (>= (% hexl-max-address 16) (% address 16)))
 737       (setq dest (+ (logand hexl-max-address -16) (% address 16))))
 738      ((> dest hexl-max-address)
 739       (setq dest hexl-max-address))
 740      ((< dest 0)
 741       (setq dest (% address 16))))
 742     (if (/= dest (+ address movement))
 743         (message "Out of hexl region."))
 744     (hexl-goto-address dest)
 745     (recenter 0)))
 746
 747 (defun hexl-beginning-of-1k-page ()
 748   "Go to beginning of 1KB boundary."
 749   (interactive)
 750   (hexl-goto-address (logand (hexl-current-address) -1024)))
 751
 752 (defun hexl-end-of-1k-page ()
 753   "Go to end of 1KB boundary."
 754   (interactive)
 755   (hexl-goto-address
 756    (max hexl-max-address (logior (hexl-current-address) 1023))))
 757
 758 (defun hexl-beginning-of-512b-page ()
 759   "Go to beginning of 512 byte boundary."
 760   (interactive)
 761   (hexl-goto-address (logand (hexl-current-address) -512)))
 762
 763 (defun hexl-end-of-512b-page ()
 764   "Go to end of 512 byte boundary."
 765   (interactive)
 766   (hexl-goto-address
 767    (max hexl-max-address (logior (hexl-current-address) 511))))
 768
 769 (defun hexl-quoted-insert (arg)
 770   "Read next input character and insert it.
 771 Useful for inserting control characters and non-ASCII characters given their
 772 numerical code.
 773 You may also type octal digits, to insert a character with that code."
 774   (interactive "p")
 775   (hexl-insert-multibyte-char (read-quoted-char) arg))
 776
 777 ;00000000: 0011 2233 4455 6677 8899 aabb ccdd eeff  0123456789ABCDEF
 778
 779 ;;;###autoload
 780 (defun hexlify-buffer ()
 781   "Convert a binary buffer to hexl format.
 782 This discards the buffer's undo information."
 783   (interactive)
 784   (and (consp buffer-undo-list)
 785        (or (y-or-n-p "Converting to hexl format discards undo info; ok? ")
 786            (error "Aborted"))
 787        (setq buffer-undo-list nil))
 788   ;; Don't decode text in the ASCII part of `hexl' program output.
 789   (let ((coding-system-for-read 'raw-text)
 790         (coding-system-for-write buffer-file-coding-system)
 791         (buffer-undo-list t))
 792     (apply 'call-process-region (point-min) (point-max)
 793            (expand-file-name hexl-program exec-directory)
 794            t t nil
 795            ;; Manually encode the args, otherwise they're encoded using
 796            ;; coding-system-for-write (i.e. buffer-file-coding-system) which
 797            ;; may not be what we want (e.g. utf-16 on a non-utf-16 system).
 798            (mapcar (lambda (s)
 799                      (if (not (multibyte-string-p s)) s
 800                        (encode-coding-string s locale-coding-system)))
 801                    (split-string hexl-options)))
 802     (if (> (point) (hexl-address-to-marker hexl-max-address))
 803         (hexl-goto-address hexl-max-address))))
 804
 805 (defun dehexlify-buffer ()
 806   "Convert a hexl format buffer to binary.
 807 This discards the buffer's undo information."
 808   (interactive)
 809   (and (consp buffer-undo-list)
 810        (or (y-or-n-p "Converting from hexl format discards undo info; ok? ")
 811            (error "Aborted"))
 812        (setq buffer-undo-list nil))
 813   (let ((coding-system-for-write 'raw-text)
 814         (coding-system-for-read buffer-file-coding-system)
 815         (buffer-undo-list t))
 816     (apply 'call-process-region (point-min) (point-max)
 817            (expand-file-name hexl-program exec-directory)
 818            t t nil "-de" (split-string hexl-options))))
 819
 820 (defun hexl-char-after-point ()
 821   "Return char for ASCII hex digits at point."
 822   (hexl-htoi (char-after (point))
 823              (char-after (1+ (point)))))
 824
 825 (defun hexl-htoi (lh rh)
 826   "Hex (char) LH (char) RH to integer."
 827     (+ (* (hexl-hex-char-to-integer lh) 16)
 828        (hexl-hex-char-to-integer rh)))
 829
 830 (defun hexl-hex-char-to-integer (character)
 831   "Take a char and return its value as if it was a hex digit."
 832   (if (and (>= character ?0) (<= character ?9))
 833       (- character ?0)
 834     (let ((ch (logior character 32)))
 835       (if (and (>= ch ?a) (<= ch ?f))
 836           (- ch (- ?a 10))
 837         (error "Invalid hex digit `%c'" ch)))))
 838
 839 (defun hexl-oct-char-to-integer (character)
 840   "Take a char and return its value as if it was a octal digit."
 841   (if (and (>= character ?0) (<= character ?7))
 842       (- character ?0)
 843     (error "Invalid octal digit `%c'" character)))
 844
 845 (defun hexl-printable-character (ch)
 846   "Return a displayable string for character CH."
 847   (format "%c" (if (equal hexl-iso "")
 848                    (if (or (< ch 32) (>= ch 127))
 849                        46
 850                      ch)
 851                  (if (or (< ch 32) (and (>= ch 127) (< ch 160)))
 852                      46
 853                    ch))))
 854
 855 (defun hexl-insert-multibyte-char (ch num)
 856   "Insert a possibly multibyte character CH NUM times.
 857
 858 Non-ASCII characters are first encoded with `buffer-file-coding-system',
 859 and their encoded form is inserted byte by byte."
 860   (let ((charset (char-charset ch))
 861         (coding (if (or (null buffer-file-coding-system)
 862                         ;; coding-system-type equals t means undecided.
 863                         (eq (coding-system-type buffer-file-coding-system) t))
 864                     (default-value 'buffer-file-coding-system)
 865                   buffer-file-coding-system)))
 866     (cond ((and (> ch 0) (< ch 256))
 867            (hexl-insert-char ch num))
 868           ((eq charset 'unknown)
 869            (error
 870             "0x%x -- invalid character code; use \\[hexl-insert-hex-string]"
 871             ch))
 872           (t
 873            (let ((encoded (encode-coding-char ch coding))
 874                  (internal (string-as-unibyte (char-to-string ch)))
 875                  internal-hex)
 876              ;; If encode-coding-char returns nil, it means our character
 877              ;; cannot be safely encoded with buffer-file-coding-system.
 878              ;; In that case, we offer to insert the internal representation
 879              ;; of that character, byte by byte.
 880              (when (null encoded)
 881                (setq internal-hex
 882                      (mapconcat (function (lambda (c) (format "%x" c)))
 883                                 internal " "))
 884                (if (yes-or-no-p
 885                     (format
 886                      "Insert char 0x%x's internal representation \"%s\"? "
 887                      ch internal-hex))
 888                    (setq encoded internal)
 889                  (error
 890                   "Can't encode `0x%x' with this buffer's coding system; try \\[hexl-insert-hex-string]"
 891                   ch)))
 892              (while (> num 0)
 893                (mapc
 894                 (function (lambda (c) (hexl-insert-char c 1))) encoded)
 895                (setq num (1- num))))))))
 896
 897 (defun hexl-self-insert-command (arg)
 898   "Insert this character.
 899 Interactively, with a numeric argument, insert this character that many times.
 900
 901 Non-ASCII characters are first encoded with `buffer-file-coding-system',
 902 and their encoded form is inserted byte by byte."
 903   (interactive "p")
 904   (hexl-insert-multibyte-char last-command-event arg))
 905
 906 (defun hexl-insert-char (ch num)
 907   "Insert the character CH NUM times in a hexl buffer.
 908
 909 CH must be a unibyte character whose value is between 0 and 255."
 910   (if (or (< ch 0) (> ch 255))
 911       (error "Invalid character 0x%x -- must be in the range [0..255]" ch))
 912   (let ((address (hexl-current-address t)))
 913     (while (> num 0)
 914       (let ((hex-position
 915              (+ (* (/ address 16) 68)
 916                 10 (point-min)
 917                 (* 2 (% address 16))
 918                 (/ (% address 16) 2)))
 919             (ascii-position
 920              (+ (* (/ address 16) 68) 51 (point-min) (% address 16)))
 921             at-ascii-position)
 922         (if (= (point) ascii-position)
 923             (setq at-ascii-position t))
 924         (goto-char hex-position)
 925         (delete-char 2)
 926         (insert (format "%02x" ch))
 927         (goto-char ascii-position)
 928         (delete-char 1)
 929         (insert (hexl-printable-character ch))
 930         (or (eq address hexl-max-address)
 931             (setq address (1+ address)))
 932         (hexl-goto-address address)
 933         (if at-ascii-position
 934             (progn
 935               (beginning-of-line)
 936               (forward-char 51)
 937               (forward-char (% address 16)))))
 938       (setq num (1- num)))))
 939
 940 ;; hex conversion
 941
 942 (defun hexl-insert-hex-char (arg)
 943   "Insert a character given by its hexadecimal code ARG times at point."
 944   (interactive "p")
 945   (let ((num (hexl-hex-string-to-integer (read-string "Hex number: "))))
 946     (if (< num 0)
 947         (error "Hex number out of range")
 948       (hexl-insert-multibyte-char num arg))))
 949
 950 (defun hexl-insert-hex-string (str arg)
 951   "Insert hexadecimal string STR at point ARG times.
 952 Embedded whitespace, dashes, and periods in the string are ignored."
 953   (interactive "sHex string: \np")
 954   (setq str (replace-regexp-in-string "[- \t.]" "" str))
 955   (let ((chars '()))
 956     (let ((len (length str))
 957           (idx 0))
 958       (if (eq (logand len 1) 1)
 959           (let ((num (hexl-hex-string-to-integer (substring str 0 1))))
 960             (setq chars (cons num chars))
 961             (setq idx 1)))
 962       (while (< idx len)
 963         (let* ((nidx (+ idx 2))
 964                (num (hexl-hex-string-to-integer (substring str idx nidx))))
 965           (setq chars (cons num chars))
 966           (setq idx nidx))))
 967     (setq chars (nreverse chars))
 968     (while (> arg 0)
 969       (let ((chars chars))
 970         (while chars
 971           (hexl-insert-char (car chars) 1)
 972           (setq chars (cdr chars))))
 973       (setq arg (- arg 1)))))
 974
 975 (defun hexl-insert-decimal-char (arg)
 976   "Insert a character given by its decimal code ARG times at point."
 977   (interactive "p")
 978   (let ((num (string-to-number (read-string "Decimal Number: "))))
 979     (if (< num 0)
 980         (error "Decimal number out of range")
 981       (hexl-insert-multibyte-char num arg))))
 982
 983 (defun hexl-insert-octal-char (arg)
 984   "Insert a character given by its octal code ARG times at point."
 985   (interactive "p")
 986   (let ((num (hexl-octal-string-to-integer (read-string "Octal Number: "))))
 987     (if (< num 0)
 988         (error "Decimal number out of range")
 989       (hexl-insert-multibyte-char num arg))))
 990
 991 (defun hexl-follow-ascii (&optional arg)
 992   "Toggle following ASCII in Hexl buffers.
 993 With prefix ARG, turn on following if and only if ARG is positive.
 994 When following is enabled, the ASCII character corresponding to the
 995 element under the point is highlighted.
 996 Customize the variable `hexl-follow-ascii' to disable this feature."
 997   (interactive "P")
 998   (let ((on-p (if arg
 999                   (> (prefix-numeric-value arg) 0)
1000                (not hexl-ascii-overlay))))
1001
1002     (if on-p
1003       ;; turn it on
1004       (if (not hexl-ascii-overlay)
1005           (progn
1006             (setq hexl-ascii-overlay (make-overlay 1 1)
1007                   hexl-follow-ascii t)
1008             (overlay-put hexl-ascii-overlay 'face 'highlight)
1009             (add-hook 'post-command-hook 'hexl-follow-ascii-find nil t)))
1010       ;; turn it off
1011       (if hexl-ascii-overlay
1012           (progn
1013             (delete-overlay hexl-ascii-overlay)
1014             (setq hexl-ascii-overlay nil
1015                   hexl-follow-ascii nil)
1016             (remove-hook 'post-command-hook 'hexl-follow-ascii-find t)
1017             )))))
1018
1019 (defun hexl-activate-ruler ()
1020   "Activate `ruler-mode'."
1021   (require 'ruler-mode)
1022   (hexl-mode--setq-local 'ruler-mode-ruler-function
1023                          #'hexl-mode-ruler)
1024   (hexl-mode--setq-local 'ruler-mode t))
1025
1026 (defun hexl-follow-line ()
1027   "Activate `hl-line-mode'."
1028   (require 'hl-line)
1029   (hexl-mode--setq-local 'hl-line-range-function
1030                          #'hexl-highlight-line-range)
1031   (hexl-mode--setq-local 'hl-line-face 'highlight)
1032   (hexl-mode--setq-local 'hl-line-mode t))
1033
1034 (defun hexl-highlight-line-range ()
1035   "Return the range of address region for the point.
1036 This function is assumed to be used as callback function for `hl-line-mode'."
1037   (cons
1038    (line-beginning-position)
1039    ;; 9 stands for (length "87654321:")
1040    (+ (line-beginning-position) 9)))
1041
1042 (defun hexl-follow-ascii-find ()
1043   "Find and highlight the ASCII element corresponding to current point."
1044   (let ((pos (+ 51
1045                 (- (point) (current-column))
1046                 (mod (hexl-current-address) 16))))
1047     (move-overlay hexl-ascii-overlay pos (1+ pos))
1048     ))
1049
1050 (defun hexl-mode-ruler ()
1051   "Return a string ruler for hexl mode."
1052   (let* ((highlight (mod (hexl-current-address) 16))
1053          (s " 87654321  0011 2233 4455 6677 8899 aabb ccdd eeff  0123456789abcdef")
1054          (pos 0))
1055     (set-text-properties 0 (length s) nil s)
1056     ;; Turn spaces in the header into stretch specs so they work
1057     ;; regardless of the header-line face.
1058     (while (string-match "[ \t]+" s pos)
1059       (setq pos (match-end 0))
1060       (put-text-property (match-beginning 0) pos 'display
1061                          ;; Assume fixed-size chars
1062                          `(space :align-to ,(1- pos))
1063                          s))
1064     ;; Highlight the current column.
1065     (put-text-property (+ 11 (/ (* 5 highlight) 2))
1066                        (+ 13 (/ (* 5 highlight) 2))
1067                        'face 'highlight s)
1068     ;; Highlight the current ascii column
1069     (put-text-property (+ 13 39 highlight) (+ 13 40 highlight)
1070                        'face 'highlight s)
1071     s))
1072
1073 ;; startup stuff.
1074
1075 (easy-menu-define hexl-menu hexl-mode-map "Hexl Mode menu"
1076   `("Hexl"
1077     :help "Hexl-specific Features"
1078
1079     ["Backward short" hexl-backward-short
1080      :help "Move to left a short"]
1081     ["Forward short" hexl-forward-short
1082      :help "Move to right a short"]
1083     ["Backward word" hexl-backward-short
1084      :help "Move to left a word"]
1085     ["Forward word" hexl-forward-short
1086      :help "Move to right a word"]
1087     "-"
1088     ["Beginning of 512b page" hexl-beginning-of-512b-page
1089      :help "Go to beginning of 512 byte boundary"]
1090     ["End of 512b page" hexl-end-of-512b-page
1091      :help "Go to end of 512 byte boundary"]
1092     ["Beginning of 1K page" hexl-beginning-of-1k-page
1093      :help "Go to beginning of 1KB boundary"]
1094     ["End of 1K page" hexl-end-of-1k-page
1095      :help "Go to end of 1KB boundary"]
1096     "-"
1097     ["Go to address" hexl-goto-address
1098      :help "Go to hexl-mode (decimal) address"]
1099     ["Go to address" hexl-goto-hex-address
1100      :help "Go to hexl-mode (hex string) address"]
1101     "-"
1102     ["Insert decimal char" hexl-insert-decimal-char
1103      :help "Insert a character given by its decimal code"]
1104     ["Insert hex char" hexl-insert-hex-char
1105      :help "Insert a character given by its hexadecimal code"]
1106     ["Insert octal char" hexl-insert-octal-char
1107      :help "Insert a character given by its octal code"]
1108     "-"
1109     ["Exit hexl mode" hexl-mode-exit
1110      :help "Exit hexl mode returning to previous mode"]))
1111
1112 (provide 'hexl)
1113
1114 ;;; hexl.el ends here