lisp/dired-x.el

   1 ;;; dired-x.el --- extra Dired functionality
   2
   3 ;; Copyright (C) 1993-1994, 1997, 2001-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   6 ;;      Lawrence R. Dodd <dodd@roebling.poly.edu>
   7 ;; Maintainer: Romain Francoise <rfrancoise@gnu.org>
   8 ;; Keywords: dired extensions files
   9 ;; Package: emacs
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; This is based on Sebastian Kremer's excellent dired-x.el (Dired Extra),
  29 ;; version 1.191, adapted for GNU Emacs.  See the `dired-x' info pages.
  30
  31 ;; USAGE: In your ~/.emacs,
  32 ;;
  33 ;; (add-hook 'dired-load-hook
  34 ;;           (lambda ()
  35 ;;                       (load "dired-x")
  36 ;;                       ;; Set global variables here.  For example:
  37 ;;                       ;; (setq dired-guess-shell-gnutar "gtar")
  38 ;;                       ))
  39 ;; (add-hook 'dired-mode-hook
  40 ;;           (lambda ()
  41 ;;                       ;; Set buffer-local variables here.  For example:
  42 ;;                       ;; (dired-omit-mode 1)
  43 ;;                       ))
  44 ;;
  45 ;; At load time dired-x.el will install itself and bind some dired keys.
  46 ;; Some dired.el and dired-aux.el functions have extra features if
  47 ;; dired-x is loaded.
  48
  49 ;; User customization: M-x customize-group RET dired-x RET.
  50
  51 ;; *Please* see the `dired-x' info pages for more details.
  52
  53 \f
  54 ;;; Code:
  55
  56 ;; This is a no-op if dired-x is being loaded via `dired-load-hook',
  57 ;; but maybe not if a dired-x function is being autoloaded.
  58 (require 'dired)
  59
  60 ;;; User-defined variables.
  61
  62 (defgroup dired-x nil
  63   "Extended directory editing (dired-x)."
  64   :group 'dired)
  65
  66 (defgroup dired-keys nil
  67   "Dired keys customizations."
  68   :prefix "dired-"
  69   :group 'dired-x)
  70
  71 (defcustom dired-bind-vm nil
  72   "Non-nil means \"V\" runs `dired-vm', otherwise \"V\" runs `dired-rmail'.
  73 RMAIL files in the old Babyl format (used before before Emacs 23.1)
  74 contain \"-*- rmail -*-\" at the top, so `dired-find-file'
  75 will run `rmail' on these files.  New RMAIL files use the standard
  76 mbox format, and so cannot be distinguished in this way."
  77   :type 'boolean
  78   :group 'dired-keys)
  79
  80 (defcustom dired-bind-jump t
  81   "Non-nil means bind `dired-jump' to C-x C-j, otherwise do not.
  82 Setting this variable directly after dired-x is loaded has no effect -
  83 use \\[customize]."
  84   :type 'boolean
  85   :set (lambda (sym val)
  86          (if (set sym val)
  87              (progn
  88                (define-key global-map "\C-x\C-j" 'dired-jump)
  89                (define-key global-map "\C-x4\C-j" 'dired-jump-other-window))
  90            (if (eq 'dired-jump (lookup-key global-map "\C-x\C-j"))
  91                (define-key global-map "\C-x\C-j" nil))
  92            (if (eq 'dired-jump-other-window (lookup-key global-map "\C-x4\C-j"))
  93                (define-key global-map "\C-x4\C-j" nil))))
  94   :group 'dired-keys)
  95
  96 (defcustom dired-bind-man t
  97   "Non-nil means bind `dired-man' to \"N\" in dired-mode, otherwise do not.
  98 Setting this variable directly after dired-x is loaded has no effect -
  99 use \\[customize]."
 100   :type 'boolean
 101   :set (lambda (sym val)
 102          (if (set sym val)
 103              (define-key dired-mode-map "N" 'dired-man)
 104            (if (eq 'dired-man (lookup-key dired-mode-map "N"))
 105                (define-key dired-mode-map "N" nil))))
 106   :group 'dired-keys)
 107
 108 (defcustom dired-bind-info t
 109   "Non-nil means bind `dired-info' to \"I\" in dired-mode, otherwise do not.
 110 Setting this variable directly after dired-x is loaded has no effect -
 111 use \\[customize]."
 112   :type 'boolean
 113   :set (lambda (sym val)
 114          (if (set sym val)
 115              (define-key dired-mode-map "I" 'dired-info)
 116            (if (eq 'dired-info (lookup-key dired-mode-map "I"))
 117                (define-key dired-mode-map "I" nil))))
 118   :group 'dired-keys)
 119
 120 (defcustom dired-vm-read-only-folders nil
 121   "If non-nil, \\[dired-vm] will visit all folders read-only.
 122 If neither nil nor t, e.g. the symbol `if-file-read-only', only
 123 files not writable by you are visited read-only."
 124   :type '(choice (const :tag "off" nil)
 125                  (const :tag "on" t)
 126                  (other :tag "non-writable only" if-file-read-only))
 127   :group 'dired-x)
 128
 129 (define-minor-mode dired-omit-mode
 130   "Toggle Dired-Omit mode.
 131 With numeric ARG, enable Dired-Omit mode if ARG is positive, disable
 132 otherwise.  Enabling and disabling is buffer-local.
 133 If enabled, \"uninteresting\" files are not listed.
 134 Uninteresting files are those whose filenames match regexp `dired-omit-files',
 135 plus those ending with extensions in `dired-omit-extensions'.
 136
 137 To enable omitting in every Dired buffer, you can put in your ~/.emacs
 138
 139   (add-hook 'dired-mode-hook (lambda () (dired-omit-mode 1)))
 140
 141 See Info node `(dired-x) Omitting Variables' for more information."
 142   :group 'dired-x
 143   (if dired-omit-mode
 144       ;; This will mention how many lines were omitted:
 145       (let ((dired-omit-size-limit nil)) (dired-omit-expunge))
 146     (revert-buffer)))
 147
 148 (put 'dired-omit-mode 'safe-local-variable 'booleanp)
 149
 150 ;; For backward compatibility
 151 (define-obsolete-variable-alias 'dired-omit-files-p 'dired-omit-mode "22.1")
 152
 153 (defcustom dired-omit-files "^\\.?#\\|^\\.$\\|^\\.\\.$"
 154   "Filenames matching this regexp will not be displayed.
 155 This only has effect when `dired-omit-mode' is t.  See interactive function
 156 `dired-omit-mode' \(\\[dired-omit-mode]\) and variable
 157 `dired-omit-extensions'.  The default is to omit  `.', `..', auto-save
 158 files and lock files."
 159   :type 'regexp
 160   :group 'dired-x)
 161
 162 (defcustom dired-omit-verbose t
 163   "When non-nil, show messages when omitting files.
 164 When nil, don't show messages."
 165   :type 'boolean
 166   :group 'dired-x)
 167
 168 (defcustom dired-find-subdir nil           ; t is pretty near to DWIM...
 169   "If non-nil, Dired always finds a directory in a buffer of its own.
 170 If nil, Dired finds the directory as a subdirectory in some other buffer
 171 if it is present as one.
 172
 173 If there are several dired buffers for a directory, the most recently
 174 used is chosen.
 175
 176 Dired avoids switching to the current buffer, so that if you have
 177 a normal and a wildcard buffer for the same directory, \\[dired] will
 178 toggle between those two."
 179   :type 'boolean
 180   :group 'dired-x)
 181
 182 (defcustom dired-omit-size-limit 30000
 183   "Maximum size for the \"omitting\" feature.
 184 If nil, there is no maximum size."
 185   :type '(choice (const :tag "no maximum" nil) integer)
 186   :group 'dired-x)
 187
 188 (defcustom dired-enable-local-variables t
 189   "Control use of local-variables lists in Dired.
 190 This temporarily overrides the value of `enable-local-variables' when
 191 listing a directory.  See also `dired-local-variables-file'."
 192   :risky t
 193   :type '(choice (const :tag "Query Unsafe" t)
 194                  (const :tag "Safe Only" :safe)
 195                  (const :tag "Do all" :all)
 196                  (const :tag "Ignore" nil)
 197                  (other :tag "Query" other))
 198   :group 'dired-x)
 199
 200 (make-obsolete-variable 'dired-enable-local-variables
 201                         "use a standard `dir-locals-file' instead." "24.1")
 202
 203 (defcustom dired-guess-shell-gnutar
 204   (catch 'found
 205     (dolist (exe '("tar" "gtar"))
 206       (if (with-temp-buffer
 207             (ignore-errors (call-process exe nil t nil "--version"))
 208             (and (re-search-backward "GNU tar" nil t) t))
 209           (throw 'found exe))))
 210   "If non-nil, name of GNU tar executable.
 211 \(E.g., \"tar\" or \"gtar\").  The `z' switch will be used with it for
 212 compressed or gzip'ed tar files.  If you don't have GNU tar, set this
 213 to nil: a pipe using `zcat' or `gunzip -c' will be used."
 214   ;; Changed from system-type test to testing --version output.
 215   ;; Maybe test --help for -z instead?
 216   :version "24.1"
 217   :type '(choice (const :tag "Not GNU tar" nil)
 218                  (string :tag "Command name"))
 219   :group 'dired-x)
 220
 221 (defcustom dired-guess-shell-gzip-quiet t
 222   "Non-nil says pass -q to gzip overriding verbose GZIP environment."
 223   :type 'boolean
 224   :group 'dired-x)
 225
 226 (defcustom dired-guess-shell-znew-switches nil
 227   "If non-nil, then string of switches passed to `znew', example: \"-K\"."
 228   :type '(choice (const :tag "None" nil)
 229                  (string :tag "Switches"))
 230   :group 'dired-x)
 231
 232 (defcustom dired-clean-up-buffers-too t
 233   "Non-nil means offer to kill buffers visiting files and dirs deleted in Dired."
 234   :type 'boolean
 235   :group 'dired-x)
 236
 237 ;;; KEY BINDINGS.
 238
 239 (define-key dired-mode-map "\M-o" 'dired-omit-mode)
 240 (define-key dired-mode-map "*O" 'dired-mark-omitted)
 241 (define-key dired-mode-map "\M-(" 'dired-mark-sexp)
 242 (define-key dired-mode-map "*(" 'dired-mark-sexp)
 243 (define-key dired-mode-map "*." 'dired-mark-extension)
 244 (define-key dired-mode-map "\M-!" 'dired-smart-shell-command)
 245 (define-key dired-mode-map "\M-G" 'dired-goto-subdir)
 246 (define-key dired-mode-map "F" 'dired-do-find-marked-files)
 247 (define-key dired-mode-map "Y"  'dired-do-relsymlink)
 248 (define-key dired-mode-map "%Y" 'dired-do-relsymlink-regexp)
 249 (define-key dired-mode-map "V" 'dired-do-run-mail)
 250
 251 ;;; MENU BINDINGS
 252
 253 (require 'easymenu)
 254
 255 (let ((menu (lookup-key dired-mode-map [menu-bar])))
 256   (easy-menu-add-item menu '("Operate")
 257                       ["Find Files" dired-do-find-marked-files
 258                        :help "Find current or marked files"]
 259                       "Shell Command...")
 260   (easy-menu-add-item menu '("Operate")
 261                       ["Relative Symlink to..." dired-do-relsymlink
 262                        :visible (fboundp 'make-symbolic-link)
 263                        :help "Make relative symbolic links for current or \
 264 marked files"]
 265                       "Hardlink to...")
 266   (easy-menu-add-item menu '("Mark")
 267                       ["Flag Extension..." dired-flag-extension
 268                        :help "Flag files with a certain extension for deletion"]
 269                       "Mark Executables")
 270   (easy-menu-add-item menu '("Mark")
 271                       ["Mark Extension..." dired-mark-extension
 272                        :help "Mark files with a certain extension"]
 273                       "Unmark All")
 274   (easy-menu-add-item menu '("Mark")
 275                       ["Mark Omitted" dired-mark-omitted
 276                        :help "Mark files matching `dired-omit-files' \
 277 and `dired-omit-extensions'"]
 278                       "Unmark All")
 279   (easy-menu-add-item menu '("Regexp")
 280                       ["Relative Symlink..." dired-do-relsymlink-regexp
 281                        :visible (fboundp 'make-symbolic-link)
 282                        :help "Make relative symbolic links for files \
 283 matching regexp"]
 284                       "Hardlink...")
 285   (easy-menu-add-item menu '("Immediate")
 286                       ["Omit Mode" dired-omit-mode
 287                        :style toggle :selected dired-omit-mode
 288                        :help "Enable or disable omitting \"uninteresting\" \
 289 files"]
 290                       "Refresh"))
 291
 292 \f
 293 ;; Install into appropriate hooks.
 294
 295 (add-hook 'dired-mode-hook 'dired-extra-startup)
 296 (add-hook 'dired-after-readin-hook 'dired-omit-expunge)
 297
 298 (defun dired-extra-startup ()
 299   "Automatically put on `dired-mode-hook' to get extra Dired features:
 300 \\<dired-mode-map>
 301   \\[dired-do-run-mail]\t-- run mail on folder (see `dired-bind-vm')
 302   \\[dired-info]\t-- run info on file
 303   \\[dired-man]\t-- run man on file
 304   \\[dired-do-find-marked-files]\t-- visit all marked files simultaneously
 305   \\[dired-omit-mode]\t-- toggle omitting of files
 306   \\[dired-mark-sexp]\t-- mark by Lisp expression
 307
 308 To see the options you can set, use M-x customize-group RET dired-x RET.
 309 See also the functions:
 310   `dired-flag-extension'
 311   `dired-virtual'
 312   `dired-jump'
 313   `dired-man'
 314   `dired-vm'
 315   `dired-rmail'
 316   `dired-info'
 317   `dired-do-find-marked-files'"
 318   (interactive)
 319   ;; These must be done in each new dired buffer.
 320   (dired-hack-local-variables)
 321   (dired-omit-startup))
 322
 323 \f
 324 ;;; EXTENSION MARKING FUNCTIONS.
 325
 326 ;; Mark files with some extension.
 327 (defun dired-mark-extension (extension &optional marker-char)
 328   "Mark all files with a certain EXTENSION for use in later commands.
 329 A `.' is *not* automatically prepended to the string entered."
 330   ;; EXTENSION may also be a list of extensions instead of a single one.
 331   ;; Optional MARKER-CHAR is marker to use.
 332   (interactive "sMarking extension: \nP")
 333   (or (listp extension)
 334       (setq extension (list extension)))
 335   (dired-mark-files-regexp
 336    (concat ".";; don't match names with nothing but an extension
 337            "\\("
 338            (mapconcat 'regexp-quote extension "\\|")
 339            "\\)$")
 340    marker-char))
 341
 342 (defun dired-flag-extension (extension)
 343   "In dired, flag all files with a certain EXTENSION for deletion.
 344 A `.' is *not* automatically prepended to the string entered."
 345   (interactive "sFlagging extension: ")
 346   (dired-mark-extension extension dired-del-marker))
 347
 348 ;; Define some unpopular file extensions.  Used for cleaning and omitting.
 349
 350 (defvar dired-patch-unclean-extensions
 351   '(".rej" ".orig")
 352   "List of extensions of dispensable files created by the `patch' program.")
 353
 354 (defvar dired-tex-unclean-extensions
 355   '(".toc" ".log" ".aux");; these are already in completion-ignored-extensions
 356   "List of extensions of dispensable files created by TeX.")
 357
 358 (defvar dired-latex-unclean-extensions
 359   '(".idx" ".lof" ".lot" ".glo")
 360   "List of extensions of dispensable files created by LaTeX.")
 361
 362 (defvar dired-bibtex-unclean-extensions
 363   '(".blg" ".bbl")
 364   "List of extensions of dispensable files created by BibTeX.")
 365
 366 (defvar dired-texinfo-unclean-extensions
 367   '(".cp" ".cps" ".fn" ".fns" ".ky" ".kys" ".pg" ".pgs"
 368     ".tp" ".tps" ".vr" ".vrs")
 369   "List of extensions of dispensable files created by texinfo.")
 370
 371 (defun dired-clean-patch ()
 372   "Flag dispensable files created by patch for deletion.
 373 See variable `dired-patch-unclean-extensions'."
 374   (interactive)
 375   (dired-flag-extension dired-patch-unclean-extensions))
 376
 377 (defun dired-clean-tex ()
 378   "Flag dispensable files created by [La]TeX etc. for deletion.
 379 See variables `dired-tex-unclean-extensions',
 380 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 381 `dired-texinfo-unclean-extensions'."
 382   (interactive)
 383   (dired-flag-extension (append dired-texinfo-unclean-extensions
 384                                 dired-latex-unclean-extensions
 385                                 dired-bibtex-unclean-extensions
 386                                 dired-tex-unclean-extensions)))
 387
 388 (defun dired-very-clean-tex ()
 389   "Flag dispensable files created by [La]TeX *and* \".dvi\" for deletion.
 390 See variables `dired-texinfo-unclean-extensions',
 391 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 392 `dired-texinfo-unclean-extensions'."
 393   (interactive)
 394   (dired-flag-extension (append dired-texinfo-unclean-extensions
 395                                 dired-latex-unclean-extensions
 396                                 dired-bibtex-unclean-extensions
 397                                 dired-tex-unclean-extensions
 398                                 (list ".dvi"))))
 399 \f
 400 ;;; JUMP.
 401
 402 ;;;###autoload
 403 (defun dired-jump (&optional other-window file-name)
 404   "Jump to dired buffer corresponding to current buffer.
 405 If in a file, dired the current directory and move to file's line.
 406 If in Dired already, pop up a level and goto old directory's line.
 407 In case the proper dired file line cannot be found, refresh the dired
 408 buffer and try again.
 409 When OTHER-WINDOW is non-nil, jump to dired buffer in other window.
 410 Interactively with prefix argument, read FILE-NAME and
 411 move to its line in dired."
 412   (interactive
 413    (list nil (and current-prefix-arg
 414                   (read-file-name "Jump to dired file: "))))
 415   (let* ((file (or file-name buffer-file-name))
 416          (dir (if file (file-name-directory file) default-directory)))
 417     (if (and (eq major-mode 'dired-mode) (null file-name))
 418         (progn
 419           (setq dir (dired-current-directory))
 420           (dired-up-directory other-window)
 421           (unless (dired-goto-file dir)
 422               ;; refresh and try again
 423             (dired-insert-subdir (file-name-directory dir))
 424             (dired-goto-file dir)))
 425       (if other-window
 426           (dired-other-window dir)
 427         (dired dir))
 428       (if file
 429           (or (dired-goto-file file)
 430               ;; refresh and try again
 431               (progn
 432                 (dired-insert-subdir (file-name-directory file))
 433                 (dired-goto-file file))
 434               ;; Toggle omitting, if it is on, and try again.
 435               (when dired-omit-mode
 436                 (dired-omit-mode)
 437                 (dired-goto-file file)))))))
 438
 439 ;;;###autoload
 440 (defun dired-jump-other-window (&optional file-name)
 441   "Like \\[dired-jump] (`dired-jump') but in other window."
 442   (interactive
 443    (list (and current-prefix-arg
 444               (read-file-name "Jump to dired file: "))))
 445   (dired-jump t file-name))
 446 \f
 447 ;;; OMITTING.
 448
 449 ;; Enhanced omitting of lines from directory listings.
 450 ;; Marked files are never omitted.
 451
 452 ;; should probably get rid of this and always use 'no-dir.
 453 ;; sk 28-Aug-1991 09:37
 454 (defvar dired-omit-localp 'no-dir
 455   "The LOCALP argument `dired-omit-expunge' passes to `dired-get-filename'.
 456 If it is `no-dir', omitting is much faster, but you can only match
 457 against the non-directory part of the file name.  Set it to nil if you
 458 need to match the entire file name.")
 459
 460 ;; \017=^O for Omit - other packages can chose other control characters.
 461 (defvar dired-omit-marker-char ?\017
 462   "Temporary marker used by Dired-Omit.
 463 Should never be used as marker by the user or other packages.")
 464
 465 (defun dired-omit-startup ()
 466   (or (assq 'dired-omit-mode minor-mode-alist)
 467       (setq minor-mode-alist
 468             (append '((dired-omit-mode
 469                        (:eval (if (eq major-mode 'dired-mode)
 470                                   " Omit" ""))))
 471                     minor-mode-alist))))
 472
 473 (defun dired-mark-omitted ()
 474   "Mark files matching `dired-omit-files' and `dired-omit-extensions'."
 475   (interactive)
 476   (let ((dired-omit-mode nil)) (revert-buffer)) ;; Show omitted files
 477   (dired-mark-unmarked-files (dired-omit-regexp) nil nil dired-omit-localp))
 478
 479 (defcustom dired-omit-extensions
 480   (append completion-ignored-extensions
 481           dired-latex-unclean-extensions
 482           dired-bibtex-unclean-extensions
 483           dired-texinfo-unclean-extensions)
 484   "If non-nil, a list of extensions \(strings\) to omit from Dired listings.
 485 Defaults to elements of `completion-ignored-extensions',
 486 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions', and
 487 `dired-texinfo-unclean-extensions'.
 488
 489 See interactive function `dired-omit-mode' \(\\[dired-omit-mode]\) and
 490 variables `dired-omit-mode' and `dired-omit-files'."
 491   :type '(repeat string)
 492   :group 'dired-x)
 493
 494 (defun dired-omit-expunge (&optional regexp)
 495   "Erases all unmarked files matching REGEXP.
 496 Does nothing if global variable `dired-omit-mode' is nil, or if called
 497   non-interactively and buffer is bigger than `dired-omit-size-limit'.
 498 If REGEXP is nil or not specified, uses `dired-omit-files', and also omits
 499   filenames ending in `dired-omit-extensions'.
 500 If REGEXP is the empty string, this function is a no-op.
 501
 502 This functions works by temporarily binding `dired-marker-char' to
 503 `dired-omit-marker-char' and calling `dired-do-kill-lines'."
 504   (interactive "sOmit files (regexp): ")
 505   (if (and dired-omit-mode
 506            (or (called-interactively-p 'interactive)
 507                (not dired-omit-size-limit)
 508                (< (buffer-size) dired-omit-size-limit)
 509                (progn
 510                  (when dired-omit-verbose
 511                    (message "Not omitting: directory larger than %d characters."
 512                             dired-omit-size-limit))
 513                  (setq dired-omit-mode nil)
 514                  nil)))
 515       (let ((omit-re (or regexp (dired-omit-regexp)))
 516             (old-modified-p (buffer-modified-p))
 517             count)
 518         (or (string= omit-re "")
 519             (let ((dired-marker-char dired-omit-marker-char))
 520               (when dired-omit-verbose (message "Omitting..."))
 521               (if (dired-mark-unmarked-files omit-re nil nil dired-omit-localp)
 522                   (progn
 523                     (setq count (dired-do-kill-lines
 524                                  nil
 525                                  (if dired-omit-verbose "Omitted %d line%s." "")))
 526                     (force-mode-line-update))
 527                 (when dired-omit-verbose (message "(Nothing to omit)")))))
 528         ;; Try to preserve modified state of buffer.  So `%*' doesn't appear
 529         ;; in mode-line of omitted buffers.
 530         (set-buffer-modified-p (and old-modified-p
 531                                     (save-excursion
 532                                       (goto-char (point-min))
 533                                       (re-search-forward dired-re-mark nil t))))
 534         count)))
 535
 536 (defun dired-omit-regexp ()
 537   (concat (if dired-omit-files (concat "\\(" dired-omit-files "\\)") "")
 538           (if (and dired-omit-files dired-omit-extensions) "\\|" "")
 539           (if dired-omit-extensions
 540               (concat ".";; a non-extension part should exist
 541                       "\\("
 542                       (mapconcat 'regexp-quote dired-omit-extensions "\\|")
 543                       "\\)$")
 544             "")))
 545
 546 ;; Returns t if any work was done, nil otherwise.
 547 (defun dired-mark-unmarked-files (regexp msg &optional unflag-p localp)
 548   "Mark unmarked files matching REGEXP, displaying MSG.
 549 REGEXP is matched against the entire file name.
 550 Does not re-mark files which already have a mark.
 551 With prefix argument, unflag all those files.
 552 Optional fourth argument LOCALP is as in `dired-get-filename'."
 553   (interactive "P")
 554   (let ((dired-marker-char (if unflag-p ?\s dired-marker-char)))
 555     (dired-mark-if
 556      (and
 557       ;; not already marked
 558       (looking-at " ")
 559       ;; uninteresting
 560       (let ((fn (dired-get-filename localp t)))
 561         (and fn (string-match regexp fn))))
 562      msg)))
 563
 564 \f
 565 ;;; VIRTUAL DIRED MODE.
 566
 567 ;; For browsing `ls -lR' listings in a dired-like fashion.
 568
 569 (defalias 'virtual-dired 'dired-virtual)
 570 (defun dired-virtual (dirname &optional switches)
 571   "Put this buffer into Virtual Dired mode.
 572
 573 In Virtual Dired mode, all commands that do not actually consult the
 574 filesystem will work.
 575
 576 This is useful if you want to peruse and move around in an ls -lR
 577 output file, for example one you got from an ftp server.  With
 578 ange-ftp, you can even dired a directory containing an ls-lR file,
 579 visit that file and turn on virtual dired mode.  But don't try to save
 580 this file, as dired-virtual indents the listing and thus changes the
 581 buffer.
 582
 583 If you have save a Dired buffer in a file you can use \\[dired-virtual] to
 584 resume it in a later session.
 585
 586 Type \\<dired-mode-map>\\[revert-buffer] \
 587 in the Virtual Dired buffer and answer `y' to convert
 588 the virtual to a real dired buffer again.  You don't have to do this, though:
 589 you can relist single subdirs using \\[dired-do-redisplay]."
 590
 591   ;; DIRNAME is the top level directory of the buffer.  It will become
 592   ;; its `default-directory'.  If nil, the old value of
 593   ;; default-directory is used.
 594
 595   ;; Optional SWITCHES are the ls switches to use.
 596
 597   ;; Shell wildcards will be used if there already is a `wildcard'
 598   ;; line in the buffer (thus it is a saved Dired buffer), but there
 599   ;; is no other way to get wildcards.  Insert a `wildcard' line by
 600   ;; hand if you want them.
 601
 602   (interactive
 603    (list (read-string "Virtual Dired directory: " (dired-virtual-guess-dir))))
 604   (goto-char (point-min))
 605   (or (looking-at "  ")
 606       ;; if not already indented, do it now:
 607       (indent-region (point-min) (point-max) 2))
 608   (or dirname (setq dirname default-directory))
 609   (setq dirname (expand-file-name (file-name-as-directory dirname)))
 610   (setq default-directory dirname)      ; contains no wildcards
 611   (let ((wildcard (save-excursion
 612                     (goto-char (point-min))
 613                     (forward-line 1)
 614                     (and (looking-at "^  wildcard ")
 615                          (buffer-substring (match-end 0)
 616                                            (line-end-position))))))
 617   (if wildcard
 618         (setq dirname (expand-file-name wildcard default-directory))))
 619   ;; If raw ls listing (not a saved old dired buffer), give it a
 620   ;; decent subdir headerline:
 621   (goto-char (point-min))
 622   (or (looking-at dired-subdir-regexp)
 623       (insert "  "
 624               (directory-file-name (file-name-directory default-directory))
 625               ":\n"))
 626   (dired-mode dirname (or switches dired-listing-switches))
 627   (setq mode-name "Virtual Dired"
 628         revert-buffer-function 'dired-virtual-revert)
 629   (set (make-local-variable 'dired-subdir-alist) nil)
 630   (dired-build-subdir-alist)
 631   (goto-char (point-min))
 632   (dired-initial-position dirname))
 633
 634 (defun dired-virtual-guess-dir ()
 635   "Guess and return appropriate working directory of this buffer.
 636 The buffer is assumed to be in Dired or ls -lR format.  The guess is
 637 based upon buffer contents.  If nothing could be guessed, returns
 638 nil."
 639
 640   (let ((regexp "^\\(  \\)?\\([^ \n\r]*\\)\\(:\\)[\n\r]")
 641         (subexpr 2))
 642     (goto-char (point-min))
 643     (cond ((looking-at regexp)
 644            ;; If a saved dired buffer, look to which dir and
 645            ;; perhaps wildcard it belongs:
 646            (let ((dir (buffer-substring (match-beginning subexpr)
 647                                         (match-end subexpr))))
 648              (file-name-as-directory dir)))
 649           ;; Else no match for headerline found.  It's a raw ls listing.
 650           ;; In raw ls listings the directory does not have a headerline
 651           ;; try parent of first subdir, if any
 652           ((re-search-forward regexp nil t)
 653            (file-name-directory
 654             (directory-file-name
 655              (file-name-as-directory
 656               (buffer-substring (match-beginning subexpr)
 657                                 (match-end subexpr))))))
 658           (t                            ; if all else fails
 659            nil))))
 660
 661
 662 (defun dired-virtual-revert (&optional arg noconfirm)
 663   (if (not
 664        (y-or-n-p "Cannot revert a Virtual Dired buffer - switch to Real Dired mode? "))
 665       (error "Cannot revert a Virtual Dired buffer")
 666     (setq mode-name "Dired"
 667           revert-buffer-function 'dired-revert)
 668     (revert-buffer)))
 669
 670 ;; A zero-arg version of dired-virtual.
 671 (defun dired-virtual-mode ()
 672   "Put current buffer into Virtual Dired mode (see `dired-virtual').
 673 Useful on `magic-mode-alist' with the regexp
 674
 675   \"^  \\\\(/[^ /]+\\\\)+/?:$\"
 676
 677 to put saved dired buffers automatically into Virtual Dired mode.
 678
 679 Also useful for `auto-mode-alist' like this:
 680
 681   (add-to-list 'auto-mode-alist
 682                '(\"[^/]\\\\.dired\\\\'\" . dired-virtual-mode))"
 683   (interactive)
 684   (dired-virtual (dired-virtual-guess-dir)))
 685
 686 \f
 687 ;;; SMART SHELL.
 688
 689 ;; An Emacs buffer can have but one working directory, stored in the
 690 ;; buffer-local variable `default-directory'.  A Dired buffer may have
 691 ;; several subdirectories inserted, but still has but one working directory:
 692 ;; that of the top level Dired directory in that buffer.  For some commands
 693 ;; it is appropriate that they use the current Dired directory instead of
 694 ;; `default-directory', e.g., `find-file' and `compile'.  This is a general
 695 ;; mechanism is provided for special handling of the working directory in
 696 ;; special major modes.
 697
 698 (define-obsolete-variable-alias 'default-directory-alist
 699   'dired-default-directory-alist "24.1")
 700
 701 ;; It's easier to add to this alist than redefine function
 702 ;; default-directory while keeping the old information.
 703 (defconst dired-default-directory-alist
 704   '((dired-mode . (if (fboundp 'dired-current-directory)
 705                       (dired-current-directory)
 706                     default-directory)))
 707   "Alist of major modes and their opinion on `default-directory'.
 708 Each element has the form (MAJOR . EXPRESSION).
 709 The function `dired-default-directory' evaluates EXPRESSION to
 710 determine a default directory.")
 711
 712 (put 'dired-default-directory-alist 'risky-local-variable t) ; gets eval'd
 713 (make-obsolete-variable 'dired-default-directory-alist
 714                         "this feature is due to be removed." "24.1")
 715
 716 (defun dired-default-directory ()
 717   "Return the `dired-default-directory-alist' entry for the current major-mode.
 718 If none, return `default-directory'."
 719   (or (eval (cdr (assq major-mode dired-default-directory-alist)))
 720       default-directory))
 721
 722 ;; It looks like this was intended to be something of a "general" feature,
 723 ;; but it only ever seems to have been used in dired-smart-shell-command,
 724 ;; and does not seem worth keeping around (?).
 725 (make-obsolete 'dired-default-directory
 726                "this feature is due to be removed." "24.1")
 727
 728 (defun dired-smart-shell-command (command &optional output-buffer error-buffer)
 729   "Like function `shell-command', but in the current Virtual Dired directory."
 730   (interactive
 731    (list
 732     (read-shell-command "Shell command: " nil nil
 733                         (cond
 734                          (buffer-file-name (file-relative-name buffer-file-name))
 735                          ((eq major-mode 'dired-mode) (dired-get-filename t t))))
 736     current-prefix-arg
 737     shell-command-default-error-buffer))
 738   (let ((default-directory (or (and (eq major-mode 'dired-mode)
 739                                     (dired-current-directory))
 740                                default-directory)))
 741     (shell-command command output-buffer error-buffer)))
 742
 743 \f
 744 ;;; LOCAL VARIABLES FOR DIRED BUFFERS.
 745
 746 ;; Brief Description  (This feature is obsolete as of Emacs 24.1)
 747 ;;
 748 ;; * `dired-extra-startup' is part of the `dired-mode-hook'.
 749 ;;
 750 ;; * `dired-extra-startup' calls `dired-hack-local-variables'
 751 ;;
 752 ;; * `dired-hack-local-variables' checks the value of
 753 ;;   `dired-local-variables-file'
 754 ;;
 755 ;; * Check if `dired-local-variables-file' is a non-nil string and is a
 756 ;;   filename found in the directory of the Dired Buffer being created.
 757 ;;
 758 ;; * If `dired-local-variables-file' satisfies the above, then temporarily
 759 ;;   include it in the Dired Buffer at the bottom.
 760 ;;
 761 ;; * Set `enable-local-variables' temporarily to the user variable
 762 ;;   `dired-enable-local-variables' and run `hack-local-variables' on the
 763 ;;   Dired Buffer.
 764
 765 (defcustom dired-local-variables-file (convert-standard-filename ".dired")
 766   "Filename, as string, containing local dired buffer variables to be hacked.
 767 If this file found in current directory, then it will be inserted into dired
 768 buffer and `hack-local-variables' will be run.  See Info node
 769 `(emacs)File Variables' for more information on local variables.
 770 See also `dired-enable-local-variables'."
 771   :type 'file
 772   :group 'dired)
 773
 774 (make-obsolete-variable 'dired-local-variables-file 'dir-locals-file "24.1")
 775
 776 (defun dired-hack-local-variables ()
 777   "Evaluate local variables in `dired-local-variables-file' for dired buffer."
 778   (and (stringp dired-local-variables-file)
 779        (file-exists-p dired-local-variables-file)
 780        (let ((opoint (point-max))
 781              (inhibit-read-only t)
 782              ;; In case user has `enable-local-variables' set to nil we
 783              ;; override it locally with dired's variable.
 784              (enable-local-variables dired-enable-local-variables))
 785          ;; Insert 'em.
 786          (save-excursion
 787            (goto-char opoint)
 788            (insert "\^L\n")
 789            (insert-file-contents dired-local-variables-file))
 790          ;; Hack 'em.
 791          (unwind-protect
 792              (let ((buffer-file-name dired-local-variables-file))
 793                (hack-local-variables))
 794            ;; Delete this stuff: `eobp' is used to find last subdir by dired.el.
 795            (delete-region opoint (point-max)))
 796          ;; Make sure that the modeline shows the proper information.
 797          (dired-sort-set-modeline))))
 798
 799 (make-obsolete 'dired-hack-local-variables
 800                'hack-dir-local-variables-non-file-buffer "24.1")
 801
 802 ;; Does not seem worth a dedicated command.
 803 ;; See the more general features in files-x.el.
 804 (defun dired-omit-here-always ()
 805   "Create `dir-locals-file' setting `dired-omit-mode' to t in `dired-mode'.
 806 If in a Dired buffer, reverts it."
 807   (interactive)
 808   (if (file-exists-p dired-local-variables-file)
 809       (error "Old-style dired-local-variables-file `./%s' found;
 810 replace it with a dir-locals-file `./%s'"
 811              dired-local-variables-file
 812              dir-locals-file))
 813   (if (file-exists-p dir-locals-file)
 814       (message "File `./%s' already exists." dir-locals-file)
 815     (with-temp-buffer
 816       (insert "\
 817 \((dired-mode . ((subdirs . nil)
 818                 (dired-omit-mode . t))))\n")
 819       (write-file dir-locals-file))
 820     ;; Run extra-hooks and revert directory.
 821     (when (derived-mode-p 'dired-mode)
 822       (hack-dir-local-variables-non-file-buffer)
 823       (dired-extra-startup)
 824       (dired-revert))))
 825
 826 (make-obsolete 'dired-omit-here-always 'add-dir-local-variable "24.1")
 827
 828 \f
 829 ;;; GUESS SHELL COMMAND.
 830
 831 ;; Brief Description:
 832 ;;;
 833 ;; * `dired-do-shell-command' is bound to `!' by dired.el.
 834 ;;;
 835 ;; * `dired-guess-shell-command' provides smarter defaults for
 836 ;;;    dired-aux.el's `dired-read-shell-command'.
 837 ;;;
 838 ;; * `dired-guess-shell-command' calls `dired-guess-default' with list of
 839 ;;;    marked files.
 840 ;;;
 841 ;; * Parse `dired-guess-shell-alist-user' and
 842 ;;;   `dired-guess-shell-alist-default' (in that order) for the first REGEXP
 843 ;;;   that matches the first file in the file list.
 844 ;;;
 845 ;; * If the REGEXP matches all the entries of the file list then evaluate
 846 ;;;   COMMAND, which is either a string or a Lisp expression returning a
 847 ;;;   string.  COMMAND may be a list of commands.
 848 ;;;
 849 ;; * Return this command to `dired-guess-shell-command' which prompts user
 850 ;;;   with it.  The list of commands is put into the list of default values.
 851 ;;;   If a command is used successfully then it is stored permanently in
 852 ;;;   `dired-shell-command-history'.
 853
 854 ;; Guess what shell command to apply to a file.
 855 (defvar dired-shell-command-history nil
 856   "History list for commands that read dired-shell commands.")
 857
 858 ;; Default list of shell commands.
 859
 860 ;; NOTE: Use `gunzip -c' instead of `zcat' on `.gz' files.  Some do not
 861 ;; install GNU zip's version of zcat.
 862
 863 (autoload 'Man-support-local-filenames "man")
 864
 865 (defvar dired-guess-shell-alist-default
 866   (list
 867    (list "\\.tar\\'"
 868          '(if dired-guess-shell-gnutar
 869               (concat dired-guess-shell-gnutar " xvf")
 870             "tar xvf")
 871          ;; Extract files into a separate subdirectory
 872          '(if dired-guess-shell-gnutar
 873               (concat "mkdir " (file-name-sans-extension file)
 874                       "; " dired-guess-shell-gnutar " -C "
 875                       (file-name-sans-extension file) " -xvf")
 876             (concat "mkdir " (file-name-sans-extension file)
 877                     "; tar -C " (file-name-sans-extension file) " -xvf"))
 878          ;; List archive contents.
 879          '(if dired-guess-shell-gnutar
 880               (concat dired-guess-shell-gnutar " tvf")
 881             "tar tvf"))
 882
 883    ;; REGEXPS for compressed archives must come before the .Z rule to
 884    ;; be recognized:
 885    (list "\\.tar\\.Z\\'"
 886          ;; Untar it.
 887          '(if dired-guess-shell-gnutar
 888               (concat dired-guess-shell-gnutar " zxvf")
 889             (concat "zcat * | tar xvf -"))
 890          ;; Optional conversion to gzip format.
 891          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 892                   " " dired-guess-shell-znew-switches))
 893
 894    ;; gzip'ed archives
 895    (list "\\.t\\(ar\\.\\)?gz\\'"
 896          '(if dired-guess-shell-gnutar
 897               (concat dired-guess-shell-gnutar " zxvf")
 898             (concat "gunzip -qc * | tar xvf -"))
 899          ;; Extract files into a separate subdirectory
 900          '(if dired-guess-shell-gnutar
 901               (concat "mkdir " (file-name-sans-extension file)
 902                       "; " dired-guess-shell-gnutar " -C "
 903                       (file-name-sans-extension file) " -zxvf")
 904             (concat "mkdir " (file-name-sans-extension file)
 905                     "; gunzip -qc * | tar -C "
 906                     (file-name-sans-extension file) " -xvf -"))
 907          ;; Optional decompression.
 908          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q" ""))
 909          ;; List archive contents.
 910          '(if dired-guess-shell-gnutar
 911               (concat dired-guess-shell-gnutar " ztvf")
 912             (concat "gunzip -qc * | tar tvf -")))
 913
 914    ;; bzip2'ed archives
 915    (list "\\.t\\(ar\\.bz2\\|bz\\)\\'"
 916          "bunzip2 -c * | tar xvf -"
 917          ;; Extract files into a separate subdirectory
 918          '(concat "mkdir " (file-name-sans-extension file)
 919                   "; bunzip2 -c * | tar -C "
 920                   (file-name-sans-extension file) " -xvf -")
 921          ;; Optional decompression.
 922          "bunzip2")
 923
 924    ;; xz'ed archives
 925    (list "\\.t\\(ar\\.\\)?xz\\'"
 926          "unxz -c * | tar xvf -"
 927          ;; Extract files into a separate subdirectory
 928          '(concat "mkdir " (file-name-sans-extension file)
 929                   "; unxz -c * | tar -C "
 930                   (file-name-sans-extension file) " -xvf -")
 931          ;; Optional decompression.
 932          "unxz")
 933
 934    '("\\.shar\\.Z\\'" "zcat * | unshar")
 935    '("\\.shar\\.g?z\\'" "gunzip -qc * | unshar")
 936
 937    '("\\.e?ps\\'" "ghostview" "xloadimage" "lpr")
 938    (list "\\.e?ps\\.g?z\\'" "gunzip -qc * | ghostview -"
 939          ;; Optional decompression.
 940          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 941    (list "\\.e?ps\\.Z\\'" "zcat * | ghostview -"
 942          ;; Optional conversion to gzip format.
 943          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 944                   " " dired-guess-shell-znew-switches))
 945
 946    '("\\.patch\\'" "cat * | patch")
 947    (list "\\.patch\\.g?z\\'" "gunzip -qc * | patch"
 948          ;; Optional decompression.
 949          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 950    (list "\\.patch\\.Z\\'" "zcat * | patch"
 951          ;; Optional conversion to gzip format.
 952          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 953                   " " dired-guess-shell-znew-switches))
 954
 955    ;; The following four extensions are useful with dired-man ("N" key)
 956    ;; FIXME "man ./" does not work with dired-do-shell-command,
 957    ;; because there seems to be no way for us to modify the filename,
 958    ;; only the command.  Hmph.  `dired-man' works though.
 959    (list "\\.\\(?:[0-9]\\|man\\)\\'" '(let ((loc (Man-support-local-filenames)))
 960                                         (cond ((eq loc 'man-db) "man -l")
 961                                               ((eq loc 'man) "man ./")
 962                                               (t
 963                                                "cat * | tbl | nroff -man -h"))))
 964    (list "\\.\\(?:[0-9]\\|man\\)\\.g?z\\'"
 965          '(let ((loc (Man-support-local-filenames)))
 966             (cond ((eq loc 'man-db)
 967                    "man -l")
 968                   ((eq loc 'man)
 969                    "man ./")
 970                   (t "gunzip -qc * | tbl | nroff -man -h")))
 971          ;; Optional decompression.
 972          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 973    (list "\\.[0-9]\\.Z\\'" '(let ((loc (Man-support-local-filenames)))
 974                               (cond ((eq loc 'man-db) "man -l")
 975                                     ((eq loc 'man) "man ./")
 976                                     (t "zcat * | tbl | nroff -man -h")))
 977          ;; Optional conversion to gzip format.
 978          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 979                   " " dired-guess-shell-znew-switches))
 980    '("\\.pod\\'" "perldoc" "pod2man * | nroff -man")
 981
 982    '("\\.dvi\\'" "xdvi" "dvips")                ; preview and printing
 983    '("\\.au\\'" "play")                 ; play Sun audiofiles
 984    '("\\.mpe?g\\'\\|\\.avi\\'" "xine -p")
 985    '("\\.ogg\\'" "ogg123")
 986    '("\\.mp3\\'" "mpg123")
 987    '("\\.wav\\'" "play")
 988    '("\\.uu\\'" "uudecode")             ; for uudecoded files
 989    '("\\.hqx\\'" "mcvert")
 990    '("\\.sh\\'" "sh")                   ; execute shell scripts
 991    '("\\.xbm\\'" "bitmap")              ; view X11 bitmaps
 992    '("\\.gp\\'" "gnuplot")
 993    '("\\.p[bgpn]m\\'" "xloadimage")
 994    '("\\.gif\\'" "xloadimage")          ; view gif pictures
 995    '("\\.tif\\'" "xloadimage")
 996    '("\\.png\\'" "display")             ; xloadimage 4.1 doesn't grok PNG
 997    '("\\.jpe?g\\'" "xloadimage")
 998    '("\\.fig\\'" "xfig")                        ; edit fig pictures
 999    '("\\.out\\'" "xgraph")              ; for plotting purposes.
1000    '("\\.tex\\'" "latex" "tex")
1001    '("\\.texi\\(nfo\\)?\\'" "makeinfo" "texi2dvi")
1002    '("\\.pdf\\'" "xpdf")
1003    '("\\.doc\\'" "antiword" "strings")
1004    '("\\.rpm\\'" "rpm -qilp" "rpm -ivh")
1005    '("\\.dia\\'" "dia")
1006    '("\\.mgp\\'" "mgp")
1007
1008    ;; Some other popular archivers.
1009    (list "\\.zip\\'" "unzip" "unzip -l"
1010          ;; Extract files into a separate subdirectory
1011          '(concat "unzip" (if dired-guess-shell-gzip-quiet " -q")
1012                   " -d " (file-name-sans-extension file)))
1013    '("\\.zoo\\'" "zoo x//")
1014    '("\\.lzh\\'" "lharc x")
1015    '("\\.arc\\'" "arc x")
1016    '("\\.shar\\'" "unshar")
1017    '("\\.rar\\'" "unrar x")
1018    '("\\.7z\\'" "7z x")
1019
1020    ;; Compression.
1021    (list "\\.g?z\\'" '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1022    (list "\\.dz\\'" "dictunzip")
1023    (list "\\.bz2\\'" "bunzip2")
1024    (list "\\.xz\\'" "unxz")
1025    (list "\\.Z\\'" "uncompress"
1026          ;; Optional conversion to gzip format.
1027          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1028                   " " dired-guess-shell-znew-switches))
1029
1030    '("\\.sign?\\'" "gpg --verify"))
1031
1032   "Default alist used for shell command guessing.
1033 See `dired-guess-shell-alist-user'.")
1034
1035 (defcustom dired-guess-shell-alist-user nil
1036   "User-defined alist of rules for suggested commands.
1037 These rules take precedence over the predefined rules in the variable
1038 `dired-guess-shell-alist-default' (to which they are prepended).
1039
1040 Each element of this list looks like
1041
1042     \(REGEXP COMMAND...\)
1043
1044 where each COMMAND can either be a string or a Lisp expression that evaluates
1045 to a string.  If several COMMANDs are given, the first one will be the default
1046 and the rest will be added temporarily to the history and can be retrieved
1047 with \\[previous-history-element] (M-p) .
1048
1049 The variable `dired-guess-shell-case-fold-search' controls whether
1050 REGEXP is matched case-sensitively.
1051
1052 You can set this variable in your ~/.emacs.  For example, to add rules for
1053 `.foo' and `.bar' files, write
1054
1055  \(setq dired-guess-shell-alist-user
1056        (list (list \"\\\\.foo\\\\'\" \"FOO-COMMAND\");; fixed rule
1057               ;; possibly more rules ...
1058               (list \"\\\\.bar\\\\'\";; rule with condition test
1059                     '(if condition
1060                           \"BAR-COMMAND-1\"
1061                         \"BAR-COMMAND-2\")))\)"
1062   :group 'dired-x
1063   :type '(alist :key-type regexp :value-type (repeat sexp)))
1064
1065 (defcustom dired-guess-shell-case-fold-search t
1066   "If non-nil, `dired-guess-shell-alist-default' and
1067 `dired-guess-shell-alist-user' are matched case-insensitively."
1068   :group 'dired-x
1069   :type 'boolean)
1070
1071 (defun dired-guess-default (files)
1072   "Guess a shell commands for FILES.  Return command or list of commands.
1073 See `dired-guess-shell-alist-user'."
1074
1075   (let* ((case-fold-search dired-guess-shell-case-fold-search)
1076          ;; Prepend the user's alist to the default alist.
1077          (alist (append dired-guess-shell-alist-user
1078                         dired-guess-shell-alist-default))
1079          (file (car files))
1080          (flist (cdr files))
1081          elt regexp cmds)
1082
1083     ;; Find the first match in the alist for first file in FILES.
1084     (while alist
1085       (setq elt (car alist)
1086             regexp (car elt)
1087             alist (cdr alist))
1088       (if (string-match regexp file)
1089           (setq cmds (cdr elt)
1090                 alist nil)))
1091
1092     ;; If more than one file, see if all of FILES match regular expression.
1093     (while (and flist
1094                 (string-match regexp (car flist)))
1095       (setq flist (cdr flist)))
1096
1097     ;; If flist is still non-nil, then do not guess since this means that not
1098     ;; all the files in FILES were matched by the regexp.
1099     (setq cmds (and (not flist) cmds))
1100
1101     ;; Return commands or nil if flist is still non-nil.
1102     ;; Evaluate the commands in order that any logical testing will be done.
1103     (if (cdr cmds)
1104         (mapcar #'eval cmds)
1105       (eval (car cmds))))) ; single command
1106
1107 (defun dired-guess-shell-command (prompt files)
1108   "Ask user with PROMPT for a shell command, guessing a default from FILES."
1109   (let ((default (dired-guess-default files))
1110         default-list val)
1111     (if (null default)
1112         ;; Nothing to guess
1113         (read-shell-command prompt nil 'dired-shell-command-history)
1114       (if (listp default)
1115           ;; More than one guess
1116           (setq default-list default
1117                 default (car default)
1118                 prompt (concat
1119                         prompt
1120                         (format "{%d guesses} " (length default-list))))
1121         ;; Just one guess
1122         (setq default-list (list default)))
1123       ;; Put the first guess in the prompt but not in the initial value.
1124       (setq prompt (concat prompt (format "[%s] " default)))
1125       ;; All guesses can be retrieved with M-n
1126       (setq val (read-shell-command prompt nil
1127                                     'dired-shell-command-history
1128                                     default-list))
1129       ;; If we got a return, then return default.
1130       (if (equal val "") default val))))
1131
1132 \f
1133 ;;; RELATIVE SYMBOLIC LINKS.
1134
1135 (declare-function make-symbolic-link "fileio.c")
1136
1137 (defvar dired-keep-marker-relsymlink ?S
1138   "See variable `dired-keep-marker-move'.")
1139
1140 (defun dired-make-relative-symlink (file1 file2 &optional ok-if-already-exists)
1141   "Make a symbolic link (pointing to FILE1) in FILE2.
1142 The link is relative (if possible), for example
1143
1144     \"/vol/tex/bin/foo\" \"/vol/local/bin/foo\"
1145
1146 results in
1147
1148     \"../../tex/bin/foo\" \"/vol/local/bin/foo\""
1149   (interactive "FRelSymLink: \nFRelSymLink %s: \np")
1150   (let (name1 name2 len1 len2 (index 0) sub)
1151     (setq file1 (expand-file-name file1)
1152           file2 (expand-file-name file2)
1153           len1 (length file1)
1154           len2 (length file2))
1155     ;; Find common initial file name components:
1156     (let (next)
1157       (while (and (setq next (string-match "/" file1 index))
1158                   (< (setq next (1+ next)) (min len1 len2))
1159                   ;; For the comparison, both substrings must end in
1160                   ;; `/', so NEXT is *one plus* the result of the
1161                   ;; string-match.
1162                   ;; E.g., consider the case of linking "/tmp/a/abc"
1163                   ;; to "/tmp/abc" erroneously giving "/tmp/a" instead
1164                   ;; of "/tmp/" as common initial component
1165                   (string-equal (substring file1 0 next)
1166                                 (substring file2 0 next)))
1167         (setq index next))
1168       (setq name2 file2
1169             sub (substring file1 0 index)
1170             name1 (substring file1 index)))
1171     (if (string-equal sub "/")
1172         ;; No common initial file name found
1173         (setq name1 file1)
1174       ;; Else they have a common parent directory
1175       (let ((tem (substring file2 index))
1176             (start 0)
1177             (count 0))
1178         ;; Count number of slashes we must compensate for ...
1179         (while (setq start (string-match "/" tem start))
1180           (setq count (1+ count)
1181                 start (1+ start)))
1182         ;; ... and prepend a "../" for each slash found:
1183         (dotimes (n count)
1184           (setq name1 (concat "../" name1)))))
1185     (make-symbolic-link
1186      (directory-file-name name1)        ; must not link to foo/
1187                                         ; (trailing slash!)
1188      name2 ok-if-already-exists)))
1189
1190 (autoload 'dired-do-create-files "dired-aux")
1191
1192 ;;;###autoload
1193 (defun dired-do-relsymlink (&optional arg)
1194    "Relative symlink all marked (or next ARG) files into a directory.
1195 Otherwise make a relative symbolic link to the current file.
1196 This creates relative symbolic links like
1197
1198     foo -> ../bar/foo
1199
1200 not absolute ones like
1201
1202     foo -> /ugly/file/name/that/may/change/any/day/bar/foo
1203
1204 For absolute symlinks, use \\[dired-do-symlink]."
1205   (interactive "P")
1206   (dired-do-create-files 'relsymlink #'dired-make-relative-symlink
1207                            "RelSymLink" arg dired-keep-marker-relsymlink))
1208
1209 (autoload 'dired-mark-read-regexp "dired-aux")
1210 (autoload 'dired-do-create-files-regexp "dired-aux")
1211
1212 (defun dired-do-relsymlink-regexp (regexp newname &optional arg whole-name)
1213   "RelSymlink all marked files containing REGEXP to NEWNAME.
1214 See functions `dired-do-rename-regexp' and `dired-do-relsymlink'
1215 for more info."
1216   (interactive (dired-mark-read-regexp "RelSymLink"))
1217   (dired-do-create-files-regexp
1218    #'dired-make-relative-symlink
1219    "RelSymLink" arg regexp newname whole-name dired-keep-marker-relsymlink))
1220
1221 \f
1222 ;;; VISIT ALL MARKED FILES SIMULTANEOUSLY.
1223
1224 ;; Brief Description:
1225 ;;;
1226 ;; `dired-do-find-marked-files' is bound to `F' by dired-x.el.
1227 ;;;
1228 ;; * Use `dired-get-marked-files' to collect the marked files in the current
1229 ;;;   Dired Buffer into a list of filenames `FILE-LIST'.
1230 ;;;
1231 ;; * Pass FILE-LIST to `dired-simultaneous-find-file' all with
1232 ;;;   `dired-do-find-marked-files''s prefix argument NOSELECT.
1233 ;;;
1234 ;; * `dired-simultaneous-find-file' runs through FILE-LIST decrementing the
1235 ;;;   list each time.
1236 ;;;
1237 ;; * If NOSELECT is non-nil then just run `find-file-noselect' on each
1238 ;;;   element of FILE-LIST.
1239 ;;;
1240 ;; * If NOSELECT is nil then calculate the `size' of the window for each file
1241 ;;;   by dividing the `window-height' by length of FILE-LIST.  Thus, `size' is
1242 ;;;   cognizant of the window-configuration.
1243 ;;;
1244 ;; * If `size' is too small abort, otherwise run `find-file' on each element
1245 ;;;   of FILE-LIST giving each a window of height `size'.
1246
1247 (defun dired-do-find-marked-files (&optional noselect)
1248   "Find all marked files displaying all of them simultaneously.
1249 With optional NOSELECT just find files but do not select them.
1250
1251 The current window is split across all files marked, as evenly as possible.
1252 Remaining lines go to bottom-most window.  The number of files that can be
1253 displayed this way is restricted by the height of the current window and
1254 `window-min-height'.
1255
1256 To keep dired buffer displayed, type \\[split-window-vertically] first.
1257 To display just marked files, type \\[delete-other-windows] first."
1258   (interactive "P")
1259   (dired-simultaneous-find-file (dired-get-marked-files) noselect))
1260
1261 (defun dired-simultaneous-find-file (file-list noselect)
1262   "Visit all files in FILE-LIST and display them simultaneously.
1263 The current window is split across all files in FILE-LIST, as evenly as
1264 possible.  Remaining lines go to the bottom-most window.  The number of
1265 files that can be displayed this way is restricted by the height of the
1266 current window and the variable `window-min-height'.  With non-nil
1267 NOSELECT the files are merely found but not selected."
1268   ;; We don't make this function interactive because it is usually too clumsy
1269   ;; to specify FILE-LIST interactively unless via dired.
1270   (let (size)
1271     (if noselect
1272         ;; Do not select the buffer.
1273         (find-file-noselect (car file-list))
1274       ;; We will have to select the buffer.  Calculate and check window size.
1275       (setq size (/ (window-height) (length file-list)))
1276       (or (<= window-min-height size)
1277           (error "Too many files to visit simultaneously.  Try C-u prefix"))
1278       (find-file (car file-list)))
1279     ;; Decrement.
1280     (dolist (file (cdr file-list))
1281       (if noselect
1282           ;; Do not select the buffer.
1283           (find-file-noselect file)
1284         ;; Vertically split off a window of desired size.  Upper window will
1285         ;; have SIZE lines.  Select lower (larger) window.  We split it again.
1286         (select-window (split-window nil size))
1287         (find-file file)))))
1288
1289 \f
1290 ;;; MISCELLANEOUS COMMANDS.
1291
1292 ;; Run man on files.
1293
1294 (declare-function Man-getpage-in-background "man" (topic))
1295
1296 (defun dired-man ()
1297   "Run `man' on this file."
1298 ;; Used also to say: "Display old buffer if buffer name matches filename."
1299 ;; but I have no idea what that means.
1300   (interactive)
1301   (require 'man)
1302   (let* ((file (dired-get-filename))
1303          (manual-program (replace-regexp-in-string "\\*" "%s"
1304                           (dired-guess-shell-command
1305                            "Man command: " (list file)))))
1306     (Man-getpage-in-background file)))
1307
1308 ;; Run Info on files.
1309
1310 (defun dired-info ()
1311   "Run `info' on this file."
1312   (interactive)
1313   (info (dired-get-filename)))
1314
1315 ;; Run mail on mail folders.
1316
1317 (declare-function vm-visit-folder "ext:vm" (folder &optional read-only))
1318 (defvar vm-folder-directory)
1319
1320 (defun dired-vm (&optional read-only)
1321   "Run VM on this file.
1322 With optional prefix argument, visits the folder read-only.
1323 Otherwise obeys the value of `dired-vm-read-only-folders'."
1324   (interactive "P")
1325   (let ((dir (dired-current-directory))
1326         (fil (dired-get-filename)))
1327     (vm-visit-folder fil (or read-only
1328                              (eq t dired-vm-read-only-folders)
1329                              (and dired-vm-read-only-folders
1330                                   (not (file-writable-p fil)))))
1331     ;; So that pressing `v' inside VM does prompt within current directory:
1332     (set (make-local-variable 'vm-folder-directory) dir)))
1333
1334 (defun dired-rmail ()
1335   "Run RMAIL on this file."
1336   (interactive)
1337   (rmail (dired-get-filename)))
1338
1339 (defun dired-do-run-mail ()
1340   "If `dired-bind-vm' is non-nil, call `dired-vm', else call `dired-rmail'."
1341   (interactive)
1342   (if dired-bind-vm
1343       ;; Read mail folder using vm.
1344       (dired-vm)
1345     ;; Read mail folder using rmail.
1346     (dired-rmail)))
1347
1348 \f
1349 ;;; MISCELLANEOUS INTERNAL FUNCTIONS.
1350
1351 ;; This should be a builtin
1352 (defun dired-buffer-more-recently-used-p (buffer1 buffer2)
1353   "Return t if BUFFER1 is more recently used than BUFFER2.
1354 Considers buffers closer to the car of `buffer-list' to be more recent."
1355   (and (not (equal buffer1 buffer2))
1356        (memq buffer1 (buffer-list))
1357        (not (memq buffer1 (memq buffer2 (buffer-list))))))
1358
1359 ;; Same thing as `dired-buffers-for-dir' of dired.el? - lrd 11/23/93
1360 ;; (defun dired-buffers-for-dir-exact (dir)
1361 ;; ;; Return a list of buffers that dired DIR (a directory or wildcard)
1362 ;; ;; at top level, or as subdirectory.
1363 ;; ;; Top level matches must match the wildcard part too, if any.
1364 ;; ;; The list is in reverse order of buffer creation, most recent last.
1365 ;; ;; As a side effect, killed dired buffers for DIR are removed from
1366 ;; ;; dired-buffers.
1367 ;;   (let ((alist dired-buffers) result elt)
1368 ;;     (while alist
1369 ;;       (setq elt (car alist)
1370 ;;             alist (cdr alist))
1371 ;;       (let ((buf (cdr elt)))
1372 ;;         (if (buffer-name buf)
1373 ;;             ;; Top level must match exactly against dired-directory in
1374 ;;             ;; case one of them is a wildcard.
1375 ;;             (if (or (equal dir (with-current-buffer buf dired-directory))
1376 ;;                     (assoc dir (with-current-buffer buf dired-subdir-alist)))
1377 ;;                 (setq result (cons buf result)))
1378 ;;           ;; else buffer is killed - clean up:
1379 ;;           (setq dired-buffers (delq elt dired-buffers)))))
1380 ;;     result))
1381
1382 \f
1383 ;; Does anyone use this? - lrd 6/29/93.
1384 ;; Apparently people do use it. - lrd 12/22/97.
1385 (defun dired-mark-sexp (predicate &optional unflag-p)
1386   "Mark files for which PREDICATE returns non-nil.
1387 With a prefix arg, unflag those files instead.
1388
1389 PREDICATE is a lisp expression that can refer to the following symbols:
1390
1391     inode  [integer] the inode of the file (only for ls -i output)
1392     s      [integer] the size of the file for ls -s output
1393                      (usually in blocks or, with -k, in KByte)
1394     mode   [string]  file permission bits, e.g. \"-rw-r--r--\"
1395     nlink  [integer] number of links to file
1396     uid    [string]  owner
1397     gid    [string]  group  (If the gid is not displayed by ls,
1398                      this will still be set (to the same as uid))
1399     size   [integer] file size in bytes
1400     time   [string]  the time that ls displays, e.g. \"Feb 12 14:17\"
1401     name   [string]  the name of the file
1402     sym    [string]  if file is a symbolic link, the linked-to name, else \"\"
1403
1404 For example, use
1405
1406         (equal 0 size)
1407
1408 to mark all zero length files."
1409   ;; Using sym="" instead of nil avoids the trap of
1410   ;; (string-match "foo" sym) into which a user would soon fall.
1411   ;; Give `equal' instead of `=' in the example, as this works on
1412   ;; integers and strings.
1413   (interactive "xMark if (lisp expr): \nP")
1414   (message "%s" predicate)
1415   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char))
1416         inode s mode nlink uid gid size time name sym)
1417     (dired-mark-if
1418      (save-excursion
1419        (and
1420         ;; Sets vars
1421         ;;                inode s mode nlink uid gid size time name sym
1422
1423         ;; according to current file line.  Returns t for success, nil if
1424         ;; there is no file line.  Upon success, all variables are set, either
1425         ;; to nil or the appropriate value, so they need not be initialized.
1426         ;; Moves point within the current line.
1427         (dired-move-to-filename)
1428         (let (pos
1429               (mode-len 10) ; length of mode string
1430               ;; like in dired.el, but with subexpressions \1=inode, \2=s:
1431               (dired-re-inode-size "\\s *\\([0-9]*\\)\\s *\\([0-9]*\\) ?"))
1432           (beginning-of-line)
1433           (forward-char 2)
1434           (if (looking-at dired-re-inode-size)
1435               (progn
1436                 (goto-char (match-end 0))
1437                 (setq inode (string-to-number
1438                              (buffer-substring (match-beginning 1)
1439                                                (match-end 1)))
1440                       s (string-to-number
1441                          (buffer-substring (match-beginning 2)
1442                                            (match-end 2)))))
1443             (setq inode nil
1444                   s nil))
1445           (setq mode (buffer-substring (point) (+ mode-len (point))))
1446           (forward-char mode-len)
1447           (setq nlink (read (current-buffer)))
1448           ;; Karsten Wenger <kw@cis.uni-muenchen.de> fixed uid.
1449           (setq uid (buffer-substring (1+ (point))
1450                                       (progn (forward-word 1) (point))))
1451           (re-search-forward directory-listing-before-filename-regexp)
1452           (goto-char (match-beginning 1))
1453           (forward-char -1)
1454           (setq size (string-to-number
1455                       (buffer-substring (save-excursion
1456                                           (backward-word 1)
1457                                           (setq pos (point)))
1458                                         (point))))
1459           (goto-char pos)
1460           (backward-word 1)
1461           ;; if no gid is displayed, gid will be set to uid
1462           ;; but user will then not reference it anyway in PREDICATE.
1463           (setq gid (buffer-substring (save-excursion
1464                                         (forward-word 1) (point))
1465                                       (point))
1466                 time (buffer-substring (match-beginning 1)
1467                                        (1- (dired-move-to-filename)))
1468                 name (buffer-substring (point)
1469                                        (or
1470                                         (dired-move-to-end-of-filename t)
1471                                         (point)))
1472                 sym (if (looking-at " -> ")
1473                         (buffer-substring (progn (forward-char 4) (point))
1474                                           (line-end-position))
1475                       ""))
1476           t)
1477         (eval predicate)))
1478      (format "'%s file" predicate))))
1479
1480 \f
1481 ;;; FIND FILE AT POINT.
1482
1483 (defcustom dired-x-hands-off-my-keys t
1484   "Non-nil means don't remap `find-file' to `dired-x-find-file'.
1485 Similarly for `find-file-other-window' and `dired-x-find-file-other-window'.
1486 If you change this variable without using \\[customize] after `dired-x.el'
1487 is loaded then call \\[dired-x-bind-find-file]."
1488   :type 'boolean
1489   :initialize 'custom-initialize-default
1490   :set (lambda (sym val)
1491          (set sym val)
1492          (dired-x-bind-find-file))
1493   :group 'dired-x)
1494
1495 (defun dired-x-bind-find-file ()
1496   "Bind `dired-x-find-file' in place of `find-file' (or vice-versa).
1497 Similarly for `dired-x-find-file-other-window' and `find-file-other-window'.
1498 Binding direction based on `dired-x-hands-off-my-keys'."
1499   (interactive)
1500   (if (called-interactively-p 'interactive)
1501       (setq dired-x-hands-off-my-keys
1502             (not (y-or-n-p "Bind dired-x-find-file over find-file? "))))
1503   (define-key (current-global-map) [remap find-file]
1504     (if (not dired-x-hands-off-my-keys) 'dired-x-find-file))
1505   (define-key (current-global-map) [remap find-file-other-window]
1506     (if (not dired-x-hands-off-my-keys) 'dired-x-find-file-other-window)))
1507
1508 ;; Now call it so binding is correct.  This could go in the :initialize
1509 ;; slot, but then dired-x-bind-find-file has to be defined before the
1510 ;; defcustom, and we get free variable warnings.
1511 (dired-x-bind-find-file)
1512
1513 (defun dired-x-find-file (filename)
1514   "Edit file FILENAME.
1515 Like `find-file', except that when called interactively with a
1516 prefix argument, it offers the filename near point as a default."
1517   (interactive (list (dired-x-read-filename-at-point "Find file: ")))
1518   (find-file filename))
1519
1520 (defun dired-x-find-file-other-window (filename)
1521   "Edit file FILENAME, in another window.
1522 Like `find-file-other-window', except that when called interactively with
1523 a prefix argument, when it offers the filename near point as a default."
1524   (interactive (list (dired-x-read-filename-at-point "Find file: ")))
1525   (find-file-other-window filename))
1526
1527 ;;; Internal functions.
1528
1529 ;; Fixme: This should probably use `thing-at-point'.  -- fx
1530 (defun dired-filename-at-point ()
1531   "Return the filename closest to point, expanded.
1532 Point should be in or after a filename."
1533   (save-excursion
1534     ;; First see if just past a filename.
1535     (or (eobp)                             ; why?
1536         (when (looking-at "[] \t\n[{}()]") ; whitespace or some parens
1537           (skip-chars-backward " \n\t\r({[]})")
1538           (or (bobp) (backward-char 1))))
1539     (let ((filename-chars "-.[:alnum:]_/:$+@")
1540           start prefix)
1541       (if (looking-at (format "[%s]" filename-chars))
1542           (progn
1543             (skip-chars-backward filename-chars)
1544             (setq start (point)
1545                   prefix
1546                   ;; This is something to do with ange-ftp filenames.
1547                   ;; It convert foo@bar to /foo@bar.
1548                   ;; But when does the former occur in dired buffers?
1549                   (and (string-match
1550                         "^\\w+@"
1551                         (buffer-substring start (line-end-position)))
1552                        "/"))
1553             (if (string-match "[/~]" (char-to-string (preceding-char)))
1554                 (setq start (1- start)))
1555             (skip-chars-forward filename-chars))
1556         (error "No file found around point!"))
1557       ;; Return string.
1558       (expand-file-name (concat prefix (buffer-substring start (point)))))))
1559
1560 (defun dired-x-read-filename-at-point (prompt)
1561   "Return filename prompting with PROMPT with completion.
1562 If `current-prefix-arg' is non-nil, uses name at point as guess."
1563   (if current-prefix-arg
1564       (let ((guess (dired-filename-at-point)))
1565         (read-file-name prompt
1566                         (file-name-directory guess)
1567                         guess
1568                         nil (file-name-nondirectory guess)))
1569     (read-file-name prompt default-directory)))
1570
1571 (define-obsolete-function-alias 'read-filename-at-point
1572   'dired-x-read-filename-at-point "24.1") ; is this even needed?
1573 \f
1574 ;;; BUG REPORTS
1575
1576 (define-obsolete-function-alias 'dired-x-submit-report 'report-emacs-bug "24.1")
1577
1578 \f
1579 ;; As Barry Warsaw would say: "This might be useful..."
1580 (provide 'dired-x)
1581
1582 ;; Local Variables:
1583 ;; byte-compile-dynamic: t
1584 ;; generated-autoload-file: "dired.el"
1585 ;; End:
1586
1587 ;;; dired-x.el ends here