lisp/dired-x.el

   1 ;;; dired-x.el --- extra Dired functionality
   2
   3 ;; Copyright (C) 1993, 1994, 1997, 2001, 2002, 2003, 2004, 2005, 2006,
   4 ;;   2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   7 ;;      Lawrence R. Dodd <dodd@roebling.poly.edu>
   8 ;; Maintainer: Romain Francoise <rfrancoise@gnu.org>
   9 ;; Keywords: dired extensions files
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; This is Sebastian Kremer's excellent dired-x.el (Dired Extra), version
  29 ;; 1.191, hacked up for GNU Emacs.  Redundant or conflicting material has
  30 ;; been removed or renamed in order to work properly with dired of GNU
  31 ;; Emacs.  All suggestions or comments are most welcomed.
  32
  33 ;;
  34 ;; Please, PLEASE, *PLEASE* see the info pages.
  35 ;;
  36
  37 ;; BUGS: Type M-x dired-x-submit-report and a report will be generated.
  38
  39 ;; INSTALLATION: In your ~/.emacs,
  40 ;;
  41 ;; (add-hook 'dired-load-hook
  42 ;;           (function (lambda ()
  43 ;;                       (load "dired-x")
  44 ;;                       ;; Set global variables here.  For example:
  45 ;;                       ;; (setq dired-guess-shell-gnutar "gtar")
  46 ;;                       )))
  47 ;; (add-hook 'dired-mode-hook
  48 ;;           (function (lambda ()
  49 ;;                       ;; Set buffer-local variables here.  For example:
  50 ;;                       ;; (dired-omit-mode 1)
  51 ;;                       )))
  52 ;;
  53 ;; At load time dired-x.el will install itself, redefine some functions, and
  54 ;; bind some dired keys.  *Please* see the info pages for more details.
  55
  56 ;; *Please* see the info pages for more details.
  57
  58 ;; User defined variables:
  59 ;;
  60 ;;      dired-bind-vm
  61 ;;      dired-vm-read-only-folders
  62 ;;      dired-bind-jump
  63 ;;      dired-bind-info
  64 ;;      dired-bind-man
  65 ;;      dired-x-hands-off-my-keys
  66 ;;      dired-find-subdir
  67 ;;      dired-enable-local-variables
  68 ;;      dired-local-variables-file
  69 ;;      dired-guess-shell-gnutar
  70 ;;      dired-guess-shell-gzip-quiet
  71 ;;      dired-guess-shell-znew-switches
  72 ;;      dired-guess-shell-alist-user
  73 ;;      dired-clean-up-buffers-too
  74 ;;      dired-omit-mode
  75 ;;      dired-omit-files
  76 ;;      dired-omit-extensions
  77 ;;      dired-omit-size-limit
  78 ;;
  79 ;; To find out more about these variables, load this file, put your cursor at
  80 ;; the end of any of the variable names, and hit C-h v [RET].  *Please* see
  81 ;; the info pages for more details.
  82
  83 ;; When loaded this code redefines the following functions of GNU Emacs
  84 ;;
  85 ;;   Function                         Found in this file of GNU Emacs
  86 ;;   --------                         -------------------------------
  87 ;;   dired-clean-up-after-deletion    ../lisp/dired.el
  88 ;;   dired-find-buffer-nocreate       ../lisp/dired.el
  89 ;;   dired-initial-position           ../lisp/dired.el
  90 ;;
  91 ;;   dired-add-entry                  ../lisp/dired-aux.el
  92 ;;   dired-read-shell-command         ../lisp/dired-aux.el
  93
  94 \f
  95 ;;; Code:
  96
  97 ;; LOAD.
  98
  99 ;; This is a no-op if dired-x is being loaded via `dired-load-hook'.  It is
 100 ;; here in case the user has autoloaded dired-x via the dired-jump key binding
 101 ;; (instead of autoloading to dired as is suggested in the info-pages).
 102
 103 (require 'dired)
 104
 105 ;; We will redefine some functions and also need some macros so we need to
 106 ;; load dired stuff of GNU Emacs.
 107
 108 (require 'dired-aux)
 109
 110 (defvar vm-folder-directory)
 111 (eval-when-compile (require 'man))
 112
 113 ;;; User-defined variables.
 114
 115 (defgroup dired-x nil
 116   "Extended directory editing (dired-x)."
 117   :group 'dired)
 118
 119 (defgroup dired-keys nil
 120   "Dired keys customizations."
 121   :prefix "dired-"
 122   :group 'dired-x)
 123
 124 (defcustom dired-bind-vm nil
 125   "Non-nil means \"V\" runs `dired-vm', otherwise \"V\" runs `dired-rmail'.
 126
 127 RMAIL files in the old Babyl format (used before before Emacs 23.1)
 128 contain \"-*- rmail -*-\" at the top, so `dired-find-file'
 129 will run `rmail' on these files.  New RMAIL files use the standard
 130 mbox format, and so cannot be distinguished in this way."
 131   :type 'boolean
 132   :group 'dired-keys)
 133
 134 (defcustom dired-bind-jump t
 135   "Non-nil means bind `dired-jump' to C-x C-j, otherwise do not."
 136   :type 'boolean
 137   :group 'dired-keys)
 138
 139 (defcustom dired-bind-man t
 140   "Non-nil means bind `dired-man' to \"N\" in dired-mode, otherwise do not."
 141   :type 'boolean
 142   :group 'dired-keys)
 143
 144 (defcustom dired-bind-info t
 145   "Non-nil means bind `dired-info' to \"I\" in dired-mode, otherwise do not."
 146   :type 'boolean
 147   :group 'dired-keys)
 148
 149 (defcustom dired-vm-read-only-folders nil
 150   "If non-nil, \\[dired-vm] will visit all folders read-only.
 151 If neither nil nor t, e.g. the symbol `if-file-read-only', only
 152 files not writable by you are visited read-only.
 153
 154 Read-only folders only work in VM 5, not in VM 4."
 155   :type '(choice (const :tag "off" nil)
 156                  (const :tag "on" t)
 157                  (other :tag "non-writable only" if-file-read-only))
 158   :group 'dired-x)
 159
 160 (define-minor-mode dired-omit-mode
 161   "Toggle Dired-Omit mode.
 162 With numeric ARG, enable Dired-Omit mode if ARG is positive, disable
 163 otherwise.  Enabling and disabling is buffer-local.
 164 If enabled, \"uninteresting\" files are not listed.
 165 Uninteresting files are those whose filenames match regexp `dired-omit-files',
 166 plus those ending with extensions in `dired-omit-extensions'.
 167
 168 To enable omitting in every Dired buffer, you can put in your ~/.emacs
 169
 170   (add-hook 'dired-mode-hook (lambda () (dired-omit-mode 1)))
 171
 172 See Info node `(dired-x) Omitting Variables' for more information."
 173   :group 'dired-x
 174   (if dired-omit-mode
 175       ;; This will mention how many lines were omitted:
 176       (let ((dired-omit-size-limit nil)) (dired-omit-expunge))
 177     (revert-buffer)))
 178
 179 ;; For backward compatibility
 180 (define-obsolete-variable-alias 'dired-omit-files-p 'dired-omit-mode "22.1")
 181
 182 (defcustom dired-omit-files "^\\.?#\\|^\\.$\\|^\\.\\.$"
 183   "Filenames matching this regexp will not be displayed.
 184 This only has effect when `dired-omit-mode' is t.  See interactive function
 185 `dired-omit-mode' \(\\[dired-omit-mode]\) and variable
 186 `dired-omit-extensions'.  The default is to omit  `.', `..', auto-save
 187 files and lock files."
 188   :type 'regexp
 189   :group 'dired-x)
 190
 191 (defcustom dired-find-subdir nil           ; t is pretty near to DWIM...
 192   "If non-nil, Dired always finds a directory in a buffer of its own.
 193 If nil, Dired finds the directory as a subdirectory in some other buffer
 194 if it is present as one.
 195
 196 If there are several dired buffers for a directory, the most recently
 197 used is chosen.
 198
 199 Dired avoids switching to the current buffer, so that if you have
 200 a normal and a wildcard buffer for the same directory, \\[dired] will
 201 toggle between those two."
 202   :type 'boolean
 203   :group 'dired-x)
 204
 205 (defcustom dired-omit-size-limit 30000
 206   "Maximum size for the \"omitting\" feature.
 207 If nil, there is no maximum size."
 208   :type '(choice (const :tag "no maximum" nil) integer)
 209   :group 'dired-x)
 210
 211 (defcustom dired-enable-local-variables t
 212   "Control use of local-variables lists in Dired.
 213 The value can be t, nil or something else.
 214 A value of t means local-variables lists are obeyed;
 215 nil means they are ignored; anything else means query.
 216
 217 This temporarily overrides the value of `enable-local-variables' when
 218 listing a directory.  See also `dired-local-variables-file'."
 219   :type 'boolean
 220   :group 'dired-x)
 221
 222 (defcustom dired-guess-shell-gnutar (when (or (eq system-type 'gnu)
 223                                               (eq system-type 'gnu/linux))
 224                                       "tar")
 225   "If non-nil, name of GNU tar executable.
 226 \(E.g., \"tar\" or \"gtar\").  The `z' switch will be used with it for
 227 compressed or gzip'ed tar files.  If you don't have GNU tar, set this
 228 to nil: a pipe using `zcat' or `gunzip -c' will be used."
 229   :type '(choice (const :tag "Not GNU tar" nil)
 230                  (string :tag "Command name"))
 231   :group 'dired-x)
 232
 233 (defcustom dired-guess-shell-gzip-quiet t
 234   "Non-nil says pass -q to gzip overriding verbose GZIP environment."
 235   :type 'boolean
 236   :group 'dired-x)
 237
 238 (defcustom dired-guess-shell-znew-switches nil
 239   "If non-nil, then string of switches passed to `znew', example: \"-K\"."
 240   :type '(choice (const :tag "None" nil)
 241                  (string :tag "Switches"))
 242   :group 'dired-x)
 243
 244 (defcustom dired-clean-up-buffers-too t
 245   "Non-nil means offer to kill buffers visiting files and dirs deleted in Dired."
 246   :type 'boolean
 247   :group 'dired-x)
 248
 249 ;;; KEY BINDINGS.
 250
 251 (define-key dired-mode-map "\M-o" 'dired-omit-mode)
 252 (define-key dired-mode-map "*O" 'dired-mark-omitted)
 253 (define-key dired-mode-map "\M-(" 'dired-mark-sexp)
 254 (define-key dired-mode-map "*(" 'dired-mark-sexp)
 255 (define-key dired-mode-map "*." 'dired-mark-extension)
 256 (define-key dired-mode-map "\M-!" 'dired-smart-shell-command)
 257 (define-key dired-mode-map "w" 'dired-copy-filename-as-kill)
 258 (define-key dired-mode-map "\M-G" 'dired-goto-subdir)
 259 (define-key dired-mode-map "F" 'dired-do-find-marked-files)
 260 (define-key dired-mode-map "Y"  'dired-do-relsymlink)
 261 (define-key dired-mode-map "%Y" 'dired-do-relsymlink-regexp)
 262 (define-key dired-mode-map "V" 'dired-do-run-mail)
 263
 264 (if dired-bind-man
 265     (define-key dired-mode-map "N" 'dired-man))
 266
 267 (if dired-bind-info
 268     (define-key dired-mode-map "I" 'dired-info))
 269
 270 ;;; MENU BINDINGS
 271
 272 (let ((menu-bar (lookup-key dired-mode-map [menu-bar])))
 273   (let ((menu (lookup-key menu-bar [operate])))
 274     (define-key-after
 275       menu
 276       [find-files]
 277       '(menu-item
 278         "Find files"
 279         dired-do-find-marked-files
 280         :help "Find current or marked files")
 281       'delete)
 282     (define-key-after
 283       menu
 284       [relsymlink]
 285       '(menu-item
 286         "Relative symlink to..."
 287         dired-do-relsymlink
 288         :visible (fboundp 'make-symbolic-link)
 289         :help "Make relative symbolic links for current or marked files")
 290       'symlink))
 291   (let ((menu (lookup-key menu-bar [mark])))
 292     (define-key-after
 293       menu
 294       [flag-extension]
 295       '(menu-item
 296         "Flag extension..."
 297         dired-flag-extension
 298         :help "Flag files with a certain extension for deletion")
 299       'garbage-files)
 300     (define-key-after
 301       menu
 302       [mark-extension]
 303       '(menu-item
 304         "Mark extension..."
 305         dired-mark-extension
 306         :help "Mark files with a certain extension")
 307       'symlinks)
 308     (define-key-after
 309       menu
 310       [mark-omitted]
 311       '(menu-item
 312         "Mark omitted"
 313         dired-mark-omitted
 314         :help "Mark files matching `dired-omit-files' and `dired-omit-extensions'")
 315       'mark-extension))
 316   (let ((menu (lookup-key menu-bar [regexp])))
 317     (define-key-after
 318       menu
 319       [relsymlink-regexp]
 320       '(menu-item
 321         "Relative symlink..."
 322         dired-do-relsymlink-regexp
 323         :visible (fboundp 'make-symbolic-link)
 324         :help "Make relative symbolic links for files matching regexp")
 325       'symlink))
 326   (let ((menu (lookup-key menu-bar [immediate])))
 327     (define-key-after
 328       menu
 329       [omit-mode]
 330       '(menu-item
 331         "Omit mode" dired-omit-mode
 332         :button (:toggle . dired-omit-mode)
 333         :help "Enable or disable omitting \"uninteresting\" files")
 334       'dashes)))
 335
 336 ;;; GLOBAL BINDING.
 337 (if dired-bind-jump
 338     (progn
 339       (define-key global-map "\C-x\C-j" 'dired-jump)
 340       (define-key global-map "\C-x4\C-j" 'dired-jump-other-window)))
 341
 342 \f
 343 ;; Install into appropriate hooks.
 344
 345 (add-hook 'dired-mode-hook 'dired-extra-startup)
 346 (add-hook 'dired-after-readin-hook 'dired-omit-expunge)
 347
 348 (defun dired-extra-startup ()
 349   "Automatically put on `dired-mode-hook' to get extra Dired features:
 350 \\<dired-mode-map>
 351   \\[dired-do-run-mail]\t-- run mail on folder (see `dired-bind-vm')
 352   \\[dired-info]\t-- run info on file
 353   \\[dired-man]\t-- run man on file
 354   \\[dired-do-find-marked-files]\t-- visit all marked files simultaneously
 355   \\[dired-omit-mode]\t-- toggle omitting of files
 356   \\[dired-mark-sexp]\t-- mark by Lisp expression
 357   \\[dired-copy-filename-as-kill]\t-- copy the file or subdir names into the kill ring;
 358   \t   you can feed it to other commands using \\[yank]
 359
 360 For more features, see variables
 361
 362   `dired-bind-vm'
 363   `dired-bind-jump'
 364   `dired-bind-info'
 365   `dired-bind-man'
 366   `dired-vm-read-only-folders'
 367   `dired-omit-mode'
 368   `dired-omit-files'
 369   `dired-omit-extensions'
 370   `dired-omit-size-limit'
 371   `dired-find-subdir'
 372   `dired-enable-local-variables'
 373   `dired-local-variables-file'
 374   `dired-guess-shell-gnutar'
 375   `dired-guess-shell-gzip-quiet'
 376   `dired-guess-shell-znew-switches'
 377   `dired-guess-shell-alist-user'
 378   `dired-clean-up-buffers-too'
 379
 380 See also functions
 381
 382   `dired-flag-extension'
 383   `dired-virtual'
 384   `dired-jump'
 385   `dired-man'
 386   `dired-vm'
 387   `dired-rmail'
 388   `dired-info'
 389   `dired-do-find-marked-files'"
 390   (interactive)
 391
 392   ;; These must be done in each new dired buffer.
 393   (dired-hack-local-variables)
 394   (dired-omit-startup))
 395
 396 \f
 397 ;;; BUFFER CLEANING.
 398
 399 ;; REDEFINE.
 400 (defun dired-clean-up-after-deletion (fn)
 401   "Clean up after a deleted file or directory FN.
 402 Remove expanded subdir of deleted dir, if any."
 403   (save-excursion (and (cdr dired-subdir-alist)
 404                        (dired-goto-subdir fn)
 405                        (dired-kill-subdir)))
 406
 407   ;; Offer to kill buffer of deleted file FN.
 408   (if dired-clean-up-buffers-too
 409       (progn
 410         (let ((buf (get-file-buffer fn)))
 411           (and buf
 412                (funcall (function y-or-n-p)
 413                         (format "Kill buffer of %s, too? "
 414                                 (file-name-nondirectory fn)))
 415                (save-excursion ; you never know where kill-buffer leaves you
 416                  (kill-buffer buf))))
 417         (let ((buf-list (dired-buffers-for-dir (expand-file-name fn)))
 418               (buf nil))
 419           (and buf-list
 420                (y-or-n-p (format "Kill dired buffer%s of %s, too? "
 421                                  (dired-plural-s (length buf-list))
 422                                  (file-name-nondirectory fn)))
 423                (while buf-list
 424                  (save-excursion (kill-buffer (car buf-list)))
 425                  (setq buf-list (cdr buf-list)))))))
 426   ;; Anything else?
 427   )
 428
 429 \f
 430 ;;; EXTENSION MARKING FUNCTIONS.
 431
 432 ;; Mark files with some extension.
 433 (defun dired-mark-extension (extension &optional marker-char)
 434   "Mark all files with a certain EXTENSION for use in later commands.
 435 A `.' is *not* automatically prepended to the string entered."
 436   ;; EXTENSION may also be a list of extensions instead of a single one.
 437   ;; Optional MARKER-CHAR is marker to use.
 438   (interactive "sMarking extension: \nP")
 439   (or (listp extension)
 440       (setq extension (list extension)))
 441   (dired-mark-files-regexp
 442    (concat ".";; don't match names with nothing but an extension
 443            "\\("
 444            (mapconcat 'regexp-quote extension "\\|")
 445            "\\)$")
 446    marker-char))
 447
 448 (defun dired-flag-extension (extension)
 449   "In dired, flag all files with a certain EXTENSION for deletion.
 450 A `.' is *not* automatically prepended to the string entered."
 451   (interactive "sFlagging extension: ")
 452   (dired-mark-extension extension dired-del-marker))
 453
 454 ;; Define some unpopular file extensions.  Used for cleaning and omitting.
 455
 456 (defvar dired-patch-unclean-extensions
 457   '(".rej" ".orig")
 458   "List of extensions of dispensable files created by the `patch' program.")
 459
 460 (defvar dired-tex-unclean-extensions
 461   '(".toc" ".log" ".aux");; these are already in completion-ignored-extensions
 462   "List of extensions of dispensable files created by TeX.")
 463
 464 (defvar dired-latex-unclean-extensions
 465   '(".idx" ".lof" ".lot" ".glo")
 466   "List of extensions of dispensable files created by LaTeX.")
 467
 468 (defvar dired-bibtex-unclean-extensions
 469   '(".blg" ".bbl")
 470   "List of extensions of dispensable files created by BibTeX.")
 471
 472 (defvar dired-texinfo-unclean-extensions
 473   '(".cp" ".cps" ".fn" ".fns" ".ky" ".kys" ".pg" ".pgs"
 474     ".tp" ".tps" ".vr" ".vrs")
 475   "List of extensions of dispensable files created by texinfo.")
 476
 477 (defun dired-clean-patch ()
 478   "Flag dispensable files created by patch for deletion.
 479 See variable `dired-patch-unclean-extensions'."
 480   (interactive)
 481   (dired-flag-extension dired-patch-unclean-extensions))
 482
 483 (defun dired-clean-tex ()
 484   "Flag dispensable files created by [La]TeX etc. for deletion.
 485 See variables `dired-tex-unclean-extensions',
 486 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 487 `dired-texinfo-unclean-extensions'."
 488   (interactive)
 489   (dired-flag-extension (append dired-texinfo-unclean-extensions
 490                                 dired-latex-unclean-extensions
 491                                 dired-bibtex-unclean-extensions
 492                                 dired-tex-unclean-extensions)))
 493
 494 (defun dired-very-clean-tex ()
 495   "Flag dispensable files created by [La]TeX *and* \".dvi\" for deletion.
 496 See variables `dired-texinfo-unclean-extensions',
 497 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 498 `dired-texinfo-unclean-extensions'."
 499   (interactive)
 500   (dired-flag-extension (append dired-texinfo-unclean-extensions
 501                                 dired-latex-unclean-extensions
 502                                 dired-bibtex-unclean-extensions
 503                                 dired-tex-unclean-extensions
 504                                 (list ".dvi"))))
 505 \f
 506 ;;; JUMP.
 507
 508 ;;;###autoload
 509 (defun dired-jump (&optional other-window)
 510   "Jump to dired buffer corresponding to current buffer.
 511 If in a file, dired the current directory and move to file's line.
 512 If in Dired already, pop up a level and goto old directory's line.
 513 In case the proper dired file line cannot be found, refresh the dired
 514 buffer and try again."
 515   (interactive "P")
 516   (let* ((file buffer-file-name)
 517          (dir (if file (file-name-directory file) default-directory)))
 518     (if (eq major-mode 'dired-mode)
 519         (progn
 520           (setq dir (dired-current-directory))
 521           (dired-up-directory other-window)
 522           (or (dired-goto-file dir)
 523               ;; refresh and try again
 524               (progn
 525                 (dired-insert-subdir (file-name-directory dir))
 526                 (dired-goto-file dir))))
 527       (if other-window
 528           (dired-other-window dir)
 529         (dired dir))
 530       (if file
 531           (or (dired-goto-file file)
 532               ;; refresh and try again
 533               (progn
 534                 (dired-insert-subdir (file-name-directory file))
 535                 (dired-goto-file file))
 536               ;; Toggle omitting, if it is on, and try again.
 537               (if dired-omit-mode
 538                   (progn
 539                     (dired-omit-mode)
 540                     (dired-goto-file file))))))))
 541
 542 (defun dired-jump-other-window ()
 543   "Like \\[dired-jump] (`dired-jump') but in other window."
 544   (interactive)
 545   (dired-jump t))
 546 \f
 547 ;;; OMITTING.
 548
 549 ;; Enhanced omitting of lines from directory listings.
 550 ;; Marked files are never omitted.
 551
 552 ;; should probably get rid of this and always use 'no-dir.
 553 ;; sk 28-Aug-1991 09:37
 554 (defvar dired-omit-localp 'no-dir
 555   "The LOCALP argument `dired-omit-expunge' passes to `dired-get-filename'.
 556 If it is `no-dir', omitting is much faster, but you can only match
 557 against the non-directory part of the file name.  Set it to nil if you
 558 need to match the entire file name.")
 559
 560 ;; \017=^O for Omit - other packages can chose other control characters.
 561 (defvar dired-omit-marker-char ?\017
 562   "Temporary marker used by Dired-Omit.
 563 Should never be used as marker by the user or other packages.")
 564
 565 (defun dired-omit-startup ()
 566   (or (assq 'dired-omit-mode minor-mode-alist)
 567       (setq minor-mode-alist
 568             (append '((dired-omit-mode
 569                        (:eval (if (eq major-mode 'dired-mode)
 570                                   " Omit" ""))))
 571                     minor-mode-alist))))
 572
 573 (defun dired-mark-omitted ()
 574   "Mark files matching `dired-omit-files' and `dired-omit-extensions'."
 575   (interactive)
 576   (let ((dired-omit-mode nil)) (revert-buffer)) ;; Show omitted files
 577   (dired-mark-unmarked-files (dired-omit-regexp) nil nil dired-omit-localp))
 578
 579 (defvar dired-omit-extensions
 580   (append completion-ignored-extensions
 581           dired-latex-unclean-extensions
 582           dired-bibtex-unclean-extensions
 583           dired-texinfo-unclean-extensions)
 584   "If non-nil, a list of extensions \(strings\) to omit from Dired listings.
 585 Defaults to elements of `completion-ignored-extensions',
 586 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions', and
 587 `dired-texinfo-unclean-extensions'.
 588
 589 See interactive function `dired-omit-mode' \(\\[dired-omit-mode]\) and
 590 variables `dired-omit-mode' and `dired-omit-files'.")
 591
 592 (defun dired-omit-expunge (&optional regexp)
 593   "Erases all unmarked files matching REGEXP.
 594 Does nothing if global variable `dired-omit-mode' is nil, or if called
 595   non-interactively and buffer is bigger than `dired-omit-size-limit'.
 596 If REGEXP is nil or not specified, uses `dired-omit-files', and also omits
 597   filenames ending in `dired-omit-extensions'.
 598 If REGEXP is the empty string, this function is a no-op.
 599
 600 This functions works by temporarily binding `dired-marker-char' to
 601 `dired-omit-marker-char' and calling `dired-do-kill-lines'."
 602   (interactive "sOmit files (regexp): ")
 603   (if (and dired-omit-mode
 604            (or (called-interactively-p 'interactive)
 605                (not dired-omit-size-limit)
 606                (< (buffer-size) dired-omit-size-limit)
 607                (progn
 608                  (message "Not omitting: directory larger than %d characters."
 609                           dired-omit-size-limit)
 610                  (setq dired-omit-mode nil)
 611                  nil)))
 612       (let ((omit-re (or regexp (dired-omit-regexp)))
 613             (old-modified-p (buffer-modified-p))
 614             count)
 615         (or (string= omit-re "")
 616             (let ((dired-marker-char dired-omit-marker-char))
 617               (message "Omitting...")
 618               (if (dired-mark-unmarked-files omit-re nil nil dired-omit-localp)
 619                   (progn
 620                     (setq count (dired-do-kill-lines nil "Omitted %d line%s."))
 621                     (force-mode-line-update))
 622                 (message "(Nothing to omit)"))))
 623         ;; Try to preserve modified state of buffer.  So `%*' doesn't appear
 624         ;; in mode-line of omitted buffers.
 625         (set-buffer-modified-p (and old-modified-p
 626                                     (save-excursion
 627                                       (goto-char (point-min))
 628                                       (re-search-forward dired-re-mark nil t))))
 629         count)))
 630
 631 (defun dired-omit-regexp ()
 632   (concat (if dired-omit-files (concat "\\(" dired-omit-files "\\)") "")
 633           (if (and dired-omit-files dired-omit-extensions) "\\|" "")
 634           (if dired-omit-extensions
 635               (concat ".";; a non-extension part should exist
 636                       "\\("
 637                       (mapconcat 'regexp-quote dired-omit-extensions "\\|")
 638                       "\\)$")
 639             "")))
 640
 641 ;; Returns t if any work was done, nil otherwise.
 642 (defun dired-mark-unmarked-files (regexp msg &optional unflag-p localp)
 643   "Mark unmarked files matching REGEXP, displaying MSG.
 644 REGEXP is matched against the entire file name.
 645 Does not re-mark files which already have a mark.
 646 With prefix argument, unflag all those files.
 647 Optional fourth argument LOCALP is as in `dired-get-filename'."
 648   (interactive "P")
 649   (let ((dired-marker-char (if unflag-p ?\s dired-marker-char)))
 650     (dired-mark-if
 651      (and
 652       ;; not already marked
 653       (looking-at " ")
 654       ;; uninteresting
 655       (let ((fn (dired-get-filename localp t)))
 656         (and fn (string-match regexp fn))))
 657      msg)))
 658
 659 ;; Compiler does not get fset.
 660 (declare-function dired-omit-old-add-entry "dired-x")
 661
 662 ;; REDEFINE.
 663 ;; Redefine dired-aux.el's version of `dired-add-entry'
 664 ;; Save old defun if not already done:
 665 (or (fboundp 'dired-omit-old-add-entry)
 666     (fset 'dired-omit-old-add-entry (symbol-function 'dired-add-entry)))
 667
 668 ;; REDEFINE.
 669 (defun dired-omit-new-add-entry (filename &optional marker-char relative)
 670   ;; This redefines dired-aux.el's dired-add-entry to avoid calling ls for
 671   ;; files that are going to be omitted anyway.
 672   (if dired-omit-mode
 673       ;; perhaps return t without calling ls
 674       (let ((omit-re (dired-omit-regexp)))
 675         (if (or (string= omit-re "")
 676                 (not
 677                  (string-match omit-re
 678                                (cond
 679                                 ((eq 'no-dir dired-omit-localp)
 680                                  filename)
 681                                 ((eq t dired-omit-localp)
 682                                  (dired-make-relative filename))
 683                                 (t
 684                                  (dired-make-absolute
 685                                   filename
 686                                   (file-name-directory filename)))))))
 687             ;; if it didn't match, go ahead and add the entry
 688             (dired-omit-old-add-entry filename marker-char relative)
 689           ;; dired-add-entry returns t for success, perhaps we should
 690           ;; return file-exists-p
 691           t))
 692     ;; omitting is not turned on at all
 693     (dired-omit-old-add-entry filename marker-char relative)))
 694
 695 ;; Redefine it.
 696 (fset 'dired-add-entry 'dired-omit-new-add-entry)
 697
 698 \f
 699 ;;; VIRTUAL DIRED MODE.
 700
 701 ;; For browsing `ls -lR' listings in a dired-like fashion.
 702
 703 (defalias 'virtual-dired 'dired-virtual)
 704 (defun dired-virtual (dirname &optional switches)
 705   "Put this buffer into Virtual Dired mode.
 706
 707 In Virtual Dired mode, all commands that do not actually consult the
 708 filesystem will work.
 709
 710 This is useful if you want to peruse and move around in an ls -lR
 711 output file, for example one you got from an ftp server.  With
 712 ange-ftp, you can even dired a directory containing an ls-lR file,
 713 visit that file and turn on virtual dired mode.  But don't try to save
 714 this file, as dired-virtual indents the listing and thus changes the
 715 buffer.
 716
 717 If you have save a Dired buffer in a file you can use \\[dired-virtual] to
 718 resume it in a later session.
 719
 720 Type \\<dired-mode-map>\\[revert-buffer] \
 721 in the Virtual Dired buffer and answer `y' to convert
 722 the virtual to a real dired buffer again.  You don't have to do this, though:
 723 you can relist single subdirs using \\[dired-do-redisplay]."
 724
 725   ;; DIRNAME is the top level directory of the buffer.  It will become
 726   ;; its `default-directory'.  If nil, the old value of
 727   ;; default-directory is used.
 728
 729   ;; Optional SWITCHES are the ls switches to use.
 730
 731   ;; Shell wildcards will be used if there already is a `wildcard'
 732   ;; line in the buffer (thus it is a saved Dired buffer), but there
 733   ;; is no other way to get wildcards.  Insert a `wildcard' line by
 734   ;; hand if you want them.
 735
 736   (interactive
 737    (list (read-string "Virtual Dired directory: " (dired-virtual-guess-dir))))
 738   (goto-char (point-min))
 739   (or (looking-at "  ")
 740       ;; if not already indented, do it now:
 741       (indent-region (point-min) (point-max) 2))
 742   (or dirname (setq dirname default-directory))
 743   (setq dirname (expand-file-name (file-name-as-directory dirname)))
 744   (setq default-directory dirname)      ; contains no wildcards
 745   (let ((wildcard (save-excursion
 746                     (goto-char (point-min))
 747                     (forward-line 1)
 748                     (and (looking-at "^  wildcard ")
 749                          (buffer-substring (match-end 0)
 750                                            (progn (end-of-line) (point)))))))
 751   (if wildcard
 752         (setq dirname (expand-file-name wildcard default-directory))))
 753   ;; If raw ls listing (not a saved old dired buffer), give it a
 754   ;; decent subdir headerline:
 755   (goto-char (point-min))
 756   (or (looking-at dired-subdir-regexp)
 757       (insert "  "
 758               (directory-file-name (file-name-directory default-directory))
 759               ":\n"))
 760   (dired-mode dirname (or switches dired-listing-switches))
 761   (setq mode-name "Virtual Dired"
 762         revert-buffer-function 'dired-virtual-revert)
 763   (set (make-local-variable 'dired-subdir-alist) nil)
 764   (dired-build-subdir-alist)
 765   (goto-char (point-min))
 766   (dired-initial-position dirname))
 767
 768 (defun dired-virtual-guess-dir ()
 769   "Guess and return appropriate working directory of this buffer.
 770 The buffer is assumed to be in Dired or ls -lR format.  The guess is
 771 based upon buffer contents.  If nothing could be guessed, returns
 772 nil."
 773
 774   (let ((regexp "^\\(  \\)?\\([^ \n\r]*\\)\\(:\\)[\n\r]")
 775         (subexpr 2))
 776     (goto-char (point-min))
 777     (cond ((looking-at regexp)
 778            ;; If a saved dired buffer, look to which dir and
 779            ;; perhaps wildcard it belongs:
 780            (let ((dir (buffer-substring (match-beginning subexpr)
 781                                         (match-end subexpr))))
 782              (file-name-as-directory dir)))
 783           ;; Else no match for headerline found.  It's a raw ls listing.
 784           ;; In raw ls listings the directory does not have a headerline
 785           ;; try parent of first subdir, if any
 786           ((re-search-forward regexp nil t)
 787            (file-name-directory
 788             (directory-file-name
 789              (file-name-as-directory
 790               (buffer-substring (match-beginning subexpr)
 791                                 (match-end subexpr))))))
 792           (t                            ; if all else fails
 793            nil))))
 794
 795
 796 (defun dired-virtual-revert (&optional arg noconfirm)
 797   (if (not
 798        (y-or-n-p "Cannot revert a Virtual Dired buffer - switch to Real Dired mode? "))
 799       (error "Cannot revert a Virtual Dired buffer")
 800     (setq mode-name "Dired"
 801           revert-buffer-function 'dired-revert)
 802     (revert-buffer)))
 803
 804 ;; A zero-arg version of dired-virtual.
 805 (defun dired-virtual-mode ()
 806   "Put current buffer into Virtual Dired mode (see `dired-virtual').
 807 Useful on `magic-mode-alist' with the regexp
 808
 809   \"^  \\\\(/[^ /]+\\\\)+/?:$\"
 810
 811 to put saved dired buffers automatically into Virtual Dired mode.
 812
 813 Also useful for `auto-mode-alist' like this:
 814
 815   (add-to-list 'auto-mode-alist
 816                '(\"[^/]\\\\.dired\\\\'\" . dired-virtual-mode))"
 817   (interactive)
 818   (dired-virtual (dired-virtual-guess-dir)))
 819
 820 \f
 821 ;;; SMART SHELL.
 822
 823 ;; An Emacs buffer can have but one working directory, stored in the
 824 ;; buffer-local variable `default-directory'.  A Dired buffer may have
 825 ;; several subdirectories inserted, but still has but one working directory:
 826 ;; that of the top level Dired directory in that buffer.  For some commands
 827 ;; it is appropriate that they use the current Dired directory instead of
 828 ;; `default-directory', e.g., `find-file' and `compile'.  This is a general
 829 ;; mechanism is provided for special handling of the working directory in
 830 ;; special major modes.
 831
 832 ;; It's easier to add to this alist than redefine function
 833 ;; default-directory while keeping the old information.
 834 (defconst default-directory-alist
 835   '((dired-mode . (if (fboundp 'dired-current-directory)
 836                       (dired-current-directory)
 837                     default-directory)))
 838   "Alist of major modes and their opinion on `default-directory'.
 839 This is given as a Lisp expression to evaluate.  A resulting value of
 840 nil is ignored in favor of `default-directory'.")
 841
 842 (defun dired-default-directory ()
 843   "Usage like variable `default-directory'.
 844 Knows about the special cases in variable `default-directory-alist'."
 845   (or (eval (cdr (assq major-mode default-directory-alist)))
 846       default-directory))
 847
 848 (defun dired-smart-shell-command (command &optional output-buffer error-buffer)
 849   "Like function `shell-command', but in the current Virtual Dired directory."
 850   (interactive
 851    (list
 852     (read-shell-command "Shell command: " nil nil
 853                         (cond
 854                          (buffer-file-name (file-relative-name buffer-file-name))
 855                          ((eq major-mode 'dired-mode) (dired-get-filename t t))))
 856     current-prefix-arg
 857     shell-command-default-error-buffer))
 858   (let ((default-directory (dired-default-directory)))
 859     (shell-command command output-buffer error-buffer)))
 860
 861 \f
 862 ;;; LOCAL VARIABLES FOR DIRED BUFFERS.
 863
 864 ;; Brief Description:
 865 ;;;
 866 ;; * `dired-extra-startup' is part of the `dired-mode-hook'.
 867 ;;;
 868 ;; * `dired-extra-startup' calls `dired-hack-local-variables'
 869 ;;;
 870 ;; * `dired-hack-local-variables' checks the value of
 871 ;;;   `dired-local-variables-file'
 872 ;;;
 873 ;; * Check if `dired-local-variables-file' is a non-nil string and is a
 874 ;;;   filename found in the directory of the Dired Buffer being created.
 875 ;;;
 876 ;; * If `dired-local-variables-file' satisfies the above, then temporarily
 877 ;;;   include it in the Dired Buffer at the bottom.
 878 ;;;
 879 ;; * Set `enable-local-variables' temporarily to the user variable
 880 ;;;   `dired-enable-local-variables' and run `hack-local-variables' on the
 881 ;;;   Dired Buffer.
 882
 883 (defvar dired-local-variables-file (convert-standard-filename ".dired")
 884   "Filename, as string, containing local dired buffer variables to be hacked.
 885 If this file found in current directory, then it will be inserted into dired
 886 buffer and `hack-local-variables' will be run.  See Info node
 887 `(emacs)File Variables' for more information on local variables.
 888 See also `dired-enable-local-variables'.")
 889
 890 (defun dired-hack-local-variables ()
 891   "Evaluate local variables in `dired-local-variables-file' for dired buffer."
 892   (if (and dired-local-variables-file
 893            (stringp dired-local-variables-file)
 894            (file-exists-p dired-local-variables-file))
 895       (let ((opoint (point-max))
 896             buffer-read-only
 897             ;; In case user has `enable-local-variables' set to nil we
 898             ;; override it locally with dired's variable.
 899             (enable-local-variables dired-enable-local-variables))
 900         ;; Insert 'em.
 901         (save-excursion
 902           (goto-char opoint)
 903           (insert "\^L\n")
 904           (insert-file-contents dired-local-variables-file))
 905         ;; Hack 'em.
 906         (let ((buffer-file-name dired-local-variables-file))
 907           (hack-local-variables))
 908         ;; Make sure that the modeline shows the proper information.
 909         (dired-sort-set-modeline)
 910         ;; Delete this stuff: `eobp' is used to find last subdir by dired.el.
 911         (delete-region opoint (point-max)))))
 912
 913 (defun dired-omit-here-always ()
 914   "Create `dired-local-variables-file' for omitting and reverts directory.
 915 Sets `dired-omit-mode' to t in a local variables file that is readable by
 916 dired."
 917   (interactive)
 918   (if (file-exists-p dired-local-variables-file)
 919       (message "File `./%s' already exists." dired-local-variables-file)
 920
 921     ;; Create `dired-local-variables-file'.
 922     (with-current-buffer (get-buffer-create " *dot-dired*")
 923       (erase-buffer)
 924       (insert "Local Variables:\ndired-omit-mode: t\nEnd:\n")
 925       (write-file dired-local-variables-file)
 926       (kill-buffer (current-buffer)))
 927
 928     ;; Run extra-hooks and revert directory.
 929     (dired-extra-startup)
 930     (dired-revert)))
 931
 932 \f
 933 ;;; GUESS SHELL COMMAND.
 934
 935 ;; Brief Description:
 936 ;;;
 937 ;; `dired-do-shell-command' is bound to `!' by dired.el.
 938 ;;;
 939 ;; * Redefine `dired-read-shell-command' so it calls
 940 ;;;   `dired-guess-shell-command'.
 941 ;;;
 942 ;; * `dired-guess-shell-command' calls `dired-guess-default' with list of
 943 ;;;    marked files.
 944 ;;;
 945 ;; * Parse `dired-guess-shell-alist-user' and
 946 ;;;   `dired-guess-shell-alist-default' (in that order) for the first REGEXP
 947 ;;;   that matches the first file in the file list.
 948 ;;;
 949 ;; * If the REGEXP matches all the entries of the file list then evaluate
 950 ;;;   COMMAND, which is either a string or a Lisp expression returning a
 951 ;;;   string.  COMMAND may be a list of commands.
 952 ;;;
 953 ;; * Return this command to `dired-guess-shell-command' which prompts user
 954 ;;;   with it.  The list of commands is put into the list of default values.
 955 ;;;   If a command is used successfully then it is stored permanently in
 956 ;;;   `dired-shell-command-history'.
 957
 958 ;; Guess what shell command to apply to a file.
 959 (defvar dired-shell-command-history nil
 960   "History list for commands that read dired-shell commands.")
 961
 962 ;; Default list of shell commands.
 963
 964 ;; NOTE: Use `gunzip -c' instead of `zcat' on `.gz' files.  Some do not
 965 ;; install GNU zip's version of zcat.
 966
 967 (defvar dired-guess-shell-alist-default
 968   (list
 969    (list "\\.tar$"
 970          '(if dired-guess-shell-gnutar
 971               (concat dired-guess-shell-gnutar " xvf")
 972             "tar xvf")
 973          ;; Extract files into a separate subdirectory
 974          '(if dired-guess-shell-gnutar
 975               (concat "mkdir " (file-name-sans-extension file)
 976                       "; " dired-guess-shell-gnutar " -C "
 977                       (file-name-sans-extension file) " -xvf")
 978             (concat "mkdir " (file-name-sans-extension file)
 979                     "; tar -C " (file-name-sans-extension file) " -xvf"))
 980          ;; List archive contents.
 981          '(if dired-guess-shell-gnutar
 982               (concat dired-guess-shell-gnutar " tvf")
 983             "tar tvf"))
 984
 985    ;; REGEXPS for compressed archives must come before the .Z rule to
 986    ;; be recognized:
 987    (list "\\.tar\\.Z$"
 988          ;; Untar it.
 989          '(if dired-guess-shell-gnutar
 990               (concat dired-guess-shell-gnutar " zxvf")
 991             (concat "zcat * | tar xvf -"))
 992          ;; Optional conversion to gzip format.
 993          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 994                   " " dired-guess-shell-znew-switches))
 995
 996    ;; gzip'ed archives
 997    (list "\\.t\\(ar\\.\\)?gz$"
 998          '(if dired-guess-shell-gnutar
 999               (concat dired-guess-shell-gnutar " zxvf")
1000             (concat "gunzip -qc * | tar xvf -"))
1001          ;; Extract files into a separate subdirectory
1002          '(if dired-guess-shell-gnutar
1003               (concat "mkdir " (file-name-sans-extension file)
1004                       "; " dired-guess-shell-gnutar " -C "
1005                       (file-name-sans-extension file) " -zxvf")
1006             (concat "mkdir " (file-name-sans-extension file)
1007                     "; gunzip -qc * | tar -C "
1008                     (file-name-sans-extension file) " -xvf -"))
1009          ;; Optional decompression.
1010          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q" ""))
1011          ;; List archive contents.
1012          '(if dired-guess-shell-gnutar
1013               (concat dired-guess-shell-gnutar " ztvf")
1014             (concat "gunzip -qc * | tar tvf -")))
1015
1016    ;; bzip2'ed archives
1017    (list "\\.t\\(ar\\.bz2\\|bz\\)$"
1018          "bunzip2 -c * | tar xvf -"
1019          ;; Extract files into a separate subdirectory
1020          '(concat "mkdir " (file-name-sans-extension file)
1021                   "; bunzip2 -c * | tar -C "
1022                   (file-name-sans-extension file) " -xvf -")
1023          ;; Optional decompression.
1024          "bunzip2")
1025
1026    ;; xz'ed archives
1027    (list "\\.t\\(ar\\.\\)?xz$"
1028          "unxz -c * | tar xvf -"
1029          ;; Extract files into a separate subdirectory
1030          '(concat "mkdir " (file-name-sans-extension file)
1031                   "; unxz -c * | tar -C "
1032                   (file-name-sans-extension file) " -xvf -")
1033          ;; Optional decompression.
1034          "unxz")
1035
1036    '("\\.shar\\.Z$" "zcat * | unshar")
1037    '("\\.shar\\.g?z$" "gunzip -qc * | unshar")
1038
1039    '("\\.e?ps$" "ghostview" "xloadimage" "lpr")
1040    (list "\\.e?ps\\.g?z$" "gunzip -qc * | ghostview -"
1041          ;; Optional decompression.
1042          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1043    (list "\\.e?ps\\.Z$" "zcat * | ghostview -"
1044          ;; Optional conversion to gzip format.
1045          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1046                   " " dired-guess-shell-znew-switches))
1047
1048    '("\\.patch$" "cat * | patch")
1049    (list "\\.patch\\.g?z$" "gunzip -qc * | patch"
1050          ;; Optional decompression.
1051          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1052    (list "\\.patch\\.Z$" "zcat * | patch"
1053          ;; Optional conversion to gzip format.
1054          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1055                   " " dired-guess-shell-znew-switches))
1056
1057    ;; The following four extensions are useful with dired-man ("N" key)
1058    (list "\\.\\(?:[0-9]\\|man\\)$" '(progn (require 'man)
1059                                            (if (Man-support-local-filenames)
1060                                                "man -l"
1061                                              "cat * | tbl | nroff -man -h")))
1062    (list "\\.\\(?:[0-9]\\|man\\)\\.g?z$" '(progn (require 'man)
1063                                                  (if (Man-support-local-filenames)
1064                                                      "man -l"
1065                                                    "gunzip -qc * | tbl | nroff -man -h"))
1066          ;; Optional decompression.
1067          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1068    (list "\\.[0-9]\\.Z$" '(progn (require 'man)
1069                                  (if (Man-support-local-filenames)
1070                                      "man -l"
1071                                    "zcat * | tbl | nroff -man -h"))
1072          ;; Optional conversion to gzip format.
1073          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1074                   " " dired-guess-shell-znew-switches))
1075    '("\\.pod$" "perldoc" "pod2man * | nroff -man")
1076
1077    '("\\.dvi$" "xdvi" "dvips")          ; preview and printing
1078    '("\\.au$" "play")                   ; play Sun audiofiles
1079    '("\\.mpe?g$\\|\\.avi$" "xine -p")
1080    '("\\.ogg$" "ogg123")
1081    '("\\.mp3$" "mpg123")
1082    '("\\.wav$" "play")
1083    '("\\.uu$" "uudecode")               ; for uudecoded files
1084    '("\\.hqx$" "mcvert")
1085    '("\\.sh$" "sh")                     ; execute shell scripts
1086    '("\\.xbm$" "bitmap")                ; view X11 bitmaps
1087    '("\\.gp$" "gnuplot")
1088    '("\\.p[bgpn]m$" "xloadimage")
1089    '("\\.gif$" "xloadimage")            ; view gif pictures
1090    '("\\.tif$" "xloadimage")
1091    '("\\.png$" "display")               ; xloadimage 4.1 doesn't grok PNG
1092    '("\\.jpe?g$" "xloadimage")
1093    '("\\.fig$" "xfig")                  ; edit fig pictures
1094    '("\\.out$" "xgraph")                ; for plotting purposes.
1095    '("\\.tex$" "latex" "tex")
1096    '("\\.texi\\(nfo\\)?$" "makeinfo" "texi2dvi")
1097    '("\\.pdf$" "xpdf")
1098    '("\\.doc$" "antiword" "strings")
1099    '("\\.rpm$" "rpm -qilp" "rpm -ivh")
1100    '("\\.dia$" "dia")
1101    '("\\.mgp$" "mgp")
1102
1103    ;; Some other popular archivers.
1104    (list "\\.zip$" "unzip" "unzip -l"
1105          ;; Extract files into a separate subdirectory
1106          '(concat "unzip" (if dired-guess-shell-gzip-quiet " -q")
1107                   " -d " (file-name-sans-extension file)))
1108    '("\\.zoo$" "zoo x//")
1109    '("\\.lzh$" "lharc x")
1110    '("\\.arc$" "arc x")
1111    '("\\.shar$" "unshar")
1112
1113    ;; Compression.
1114    (list "\\.g?z$" '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1115    (list "\\.dz$" "dictunzip")
1116    (list "\\.bz2$" "bunzip2")
1117    (list "\\.xz$" "unxz")
1118    (list "\\.Z$" "uncompress"
1119          ;; Optional conversion to gzip format.
1120          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1121                   " " dired-guess-shell-znew-switches))
1122
1123    '("\\.sign?$" "gpg --verify"))
1124
1125   "Default alist used for shell command guessing.
1126 See `dired-guess-shell-alist-user'.")
1127
1128 (defcustom dired-guess-shell-alist-user nil
1129   "User-defined alist of rules for suggested commands.
1130 These rules take precedence over the predefined rules in the variable
1131 `dired-guess-shell-alist-default' (to which they are prepended).
1132
1133 Each element of this list looks like
1134
1135     \(REGEXP COMMAND...\)
1136
1137 where each COMMAND can either be a string or a Lisp expression that evaluates
1138 to a string.  If several COMMANDs are given, the first one will be the default
1139 and the rest will be added temporarily to the history and can be retrieved
1140 with \\[previous-history-element] (M-p) .
1141
1142 The variable `dired-guess-shell-case-fold-search' controls whether
1143 REGEXP is matched case-sensitively.
1144
1145 You can set this variable in your ~/.emacs.  For example, to add rules for
1146 `.foo' and `.bar' files, write
1147
1148  \(setq dired-guess-shell-alist-user
1149        (list (list \"\\\\.foo\\\\'\" \"FOO-COMMAND\");; fixed rule
1150               ;; possibly more rules ...
1151               (list \"\\\\.bar\\\\'\";; rule with condition test
1152                     '(if condition
1153                           \"BAR-COMMAND-1\"
1154                         \"BAR-COMMAND-2\")))\)"
1155   :group 'dired-x
1156   :type '(alist :key-type regexp :value-type (repeat sexp)))
1157
1158 (defcustom dired-guess-shell-case-fold-search t
1159   "If non-nil, `dired-guess-shell-alist-default' and
1160 `dired-guess-shell-alist-user' are matched case-insensitively."
1161   :group 'dired-x
1162   :type 'boolean)
1163
1164 (defun dired-guess-default (files)
1165   "Guess a shell commands for FILES.  Return command or list of commands.
1166 See `dired-guess-shell-alist-user'."
1167
1168   (let* ((case-fold-search dired-guess-shell-case-fold-search)
1169          ;; Prepend the user's alist to the default alist.
1170          (alist (append dired-guess-shell-alist-user
1171                         dired-guess-shell-alist-default))
1172          (file (car files))
1173          (flist (cdr files))
1174          elt regexp cmds)
1175
1176     ;; Find the first match in the alist for first file in FILES.
1177     (while alist
1178       (setq elt (car alist)
1179             regexp (car elt)
1180             alist (cdr alist))
1181       (if (string-match regexp file)
1182           (setq cmds (cdr elt)
1183                 alist nil)))
1184
1185     ;; If more than one file, see if all of FILES match regular expression.
1186     (while (and flist
1187                 (string-match regexp (car flist)))
1188       (setq flist (cdr flist)))
1189
1190     ;; If flist is still non-nil, then do not guess since this means that not
1191     ;; all the files in FILES were matched by the regexp.
1192     (setq cmds (and (not flist) cmds))
1193
1194     ;; Return commands or nil if flist is still non-nil.
1195     ;; Evaluate the commands in order that any logical testing will be done.
1196     (cond ((not (cdr cmds))
1197            (eval (car cmds))) ; single command
1198           (t
1199            (mapcar (function eval) cmds)))))
1200
1201 (defun dired-guess-shell-command (prompt files)
1202   "Ask user with PROMPT for a shell command, guessing a default from FILES."
1203   (let ((default (dired-guess-default files))
1204         default-list val)
1205     (if (null default)
1206         ;; Nothing to guess
1207         (read-shell-command prompt nil 'dired-shell-command-history)
1208       (if (listp default)
1209           ;; More than one guess
1210           (setq default-list default
1211                 default (car default)
1212                 prompt (concat
1213                         prompt
1214                         (format "{%d guesses} " (length default-list))))
1215         ;; Just one guess
1216         (setq default-list (list default)))
1217       ;; Put the first guess in the prompt but not in the initial value.
1218       (setq prompt (concat prompt (format "[%s] " default)))
1219       ;; All guesses can be retrieved with M-n
1220       (setq val (read-shell-command prompt nil
1221                                     'dired-shell-command-history
1222                                     default-list))
1223       ;; If we got a return, then return default.
1224       (if (equal val "") default val))))
1225
1226 ;; REDEFINE.
1227 ;; Redefine dired-aux.el's version:
1228 (defun dired-read-shell-command (prompt arg files)
1229   "Read a dired shell command prompting with PROMPT (using `read-shell-command').
1230 ARG is the prefix arg and may be used to indicate in the prompt which
1231 FILES are affected.
1232 This is an extra function so that you can redefine it."
1233   (minibuffer-with-setup-hook
1234       (lambda ()
1235         (set (make-local-variable 'minibuffer-default-add-function)
1236              'minibuffer-default-add-dired-shell-commands))
1237     (dired-mark-pop-up
1238      nil 'shell files
1239      'dired-guess-shell-command
1240      (format prompt (dired-mark-prompt arg files)) ; PROMPT
1241      files)))                                      ; FILES
1242
1243 \f
1244 ;;; RELATIVE SYMBOLIC LINKS.
1245
1246 (declare-function make-symbolic-link "fileio.c")
1247
1248 (defvar dired-keep-marker-relsymlink ?S
1249   "See variable `dired-keep-marker-move'.")
1250
1251 (defun dired-make-relative-symlink (file1 file2 &optional ok-if-already-exists)
1252   "Make a symbolic link (pointing to FILE1) in FILE2.
1253 The link is relative (if possible), for example
1254
1255     \"/vol/tex/bin/foo\" \"/vol/local/bin/foo\"
1256
1257 results in
1258
1259     \"../../tex/bin/foo\" \"/vol/local/bin/foo\""
1260   (interactive "FRelSymLink: \nFRelSymLink %s: \np")
1261   (let (name1 name2 len1 len2 (index 0) sub)
1262     (setq file1 (expand-file-name file1)
1263           file2 (expand-file-name file2)
1264           len1 (length file1)
1265           len2 (length file2))
1266     ;; Find common initial file name components:
1267     (let (next)
1268       (while (and (setq next (string-match "/" file1 index))
1269                   (setq next (1+ next))
1270                   (< next (min len1 len2))
1271                   ;; For the comparison, both substrings must end in
1272                   ;; `/', so NEXT is *one plus* the result of the
1273                   ;; string-match.
1274                   ;; E.g., consider the case of linking "/tmp/a/abc"
1275                   ;; to "/tmp/abc" erroneously giving "/tmp/a" instead
1276                   ;; of "/tmp/" as common initial component
1277                   (string-equal (substring file1 0 next)
1278                                 (substring file2 0 next)))
1279         (setq index next))
1280       (setq name2 file2
1281             sub (substring file1 0 index)
1282             name1 (substring file1 index)))
1283     (if (string-equal sub "/")
1284         ;; No common initial file name found
1285         (setq name1 file1)
1286       ;; Else they have a common parent directory
1287       (let ((tem (substring file2 index))
1288             (start 0)
1289             (count 0))
1290         ;; Count number of slashes we must compensate for ...
1291         (while (setq start (string-match "/" tem start))
1292           (setq count (1+ count)
1293                 start (1+ start)))
1294         ;; ... and prepend a "../" for each slash found:
1295         (while (> count 0)
1296           (setq count (1- count)
1297                 name1 (concat "../" name1)))))
1298     (make-symbolic-link
1299      (directory-file-name name1)        ; must not link to foo/
1300                                         ; (trailing slash!)
1301      name2 ok-if-already-exists)))
1302
1303 ;;;###autoload
1304 (defun dired-do-relsymlink (&optional arg)
1305    "Relative symlink all marked (or next ARG) files into a directory.
1306 Otherwise make a relative symbolic link to the current file.
1307 This creates relative symbolic links like
1308
1309     foo -> ../bar/foo
1310
1311 not absolute ones like
1312
1313     foo -> /ugly/file/name/that/may/change/any/day/bar/foo
1314
1315 For absolute symlinks, use \\[dired-do-symlink]."
1316   (interactive "P")
1317   (dired-do-create-files 'relsymlink (function dired-make-relative-symlink)
1318                            "RelSymLink" arg dired-keep-marker-relsymlink))
1319
1320 (defun dired-do-relsymlink-regexp (regexp newname &optional arg whole-name)
1321   "RelSymlink all marked files containing REGEXP to NEWNAME.
1322 See functions `dired-do-rename-regexp' and `dired-do-relsymlink'
1323 for more info."
1324   (interactive (dired-mark-read-regexp "RelSymLink"))
1325   (dired-do-create-files-regexp
1326    (function dired-make-relative-symlink)
1327    "RelSymLink" arg regexp newname whole-name dired-keep-marker-relsymlink))
1328
1329 \f
1330 ;;; VISIT ALL MARKED FILES SIMULTANEOUSLY.
1331
1332 ;; Brief Description:
1333 ;;;
1334 ;; `dired-do-find-marked-files' is bound to `F' by dired-x.el.
1335 ;;;
1336 ;; * Use `dired-get-marked-files' to collect the marked files in the current
1337 ;;;   Dired Buffer into a list of filenames `FILE-LIST'.
1338 ;;;
1339 ;; * Pass FILE-LIST to `dired-simultaneous-find-file' all with
1340 ;;;   `dired-do-find-marked-files''s prefix argument NOSELECT.
1341 ;;;
1342 ;; * `dired-simultaneous-find-file' runs through FILE-LIST decrementing the
1343 ;;;   list each time.
1344 ;;;
1345 ;; * If NOSELECT is non-nil then just run `find-file-noselect' on each
1346 ;;;   element of FILE-LIST.
1347 ;;;
1348 ;; * If NOSELECT is nil then calculate the `size' of the window for each file
1349 ;;;   by dividing the `window-height' by length of FILE-LIST.  Thus, `size' is
1350 ;;;   cognizant of the window-configuration.
1351 ;;;
1352 ;; * If `size' is too small abort, otherwise run `find-file' on each element
1353 ;;;   of FILE-LIST giving each a window of height `size'.
1354
1355 (defun dired-do-find-marked-files (&optional noselect)
1356   "Find all marked files displaying all of them simultaneously.
1357 With optional NOSELECT just find files but do not select them.
1358
1359 The current window is split across all files marked, as evenly as possible.
1360 Remaining lines go to bottom-most window.  The number of files that can be
1361 displayed this way is restricted by the height of the current window and
1362 `window-min-height'.
1363
1364 To keep dired buffer displayed, type \\[split-window-vertically] first.
1365 To display just marked files, type \\[delete-other-windows] first."
1366
1367   (interactive "P")
1368   (dired-simultaneous-find-file (dired-get-marked-files) noselect))
1369
1370 (defun dired-simultaneous-find-file (file-list noselect)
1371
1372   "Visit all files in FILE-LIST and display them simultaneously.
1373 The current window is split across all files in FILE-LIST, as evenly as
1374 possible.  Remaining lines go to the bottom-most window.  The number of
1375 files that can be displayed this way is restricted by the height of the
1376 current window and the variable `window-min-height'.  With non-nil
1377 NOSELECT the files are merely found but not selected."
1378
1379   ;; We don't make this function interactive because it is usually too clumsy
1380   ;; to specify FILE-LIST interactively unless via dired.
1381
1382   (let (size)
1383
1384     (if noselect
1385         ;; Do not select the buffer.
1386         (find-file-noselect (car file-list))
1387
1388       ;; We will have to select the buffer.  Calculate and check window size.
1389       (setq size (/ (window-height) (length file-list)))
1390       (or (<= window-min-height size)
1391           (error "Too many files to visit simultaneously.  Try C-u prefix"))
1392       (find-file (car file-list)))
1393
1394     ;; Decrement.
1395     (setq file-list (cdr file-list))
1396
1397     (while file-list
1398
1399       (if noselect
1400           ;; Do not select the buffer.
1401           (find-file-noselect (car file-list))
1402
1403         ;; Vertically split off a window of desired size.  Upper window will
1404         ;; have SIZE lines.  Select lower (larger) window.  We split it again.
1405         (select-window (split-window nil size))
1406         (find-file (car file-list)))
1407
1408       ;; Decrement.
1409       (setq file-list (cdr file-list)))))
1410
1411 \f
1412 ;;; MISCELLANEOUS COMMANDS.
1413
1414 ;; Run man on files.
1415
1416 (defun dired-man ()
1417   "Run man on this file.  Display old buffer if buffer name matches filename.
1418 Uses `man.el' of \\[manual-entry] fame."
1419   (interactive)
1420   (require 'man)
1421   (let* ((file (dired-get-filename))
1422          (manual-program (replace-regexp-in-string "\\*" "%s"
1423                           (dired-guess-shell-command
1424                            "Man command: " (list file)))))
1425     (Man-getpage-in-background file)))
1426
1427 ;; Run Info on files.
1428
1429 (defun dired-info ()
1430   "Run info on this file."
1431   (interactive)
1432   (info (dired-get-filename)))
1433
1434 ;; Run mail on mail folders.
1435
1436 ;; Avoid compiler warning.
1437 (eval-when-compile
1438   (when (not (fboundp 'vm-visit-folder))
1439     (defun vm-visit-folder (file &optional arg)
1440       nil)))
1441
1442 (defun dired-vm (&optional read-only)
1443   "Run VM on this file.
1444 With prefix arg, visit folder read-only (this requires at least VM 5).
1445 See also variable `dired-vm-read-only-folders'."
1446   (interactive "P")
1447   (let ((dir (dired-current-directory))
1448         (fil (dired-get-filename)))
1449     ;; take care to supply 2nd arg only if requested - may still run VM 4!
1450     (cond (read-only (vm-visit-folder fil t))
1451           ((eq t dired-vm-read-only-folders) (vm-visit-folder fil t))
1452           ((null dired-vm-read-only-folders) (vm-visit-folder fil))
1453           (t (vm-visit-folder fil (not (file-writable-p fil)))))
1454     ;; so that pressing `v' inside VM does prompt within current directory:
1455     (set (make-local-variable 'vm-folder-directory) dir)))
1456
1457 (defun dired-rmail ()
1458   "Run RMAIL on this file."
1459   (interactive)
1460   (rmail (dired-get-filename)))
1461
1462 (defun dired-do-run-mail ()
1463   "If `dired-bind-vm' is t, then function `dired-vm', otherwise `dired-rmail'."
1464   (interactive)
1465   (if dired-bind-vm
1466       ;; Read mail folder using vm.
1467       (dired-vm)
1468     ;; Read mail folder using rmail.
1469     (dired-rmail)))
1470
1471 \f
1472 ;;; MISCELLANEOUS INTERNAL FUNCTIONS.
1473
1474 (declare-function dired-old-find-buffer-nocreate "dired-x")
1475
1476 (or (fboundp 'dired-old-find-buffer-nocreate)
1477     (fset 'dired-old-find-buffer-nocreate
1478           (symbol-function 'dired-find-buffer-nocreate)))
1479
1480 ;; REDEFINE.
1481 ;; Redefines dired.el's version of `dired-find-buffer-nocreate'
1482 (defun dired-find-buffer-nocreate (dirname &optional mode)
1483   (if (and dired-find-subdir
1484            ;; don't try to find a wildcard as a subdirectory
1485            (string-equal dirname (file-name-directory dirname)))
1486       (let* ((cur-buf (current-buffer))
1487              (buffers (nreverse
1488                        (dired-buffers-for-dir (expand-file-name dirname))))
1489              (cur-buf-matches (and (memq cur-buf buffers)
1490                                    ;; wildcards must match, too:
1491                                    (equal dired-directory dirname))))
1492         ;; We don't want to switch to the same buffer---
1493         (setq buffers (delq cur-buf buffers));;need setq with delq
1494         (or (car (sort buffers (function dired-buffer-more-recently-used-p)))
1495             ;; ---unless it's the only possibility:
1496             (and cur-buf-matches cur-buf)))
1497     (dired-old-find-buffer-nocreate dirname mode)))
1498
1499 ;; This should be a builtin
1500 (defun dired-buffer-more-recently-used-p (buffer1 buffer2)
1501   "Return t if BUFFER1 is more recently used than BUFFER2."
1502   (if (equal buffer1 buffer2)
1503       nil
1504     (let ((more-recent nil)
1505           (list (buffer-list)))
1506       (while (and list
1507                   (not (setq more-recent (equal buffer1 (car list))))
1508                   (not (equal buffer2 (car list))))
1509         (setq list (cdr list)))
1510       more-recent)))
1511
1512 ;; Same thing as `dired-buffers-for-dir' of dired.el? - lrd 11/23/93
1513 ;; (defun dired-buffers-for-dir-exact (dir)
1514 ;; ;; Return a list of buffers that dired DIR (a directory or wildcard)
1515 ;; ;; at top level, or as subdirectory.
1516 ;; ;; Top level matches must match the wildcard part too, if any.
1517 ;; ;; The list is in reverse order of buffer creation, most recent last.
1518 ;; ;; As a side effect, killed dired buffers for DIR are removed from
1519 ;; ;; dired-buffers.
1520 ;;   (let ((alist dired-buffers) result elt)
1521 ;;     (while alist
1522 ;;       (setq elt (car alist)
1523 ;;             alist (cdr alist))
1524 ;;       (let ((buf (cdr elt)))
1525 ;;         (if (buffer-name buf)
1526 ;;             ;; Top level must match exactly against dired-directory in
1527 ;;             ;; case one of them is a wildcard.
1528 ;;             (if (or (equal dir (with-current-buffer buf dired-directory))
1529 ;;                     (assoc dir (with-current-buffer buf dired-subdir-alist)))
1530 ;;                 (setq result (cons buf result)))
1531 ;;           ;; else buffer is killed - clean up:
1532 ;;           (setq dired-buffers (delq elt dired-buffers)))))
1533 ;;     result))
1534
1535 ;; REDEFINE.
1536 ;; Redefines dired.el's version of `dired-initial-position'
1537 (defun dired-initial-position (dirname)
1538   "Where point should go in a new listing of DIRNAME.
1539 Point assumed at beginning of new subdir line.
1540 You may redefine this function as you wish, e.g. like in `dired-x.el'."
1541   (end-of-line)
1542   (if dired-find-subdir (dired-goto-subdir dirname)) ; new
1543   (if dired-trivial-filenames (dired-goto-next-nontrivial-file)))
1544
1545 \f
1546 ;; Does anyone use this? - lrd 6/29/93.
1547 ;; Apparently people do use it. - lrd 12/22/97.
1548 (defun dired-mark-sexp (predicate &optional unflag-p)
1549   "Mark files for which PREDICATE returns non-nil.
1550 With a prefix arg, unflag those files instead.
1551
1552 PREDICATE is a lisp expression that can refer to the following symbols:
1553
1554     inode  [integer] the inode of the file (only for ls -i output)
1555     s      [integer] the size of the file for ls -s output
1556                      (usually in blocks or, with -k, in KByte)
1557     mode   [string]  file permission bits, e.g. \"-rw-r--r--\"
1558     nlink  [integer] number of links to file
1559     uid    [string]  owner
1560     gid    [string]  group  (If the gid is not displayed by ls,
1561                      this will still be set (to the same as uid))
1562     size   [integer] file size in bytes
1563     time   [string]  the time that ls displays, e.g. \"Feb 12 14:17\"
1564     name   [string]  the name of the file
1565     sym    [string]  if file is a symbolic link, the linked-to name, else \"\"
1566
1567 For example, use
1568
1569         (equal 0 size)
1570
1571 to mark all zero length files."
1572   ;; Using sym="" instead of nil avoids the trap of
1573   ;; (string-match "foo" sym) into which a user would soon fall.
1574   ;; Give `equal' instead of `=' in the example, as this works on
1575   ;; integers and strings.
1576   (interactive "xMark if (lisp expr): \nP")
1577   (message "%s" predicate)
1578   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char))
1579         inode s mode nlink uid gid size time name sym)
1580     (dired-mark-if
1581      (save-excursion
1582        (and
1583         ;; Sets vars
1584         ;;                inode s mode nlink uid gid size time name sym
1585
1586         ;; according to current file line.  Returns t for success, nil if
1587         ;; there is no file line.  Upon success, all variables are set, either
1588         ;; to nil or the appropriate value, so they need not be initialized.
1589         ;; Moves point within the current line.
1590         (if (dired-move-to-filename)
1591             (let (pos
1592                   (mode-len 10) ; length of mode string
1593                   ;; like in dired.el, but with subexpressions \1=inode, \2=s:
1594                   (dired-re-inode-size "\\s *\\([0-9]*\\)\\s *\\([0-9]*\\) ?"))
1595               (beginning-of-line)
1596               (forward-char 2)
1597               (if (looking-at dired-re-inode-size)
1598                   (progn
1599                     (goto-char (match-end 0))
1600                     (setq inode (string-to-number (buffer-substring (match-beginning 1)
1601                                                                     (match-end 1)))
1602                           s (string-to-number (buffer-substring (match-beginning 2)
1603                                                                 (match-end 2)))))
1604                 (setq inode nil
1605                       s nil))
1606               (setq mode (buffer-substring (point) (+ mode-len (point))))
1607               (forward-char mode-len)
1608               (setq nlink (read (current-buffer)))
1609               ;; Karsten Wenger <kw@cis.uni-muenchen.de> fixed uid.
1610               (setq uid (buffer-substring (+ (point) 1)
1611                                           (progn (forward-word 1) (point))))
1612               (re-search-forward directory-listing-before-filename-regexp)
1613               (goto-char (match-beginning 1))
1614               (forward-char -1)
1615               (setq size (string-to-number (buffer-substring (save-excursion
1616                                                                (backward-word 1)
1617                                                                (setq pos (point)))
1618                                                              (point))))
1619               (goto-char pos)
1620               (backward-word 1)
1621               ;; if no gid is displayed, gid will be set to uid
1622               ;; but user will then not reference it anyway in PREDICATE.
1623               (setq gid (buffer-substring (save-excursion
1624                                             (forward-word 1) (point))
1625                                           (point))
1626                     time (buffer-substring (match-beginning 1)
1627                                            (1- (dired-move-to-filename)))
1628                     name (buffer-substring (point)
1629                                            (or
1630                                             (dired-move-to-end-of-filename t)
1631                                             (point)))
1632                     sym  (progn
1633                            (if (looking-at " -> ")
1634                                (buffer-substring
1635                                 (progn (forward-char 4) (point))
1636                                 (progn (end-of-line) (point)))
1637                              "")))
1638               t)
1639           nil)
1640                       (eval predicate)))
1641      (format "'%s file" predicate))))
1642
1643 \f
1644 ;;; FIND FILE AT POINT.
1645
1646 (defvar dired-x-hands-off-my-keys t
1647   "*Non-nil means don't bind `dired-x-find-file' over `find-file' on keyboard.
1648 Similarly for `dired-x-find-file-other-window' over `find-file-other-window'.
1649 If you change this variable after `dired-x.el' is loaded then do
1650 \\[dired-x-bind-find-file].")
1651
1652 ;; Bind `dired-x-find-file{-other-window}' over wherever
1653 ;; `find-file{-other-window}' is bound?
1654 (defun dired-x-bind-find-file ()
1655   "Bind `dired-x-find-file' in place of `find-file' \(or reverse\).
1656 Similarly for `dired-x-find-file-other-window' and `find-file-other-window'.
1657 Binding direction based on `dired-x-hands-off-my-keys'.
1658 This function is part of `after-init-hook'."
1659   (interactive)
1660   (if (called-interactively-p 'interactive)
1661       (setq dired-x-hands-off-my-keys
1662             (not (y-or-n-p "Bind dired-x-find-file over find-file? "))))
1663   (cond ((not dired-x-hands-off-my-keys)
1664          (substitute-key-definition 'find-file
1665                                     'dired-x-find-file
1666                                     (current-global-map))
1667          (substitute-key-definition 'find-file-other-window
1668                                     'dired-x-find-file-other-window
1669                                     (current-global-map)))
1670         (t
1671          (substitute-key-definition 'dired-x-find-file
1672                                     'find-file
1673                                     (current-global-map))
1674          (substitute-key-definition 'dired-x-find-file-other-window
1675                                     'find-file-other-window
1676                                     (current-global-map))))
1677   ;; Clear mini-buffer.
1678   (message nil))
1679
1680 ;; Now call it so binding is correct and put on `after-init-hook' in case
1681 ;; user changes binding.
1682 (dired-x-bind-find-file)
1683 (add-hook 'after-init-hook 'dired-x-bind-find-file)
1684
1685 (defun dired-x-find-file (filename)
1686   "Edit file FILENAME.
1687 May create a new window, or reuse an existing one.
1688 See the function `display-buffer'.
1689
1690 Identical to `find-file' except when called interactively, with a prefix arg
1691 \(e.g., \\[universal-argument]\), in which case it guesses filename near point.
1692 Useful for editing file mentioned in buffer you are viewing,
1693 or to test if that file exists.  Use minibuffer after snatching filename."
1694   (interactive (list (read-filename-at-point "Find file: ")))
1695   (find-file (expand-file-name filename)))
1696
1697 (defun dired-x-find-file-other-window (filename)
1698   "Edit file FILENAME, in another window.
1699 May create a new window, or reuse an existing one.
1700 See the function `display-buffer'.
1701
1702 Identical to `find-file-other-window' except when called interactively, with
1703 a prefix arg \(e.g., \\[universal-argument]\), in which case it guesses filename near point.
1704 Useful for editing file mentioned in buffer you are viewing,
1705 or to test if that file exists.  Use minibuffer after snatching filename."
1706   (interactive (list (read-filename-at-point "Find file: ")))
1707   (find-file-other-window (expand-file-name filename)))
1708
1709 ;;; Internal functions.
1710
1711 ;; Fixme: This should probably use `thing-at-point'.  -- fx
1712 (defun dired-filename-at-point ()
1713   "Get the filename closest to point, but do not change position.
1714 Has a preference for looking backward when not directly on a symbol.
1715 Not perfect - point must be in middle of or end of filename."
1716
1717   (let ((filename-chars "-.[:alnum:]_/:$+@")
1718         start end filename prefix)
1719
1720     (save-excursion
1721       ;; First see if just past a filename.
1722       (if (not (eobp))
1723           (if (looking-at "[] \t\n[{}()]") ; whitespace or some parens
1724               (progn
1725                 (skip-chars-backward " \n\t\r({[]})")
1726                 (if (not (bobp))
1727                     (backward-char 1)))))
1728
1729       (if (string-match (concat "[" filename-chars "]")
1730                         (char-to-string (following-char)))
1731           (progn
1732             (if (re-search-backward (concat "[^" filename-chars "]") nil t)
1733                 (forward-char)
1734               (goto-char (point-min)))
1735             (setq start (point))
1736             (setq prefix
1737                   (and (string-match
1738                         "^\\w+@"
1739                         (buffer-substring start (line-beginning-position)))
1740                        "/"))
1741             (goto-char start)
1742             (if (string-match "[/~]" (char-to-string (preceding-char)))
1743                 (setq start (1- start)))
1744             (re-search-forward (concat "\\=[" filename-chars "]*") nil t))
1745
1746         (error "No file found around point!"))
1747
1748       ;; Return string.
1749       (expand-file-name (concat prefix (buffer-substring start (point)))))))
1750
1751 (defun read-filename-at-point (prompt)
1752   "Return filename prompting with PROMPT with completion.
1753 If `current-prefix-arg' is non-nil, uses name at point as guess."
1754   (if current-prefix-arg
1755       (let ((guess (dired-filename-at-point)))
1756         (read-file-name prompt
1757                         (file-name-directory guess)
1758                         guess
1759                         nil (file-name-nondirectory guess)))
1760     (read-file-name prompt default-directory)))
1761 \f
1762 ;;; BUG REPORTS
1763
1764 ;; Fixme: get rid of this later.
1765
1766 ;; This section is provided for reports.  It uses Barry A. Warsaw's
1767 ;; reporter.el which is bundled with GNU Emacs v19.
1768
1769 (defconst dired-x-help-address "bug-gnu-emacs@gnu.org"
1770   "Address(es) accepting submission of reports on dired-x.el.")
1771
1772 (defconst dired-x-variable-list
1773   (list
1774    'dired-bind-vm
1775    'dired-vm-read-only-folders
1776    'dired-bind-jump
1777    'dired-bind-info
1778    'dired-bind-man
1779    'dired-find-subdir
1780    'dired-enable-local-variables
1781    'dired-local-variables-file
1782    'dired-guess-shell-gnutar
1783    'dired-guess-shell-gzip-quiet
1784    'dired-guess-shell-znew-switches
1785    'dired-guess-shell-alist-user
1786    'dired-clean-up-buffers-too
1787    'dired-omit-mode
1788    'dired-omit-files
1789    'dired-omit-extensions
1790    )
1791   "List of variables to be appended to reports sent by `dired-x-submit-report'.")
1792
1793 (defun dired-x-submit-report ()
1794   "Submit via `reporter.el' a bug report on program.
1795 Send report on `dired-x-file' version `dired-x-version', to
1796 `dired-x-maintainer' at address `dired-x-help-address' listing
1797 variables `dired-x-variable-list' in the message."
1798   (interactive)
1799
1800   (reporter-submit-bug-report
1801    dired-x-help-address                 ; address
1802    "dired-x"                            ; pkgname
1803    dired-x-variable-list                ; varlist
1804    nil nil                              ; pre-/post-hooks
1805    ""))
1806
1807 \f
1808 ;; As Barry Warsaw would say: "This might be useful..."
1809 (provide 'dired-x)
1810
1811 ;; Local Variables:
1812 ;; byte-compile-dynamic: t
1813 ;; generated-autoload-file: "dired.el"
1814 ;; End:
1815
1816 ;; arch-tag: 71a43ba2-7a00-4793-a028-0613dd7765ae
1817 ;;; dired-x.el ends here