lisp/ibuf-macs.el

   1 ;;; ibuf-macs.el --- macros for ibuffer  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2000-2017 Free Software Foundation, Inc.
   4
   5 ;; Author: Colin Walters <walters@verbum.org>
   6 ;; Maintainer: John Paul Wallington <jpw@gnu.org>
   7 ;; Created: 6 Dec 2001
   8 ;; Keywords: buffer, convenience
   9 ;; Package: ibuffer
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl-lib))
  31
  32 ;; From Paul Graham's "ANSI Common Lisp", adapted for Emacs Lisp here.
  33 (defmacro ibuffer-aif (test true-body &rest false-body)
  34   "Evaluate TRUE-BODY or FALSE-BODY depending on value of TEST.
  35 If TEST returns non-nil, bind `it' to the value, and evaluate
  36 TRUE-BODY.  Otherwise, evaluate forms in FALSE-BODY as if in `progn'.
  37 Compare with `if'."
  38   (declare (indent 2))
  39   (let ((sym (make-symbol "ibuffer-aif-sym")))
  40     `(let ((,sym ,test))
  41        (if ,sym
  42            (let ((it ,sym))
  43              ,true-body)
  44          (progn
  45            ,@false-body)))))
  46
  47 (defmacro ibuffer-awhen (test &rest body)
  48   "Evaluate BODY if TEST returns non-nil.
  49 During evaluation of body, bind `it' to the value returned by TEST."
  50   (declare (indent 1))
  51   `(ibuffer-aif ,test
  52        (progn ,@body)
  53      nil))
  54
  55 (defmacro ibuffer-save-marks (&rest body)
  56   "Save the marked status of the buffers and execute BODY; restore marks."
  57   (declare (indent 0))
  58   (let ((bufsym (make-symbol "bufsym")))
  59     `(let ((,bufsym (current-buffer))
  60            (ibuffer-save-marks-tmp-mark-list (ibuffer-current-state-list)))
  61        (unwind-protect
  62            (progn
  63              (save-excursion
  64                ,@body))
  65          (with-current-buffer ,bufsym
  66            (ibuffer-redisplay-engine
  67             ;; Get rid of dead buffers
  68             (delq nil
  69                   (mapcar #'(lambda (e) (when (buffer-live-p (car e))
  70                                           e))
  71                           ibuffer-save-marks-tmp-mark-list)))
  72            (ibuffer-redisplay t))))))
  73
  74 ;;;###autoload
  75 (cl-defmacro define-ibuffer-column (symbol (&key name inline props summarizer
  76                                                header-mouse-map) &rest body)
  77   "Define a column SYMBOL for use with `ibuffer-formats'.
  78
  79 BODY will be called with `buffer' bound to the buffer object, and
  80 `mark' bound to the current mark on the buffer.  The original ibuffer
  81 buffer will be bound to `ibuffer-buf'.
  82
  83 If NAME is given, it will be used as a title for the column.
  84 Otherwise, the title will default to a capitalized version of the
  85 SYMBOL's name.  PROPS is a plist of additional properties to add to
  86 the text, such as `mouse-face'.  And SUMMARIZER, if given, is a
  87 function which will be passed a list of all the strings in its column;
  88 it should return a string to display at the bottom.
  89
  90 If HEADER-MOUSE-MAP is given, it will be used as a keymap for the
  91 title of the column.
  92
  93 Note that this macro expands into a `defun' for a function named
  94 ibuffer-make-column-NAME.  If INLINE is non-nil, then the form will be
  95 inlined into the compiled format versions.  This means that if you
  96 change its definition, you should explicitly call
  97 `ibuffer-recompile-formats'.
  98
  99 \(fn SYMBOL (&key NAME INLINE PROPS SUMMARIZER) &rest BODY)"
 100   (declare (indent defun))
 101   (let* ((sym (intern (concat "ibuffer-make-column-"
 102                               (symbol-name symbol))))
 103          (bod-1 `(with-current-buffer buffer
 104                    ,@body))
 105          (bod (if props
 106                   `(propertize
 107                     ,bod-1
 108                     ,@props)
 109                 bod-1)))
 110     `(progn
 111        ,(if inline
 112             `(push '(,sym ,bod) ibuffer-inline-columns)
 113           `(defun ,sym (buffer mark)
 114              (ignore mark)            ;Silence byte-compiler if mark is unused.
 115              ,bod))
 116        (put (quote ,sym) 'ibuffer-column-name
 117             ,(if (stringp name)
 118                  name
 119                (capitalize (symbol-name symbol))))
 120        ,(if header-mouse-map `(put (quote ,sym) 'header-mouse-map ,header-mouse-map))
 121        ,(if summarizer
 122             ;; Store the name of the summarizing function.
 123             `(put (quote ,sym) 'ibuffer-column-summarizer
 124                   (quote ,summarizer)))
 125        ,(if summarizer
 126             ;; This will store the actual values of the column
 127             ;; summary.
 128             `(put (quote ,sym) 'ibuffer-column-summary nil))
 129        :autoload-end)))
 130
 131 ;;;###autoload
 132 (cl-defmacro define-ibuffer-sorter (name documentation
 133                                        (&key
 134                                         description)
 135                                        &rest body)
 136   "Define a method of sorting named NAME.
 137 DOCUMENTATION is the documentation of the function, which will be called
 138 `ibuffer-do-sort-by-NAME'.
 139 DESCRIPTION is a short string describing the sorting method.
 140
 141 For sorting, the forms in BODY will be evaluated with `a' bound to one
 142 buffer object, and `b' bound to another.  BODY should return a non-nil
 143 value if and only if `a' is \"less than\" `b'.
 144
 145 \(fn NAME DOCUMENTATION (&key DESCRIPTION) &rest BODY)"
 146   (declare (indent 1) (doc-string 2))
 147   `(progn
 148      (defun ,(intern (concat "ibuffer-do-sort-by-" (symbol-name name))) ()
 149        ,(or documentation "No :documentation specified for this sorting method.")
 150        (interactive)
 151        (setq ibuffer-sorting-mode ',name)
 152        (when (eq ibuffer-sorting-mode ibuffer-last-sorting-mode)
 153          (setq ibuffer-sorting-reversep (not ibuffer-sorting-reversep)))
 154        (ibuffer-redisplay t)
 155        (setq ibuffer-last-sorting-mode ',name))
 156      (push (list ',name ,description
 157                  #'(lambda (a b)
 158                      ,@body))
 159            ibuffer-sorting-functions-alist)
 160      :autoload-end))
 161
 162 ;;;###autoload
 163 (cl-defmacro define-ibuffer-op (op args
 164                                  documentation
 165                                  (&key
 166                                   interactive
 167                                   mark
 168                                   modifier-p
 169                                   dangerous
 170                                   (opstring "operated on")
 171                                   (active-opstring "Operate on")
 172                                   complex)
 173                                  &rest body)
 174   "Generate a function which operates on a buffer.
 175 OP becomes the name of the function; if it doesn't begin with
 176 `ibuffer-do-', then that is prepended to it.
 177 When an operation is performed, this function will be called once for
 178 each marked buffer, with that buffer current.
 179
 180 ARGS becomes the formal parameters of the function.
 181 DOCUMENTATION becomes the docstring of the function.
 182 INTERACTIVE becomes the interactive specification of the function.
 183 MARK describes which type of mark (:deletion, or nil) this operation
 184 uses.  :deletion means the function operates on buffers marked for
 185 deletion, otherwise it acts on normally marked buffers.
 186 MODIFIER-P describes how the function modifies buffers.  This is used
 187 to set the modification flag of the Ibuffer buffer itself.  Valid
 188 values are:
 189  nil - the function never modifiers buffers
 190  t - the function it always modifies buffers
 191  :maybe - attempt to discover this information by comparing the
 192   buffer's modification flag.
 193 DANGEROUS is a boolean which should be set if the user should be
 194 prompted before performing this operation.
 195 OPSTRING is a string which will be displayed to the user after the
 196 operation is complete, in the form:
 197  \"Operation complete; OPSTRING x buffers\"
 198 ACTIVE-OPSTRING is a string which will be displayed to the user in a
 199 confirmation message, in the form:
 200  \"Really ACTIVE-OPSTRING x buffers?\"
 201 COMPLEX means this function is special; if COMPLEX is nil BODY
 202 evaluates once for each marked buffer, MBUF, with MBUF current
 203 and saving the point.  If COMPLEX is non-nil, BODY evaluates
 204 without requiring MBUF current.
 205 BODY define the operation; they are forms to evaluate per each
 206 marked buffer.  BODY is evaluated with `buf' bound to the
 207 buffer object.
 208
 209 \(fn OP ARGS DOCUMENTATION (&key INTERACTIVE MARK MODIFIER-P DANGEROUS OPSTRING ACTIVE-OPSTRING COMPLEX) &rest BODY)"
 210   (declare (indent 2) (doc-string 3))
 211   `(progn
 212      (defun ,(intern (concat (if (string-match "^ibuffer-do" (symbol-name op))
 213                                  "" "ibuffer-do-")
 214                              (symbol-name op)))
 215        ,args
 216        ,(if (stringp documentation)
 217             documentation
 218           (format "%s marked buffers." active-opstring))
 219        ,(if (not (null interactive))
 220             `(interactive ,interactive)
 221           '(interactive))
 222        (cl-assert (derived-mode-p 'ibuffer-mode))
 223        (setq ibuffer-did-modification nil)
 224        (let ((marked-names  (,(pcase mark
 225                                 (:deletion
 226                                  'ibuffer-deletion-marked-buffer-names)
 227                                 (_
 228                                  'ibuffer-marked-buffer-names)))))
 229          (when (null marked-names)
 230            (setq marked-names (list (buffer-name (ibuffer-current-buffer))))
 231            (ibuffer-set-mark ,(pcase mark
 232                                 (:deletion
 233                                  'ibuffer-deletion-char)
 234                                 (_
 235                                  'ibuffer-marked-char))))
 236          ,(let* ((finish (append
 237                           '(progn)
 238                           (if (eq modifier-p t)
 239                               '((setq ibuffer-did-modification t))
 240                             ())
 241                           `((ibuffer-redisplay t)
 242                             (message ,(concat "Operation finished; " opstring " %s buffers") count))))
 243                  (inner-body (if complex
 244                                  `(progn ,@body)
 245                                `(progn
 246                                   (with-current-buffer buf
 247                                     (save-excursion
 248                                       ,@body))
 249                                   t)))
 250                  (body `(let ((count
 251                                (,(pcase mark
 252                                    (:deletion
 253                                     'ibuffer-map-deletion-lines)
 254                                    (_
 255                                     'ibuffer-map-marked-lines))
 256                                 #'(lambda (buf mark)
 257                                     ;; Silence warning for code that doesn't
 258                                     ;; use `mark'.
 259                                     (ignore mark)
 260                                     ,(if (eq modifier-p :maybe)
 261                                          `(let ((ibuffer-tmp-previous-buffer-modification
 262                                                  (buffer-modified-p buf)))
 263                                             (prog1 ,inner-body
 264                                               (when (not (eq ibuffer-tmp-previous-buffer-modification
 265                                                              (buffer-modified-p buf)))
 266                                                 (setq ibuffer-did-modification t))))
 267                                        inner-body)))))
 268                           ,finish)))
 269             (if dangerous
 270                 `(when (ibuffer-confirm-operation-on ,active-opstring marked-names)
 271                    ,body)
 272               body))))
 273      :autoload-end))
 274
 275 ;;;###autoload
 276 (cl-defmacro define-ibuffer-filter (name documentation
 277                                        (&key
 278                                         reader
 279                                         description)
 280                                        &rest body)
 281   "Define a filter named NAME.
 282 DOCUMENTATION is the documentation of the function.
 283 READER is a form which should read a qualifier from the user.
 284 DESCRIPTION is a short string describing the filter.
 285
 286 BODY should contain forms which will be evaluated to test whether or
 287 not a particular buffer should be displayed or not.  The forms in BODY
 288 will be evaluated with BUF bound to the buffer object, and QUALIFIER
 289 bound to the current value of the filter.
 290
 291 \(fn NAME DOCUMENTATION (&key READER DESCRIPTION) &rest BODY)"
 292   (declare (indent 2) (doc-string 2))
 293   (let ((fn-name (intern (concat "ibuffer-filter-by-" (symbol-name name)))))
 294     `(progn
 295        (defun ,fn-name (qualifier)
 296          ,(or documentation "This filter is not documented.")
 297          (interactive (list ,reader))
 298          (ibuffer-push-filter (cons ',name qualifier))
 299          (message "%s"
 300                   (format ,(concat (format "Filter by %s added: " description)
 301                                    " %s")
 302                           qualifier))
 303          (ibuffer-update nil t))
 304        (push (list ',name ,description
 305                    (lambda (buf qualifier)
 306                      (condition-case nil
 307                          (progn ,@body)
 308                        (error (ibuffer-pop-filter)
 309                               (when (eq ',name 'predicate)
 310                                 (error "Wrong filter predicate: %S"
 311                                        qualifier))))))
 312              ibuffer-filtering-alist)
 313        :autoload-end)))
 314
 315 (provide 'ibuf-macs)
 316
 317 ;;; ibuf-macs.el ends here