m4/stdint.m4

   1 # stdint.m4 serial 47
   2 dnl Copyright (C) 2001-2016 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Paul Eggert and Bruno Haible.
   8 dnl Test whether <stdint.h> is supported or must be substituted.
   9
  10 AC_DEFUN_ONCE([gl_STDINT_H],
  11 [
  12   AC_PREREQ([2.59])dnl
  13
  14   AC_REQUIRE([gl_LIMITS_H])
  15
  16   dnl Check for long long int and unsigned long long int.
  17   AC_REQUIRE([AC_TYPE_LONG_LONG_INT])
  18   if test $ac_cv_type_long_long_int = yes; then
  19     HAVE_LONG_LONG_INT=1
  20   else
  21     HAVE_LONG_LONG_INT=0
  22   fi
  23   AC_SUBST([HAVE_LONG_LONG_INT])
  24   AC_REQUIRE([AC_TYPE_UNSIGNED_LONG_LONG_INT])
  25   if test $ac_cv_type_unsigned_long_long_int = yes; then
  26     HAVE_UNSIGNED_LONG_LONG_INT=1
  27   else
  28     HAVE_UNSIGNED_LONG_LONG_INT=0
  29   fi
  30   AC_SUBST([HAVE_UNSIGNED_LONG_LONG_INT])
  31
  32   dnl Check for <wchar.h>, in the same way as gl_WCHAR_H does.
  33   AC_CHECK_HEADERS_ONCE([wchar.h])
  34   if test $ac_cv_header_wchar_h = yes; then
  35     HAVE_WCHAR_H=1
  36   else
  37     HAVE_WCHAR_H=0
  38   fi
  39   AC_SUBST([HAVE_WCHAR_H])
  40
  41   dnl Check for <inttypes.h>.
  42   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_inttypes_h.
  43   if test $ac_cv_header_inttypes_h = yes; then
  44     HAVE_INTTYPES_H=1
  45   else
  46     HAVE_INTTYPES_H=0
  47   fi
  48   AC_SUBST([HAVE_INTTYPES_H])
  49
  50   dnl Check for <sys/types.h>.
  51   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_sys_types_h.
  52   if test $ac_cv_header_sys_types_h = yes; then
  53     HAVE_SYS_TYPES_H=1
  54   else
  55     HAVE_SYS_TYPES_H=0
  56   fi
  57   AC_SUBST([HAVE_SYS_TYPES_H])
  58
  59   gl_CHECK_NEXT_HEADERS([stdint.h])
  60   if test $ac_cv_header_stdint_h = yes; then
  61     HAVE_STDINT_H=1
  62   else
  63     HAVE_STDINT_H=0
  64   fi
  65   AC_SUBST([HAVE_STDINT_H])
  66
  67   dnl Now see whether we need a substitute <stdint.h>.
  68   if test $ac_cv_header_stdint_h = yes; then
  69     AC_CACHE_CHECK([whether stdint.h conforms to C99],
  70       [gl_cv_header_working_stdint_h],
  71       [gl_cv_header_working_stdint_h=no
  72        AC_COMPILE_IFELSE([
  73          AC_LANG_PROGRAM([[
  74 #define _GL_JUST_INCLUDE_SYSTEM_STDINT_H 1 /* work if build isn't clean */
  75 #define __STDC_CONSTANT_MACROS 1
  76 #define __STDC_LIMIT_MACROS 1
  77 #include <stdint.h>
  78 /* Dragonfly defines WCHAR_MIN, WCHAR_MAX only in <wchar.h>.  */
  79 #if !(defined WCHAR_MIN && defined WCHAR_MAX)
  80 #error "WCHAR_MIN, WCHAR_MAX not defined in <stdint.h>"
  81 #endif
  82 ]
  83 gl_STDINT_INCLUDES
  84 [
  85 #ifdef INT8_MAX
  86 int8_t a1 = INT8_MAX;
  87 int8_t a1min = INT8_MIN;
  88 #endif
  89 #ifdef INT16_MAX
  90 int16_t a2 = INT16_MAX;
  91 int16_t a2min = INT16_MIN;
  92 #endif
  93 #ifdef INT32_MAX
  94 int32_t a3 = INT32_MAX;
  95 int32_t a3min = INT32_MIN;
  96 #endif
  97 #ifdef INT64_MAX
  98 int64_t a4 = INT64_MAX;
  99 int64_t a4min = INT64_MIN;
 100 #endif
 101 #ifdef UINT8_MAX
 102 uint8_t b1 = UINT8_MAX;
 103 #else
 104 typedef int b1[(unsigned char) -1 != 255 ? 1 : -1];
 105 #endif
 106 #ifdef UINT16_MAX
 107 uint16_t b2 = UINT16_MAX;
 108 #endif
 109 #ifdef UINT32_MAX
 110 uint32_t b3 = UINT32_MAX;
 111 #endif
 112 #ifdef UINT64_MAX
 113 uint64_t b4 = UINT64_MAX;
 114 #endif
 115 int_least8_t c1 = INT8_C (0x7f);
 116 int_least8_t c1max = INT_LEAST8_MAX;
 117 int_least8_t c1min = INT_LEAST8_MIN;
 118 int_least16_t c2 = INT16_C (0x7fff);
 119 int_least16_t c2max = INT_LEAST16_MAX;
 120 int_least16_t c2min = INT_LEAST16_MIN;
 121 int_least32_t c3 = INT32_C (0x7fffffff);
 122 int_least32_t c3max = INT_LEAST32_MAX;
 123 int_least32_t c3min = INT_LEAST32_MIN;
 124 int_least64_t c4 = INT64_C (0x7fffffffffffffff);
 125 int_least64_t c4max = INT_LEAST64_MAX;
 126 int_least64_t c4min = INT_LEAST64_MIN;
 127 uint_least8_t d1 = UINT8_C (0xff);
 128 uint_least8_t d1max = UINT_LEAST8_MAX;
 129 uint_least16_t d2 = UINT16_C (0xffff);
 130 uint_least16_t d2max = UINT_LEAST16_MAX;
 131 uint_least32_t d3 = UINT32_C (0xffffffff);
 132 uint_least32_t d3max = UINT_LEAST32_MAX;
 133 uint_least64_t d4 = UINT64_C (0xffffffffffffffff);
 134 uint_least64_t d4max = UINT_LEAST64_MAX;
 135 int_fast8_t e1 = INT_FAST8_MAX;
 136 int_fast8_t e1min = INT_FAST8_MIN;
 137 int_fast16_t e2 = INT_FAST16_MAX;
 138 int_fast16_t e2min = INT_FAST16_MIN;
 139 int_fast32_t e3 = INT_FAST32_MAX;
 140 int_fast32_t e3min = INT_FAST32_MIN;
 141 int_fast64_t e4 = INT_FAST64_MAX;
 142 int_fast64_t e4min = INT_FAST64_MIN;
 143 uint_fast8_t f1 = UINT_FAST8_MAX;
 144 uint_fast16_t f2 = UINT_FAST16_MAX;
 145 uint_fast32_t f3 = UINT_FAST32_MAX;
 146 uint_fast64_t f4 = UINT_FAST64_MAX;
 147 #ifdef INTPTR_MAX
 148 intptr_t g = INTPTR_MAX;
 149 intptr_t gmin = INTPTR_MIN;
 150 #endif
 151 #ifdef UINTPTR_MAX
 152 uintptr_t h = UINTPTR_MAX;
 153 #endif
 154 intmax_t i = INTMAX_MAX;
 155 uintmax_t j = UINTMAX_MAX;
 156
 157 #include <limits.h> /* for CHAR_BIT */
 158 #define TYPE_MINIMUM(t) \
 159   ((t) ((t) 0 < (t) -1 ? (t) 0 : ~ TYPE_MAXIMUM (t)))
 160 #define TYPE_MAXIMUM(t) \
 161   ((t) ((t) 0 < (t) -1 \
 162         ? (t) -1 \
 163         : ((((t) 1 << (sizeof (t) * CHAR_BIT - 2)) - 1) * 2 + 1)))
 164 struct s {
 165   int check_PTRDIFF:
 166       PTRDIFF_MIN == TYPE_MINIMUM (ptrdiff_t)
 167       && PTRDIFF_MAX == TYPE_MAXIMUM (ptrdiff_t)
 168       ? 1 : -1;
 169   /* Detect bug in FreeBSD 6.0 / ia64.  */
 170   int check_SIG_ATOMIC:
 171       SIG_ATOMIC_MIN == TYPE_MINIMUM (sig_atomic_t)
 172       && SIG_ATOMIC_MAX == TYPE_MAXIMUM (sig_atomic_t)
 173       ? 1 : -1;
 174   int check_SIZE: SIZE_MAX == TYPE_MAXIMUM (size_t) ? 1 : -1;
 175   int check_WCHAR:
 176       WCHAR_MIN == TYPE_MINIMUM (wchar_t)
 177       && WCHAR_MAX == TYPE_MAXIMUM (wchar_t)
 178       ? 1 : -1;
 179   /* Detect bug in mingw.  */
 180   int check_WINT:
 181       WINT_MIN == TYPE_MINIMUM (wint_t)
 182       && WINT_MAX == TYPE_MAXIMUM (wint_t)
 183       ? 1 : -1;
 184
 185   /* Detect bugs in glibc 2.4 and Solaris 10 stdint.h, among others.  */
 186   int check_UINT8_C:
 187         (-1 < UINT8_C (0)) == (-1 < (uint_least8_t) 0) ? 1 : -1;
 188   int check_UINT16_C:
 189         (-1 < UINT16_C (0)) == (-1 < (uint_least16_t) 0) ? 1 : -1;
 190
 191   /* Detect bugs in OpenBSD 3.9 stdint.h.  */
 192 #ifdef UINT8_MAX
 193   int check_uint8: (uint8_t) -1 == UINT8_MAX ? 1 : -1;
 194 #endif
 195 #ifdef UINT16_MAX
 196   int check_uint16: (uint16_t) -1 == UINT16_MAX ? 1 : -1;
 197 #endif
 198 #ifdef UINT32_MAX
 199   int check_uint32: (uint32_t) -1 == UINT32_MAX ? 1 : -1;
 200 #endif
 201 #ifdef UINT64_MAX
 202   int check_uint64: (uint64_t) -1 == UINT64_MAX ? 1 : -1;
 203 #endif
 204   int check_uint_least8: (uint_least8_t) -1 == UINT_LEAST8_MAX ? 1 : -1;
 205   int check_uint_least16: (uint_least16_t) -1 == UINT_LEAST16_MAX ? 1 : -1;
 206   int check_uint_least32: (uint_least32_t) -1 == UINT_LEAST32_MAX ? 1 : -1;
 207   int check_uint_least64: (uint_least64_t) -1 == UINT_LEAST64_MAX ? 1 : -1;
 208   int check_uint_fast8: (uint_fast8_t) -1 == UINT_FAST8_MAX ? 1 : -1;
 209   int check_uint_fast16: (uint_fast16_t) -1 == UINT_FAST16_MAX ? 1 : -1;
 210   int check_uint_fast32: (uint_fast32_t) -1 == UINT_FAST32_MAX ? 1 : -1;
 211   int check_uint_fast64: (uint_fast64_t) -1 == UINT_FAST64_MAX ? 1 : -1;
 212   int check_uintptr: (uintptr_t) -1 == UINTPTR_MAX ? 1 : -1;
 213   int check_uintmax: (uintmax_t) -1 == UINTMAX_MAX ? 1 : -1;
 214   int check_size: (size_t) -1 == SIZE_MAX ? 1 : -1;
 215 };
 216          ]])],
 217          [dnl Determine whether the various *_MIN, *_MAX macros are usable
 218           dnl in preprocessor expression. We could do it by compiling a test
 219           dnl program for each of these macros. It is faster to run a program
 220           dnl that inspects the macro expansion.
 221           dnl This detects a bug on HP-UX 11.23/ia64.
 222           AC_RUN_IFELSE([
 223             AC_LANG_PROGRAM([[
 224 #define _GL_JUST_INCLUDE_SYSTEM_STDINT_H 1 /* work if build isn't clean */
 225 #define __STDC_CONSTANT_MACROS 1
 226 #define __STDC_LIMIT_MACROS 1
 227 #include <stdint.h>
 228 ]
 229 gl_STDINT_INCLUDES
 230 [
 231 #include <stdio.h>
 232 #include <string.h>
 233 #define MVAL(macro) MVAL1(macro)
 234 #define MVAL1(expression) #expression
 235 static const char *macro_values[] =
 236   {
 237 #ifdef INT8_MAX
 238     MVAL (INT8_MAX),
 239 #endif
 240 #ifdef INT16_MAX
 241     MVAL (INT16_MAX),
 242 #endif
 243 #ifdef INT32_MAX
 244     MVAL (INT32_MAX),
 245 #endif
 246 #ifdef INT64_MAX
 247     MVAL (INT64_MAX),
 248 #endif
 249 #ifdef UINT8_MAX
 250     MVAL (UINT8_MAX),
 251 #endif
 252 #ifdef UINT16_MAX
 253     MVAL (UINT16_MAX),
 254 #endif
 255 #ifdef UINT32_MAX
 256     MVAL (UINT32_MAX),
 257 #endif
 258 #ifdef UINT64_MAX
 259     MVAL (UINT64_MAX),
 260 #endif
 261     NULL
 262   };
 263 ]], [[
 264   const char **mv;
 265   for (mv = macro_values; *mv != NULL; mv++)
 266     {
 267       const char *value = *mv;
 268       /* Test whether it looks like a cast expression.  */
 269       if (strncmp (value, "((unsigned int)"/*)*/, 15) == 0
 270           || strncmp (value, "((unsigned short)"/*)*/, 17) == 0
 271           || strncmp (value, "((unsigned char)"/*)*/, 16) == 0
 272           || strncmp (value, "((int)"/*)*/, 6) == 0
 273           || strncmp (value, "((signed short)"/*)*/, 15) == 0
 274           || strncmp (value, "((signed char)"/*)*/, 14) == 0)
 275         return mv - macro_values + 1;
 276     }
 277   return 0;
 278 ]])],
 279               [gl_cv_header_working_stdint_h=yes],
 280               [],
 281               [dnl When cross-compiling, assume it works.
 282                gl_cv_header_working_stdint_h=yes
 283               ])
 284          ])
 285       ])
 286   fi
 287
 288   HAVE_C99_STDINT_H=0
 289   HAVE_SYS_BITYPES_H=0
 290   HAVE_SYS_INTTYPES_H=0
 291   STDINT_H=stdint.h
 292   if test "$gl_cv_header_working_stdint_h" = yes; then
 293     HAVE_C99_STDINT_H=1
 294     dnl Now see whether the system <stdint.h> works without
 295     dnl __STDC_CONSTANT_MACROS/__STDC_LIMIT_MACROS defined.
 296     AC_CACHE_CHECK([whether stdint.h predates C++11],
 297       [gl_cv_header_stdint_predates_cxx11_h],
 298       [gl_cv_header_stdint_predates_cxx11_h=yes
 299        AC_COMPILE_IFELSE([
 300          AC_LANG_PROGRAM([[
 301 #define _GL_JUST_INCLUDE_SYSTEM_STDINT_H 1 /* work if build isn't clean */
 302 #include <stdint.h>
 303 ]
 304 gl_STDINT_INCLUDES
 305 [
 306 intmax_t im = INTMAX_MAX;
 307 int32_t i32 = INT32_C (0x7fffffff);
 308          ]])],
 309          [gl_cv_header_stdint_predates_cxx11_h=no])])
 310
 311     if test "$gl_cv_header_stdint_predates_cxx11_h" = yes; then
 312       AC_DEFINE([__STDC_CONSTANT_MACROS], [1],
 313                 [Define to 1 if the system <stdint.h> predates C++11.])
 314       AC_DEFINE([__STDC_LIMIT_MACROS], [1],
 315                 [Define to 1 if the system <stdint.h> predates C++11.])
 316     fi
 317     AC_CACHE_CHECK([whether stdint.h has UINTMAX_WIDTH etc.],
 318       [gl_cv_header_stdint_width],
 319       [gl_cv_header_stdint_width=no
 320        AC_COMPILE_IFELSE(
 321          [AC_LANG_PROGRAM([[
 322             /* Work if build is not clean.  */
 323             #define _GL_JUST_INCLUDE_SYSTEM_STDINT_H 1
 324             #ifndef __STDC_WANT_IEC_60559_BFP_EXT__
 325              #define __STDC_WANT_IEC_60559_BFP_EXT__ 1
 326             #endif
 327             #include <stdint.h>
 328             ]gl_STDINT_INCLUDES[
 329             int iw = UINTMAX_WIDTH;
 330             ]])],
 331          [gl_cv_header_stdint_width=yes])])
 332     if test "$gl_cv_header_stdint_width" = yes; then
 333       STDINT_H=
 334     fi
 335   else
 336     dnl Check for <sys/inttypes.h>, and for
 337     dnl <sys/bitypes.h> (used in Linux libc4 >= 4.6.7 and libc5).
 338     AC_CHECK_HEADERS([sys/inttypes.h sys/bitypes.h])
 339     if test $ac_cv_header_sys_inttypes_h = yes; then
 340       HAVE_SYS_INTTYPES_H=1
 341     fi
 342     if test $ac_cv_header_sys_bitypes_h = yes; then
 343       HAVE_SYS_BITYPES_H=1
 344     fi
 345     gl_STDINT_TYPE_PROPERTIES
 346   fi
 347
 348   # The substitute stdint.h needs the substitute limit.h's _GL_INTEGER_WIDTH.
 349   LIMITS_H=limits.h
 350   AM_CONDITIONAL([GL_GENERATE_LIMITS_H], [test -n "$LIMITS_H"])
 351
 352   AC_SUBST([HAVE_C99_STDINT_H])
 353   AC_SUBST([HAVE_SYS_BITYPES_H])
 354   AC_SUBST([HAVE_SYS_INTTYPES_H])
 355   AC_SUBST([STDINT_H])
 356   AM_CONDITIONAL([GL_GENERATE_STDINT_H], [test -n "$STDINT_H"])
 357 ])
 358
 359 dnl gl_STDINT_BITSIZEOF(TYPES, INCLUDES)
 360 dnl Determine the size of each of the given types in bits.
 361 AC_DEFUN([gl_STDINT_BITSIZEOF],
 362 [
 363   dnl Use a shell loop, to avoid bloating configure, and
 364   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 365   dnl   config.h.in,
 366   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 367   m4_foreach_w([gltype], [$1],
 368     [AH_TEMPLATE([BITSIZEOF_]m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]),
 369        [Define to the number of bits in type ']gltype['.])])
 370   for gltype in $1 ; do
 371     AC_CACHE_CHECK([for bit size of $gltype], [gl_cv_bitsizeof_${gltype}],
 372       [AC_COMPUTE_INT([result], [sizeof ($gltype) * CHAR_BIT],
 373          [$2
 374 #include <limits.h>], [result=unknown])
 375        eval gl_cv_bitsizeof_${gltype}=\$result
 376       ])
 377     eval result=\$gl_cv_bitsizeof_${gltype}
 378     if test $result = unknown; then
 379       dnl Use a nonempty default, because some compilers, such as IRIX 5 cc,
 380       dnl do a syntax check even on unused #if conditions and give an error
 381       dnl on valid C code like this:
 382       dnl   #if 0
 383       dnl   # if  > 32
 384       dnl   # endif
 385       dnl   #endif
 386       result=0
 387     fi
 388     GLTYPE=`echo "$gltype" | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 389     AC_DEFINE_UNQUOTED([BITSIZEOF_${GLTYPE}], [$result])
 390     eval BITSIZEOF_${GLTYPE}=\$result
 391   done
 392   m4_foreach_w([gltype], [$1],
 393     [AC_SUBST([BITSIZEOF_]m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]))])
 394 ])
 395
 396 dnl gl_CHECK_TYPES_SIGNED(TYPES, INCLUDES)
 397 dnl Determine the signedness of each of the given types.
 398 dnl Define HAVE_SIGNED_TYPE if type is signed.
 399 AC_DEFUN([gl_CHECK_TYPES_SIGNED],
 400 [
 401   dnl Use a shell loop, to avoid bloating configure, and
 402   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 403   dnl   config.h.in,
 404   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 405   m4_foreach_w([gltype], [$1],
 406     [AH_TEMPLATE([HAVE_SIGNED_]m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]),
 407        [Define to 1 if ']gltype[' is a signed integer type.])])
 408   for gltype in $1 ; do
 409     AC_CACHE_CHECK([whether $gltype is signed], [gl_cv_type_${gltype}_signed],
 410       [AC_COMPILE_IFELSE(
 411          [AC_LANG_PROGRAM([$2[
 412             int verify[2 * (($gltype) -1 < ($gltype) 0) - 1];]])],
 413          result=yes, result=no)
 414        eval gl_cv_type_${gltype}_signed=\$result
 415       ])
 416     eval result=\$gl_cv_type_${gltype}_signed
 417     GLTYPE=`echo $gltype | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 418     if test "$result" = yes; then
 419       AC_DEFINE_UNQUOTED([HAVE_SIGNED_${GLTYPE}], [1])
 420       eval HAVE_SIGNED_${GLTYPE}=1
 421     else
 422       eval HAVE_SIGNED_${GLTYPE}=0
 423     fi
 424   done
 425   m4_foreach_w([gltype], [$1],
 426     [AC_SUBST([HAVE_SIGNED_]m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]))])
 427 ])
 428
 429 dnl gl_INTEGER_TYPE_SUFFIX(TYPES, INCLUDES)
 430 dnl Determine the suffix to use for integer constants of the given types.
 431 dnl Define t_SUFFIX for each such type.
 432 AC_DEFUN([gl_INTEGER_TYPE_SUFFIX],
 433 [
 434   dnl Use a shell loop, to avoid bloating configure, and
 435   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 436   dnl   config.h.in,
 437   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 438   m4_foreach_w([gltype], [$1],
 439     [AH_TEMPLATE(m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_])[_SUFFIX],
 440        [Define to l, ll, u, ul, ull, etc., as suitable for
 441         constants of type ']gltype['.])])
 442   for gltype in $1 ; do
 443     AC_CACHE_CHECK([for $gltype integer literal suffix],
 444       [gl_cv_type_${gltype}_suffix],
 445       [eval gl_cv_type_${gltype}_suffix=no
 446        eval result=\$gl_cv_type_${gltype}_signed
 447        if test "$result" = yes; then
 448          glsufu=
 449        else
 450          glsufu=u
 451        fi
 452        for glsuf in "$glsufu" ${glsufu}l ${glsufu}ll ${glsufu}i64; do
 453          case $glsuf in
 454            '')  gltype1='int';;
 455            l)   gltype1='long int';;
 456            ll)  gltype1='long long int';;
 457            i64) gltype1='__int64';;
 458            u)   gltype1='unsigned int';;
 459            ul)  gltype1='unsigned long int';;
 460            ull) gltype1='unsigned long long int';;
 461            ui64)gltype1='unsigned __int64';;
 462          esac
 463          AC_COMPILE_IFELSE(
 464            [AC_LANG_PROGRAM([$2[
 465               extern $gltype foo;
 466               extern $gltype1 foo;]])],
 467            [eval gl_cv_type_${gltype}_suffix=\$glsuf])
 468          eval result=\$gl_cv_type_${gltype}_suffix
 469          test "$result" != no && break
 470        done])
 471     GLTYPE=`echo $gltype | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 472     eval result=\$gl_cv_type_${gltype}_suffix
 473     test "$result" = no && result=
 474     eval ${GLTYPE}_SUFFIX=\$result
 475     AC_DEFINE_UNQUOTED([${GLTYPE}_SUFFIX], [$result])
 476   done
 477   m4_foreach_w([gltype], [$1],
 478     [AC_SUBST(m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_])[_SUFFIX])])
 479 ])
 480
 481 dnl gl_STDINT_INCLUDES
 482 AC_DEFUN([gl_STDINT_INCLUDES],
 483 [[
 484   /* BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be
 485      included before <wchar.h>.  */
 486   #include <stddef.h>
 487   #include <signal.h>
 488   #if HAVE_WCHAR_H
 489   # include <stdio.h>
 490   # include <time.h>
 491   # include <wchar.h>
 492   #endif
 493 ]])
 494
 495 dnl gl_STDINT_TYPE_PROPERTIES
 496 dnl Compute HAVE_SIGNED_t, BITSIZEOF_t and t_SUFFIX, for all the types t
 497 dnl of interest to stdint.in.h.
 498 AC_DEFUN([gl_STDINT_TYPE_PROPERTIES],
 499 [
 500   AC_REQUIRE([gl_MULTIARCH])
 501   if test $APPLE_UNIVERSAL_BUILD = 0; then
 502     gl_STDINT_BITSIZEOF([ptrdiff_t size_t],
 503       [gl_STDINT_INCLUDES])
 504   fi
 505   gl_STDINT_BITSIZEOF([sig_atomic_t wchar_t wint_t],
 506     [gl_STDINT_INCLUDES])
 507   gl_CHECK_TYPES_SIGNED([sig_atomic_t wchar_t wint_t],
 508     [gl_STDINT_INCLUDES])
 509   gl_cv_type_ptrdiff_t_signed=yes
 510   gl_cv_type_size_t_signed=no
 511   if test $APPLE_UNIVERSAL_BUILD = 0; then
 512     gl_INTEGER_TYPE_SUFFIX([ptrdiff_t size_t],
 513       [gl_STDINT_INCLUDES])
 514   fi
 515   gl_INTEGER_TYPE_SUFFIX([sig_atomic_t wchar_t wint_t],
 516     [gl_STDINT_INCLUDES])
 517
 518   dnl If wint_t is smaller than 'int', it cannot satisfy the ISO C 99
 519   dnl requirement that wint_t is "unchanged by default argument promotions".
 520   dnl In this case gnulib's <wchar.h> and <wctype.h> override wint_t.
 521   dnl Set the variable BITSIZEOF_WINT_T accordingly.
 522   if test $BITSIZEOF_WINT_T -lt 32; then
 523     BITSIZEOF_WINT_T=32
 524   fi
 525 ])
 526
 527 dnl Autoconf >= 2.61 has AC_COMPUTE_INT built-in.
 528 dnl Remove this when we can assume autoconf >= 2.61.
 529 m4_ifdef([AC_COMPUTE_INT], [], [
 530   AC_DEFUN([AC_COMPUTE_INT], [_AC_COMPUTE_INT([$2],[$1],[$3],[$4])])
 531 ])