lisp/play/gamegrid.el

   1 ;;; gamegrid.el --- library for implementing grid-based games on Emacs
   2
   3 ;; Copyright (C) 1997, 1998 Free Software Foundation, Inc.
   4
   5 ;; Author: Glynn Clements <glynn@sensei.co.uk>
   6 ;; Version: 1.02
   7 ;; Created: 1997-08-13
   8 ;; Keywords: games
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (eval-when-compile
  32   (require 'cl))
  33
  34 ;; ;;;;;;;;;;;;; buffer-local variables ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  35
  36 (defvar gamegrid-use-glyphs t
  37   "Non-nil means use glyphs when available.")
  38
  39 (defvar gamegrid-use-color t
  40   "Non-nil means use color when available.")
  41
  42 (defvar gamegrid-font "-*-courier-medium-r-*-*-*-140-100-75-*-*-iso8859-*"
  43   "Name of the font used in X mode.")
  44
  45 (defvar gamegrid-face nil
  46   "Indicates the face to use as a default.")
  47 (make-variable-buffer-local 'gamegrid-face)
  48
  49 (defvar gamegrid-display-options nil)
  50
  51 (defvar gamegrid-buffer-width 0)
  52 (defvar gamegrid-buffer-height 0)
  53 (defvar gamegrid-blank 0)
  54
  55 (defvar gamegrid-timer nil)
  56
  57 (defvar gamegrid-display-mode nil)
  58
  59 (defvar gamegrid-display-table)
  60
  61 (defvar gamegrid-face-table nil)
  62
  63 (defvar gamegrid-buffer-start 1)
  64
  65 (defvar gamegrid-score-file-length 50
  66   "Number of high scores to keep")
  67
  68 (defvar gamegrid-user-score-file-directory "~/.emacs.d/games"
  69   "A directory for game scores which can't be shared.
  70 If Emacs was built without support for shared game scores, then this
  71 directory will be used.")
  72
  73 (make-variable-buffer-local 'gamegrid-use-glyphs)
  74 (make-variable-buffer-local 'gamegrid-use-color)
  75 (make-variable-buffer-local 'gamegrid-font)
  76 (make-variable-buffer-local 'gamegrid-display-options)
  77 (make-variable-buffer-local 'gamegrid-buffer-width)
  78 (make-variable-buffer-local 'gamegrid-buffer-height)
  79 (make-variable-buffer-local 'gamegrid-blank)
  80 (make-variable-buffer-local 'gamegrid-timer)
  81 (make-variable-buffer-local 'gamegrid-display-mode)
  82 (make-variable-buffer-local 'gamegrid-display-table)
  83 (make-variable-buffer-local 'gamegrid-face-table)
  84 (make-variable-buffer-local 'gamegrid-buffer-start)
  85 (make-variable-buffer-local 'gamegrid-score-file-length)
  86
  87 ;; ;;;;;;;;;;;;; global variables ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  88
  89 (defvar gamegrid-grid-x-face nil)
  90 (defvar gamegrid-mono-x-face nil)
  91 (defvar gamegrid-mono-tty-face nil)
  92
  93 ;; ;;;;;;;;;;;;; constants ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  94
  95 (defconst gamegrid-glyph-height 16)
  96
  97 (defconst gamegrid-xpm "\
  98 /* XPM */
  99 static char *noname[] = {
 100 /* width height ncolors chars_per_pixel */
 101 \"16 16 3 1\",
 102 /* colors */
 103 \"+ s col1\",
 104 \". s col2\",
 105 \"- s col3\",
 106 /* pixels */
 107 \"---------------+\",
 108 \"--------------++\",
 109 \"--............++\",
 110 \"--............++\",
 111 \"--............++\",
 112 \"--............++\",
 113 \"--............++\",
 114 \"--............++\",
 115 \"--............++\",
 116 \"--............++\",
 117 \"--............++\",
 118 \"--............++\",
 119 \"--............++\",
 120 \"--............++\",
 121 \"-+++++++++++++++\",
 122 \"++++++++++++++++\"
 123 };
 124 "
 125   "XPM format image used for each square")
 126
 127 (defvar gamegrid-xbm "\
 128 /* gamegrid XBM */
 129 #define gamegrid_width 16
 130 #define gamegrid_height 16
 131 static unsigned char gamegrid_bits[] = {
 132    0xff, 0xff, 0xff, 0x7f, 0xff, 0x3f, 0xaf, 0x0a, 0x57, 0x15, 0xaf, 0x0a,
 133    0x57, 0x15, 0xaf, 0x0a, 0x57, 0x15, 0xaf, 0x0a, 0x57, 0x15, 0xaf, 0x0a,
 134    0x57, 0x15, 0x07, 0x00, 0x03, 0x00, 0x01, 0x00 };"
 135   "XBM format image used for each square.")
 136
 137 ;; ;;;;;;;;;;;;;;;; miscellaneous functions ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 138
 139 (defsubst gamegrid-characterp (arg)
 140   (if (fboundp 'characterp)
 141       (characterp arg)
 142     (integerp arg)))
 143
 144 (defsubst gamegrid-event-x (event)
 145   (if (fboundp 'event-x)
 146       (event-x event)
 147     (car (posn-col-row (event-end event)))))
 148
 149 (defsubst gamegrid-event-y (event)
 150   (if (fboundp 'event-y)
 151       (event-y event)
 152     (cdr (posn-col-row (event-end event)))))
 153
 154 ;; ;;;;;;;;;;;;; display functions ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 155
 156 (defun gamegrid-color (color shade)
 157   (let* ((v (floor (* shade 255)))
 158          (r (* v (aref color 0)))
 159          (g (* v (aref color 1)))
 160          (b (* v (aref color 2))))
 161     (format "#%02x%02x%02x" r g b)))
 162
 163 (defun gamegrid-set-font (face)
 164   (if gamegrid-font
 165       (condition-case nil
 166           (set-face-font face gamegrid-font)
 167         (error nil))))
 168
 169 (defun gamegrid-setup-face (face color)
 170   (set-face-foreground face color)
 171   (set-face-background face color)
 172   (gamegrid-set-font face)
 173   (condition-case nil
 174       (set-face-background-pixmap face [nothing]);; XEmacs
 175     (error nil))
 176   (condition-case nil
 177       (set-face-background-pixmap face nil);; Emacs
 178     (error nil)))
 179
 180 (defun gamegrid-make-mono-tty-face ()
 181   (let ((face (make-face 'gamegrid-mono-tty-face)))
 182     (condition-case nil
 183         (set-face-property face 'reverse t)
 184       (error nil))
 185     face))
 186
 187 (defun gamegrid-make-color-tty-face (color)
 188   (let* ((color-str (if (symbolp color) (symbol-value color) color))
 189          (name (intern (format "gamegrid-color-tty-face-%s" color-str)))
 190          (face (make-face name)))
 191     (gamegrid-setup-face face color-str)
 192     face))
 193
 194 (defun gamegrid-make-grid-x-face ()
 195   (let ((face (make-face 'gamegrid-x-border-face)))
 196     (gamegrid-set-font face)
 197     face))
 198
 199 (defun gamegrid-make-mono-x-face ()
 200   (let ((face (make-face 'gamegrid-mono-x-face))
 201         (color (face-foreground 'default)))
 202     (if (null color)
 203         (setq color
 204               (cdr-safe (assq 'foreground-color (frame-parameters)))))
 205     (gamegrid-setup-face face color)
 206     face))
 207
 208 (defun gamegrid-make-color-x-face (color)
 209   (let* ((hex (gamegrid-color color 1.0))
 210          (name (intern (format "gamegrid-color-x-face-%s" hex)))
 211          (face (make-face name)))
 212     (gamegrid-setup-face face hex)
 213     face))
 214
 215 (defun gamegrid-make-face (data-spec-list color-spec-list)
 216   (let ((data (gamegrid-match-spec-list data-spec-list))
 217         (color (gamegrid-match-spec-list color-spec-list)))
 218     (case data
 219       ('color-x
 220        (gamegrid-make-color-x-face color))
 221       ('grid-x
 222        (unless gamegrid-grid-x-face
 223          (setq gamegrid-grid-x-face (gamegrid-make-grid-x-face)))
 224        gamegrid-grid-x-face)
 225       ('mono-x
 226        (unless gamegrid-mono-x-face
 227          (setq gamegrid-mono-x-face (gamegrid-make-mono-x-face)))
 228        gamegrid-mono-x-face)
 229       ('color-tty
 230        (gamegrid-make-color-tty-face color))
 231       ('mono-tty
 232        (unless gamegrid-mono-tty-face
 233          (setq gamegrid-mono-tty-face (gamegrid-make-mono-tty-face)))
 234        gamegrid-mono-tty-face))))
 235
 236 (defun gamegrid-colorize-glyph (color)
 237   (find-image `((:type xpm :data ,gamegrid-xpm
 238                        :ascent center
 239                        :color-symbols
 240                        (("col1" . ,(gamegrid-color color 0.6))
 241                         ("col2" . ,(gamegrid-color color 0.8))
 242                         ("col3" . ,(gamegrid-color color 1.0))))
 243                 (:type xbm :data ,gamegrid-xbm
 244                        :ascent center
 245                        :foreground ,(gamegrid-color color 1.0)
 246                        :background ,(gamegrid-color color 0.5)))))
 247
 248 (defun gamegrid-match-spec (spec)
 249   (let ((locale (car spec))
 250         (value (cadr spec)))
 251     (and (or (eq locale t)
 252              (and (listp locale)
 253                   (memq gamegrid-display-mode locale))
 254              (and (symbolp locale)
 255                   (eq gamegrid-display-mode locale)))
 256          value)))
 257
 258 (defun gamegrid-match-spec-list (spec-list)
 259   (and spec-list
 260        (or (gamegrid-match-spec (car spec-list))
 261            (gamegrid-match-spec-list (cdr spec-list)))))
 262
 263 (defun gamegrid-make-glyph (data-spec-list color-spec-list)
 264   (let ((data (gamegrid-match-spec-list data-spec-list))
 265         (color (gamegrid-match-spec-list color-spec-list)))
 266     (cond ((gamegrid-characterp data)
 267            (vector data))
 268           ((eq data 'colorize)
 269            (gamegrid-colorize-glyph color))
 270           ((listp data)
 271            (find-image data)) ;untested!
 272           ((vectorp data)
 273            (gamegrid-make-image-from-vector data)))))
 274
 275 (defun gamegrid-make-image-from-vector (vect)
 276   "Convert an XEmacs style \"glyph\" to an image-spec."
 277   (let ((l (list 'image :type)))
 278     (dotimes (n (length vect))
 279       (setf l (nconc l (list (aref vect n)))))
 280     (nconc l (list :ascent 'center))))
 281
 282 (defun gamegrid-display-type ()
 283   (cond ((and gamegrid-use-glyphs
 284               (display-images-p))
 285          'glyph)
 286         ((and gamegrid-use-color
 287               (display-graphic-p)
 288               (display-color-p))
 289          'color-x)
 290         ((display-graphic-p)
 291          'mono-x)
 292         ((and gamegrid-use-color
 293               (display-color-p))
 294          'color-tty)
 295         ((display-multi-font-p) ;???
 296          'mono-tty)
 297         (t
 298            'emacs-tty)))
 299
 300 (defun gamegrid-set-display-table ()
 301   (if (fboundp 'specifierp)
 302       (add-spec-to-specifier current-display-table
 303                              gamegrid-display-table
 304                              (current-buffer)
 305                              nil
 306                              'remove-locale)
 307     (setq buffer-display-table gamegrid-display-table)))
 308
 309 (defun gamegrid-setup-default-font ()
 310   (setq gamegrid-face
 311         (copy-face 'default
 312                    (intern (concat "gamegrid-face-" (buffer-name)))))
 313   (when (eq gamegrid-display-mode 'glyph)
 314     (let ((max-height nil))
 315       (loop for c from 0 to 255 do
 316             (let ((glyph (aref gamegrid-display-table c)))
 317               (when (and (listp glyph) (eq (car  glyph) 'image))
 318                 (let ((height (cdr (image-size glyph))))
 319                   (if (or (null max-height)
 320                           (< max-height height))
 321                       (setq max-height height))))))
 322       (when (and max-height (< max-height 1))
 323         (set-face-attribute gamegrid-face nil :height max-height)))))
 324
 325 (defun gamegrid-initialize-display ()
 326   (setq gamegrid-display-mode (gamegrid-display-type))
 327   (setq gamegrid-display-table (make-display-table))
 328   (setq gamegrid-face-table (make-vector 256 nil))
 329   (loop for c from 0 to 255 do
 330     (let* ((spec (aref gamegrid-display-options c))
 331            (glyph (gamegrid-make-glyph (car spec) (caddr spec)))
 332            (face (gamegrid-make-face (cadr spec) (caddr spec))))
 333       (aset gamegrid-face-table c face)
 334       (aset gamegrid-display-table c glyph)))
 335   (gamegrid-setup-default-font)
 336   (gamegrid-set-display-table)
 337   (setq cursor-type nil))
 338
 339
 340 (defun gamegrid-set-face (c)
 341   (if (eq gamegrid-display-mode 'glyph)
 342       (add-text-properties (1- (point)) (point)
 343                            (list 'display (list (aref gamegrid-display-table c))))
 344     (put-text-property (1- (point))
 345                        (point)
 346                        'face
 347                        (aref gamegrid-face-table c))))
 348
 349 (defun gamegrid-cell-offset (x y)
 350   (+ gamegrid-buffer-start
 351      (* (1+ gamegrid-buffer-width) y)
 352      x))
 353
 354 ;; ;;;;;;;;;;;;;;;; grid functions ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 355
 356 (defun gamegrid-get-cell (x y)
 357   (char-after (gamegrid-cell-offset x y)))
 358
 359 (defun gamegrid-set-cell (x y c)
 360   (save-excursion
 361     (let ((buffer-read-only nil))
 362       (goto-char (gamegrid-cell-offset x y))
 363       (delete-char 1)
 364       (insert-char c 1)
 365       (gamegrid-set-face c))))
 366
 367 (defun gamegrid-init-buffer (width height blank)
 368   (setq gamegrid-buffer-width width
 369         gamegrid-buffer-height height)
 370   (let ((line (concat
 371                (make-string width blank)
 372                "\n"))
 373         (buffer-read-only nil))
 374     (erase-buffer)
 375     (setq gamegrid-buffer-start (point))
 376     (dotimes (i height)
 377       (insert line))
 378     ;; Adjust the height of the default face to the height of the
 379     ;; images. Unlike XEmacs, Emacs doesn't allow to make the default
 380     ;; face buffer-local; so we do this with an overlay.
 381     (when (eq gamegrid-display-mode 'glyph)
 382       (overlay-put (make-overlay (point-min) (point-max))
 383                    'face gamegrid-face))
 384     (goto-char (point-min))))
 385
 386 (defun gamegrid-init (options)
 387   (setq buffer-read-only t
 388         truncate-lines t
 389         gamegrid-display-options options)
 390   (buffer-disable-undo (current-buffer))
 391   (gamegrid-initialize-display))
 392
 393 ;; ;;;;;;;;;;;;;;;; timer functions ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 394
 395 (defun gamegrid-start-timer (period func)
 396   (setq gamegrid-timer
 397         (if (featurep 'itimer)
 398             (start-itimer "Gamegrid"
 399                           func
 400                           period
 401                           period
 402                           nil
 403                           t
 404                           (current-buffer))
 405           (run-with-timer period
 406                           period
 407                           func
 408                           (current-buffer)))))
 409
 410 (defun gamegrid-set-timer (delay)
 411   (if gamegrid-timer
 412       (if (featurep 'itimer)
 413           (set-itimer-restart gamegrid-timer delay)
 414         (timer-set-time gamegrid-timer
 415                         (list (aref gamegrid-timer 1)
 416                               (aref gamegrid-timer 2)
 417                               (aref gamegrid-timer 3))
 418                         delay))))
 419
 420 (defun gamegrid-kill-timer ()
 421   (if gamegrid-timer
 422       (if (featurep 'itimer)
 423           (delete-itimer gamegrid-timer)
 424         (timer-set-time gamegrid-timer '(0 0 0) nil)))
 425   (setq gamegrid-timer nil))
 426
 427 ;; ;;;;;;;;;;;;;;; high score functions ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 428
 429 (defun gamegrid-add-score (file score)
 430   "Add the current score to the high score file.
 431
 432 On POSIX systems there may be a shared game directory for all users in
 433 which the scorefiles are kept. On such systems Emacs doesn't create
 434 the score file FILE in this directory, if it doesn't already exist. In
 435 this case Emacs searches for FILE in the directory specified by
 436 `gamegrid-user-score-file-directory' and creates it there, if
 437 necessary.
 438
 439 To add the score file for a game to the system wide shared game
 440 directory, create the file with the shell command \"touch\" in this
 441 directory and make sure that it is owned by the correct user and
 442 group. You probably need special user privileges to do this.
 443
 444 On non-POSIX systems Emacs searches for FILE in the directory
 445 specified by the variable `temporary-file-directory'. If necessary,
 446 FILE is created there."
 447   (case system-type
 448     ((ms-dos windows-nt)
 449      (gamegrid-add-score-insecure file score))
 450     (t
 451      (gamegrid-add-score-with-update-game-score file score))))
 452
 453
 454 ;; On POSIX systems there are four cases to distinguish:
 455
 456 ;;     1. FILE is an absolute filename.  Then it should be a file in
 457 ;;        temporary file directory.  This is the way,
 458 ;;        `gamegrid-add-score' was supposed to be used in the past and
 459 ;;        is covered here for backward-compatibility.
 460 ;;
 461 ;;     2. The helper program "update-game-score" is setuid and the
 462 ;;        file FILE does already exist in a system wide shared game
 463 ;;        directory.  This should be the normal case on POSIX systems,
 464 ;;        if the game was installed system wide.  Use
 465 ;;        "update-game-score" to add the score to the file in the
 466 ;;        shared game directory.
 467 ;;
 468 ;;     3. "update-game-score" is setuid, but the file FILE does *not*
 469 ;;        exist in the system wide shared game directory.  Use
 470 ;;        `gamegrid-add-score-insecure' to create--if necessary--and
 471 ;;        update FILE.  This is for the case that a user has installed
 472 ;;        a game on her own.
 473 ;;
 474 ;;     4. "update-game-score" is not setuid.  Use it to create/update
 475 ;;        FILE in the user's home directory.  There is presumably no
 476 ;;        shared game directory.
 477
 478 (defun gamegrid-add-score-with-update-game-score (file score)
 479   (let* ((result nil) ;; What is this good for? -- os
 480          (have-shared-game-dir
 481           (not (zerop (logand (file-modes
 482                                (expand-file-name "update-game-score"
 483                                                  exec-directory))
 484                               #o4000)))))
 485     (cond ((file-name-absolute-p file)
 486            (gamegrid-add-score-insecure file score))
 487           ((and have-shared-game-dir
 488                 (file-exists-p (expand-file-name file shared-game-score-directory)))
 489            ;; Use the setuid "update-game-score" program to update a
 490            ;; system-wide score file.
 491            (gamegrid-add-score-with-update-game-score-1
 492             (expand-file-name file shared-game-score-directory) score))
 493           ;; Else: Add the score to a score file in the user's home
 494           ;; directory.
 495           (have-shared-game-dir
 496            ;; If `have-shared-game-dir' is non-nil, then
 497            ;; "update-gamescore" program is setuid, so don't use it.
 498            (unless (file-exists-p
 499                     (directory-file-name gamegrid-user-score-file-directory))
 500              (make-directory gamegrid-user-score-file-directory t))
 501            (gamegrid-add-score-insecure file score
 502                                         gamegrid-user-score-file-directory))
 503           (t (let ((f (expand-file-name
 504                        gamegrid-user-score-file-directory)))
 505                (when (file-writable-p f)
 506                  (unless (eq (car-safe (file-attributes f))
 507                              t)
 508                    (make-directory f))
 509                  (setq f (expand-file-name file f))
 510                  (unless (file-exists-p f)
 511                    (write-region "" nil f nil 'silent nil 'excl)))
 512                (gamegrid-add-score-with-update-game-score-1 f score))))))
 513
 514 (defun gamegrid-add-score-with-update-game-score-1 (target score)
 515   (let ((default-directory "/")
 516         (errbuf (generate-new-buffer " *update-game-score loss*")))
 517     (apply
 518      'call-process
 519      (append
 520       (list
 521        (expand-file-name "update-game-score" exec-directory)
 522        nil errbuf nil
 523        "-m" (int-to-string gamegrid-score-file-length)
 524        "-d" (if have-shared-game-dir
 525                 (expand-file-name shared-game-score-directory)
 526               (file-name-directory target))
 527        file
 528        (int-to-string score)
 529        (concat
 530         (user-full-name)
 531         " <"
 532         (cond ((fboundp 'user-mail-address)
 533                (user-mail-address))
 534               ((boundp 'user-mail-address)
 535                user-mail-address)
 536               (t ""))
 537         ">  "
 538         (current-time-string)))))
 539     (if (buffer-modified-p errbuf)
 540         (progn
 541           (display-buffer errbuf)
 542           (error "Failed to update game score file"))
 543       (kill-buffer errbuf))
 544     (save-excursion
 545       (let ((buf (find-buffer-visiting target)))
 546         (if buf
 547             (progn
 548               (with-current-buffer buf
 549                 (revert-buffer nil t nil))
 550               (display-buffer buf))
 551           (find-file-read-only-other-window target))))))
 552
 553 (defun gamegrid-add-score-insecure (file score &optional directory)
 554   (save-excursion
 555     (setq file (expand-file-name file (or directory
 556                                           temporary-file-directory)))
 557     (find-file-other-window file)
 558     (setq buffer-read-only nil)
 559     (goto-char (point-max))
 560     (insert (format "%05d\t%s\t%s <%s>\n"
 561                     score
 562                     (current-time-string)
 563                     (user-full-name)
 564                     (cond ((fboundp 'user-mail-address)
 565                            (user-mail-address))
 566                           ((boundp 'user-mail-address)
 567                            user-mail-address)
 568                           (t ""))))
 569     (sort-fields 1 (point-min) (point-max))
 570     (reverse-region (point-min) (point-max))
 571     (goto-line (1+ gamegrid-score-file-length))
 572     (delete-region (point) (point-max))
 573     (setq buffer-read-only t)
 574     (save-buffer)))
 575
 576
 577 ;; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 578
 579 (provide 'gamegrid)
 580
 581 ;;; arch-tag: a96c2ff4-1c12-427e-bd3d-faeaf174cd46
 582 ;;; gamegrid.el ends here