lisp/emacs-lisp/ring.el

   1 ;;; ring.el --- handle rings of items
   2
   3 ;; Copyright (C) 1992, 2001, 2002, 2003, 2004, 2005,
   4 ;;   2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: extensions
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This code defines a ring data structure.  A ring is a
  29 ;;     (hd-index length . vector)
  30 ;; list.  You can insert to, remove from, and rotate a ring.  When the ring
  31 ;; fills up, insertions cause the oldest elts to be quietly dropped.
  32 ;;
  33 ;; In ring-ref, 0 is the index of the newest element.  Higher indexes
  34 ;; correspond to older elements; when the index equals the ring length,
  35 ;; it wraps to the newest element again.
  36 ;;
  37 ;; hd-index = vector index of the oldest ring item.
  38 ;;         Newer items follow this item; at the end of the vector,
  39 ;;         they wrap around to the start of the vector.
  40 ;; length = number of items currently in the ring.
  41 ;;         This never exceeds the length of the vector itself.
  42 ;;
  43 ;; These functions are used by the input history mechanism, but they can
  44 ;; be used for other purposes as well.
  45
  46 ;;; Code:
  47
  48 ;;; User Functions:
  49
  50 ;;;###autoload
  51 (defun ring-p (x)
  52   "Return t if X is a ring; nil otherwise."
  53   (and (consp x) (integerp (car x))
  54        (consp (cdr x)) (integerp (cadr x))
  55        (vectorp (cddr x))))
  56
  57 ;;;###autoload
  58 (defun make-ring (size)
  59   "Make a ring that can contain SIZE elements."
  60   (cons 0 (cons 0 (make-vector size nil))))
  61
  62 (defun ring-insert-at-beginning (ring item)
  63   "Add to RING the item ITEM, at the front, as the oldest item."
  64   (let* ((vec (cddr ring))
  65          (veclen (length vec))
  66          (hd (car ring))
  67          (ln (cadr ring)))
  68     (setq ln (min veclen (1+ ln))
  69           hd (ring-minus1 hd veclen))
  70     (aset vec hd item)
  71     (setcar ring hd)
  72     (setcar (cdr ring) ln)))
  73
  74 (defun ring-plus1 (index veclen)
  75   "Return INDEX+1, with wraparound."
  76   (let ((new-index (1+ index)))
  77     (if (= new-index veclen) 0 new-index)))
  78
  79 (defun ring-minus1 (index veclen)
  80   "Return INDEX-1, with wraparound."
  81   (- (if (zerop index) veclen index) 1))
  82
  83 (defun ring-length (ring)
  84   "Return the number of elements in the RING."
  85   (cadr ring))
  86
  87 (defun ring-index (index head ringlen veclen)
  88   "Convert nominal ring index INDEX to an internal index.
  89 The internal index refers to the items ordered from newest to oldest.
  90 HEAD is the index of the oldest element in the ring.
  91 RINGLEN is the number of elements currently in the ring.
  92 VECLEN is the size of the vector in the ring."
  93   (setq index (mod index ringlen))
  94   (mod (1- (+ head (- ringlen index))) veclen))
  95
  96 (defun ring-empty-p (ring)
  97   "Return t if RING is empty; nil otherwise."
  98   (zerop (cadr ring)))
  99
 100 (defun ring-size (ring)
 101   "Return the size of RING, the maximum number of elements it can contain."
 102   (length (cddr ring)))
 103
 104 (defun ring-copy (ring)
 105   "Return a copy of RING."
 106   (let ((vec (cddr ring))
 107         (hd  (car ring))
 108         (ln  (cadr ring)))
 109     (cons hd (cons ln (copy-sequence vec)))))
 110
 111 (defun ring-insert (ring item)
 112   "Insert onto ring RING the item ITEM, as the newest (last) item.
 113 If the ring is full, dump the oldest item to make room."
 114   (let* ((vec (cddr ring))
 115          (veclen (length vec))
 116          (hd (car ring))
 117          (ln (cadr ring)))
 118     (prog1
 119         (aset vec (mod (+ hd ln) veclen) item)
 120       (if (= ln veclen)
 121           (setcar ring (ring-plus1 hd veclen))
 122         (setcar (cdr ring) (1+ ln))))))
 123
 124 (defun ring-remove (ring &optional index)
 125   "Remove an item from the RING.  Return the removed item.
 126 If optional INDEX is nil, remove the oldest item.  If it's
 127 numeric, remove the element indexed."
 128   (if (ring-empty-p ring)
 129       (error "Ring empty")
 130     (let* ((hd (car ring))
 131            (ln (cadr ring))
 132            (vec (cddr ring))
 133            (veclen (length vec))
 134            (tl (mod (1- (+ hd ln)) veclen))
 135            oldelt)
 136       (when (null index)
 137         (setq index (1- ln)))
 138       (setq index (ring-index index hd ln veclen))
 139       (setq oldelt (aref vec index))
 140       (while (/= index tl)
 141         (aset vec index (aref vec (ring-plus1 index veclen)))
 142         (setq index (ring-plus1 index veclen)))
 143       (aset vec tl nil)
 144       (setcar (cdr ring) (1- ln))
 145       oldelt)))
 146
 147 (defun ring-ref (ring index)
 148   "Return RING's INDEX element.
 149 INDEX = 0 is the most recently inserted; higher indices
 150 correspond to older elements.
 151 INDEX need not be <= the ring length; the appropriate modulo operation
 152 will be performed."
 153   (if (ring-empty-p ring)
 154       (error "Accessing an empty ring")
 155     (let ((hd (car ring))
 156           (ln (cadr ring))
 157           (vec (cddr ring)))
 158       (aref vec (ring-index index hd ln (length vec))))))
 159
 160 (defun ring-elements (ring)
 161   "Return a list of the elements of RING, in order, newest first."
 162   (let ((start (car ring))
 163         (size (ring-size ring))
 164         (vect (cddr ring))
 165         lst)
 166     (dotimes (var (cadr ring) lst)
 167       (push (aref vect (mod (+ start var) size)) lst))))
 168
 169 (defun ring-member (ring item)
 170   "Return index of ITEM if on RING, else nil.
 171 Comparison is done via `equal'.  The index is 0-based."
 172   (catch 'found
 173     (dotimes (ind (ring-length ring) nil)
 174       (when (equal item (ring-ref ring ind))
 175         (throw 'found ind)))))
 176
 177 (defun ring-next (ring item)
 178   "Return the next item in the RING, after ITEM.
 179 Raise error if ITEM is not in the RING."
 180   (let ((curr-index (ring-member ring item)))
 181     (unless curr-index (error "Item is not in the ring: `%s'" item))
 182     (ring-ref ring (ring-plus1 curr-index (ring-length ring)))))
 183
 184 (defun ring-previous (ring item)
 185   "Return the previous item in the RING, before ITEM.
 186 Raise error if ITEM is not in the RING."
 187   (let ((curr-index (ring-member ring item)))
 188     (unless curr-index (error "Item is not in the ring: `%s'" item))
 189     (ring-ref ring (ring-minus1 curr-index (ring-length ring)))))
 190
 191 (defun ring-insert+extend (ring item &optional grow-p)
 192   "Like `ring-insert', but if GROW-P is non-nil, then enlarge ring.
 193 Insert onto ring RING the item ITEM, as the newest (last) item.
 194 If the ring is full, behavior depends on GROW-P:
 195   If GROW-P is non-nil, enlarge the ring to accommodate the new item.
 196   If GROW-P is nil, dump the oldest item to make room for the new."
 197   (let* ((vec (cddr ring))
 198          (veclen (length vec))
 199          (hd (car ring))
 200          (ringlen (ring-length ring)))
 201     (prog1
 202         (cond ((and grow-p (= ringlen veclen)) ; Full ring.  Enlarge it.
 203                (setq veclen (1+ veclen))
 204                (setcdr ring (cons (setq ringlen (1+ ringlen))
 205                                   (setq vec (vconcat vec (vector item)))))
 206                (setcar ring hd))
 207               (t (aset vec (mod (+ hd ringlen) veclen) item)))
 208       (if (= ringlen veclen)
 209           (setcar ring (ring-plus1 hd veclen))
 210         (setcar (cdr ring) (1+ ringlen))))))
 211
 212 (defun ring-remove+insert+extend (ring item &optional grow-p)
 213   "`ring-remove' ITEM from RING, then `ring-insert+extend' it.
 214 This ensures that there is only one ITEM on RING.
 215
 216 If the RING is full, behavior depends on GROW-P:
 217   If GROW-P is non-nil, enlarge the ring to accommodate the new ITEM.
 218   If GROW-P is nil, dump the oldest item to make room for the new."
 219   (let (ind)
 220     (while (setq ind (ring-member ring item))
 221       (ring-remove ring ind)))
 222   (ring-insert+extend ring item grow-p))
 223
 224 (defun ring-convert-sequence-to-ring (seq)
 225   "Convert sequence SEQ to a ring.  Return the ring.
 226 If SEQ is already a ring, return it."
 227   (if (ring-p seq)
 228       seq
 229     (let* ((size (length seq))
 230            (ring (make-ring size)))
 231       (dotimes (count size)
 232         (when (or (ring-empty-p ring)
 233                   (not (equal (ring-ref ring 0) (elt seq count))))
 234           (ring-insert-at-beginning ring (elt seq count))))
 235       ring)))
 236
 237 ;;; provide ourself:
 238
 239 (provide 'ring)
 240
 241 ;;; arch-tag: e707682b-ed69-47c9-b20f-cf2c68cc92d2
 242 ;;; ring.el ends here