lisp/emacs-lisp/byte-run.el

   1 ;;; byte-run.el --- byte-compiler support for inlining
   2
   3 ;; Copyright (C) 1992, 2001, 2002, 2003, 2004, 2005,
   4 ;;   2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Jamie Zawinski <jwz@lucid.com>
   7 ;;      Hallvard Furuseth <hbf@ulrik.uio.no>
   8 ;; Maintainer: FSF
   9 ;; Keywords: internal
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; interface to selectively inlining functions.
  31 ;; This only happens when source-code optimization is turned on.
  32
  33 ;;; Code:
  34
  35 ;; We define macro-declaration-function here because it is needed to
  36 ;; handle declarations in macro definitions and this is the first file
  37 ;; loaded by loadup.el that uses declarations in macros.
  38
  39 (defun macro-declaration-function (macro decl)
  40   "Process a declaration found in a macro definition.
  41 This is set as the value of the variable `macro-declaration-function'.
  42 MACRO is the name of the macro being defined.
  43 DECL is a list `(declare ...)' containing the declarations.
  44 The return value of this function is not used."
  45   ;; We can't use `dolist' or `cadr' yet for bootstrapping reasons.
  46   (let (d)
  47     ;; Ignore the first element of `decl' (it's always `declare').
  48     (while (setq decl (cdr decl))
  49       (setq d (car decl))
  50       (cond ((and (consp d) (eq (car d) 'indent))
  51              (put macro 'lisp-indent-function (car (cdr d))))
  52             ((and (consp d) (eq (car d) 'debug))
  53              (put macro 'edebug-form-spec (car (cdr d))))
  54             ((and (consp d) (eq (car d) 'doc-string))
  55              (put macro 'doc-string-elt (car (cdr d))))
  56             (t
  57              (message "Unknown declaration %s" d))))))
  58
  59 (setq macro-declaration-function 'macro-declaration-function)
  60
  61 \f
  62 ;; Redefined in byte-optimize.el.
  63 ;; This is not documented--it's not clear that we should promote it.
  64 (fset 'inline 'progn)
  65 (put 'inline 'lisp-indent-function 0)
  66
  67 ;;; Interface to inline functions.
  68
  69 ;; (defmacro proclaim-inline (&rest fns)
  70 ;;   "Cause the named functions to be open-coded when called from compiled code.
  71 ;; They will only be compiled open-coded when byte-compile-optimize is true."
  72 ;;   (cons 'eval-and-compile
  73 ;;      (mapcar '(lambda (x)
  74 ;;                 (or (memq (get x 'byte-optimizer)
  75 ;;                           '(nil byte-compile-inline-expand))
  76 ;;                     (error
  77 ;;                      "%s already has a byte-optimizer, can't make it inline"
  78 ;;                      x))
  79 ;;                 (list 'put (list 'quote x)
  80 ;;                       ''byte-optimizer ''byte-compile-inline-expand))
  81 ;;              fns)))
  82
  83 ;; (defmacro proclaim-notinline (&rest fns)
  84 ;;   "Cause the named functions to no longer be open-coded."
  85 ;;   (cons 'eval-and-compile
  86 ;;      (mapcar '(lambda (x)
  87 ;;                 (if (eq (get x 'byte-optimizer) 'byte-compile-inline-expand)
  88 ;;                     (put x 'byte-optimizer nil))
  89 ;;                 (list 'if (list 'eq (list 'get (list 'quote x) ''byte-optimizer)
  90 ;;                                 ''byte-compile-inline-expand)
  91 ;;                       (list 'put x ''byte-optimizer nil)))
  92 ;;              fns)))
  93
  94 ;; This has a special byte-hunk-handler in bytecomp.el.
  95 (defmacro defsubst (name arglist &rest body)
  96   "Define an inline function.  The syntax is just like that of `defun'."
  97   (declare (debug defun))
  98   (or (memq (get name 'byte-optimizer)
  99             '(nil byte-compile-inline-expand))
 100       (error "`%s' is a primitive" name))
 101   `(prog1
 102        (defun ,name ,arglist ,@body)
 103      (eval-and-compile
 104        (put ',name 'byte-optimizer 'byte-compile-inline-expand))))
 105
 106 (defun make-obsolete (obsolete-name current-name &optional when)
 107   "Make the byte-compiler warn that OBSOLETE-NAME is obsolete.
 108 The warning will say that CURRENT-NAME should be used instead.
 109 If CURRENT-NAME is a string, that is the `use instead' message
 110 \(it should end with a period, and not start with a capital).
 111 If provided, WHEN should be a string indicating when the function
 112 was first made obsolete, for example a date or a release number."
 113   (interactive "aMake function obsolete: \nxObsoletion replacement: ")
 114   (let ((handler (get obsolete-name 'byte-compile)))
 115     (if (eq 'byte-compile-obsolete handler)
 116         (setq handler (nth 1 (get obsolete-name 'byte-obsolete-info)))
 117       (put obsolete-name 'byte-compile 'byte-compile-obsolete))
 118     (put obsolete-name 'byte-obsolete-info (list current-name handler when)))
 119   obsolete-name)
 120
 121 (defmacro define-obsolete-function-alias (obsolete-name current-name
 122                                                    &optional when docstring)
 123   "Set OBSOLETE-NAME's function definition to CURRENT-NAME and mark it obsolete.
 124
 125 \(define-obsolete-function-alias 'old-fun 'new-fun \"22.1\" \"old-fun's doc.\")
 126
 127 is equivalent to the following two lines of code:
 128
 129 \(defalias 'old-fun 'new-fun \"old-fun's doc.\")
 130 \(make-obsolete 'old-fun 'new-fun \"22.1\")
 131
 132 See the docstrings of `defalias' and `make-obsolete' for more details."
 133   (declare (doc-string 4))
 134   `(progn
 135      (defalias ,obsolete-name ,current-name ,docstring)
 136      (make-obsolete ,obsolete-name ,current-name ,when)))
 137
 138 (defun make-obsolete-variable (obsolete-name current-name &optional when)
 139   "Make the byte-compiler warn that OBSOLETE-NAME is obsolete.
 140 The warning will say that CURRENT-NAME should be used instead.
 141 If CURRENT-NAME is a string, that is the `use instead' message.
 142 If provided, WHEN should be a string indicating when the variable
 143 was first made obsolete, for example a date or a release number."
 144   (interactive
 145    (list
 146     (let ((str (completing-read "Make variable obsolete: " obarray 'boundp t)))
 147       (if (equal str "") (error ""))
 148       (intern str))
 149     (car (read-from-string (read-string "Obsoletion replacement: ")))))
 150   (put obsolete-name 'byte-obsolete-variable (cons current-name when))
 151   obsolete-name)
 152
 153 (defmacro define-obsolete-variable-alias (obsolete-name current-name
 154                                                  &optional when docstring)
 155   "Make OBSOLETE-NAME a variable alias for CURRENT-NAME and mark it obsolete.
 156
 157 \(define-obsolete-variable-alias 'old-var 'new-var \"22.1\" \"old-var's doc.\")
 158
 159 is equivalent to the following two lines of code:
 160
 161 \(defvaralias 'old-var 'new-var \"old-var's doc.\")
 162 \(make-obsolete-variable 'old-var 'new-var \"22.1\")
 163
 164 See the docstrings of `defvaralias' and `make-obsolete-variable' or
 165 Info node `(elisp)Variable Aliases' for more details."
 166   (declare (doc-string 4))
 167   `(progn
 168      (defvaralias ,obsolete-name ,current-name ,docstring)
 169      (make-obsolete-variable ,obsolete-name ,current-name ,when)))
 170
 171 (defmacro dont-compile (&rest body)
 172   "Like `progn', but the body always runs interpreted (not compiled).
 173 If you think you need this, you're probably making a mistake somewhere."
 174   (declare (debug t) (indent 0))
 175   (list 'eval (list 'quote (if (cdr body) (cons 'progn body) (car body)))))
 176
 177 \f
 178 ;; interface to evaluating things at compile time and/or load time
 179 ;; these macro must come after any uses of them in this file, as their
 180 ;; definition in the file overrides the magic definitions on the
 181 ;; byte-compile-macro-environment.
 182
 183 (defmacro eval-when-compile (&rest body)
 184   "Like `progn', but evaluates the body at compile time if you're compiling.
 185 Thus, the result of the body appears to the compiler as a quoted constant.
 186 In interpreted code, this is entirely equivalent to `progn'."
 187   (declare (debug t) (indent 0))
 188   ;; Not necessary because we have it in b-c-initial-macro-environment
 189   ;; (list 'quote (eval (cons 'progn body)))
 190   (cons 'progn body))
 191
 192 (defmacro eval-and-compile (&rest body)
 193   "Like `progn', but evaluates the body at compile time and at load time."
 194   (declare (debug t) (indent 0))
 195   ;; Remember, it's magic.
 196   (cons 'progn body))
 197
 198 (put 'with-no-warnings 'lisp-indent-function 0)
 199 (defun with-no-warnings (&rest body)
 200   "Like `progn', but prevents compiler warnings in the body."
 201   ;; The implementation for the interpreter is basically trivial.
 202   (car (last body)))
 203
 204 \f
 205 ;; I nuked this because it's not a good idea for users to think of using it.
 206 ;; These options are a matter of installation preference, and have nothing to
 207 ;; with particular source files; it's a mistake to suggest to users
 208 ;; they should associate these with particular source files.
 209 ;; There is hardly any reason to change these parameters, anyway.
 210 ;; --rms.
 211
 212 ;; (put 'byte-compiler-options 'lisp-indent-function 0)
 213 ;; (defmacro byte-compiler-options (&rest args)
 214 ;;   "Set some compilation-parameters for this file.  This will affect only the
 215 ;; file in which it appears; this does nothing when evaluated, and when loaded
 216 ;; from a .el file.
 217 ;;
 218 ;; Each argument to this macro must be a list of a key and a value.
 219 ;;
 220 ;;   Keys:                Values:               Corresponding variable:
 221 ;;
 222 ;;   verbose      t, nil                byte-compile-verbose
 223 ;;   optimize     t, nil, source, byte  byte-compile-optimize
 224 ;;   warnings     list of warnings      byte-compile-warnings
 225 ;;                    Valid elements: (callargs redefine free-vars unresolved)
 226 ;;   file-format          emacs18, emacs19      byte-compile-compatibility
 227 ;;
 228 ;; For example, this might appear at the top of a source file:
 229 ;;
 230 ;;     (byte-compiler-options
 231 ;;       (optimize t)
 232 ;;       (warnings (- free-vars))               ; Don't warn about free variables
 233 ;;       (file-format emacs19))"
 234 ;;   nil)
 235
 236 ;; arch-tag: 76f8328a-1f66-4df2-9b6d-5c3666dc05e9
 237 ;;; byte-run.el ends here