lisp/autorevert.el

   1 ;;; autorevert.el --- revert buffers when files on disk change
   2
   3 ;; Copyright (C) 1997, 1998, 1999, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Anders Lindgren <andersl@andersl.com>
   6 ;; Keywords: convenience
   7 ;; Created: 1997-06-01
   8 ;; Date: 1999-11-30
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Introduction:
  30 ;;
  31 ;; Whenever a file that Emacs is editing has been changed by another
  32 ;; program the user normally has to execute the command `revert-buffer'
  33 ;; to load the new content of the file into Emacs.
  34 ;;
  35 ;; This package contains two minor modes: Global Auto-Revert Mode and
  36 ;; Auto-Revert Mode.  Both modes automatically revert buffers
  37 ;; whenever the corresponding files have been changed on disk.
  38 ;;
  39 ;; Auto-Revert Mode can be activated for individual buffers.
  40 ;; Global Auto-Revert Mode applies to all file buffers.
  41 ;;
  42 ;; Both modes operate by checking the time stamp of all files at
  43 ;; intervals of `auto-revert-interval'.  The default is every five
  44 ;; seconds.  The check is aborted whenever the user actually uses
  45 ;; Emacs.  You should never even notice that this package is active
  46 ;; (except that your buffers will be reverted, of course).
  47
  48 ;; Usage:
  49 ;;
  50 ;; Go to the appropriate buffer and press:
  51 ;;   M-x auto-revert-mode RET
  52 ;;
  53 ;; To activate Global Auto-Revert Mode, press:
  54 ;;   M-x global-auto-revert-mode RET
  55 ;;
  56 ;; To activate Global Auto-Revert Mode every time Emacs is started
  57 ;; customise the option `global-auto-revert-mode' or the following
  58 ;; line could be added to your ~/.emacs:
  59 ;;   (global-auto-revert-mode 1)
  60 ;;
  61 ;; The function `turn-on-auto-revert-mode' could be added to any major
  62 ;; mode hook to activate Auto-Revert Mode for all buffers in that
  63 ;; mode.  For example, the following line will activate Auto-Revert
  64 ;; Mode in all C mode buffers:
  65 ;;
  66 ;; (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)
  67
  68 ;;; Code:
  69
  70 ;; Dependencies:
  71
  72 (require 'timer)
  73 (eval-when-compile (require 'cl))
  74
  75
  76 ;; Custom Group:
  77 ;;
  78 ;; The two modes will be placed next to Auto Save Mode under the
  79 ;; Files group under Emacs.
  80
  81 (defgroup auto-revert nil
  82   "Revert individual buffers when files on disk change.
  83
  84 Auto-Revert Mode can be activated for individual buffer.
  85 Global Auto-Revert Mode applies to all buffers."
  86   :group 'files
  87   :group 'convenience)
  88
  89
  90 ;; Variables:
  91
  92 ;; Autoload for the benefit of `make-mode-line-mouse-sensitive'.
  93 ;;;###autoload
  94 (defvar auto-revert-mode nil
  95   "*Non-nil when Auto-Revert Mode is active.
  96
  97 Never set this variable directly, use the command `auto-revert-mode'
  98 instead.")
  99
 100 ;;;###autoload
 101 (defcustom global-auto-revert-mode nil
 102   "When on, buffers are automatically reverted when files on disk change.
 103
 104 Set this variable using \\[customize] only.  Otherwise, use the
 105 command `global-auto-revert-mode'."
 106   :group 'auto-revert
 107   :initialize 'custom-initialize-default
 108   :set '(lambda (symbol value)
 109           (global-auto-revert-mode (or value 0)))
 110   :type 'boolean
 111   :require 'autorevert)
 112
 113 (defcustom auto-revert-interval 5
 114   "Time, in seconds, between Auto-Revert Mode file checks."
 115   :group 'auto-revert
 116   :type 'integer)
 117
 118 (defcustom auto-revert-stop-on-user-input t
 119   "When non-nil Auto-Revert Mode stops checking files on user input."
 120   :group 'auto-revert
 121   :type 'boolean)
 122
 123 (defcustom auto-revert-verbose t
 124   "When nil, Auto-Revert Mode will not generate any messages.
 125
 126 Currently, messages are generated when the mode is activated or
 127 deactivated, and whenever a file is reverted."
 128   :group 'auto-revert
 129   :type 'boolean)
 130
 131 (defcustom auto-revert-mode-text " ARev"
 132   "String to display in the mode line when Auto-Revert Mode is active.
 133
 134 \(When the string is not empty, make sure that it has a leading space.)"
 135   :tag "Auto Revert Mode Text"          ; To separate it from `global-...'
 136   :group 'auto-revert
 137   :type 'string)
 138
 139 (defcustom auto-revert-mode-hook nil
 140   "Functions to run when Auto-Revert Mode is activated."
 141   :tag "Auto Revert Mode Hook"          ; To separate it from `global-...'
 142   :group 'auto-revert
 143   :type 'hook)
 144
 145 (defcustom global-auto-revert-mode-text ""
 146   "String to display when Global Auto-Revert Mode is active.
 147
 148 The default is nothing since when this mode is active this text doesn't
 149 vary over time, or between buffers.  Hence mode line text
 150 would only waste precious space."
 151   :group 'auto-revert
 152   :type 'string)
 153
 154 (defcustom global-auto-revert-mode-hook nil
 155   "Hook called when Global Auto-Revert Mode is activated."
 156   :group 'auto-revert
 157   :type 'hook)
 158
 159 (defcustom global-auto-revert-non-file-buffers nil
 160   "*When nil only file buffers are reverted by Global Auto-Revert Mode.
 161
 162 When non-nil, both file buffers and buffers with a custom
 163 `revert-buffer-function' are reverted by Global Auto-Revert Mode."
 164   :group 'auto-revert
 165   :type 'boolean)
 166
 167 (defcustom global-auto-revert-ignore-modes '()
 168   "List of major modes Global Auto-Revert Mode should not check."
 169   :group 'auto-revert
 170   :type '(repeat sexp))
 171
 172 (defcustom auto-revert-load-hook nil
 173   "Functions to run when Auto-Revert Mode is first loaded."
 174   :tag "Load Hook"
 175   :group 'auto-revert
 176   :type 'hook)
 177
 178 (defvar global-auto-revert-ignore-buffer nil
 179   "*When non-nil, Global Auto-Revert Mode will not revert this buffer.
 180
 181 This variable becomes buffer local when set in any fashion.")
 182 (make-variable-buffer-local 'global-auto-revert-ignore-buffer)
 183
 184
 185 ;; Internal variables:
 186
 187 (defvar auto-revert-buffer-list '()
 188   "List of buffers in Auto-Revert Mode.
 189
 190 Note that only Auto-Revert Mode, never Global Auto-Revert Mode, adds
 191 buffers to this list.
 192
 193 The timer function `auto-revert-buffers' is responsible for purging
 194 the list of old buffers.")
 195
 196 (defvar auto-revert-timer nil
 197   "Timer used by Auto-Revert Mode.")
 198
 199 (defvar auto-revert-remaining-buffers '()
 200   "Buffers not checked when user input stopped execution.")
 201
 202
 203 ;; Functions:
 204
 205 ;;;###autoload
 206 (defun auto-revert-mode (&optional arg)
 207   "Toggle reverting buffer when file on disk changes.
 208
 209 With arg, turn Auto Revert mode on if and only if arg is positive.
 210 This is a minor mode that affects only the current buffer.
 211 Use `global-auto-revert-mode' to automatically revert all buffers."
 212   (interactive "P")
 213   (make-local-variable 'auto-revert-mode)
 214   (put 'auto-revert-mode 'permanent-local t)
 215   (setq auto-revert-mode
 216         (if (null arg)
 217             (not auto-revert-mode)
 218           (> (prefix-numeric-value arg) 0)))
 219   (if (and auto-revert-verbose
 220            (interactive-p))
 221       (message "Auto-Revert Mode is now %s."
 222                (if auto-revert-mode "on" "off")))
 223   (if auto-revert-mode
 224       (if (not (memq (current-buffer) auto-revert-buffer-list))
 225           (push (current-buffer) auto-revert-buffer-list))
 226     (setq auto-revert-buffer-list
 227           (delq (current-buffer) auto-revert-buffer-list)))
 228   (auto-revert-set-timer)
 229   (when auto-revert-mode
 230     (auto-revert-buffers)
 231     (run-hooks 'auto-revert-mode-hook))
 232   auto-revert-mode)
 233
 234
 235 ;;;###autoload
 236 (defun turn-on-auto-revert-mode ()
 237   "Turn on Auto-Revert Mode.
 238
 239 This function is designed to be added to hooks, for example:
 240   (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)"
 241   (auto-revert-mode 1))
 242
 243
 244 ;;;###autoload
 245 (defun global-auto-revert-mode (&optional arg)
 246   "Revert any buffer when file on disk change.
 247
 248 With arg, turn Auto Revert mode on globally if and only if arg is positive.
 249 This is a minor mode that affects all buffers.
 250 Use `auto-revert-mode' to revert a particular buffer."
 251   (interactive "P")
 252   (setq global-auto-revert-mode
 253         (if (null arg)
 254             (not global-auto-revert-mode)
 255           (> (prefix-numeric-value arg) 0)))
 256   (if (and auto-revert-verbose
 257            (interactive-p))
 258       (message "Global Auto-Revert Mode is now %s."
 259                (if global-auto-revert-mode "on" "off")))
 260   (auto-revert-set-timer)
 261   (when global-auto-revert-mode
 262     (auto-revert-buffers)
 263     (run-hooks 'global-auto-revert-mode-hook)))
 264
 265
 266 (defun auto-revert-set-timer ()
 267   "Restart or cancel the timer."
 268   (if (timerp auto-revert-timer)
 269       (cancel-timer auto-revert-timer))
 270   (if (or global-auto-revert-mode auto-revert-buffer-list)
 271       (setq auto-revert-timer (run-with-timer auto-revert-interval
 272                                               auto-revert-interval
 273                                               'auto-revert-buffers))
 274     (setq auto-revert-timer nil)))
 275
 276
 277 (defun auto-revert-buffers ()
 278   "Revert buffers as specified by Auto-Revert and Global Auto-Revert Mode.
 279
 280 Should `global-auto-revert-mode' be active all file buffers are checked.
 281
 282 Should `auto-revert-mode' be active in some buffers, those buffers
 283 are checked.
 284
 285 Non-file buffers that have a custom `revert-buffer-function' are
 286 reverted either when Auto-Revert Mode is active in that buffer, or
 287 when the variable `global-auto-revert-non-file-buffers' is non-nil
 288 and Global Auto-Revert Mode is active.
 289
 290 This function stops whenever there is user input.  The buffers not
 291 checked are stored in the variable `auto-revert-remaining-buffers'.
 292
 293 To avoid starvation, the buffers in `auto-revert-remaining-buffers'
 294 are checked first the next time this function is called.
 295
 296 This function is also responsible for removing buffers no longer in
 297 Auto-Revert mode from `auto-revert-buffer-list', and for canceling
 298 the timer when no buffers need to be checked."
 299   (let ((bufs (if global-auto-revert-mode
 300                   (buffer-list)
 301                 auto-revert-buffer-list))
 302         (remaining '())
 303         (new '()))
 304     ;; Partition `bufs' into two halves depending on whether or not
 305     ;; the buffers are in `auto-revert-remaining-buffers'.  The two
 306     ;; halves are then re-joined with the "remaining" buffers at the
 307     ;; head of the list.
 308     (dolist (buf auto-revert-remaining-buffers)
 309       (if (memq buf bufs)
 310           (push buf remaining)))
 311     (dolist (buf bufs)
 312       (if (not (memq buf remaining))
 313           (push buf new)))
 314     (setq bufs (nreverse (nconc new remaining)))
 315     (while (and bufs
 316                 (not (and auto-revert-stop-on-user-input
 317                           (input-pending-p))))
 318       (let ((buf (car bufs)))
 319         (if (buffer-name buf)           ; Buffer still alive?
 320             (save-excursion
 321               (set-buffer buf)
 322               ;; Test if someone has turned off Auto-Revert Mode in a
 323               ;; non-standard way, for example by changing major mode.
 324               (if (and (not auto-revert-mode)
 325                        (memq buf auto-revert-buffer-list))
 326                   (setq auto-revert-buffer-list
 327                         (delq buf auto-revert-buffer-list)))
 328               (when (and
 329                      (or auto-revert-mode
 330                          (and
 331                           global-auto-revert-mode
 332                           (not global-auto-revert-ignore-buffer)
 333                           (not (memq major-mode
 334                                      global-auto-revert-ignore-modes))))
 335                      (not (buffer-modified-p))
 336                      (if (buffer-file-name)
 337                          (and (file-readable-p (buffer-file-name))
 338                               (not (verify-visited-file-modtime buf)))
 339                        (and revert-buffer-function
 340                             (or (and global-auto-revert-mode
 341                                      global-auto-revert-non-file-buffers)
 342                                 auto-revert-mode))))
 343                 (if auto-revert-verbose
 344                     (message "Reverting buffer `%s'." buf))
 345                 (revert-buffer t t t)))
 346           ;; Remove dead buffer from `auto-revert-buffer-list'.
 347           (setq auto-revert-buffer-list
 348                 (delq buf auto-revert-buffer-list))))
 349       (setq bufs (cdr bufs)))
 350     (setq auto-revert-remaining-buffers bufs)
 351     ;; Check if we should cancel the timer.
 352     (when (and (not global-auto-revert-mode)
 353                (null auto-revert-buffer-list))
 354       (cancel-timer auto-revert-timer)
 355       (setq auto-revert-timer nil))))
 356
 357
 358 ;; The end:
 359
 360 (unless (assq 'auto-revert-mode minor-mode-alist)
 361   (push '(auto-revert-mode auto-revert-mode-text)
 362         minor-mode-alist))
 363 (unless (assq 'global-auto-revert-mode minor-mode-alist)
 364   (push '(global-auto-revert-mode global-auto-revert-mode-text)
 365         minor-mode-alist))
 366
 367 (provide 'autorevert)
 368
 369 (run-hooks 'auto-revert-load-hook)
 370
 371 ;; This makes it possible to set Global Auto-Revert Mode from
 372 ;; Customize.
 373 (if global-auto-revert-mode
 374     (global-auto-revert-mode 1))
 375
 376 ;;; autorevert.el ends here