lisp/gnus/mml.el

   1 ;;; mml.el --- A package for parsing and validating MML documents
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  22 ;; Boston, MA 02110-1301, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'mm-util)
  29 (require 'mm-bodies)
  30 (require 'mm-encode)
  31 (require 'mm-decode)
  32 (require 'mml-sec)
  33 (eval-when-compile (require 'cl))
  34
  35 (eval-and-compile
  36   (autoload 'message-make-message-id "message")
  37   (autoload 'gnus-setup-posting-charset "gnus-msg")
  38   (autoload 'gnus-add-minor-mode "gnus-ems")
  39   (autoload 'gnus-make-local-hook "gnus-util")
  40   (autoload 'message-fetch-field "message")
  41   (autoload 'message-info "message")
  42   (autoload 'fill-flowed-encode "flow-fill")
  43   (autoload 'message-posting-charset "message"))
  44
  45 (defvar gnus-article-mime-handles)
  46 (defvar gnus-mouse-2)
  47 (defvar gnus-newsrc-hashtb)
  48 (defvar message-default-charset)
  49 (defvar message-deletable-headers)
  50 (defvar message-options)
  51 (defvar message-posting-charset)
  52 (defvar message-required-mail-headers)
  53 (defvar message-required-news-headers)
  54
  55 (defcustom mml-content-type-parameters
  56   '(name access-type expiration size permission format)
  57   "*A list of acceptable parameters in MML tag.
  58 These parameters are generated in Content-Type header if exists."
  59   :version "22.1"
  60   :type '(repeat (symbol :tag "Parameter"))
  61   :group 'message)
  62
  63 (defcustom mml-content-disposition-parameters
  64   '(filename creation-date modification-date read-date)
  65   "*A list of acceptable parameters in MML tag.
  66 These parameters are generated in Content-Disposition header if exists."
  67   :version "22.1"
  68   :type '(repeat (symbol :tag "Parameter"))
  69   :group 'message)
  70
  71 (defcustom mml-insert-mime-headers-always nil
  72   "If non-nil, always put Content-Type: text/plain at top of empty parts.
  73 It is necessary to work against a bug in certain clients."
  74   :version "22.1"
  75   :type 'boolean
  76   :group 'message)
  77
  78 (defvar mml-tweak-type-alist nil
  79   "A list of (TYPE . FUNCTION) for tweaking MML parts.
  80 TYPE is a string containing a regexp to match the MIME type.  FUNCTION
  81 is a Lisp function which is called with the MML handle to tweak the
  82 part.  This variable is used only when no TWEAK parameter exists in
  83 the MML handle.")
  84
  85 (defvar mml-tweak-function-alist nil
  86   "A list of (NAME . FUNCTION) for tweaking MML parts.
  87 NAME is a string containing the name of the TWEAK parameter in the MML
  88 handle.  FUNCTION is a Lisp function which is called with the MML
  89 handle to tweak the part.")
  90
  91 (defvar mml-tweak-sexp-alist
  92   '((mml-externalize-attachments . mml-tweak-externalize-attachments))
  93   "A list of (SEXP . FUNCTION) for tweaking MML parts.
  94 SEXP is an s-expression.  If the evaluation of SEXP is non-nil, FUNCTION
  95 is called.  FUNCTION is a Lisp function which is called with the MML
  96 handle to tweak the part.")
  97
  98 (defvar mml-externalize-attachments nil
  99   "*If non-nil, local-file attachments are generated as external parts.")
 100
 101 (defvar mml-generate-multipart-alist nil
 102   "*Alist of multipart generation functions.
 103 Each entry has the form (NAME . FUNCTION), where
 104 NAME is a string containing the name of the part (without the
 105 leading \"/multipart/\"),
 106 FUNCTION is a Lisp function which is called to generate the part.
 107
 108 The Lisp function has to supply the appropriate MIME headers and the
 109 contents of this part.")
 110
 111 (defvar mml-syntax-table
 112   (let ((table (copy-syntax-table emacs-lisp-mode-syntax-table)))
 113     (modify-syntax-entry ?\\ "/" table)
 114     (modify-syntax-entry ?< "(" table)
 115     (modify-syntax-entry ?> ")" table)
 116     (modify-syntax-entry ?@ "w" table)
 117     (modify-syntax-entry ?/ "w" table)
 118     (modify-syntax-entry ?= " " table)
 119     (modify-syntax-entry ?* " " table)
 120     (modify-syntax-entry ?\; " " table)
 121     (modify-syntax-entry ?\' " " table)
 122     table))
 123
 124 (defvar mml-boundary-function 'mml-make-boundary
 125   "A function called to suggest a boundary.
 126 The function may be called several times, and should try to make a new
 127 suggestion each time.  The function is called with one parameter,
 128 which is a number that says how many times the function has been
 129 called for this message.")
 130
 131 (defvar mml-confirmation-set nil
 132   "A list of symbols, each of which disables some warning.
 133 `unknown-encoding': always send messages contain characters with
 134 unknown encoding; `use-ascii': always use ASCII for those characters
 135 with unknown encoding; `multipart': always send messages with more than
 136 one charsets.")
 137
 138 (defvar mml-generate-default-type "text/plain"
 139   "Content type by which the Content-Type header can be omitted.
 140 The Content-Type header will not be put in the MIME part if the type
 141 equals the value and there's no parameter (e.g. charset, format, etc.)
 142 and `mml-insert-mime-headers-always' is nil.  The value will be bound
 143 to \"message/rfc822\" when encoding an article to be forwarded as a MIME
 144 part.  This is for the internal use, you should never modify the value.")
 145
 146 (defvar mml-buffer-list nil)
 147
 148 (defun mml-generate-new-buffer (name)
 149   (let ((buf (generate-new-buffer name)))
 150     (push buf mml-buffer-list)
 151     buf))
 152
 153 (defun mml-destroy-buffers ()
 154   (let (kill-buffer-hook)
 155     (mapcar 'kill-buffer mml-buffer-list)
 156     (setq mml-buffer-list nil)))
 157
 158 (defun mml-parse ()
 159   "Parse the current buffer as an MML document."
 160   (save-excursion
 161     (goto-char (point-min))
 162     (let ((table (syntax-table)))
 163       (unwind-protect
 164           (progn
 165             (set-syntax-table mml-syntax-table)
 166             (mml-parse-1))
 167         (set-syntax-table table)))))
 168
 169 (defun mml-parse-1 ()
 170   "Parse the current buffer as an MML document."
 171   (let (struct tag point contents charsets warn use-ascii no-markup-p raw)
 172     (while (and (not (eobp))
 173                 (not (looking-at "<#/multipart")))
 174       (cond
 175        ((looking-at "<#secure")
 176         ;; The secure part is essentially a meta-meta tag, which
 177         ;; expands to either a part tag if there are no other parts in
 178         ;; the document or a multipart tag if there are other parts
 179         ;; included in the message
 180         (let* (secure-mode
 181                (taginfo (mml-read-tag))
 182                (recipients (cdr (assq 'recipients taginfo)))
 183                (sender (cdr (assq 'sender taginfo)))
 184                (location (cdr (assq 'tag-location taginfo)))
 185                (mode (cdr (assq 'mode taginfo)))
 186                (method (cdr (assq 'method taginfo)))
 187                tags)
 188           (save-excursion
 189             (if
 190                 (re-search-forward
 191                  "<#\\(/\\)?\\(multipart\\|part\\|external\\|mml\\)." nil t)
 192                 (setq secure-mode "multipart")
 193               (setq secure-mode "part")))
 194           (save-excursion
 195             (goto-char location)
 196             (re-search-forward "<#secure[^\n]*>\n"))
 197           (delete-region (match-beginning 0) (match-end 0))
 198           (cond ((string= mode "sign")
 199                  (setq tags (list "sign" method)))
 200                 ((string= mode "encrypt")
 201                  (setq tags (list "encrypt" method)))
 202                 ((string= mode "signencrypt")
 203                  (setq tags (list "sign" method "encrypt" method))))
 204           (eval `(mml-insert-tag ,secure-mode
 205                                  ,@tags
 206                                  ,(if recipients "recipients")
 207                                  ,recipients
 208                                  ,(if sender "sender")
 209                                  ,sender))
 210           ;; restart the parse
 211           (goto-char location)))
 212        ((looking-at "<#multipart")
 213         (push (nconc (mml-read-tag) (mml-parse-1)) struct))
 214        ((looking-at "<#external")
 215         (push (nconc (mml-read-tag) (list (cons 'contents (mml-read-part))))
 216               struct))
 217        (t
 218         (if (or (looking-at "<#part") (looking-at "<#mml"))
 219             (setq tag (mml-read-tag)
 220                   no-markup-p nil
 221                   warn nil)
 222           (setq tag (list 'part '(type . "text/plain"))
 223                 no-markup-p t
 224                 warn t))
 225         (setq raw (cdr (assq 'raw tag))
 226               point (point)
 227               contents (mml-read-part (eq 'mml (car tag)))
 228               charsets (cond
 229                         (raw nil)
 230                         ((assq 'charset tag)
 231                          (list
 232                           (intern (downcase (cdr (assq 'charset tag))))))
 233                         (t
 234                          (mm-find-mime-charset-region point (point)
 235                                                       mm-hack-charsets))))
 236         (when (and (not raw) (memq nil charsets))
 237           (if (or (memq 'unknown-encoding mml-confirmation-set)
 238                   (message-options-get 'unknown-encoding)
 239                   (and (y-or-n-p "\
 240 Message contains characters with unknown encoding.  Really send? ")
 241                        (message-options-set 'unknown-encoding t)))
 242               (if (setq use-ascii
 243                         (or (memq 'use-ascii mml-confirmation-set)
 244                             (message-options-get 'use-ascii)
 245                             (and (y-or-n-p "Use ASCII as charset? ")
 246                                  (message-options-set 'use-ascii t))))
 247                   (setq charsets (delq nil charsets))
 248                 (setq warn nil))
 249             (error "Edit your message to remove those characters")))
 250         (if (or raw
 251                 (eq 'mml (car tag))
 252                 (< (length charsets) 2))
 253             (if (or (not no-markup-p)
 254                     (string-match "[^ \t\r\n]" contents))
 255                 ;; Don't create blank parts.
 256                 (push (nconc tag (list (cons 'contents contents)))
 257                       struct))
 258           (let ((nstruct (mml-parse-singlepart-with-multiple-charsets
 259                           tag point (point) use-ascii)))
 260             (when (and warn
 261                        (not (memq 'multipart mml-confirmation-set))
 262                        (not (message-options-get 'multipart))
 263                        (not (and (y-or-n-p (format "\
 264 A message part needs to be split into %d charset parts.  Really send? "
 265                                                    (length nstruct)))
 266                                  (message-options-set 'multipart t))))
 267               (error "Edit your message to use only one charset"))
 268             (setq struct (nconc nstruct struct)))))))
 269     (unless (eobp)
 270       (forward-line 1))
 271     (nreverse struct)))
 272
 273 (defun mml-parse-singlepart-with-multiple-charsets
 274   (orig-tag beg end &optional use-ascii)
 275   (save-excursion
 276     (save-restriction
 277       (narrow-to-region beg end)
 278       (goto-char (point-min))
 279       (let ((current (or (mm-mime-charset (mm-charset-after))
 280                          (and use-ascii 'us-ascii)))
 281             charset struct space newline paragraph)
 282         (while (not (eobp))
 283           (setq charset (mm-mime-charset (mm-charset-after)))
 284           (cond
 285            ;; The charset remains the same.
 286            ((eq charset 'us-ascii))
 287            ((or (and use-ascii (not charset))
 288                 (eq charset current))
 289             (setq space nil
 290                   newline nil
 291                   paragraph nil))
 292            ;; The initial charset was ascii.
 293            ((eq current 'us-ascii)
 294             (setq current charset
 295                   space nil
 296                   newline nil
 297                   paragraph nil))
 298            ;; We have a change in charsets.
 299            (t
 300             (push (append
 301                    orig-tag
 302                    (list (cons 'contents
 303                                (buffer-substring-no-properties
 304                                 beg (or paragraph newline space (point))))))
 305                   struct)
 306             (setq beg (or paragraph newline space (point))
 307                   current charset
 308                   space nil
 309                   newline nil
 310                   paragraph nil)))
 311           ;; Compute places where it might be nice to break the part.
 312           (cond
 313            ((memq (following-char) '(?  ?\t))
 314             (setq space (1+ (point))))
 315            ((and (eq (following-char) ?\n)
 316                  (not (bobp))
 317                  (eq (char-after (1- (point))) ?\n))
 318             (setq paragraph (point)))
 319            ((eq (following-char) ?\n)
 320             (setq newline (1+ (point)))))
 321           (forward-char 1))
 322         ;; Do the final part.
 323         (unless (= beg (point))
 324           (push (append orig-tag
 325                         (list (cons 'contents
 326                                     (buffer-substring-no-properties
 327                                      beg (point)))))
 328                 struct))
 329         struct))))
 330
 331 (defun mml-read-tag ()
 332   "Read a tag and return the contents."
 333   (let ((orig-point (point))
 334         contents name elem val)
 335     (forward-char 2)
 336     (setq name (buffer-substring-no-properties
 337                 (point) (progn (forward-sexp 1) (point))))
 338     (skip-chars-forward " \t\n")
 339     (while (not (looking-at ">[ \t]*\n?"))
 340       (setq elem (buffer-substring-no-properties
 341                   (point) (progn (forward-sexp 1) (point))))
 342       (skip-chars-forward "= \t\n")
 343       (setq val (buffer-substring-no-properties
 344                  (point) (progn (forward-sexp 1) (point))))
 345       (when (string-match "^\"\\(.*\\)\"$" val)
 346         (setq val (match-string 1 val)))
 347       (push (cons (intern elem) val) contents)
 348       (skip-chars-forward " \t\n"))
 349     (goto-char (match-end 0))
 350     ;; Don't skip the leading space.
 351     ;;(skip-chars-forward " \t\n")
 352     ;; Put the tag location into the returned contents
 353     (setq contents (append (list (cons 'tag-location orig-point)) contents))
 354     (cons (intern name) (nreverse contents))))
 355
 356 (defun mml-buffer-substring-no-properties-except-hard-newlines (start end)
 357   (let ((str (buffer-substring-no-properties start end))
 358         (bufstart start) tmp)
 359     (while (setq tmp (text-property-any start end 'hard 't))
 360       (set-text-properties (- tmp bufstart) (- tmp bufstart -1)
 361                            '(hard t) str)
 362       (setq start (1+ tmp)))
 363     str))
 364
 365 (defun mml-read-part (&optional mml)
 366   "Return the buffer up till the next part, multipart or closing part or multipart.
 367 If MML is non-nil, return the buffer up till the correspondent mml tag."
 368   (let ((beg (point)) (count 1))
 369     ;; If the tag ended at the end of the line, we go to the next line.
 370     (when (looking-at "[ \t]*\n")
 371       (forward-line 1))
 372     (if mml
 373         (progn
 374           (while (and (> count 0) (not (eobp)))
 375             (if (re-search-forward "<#\\(/\\)?mml." nil t)
 376                 (setq count (+ count (if (match-beginning 1) -1 1)))
 377               (goto-char (point-max))))
 378           (mml-buffer-substring-no-properties-except-hard-newlines
 379            beg (if (> count 0)
 380                    (point)
 381                  (match-beginning 0))))
 382       (if (re-search-forward
 383            "<#\\(/\\)?\\(multipart\\|part\\|external\\|mml\\)." nil t)
 384           (prog1
 385               (mml-buffer-substring-no-properties-except-hard-newlines
 386                beg (match-beginning 0))
 387             (if (or (not (match-beginning 1))
 388                     (equal (match-string 2) "multipart"))
 389                 (goto-char (match-beginning 0))
 390               (when (looking-at "[ \t]*\n")
 391                 (forward-line 1))))
 392         (mml-buffer-substring-no-properties-except-hard-newlines
 393          beg (goto-char (point-max)))))))
 394
 395 (defvar mml-boundary nil)
 396 (defvar mml-base-boundary "-=-=")
 397 (defvar mml-multipart-number 0)
 398
 399 (defun mml-generate-mime ()
 400   "Generate a MIME message based on the current MML document."
 401   (let ((cont (mml-parse))
 402         (mml-multipart-number mml-multipart-number))
 403     (if (not cont)
 404         nil
 405       (with-temp-buffer
 406         (if (and (consp (car cont))
 407                  (= (length cont) 1))
 408             (mml-generate-mime-1 (car cont))
 409           (mml-generate-mime-1 (nconc (list 'multipart '(type . "mixed"))
 410                                       cont)))
 411         (buffer-string)))))
 412
 413 (defun mml-generate-mime-1 (cont)
 414   (let ((mm-use-ultra-safe-encoding
 415          (or mm-use-ultra-safe-encoding (assq 'sign cont))))
 416     (save-restriction
 417       (narrow-to-region (point) (point))
 418       (mml-tweak-part cont)
 419       (cond
 420        ((or (eq (car cont) 'part) (eq (car cont) 'mml))
 421         (let* ((raw (cdr (assq 'raw cont)))
 422                (filename (cdr (assq 'filename cont)))
 423                (type (or (cdr (assq 'type cont))
 424                          (if filename
 425                              (or (mm-default-file-encoding filename)
 426                                  "application/octet-stream")
 427                            "text/plain")))
 428                coded encoding charset flowed)
 429           (if (and (not raw)
 430                    (member (car (split-string type "/")) '("text" "message")))
 431               (progn
 432                 (with-temp-buffer
 433                   (setq charset (mm-charset-to-coding-system
 434                                  (cdr (assq 'charset cont))))
 435                   (when (eq charset 'ascii)
 436                     (setq charset nil))
 437                   (cond
 438                    ((cdr (assq 'buffer cont))
 439                     (insert-buffer-substring (cdr (assq 'buffer cont))))
 440                    ((and filename
 441                          (not (equal (cdr (assq 'nofile cont)) "yes")))
 442                     (let ((coding-system-for-read charset))
 443                       (mm-insert-file-contents filename)))
 444                    ((eq 'mml (car cont))
 445                     (insert (cdr (assq 'contents cont))))
 446                    (t
 447                     (save-restriction
 448                       (narrow-to-region (point) (point))
 449                       (insert (cdr (assq 'contents cont)))
 450                       ;; Remove quotes from quoted tags.
 451                       (goto-char (point-min))
 452                       (while (re-search-forward
 453                               "<#!+/?\\(part\\|multipart\\|external\\|mml\\)"
 454                               nil t)
 455                         (delete-region (+ (match-beginning 0) 2)
 456                                        (+ (match-beginning 0) 3))))))
 457                   (cond
 458                    ((eq (car cont) 'mml)
 459                     (let ((mml-boundary (mml-compute-boundary cont))
 460                           ;; It is necessary for the case where this
 461                           ;; function is called recursively since
 462                           ;; `m-g-d-t' will be bound to "message/rfc822"
 463                           ;; when encoding an article to be forwarded.
 464                           (mml-generate-default-type "text/plain"))
 465                       (mml-to-mime))
 466                     (let ((mm-7bit-chars (concat mm-7bit-chars "\x1b")))
 467                       ;; ignore 0x1b, it is part of iso-2022-jp
 468                       (setq encoding (mm-body-7-or-8))))
 469                    ((string= (car (split-string type "/")) "message")
 470                     (let ((mm-7bit-chars (concat mm-7bit-chars "\x1b")))
 471                       ;; ignore 0x1b, it is part of iso-2022-jp
 472                       (setq encoding (mm-body-7-or-8))))
 473                    (t
 474                     ;; Only perform format=flowed filling on text/plain
 475                     ;; parts where there either isn't a format parameter
 476                     ;; in the mml tag or it says "flowed" and there
 477                     ;; actually are hard newlines in the text.
 478                     (let (use-hard-newlines)
 479                       (when (and (string= type "text/plain")
 480                                  (not (string= (cdr (assq 'sign cont)) "pgp"))
 481                                  (or (null (assq 'format cont))
 482                                      (string= (cdr (assq 'format cont))
 483                                               "flowed"))
 484                                  (setq use-hard-newlines
 485                                        (text-property-any
 486                                         (point-min) (point-max) 'hard 't)))
 487                         (fill-flowed-encode)
 488                         ;; Indicate that `mml-insert-mime-headers' should
 489                         ;; insert a "; format=flowed" string unless the
 490                         ;; user has already specified it.
 491                         (setq flowed (null (assq 'format cont)))))
 492                     (setq charset (mm-encode-body charset))
 493                     (setq encoding (mm-body-encoding
 494                                     charset (cdr (assq 'encoding cont))))))
 495                   (setq coded (buffer-string)))
 496                 (mml-insert-mime-headers cont type charset encoding flowed)
 497                 (insert "\n")
 498                 (insert coded))
 499             (mm-with-unibyte-buffer
 500               (cond
 501                ((cdr (assq 'buffer cont))
 502                 (insert (with-current-buffer (cdr (assq 'buffer cont))
 503                           (mm-with-unibyte-current-buffer
 504                             (buffer-string)))))
 505                ((and filename
 506                      (not (equal (cdr (assq 'nofile cont)) "yes")))
 507                 (let ((coding-system-for-read mm-binary-coding-system))
 508                   (mm-insert-file-contents filename nil nil nil nil t)))
 509                (t
 510                 (insert (cdr (assq 'contents cont)))))
 511               (setq encoding (mm-encode-buffer type)
 512                     coded (mm-string-as-multibyte (buffer-string))))
 513             (mml-insert-mime-headers cont type charset encoding nil)
 514             (insert "\n")
 515             (mm-with-unibyte-current-buffer
 516               (insert coded)))))
 517        ((eq (car cont) 'external)
 518         (insert "Content-Type: message/external-body")
 519         (let ((parameters (mml-parameter-string
 520                            cont '(expiration size permission)))
 521               (name (cdr (assq 'name cont)))
 522               (url (cdr (assq 'url cont))))
 523           (when name
 524             (setq name (mml-parse-file-name name))
 525             (if (stringp name)
 526                 (mml-insert-parameter
 527                  (mail-header-encode-parameter "name" name)
 528                  "access-type=local-file")
 529               (mml-insert-parameter
 530                (mail-header-encode-parameter
 531                 "name" (file-name-nondirectory (nth 2 name)))
 532                (mail-header-encode-parameter "site" (nth 1 name))
 533                (mail-header-encode-parameter
 534                 "directory" (file-name-directory (nth 2 name))))
 535               (mml-insert-parameter
 536                (concat "access-type="
 537                        (if (member (nth 0 name) '("ftp@" "anonymous@"))
 538                            "anon-ftp"
 539                          "ftp")))))
 540           (when url
 541             (mml-insert-parameter
 542              (mail-header-encode-parameter "url" url)
 543              "access-type=url"))
 544           (when parameters
 545             (mml-insert-parameter-string
 546              cont '(expiration size permission)))
 547           (insert "\n\n")
 548           (insert "Content-Type: "
 549                   (or (cdr (assq 'type cont))
 550                       (if name
 551                           (or (mm-default-file-encoding name)
 552                               "application/octet-stream")
 553                         "text/plain"))
 554                   "\n")
 555           (insert "Content-ID: " (message-make-message-id) "\n")
 556           (insert "Content-Transfer-Encoding: "
 557                   (or (cdr (assq 'encoding cont)) "binary"))
 558           (insert "\n\n")
 559           (insert (or (cdr (assq 'contents cont))))
 560           (insert "\n")))
 561        ((eq (car cont) 'multipart)
 562         (let* ((type (or (cdr (assq 'type cont)) "mixed"))
 563                (mml-generate-default-type (if (equal type "digest")
 564                                               "message/rfc822"
 565                                             "text/plain"))
 566                (handler (assoc type mml-generate-multipart-alist)))
 567           (if handler
 568               (funcall (cdr handler) cont)
 569             ;; No specific handler.  Use default one.
 570             (let ((mml-boundary (mml-compute-boundary cont)))
 571               (insert (format "Content-Type: multipart/%s; boundary=\"%s\""
 572                               type mml-boundary)
 573                       (if (cdr (assq 'start cont))
 574                           (format "; start=\"%s\"\n" (cdr (assq 'start cont)))
 575                         "\n"))
 576               (let ((cont cont) part)
 577                 (while (setq part (pop cont))
 578                   ;; Skip `multipart' and attributes.
 579                   (when (and (consp part) (consp (cdr part)))
 580                     (insert "\n--" mml-boundary "\n")
 581                     (mml-generate-mime-1 part))))
 582               (insert "\n--" mml-boundary "--\n")))))
 583        (t
 584         (error "Invalid element: %S" cont)))
 585       ;; handle sign & encrypt tags in a semi-smart way.
 586       (let ((sign-item (assoc (cdr (assq 'sign cont)) mml-sign-alist))
 587             (encrypt-item (assoc (cdr (assq 'encrypt cont))
 588                                  mml-encrypt-alist))
 589             sender recipients)
 590         (when (or sign-item encrypt-item)
 591           (when (setq sender (cdr (assq 'sender cont)))
 592             (message-options-set 'mml-sender sender)
 593             (message-options-set 'message-sender sender))
 594           (if (setq recipients (cdr (assq 'recipients cont)))
 595               (message-options-set 'message-recipients recipients))
 596           (let ((style (mml-signencrypt-style
 597                         (first (or sign-item encrypt-item)))))
 598             ;; check if: we're both signing & encrypting, both methods
 599             ;; are the same (why would they be different?!), and that
 600             ;; the signencrypt style allows for combined operation.
 601             (if (and sign-item encrypt-item (equal (first sign-item)
 602                                                    (first encrypt-item))
 603                      (equal style 'combined))
 604                 (funcall (nth 1 encrypt-item) cont t)
 605               ;; otherwise, revert to the old behavior.
 606               (when sign-item
 607                 (funcall (nth 1 sign-item) cont))
 608               (when encrypt-item
 609                 (funcall (nth 1 encrypt-item) cont)))))))))
 610
 611 (defun mml-compute-boundary (cont)
 612   "Return a unique boundary that does not exist in CONT."
 613   (let ((mml-boundary (funcall mml-boundary-function
 614                                (incf mml-multipart-number))))
 615     ;; This function tries again and again until it has found
 616     ;; a unique boundary.
 617     (while (not (catch 'not-unique
 618                   (mml-compute-boundary-1 cont))))
 619     mml-boundary))
 620
 621 (defun mml-compute-boundary-1 (cont)
 622   (let (filename)
 623     (cond
 624      ((eq (car cont) 'part)
 625       (with-temp-buffer
 626         (cond
 627          ((cdr (assq 'buffer cont))
 628           (insert-buffer-substring (cdr (assq 'buffer cont))))
 629          ((and (setq filename (cdr (assq 'filename cont)))
 630                (not (equal (cdr (assq 'nofile cont)) "yes")))
 631           (mm-insert-file-contents filename nil nil nil nil t))
 632          (t
 633           (insert (cdr (assq 'contents cont)))))
 634         (goto-char (point-min))
 635         (when (re-search-forward (concat "^--" (regexp-quote mml-boundary))
 636                                  nil t)
 637           (setq mml-boundary (funcall mml-boundary-function
 638                                       (incf mml-multipart-number)))
 639           (throw 'not-unique nil))))
 640      ((eq (car cont) 'multipart)
 641       (mapcar 'mml-compute-boundary-1 (cddr cont))))
 642     t))
 643
 644 (defun mml-make-boundary (number)
 645   (concat (make-string (% number 60) ?=)
 646           (if (> number 17)
 647               (format "%x" number)
 648             "")
 649           mml-base-boundary))
 650
 651 (defun mml-insert-mime-headers (cont type charset encoding flowed)
 652   (let (parameters id disposition description)
 653     (setq parameters
 654           (mml-parameter-string
 655            cont mml-content-type-parameters))
 656     (when (or charset
 657               parameters
 658               flowed
 659               (not (equal type mml-generate-default-type))
 660               mml-insert-mime-headers-always)
 661       (when (consp charset)
 662         (error
 663          "Can't encode a part with several charsets"))
 664       (insert "Content-Type: " type)
 665       (when charset
 666         (insert "; " (mail-header-encode-parameter
 667                       "charset" (symbol-name charset))))
 668       (when flowed
 669         (insert "; format=flowed"))
 670       (when parameters
 671         (mml-insert-parameter-string
 672          cont mml-content-type-parameters))
 673       (insert "\n"))
 674     (when (setq id (cdr (assq 'id cont)))
 675       (insert "Content-ID: " id "\n"))
 676     (setq parameters
 677           (mml-parameter-string
 678            cont mml-content-disposition-parameters))
 679     (when (or (setq disposition (cdr (assq 'disposition cont)))
 680               parameters)
 681       (insert "Content-Disposition: " (or disposition "inline"))
 682       (when parameters
 683         (mml-insert-parameter-string
 684          cont mml-content-disposition-parameters))
 685       (insert "\n"))
 686     (unless (eq encoding '7bit)
 687       (insert (format "Content-Transfer-Encoding: %s\n" encoding)))
 688     (when (setq description (cdr (assq 'description cont)))
 689       (insert "Content-Description: "
 690               (mail-encode-encoded-word-string description) "\n"))))
 691
 692 (defun mml-parameter-string (cont types)
 693   (let ((string "")
 694         value type)
 695     (while (setq type (pop types))
 696       (when (setq value (cdr (assq type cont)))
 697         ;; Strip directory component from the filename parameter.
 698         (when (eq type 'filename)
 699           (setq value (file-name-nondirectory value)))
 700         (setq string (concat string "; "
 701                              (mail-header-encode-parameter
 702                               (symbol-name type) value)))))
 703     (when (not (zerop (length string)))
 704       string)))
 705
 706 (defun mml-insert-parameter-string (cont types)
 707   (let (value type)
 708     (while (setq type (pop types))
 709       (when (setq value (cdr (assq type cont)))
 710         ;; Strip directory component from the filename parameter.
 711         (when (eq type 'filename)
 712           (setq value (file-name-nondirectory value)))
 713         (mml-insert-parameter
 714          (mail-header-encode-parameter
 715           (symbol-name type) value))))))
 716
 717 (eval-when-compile
 718   (defvar ange-ftp-name-format)
 719   (defvar efs-path-regexp))
 720 (defun mml-parse-file-name (path)
 721   (if (if (boundp 'efs-path-regexp)
 722           (string-match efs-path-regexp path)
 723         (if (boundp 'ange-ftp-name-format)
 724             (string-match (car ange-ftp-name-format) path)))
 725       (list (match-string 1 path) (match-string 2 path)
 726             (substring path (1+ (match-end 2))))
 727     path))
 728
 729 (defun mml-insert-buffer (buffer)
 730   "Insert BUFFER at point and quote any MML markup."
 731   (save-restriction
 732     (narrow-to-region (point) (point))
 733     (insert-buffer-substring buffer)
 734     (mml-quote-region (point-min) (point-max))
 735     (goto-char (point-max))))
 736
 737 ;;;
 738 ;;; Transforming MIME to MML
 739 ;;;
 740
 741 (defun mime-to-mml (&optional handles)
 742   "Translate the current buffer (which should be a message) into MML.
 743 If HANDLES is non-nil, use it instead reparsing the buffer."
 744   ;; First decode the head.
 745   (save-restriction
 746     (message-narrow-to-head)
 747     (let ((rfc2047-quote-decoded-words-containing-tspecials t))
 748       (mail-decode-encoded-word-region (point-min) (point-max))))
 749   (unless handles
 750     (setq handles (mm-dissect-buffer t)))
 751   (goto-char (point-min))
 752   (search-forward "\n\n" nil t)
 753   (delete-region (point) (point-max))
 754   (if (stringp (car handles))
 755       (mml-insert-mime handles)
 756     (mml-insert-mime handles t))
 757   (mm-destroy-parts handles)
 758   (save-restriction
 759     (message-narrow-to-head)
 760     ;; Remove them, they are confusing.
 761     (message-remove-header "Content-Type")
 762     (message-remove-header "MIME-Version")
 763     (message-remove-header "Content-Disposition")
 764     (message-remove-header "Content-Transfer-Encoding")))
 765
 766 (defun mml-to-mime ()
 767   "Translate the current buffer from MML to MIME."
 768   (message-encode-message-body)
 769   (save-restriction
 770     (message-narrow-to-headers-or-head)
 771     ;; Skip past any From_ headers.
 772     (while (looking-at "From ")
 773       (forward-line 1))
 774     (let ((mail-parse-charset message-default-charset))
 775       (mail-encode-encoded-word-buffer))))
 776
 777 (defun mml-insert-mime (handle &optional no-markup)
 778   (let (textp buffer mmlp)
 779     ;; Determine type and stuff.
 780     (unless (stringp (car handle))
 781       (unless (setq textp (equal (mm-handle-media-supertype handle) "text"))
 782         (save-excursion
 783           (set-buffer (setq buffer (mml-generate-new-buffer " *mml*")))
 784           (mm-insert-part handle)
 785           (if (setq mmlp (equal (mm-handle-media-type handle)
 786                                 "message/rfc822"))
 787               (mime-to-mml)))))
 788     (if mmlp
 789         (mml-insert-mml-markup handle nil t t)
 790       (unless (and no-markup
 791                    (equal (mm-handle-media-type handle) "text/plain"))
 792         (mml-insert-mml-markup handle buffer textp)))
 793     (cond
 794      (mmlp
 795       (insert-buffer-substring buffer)
 796       (goto-char (point-max))
 797       (insert "<#/mml>\n"))
 798      ((stringp (car handle))
 799       (mapcar 'mml-insert-mime (cdr handle))
 800       (insert "<#/multipart>\n"))
 801      (textp
 802       (let ((charset (mail-content-type-get
 803                       (mm-handle-type handle) 'charset))
 804             (start (point)))
 805         (if (eq charset 'gnus-decoded)
 806             (mm-insert-part handle)
 807           (insert (mm-decode-string (mm-get-part handle) charset)))
 808         (mml-quote-region start (point)))
 809       (goto-char (point-max)))
 810      (t
 811       (insert "<#/part>\n")))))
 812
 813 (defun mml-insert-mml-markup (handle &optional buffer nofile mmlp)
 814   "Take a MIME handle and insert an MML tag."
 815   (if (stringp (car handle))
 816       (progn
 817         (insert "<#multipart type=" (mm-handle-media-subtype handle))
 818         (let ((start (mm-handle-multipart-ctl-parameter handle 'start)))
 819           (when start
 820             (insert " start=\"" start "\"")))
 821         (insert ">\n"))
 822     (if mmlp
 823         (insert "<#mml type=" (mm-handle-media-type handle))
 824       (insert "<#part type=" (mm-handle-media-type handle)))
 825     (dolist (elem (append (cdr (mm-handle-type handle))
 826                           (cdr (mm-handle-disposition handle))))
 827       (unless (symbolp (cdr elem))
 828         (insert " " (symbol-name (car elem)) "=\"" (cdr elem) "\"")))
 829     (when (mm-handle-id handle)
 830       (insert " id=\"" (mm-handle-id handle) "\""))
 831     (when (mm-handle-disposition handle)
 832       (insert " disposition=" (car (mm-handle-disposition handle))))
 833     (when buffer
 834       (insert " buffer=\"" (buffer-name buffer) "\""))
 835     (when nofile
 836       (insert " nofile=yes"))
 837     (when (mm-handle-description handle)
 838       (insert " description=\"" (mm-handle-description handle) "\""))
 839     (insert ">\n")))
 840
 841 (defun mml-insert-parameter (&rest parameters)
 842   "Insert PARAMETERS in a nice way."
 843   (dolist (param parameters)
 844     (insert ";")
 845     (let ((point (point)))
 846       (insert " " param)
 847       (when (> (current-column) 71)
 848         (goto-char point)
 849         (insert "\n ")
 850         (end-of-line)))))
 851
 852 ;;;
 853 ;;; Mode for inserting and editing MML forms
 854 ;;;
 855
 856 (defvar mml-mode-map
 857   (let ((sign (make-sparse-keymap))
 858         (encrypt (make-sparse-keymap))
 859         (signpart (make-sparse-keymap))
 860         (encryptpart (make-sparse-keymap))
 861         (map (make-sparse-keymap))
 862         (main (make-sparse-keymap)))
 863     (define-key sign "p" 'mml-secure-message-sign-pgpmime)
 864     (define-key sign "o" 'mml-secure-message-sign-pgp)
 865     (define-key sign "s" 'mml-secure-message-sign-smime)
 866     (define-key signpart "p" 'mml-secure-sign-pgpmime)
 867     (define-key signpart "o" 'mml-secure-sign-pgp)
 868     (define-key signpart "s" 'mml-secure-sign-smime)
 869     (define-key encrypt "p" 'mml-secure-message-encrypt-pgpmime)
 870     (define-key encrypt "o" 'mml-secure-message-encrypt-pgp)
 871     (define-key encrypt "s" 'mml-secure-message-encrypt-smime)
 872     (define-key encryptpart "p" 'mml-secure-encrypt-pgpmime)
 873     (define-key encryptpart "o" 'mml-secure-encrypt-pgp)
 874     (define-key encryptpart "s" 'mml-secure-encrypt-smime)
 875     (define-key map "\C-n" 'mml-unsecure-message)
 876     (define-key map "f" 'mml-attach-file)
 877     (define-key map "b" 'mml-attach-buffer)
 878     (define-key map "e" 'mml-attach-external)
 879     (define-key map "q" 'mml-quote-region)
 880     (define-key map "m" 'mml-insert-multipart)
 881     (define-key map "p" 'mml-insert-part)
 882     (define-key map "v" 'mml-validate)
 883     (define-key map "P" 'mml-preview)
 884     (define-key map "s" sign)
 885     (define-key map "S" signpart)
 886     (define-key map "c" encrypt)
 887     (define-key map "C" encryptpart)
 888     ;;(define-key map "n" 'mml-narrow-to-part)
 889     ;; `M-m' conflicts with `back-to-indentation'.
 890     ;; (define-key main "\M-m" map)
 891     (define-key main "\C-c\C-m" map)
 892     main))
 893
 894 (easy-menu-define
 895   mml-menu mml-mode-map ""
 896   `("Attachments"
 897     ["Attach File..." mml-attach-file
 898      ,@(if (featurep 'xemacs) '(t)
 899          '(:help "Attach a file at point"))]
 900     ["Attach Buffer..." mml-attach-buffer t]
 901     ["Attach External..." mml-attach-external t]
 902     ["Insert Part..." mml-insert-part t]
 903     ["Insert Multipart..." mml-insert-multipart t]
 904     ["PGP/MIME Sign" mml-secure-message-sign-pgpmime t]
 905     ["PGP/MIME Encrypt" mml-secure-message-encrypt-pgpmime t]
 906     ["PGP Sign" mml-secure-message-sign-pgp t]
 907     ["PGP Encrypt" mml-secure-message-encrypt-pgp t]
 908     ["S/MIME Sign" mml-secure-message-sign-smime t]
 909     ["S/MIME Encrypt" mml-secure-message-encrypt-smime t]
 910     ("Secure MIME part"
 911      ["PGP/MIME Sign Part" mml-secure-sign-pgpmime t]
 912      ["PGP/MIME Encrypt Part" mml-secure-encrypt-pgpmime t]
 913      ["PGP Sign Part" mml-secure-sign-pgp t]
 914      ["PGP Encrypt Part" mml-secure-encrypt-pgp t]
 915      ["S/MIME Sign Part" mml-secure-sign-smime t]
 916      ["S/MIME Encrypt Part" mml-secure-encrypt-smime t])
 917     ["Encrypt/Sign off" mml-unsecure-message t]
 918     ;;["Narrow" mml-narrow-to-part t]
 919     ["Quote MML" mml-quote-region t]
 920     ["Validate MML" mml-validate t]
 921     ["Preview" mml-preview t]
 922     "----"
 923     ["Emacs MIME manual" (lambda () (interactive) (message-info 4))
 924      ,@(if (featurep 'xemacs) '(t)
 925          '(:help "Display the Emacs MIME manual"))]
 926     ["PGG manual" (lambda () (interactive) (message-info 16))
 927      ,@(if (featurep 'xemacs) '(t)
 928          '(:help "Display the PGG manual"))]))
 929
 930 (defvar mml-mode nil
 931   "Minor mode for editing MML.")
 932
 933 (defun mml-mode (&optional arg)
 934   "Minor mode for editing MML.
 935 MML is the MIME Meta Language, a minor mode for composing MIME articles.
 936 See Info node `(emacs-mime)Composing'.
 937
 938 \\{mml-mode-map}"
 939   (interactive "P")
 940   (when (set (make-local-variable 'mml-mode)
 941              (if (null arg) (not mml-mode)
 942                (> (prefix-numeric-value arg) 0)))
 943     (gnus-add-minor-mode 'mml-mode " MML" mml-mode-map)
 944     (easy-menu-add mml-menu mml-mode-map)
 945     (run-hooks 'mml-mode-hook)))
 946
 947 ;;;
 948 ;;; Helper functions for reading MIME stuff from the minibuffer and
 949 ;;; inserting stuff to the buffer.
 950 ;;;
 951
 952 (defun mml-minibuffer-read-file (prompt)
 953   (let* ((completion-ignored-extensions nil)
 954          (file (read-file-name prompt nil nil t)))
 955     ;; Prevent some common errors.  This is inspired by similar code in
 956     ;; VM.
 957     (when (file-directory-p file)
 958       (error "%s is a directory, cannot attach" file))
 959     (unless (file-exists-p file)
 960       (error "No such file: %s" file))
 961     (unless (file-readable-p file)
 962       (error "Permission denied: %s" file))
 963     file))
 964
 965 (defun mml-minibuffer-read-type (name &optional default)
 966   (mailcap-parse-mimetypes)
 967   (let* ((default (or default
 968                       (mm-default-file-encoding name)
 969                       ;; Perhaps here we should check what the file
 970                       ;; looks like, and offer text/plain if it looks
 971                       ;; like text/plain.
 972                       "application/octet-stream"))
 973          (string (completing-read
 974                   (format "Content type (default %s): " default)
 975                   (mapcar 'list (mailcap-mime-types)))))
 976     (if (not (equal string ""))
 977         string
 978       default)))
 979
 980 (defun mml-minibuffer-read-description ()
 981   (let ((description (read-string "One line description: ")))
 982     (when (string-match "\\`[ \t]*\\'" description)
 983       (setq description nil))
 984     description))
 985
 986 (defun mml-minibuffer-read-disposition (type &optional default)
 987   (unless default (setq default
 988                         (if (and (string-match "\\`text/" type)
 989                                  (not (string-match "\\`text/rtf\\'" type)))
 990                             "inline"
 991                           "attachment")))
 992   (let ((disposition (completing-read
 993                       (format "Disposition (default %s): " default)
 994                       '(("attachment") ("inline") (""))
 995                       nil t nil nil default)))
 996     (if (not (equal disposition ""))
 997         disposition
 998       default)))
 999
1000 (defun mml-quote-region (beg end)
1001   "Quote the MML tags in the region."
1002   (interactive "r")
1003   (save-excursion
1004     (save-restriction
1005       ;; Temporarily narrow the region to defend from changes
1006       ;; invalidating END.
1007       (narrow-to-region beg end)
1008       (goto-char (point-min))
1009       ;; Quote parts.
1010       (while (re-search-forward
1011               "<#!*/?\\(multipart\\|part\\|external\\|mml\\)" nil t)
1012         ;; Insert ! after the #.
1013         (goto-char (+ (match-beginning 0) 2))
1014         (insert "!")))))
1015
1016 (defun mml-insert-tag (name &rest plist)
1017   "Insert an MML tag described by NAME and PLIST."
1018   (when (symbolp name)
1019     (setq name (symbol-name name)))
1020   (insert "<#" name)
1021   (while plist
1022     (let ((key (pop plist))
1023           (value (pop plist)))
1024       (when value
1025         ;; Quote VALUE if it contains suspicious characters.
1026         (when (string-match "[\"'\\~/*;() \t\n]" value)
1027           (setq value (with-output-to-string
1028                         (let (print-escape-nonascii)
1029                           (prin1 value)))))
1030         (insert (format " %s=%s" key value)))))
1031   (insert ">\n"))
1032
1033 (defun mml-insert-empty-tag (name &rest plist)
1034   "Insert an empty MML tag described by NAME and PLIST."
1035   (when (symbolp name)
1036     (setq name (symbol-name name)))
1037   (apply #'mml-insert-tag name plist)
1038   (insert "<#/" name ">\n"))
1039
1040 ;;; Attachment functions.
1041
1042 (defun mml-attach-file (file &optional type description disposition)
1043   "Attach a file to the outgoing MIME message.
1044 The file is not inserted or encoded until you send the message with
1045 `\\[message-send-and-exit]' or `\\[message-send]'.
1046
1047 FILE is the name of the file to attach.  TYPE is its
1048 content-type, a string of the form \"type/subtype\".  DESCRIPTION
1049 is a one-line description of the attachment.  The DISPOSITION
1050 specifies how the attachment is intended to be displayed.  It can
1051 be either \"inline\" (displayed automatically within the message
1052 body) or \"attachment\" (separate from the body)."
1053   (interactive
1054    (let* ((file (mml-minibuffer-read-file "Attach file: "))
1055           (type (mml-minibuffer-read-type file))
1056           (description (mml-minibuffer-read-description))
1057           (disposition (mml-minibuffer-read-disposition type)))
1058      (list file type description disposition)))
1059   (mml-insert-empty-tag 'part
1060                         'type type
1061                         'filename file
1062                         'disposition (or disposition "attachment")
1063                         'description description))
1064
1065 (defun mml-attach-buffer (buffer &optional type description)
1066   "Attach a buffer to the outgoing MIME message.
1067 See `mml-attach-file' for details of operation."
1068   (interactive
1069    (let* ((buffer (read-buffer "Attach buffer: "))
1070           (type (mml-minibuffer-read-type buffer "text/plain"))
1071           (description (mml-minibuffer-read-description)))
1072      (list buffer type description)))
1073   (mml-insert-empty-tag 'part 'type type 'buffer buffer
1074                         'disposition "attachment" 'description description))
1075
1076 (defun mml-attach-external (file &optional type description)
1077   "Attach an external file into the buffer.
1078 FILE is an ange-ftp/efs specification of the part location.
1079 TYPE is the MIME type to use."
1080   (interactive
1081    (let* ((file (mml-minibuffer-read-file "Attach external file: "))
1082           (type (mml-minibuffer-read-type file))
1083           (description (mml-minibuffer-read-description)))
1084      (list file type description)))
1085   (mml-insert-empty-tag 'external 'type type 'name file
1086                         'disposition "attachment" 'description description))
1087
1088 (defun mml-insert-multipart (&optional type)
1089   (interactive (list (completing-read "Multipart type (default mixed): "
1090                                       '(("mixed") ("alternative") ("digest") ("parallel")
1091                                         ("signed") ("encrypted"))
1092                                       nil nil "mixed")))
1093   (or type
1094       (setq type "mixed"))
1095   (mml-insert-empty-tag "multipart" 'type type)
1096   (forward-line -1))
1097
1098 (defun mml-insert-part (&optional type)
1099   (interactive
1100    (list (mml-minibuffer-read-type "")))
1101   (mml-insert-tag 'part 'type type 'disposition "inline")
1102   (forward-line -1))
1103
1104 (defun mml-preview-insert-mail-followup-to ()
1105   "Insert a Mail-Followup-To header before previewing an article.
1106 Should be adopted if code in `message-send-mail' is changed."
1107   (when (and (message-mail-p)
1108              (message-subscribed-p)
1109              (not (mail-fetch-field "mail-followup-to"))
1110              (message-make-mail-followup-to))
1111     (message-position-on-field "Mail-Followup-To" "X-Draft-From")
1112     (insert (message-make-mail-followup-to))))
1113
1114 (defun mml-preview (&optional raw)
1115   "Display current buffer with Gnus, in a new buffer.
1116 If RAW, display a raw encoded MIME message."
1117   (interactive "P")
1118   (save-excursion
1119     (let* ((buf (current-buffer))
1120            (message-options message-options)
1121            (message-this-is-mail (message-mail-p))
1122            (message-this-is-news (message-news-p))
1123            (message-posting-charset (or (gnus-setup-posting-charset
1124                                          (save-restriction
1125                                            (message-narrow-to-headers-or-head)
1126                                            (message-fetch-field "Newsgroups")))
1127                                         message-posting-charset)))
1128       (message-options-set-recipient)
1129       (pop-to-buffer (generate-new-buffer
1130                       (concat (if raw "*Raw MIME preview of "
1131                                 "*MIME preview of ") (buffer-name))))
1132       (when (boundp 'gnus-buffers)
1133         (push (current-buffer) gnus-buffers))
1134       (erase-buffer)
1135       (insert-buffer-substring buf)
1136       (mml-preview-insert-mail-followup-to)
1137       (let ((message-deletable-headers (if (message-news-p)
1138                                            nil
1139                                          message-deletable-headers)))
1140         (message-generate-headers
1141          (copy-sequence (if (message-news-p)
1142                             message-required-news-headers
1143                           message-required-mail-headers))))
1144       (if (re-search-forward
1145            (concat "^" (regexp-quote mail-header-separator) "\n") nil t)
1146           (replace-match "\n"))
1147       (let ((mail-header-separator ""));; mail-header-separator is removed.
1148         (mml-to-mime))
1149       (if raw
1150           (when (fboundp 'set-buffer-multibyte)
1151             (let ((s (buffer-string)))
1152               ;; Insert the content into unibyte buffer.
1153               (erase-buffer)
1154               (mm-disable-multibyte)
1155               (insert s)))
1156         (let ((gnus-newsgroup-charset (car message-posting-charset))
1157               gnus-article-prepare-hook gnus-original-article-buffer)
1158           (run-hooks 'gnus-article-decode-hook)
1159           (let ((gnus-newsgroup-name "dummy")
1160                 (gnus-newsrc-hashtb (or gnus-newsrc-hashtb
1161                                         (gnus-make-hashtable 5))))
1162             (gnus-article-prepare-display))))
1163       ;; Disable article-mode-map.
1164       (use-local-map nil)
1165       (gnus-make-local-hook 'kill-buffer-hook)
1166       (add-hook 'kill-buffer-hook
1167                 (lambda ()
1168                   (mm-destroy-parts gnus-article-mime-handles)) nil t)
1169       (setq buffer-read-only t)
1170       (local-set-key "q" (lambda () (interactive) (kill-buffer nil)))
1171       (local-set-key "=" (lambda () (interactive) (delete-other-windows)))
1172       (local-set-key "\r"
1173                      (lambda ()
1174                        (interactive)
1175                        (widget-button-press (point))))
1176       (local-set-key gnus-mouse-2
1177                      (lambda (event)
1178                        (interactive "@e")
1179                        (widget-button-press (widget-event-point event) event)))
1180       (goto-char (point-min)))))
1181
1182 (defun mml-validate ()
1183   "Validate the current MML document."
1184   (interactive)
1185   (mml-parse))
1186
1187 (defun mml-tweak-part (cont)
1188   "Tweak a MML part."
1189   (let ((tweak (cdr (assq 'tweak cont)))
1190         func)
1191     (cond
1192      (tweak
1193       (setq func
1194             (or (cdr (assoc tweak mml-tweak-function-alist))
1195                 (intern tweak))))
1196      (mml-tweak-type-alist
1197       (let ((alist mml-tweak-type-alist)
1198             (type (or (cdr (assq 'type cont)) "text/plain")))
1199         (while alist
1200           (if (string-match (caar alist) type)
1201               (setq func (cdar alist)
1202                     alist nil)
1203             (setq alist (cdr alist)))))))
1204     (if func
1205         (funcall func cont)
1206       cont)
1207     (let ((alist mml-tweak-sexp-alist))
1208       (while alist
1209         (if (eval (caar alist))
1210             (funcall (cdar alist) cont))
1211         (setq alist (cdr alist)))))
1212   cont)
1213
1214 (defun mml-tweak-externalize-attachments (cont)
1215   "Tweak attached files as external parts."
1216   (let (filename-cons)
1217     (when (and (eq (car cont) 'part)
1218                (not (cdr (assq 'buffer cont)))
1219                (and (setq filename-cons (assq 'filename cont))
1220                     (not (equal (cdr (assq 'nofile cont)) "yes"))))
1221       (setcar cont 'external)
1222       (setcar filename-cons 'name))))
1223
1224 (provide 'mml)
1225
1226 ;;; arch-tag: 583c96cf-1ffe-451b-a5e5-4733ae9ddd12
1227 ;;; mml.el ends here