lisp/tool-bar.el

   1 ;;; tool-bar.el --- setting up the tool bar
   2 ;;
   3 ;; Copyright (C) 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5 ;;
   6 ;; Author: Dave Love <fx@gnu.org>
   7 ;; Keywords: mouse frames
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Provides `tool-bar-mode' to control display of the tool-bar and
  27 ;; bindings for the global tool bar with convenience functions
  28 ;; `tool-bar-add-item' and `tool-bar-add-item-from-menu'.
  29
  30 ;; The normal global binding for [tool-bar] (below) uses the value of
  31 ;; `tool-bar-map' as the actual keymap to define the tool bar.  Modes
  32 ;; may either bind items under the [tool-bar] prefix key of the local
  33 ;; map to add to the global bar or may set `tool-bar-map'
  34 ;; buffer-locally to override it.  (Some items are removed from the
  35 ;; global bar in modes which have `special' as their `mode-class'
  36 ;; property.)
  37
  38 ;; Todo: Somehow make tool bars easily customizable by the naive?
  39
  40 ;;; Code:
  41
  42 ;; The autoload cookie doesn't work when preloading.
  43 ;; Deleting it means invoking this command won't work
  44 ;; when you are on a tty.  I hope that won't cause too much trouble -- rms.
  45 (define-minor-mode tool-bar-mode
  46   "Toggle use of the tool bar.
  47 With numeric ARG, display the tool bar if and only if ARG is positive.
  48
  49 See `tool-bar-add-item' and `tool-bar-add-item-from-menu' for
  50 conveniently adding tool bar items."
  51   :init-value t
  52   :global t
  53   :group 'mouse
  54   :group 'frames
  55   (let ((val (if tool-bar-mode 1 0)))
  56     (dolist (frame (frame-list))
  57       (set-frame-parameter frame 'tool-bar-lines val))
  58     ;; If the user has given `default-frame-alist' a `tool-bar-lines'
  59     ;; parameter, replace it.
  60     (if (assq 'tool-bar-lines default-frame-alist)
  61         (setq default-frame-alist
  62               (cons (cons 'tool-bar-lines val)
  63                     (assq-delete-all 'tool-bar-lines
  64                                      default-frame-alist)))))
  65   (and tool-bar-mode
  66        (= 1 (length (default-value 'tool-bar-map))) ; not yet setup
  67        (tool-bar-setup)))
  68
  69 ;;;###autoload
  70 ;; Used in the Show/Hide menu, to have the toggle reflect the current frame.
  71 (defun toggle-tool-bar-mode-from-frame (&optional arg)
  72   "Toggle tool bar on or off, based on the status of the current frame.
  73 See `tool-bar-mode' for more information."
  74   (interactive (list (or current-prefix-arg 'toggle)))
  75   (if (eq arg 'toggle)
  76       (tool-bar-mode (if (> (frame-parameter nil 'tool-bar-lines) 0) 0 1))
  77     (tool-bar-mode arg)))
  78
  79 (defvar tool-bar-map (make-sparse-keymap)
  80   "Keymap for the tool bar.
  81 Define this locally to override the global tool bar.")
  82
  83 (global-set-key [tool-bar]
  84                 `(menu-item ,(purecopy "tool bar") ignore
  85                             :filter tool-bar-make-keymap))
  86
  87 (declare-function image-mask-p "image.c" (spec &optional frame))
  88
  89 (defconst tool-bar-keymap-cache (make-hash-table :weakness t :test 'equal))
  90
  91 (defun tool-bar-make-keymap (&optional ignore)
  92   "Generate an actual keymap from `tool-bar-map'.
  93 Its main job is to figure out which images to use based on the display's
  94 color capability and based on the available image libraries."
  95   (let ((key (cons (frame-terminal) tool-bar-map)))
  96     (or (gethash key tool-bar-keymap-cache)
  97         (puthash key (tool-bar-make-keymap-1) tool-bar-keymap-cache))))
  98
  99 (defun tool-bar-make-keymap-1 ()
 100   "Generate an actual keymap from `tool-bar-map', without caching."
 101   (mapcar (lambda (bind)
 102             (let (image-exp plist)
 103               (when (and (eq (car-safe (cdr-safe bind)) 'menu-item)
 104                          ;; For the format of menu-items, see node
 105                          ;; `Extended Menu Items' in the Elisp manual.
 106                          (setq plist (nthcdr (if (consp (nth 4 bind)) 5 4)
 107                                              bind))
 108                          (setq image-exp (plist-get plist :image))
 109                          (consp image-exp)
 110                          (not (eq (car image-exp) 'image))
 111                          (fboundp (car image-exp)))
 112                 (if (not (display-images-p))
 113                     (setq bind nil)
 114                   (let ((image (eval image-exp)))
 115                     (unless (and image (image-mask-p image))
 116                       (setq image (append image '(:mask heuristic))))
 117                     (setq bind (copy-sequence bind)
 118                           plist (nthcdr (if (consp (nth 4 bind)) 5 4)
 119                                         bind))
 120                     (plist-put plist :image image))))
 121               bind))
 122           tool-bar-map))
 123
 124 ;;;###autoload
 125 (defun tool-bar-add-item (icon def key &rest props)
 126   "Add an item to the tool bar.
 127 ICON names the image, DEF is the key definition and KEY is a symbol
 128 for the fake function key in the menu keymap.  Remaining arguments
 129 PROPS are additional items to add to the menu item specification.  See
 130 Info node `(elisp)Tool Bar'.  Items are added from left to right.
 131
 132 ICON is the base name of a file containing the image to use.  The
 133 function will first try to use low-color/ICON.xpm if `display-color-cells'
 134 is less or equal to 256, then ICON.xpm, then ICON.pbm, and finally
 135 ICON.xbm, using `find-image'.
 136
 137 Use this function only to make bindings in the global value of `tool-bar-map'.
 138 To define items in any other map, use `tool-bar-local-item'."
 139   (apply 'tool-bar-local-item icon def key tool-bar-map props))
 140
 141 ;;;###autoload
 142 (defun tool-bar-local-item (icon def key map &rest props)
 143   "Add an item to the tool bar in map MAP.
 144 ICON names the image, DEF is the key definition and KEY is a symbol
 145 for the fake function key in the menu keymap.  Remaining arguments
 146 PROPS are additional items to add to the menu item specification.  See
 147 Info node `(elisp)Tool Bar'.  Items are added from left to right.
 148
 149 ICON is the base name of a file containing the image to use.  The
 150 function will first try to use low-color/ICON.xpm if `display-color-cells'
 151 is less or equal to 256, then ICON.xpm, then ICON.pbm, and finally
 152 ICON.xbm, using `find-image'."
 153   (let* ((fg (face-attribute 'tool-bar :foreground))
 154          (bg (face-attribute 'tool-bar :background))
 155          (colors (nconc (if (eq fg 'unspecified) nil (list :foreground fg))
 156                         (if (eq bg 'unspecified) nil (list :background bg))))
 157          (xpm-spec (list :type 'xpm :file (concat icon ".xpm")))
 158          (xpm-lo-spec (list :type 'xpm :file
 159                             (concat "low-color/" icon ".xpm")))
 160          (pbm-spec (append (list :type 'pbm :file
 161                                  (concat icon ".pbm")) colors))
 162          (xbm-spec (append (list :type 'xbm :file
 163                                  (concat icon ".xbm")) colors))
 164          (image-exp `(find-image
 165                       (cond ((not (display-color-p))
 166                              ',(list pbm-spec xbm-spec xpm-lo-spec xpm-spec))
 167                             ((< (display-color-cells) 256)
 168                              ',(list xpm-lo-spec xpm-spec pbm-spec xbm-spec))
 169                             (t
 170                              ',(list xpm-spec pbm-spec xbm-spec))))))
 171     (define-key-after map (vector key)
 172       `(menu-item ,(symbol-name key) ,def :image ,image-exp ,@props))))
 173
 174 ;;;###autoload
 175 (defun tool-bar-add-item-from-menu (command icon &optional map &rest props)
 176   "Define tool bar binding for COMMAND in keymap MAP using the given ICON.
 177 This makes a binding for COMMAND in `tool-bar-map', copying its
 178 binding from the menu bar in MAP (which defaults to `global-map'), but
 179 modifies the binding by adding an image specification for ICON.  It
 180 finds ICON just like `tool-bar-add-item'.  PROPS are additional
 181 properties to add to the binding.
 182
 183 MAP must contain appropriate binding for `[menu-bar]' which holds a keymap.
 184
 185 Use this function only to make bindings in the global value of `tool-bar-map'.
 186 To define items in any other map, use `tool-bar-local-item-from-menu'."
 187   (apply 'tool-bar-local-item-from-menu command icon
 188          (default-value 'tool-bar-map) map props))
 189
 190 ;;;###autoload
 191 (defun tool-bar-local-item-from-menu (command icon in-map &optional from-map &rest props)
 192   "Define local tool bar binding for COMMAND using the given ICON.
 193 This makes a binding for COMMAND in IN-MAP, copying its binding from
 194 the menu bar in FROM-MAP (which defaults to `global-map'), but
 195 modifies the binding by adding an image specification for ICON.  It
 196 finds ICON just like `tool-bar-add-item'.  PROPS are additional
 197 properties to add to the binding.
 198
 199 FROM-MAP must contain appropriate binding for `[menu-bar]' which
 200 holds a keymap."
 201   (unless from-map
 202     (setq from-map global-map))
 203   (let* ((menu-bar-map (lookup-key from-map [menu-bar]))
 204          (keys (where-is-internal command menu-bar-map))
 205          (fg (face-attribute 'tool-bar :foreground))
 206          (bg (face-attribute 'tool-bar :background))
 207          (colors (nconc (if (eq fg 'unspecified) nil (list :foreground fg))
 208                         (if (eq bg 'unspecified) nil (list :background bg))))
 209          (xpm-spec (list :type 'xpm :file (concat icon ".xpm")))
 210          (xpm-lo-spec (list :type 'xpm :file
 211                             (concat "low-color/" icon ".xpm")))
 212          (pbm-spec (append (list :type 'pbm :file
 213                                  (concat icon ".pbm")) colors))
 214          (xbm-spec (append (list :type 'xbm :file
 215                                  (concat icon ".xbm")) colors))
 216          (image-exp `(find-image
 217                       (cond ((not (display-color-p))
 218                              ',(list pbm-spec xbm-spec xpm-lo-spec xpm-spec))
 219                             ((< (display-color-cells) 256)
 220                              ',(list xpm-lo-spec xpm-spec pbm-spec xbm-spec))
 221                             (t
 222                              ',(list xpm-spec pbm-spec xbm-spec)))))
 223          submap key)
 224     ;; We'll pick up the last valid entry in the list of keys if
 225     ;; there's more than one.
 226     ;; FIXME: Aren't they *all* "valid"??  --Stef
 227     (dolist (k keys)
 228       ;; We're looking for a binding of the command in a submap of
 229       ;; the menu bar map, so the key sequence must be two or more
 230       ;; long.
 231       (if (and (vectorp k)
 232                (> (length k) 1))
 233           (let ((m (lookup-key menu-bar-map (substring k 0 -1)))
 234                 ;; Last element in the bound key sequence:
 235                 (kk (aref k (1- (length k)))))
 236             (if (and (keymapp m)
 237                      (symbolp kk))
 238                 (setq submap m
 239                       key kk)))))
 240     (when (and (symbolp submap) (boundp submap))
 241       (setq submap (eval submap)))
 242     (let ((defn (assq key (cdr submap))))
 243       (if (eq (cadr defn) 'menu-item)
 244           (define-key-after in-map (vector key)
 245             (append (cdr defn) (list :image image-exp) props))
 246         (setq defn (cdr defn))
 247         (define-key-after in-map (vector key)
 248           (let ((rest (cdr defn)))
 249             ;; If the rest of the definition starts
 250             ;; with a list of menu cache info, get rid of that.
 251             (if (and (consp rest) (consp (car rest)))
 252                 (setq rest (cdr rest)))
 253             (append `(menu-item ,(car defn) ,rest)
 254                     (list :image image-exp) props)))))))
 255
 256 ;;; Set up some global items.  Additions/deletions up for grabs.
 257
 258 (defun tool-bar-setup ()
 259   ;; People say it's bad to have EXIT on the tool bar, since users
 260   ;; might inadvertently click that button.
 261   ;;(tool-bar-add-item-from-menu 'save-buffers-kill-emacs "exit")
 262   (tool-bar-add-item-from-menu 'find-file "new" nil :label "New File")
 263   (tool-bar-add-item-from-menu 'menu-find-file-existing "open")
 264   (tool-bar-add-item-from-menu 'dired "diropen")
 265   (tool-bar-add-item-from-menu 'kill-this-buffer "close")
 266   (tool-bar-add-item-from-menu 'save-buffer "save" nil
 267                                :visible '(or buffer-file-name
 268                                              (not (eq 'special
 269                                                       (get major-mode
 270                                                            'mode-class)))))
 271   (tool-bar-add-item-from-menu 'write-file "saveas" nil
 272                                :visible '(or buffer-file-name
 273                                              (not (eq 'special
 274                                                       (get major-mode
 275                                                            'mode-class)))))
 276   (tool-bar-add-item-from-menu 'undo "undo" nil
 277                                :visible '(not (eq 'special (get major-mode
 278                                                                 'mode-class))))
 279   (tool-bar-add-item-from-menu (lookup-key menu-bar-edit-menu [cut])
 280                                "cut" nil
 281                                :visible '(not (eq 'special (get major-mode
 282                                                                 'mode-class))))
 283   (tool-bar-add-item-from-menu (lookup-key menu-bar-edit-menu [copy])
 284                                "copy")
 285   (tool-bar-add-item-from-menu (lookup-key menu-bar-edit-menu [paste])
 286                                "paste" nil
 287                                :visible '(not (eq 'special (get major-mode
 288                                                                 'mode-class))))
 289   (tool-bar-add-item-from-menu 'nonincremental-search-forward "search"
 290                                nil :label "Search")
 291   ;;(tool-bar-add-item-from-menu 'ispell-buffer "spell")
 292
 293   ;; There's no icon appropriate for News and we need a command rather
 294   ;; than a lambda for Read Mail.
 295   ;;(tool-bar-add-item-from-menu 'compose-mail "mail/compose")
 296
 297   (tool-bar-add-item-from-menu 'print-buffer "print" nil :label "Print")
 298
 299   ;; tool-bar-add-item-from-menu itself operates on
 300   ;; (default-value 'tool-bar-map), but when we don't use that function,
 301   ;; we must explicitly operate on the default value.
 302
 303   (let ((tool-bar-map (default-value 'tool-bar-map)))
 304     (tool-bar-add-item "preferences" 'customize 'customize
 305                        :help "Edit preferences (customize)")
 306
 307     (tool-bar-add-item "help" (lambda ()
 308                                 (interactive)
 309                                 (popup-menu menu-bar-help-menu))
 310                        'help
 311                        :help "Pop up the Help menu")))
 312
 313
 314 (provide 'tool-bar)
 315 ;; arch-tag: 15f30f0a-d0d7-4d50-bbb7-f48fd0c8582f
 316 ;;; tool-bar.el ends here