lisp/tmm.el

   1 ;;; tmm.el --- text mode access to menu-bar
   2
   3 ;; Copyright (C) 1994, 1995, 1996, 2000, 2001
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Ilya Zakharevich <ilya@math.mps.ohio-state.edu>
   7 ;; Maintainer: FSF
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; To use this package add
  29
  30 ;; (autoload 'tmm-menubar 'tmm "Text mode substitute for menubar" t)
  31 ;; (global-set-key [f10] 'tmm-menubar)
  32 ;; to your .emacs file. You can also add your own access to different
  33 ;; menus available in Window System Emacs modeling definition after
  34 ;; tmm-menubar.
  35
  36 ;;; Code:
  37
  38 (require 'electric)
  39
  40 (defgroup tmm nil
  41   "Text mode access to menu-bar."
  42   :prefix "tmm-"
  43   :group 'menu)
  44
  45 ;;; The following will be localized, added only to pacify the compiler.
  46 (defvar tmm-short-cuts)
  47 (defvar tmm-old-mb-map nil)
  48 (defvar tmm-old-comp-map)
  49 (defvar tmm-c-prompt)
  50 (defvar tmm-km-list)
  51 (defvar tmm-next-shortcut-digit)
  52 (defvar tmm-table-undef)
  53
  54 ;;;###autoload (define-key global-map "\M-`" 'tmm-menubar)
  55 ;;;###autoload (define-key global-map [f10] 'tmm-menubar)
  56 ;;;###autoload (define-key global-map [menu-bar mouse-1] 'tmm-menubar-mouse)
  57
  58 ;;;###autoload
  59 (defun tmm-menubar (&optional x-position)
  60   "Text-mode emulation of looking and choosing from a menubar.
  61 See the documentation for `tmm-prompt'.
  62 X-POSITION, if non-nil, specifies a horizontal position within the menu bar;
  63 we make that menu bar item (the one at that position) the default choice."
  64   (interactive)
  65   (run-hooks 'menu-bar-update-hook)
  66   ;; Obey menu-bar-final-items; put those items last.
  67   (let ((menu-bar (tmm-get-keybind [menu-bar]))
  68         menu-bar-item)
  69     (let ((list menu-bar-final-items))
  70       (while list
  71         (let ((item (car list)))
  72           ;; ITEM is the name of an item that we want to put last.
  73           ;; Find it in MENU-BAR and move it to the end.
  74           (let ((this-one (assq item menu-bar)))
  75             (setq menu-bar (append (delq this-one menu-bar)
  76                                    (list this-one)))))
  77         (setq list (cdr list))))
  78     (if x-position
  79         (let ((tail menu-bar)
  80               this-one
  81               (column 0))
  82           (while (and tail (< column x-position))
  83             (setq this-one (car tail))
  84             (if (and (consp (car tail))
  85                      (consp (cdr (car tail)))
  86                      (stringp (nth 1 (car tail))))
  87                 (setq column (+ column
  88                                 (length (nth 1 (car tail)))
  89                                 1)))
  90             (setq tail (cdr tail)))
  91           (setq menu-bar-item (car this-one))))
  92     (tmm-prompt menu-bar nil menu-bar-item)))
  93
  94 ;;;###autoload
  95 (defun tmm-menubar-mouse (event)
  96   "Text-mode emulation of looking and choosing from a menubar.
  97 This command is used when you click the mouse in the menubar
  98 on a console which has no window system but does have a mouse.
  99 See the documentation for `tmm-prompt'."
 100   (interactive "e")
 101   (tmm-menubar (car (posn-x-y (event-start event)))))
 102
 103 (defcustom tmm-mid-prompt "==>"
 104   "*String to insert between shortcut and menu item.
 105 If nil, there will be no shortcuts. It should not consist only of spaces,
 106 or else the correct item might not be found in the `*Completions*' buffer."
 107   :type 'string
 108   :group 'tmm)
 109
 110 (defvar tmm-mb-map nil
 111   "A place to store minibuffer map.")
 112
 113 (defcustom tmm-completion-prompt
 114   "Press PageUp Key to reach this buffer from the minibuffer.
 115 Alternatively, you can use Up/Down keys (or your History keys) to change
 116 the item in the minibuffer, and press RET when you are done, or press the
 117 marked letters to pick up your choice.  Type C-g or ESC ESC ESC to cancel.
 118 "
 119   "*Help text to insert on the top of the completion buffer.
 120 To save space, you can set this to nil,
 121 in which case the standard introduction text is deleted too."
 122   :type '(choice string (const nil))
 123   :group 'tmm)
 124
 125 (defcustom tmm-shortcut-style '(downcase upcase)
 126   "*What letters to use as menu shortcuts.
 127 Must be either one of the symbols `downcase' or `upcase',
 128 or else a list of the two in the order you prefer."
 129   :type '(choice (const downcase)
 130                  (const upcase)
 131                  (repeat (choice (const downcase) (const upcase))))
 132   :group 'tmm)
 133
 134 (defcustom tmm-shortcut-words 2
 135   "*How many successive words to try for shortcuts, nil means all.
 136 If you use only one of `downcase' or `upcase' for `tmm-shortcut-style',
 137 specify nil for this variable."
 138   :type '(choice integer (const nil))
 139   :group 'tmm)
 140
 141 ;;;###autoload
 142 (defun tmm-prompt (menu &optional in-popup default-item)
 143   "Text-mode emulation of calling the bindings in keymap.
 144 Creates a text-mode menu of possible choices.  You can access the elements
 145 in the menu in two ways:
 146    *)  via history mechanism from minibuffer;
 147    *)  Or via completion-buffer that is automatically shown.
 148 The last alternative is currently a hack, you cannot use mouse reliably.
 149
 150 MENU is like the MENU argument to `x-popup-menu': either a
 151 keymap or an alist of alists.
 152 DEFAULT-ITEM, if non-nil, specifies an initial default choice.
 153 Its value should be an event that has a binding in MENU."
 154   ;; If the optional argument IN-POPUP is t,
 155   ;; then MENU is an alist of elements of the form (STRING . VALUE).
 156   ;; That is used for recursive calls only.
 157   (let ((gl-str "Menu bar")  ;; The menu bar itself is not a menu keymap
 158                                         ; so it doesn't have a name.
 159         tmm-km-list out history history-len tmm-table-undef tmm-c-prompt
 160         tmm-old-mb-map tmm-old-comp-map tmm-short-cuts
 161         chosen-string choice
 162         (not-menu (not (keymapp menu))))
 163     (run-hooks 'activate-menubar-hook)
 164     ;; Compute tmm-km-list from MENU.
 165     ;; tmm-km-list is an alist of (STRING . MEANING).
 166     ;; It has no other elements.
 167     ;; The order of elements in tmm-km-list is the order of the menu bar.
 168     (mapc (lambda (elt)
 169             (if (stringp elt)
 170                 (setq gl-str elt)
 171               (and (listp elt) (tmm-get-keymap elt not-menu))))
 172             menu)
 173     ;; Choose an element of tmm-km-list; put it in choice.
 174     (if (and not-menu (= 1 (length tmm-km-list)))
 175         ;; If this is the top-level of an x-popup-menu menu,
 176         ;; and there is just one pane, choose that one silently.
 177         ;; This way we only ask the user one question,
 178         ;; for which element of that pane.
 179         (setq choice (cdr (car tmm-km-list)))
 180       (unless tmm-km-list
 181         (error "Empty menu reached"))
 182       (and tmm-km-list
 183            (let ((index-of-default 0))
 184              (if tmm-mid-prompt
 185                  (setq tmm-km-list (tmm-add-shortcuts tmm-km-list))
 186                t)
 187              ;; Find the default item's index within the menu bar.
 188              ;; We use this to decide the initial minibuffer contents
 189              ;; and initial history position.
 190              (if default-item
 191                  (let ((tail menu))
 192                    (while (and tail
 193                                (not (eq (car-safe (car tail)) default-item)))
 194                      ;; Be careful to count only the elements of MENU
 195                      ;; that actually constitute menu bar items.
 196                      (if (and (consp (car tail))
 197                               (or (stringp (car-safe (cdr (car tail))))
 198                                   (eq (car-safe (cdr (car tail))) 'menu-item)))
 199                          (setq index-of-default (1+ index-of-default)))
 200                      (setq tail (cdr tail)))))
 201              (setq history (reverse (mapcar 'car tmm-km-list)))
 202              (setq history-len (length history))
 203              (setq history (append history history history history))
 204              (setq tmm-c-prompt (nth (- history-len 1 index-of-default) history))
 205              (add-hook 'minibuffer-setup-hook 'tmm-add-prompt)
 206              (save-excursion
 207                (unwind-protect
 208                    (setq out
 209                          (completing-read
 210                           (concat gl-str " (up/down to change, PgUp to menu): ")
 211                           tmm-km-list nil t nil
 212                           (cons 'history (- (* 2 history-len) index-of-default))))
 213                  (save-excursion
 214                    (remove-hook 'minibuffer-setup-hook 'tmm-add-prompt)
 215                    (if (get-buffer "*Completions*")
 216                        (progn
 217                          (set-buffer "*Completions*")
 218                          (use-local-map tmm-old-comp-map)
 219                          (bury-buffer (current-buffer)))))
 220                  ))))
 221       (setq choice (cdr (assoc out tmm-km-list)))
 222       (and (null choice)
 223            (> (length out) (length tmm-c-prompt))
 224            (string= (substring out 0 (length tmm-c-prompt)) tmm-c-prompt)
 225            (setq out (substring out (length tmm-c-prompt))
 226                  choice (cdr (assoc out tmm-km-list))))
 227       (and (null choice) out
 228            (setq out (try-completion out tmm-km-list)
 229                  choice (cdr (assoc  out tmm-km-list)))))
 230     ;; CHOICE is now (STRING . MEANING).  Separate the two parts.
 231     (setq chosen-string (car choice))
 232     (setq choice (cdr choice))
 233     (cond (in-popup
 234            ;; We just did the inner level of a -popup menu.
 235            choice)
 236           ;; We just did the outer level.  Do the inner level now.
 237           (not-menu (tmm-prompt choice t))
 238           ;; We just handled a menu keymap and found another keymap.
 239           ((keymapp choice)
 240            (if (symbolp choice)
 241                (setq choice (indirect-function choice)))
 242            (condition-case nil
 243                (require 'mouse)
 244              (error nil))
 245            (condition-case nil
 246                (x-popup-menu nil choice) ; Get the shortcuts
 247              (error nil))
 248            (tmm-prompt choice))
 249           ;; We just handled a menu keymap and found a command.
 250           (choice
 251            (if chosen-string
 252                (progn
 253                  (setq last-command-event chosen-string)
 254                  (call-interactively choice))
 255              choice)))))
 256
 257 (defun tmm-add-shortcuts (list)
 258   "Adds shortcuts to cars of elements of the list.
 259 Takes a list of lists with a string as car, returns list with
 260 shortcuts added to these cars.
 261 Stores a list of all the shortcuts in the free variable `tmm-short-cuts'."
 262   (let ((tmm-next-shortcut-digit ?0))
 263     (mapcar 'tmm-add-one-shortcut (reverse list))))
 264
 265 (defsubst tmm-add-one-shortcut (elt)
 266 ;; uses the free vars tmm-next-shortcut-digit and tmm-short-cuts
 267   (let* ((str (car elt))
 268         (paren (string-match "(" str))
 269         (pos 0) (word 0) char)
 270     (catch 'done                        ; ??? is this slow?
 271       (while (and (or (not tmm-shortcut-words) ; no limit on words
 272                       (< word tmm-shortcut-words)) ; try n words
 273                   (setq pos (string-match "\\w+" str pos)) ; get next word
 274                   (not (and paren (> pos paren)))) ; don't go past "(binding.."
 275         (if (or (= pos 0)
 276                 (/= (aref str (1- pos)) ?.)) ; avoid file extensions
 277             (let ((shortcut-style
 278                    (if (listp tmm-shortcut-style) ; convert to list
 279                        tmm-shortcut-style
 280                      (list tmm-shortcut-style))))
 281               (while shortcut-style     ; try upcase and downcase variants
 282                 (setq char (funcall (car shortcut-style) (aref str pos)))
 283                 (if (not (memq char tmm-short-cuts)) (throw 'done char))
 284                 (setq shortcut-style (cdr shortcut-style)))))
 285         (setq word (1+ word))
 286         (setq pos (match-end 0)))
 287       (while (<= tmm-next-shortcut-digit ?9) ; no letter shortcut, pick a digit
 288         (setq char tmm-next-shortcut-digit)
 289         (setq tmm-next-shortcut-digit (1+ tmm-next-shortcut-digit))
 290         (if (not (memq char tmm-short-cuts)) (throw 'done char)))
 291       (setq char nil))
 292     (if char (setq tmm-short-cuts (cons char tmm-short-cuts)))
 293     (cons (concat (if char (concat (char-to-string char) tmm-mid-prompt)
 294                     ;; keep them lined up in columns
 295                     (make-string (1+ (length tmm-mid-prompt)) ?\ ))
 296                   str)
 297           (cdr elt))))
 298
 299 ;; This returns the old map.
 300 (defun tmm-define-keys (minibuffer)
 301   (let ((map (make-sparse-keymap)))
 302     (suppress-keymap map t)
 303     (mapc
 304      (lambda (c)
 305        (if (listp tmm-shortcut-style)
 306            (define-key map (char-to-string c) 'tmm-shortcut)
 307          ;; only one kind of letters are shortcuts, so map both upcase and
 308          ;; downcase input to the same
 309          (define-key map (char-to-string (downcase c)) 'tmm-shortcut)
 310          (define-key map (char-to-string (upcase c)) 'tmm-shortcut)))
 311      tmm-short-cuts)
 312     (if minibuffer
 313         (progn
 314           (define-key map [pageup] 'tmm-goto-completions)
 315           (define-key map [prior] 'tmm-goto-completions)
 316           (define-key map "\ev" 'tmm-goto-completions)
 317           (define-key map "\C-n" 'next-history-element)
 318           (define-key map "\C-p" 'previous-history-element)))
 319     (prog1 (current-local-map)
 320       (use-local-map (append map (current-local-map))))))
 321
 322 (defun tmm-completion-delete-prompt ()
 323   (set-buffer standard-output)
 324   (goto-char 1)
 325   (delete-region 1 (search-forward "Possible completions are:\n")))
 326
 327 (defun tmm-add-prompt ()
 328   (remove-hook 'minibuffer-setup-hook 'tmm-add-prompt)
 329   (make-local-hook 'minibuffer-exit-hook)
 330   (add-hook 'minibuffer-exit-hook 'tmm-delete-map nil t)
 331   (let ((win (selected-window)))
 332     (setq tmm-old-mb-map (tmm-define-keys t))
 333     ;; Get window and hide it for electric mode to get correct size
 334     (save-window-excursion
 335       (let ((completions
 336              (mapcar 'car minibuffer-completion-table)))
 337         (or tmm-completion-prompt
 338             (add-hook 'completion-setup-hook
 339                       'tmm-completion-delete-prompt 'append))
 340         (with-output-to-temp-buffer "*Completions*"
 341           (display-completion-list completions))
 342         (remove-hook 'completion-setup-hook 'tmm-completion-delete-prompt))
 343       (when tmm-completion-prompt
 344         (set-buffer "*Completions*")
 345         (let ((buffer-read-only nil))
 346           (goto-char (point-min))
 347           (insert tmm-completion-prompt))))
 348     (save-selected-window
 349       (other-window 1)                  ; Electric-pop-up-window does
 350                                         ; not work in minibuffer
 351       (Electric-pop-up-window "*Completions*")
 352       (with-current-buffer "*Completions*"
 353         (setq tmm-old-comp-map (tmm-define-keys nil))))
 354
 355     (insert tmm-c-prompt)))
 356
 357 (defun tmm-delete-map ()
 358   (remove-hook 'minibuffer-exit-hook 'tmm-delete-map t)
 359   (if tmm-old-mb-map
 360       (use-local-map tmm-old-mb-map)))
 361
 362 (defun tmm-shortcut ()
 363   "Choose the shortcut that the user typed."
 364   (interactive)
 365   (let ((c last-command-char) s)
 366     (if (symbolp tmm-shortcut-style)
 367         (setq c (funcall tmm-shortcut-style c)))
 368     (if (memq c tmm-short-cuts)
 369         (if (equal (buffer-name) "*Completions*")
 370             (progn
 371               (beginning-of-buffer)
 372               (re-search-forward
 373                (concat "\\(^\\|[ \t]\\)" (char-to-string c) tmm-mid-prompt))
 374               (choose-completion))
 375           ;; In minibuffer
 376           (delete-region (minibuffer-prompt-end) (point-max))
 377           (mapc (lambda (elt)
 378                   (if (string=
 379                        (substring (car elt) 0
 380                                   (min (1+ (length tmm-mid-prompt))
 381                                        (length (car elt))))
 382                        (concat (char-to-string c) tmm-mid-prompt))
 383                       (setq s (car elt))))
 384                   tmm-km-list)
 385           (insert s)
 386           (exit-minibuffer)))))
 387
 388 (defun tmm-goto-completions ()
 389   (interactive)
 390   (let ((prompt-end (minibuffer-prompt-end)))
 391     (setq tmm-c-prompt (buffer-substring prompt-end (point-max)))
 392     (delete-region prompt-end (point-max)))
 393   (switch-to-buffer-other-window "*Completions*")
 394   (search-forward tmm-c-prompt)
 395   (search-backward tmm-c-prompt))
 396
 397 (defun tmm-get-keymap (elt &optional in-x-menu)
 398   "Prepends (DOCSTRING EVENT BINDING) to free variable `tmm-km-list'.
 399 The values are deduced from the argument ELT, that should be an
 400 element of keymap, an `x-popup-menu' argument, or an element of
 401 `x-popup-menu' argument (when IN-X-MENU is not-nil).
 402 This function adds the element only if it is not already present.
 403 It uses the free variable `tmm-table-undef' to keep undefined keys."
 404   (let (km str cache plist filter (event (car elt)))
 405     (setq elt (cdr elt))
 406     (if (eq elt 'undefined)
 407         (setq tmm-table-undef (cons (cons event nil) tmm-table-undef))
 408       (unless (assoc event tmm-table-undef)
 409         (cond ((if (listp elt)
 410                    (or (keymapp elt) (eq (car elt) 'lambda))
 411                  (fboundp elt))
 412                (setq km elt))
 413
 414               ((if (listp (cdr-safe elt))
 415                    (or (keymapp (cdr-safe elt))
 416                        (eq (car (cdr-safe elt)) 'lambda))
 417                  (fboundp (cdr-safe elt)))
 418                (setq km (cdr elt))
 419                (and (stringp (car elt)) (setq str (car elt))))
 420
 421               ((if (listp (cdr-safe (cdr-safe elt)))
 422                    (or (keymapp (cdr-safe (cdr-safe elt)))
 423                        (eq (car (cdr-safe (cdr-safe elt))) 'lambda))
 424                  (fboundp (cdr-safe (cdr-safe elt))))
 425                (setq km (cdr (cdr elt)))
 426                (and (stringp (car elt)) (setq str (car elt)))
 427                (and str
 428                     (stringp (cdr (car (cdr elt)))) ; keyseq cache
 429                     (setq cache (cdr (car (cdr elt))))
 430                     cache (setq str (concat str cache))))
 431
 432               ((eq (car-safe elt) 'menu-item)
 433                ;; (menu-item TITLE COMMAND KEY ...)
 434                (setq plist (cdr-safe (cdr-safe (cdr-safe elt))))
 435                (when (consp (car-safe plist))
 436                  (setq plist (cdr-safe plist)))
 437                (setq km (nth 2 elt))
 438                (setq str (eval (nth 1 elt)))
 439                (setq filter (plist-get plist :filter))
 440                (if filter
 441                    (setq km (funcall filter km)))
 442                (and str
 443                     (consp (nth 3 elt))
 444                     (stringp (cdr (nth 3 elt))) ; keyseq cache
 445                     (setq cache (cdr (nth 3 elt)))
 446                     cache
 447                     (setq str (concat str cache))))
 448
 449               ((if (listp (cdr-safe (cdr-safe (cdr-safe elt))))
 450                    (or (keymapp (cdr-safe (cdr-safe (cdr-safe elt))))
 451                        (eq (car (cdr-safe (cdr-safe (cdr-safe elt)))) 'lambda))
 452                  (fboundp (cdr-safe (cdr-safe (cdr-safe elt)))))
 453                                          ; New style of easy-menu
 454                (setq km (cdr (cdr (cdr elt))))
 455                (and (stringp (car elt)) (setq str (car elt)))
 456                (and str
 457                     (stringp (cdr (car (cdr (cdr elt))))) ; keyseq cache
 458                     (setq cache (cdr (car (cdr (cdr elt)))))
 459                     cache (setq str (concat str cache))))
 460
 461               ((stringp event)          ; x-popup or x-popup element
 462                (if (or in-x-menu (stringp (car-safe elt)))
 463                    (setq str event event nil km elt)
 464                  (setq str event event nil km (cons 'keymap elt))
 465                  ))))
 466       (and km (stringp km) (setq str km))
 467       ;; Verify that the command is enabled;
 468       ;; if not, don't mention it.
 469       (when (and km (symbolp km) (get km 'menu-enable))
 470         (unless (eval (get km 'menu-enable))
 471           (setq km nil)))
 472       (and km str
 473            (or (assoc str tmm-km-list)
 474                (push (cons str (cons event km)) tmm-km-list))))))
 475
 476 (defun tmm-get-keybind (keyseq)
 477   "Return the current binding of KEYSEQ, merging prefix definitions.
 478 If KEYSEQ is a prefix key that has local and global bindings,
 479 we merge them into a single keymap which shows the proper order of the menu.
 480 However, for the menu bar itself, the value does not take account
 481 of `menu-bar-final-items'."
 482   (let (allbind bind)
 483     (setq bind (key-binding keyseq))
 484     ;; If KEYSEQ is a prefix key, then BIND is either nil
 485     ;; or a symbol defined as a keymap (which satisfies keymapp).
 486     (if (keymapp bind)
 487         (setq bind nil))
 488     ;; If we have a non-keymap definition, return that.
 489     (or bind
 490         (progn
 491           ;; Otherwise, it is a prefix, so make a list of the subcommands.
 492           ;; Make a list of all the bindings in all the keymaps.
 493           (setq allbind (mapcar 'cdr (minor-mode-key-binding keyseq)))
 494           (setq allbind (cons (local-key-binding keyseq) allbind))
 495           (setq allbind (cons (global-key-binding keyseq) allbind))
 496           ;; Merge all the elements of ALLBIND into one keymap.
 497           (mapc (lambda (in)
 498                   (if (and (symbolp in) (keymapp in))
 499                       (setq in (symbol-function in)))
 500                   (and in (keymapp in)
 501                        (if (keymapp bind)
 502                            (setq bind (nconc bind (copy-sequence (cdr in))))
 503                          (setq bind (copy-sequence in)))))
 504                   allbind)
 505           ;; Return that keymap.
 506           bind))))
 507
 508 (add-hook 'calendar-load-hook (lambda () (require 'cal-menu)))
 509
 510 (provide 'tmm)
 511
 512 ;;; tmm.el ends here