lisp/indent.el

   1 ;;; indent.el --- indentation commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1995 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22
  23 ;;; Commentary:
  24
  25 ;; Commands for making and changing indentation in text.  These are
  26 ;; described in the Emacs manual.
  27
  28 ;;; Code:
  29
  30 (defvar standard-indent 4 "\
  31 Default number of columns for margin-changing functions to indent.")
  32
  33 (defvar indent-line-function 'indent-to-left-margin "\
  34 Function to indent current line.")
  35
  36 (defun indent-according-to-mode ()
  37   "Indent line in proper way for current major mode."
  38   (interactive)
  39   (funcall indent-line-function))
  40
  41 (defun indent-for-tab-command (&optional prefix-arg)
  42   "Indent line in proper way for current major mode."
  43   (interactive "P")
  44   (if (eq indent-line-function 'indent-to-left-margin)
  45       (insert-tab)
  46     (if prefix-arg
  47         (funcall indent-line-function prefix-arg)
  48       (funcall indent-line-function))))
  49
  50 (defun insert-tab ()
  51   (if abbrev-mode
  52       (expand-abbrev))
  53   (if indent-tabs-mode
  54       (insert ?\t)
  55     (indent-to (* tab-width (1+ (/ (current-column) tab-width))))))
  56
  57 (defun indent-rigidly (start end arg)
  58   "Indent all lines starting in the region sideways by ARG columns.
  59 Called from a program, takes three arguments, START, END and ARG."
  60   (interactive "r\np")
  61   (save-excursion
  62     (goto-char end)
  63     (setq end (point-marker))
  64     (goto-char start)
  65     (or (bolp) (forward-line 1))
  66     (while (< (point) end)
  67       (let ((indent (current-indentation))
  68             eol-flag)
  69         (save-excursion
  70           (skip-chars-forward " \t")
  71           (setq eol-flag (eolp)))
  72         (or eol-flag
  73             (indent-to (max 0 (+ indent arg)) 0))
  74         (delete-region (point) (progn (skip-chars-forward " \t") (point))))
  75       (forward-line 1))
  76     (move-marker end nil)))
  77
  78 (defun indent-line-to (column)
  79   "Indent current line to COLUMN.
  80 This function removes or adds spaces and tabs at beginning of line
  81 only if necessary.  It leaves point at end of indentation."
  82   (back-to-indentation)
  83   (let ((cur-col (current-column)))
  84     (cond ((< cur-col column)
  85            (indent-to column))
  86           ((> cur-col column) ; too far right (after tab?)
  87            (delete-region (progn (move-to-column column t) (point))
  88                           (progn (back-to-indentation) (point)))))))
  89
  90 (defun current-left-margin ()
  91   "Return the left margin to use for this line.
  92 This is the value of the buffer-local variable `left-margin' plus the value
  93 of the `left-margin' text-property at the start of the line."
  94   (save-excursion
  95     (back-to-indentation)
  96     (max 0
  97          (+ left-margin (or (get-text-property
  98                              (if (and (eobp) (not (bobp)))
  99                                  (1- (point)) (point))
 100                              'left-margin) 0)))))
 101
 102 (defun move-to-left-margin (&optional n force)
 103   "Move to the left margin of the current line.
 104 With optional argument, move forward N-1 lines first.
 105 The column moved to is the one given by the `current-left-margin' function.
 106 If the line's indentation appears to be wrong, and this command is called
 107 interactively or with optional argument FORCE, it will be fixed."
 108   (interactive (list (prefix-numeric-value current-prefix-arg) t))
 109   (beginning-of-line n)
 110   (let ((lm (current-left-margin)))
 111     (if (memq (current-justification) '(right center))
 112         (move-to-column lm)
 113       (skip-chars-forward " \t"))
 114     (let ((cc (current-column)))
 115       (cond ((> cc lm)
 116              (if (> (move-to-column lm force) lm)
 117                  ;; If lm is in a tab and we are not forcing, move before tab
 118                  (backward-char 1)))
 119             ((and force (< cc lm))
 120              (indent-to-left-margin))))))
 121
 122 ;; This is the default indent-line-function,
 123 ;; used in Fundamental Mode, Text Mode, etc.
 124 (defun indent-to-left-margin ()
 125   "Indent current line to the column given by `current-left-margin'."
 126   (indent-line-to (current-left-margin)))
 127
 128 (defun delete-to-left-margin (&optional from to)
 129   "Remove left margin indentation from a region.
 130 This deletes to the column given by `current-left-margin'.
 131 In no case will it delete non-whitespace.
 132 Args FROM and TO are optional; default is the whole buffer."
 133   (save-excursion
 134     (goto-char (or to (point-max)))
 135     (setq to (point-marker))
 136     (goto-char (or from (point-min)))
 137     (or (bolp) (forward-line 1))
 138     (while (< (point) to)
 139       (delete-region (point) (progn (move-to-left-margin nil t) (point)))
 140       (forward-line 1))
 141     (move-marker to nil)))
 142
 143 (defun set-left-margin (from to lm)
 144   "Set the left margin of the region to WIDTH.
 145 If `auto-fill-mode' is active, re-fill the region to fit the new margin."
 146   (interactive "r\nNSet left margin to column: ")
 147   (if (interactive-p) (setq lm (prefix-numeric-value lm)))
 148   (save-excursion
 149     ;; If inside indentation, start from BOL.
 150     (goto-char from)
 151     (skip-chars-backward " \t")
 152     (if (bolp) (setq from (point)))
 153     ;; Place end after whitespace
 154     (goto-char to)
 155     (skip-chars-forward " \t")
 156     (setq to (point-marker)))
 157   ;; Delete margin indentation first, but keep paragraph indentation.
 158   (delete-to-left-margin from to)
 159   (put-text-property from to 'left-margin lm)
 160   (indent-rigidly from to lm)
 161   (if auto-fill-function (save-excursion (fill-region from to nil t t)))
 162   (move-marker to nil))
 163
 164 (defun set-right-margin (from to lm)
 165   "Set the right margin of the region to WIDTH.
 166 If `auto-fill-mode' is active, re-fill the region to fit the new margin."
 167   (interactive "r\nNSet right margin to width: ")
 168   (if (interactive-p) (setq lm (prefix-numeric-value lm)))
 169   (save-excursion
 170     (goto-char from)
 171     (skip-chars-backward " \t")
 172     (if (bolp) (setq from (point))))
 173   (put-text-property from to 'right-margin lm)
 174   (if auto-fill-function (save-excursion (fill-region from to nil t t))))
 175
 176 (defun alter-text-property (from to prop func &optional object)
 177   "Programmatically change value of a text-property.
 178 For each region between FROM and TO that has a single value for PROPERTY,
 179 apply FUNCTION to that value and sets the property to the function's result.
 180 Optional fifth argument OBJECT specifies the string or buffer to operate on."
 181   (let ((begin from)
 182         end val)
 183     (while (setq val (get-text-property begin prop object)
 184                  end (text-property-not-all begin to prop val object))
 185       (put-text-property begin end prop (funcall func val) object)
 186       (setq begin end))
 187     (if (< begin to)
 188         (put-text-property begin to prop (funcall func val) object))))
 189
 190 (defun increase-left-margin (from to inc)
 191   "Increase or decrease the left-margin of the region.
 192 With no prefix argument, this adds `standard-indent' of indentation.
 193 A prefix arg (optional third arg INC noninteractively) specifies the amount
 194 to change the margin by, in characters.
 195 If `auto-fill-mode' is active, re-fill the region to fit the new margin."
 196   (interactive "*r\nP")
 197   (setq inc (if inc (prefix-numeric-value inc) standard-indent))
 198   (save-excursion
 199     (goto-char from)
 200     (skip-chars-backward " \t")
 201     (if (bolp) (setq from (point)))
 202     (goto-char to)
 203     (setq to (point-marker)))
 204   (alter-text-property from to 'left-margin
 205                        (lambda (v) (max (- left-margin) (+ inc (or v 0)))))
 206   (indent-rigidly from to inc)
 207   (if auto-fill-function (save-excursion (fill-region from to nil t t)))
 208   (move-marker to nil))
 209
 210 (defun decrease-left-margin (from to inc)
 211   "Make the left margin of the region smaller.
 212 With no prefix argument, decrease the indentation by `standard-indent'.
 213 A prefix arg (optional third arg INC noninteractively) specifies the amount
 214 to change the margin by, in characters.
 215 If `auto-fill-mode' is active, re-fill the region to fit the new margin."
 216   (interactive "*r\nP")
 217   (setq inc (if inc (prefix-numeric-value inc) standard-indent))
 218   (increase-left-margin from to (- inc)))
 219
 220 (defun increase-right-margin (from to inc)
 221   "Increase the right-margin of the region.
 222 With no prefix argument, increase the right margin by `standard-indent'.
 223 A prefix arg (optional third arg INC noninteractively) specifies the amount
 224 to change the margin by, in characters.  A negative argument decreases
 225 the right margin width.
 226 If `auto-fill-mode' is active, re-fill the region to fit the new margin."
 227   (interactive "r\nP")
 228   (if (interactive-p)
 229       (setq inc (if inc (prefix-numeric-value current-prefix-arg)
 230                   standard-indent)))
 231   (save-excursion
 232     (alter-text-property from to 'right-margin
 233        (lambda (v) (+ inc (or v 0))))
 234     (if auto-fill-function
 235         (fill-region from to nil t t))))
 236
 237 (defun decrease-right-margin (from to inc)
 238   "Make the right margin of the region smaller.
 239 With no prefix argument, decrease the right margin by `standard-indent'.
 240 A prefix arg (optional third arg INC noninteractively) specifies the amount
 241 of width to remove, in characters.  A negative argument increases
 242 the right margin width.
 243 If `auto-fill-mode' is active, re-fills region to fit in new margin."
 244   (interactive "*r\nP")
 245   (setq inc (if inc (prefix-numeric-value inc) standard-indent))
 246   (increase-right-margin from to (- inc)))
 247
 248 (defun beginning-of-line-text (&optional n)
 249   "Move to the beginning of the text on this line.
 250 With optional argument, move forward N-1 lines first.
 251 From the beginning of the line, moves past the left-margin indentation, the
 252 fill-prefix, and any indentation used for centering or right-justifying the
 253 line, but does not move past any whitespace that was explicitly inserted
 254 \(such as a tab used to indent the first line of a paragraph)."
 255   (interactive "p")
 256   (beginning-of-line n)
 257   (skip-chars-forward " \t")
 258   ;; Skip over fill-prefix.
 259   (if (and fill-prefix
 260            (not (string-equal fill-prefix "")))
 261       (if (equal fill-prefix
 262                  (buffer-substring
 263                   (point) (min (point-max) (+ (length fill-prefix) (point)))))
 264           (forward-char (length fill-prefix)))
 265     (if (and adaptive-fill-mode
 266              (looking-at adaptive-fill-regexp))
 267         (goto-char (match-end 0))))
 268   ;; Skip centering or flushright indentation
 269   (if (memq (current-justification) '(center right))
 270       (skip-chars-forward " \t")))
 271
 272 (defvar indent-region-function nil
 273   "Short cut function to indent region using `indent-according-to-mode'.
 274 A value of nil means really run `indent-according-to-mode' on each line.")
 275
 276 (defun indent-region (start end column)
 277   "Indent each nonblank line in the region.
 278 With no argument, indent each line using `indent-according-to-mode',
 279 or use `indent-region-function' to do the whole region if that's non-nil.
 280 If there is a fill prefix, make each line start with the fill prefix.
 281 With argument COLUMN, indent each line to that column.
 282 Called from a program, takes three args: START, END and COLUMN."
 283   (interactive "r\nP")
 284   (if (null column)
 285       (if fill-prefix
 286           (save-excursion
 287             (goto-char end)
 288             (setq end (point-marker))
 289             (goto-char start)
 290             (let ((regexp (regexp-quote fill-prefix)))
 291               (while (< (point) end)
 292                 (or (looking-at regexp)
 293                     (and (bolp) (eolp))
 294                     (insert fill-prefix))
 295                 (forward-line 1))))
 296         (if indent-region-function
 297             (funcall indent-region-function start end)
 298           (save-excursion
 299             (goto-char end)
 300             (setq end (point-marker))
 301             (goto-char start)
 302             (or (bolp) (forward-line 1))
 303             (while (< (point) end)
 304               (or (and (bolp) (eolp))
 305                   (funcall indent-line-function))
 306               (forward-line 1))
 307             (move-marker end nil))))
 308     (setq column (prefix-numeric-value column))
 309     (save-excursion
 310       (goto-char end)
 311       (setq end (point-marker))
 312       (goto-char start)
 313       (or (bolp) (forward-line 1))
 314       (while (< (point) end)
 315         (delete-region (point) (progn (skip-chars-forward " \t") (point)))
 316         (or (eolp)
 317             (indent-to column 0))
 318         (forward-line 1))
 319       (move-marker end nil))))
 320
 321 (defun indent-relative-maybe ()
 322   "Indent a new line like previous nonblank line."
 323   (interactive)
 324   (indent-relative t))
 325
 326 (defun indent-relative (&optional unindented-ok)
 327   "Space out to under next indent point in previous nonblank line.
 328 An indent point is a non-whitespace character following whitespace.
 329 If the previous nonblank line has no indent points beyond the
 330 column point starts at, `tab-to-tab-stop' is done instead."
 331   (interactive "P")
 332   (if abbrev-mode (expand-abbrev))
 333   (let ((start-column (current-column))
 334         indent)
 335     (save-excursion
 336       (beginning-of-line)
 337       (if (re-search-backward "^[^\n]" nil t)
 338           (let ((end (save-excursion (forward-line 1) (point))))
 339             (move-to-column start-column)
 340             ;; Is start-column inside a tab on this line?
 341             (if (> (current-column) start-column)
 342                 (backward-char 1))
 343             (or (looking-at "[ \t]")
 344                 unindented-ok
 345                 (skip-chars-forward "^ \t" end))
 346             (skip-chars-forward " \t" end)
 347             (or (= (point) end) (setq indent (current-column))))))
 348     (if indent
 349         (let ((opoint (point-marker)))
 350           (delete-region (point) (progn (skip-chars-backward " \t") (point)))
 351           (indent-to indent 0)
 352           (if (> opoint (point))
 353               (goto-char opoint))
 354           (move-marker opoint nil))
 355       (tab-to-tab-stop))))
 356
 357 (defvar tab-stop-list
 358   '(8 16 24 32 40 48 56 64 72 80 88 96 104 112 120)
 359   "*List of tab stop positions used by `tab-to-tab-stops'.
 360 This should be a list of integers, ordered from smallest to largest.")
 361
 362 (defvar edit-tab-stops-map nil "Keymap used in `edit-tab-stops'.")
 363 (if edit-tab-stops-map
 364     nil
 365   (setq edit-tab-stops-map (make-sparse-keymap))
 366   (define-key edit-tab-stops-map "\C-x\C-s" 'edit-tab-stops-note-changes)
 367   (define-key edit-tab-stops-map "\C-c\C-c" 'edit-tab-stops-note-changes))
 368
 369 (defvar edit-tab-stops-buffer nil
 370   "Buffer whose tab stops are being edited--in case
 371 the variable `tab-stop-list' is local in that buffer.")
 372
 373 (defun edit-tab-stops ()
 374   "Edit the tab stops used by `tab-to-tab-stop'.
 375 Creates a buffer *Tab Stops* containing text describing the tab stops.
 376 A colon indicates a column where there is a tab stop.
 377 You can add or remove colons and then do \\<edit-tab-stops-map>\\[edit-tab-stops-note-changes] to make changes take effect."
 378   (interactive)
 379   (setq edit-tab-stops-buffer (current-buffer))
 380   (switch-to-buffer (get-buffer-create "*Tab Stops*"))
 381   (use-local-map edit-tab-stops-map)
 382   (make-local-variable 'indent-tabs-mode)
 383   (setq indent-tabs-mode nil)
 384   (overwrite-mode 1)
 385   (setq truncate-lines t)
 386   (erase-buffer)
 387   (let ((tabs tab-stop-list))
 388     (while tabs
 389       (indent-to (car tabs) 0)
 390       (insert ?:)
 391       (setq tabs (cdr tabs))))
 392   (let ((count 0))
 393     (insert ?\n)
 394     (while (< count 8)
 395       (insert (+ count ?0))
 396     (insert "         ")
 397       (setq count (1+ count)))
 398     (insert ?\n)
 399     (while (> count 0)
 400       (insert "0123456789")
 401       (setq count (1- count))))
 402   (insert "\nTo install changes, type C-c C-c")
 403   (goto-char (point-min)))
 404
 405 (defun edit-tab-stops-note-changes ()
 406   "Put edited tab stops into effect."
 407   (interactive)
 408     (let (tabs)
 409       (save-excursion
 410         (goto-char 1)
 411         (end-of-line)
 412         (while (search-backward ":" nil t)
 413           (setq tabs (cons (current-column) tabs))))
 414       (bury-buffer (prog1 (current-buffer)
 415                           (switch-to-buffer edit-tab-stops-buffer)))
 416       (setq tab-stop-list tabs))
 417   (message "Tab stops installed"))
 418
 419 (defun tab-to-tab-stop ()
 420   "Insert spaces or tabs to next defined tab-stop column.
 421 The variable `tab-stop-list' is a list of columns at which there are tab stops.
 422 Use \\[edit-tab-stops] to edit them interactively."
 423   (interactive)
 424   (and abbrev-mode (= (char-syntax (preceding-char)) ?w)
 425        (expand-abbrev))
 426   (let ((tabs tab-stop-list))
 427     (while (and tabs (>= (current-column) (car tabs)))
 428       (setq tabs (cdr tabs)))
 429     (if tabs
 430         (let ((opoint (point)))
 431           (skip-chars-backward " \t")
 432           (delete-region (point) opoint)
 433           (indent-to (car tabs)))
 434       (insert ?\ ))))
 435
 436 (defun move-to-tab-stop ()
 437   "Move point to next defined tab-stop column.
 438 The variable `tab-stop-list' is a list of columns at which there are tab stops.
 439 Use \\[edit-tab-stops] to edit them interactively."
 440   (interactive)
 441   (let ((tabs tab-stop-list))
 442     (while (and tabs (>= (current-column) (car tabs)))
 443       (setq tabs (cdr tabs)))
 444     (if tabs
 445         (let ((before (point)))
 446           (move-to-column (car tabs) t)
 447           (save-excursion
 448             (goto-char before)
 449             ;; If we just added a tab, or moved over one,
 450             ;; delete any superfluous spaces before the old point.
 451             (if (and (eq (preceding-char) ?\ )
 452                      (eq (following-char) ?\t))
 453                 (let ((tabend (* (/ (current-column) tab-width) tab-width)))
 454                   (while (and (> (current-column) tabend)
 455                               (eq (preceding-char) ?\ ))
 456                     (forward-char -1))
 457                   (delete-region (point) before))))))))
 458
 459 (define-key global-map "\t" 'indent-for-tab-command)
 460 (define-key esc-map "\034" 'indent-region)
 461 (define-key ctl-x-map "\t" 'indent-rigidly)
 462 (define-key esc-map "i" 'tab-to-tab-stop)
 463
 464 ;;; indent.el ends here