lisp/mail/mailpost.el

   1 ;;; mailpost.el --- RMAIL coupler to /usr/uci/post mailer
   2
   3 ;; This is in the public domain
   4 ;; since Delp distributed it in 1986 without a copyright notice.
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; Author: Gary Delp <delp@huey.Udel.Edu>
   9 ;; Maintainer: FSF
  10 ;; Created: 13 Jan 1986
  11 ;; Keywords: mail
  12
  13 ;;; Commentary:
  14
  15 ;; Yet another mail interface.  this for the rmail system to provide
  16 ;;  the missing sendmail interface on systems without /usr/lib/sendmail,
  17 ;;   but with /usr/uci/post.
  18
  19 ;;; Code:
  20
  21 (require 'mailalias)
  22 (require 'sendmail)
  23
  24 ;; (setq send-mail-function 'post-mail-send-it)
  25
  26 (defun post-mail-send-it ()
  27   "The MH -post interface for `rmail-mail' to call.
  28 To use it, include \"(setq send-mail-function 'post-mail-send-it)\" in
  29 site-init."
  30   (let ((errbuf (if mail-interactive
  31                     (generate-new-buffer " post-mail errors")
  32                   0))
  33         temfile
  34         (tembuf (generate-new-buffer " post-mail temp"))
  35         (case-fold-search nil)
  36         delimline
  37         (mailbuf (current-buffer)))
  38     (unwind-protect
  39         (with-current-buffer tembuf
  40           (erase-buffer)
  41           (insert-buffer-substring mailbuf)
  42           (goto-char (point-max))
  43           ;; require one newline at the end.
  44           (or (= (preceding-char) ?\n)
  45               (insert ?\n))
  46           ;; Change header-delimiter to be what post-mail expects.
  47           (mail-sendmail-undelimit-header)
  48           (setq delimline (point-marker))
  49           (if mail-aliases
  50               (expand-mail-aliases (point-min) delimline))
  51           (goto-char (point-min))
  52           ;; ignore any blank lines in the header
  53           (while (and (re-search-forward "\n\n\n*" delimline t)
  54                       (< (point) delimline))
  55             (replace-match "\n"))
  56           ;; Find and handle any FCC fields.
  57           (let ((case-fold-search t))
  58             (goto-char (point-min))
  59             (if (re-search-forward "^FCC:" delimline t)
  60                 (mail-do-fcc delimline))
  61             ;; If there is a From and no Sender, put it a Sender.
  62             (goto-char (point-min))
  63             (and (re-search-forward "^From:"  delimline t)
  64                  (not (save-excursion
  65                         (goto-char (point-min))
  66                         (re-search-forward "^Sender:" delimline t)))
  67                  (progn
  68                    (forward-line 1)
  69                    (insert "Sender: " (user-login-name) "\n")))
  70             ;; don't send out a blank subject line
  71             (goto-char (point-min))
  72             (if (re-search-forward "^Subject:[ \t]*\n" delimline t)
  73                 (replace-match ""))
  74             (if mail-interactive
  75                 (with-current-buffer errbuf
  76                   (erase-buffer))))
  77           (let ((m (default-file-modes)))
  78             (unwind-protect
  79                 (progn
  80                   (set-default-file-modes 384)
  81                   (setq temfile  (make-temp-file ",rpost")))
  82               (set-default-file-modes m)))
  83           (apply 'call-process
  84                  (append (list (if (boundp 'post-mail-program)
  85                                    post-mail-program
  86                                  "/usr/uci/lib/mh/post")
  87                                nil errbuf nil
  88                                "-nofilter" "-msgid")
  89                          (if mail-interactive '("-watch") '("-nowatch"))
  90                          (list temfile)))
  91           (if mail-interactive
  92               (with-current-buffer errbuf
  93                 (goto-char (point-min))
  94                 (while (re-search-forward "\n\n* *" nil t)
  95                   (replace-match "; "))
  96                 (if (not (zerop (buffer-size)))
  97                     (error "Sending...failed to %s"
  98                            (buffer-substring (point-min) (point-max)))))))
  99       (kill-buffer tembuf)
 100       (if (bufferp errbuf)
 101           (switch-to-buffer errbuf)))))
 102
 103 (provide 'mailpost)
 104
 105 ;;; mailpost.el ends here