lisp/vc/vc-hg.el

   1 ;;; vc-hg.el --- VC backend for the mercurial version control system  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2006-2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Ivan Kanis
   6 ;; Maintainer: emacs-devel@gnu.org
   7 ;; Keywords: vc tools
   8 ;; Package: vc
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This is a mercurial version control backend
  28
  29 ;;; Thanks:
  30
  31 ;;; Bugs:
  32
  33 ;;; Installation:
  34
  35 ;;; Todo:
  36
  37 ;; 1) Implement the rest of the vc interface. See the comment at the
  38 ;; beginning of vc.el. The current status is:
  39
  40 ;; FUNCTION NAME                               STATUS
  41 ;; BACKEND PROPERTIES
  42 ;; * revision-granularity                      OK
  43 ;; STATE-QUERYING FUNCTIONS
  44 ;; * registered (file)                         OK
  45 ;; * state (file)                              OK
  46 ;; - dir-status-files (dir files uf)           OK
  47 ;; - dir-extra-headers (dir)                   OK
  48 ;; - dir-printer (fileinfo)                    OK
  49 ;; * working-revision (file)                   OK
  50 ;; * checkout-model (files)                    OK
  51 ;; - mode-line-string (file)                   NOT NEEDED
  52 ;; STATE-CHANGING FUNCTIONS
  53 ;; * register (files &optional rev comment)    OK
  54 ;; * create-repo ()                            OK
  55 ;; - responsible-p (file)                      OK
  56 ;; - receive-file (file rev)                   ?? PROBABLY NOT NEEDED
  57 ;; - unregister (file)                         OK
  58 ;; * checkin (files rev comment)               OK
  59 ;; * find-revision (file rev buffer)           OK
  60 ;; * checkout (file &optional rev)             OK
  61 ;; * revert (file &optional contents-done)     OK
  62 ;; - merge (file rev1 rev2)                    NEEDED
  63 ;; - merge-news (file)                         NEEDED
  64 ;; - steal-lock (file &optional revision)      NOT NEEDED
  65 ;; HISTORY FUNCTIONS
  66 ;; * print-log (files buffer &optional shortlog start-revision limit) OK
  67 ;; - log-view-mode ()                          OK
  68 ;; - show-log-entry (revision)                 NOT NEEDED, DEFAULT IS GOOD
  69 ;; - comment-history (file)                    NOT NEEDED
  70 ;; - update-changelog (files)                  NOT NEEDED
  71 ;; * diff (files &optional rev1 rev2 buffer)   OK
  72 ;; - revision-completion-table (files)         OK?
  73 ;; - annotate-command (file buf &optional rev) OK
  74 ;; - annotate-time ()                          OK
  75 ;; - annotate-current-time ()                  NOT NEEDED
  76 ;; - annotate-extract-revision-at-line ()      OK
  77 ;; TAG SYSTEM
  78 ;; - create-tag (dir name branchp)             OK
  79 ;; - retrieve-tag (dir name update)            OK FIXME UPDATE BUFFERS
  80 ;; MISCELLANEOUS
  81 ;; - make-version-backups-p (file)             ??
  82 ;; - previous-revision (file rev)              OK
  83 ;; - next-revision (file rev)                  OK
  84 ;; - check-headers ()                          ??
  85 ;; - delete-file (file)                        TEST IT
  86 ;; - rename-file (old new)                     OK
  87 ;; - find-file-hook ()                         added for bug#10709
  88
  89 ;; 2) Implement Stefan Monnier's advice:
  90 ;; vc-hg-registered and vc-hg-state
  91 ;; Both of those functions should be super extra careful to fail gracefully in
  92 ;; unexpected circumstances. The reason this is important is that any error
  93 ;; there will prevent the user from even looking at the file :-(
  94 ;; Ideally, just like in vc-arch and vc-cvs, checking that the file is under
  95 ;; mercurial's control and extracting the current revision should be done
  96 ;; without even using `hg' (this way even if you don't have `hg' installed,
  97 ;; Emacs is able to tell you this file is under mercurial's control).
  98
  99 ;;; History:
 100 ;;
 101
 102 ;;; Code:
 103
 104 (eval-when-compile
 105   (require 'cl-lib)
 106   (require 'vc)
 107   (require 'vc-dir))
 108
 109 ;;; Customization options
 110
 111 (defgroup vc-hg nil
 112   "VC Mercurial (hg) backend."
 113   :version "24.1"
 114   :group 'vc)
 115
 116 (defcustom vc-hg-global-switches nil
 117   "Global switches to pass to any Hg command."
 118   :type '(choice (const :tag "None" nil)
 119          (string :tag "Argument String")
 120          (repeat :tag "Argument List" :value ("") string))
 121   :version "22.2"
 122   :group 'vc-hg)
 123
 124 (defcustom vc-hg-diff-switches t ; Hg doesn't support common args like -u
 125   "String or list of strings specifying switches for Hg diff under VC.
 126 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
 127   :type '(choice (const :tag "Unspecified" nil)
 128                  (const :tag "None" t)
 129                  (string :tag "Argument String")
 130                  (repeat :tag "Argument List" :value ("") string))
 131   :version "23.1"
 132   :group 'vc-hg)
 133
 134 (defcustom vc-hg-annotate-switches nil
 135   "String or list of strings specifying switches for hg annotate under VC.
 136 If nil, use the value of `vc-annotate-switches'.  If t, use no
 137 switches."
 138   :type '(choice (const :tag "Unspecified" nil)
 139                  (const :tag "None" t)
 140                  (string :tag "Argument String")
 141                  (repeat :tag "Argument List" :value ("") string))
 142   :version "25.1"
 143   :group 'vc-hg)
 144
 145 (defcustom vc-hg-program "hg"
 146   "Name of the Mercurial executable (excluding any arguments)."
 147   :type 'string
 148   :group 'vc-hg)
 149
 150 (defcustom vc-hg-root-log-format
 151   `(,(concat "{rev}:{ifeq(branch, 'default','', '{branch}')}"
 152              ":{bookmarks}:{tags}:{author|person}"
 153              " {date|shortdate} {desc|firstline}\\n")
 154     ,(concat "^\\(?:[+@o x|-]*\\)"      ;Graph data.
 155              "\\([0-9]+\\):\\([^:]*\\)"
 156              ":\\([^:]*\\):\\([^:]*\\):\\(.*?\\)"
 157              "[ \t]+\\([0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\}\\)")
 158     ((1 'log-view-message-face)
 159      (2 'change-log-file)
 160      (3 'change-log-list)
 161      (4 'change-log-conditionals)
 162      (5 'change-log-name)
 163      (6 'change-log-date)))
 164   "Mercurial log template for `vc-hg-print-log' short format.
 165 This should be a list (TEMPLATE REGEXP KEYWORDS), where TEMPLATE
 166 is the \"--template\" argument string to pass to Mercurial,
 167 REGEXP is a regular expression matching the resulting Mercurial
 168 output, and KEYWORDS is a list of `font-lock-keywords' for
 169 highlighting the Log View buffer."
 170   :type '(list string string (repeat sexp))
 171   :group 'vc-hg
 172   :version "24.5")
 173
 174 \f
 175 ;;; Properties of the backend
 176
 177 (defvar vc-hg-history nil)
 178
 179 (defun vc-hg-revision-granularity () 'repository)
 180 (defun vc-hg-checkout-model (_files) 'implicit)
 181
 182 ;;; State querying functions
 183
 184 ;;;###autoload (defun vc-hg-registered (file)
 185 ;;;###autoload   "Return non-nil if FILE is registered with hg."
 186 ;;;###autoload   (if (vc-find-root file ".hg")       ; short cut
 187 ;;;###autoload       (progn
 188 ;;;###autoload         (load "vc-hg" nil t)
 189 ;;;###autoload         (vc-hg-registered file))))
 190
 191 ;; Modeled after the similar function in vc-bzr.el
 192 (defun vc-hg-registered (file)
 193   "Return non-nil if FILE is registered with hg."
 194   (when (vc-hg-root file)           ; short cut
 195     (let ((state (vc-hg-state file)))  ; expensive
 196       (and state (not (memq state '(ignored unregistered)))))))
 197
 198 (defun vc-hg-state (file)
 199   "Hg-specific version of `vc-state'."
 200   (setq file (expand-file-name file))
 201   (let*
 202       ((status nil)
 203        (default-directory (file-name-directory file))
 204        (out
 205         (with-output-to-string
 206           (with-current-buffer
 207               standard-output
 208             (setq status
 209                   (condition-case nil
 210                       ;; Ignore all errors.
 211                       (let ((process-environment
 212                              ;; Avoid localization of messages so we
 213                              ;; can parse the output.  Disable pager.
 214                              (append
 215                               (list "TERM=dumb" "LANGUAGE=C" "HGPLAIN=1")
 216                               process-environment)))
 217                         (process-file
 218                          vc-hg-program nil t nil
 219                          "--config" "alias.status=status"
 220                          "--config" "defaults.status="
 221                          "status" "-A" (file-relative-name file)))
 222                     ;; Some problem happened.  E.g. We can't find an `hg'
 223                     ;; executable.
 224                     (error nil)))))))
 225     (when (and (eq 0 status)
 226                (> (length out) 0)
 227                (null (string-match ".*: No such file or directory$" out)))
 228       (let ((state (aref out 0)))
 229         (cond
 230          ((eq state ?=) 'up-to-date)
 231          ((eq state ?A) 'added)
 232          ((eq state ?M) 'edited)
 233          ((eq state ?I) 'ignored)
 234          ((eq state ?R) 'removed)
 235          ((eq state ?!) 'missing)
 236          ((eq state ??) 'unregistered)
 237          ((eq state ?C) 'up-to-date) ;; Older mercurial versions use this.
 238          (t 'up-to-date))))))
 239
 240 (defun vc-hg-working-revision (file)
 241   "Hg-specific version of `vc-working-revision'."
 242   (or (ignore-errors
 243         (with-output-to-string
 244           (vc-hg-command standard-output 0 file
 245                          "parent" "--template" "{rev}")))
 246       "0"))
 247
 248 ;;; History functions
 249
 250 (defcustom vc-hg-log-switches nil
 251   "String or list of strings specifying switches for hg log under VC."
 252   :type '(choice (const :tag "None" nil)
 253                  (string :tag "Argument String")
 254                  (repeat :tag "Argument List" :value ("") string))
 255   :group 'vc-hg)
 256
 257 (autoload 'vc-setup-buffer "vc-dispatcher")
 258
 259 (defvar vc-hg-log-graph nil
 260   "If non-nil, use `--graph' in the short log output.")
 261
 262 (defvar vc-hg-log-format (concat "changeset:   {rev}:{node|short}\n"
 263                                  "{tags % 'tag:         {tag}\n'}"
 264                                  "{if(parents, 'parents:     {parents}\n')}"
 265                                  "user:        {author}\n"
 266                                  "Date:        {date|date}\n"
 267                                  "summary:     {desc|tabindent}\n\n")
 268   "Mercurial log template for `vc-hg-print-log' long format.")
 269
 270 (defun vc-hg-print-log (files buffer &optional shortlog start-revision limit)
 271   "Print commit log associated with FILES into specified BUFFER.
 272 If SHORTLOG is non-nil, use a short format based on `vc-hg-root-log-format'.
 273 If START-REVISION is non-nil, it is the newest revision to show.
 274 If LIMIT is non-nil, show no more than this many entries."
 275   ;; `vc-do-command' creates the buffer, but we need it before running
 276   ;; the command.
 277   (vc-setup-buffer buffer)
 278   ;; If the buffer exists from a previous invocation it might be
 279   ;; read-only.
 280   (let ((inhibit-read-only t))
 281     (with-current-buffer
 282         buffer
 283       (apply 'vc-hg-command buffer 'async files "log"
 284              (nconc
 285               (when start-revision (list (format "-r%s:0" start-revision)))
 286               (when limit (list "-l" (format "%s" limit)))
 287               (if shortlog
 288                   `(,@(if vc-hg-log-graph '("--graph"))
 289                     "--template"
 290                     ,(car vc-hg-root-log-format))
 291                 `("--template" ,vc-hg-log-format))
 292               vc-hg-log-switches)))))
 293
 294 (defvar log-view-message-re)
 295 (defvar log-view-file-re)
 296 (defvar log-view-font-lock-keywords)
 297 (defvar log-view-per-file-logs)
 298 (defvar log-view-expanded-log-entry-function)
 299
 300 (define-derived-mode vc-hg-log-view-mode log-view-mode "Hg-Log-View"
 301   (require 'add-log) ;; we need the add-log faces
 302   (set (make-local-variable 'log-view-file-re) "\\`a\\`")
 303   (set (make-local-variable 'log-view-per-file-logs) nil)
 304   (set (make-local-variable 'log-view-message-re)
 305        (if (eq vc-log-view-type 'short)
 306            (cadr vc-hg-root-log-format)
 307          "^changeset:[ \t]*\\([0-9]+\\):\\(.+\\)"))
 308   (set (make-local-variable 'tab-width) 2)
 309   ;; Allow expanding short log entries
 310   (when (eq vc-log-view-type 'short)
 311     (setq truncate-lines t)
 312     (set (make-local-variable 'log-view-expanded-log-entry-function)
 313          'vc-hg-expanded-log-entry))
 314   (set (make-local-variable 'log-view-font-lock-keywords)
 315        (if (eq vc-log-view-type 'short)
 316            (list (cons (nth 1 vc-hg-root-log-format)
 317                        (nth 2 vc-hg-root-log-format)))
 318          (append
 319           log-view-font-lock-keywords
 320           '(
 321             ;; Handle the case:
 322             ;; user: FirstName LastName <foo@bar>
 323             ("^user:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 324              (1 'change-log-name)
 325              (2 'change-log-email))
 326             ;; Handle the cases:
 327             ;; user: foo@bar
 328             ;; and
 329             ;; user: foo
 330             ("^user:[ \t]+\\([A-Za-z0-9_.+-]+\\(?:@[A-Za-z0-9_.-]+\\)?\\)"
 331              (1 'change-log-email))
 332             ("^date: \\(.+\\)" (1 'change-log-date))
 333             ("^tag: +\\([^ ]+\\)$" (1 'highlight))
 334             ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message)))))))
 335
 336 (autoload 'vc-switches "vc")
 337
 338 (defun vc-hg-diff (files &optional oldvers newvers buffer async)
 339   "Get a difference report using hg between two revisions of FILES."
 340   (let* ((firstfile (car files))
 341          (working (and firstfile (vc-working-revision firstfile))))
 342     (when (and (equal oldvers working) (not newvers))
 343       (setq oldvers nil))
 344     (when (and (not oldvers) newvers)
 345       (setq oldvers working))
 346     (apply #'vc-hg-command
 347            (or buffer "*vc-diff*")
 348            (if async 'async nil)
 349            files "diff"
 350            (append
 351             (vc-switches 'hg 'diff)
 352             (when oldvers
 353               (if newvers
 354                   (list "-r" oldvers "-r" newvers)
 355                 (list "-r" oldvers)))))))
 356
 357 (defun vc-hg-expanded-log-entry (revision)
 358   (with-temp-buffer
 359     (vc-hg-command t nil nil "log" "-r" revision "--template" vc-hg-log-format)
 360     (goto-char (point-min))
 361     (unless (eobp)
 362       ;; Indent the expanded log entry.
 363       (indent-region (point-min) (point-max) 2)
 364       (goto-char (point-max))
 365       (buffer-string))))
 366
 367 (defun vc-hg-revision-table (files)
 368   (let ((default-directory (file-name-directory (car files))))
 369     (with-temp-buffer
 370       (vc-hg-command t nil files "log" "--template" "{rev} ")
 371       (split-string
 372        (buffer-substring-no-properties (point-min) (point-max))))))
 373
 374 ;; Modeled after the similar function in vc-cvs.el
 375 (defun vc-hg-revision-completion-table (files)
 376   (letrec ((table (lazy-completion-table
 377                    table (lambda () (vc-hg-revision-table files)))))
 378     table))
 379
 380 (defun vc-hg-annotate-command (file buffer &optional revision)
 381   "Execute \"hg annotate\" on FILE, inserting the contents in BUFFER.
 382 Optional arg REVISION is a revision to annotate from."
 383   (apply #'vc-hg-command buffer 0 file "annotate" "-d" "-n" "--follow"
 384          (append (vc-switches 'hg 'annotate)
 385                  (if revision (list (concat "-r" revision))))))
 386
 387 (declare-function vc-annotate-convert-time "vc-annotate" (&optional time))
 388
 389 ;; The format for one line output by "hg annotate -d -n" looks like this:
 390 ;;215 Wed Jun 20 21:22:58 2007 -0700: CONTENTS
 391 ;; i.e: VERSION_NUMBER DATE: CONTENTS
 392 ;; If the user has set the "--follow" option, the output looks like:
 393 ;;215 Wed Jun 20 21:22:58 2007 -0700 foo.c: CONTENTS
 394 ;; i.e. VERSION_NUMBER DATE FILENAME: CONTENTS
 395 (defconst vc-hg-annotate-re
 396   "^[ \t]*\\([0-9]+\\) \\(.\\{30\\}\\)\\(?:\\(: \\)\\|\\(?: +\\([^:\n]+\\(?::\\(?:[^: \n][^:\n]*\\)?\\)*\\): \\)\\)")
 397
 398 (defun vc-hg-annotate-time ()
 399   (when (looking-at vc-hg-annotate-re)
 400     (goto-char (match-end 0))
 401     (vc-annotate-convert-time
 402      (date-to-time (match-string-no-properties 2)))))
 403
 404 (defun vc-hg-annotate-extract-revision-at-line ()
 405   (save-excursion
 406     (beginning-of-line)
 407     (when (looking-at vc-hg-annotate-re)
 408       (if (match-beginning 3)
 409           (match-string-no-properties 1)
 410         (cons (match-string-no-properties 1)
 411       (expand-file-name (match-string-no-properties 4)
 412  (vc-hg-root default-directory)))))))
 413
 414 ;;; Tag system
 415
 416 (defun vc-hg-create-tag (dir name branchp)
 417   "Attach the tag NAME to the state of the working copy."
 418   (let ((default-directory dir))
 419     (and (vc-hg-command nil 0 nil "status")
 420          (vc-hg-command nil 0 nil (if branchp "bookmark" "tag") name))))
 421
 422 (defun vc-hg-retrieve-tag (dir name _update)
 423   "Retrieve the version tagged by NAME of all registered files at or below DIR."
 424   (let ((default-directory dir))
 425     (vc-hg-command nil 0 nil "update" name)
 426     ;; FIXME: update buffers if `update' is true
 427     ;; TODO: update *vc-change-log* buffer so can see @ if --graph
 428     ))
 429
 430 ;;; Miscellaneous
 431
 432 (defun vc-hg-previous-revision (_file rev)
 433   (let ((newrev (1- (string-to-number rev))))
 434     (when (>= newrev 0)
 435       (number-to-string newrev))))
 436
 437 (defun vc-hg-next-revision (_file rev)
 438   (let ((newrev (1+ (string-to-number rev)))
 439         (tip-revision
 440          (with-temp-buffer
 441            (vc-hg-command t 0 nil "tip" "--style=default")
 442            (goto-char (point-min))
 443            (re-search-forward "^changeset:[ \t]*\\([0-9]+\\):")
 444            (string-to-number (match-string-no-properties 1)))))
 445     ;; We don't want to exceed the maximum possible revision number, ie
 446     ;; the tip revision.
 447     (when (<= newrev tip-revision)
 448       (number-to-string newrev))))
 449
 450 ;; Modeled after the similar function in vc-bzr.el
 451 (defun vc-hg-delete-file (file)
 452   "Delete FILE and delete it in the hg repository."
 453   (condition-case ()
 454       (delete-file file)
 455     (file-error nil))
 456   (vc-hg-command nil 0 file "remove" "--after" "--force"))
 457
 458 ;; Modeled after the similar function in vc-bzr.el
 459 (defun vc-hg-rename-file (old new)
 460   "Rename file from OLD to NEW using `hg mv'."
 461   (vc-hg-command nil 0 new "mv" old))
 462
 463 (defun vc-hg-register (files &optional _comment)
 464   "Register FILES under hg. COMMENT is ignored."
 465   (vc-hg-command nil 0 files "add"))
 466
 467 (defun vc-hg-create-repo ()
 468   "Create a new Mercurial repository."
 469   (vc-hg-command nil 0 nil "init"))
 470
 471 (defalias 'vc-hg-responsible-p 'vc-hg-root)
 472
 473 (defun vc-hg-unregister (file)
 474   "Unregister FILE from hg."
 475   (vc-hg-command nil 0 file "forget"))
 476
 477 (declare-function log-edit-extract-headers "log-edit" (headers string))
 478
 479 (defun vc-hg-checkin (files comment &optional _rev)
 480   "Hg-specific version of `vc-backend-checkin'.
 481 REV is ignored."
 482   (apply 'vc-hg-command nil 0 files
 483          (nconc (list "commit" "-m")
 484                 (log-edit-extract-headers '(("Author" . "--user")
 485                                             ("Date" . "--date"))
 486                                           comment))))
 487
 488 (defun vc-hg-find-revision (file rev buffer)
 489   (let ((coding-system-for-read 'binary)
 490         (coding-system-for-write 'binary))
 491     (if rev
 492         (vc-hg-command buffer 0 file "cat" "-r" rev)
 493       (vc-hg-command buffer 0 file "cat"))))
 494
 495 (defun vc-hg-find-ignore-file (file)
 496   "Return the root directory of the repository of FILE."
 497   (expand-file-name ".hgignore"
 498                     (vc-hg-root file)))
 499
 500 ;; Modeled after the similar function in vc-bzr.el
 501 (defun vc-hg-checkout (file &optional rev)
 502   "Retrieve a revision of FILE.
 503 EDITABLE is ignored.
 504 REV is the revision to check out into WORKFILE."
 505   (let ((coding-system-for-read 'binary)
 506         (coding-system-for-write 'binary))
 507   (with-current-buffer (or (get-file-buffer file) (current-buffer))
 508     (if rev
 509         (vc-hg-command t 0 file "cat" "-r" rev)
 510       (vc-hg-command t 0 file "cat")))))
 511
 512 (defun vc-hg-resolve-when-done ()
 513   "Call \"hg resolve -m\" if the conflict markers have been removed."
 514   (save-excursion
 515     (goto-char (point-min))
 516     (unless (re-search-forward "^<<<<<<< " nil t)
 517       (vc-hg-command nil 0 buffer-file-name "resolve" "-m")
 518       ;; Remove the hook so that it is not called multiple times.
 519       (remove-hook 'after-save-hook 'vc-hg-resolve-when-done t))))
 520
 521 (defun vc-hg-find-file-hook ()
 522   (when (and buffer-file-name
 523              (file-exists-p (concat buffer-file-name ".orig"))
 524              ;; Hg does not seem to have a "conflict" status, eg
 525              ;; hg http://bz.selenic.com/show_bug.cgi?id=2724
 526              (memq (vc-file-getprop buffer-file-name 'vc-state)
 527                    '(edited conflict))
 528              ;; Maybe go on to check that "hg resolve -l" says "U"?
 529              ;; If "hg resolve -l" says there's a conflict but there are no
 530              ;; conflict markers, it's not clear what we should do.
 531              (save-excursion
 532                (goto-char (point-min))
 533                (re-search-forward "^<<<<<<< " nil t)))
 534     ;; Hg may not recognize "conflict" as a state, but we can do better.
 535     (vc-file-setprop buffer-file-name 'vc-state 'conflict)
 536     (smerge-start-session)
 537     (add-hook 'after-save-hook 'vc-hg-resolve-when-done nil t)
 538     (message "There are unresolved conflicts in this file")))
 539
 540
 541 ;; Modeled after the similar function in vc-bzr.el
 542 (defun vc-hg-revert (file &optional contents-done)
 543   (unless contents-done
 544     (with-temp-buffer (vc-hg-command t 0 file "revert"))))
 545
 546 ;;; Hg specific functionality.
 547
 548 (defvar vc-hg-extra-menu-map
 549   (let ((map (make-sparse-keymap)))
 550     map))
 551
 552 (defun vc-hg-extra-menu () vc-hg-extra-menu-map)
 553
 554 (defun vc-hg-extra-status-menu () vc-hg-extra-menu-map)
 555
 556 (defvar log-view-vc-backend)
 557
 558 (cl-defstruct (vc-hg-extra-fileinfo
 559             (:copier nil)
 560             (:constructor vc-hg-create-extra-fileinfo (rename-state extra-name))
 561             (:conc-name vc-hg-extra-fileinfo->))
 562   rename-state        ;; rename or copy state
 563   extra-name)         ;; original name for copies and rename targets, new name for
 564
 565 (declare-function vc-default-dir-printer "vc-dir" (backend fileentry))
 566
 567 (defun vc-hg-dir-printer (info)
 568   "Pretty-printer for the vc-dir-fileinfo structure."
 569   (let ((extra (vc-dir-fileinfo->extra info)))
 570     (vc-default-dir-printer 'Hg info)
 571     (when extra
 572       (insert (propertize
 573                (format "   (%s %s)"
 574                        (pcase (vc-hg-extra-fileinfo->rename-state extra)
 575                          (`copied "copied from")
 576                          (`renamed-from "renamed from")
 577                          (`renamed-to "renamed to"))
 578                        (vc-hg-extra-fileinfo->extra-name extra))
 579                'face 'font-lock-comment-face)))))
 580
 581 (defun vc-hg-after-dir-status (update-function)
 582   (let ((file nil)
 583         (translation '((?= . up-to-date)
 584                        (?C . up-to-date)
 585                        (?A . added)
 586                        (?R . removed)
 587                        (?M . edited)
 588                        (?I . ignored)
 589                        (?! . missing)
 590                        (?  . copy-rename-line)
 591                        (?? . unregistered)))
 592         (translated nil)
 593         (result nil)
 594         (last-added nil)
 595         (last-line-copy nil))
 596       (goto-char (point-min))
 597       (while (not (eobp))
 598         (setq translated (cdr (assoc (char-after) translation)))
 599         (setq file
 600               (buffer-substring-no-properties (+ (point) 2)
 601                                               (line-end-position)))
 602         (cond ((not translated)
 603                (setq last-line-copy nil))
 604               ((eq translated 'up-to-date)
 605                (setq last-line-copy nil))
 606               ((eq translated 'copy-rename-line)
 607                ;; For copied files the output looks like this:
 608                ;; A COPIED_FILE_NAME
 609                ;;   ORIGINAL_FILE_NAME
 610                (setf (nth 2 last-added)
 611                      (vc-hg-create-extra-fileinfo 'copied file))
 612                (setq last-line-copy t))
 613               ((and last-line-copy (eq translated 'removed))
 614                ;; For renamed files the output looks like this:
 615                ;; A NEW_FILE_NAME
 616                ;;   ORIGINAL_FILE_NAME
 617                ;; R ORIGINAL_FILE_NAME
 618                ;; We need to adjust the previous entry to not think it is a copy.
 619                (setf (vc-hg-extra-fileinfo->rename-state (nth 2 last-added))
 620                      'renamed-from)
 621                (push (list file translated
 622                            (vc-hg-create-extra-fileinfo
 623                             'renamed-to (nth 0 last-added))) result)
 624                (setq last-line-copy nil))
 625               (t
 626                (setq last-added (list file translated nil))
 627                (push last-added result)
 628                (setq last-line-copy nil)))
 629         (forward-line))
 630       (funcall update-function result)))
 631
 632 ;; Follows vc-hg-command (or vc-do-async-command), which uses vc-do-command
 633 ;; from vc-dispatcher.
 634 (declare-function vc-exec-after "vc-dispatcher" (code))
 635 ;; Follows vc-exec-after.
 636 (declare-function vc-set-async-update "vc-dispatcher" (process-buffer))
 637
 638 (defun vc-hg-dir-status-files (dir files update-function)
 639   (apply 'vc-hg-command (current-buffer) 'async dir "status"
 640          (concat "-mardu" (if files "i"))
 641          "-C" files)
 642   (vc-run-delayed
 643     (vc-hg-after-dir-status update-function)))
 644
 645 (defun vc-hg-dir-extra-header (name &rest commands)
 646   (concat (propertize name 'face 'font-lock-type-face)
 647           (propertize
 648            (with-temp-buffer
 649              (apply 'vc-hg-command (current-buffer) 0 nil commands)
 650              (buffer-substring-no-properties (point-min) (1- (point-max))))
 651            'face 'font-lock-variable-name-face)))
 652
 653 (defun vc-hg-dir-extra-headers (dir)
 654   "Generate extra status headers for a Mercurial tree."
 655   (let ((default-directory dir))
 656     (concat
 657      (vc-hg-dir-extra-header "Root       : " "root") "\n"
 658      (vc-hg-dir-extra-header "Branch     : " "id" "-b") "\n"
 659      (vc-hg-dir-extra-header "Tags       : " "id" "-t") ; "\n"
 660      ;; these change after each commit
 661      ;; (vc-hg-dir-extra-header "Local num  : " "id" "-n") "\n"
 662      ;; (vc-hg-dir-extra-header "Global id  : " "id" "-i")
 663      )))
 664
 665 (defun vc-hg-log-incoming (buffer remote-location)
 666   (vc-hg-command buffer 1 nil "incoming" "-n" (unless (string= remote-location "")
 667                                                 remote-location)))
 668
 669 (defun vc-hg-log-outgoing (buffer remote-location)
 670   (vc-hg-command buffer 1 nil "outgoing" "-n" (unless (string= remote-location "")
 671                                                 remote-location)))
 672
 673 (defvar vc-hg-error-regexp-alist nil
 674   ;; 'hg pull' does not list modified files, so, for now, the only
 675   ;; benefit of `vc-compilation-mode' is that one can get rid of
 676   ;; *vc-hg* buffer with 'q' or 'z'.
 677   ;; TODO: call 'hg incoming' before pull/merge to get the list of
 678   ;;       modified files
 679   "Value of `compilation-error-regexp-alist' in *vc-hg* buffers.")
 680
 681 (autoload 'vc-do-async-command "vc-dispatcher")
 682 (autoload 'log-view-get-marked "log-view")
 683
 684 (defun vc-hg--pushpull (command prompt &optional obsolete)
 685   "Run COMMAND (a string; either push or pull) on the current Hg branch.
 686 If PROMPT is non-nil, prompt for the Hg command to run.
 687 If OBSOLETE is non-nil, behave like the old versions of the Hg push/pull
 688 commands, which only operated on marked files."
 689   (let (marked-list)
 690     ;; The `vc-hg-pull' and `vc-hg-push' commands existed before the
 691     ;; `pull'/`push' VC actions were implemented.
 692     ;; The following is for backwards compatibility.
 693     (if (and obsolete (setq marked-list (log-view-get-marked)))
 694         (apply #'vc-hg-command
 695                nil 0 nil
 696                command
 697                (apply 'nconc
 698                       (mapcar (lambda (arg) (list "-r" arg)) marked-list)))
 699       (let* ((root (vc-hg-root default-directory))
 700              (buffer (format "*vc-hg : %s*" (expand-file-name root)))
 701              (hg-program vc-hg-program)
 702              ;; Fixme: before updating the working copy to the latest
 703              ;; state, should check if it's visiting an old revision.
 704              (args (if (equal command "pull") '("-u"))))
 705         ;; If necessary, prompt for the exact command.
 706         ;; TODO if pushing, prompt if no default push location - cf bzr.
 707         (when prompt
 708           (setq args (split-string
 709                       (read-shell-command
 710                        (format "Hg %s command: " command)
 711                        (format "%s %s%s" hg-program command
 712                                (if (not args) ""
 713                                  (concat " " (mapconcat 'identity args " "))))
 714                        'vc-hg-history)
 715                       " " t))
 716           (setq hg-program (car  args)
 717                 command    (cadr args)
 718                 args       (cddr args)))
 719         (apply 'vc-do-async-command buffer root hg-program command args)
 720         (with-current-buffer buffer
 721           (vc-run-delayed (vc-compilation-mode 'hg)))
 722         (vc-set-async-update buffer)))))
 723
 724 (defun vc-hg-pull (prompt)
 725   "Issue a Mercurial pull command.
 726 If called interactively with a set of marked Log View buffers,
 727 call \"hg pull -r REVS\" to pull in the specified revisions REVS.
 728
 729 With a prefix argument or if PROMPT is non-nil, prompt for a
 730 specific Mercurial pull command.  The default is \"hg pull -u\",
 731 which fetches changesets from the default remote repository and
 732 then attempts to update the working directory."
 733   (interactive "P")
 734   (vc-hg--pushpull "pull" prompt (called-interactively-p 'interactive)))
 735
 736 (defun vc-hg-push (prompt)
 737   "Push changes from the current Mercurial branch.
 738 Normally, this runs \"hg push\".  If PROMPT is non-nil, prompt
 739 for the Hg command to run.
 740
 741 If called interactively with a set of marked Log View buffers,
 742 call \"hg push -r REVS\" to push the specified revisions REVS."
 743   (interactive "P")
 744   (vc-hg--pushpull "push" prompt (called-interactively-p 'interactive)))
 745
 746 (defun vc-hg-merge-branch ()
 747   "Merge incoming changes into the current working directory.
 748 This runs the command \"hg merge\"."
 749   (let* ((root (vc-hg-root default-directory))
 750          (buffer (format "*vc-hg : %s*" (expand-file-name root))))
 751     (apply 'vc-do-async-command buffer root vc-hg-program '("merge"))
 752     (with-current-buffer buffer (vc-run-delayed (vc-compilation-mode 'hg)))
 753     (vc-set-async-update buffer)))
 754
 755 ;;; Internal functions
 756
 757 (defun vc-hg-command (buffer okstatus file-or-list &rest flags)
 758   "A wrapper around `vc-do-command' for use in vc-hg.el.
 759 This function differs from vc-do-command in that it invokes
 760 `vc-hg-program', and passes `vc-hg-global-switches' to it before FLAGS."
 761   (apply 'vc-do-command (or buffer "*vc*") okstatus vc-hg-program file-or-list
 762          (if (stringp vc-hg-global-switches)
 763              (cons vc-hg-global-switches flags)
 764            (append vc-hg-global-switches
 765                    flags))))
 766
 767 (defun vc-hg-root (file)
 768   (vc-find-root file ".hg"))
 769
 770 (provide 'vc-hg)
 771
 772 ;;; vc-hg.el ends here