lisp/autorevert.el

   1 ;;; autorevert.el --- revert buffers when files on disk change
   2
   3 ;; Copyright (C) 1997, 1998, 1999, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; Author: Anders Lindgren <andersl@andersl.com>
   7 ;; Keywords: convenience
   8 ;; Created: 1997-06-01
   9 ;; Date: 1999-11-30
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; Introduction:
  29 ;;
  30 ;; Whenever a file that Emacs is editing has been changed by another
  31 ;; program the user normally has to execute the command `revert-buffer'
  32 ;; to load the new content of the file into Emacs.
  33 ;;
  34 ;; This package contains two minor modes: Global Auto-Revert Mode and
  35 ;; Auto-Revert Mode.  Both modes automatically revert buffers
  36 ;; whenever the corresponding files have been changed on disk and the
  37 ;; buffer contains no unsaved changes.
  38 ;;
  39 ;; Auto-Revert Mode can be activated for individual buffers.  Global
  40 ;; Auto-Revert Mode applies to all file buffers. (If the user option
  41 ;; `global-auto-revert-non-file-buffers' is non-nil, it also applies
  42 ;; to some non-file buffers.  This option is disabled by default.)
  43 ;; Since checking a remote file is too slow, these modes do not check
  44 ;; or revert remote files.
  45 ;;
  46 ;; Both modes operate by checking the time stamp of all files at
  47 ;; intervals of `auto-revert-interval'.  The default is every five
  48 ;; seconds.  The check is aborted whenever the user actually uses
  49 ;; Emacs.  You should never even notice that this package is active
  50 ;; (except that your buffers will be reverted, of course).
  51 ;;
  52 ;; After reverting a file buffer, Auto Revert Mode normally puts point
  53 ;; at the same position that a regular manual revert would.  However,
  54 ;; there is one exception to this rule.  If point is at the end of the
  55 ;; buffer before reverting, it stays at the end.  Similarly if point
  56 ;; is displayed at the end of a file buffer in any window, it will stay
  57 ;; at the end of the buffer in that window, even if the window is not
  58 ;; selected.  This way, you can use Auto Revert Mode to `tail' a file.
  59 ;; Just put point at the end of the buffer and it will stay there.
  60 ;; These rules apply to file buffers. For non-file buffers, the
  61 ;; behavior may be mode dependent.
  62 ;;
  63 ;; While you can use Auto Revert Mode to tail a file, this package
  64 ;; contains a third minor mode, Auto Revert Tail Mode, which does so
  65 ;; more efficiently, as long as you are sure that the file will only
  66 ;; change by growing at the end.  It only appends the new output,
  67 ;; instead of reverting the entire buffer.  It does so even if the
  68 ;; buffer contains unsaved changes.  (Because they will not be lost.)
  69
  70 ;; Usage:
  71 ;;
  72 ;; Go to the appropriate buffer and press either of:
  73 ;;   M-x auto-revert-mode RET
  74 ;;   M-x auto-revert-tail-mode RET
  75 ;;
  76 ;; To activate Global Auto-Revert Mode, press:
  77 ;;   M-x global-auto-revert-mode RET
  78 ;;
  79 ;; To activate Global Auto-Revert Mode every time Emacs is started
  80 ;; customise the option `global-auto-revert-mode' or the following
  81 ;; line could be added to your ~/.emacs:
  82 ;;   (global-auto-revert-mode 1)
  83 ;;
  84 ;; The function `turn-on-auto-revert-mode' could be added to any major
  85 ;; mode hook to activate Auto-Revert Mode for all buffers in that
  86 ;; mode.  For example, the following line will activate Auto-Revert
  87 ;; Mode in all C mode buffers:
  88 ;;
  89 ;; (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)
  90
  91 ;;; Code:
  92
  93 ;; Dependencies:
  94
  95 (require 'timer)
  96
  97 (eval-when-compile (require 'cl))
  98
  99
 100 ;; Custom Group:
 101 ;;
 102 ;; The two modes will be placed next to Auto Save Mode under the
 103 ;; Files group under Emacs.
 104
 105 (defgroup auto-revert nil
 106   "Revert individual buffers when files on disk change.
 107
 108 Auto-Revert Mode can be activated for individual buffer.
 109 Global Auto-Revert Mode applies to all buffers."
 110   :group 'files
 111   :group 'convenience)
 112
 113
 114 ;; Variables:
 115
 116 ;;; What's this?: ;; Autoload for the benefit of `make-mode-line-mouse-sensitive'.
 117 ;;; What's this?: ;;;###autoload
 118 (defvar auto-revert-mode nil
 119   "*Non-nil when Auto-Revert Mode is active.
 120 Never set this variable directly, use the command `auto-revert-mode' instead.")
 121 (put 'auto-revert-mode 'permanent-local t)
 122
 123 (defvar auto-revert-tail-mode nil
 124   "*Non-nil when Auto-Revert Tail Mode is active.
 125 Never set this variable directly, use the command
 126 `auto-revert-tail-mode' instead.")
 127 (put 'auto-revert-tail-mode 'permanent-local t)
 128
 129 (defvar auto-revert-timer nil
 130   "Timer used by Auto-Revert Mode.")
 131
 132 (defcustom auto-revert-interval 5
 133   "Time, in seconds, between Auto-Revert Mode file checks.
 134 The value may be an integer or floating point number.
 135
 136 If a timer is already active, there are two ways to make sure
 137 that the new value will take effect immediately.  You can set
 138 this variable through Custom or you can call the command
 139 `auto-revert-set-timer' after setting the variable.  Otherwise,
 140 the new value will take effect the first time Auto Revert Mode
 141 calls `auto-revert-set-timer' for internal reasons or in your
 142 next editing session."
 143   :group 'auto-revert
 144   :type 'number
 145   :set (lambda (variable value)
 146          (set-default variable value)
 147          (and (boundp 'auto-revert-timer)
 148               auto-revert-timer
 149               (auto-revert-set-timer))))
 150
 151 (defcustom auto-revert-stop-on-user-input t
 152   "When non-nil, user input temporarily interrupts Auto-Revert Mode.
 153 With this setting, Auto-Revert Mode checks for user input after
 154 handling each buffer and does not process any further buffers
 155 \(until the next run of the timer) if user input is available.
 156 When nil, Auto-Revert Mode checks files and reverts buffers,
 157 with quitting disabled, without paying attention to user input.
 158 Thus, with this setting, Emacs might be non-responsive at times."
 159   :group 'auto-revert
 160   :type 'boolean)
 161
 162 (defcustom auto-revert-verbose t
 163   "When nil, Auto-Revert Mode does not generate any messages.
 164 When non-nil, a message is generated whenever a file is reverted."
 165   :group 'auto-revert
 166   :type 'boolean)
 167
 168 (defcustom auto-revert-mode-text " ARev"
 169   "String to display in the mode line when Auto-Revert Mode is active.
 170
 171 \(When the string is not empty, make sure that it has a leading space.)"
 172   :tag "Auto Revert Mode Text"          ; To separate it from `global-...'
 173   :group 'auto-revert
 174   :type 'string)
 175
 176 (defcustom auto-revert-tail-mode-text " Tail"
 177   "String to display in the mode line when Auto-Revert Tail Mode is active.
 178
 179 \(When the string is not empty, make sure that it has a leading space.)"
 180   :group 'auto-revert
 181   :type 'string
 182   :version "22.1")
 183
 184 (defcustom auto-revert-mode-hook nil
 185   "Functions to run when Auto-Revert Mode is activated."
 186   :tag "Auto Revert Mode Hook"          ; To separate it from `global-...'
 187   :group 'auto-revert
 188   :type 'hook)
 189
 190 (defcustom global-auto-revert-mode-text ""
 191   "String to display when Global Auto-Revert Mode is active.
 192
 193 The default is nothing since when this mode is active this text doesn't
 194 vary over time, or between buffers.  Hence mode line text
 195 would only waste precious space."
 196   :group 'auto-revert
 197   :type 'string)
 198
 199 (defcustom global-auto-revert-mode-hook nil
 200   "Hook called when Global Auto-Revert Mode is activated."
 201   :group 'auto-revert
 202   :type 'hook)
 203
 204 (defcustom global-auto-revert-non-file-buffers nil
 205   "When nil, Global Auto-Revert mode operates only on file-visiting buffers.
 206
 207 When non-nil, both file buffers and buffers with a custom
 208 `revert-buffer-function' and a `buffer-stale-function' are
 209 reverted by Global Auto-Revert mode.  These include the Buffer
 210 List buffer, and Dired buffers showing complete local
 211 directories.  Dired buffers do not auto-revert as a result of
 212 changes in subdirectories or in the contents, size, modes, etc.,
 213 of files.  You may still sometimes want to revert them manually.
 214
 215 Use this option with care since it could lead to excessive auto-reverts.
 216 For more information, see Info node `(emacs)Autorevert'."
 217   :group 'auto-revert
 218   :type 'boolean
 219   :link '(info-link "(emacs)Autorevert"))
 220
 221 (defcustom global-auto-revert-ignore-modes ()
 222   "List of major modes Global Auto-Revert Mode should not check."
 223   :group 'auto-revert
 224   :type '(repeat sexp))
 225
 226 (defcustom auto-revert-load-hook nil
 227   "Functions to run when Auto-Revert Mode is first loaded."
 228   :tag "Load Hook"
 229   :group 'auto-revert
 230   :type 'hook)
 231
 232 (defcustom auto-revert-check-vc-info nil
 233   "If non-nil Auto Revert Mode reliably updates version control info.
 234 Auto Revert Mode updates version control info whenever the buffer
 235 needs reverting, regardless of the value of this variable.
 236 However, the version control state can change without changes to
 237 the work file.  If the change is made from the current Emacs
 238 session, all info is updated.  But if, for instance, a new
 239 version is checked in from outside the current Emacs session, the
 240 version control number in the mode line, as well as other version
 241 control related information, may not be properly updated.  If you
 242 are worried about this, set this variable to a non-nil value.
 243
 244 This currently works by automatically updating the version
 245 control info every `auto-revert-interval' seconds.  Nevertheless,
 246 it should not cause excessive CPU usage on a reasonably fast
 247 machine, if it does not apply to too many version controlled
 248 buffers.  CPU usage depends on the version control system."
 249   :group 'auto-revert
 250   :type 'boolean
 251   :version "22.1")
 252
 253 (defvar global-auto-revert-ignore-buffer nil
 254   "*When non-nil, Global Auto-Revert Mode will not revert this buffer.
 255
 256 This variable becomes buffer local when set in any fashion.")
 257 (make-variable-buffer-local 'global-auto-revert-ignore-buffer)
 258
 259 ;; Internal variables:
 260
 261 (defvar auto-revert-buffer-list ()
 262   "List of buffers in Auto-Revert Mode.
 263
 264 Note that only Auto-Revert Mode, never Global Auto-Revert Mode, adds
 265 buffers to this list.
 266
 267 The timer function `auto-revert-buffers' is responsible for purging
 268 the list of old buffers.")
 269
 270 (defvar auto-revert-remaining-buffers ()
 271   "Buffers not checked when user input stopped execution.")
 272
 273 (defvar auto-revert-tail-pos 0
 274   "Position of last known end of file.")
 275
 276 (add-hook 'find-file-hook
 277           (lambda ()
 278             (set (make-local-variable 'auto-revert-tail-pos)
 279                  (nth 7 (file-attributes buffer-file-name)))))
 280
 281 ;; Functions:
 282
 283 ;;;###autoload
 284 (define-minor-mode auto-revert-mode
 285   "Toggle reverting buffer when file on disk changes.
 286
 287 With arg, turn Auto Revert mode on if and only if arg is positive.
 288 This is a minor mode that affects only the current buffer.
 289 Use `global-auto-revert-mode' to automatically revert all buffers.
 290 Use `auto-revert-tail-mode' if you know that the file will only grow
 291 without being changed in the part that is already in the buffer."
 292   :group 'auto-revert :lighter auto-revert-mode-text
 293   (if auto-revert-mode
 294       (if (not (memq (current-buffer) auto-revert-buffer-list))
 295           (push (current-buffer) auto-revert-buffer-list))
 296     (setq auto-revert-buffer-list
 297           (delq (current-buffer) auto-revert-buffer-list)))
 298   (auto-revert-set-timer)
 299   (when auto-revert-mode
 300     (auto-revert-buffers)
 301     (setq auto-revert-tail-mode nil)))
 302
 303
 304 ;;;###autoload
 305 (defun turn-on-auto-revert-mode ()
 306   "Turn on Auto-Revert Mode.
 307
 308 This function is designed to be added to hooks, for example:
 309   (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)"
 310   (auto-revert-mode 1))
 311
 312
 313 ;;;###autoload
 314 (define-minor-mode auto-revert-tail-mode
 315   "Toggle reverting tail of buffer when file on disk grows.
 316 With arg, turn Tail mode on if arg is positive, otherwise turn it off.
 317
 318 When Tail mode is enabled, the tail of the file is constantly
 319 followed, as with the shell command `tail -f'.  This means that
 320 whenever the file grows on disk (presumably because some
 321 background process is appending to it from time to time), this is
 322 reflected in the current buffer.
 323
 324 You can edit the buffer and turn this mode off and on again as
 325 you please.  But make sure the background process has stopped
 326 writing before you save the file!
 327
 328 Use `auto-revert-mode' for changes other than appends!"
 329   :group 'find-file :lighter auto-revert-tail-mode-text
 330   (when auto-revert-tail-mode
 331     (unless buffer-file-name
 332       (auto-revert-tail-mode 0)
 333       (error "This buffer is not visiting a file"))
 334     (if (and (buffer-modified-p)
 335              (zerop auto-revert-tail-pos) ; library was loaded only after finding file
 336              (not (y-or-n-p "Buffer is modified, so tail offset may be wrong.  Proceed? ")))
 337         (auto-revert-tail-mode 0)
 338       ;; a-r-tail-pos stores the size of the file at the time of the
 339       ;; last revert. After this package loads, it adds a
 340       ;; find-file-hook to set this variable every time a file is
 341       ;; loaded.  If the package is loaded only _after_ visiting the
 342       ;; file to be reverted, then we have no idea what the value of
 343       ;; a-r-tail-pos should have been when the file was visited.  If
 344       ;; the file has changed on disk in the meantime, all we can do
 345       ;; is offer to revert the whole thing. If you choose not to
 346       ;; revert, then you might miss some output then happened
 347       ;; between visiting the file and activating a-r-t-mode.
 348       (and (zerop auto-revert-tail-pos)
 349            (not (verify-visited-file-modtime (current-buffer)))
 350            (y-or-n-p "File changed on disk, content may be missing.  \
 351 Perform a full revert? ")
 352            ;; Use this (not just revert-buffer) for point-preservation.
 353            (auto-revert-handler))
 354       ;; else we might reappend our own end when we save
 355       (add-hook 'before-save-hook (lambda () (auto-revert-tail-mode 0)) nil t)
 356       (or (local-variable-p 'auto-revert-tail-pos) ; don't lose prior position
 357           (set (make-local-variable 'auto-revert-tail-pos)
 358                (nth 7 (file-attributes buffer-file-name))))
 359       ;; let auto-revert-mode set up the mechanism for us if it isn't already
 360       (or auto-revert-mode
 361           (let ((auto-revert-tail-mode t))
 362             (auto-revert-mode 1)))
 363       (setq auto-revert-mode nil))))
 364
 365
 366 ;;;###autoload
 367 (defun turn-on-auto-revert-tail-mode ()
 368   "Turn on Auto-Revert Tail Mode.
 369
 370 This function is designed to be added to hooks, for example:
 371   (add-hook 'my-logfile-mode-hook 'turn-on-auto-revert-tail-mode)"
 372   (auto-revert-tail-mode 1))
 373
 374
 375 ;;;###autoload
 376 (define-minor-mode global-auto-revert-mode
 377   "Revert any buffer when file on disk changes.
 378
 379 With arg, turn Auto Revert mode on globally if and only if arg is positive.
 380 This is a minor mode that affects all buffers.
 381 Use `auto-revert-mode' to revert a particular buffer."
 382   :global t :group 'auto-revert :lighter global-auto-revert-mode-text
 383   (auto-revert-set-timer)
 384   (when global-auto-revert-mode
 385     (auto-revert-buffers)))
 386
 387
 388 (defun auto-revert-set-timer ()
 389   "Restart or cancel the timer used by Auto-Revert Mode.
 390 If such a timer is active, cancel it.  Start a new timer if
 391 Global Auto-Revert Mode is active or if Auto-Revert Mode is active
 392 in some buffer.  Restarting the timer ensures that Auto-Revert Mode
 393 will use an up-to-date value of `auto-revert-interval'"
 394   (interactive)
 395   (if (timerp auto-revert-timer)
 396       (cancel-timer auto-revert-timer))
 397   (setq auto-revert-timer
 398         (if (or global-auto-revert-mode auto-revert-buffer-list)
 399             (run-with-timer auto-revert-interval
 400                             auto-revert-interval
 401                             'auto-revert-buffers))))
 402
 403 (defun auto-revert-active-p ()
 404   "Check if auto-revert is active (in current buffer or globally)."
 405   (or auto-revert-mode
 406       auto-revert-tail-mode
 407       (and
 408        global-auto-revert-mode
 409        (not global-auto-revert-ignore-buffer)
 410        (not (memq major-mode
 411                   global-auto-revert-ignore-modes)))))
 412
 413 (defun auto-revert-handler ()
 414   "Revert current buffer, if appropriate.
 415 This is an internal function used by Auto-Revert Mode."
 416   (when (or auto-revert-tail-mode (not (buffer-modified-p)))
 417     (let* ((buffer (current-buffer)) size
 418            (revert
 419             (or (and buffer-file-name
 420                      (not (file-remote-p buffer-file-name))
 421                      (file-readable-p buffer-file-name)
 422                      (if auto-revert-tail-mode
 423                          (/= auto-revert-tail-pos
 424                             (setq size
 425                                   (nth 7 (file-attributes buffer-file-name))))
 426                        (not (verify-visited-file-modtime buffer))))
 427                 (and (or auto-revert-mode
 428                          global-auto-revert-non-file-buffers)
 429                      revert-buffer-function
 430                      (boundp 'buffer-stale-function)
 431                      (functionp buffer-stale-function)
 432                      (funcall buffer-stale-function t))))
 433            eob eoblist)
 434       (when revert
 435         (when (and auto-revert-verbose
 436                    (not (eq revert 'fast)))
 437           (message "Reverting buffer `%s'." (buffer-name)))
 438         ;; If point (or a window point) is at the end of the buffer,
 439         ;; we want to keep it at the end after reverting.  This allows
 440         ;; to tail a file.
 441         (when buffer-file-name
 442           (setq eob (eobp))
 443           (walk-windows
 444            #'(lambda (window)
 445                (and (eq (window-buffer window) buffer)
 446                     (= (window-point window) (point-max))
 447                     (push window eoblist)))
 448            'no-mini t))
 449         (if auto-revert-tail-mode
 450             (auto-revert-tail-handler size)
 451           ;; Bind buffer-read-only in case user has done C-x C-q,
 452           ;; so as not to forget that.  This gives undesirable results
 453           ;; when the file's mode changes, but that is less common.
 454           (let ((buffer-read-only buffer-read-only))
 455             (revert-buffer 'ignore-auto 'dont-ask 'preserve-modes)))
 456         (when buffer-file-name
 457           (when eob (goto-char (point-max)))
 458           (dolist (window eoblist)
 459             (set-window-point window (point-max)))))
 460       ;; `preserve-modes' avoids changing the (minor) modes.  But we
 461       ;; do want to reset the mode for VC, so we do it manually.
 462       (when (or revert auto-revert-check-vc-info)
 463         (vc-find-file-hook)))))
 464
 465 (defun auto-revert-tail-handler (size)
 466   (let ((modified (buffer-modified-p))
 467         (inhibit-read-only t)           ; Ignore.
 468         (file buffer-file-name)
 469         (buffer-file-name nil))         ; Ignore that file has changed.
 470     (when (/= auto-revert-tail-pos size)
 471       (run-hooks 'before-revert-hook)
 472       (undo-boundary)
 473       (save-restriction
 474         (widen)
 475         (save-excursion
 476           (goto-char (point-max))
 477           (insert-file-contents file nil
 478                                 (and (< auto-revert-tail-pos size)
 479                                      auto-revert-tail-pos)
 480                                 size)))
 481       (run-hooks 'after-revert-hook)
 482       (undo-boundary)
 483       (setq auto-revert-tail-pos size)
 484       (restore-buffer-modified-p modified)))
 485   (set-visited-file-modtime))
 486
 487 (defun auto-revert-buffers ()
 488   "Revert buffers as specified by Auto-Revert and Global Auto-Revert Mode.
 489
 490 Should `global-auto-revert-mode' be active all file buffers are checked.
 491
 492 Should `auto-revert-mode' be active in some buffers, those buffers
 493 are checked.
 494
 495 Non-file buffers that have a custom `revert-buffer-function' and
 496 a `buffer-stale-function' are reverted either when Auto-Revert
 497 Mode is active in that buffer, or when the variable
 498 `global-auto-revert-non-file-buffers' is non-nil and Global
 499 Auto-Revert Mode is active.
 500
 501 This function stops whenever there is user input.  The buffers not
 502 checked are stored in the variable `auto-revert-remaining-buffers'.
 503
 504 To avoid starvation, the buffers in `auto-revert-remaining-buffers'
 505 are checked first the next time this function is called.
 506
 507 This function is also responsible for removing buffers no longer in
 508 Auto-Revert mode from `auto-revert-buffer-list', and for canceling
 509 the timer when no buffers need to be checked."
 510   (save-match-data
 511     (let ((bufs (if global-auto-revert-mode
 512                     (buffer-list)
 513                   auto-revert-buffer-list))
 514           (remaining ())
 515           (new ()))
 516       ;; Partition `bufs' into two halves depending on whether or not
 517       ;; the buffers are in `auto-revert-remaining-buffers'.  The two
 518       ;; halves are then re-joined with the "remaining" buffers at the
 519       ;; head of the list.
 520       (dolist (buf auto-revert-remaining-buffers)
 521         (if (memq buf bufs)
 522             (push buf remaining)))
 523       (dolist (buf bufs)
 524         (if (not (memq buf remaining))
 525             (push buf new)))
 526       (setq bufs (nreverse (nconc new remaining)))
 527       (while (and bufs
 528                   (not (and auto-revert-stop-on-user-input
 529                             (input-pending-p))))
 530         (let ((buf (car bufs)))
 531           (if (buffer-live-p buf)
 532               (with-current-buffer buf
 533                 ;; Test if someone has turned off Auto-Revert Mode in a
 534                 ;; non-standard way, for example by changing major mode.
 535                 (if (and (not auto-revert-mode)
 536                          (not auto-revert-tail-mode)
 537                          (memq buf auto-revert-buffer-list))
 538                     (setq auto-revert-buffer-list
 539                           (delq buf auto-revert-buffer-list)))
 540                 (when (auto-revert-active-p) (auto-revert-handler)))
 541             ;; Remove dead buffer from `auto-revert-buffer-list'.
 542             (setq auto-revert-buffer-list
 543                   (delq buf auto-revert-buffer-list))))
 544         (setq bufs (cdr bufs)))
 545       (setq auto-revert-remaining-buffers bufs)
 546       ;; Check if we should cancel the timer.
 547       (when (and (not global-auto-revert-mode)
 548                  (null auto-revert-buffer-list))
 549         (cancel-timer auto-revert-timer)
 550         (setq auto-revert-timer nil)))))
 551
 552
 553 ;; The end:
 554 (provide 'autorevert)
 555
 556 (run-hooks 'auto-revert-load-hook)
 557
 558 ;; arch-tag: f6bcb07b-4841-477e-9e44-b18678e58876
 559 ;;; autorevert.el ends here