lisp/net/tls.el

   1 ;;; tls.el --- TLS/SSL support via wrapper around GnuTLS
   2
   3 ;; Copyright (C) 1996-1999, 2002-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Josefsson <simon@josefsson.org>
   6 ;; Keywords: comm, tls, gnutls, ssl
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This package implements a simple wrapper around "gnutls-cli" to
  26 ;; make Emacs support TLS/SSL.
  27 ;;
  28 ;; Usage is the same as `open-network-stream', i.e.:
  29 ;;
  30 ;; (setq tmp (open-tls-stream "test" (current-buffer) "news.mozilla.org" 563))
  31 ;; ...
  32 ;; #<process test>
  33 ;; (process-send-string tmp "mode reader\n")
  34 ;; 200 secnews.netscape.com Netscape-Collabra/3.52 03615 NNRP ready ...
  35 ;; nil
  36 ;; (process-send-string tmp "quit\n")
  37 ;; 205
  38 ;; nil
  39
  40 ;; To use this package as a replacement for ssl.el by William M. Perry
  41 ;; <wmperry@cs.indiana.edu>, you need to evaluate the following:
  42 ;;
  43 ;; (defalias 'open-ssl-stream 'open-tls-stream)
  44
  45 ;;; Code:
  46
  47 (autoload 'format-spec "format-spec")
  48 (autoload 'format-spec-make "format-spec")
  49
  50 (defgroup tls nil
  51   "Transport Layer Security (TLS) parameters."
  52   :group 'comm)
  53
  54 (defcustom tls-end-of-info
  55   (concat
  56    "\\("
  57    ;; `openssl s_client' regexp.  See ssl/ssl_txt.c lines 219-220.
  58    ;; According to apps/s_client.c line 1515 `---' is always the last
  59    ;; line that is printed by s_client before the real data.
  60    "^    Verify return code: .+\n---\n\\|"
  61    ;; `gnutls' regexp. See src/cli.c lines 721-.
  62    "^- Simple Client Mode:\n"
  63    "\\(\n\\|"                           ; ignore blank lines
  64    ;; According to GnuTLS v2.1.5 src/cli.c lines 640-650 and 705-715
  65    ;; in `main' the handshake will start after this message.  If the
  66    ;; handshake fails, the programs will abort.
  67    "^\\*\\*\\* Starting TLS handshake\n\\)*"
  68    "\\)")
  69   "Regexp matching end of TLS client informational messages.
  70 Client data stream begins after the last character matched by
  71 this.  The default matches `openssl s_client' (version 0.9.8c)
  72 and `gnutls-cli' (version 2.0.1) output."
  73   :version "22.2"
  74   :type 'regexp
  75   :group 'tls)
  76
  77 (defcustom tls-program '("gnutls-cli --insecure -p %p %h"
  78                          "gnutls-cli --insecure -p %p %h --protocols ssl3"
  79                          "openssl s_client -connect %h:%p -no_ssl2 -ign_eof")
  80   "List of strings containing commands to start TLS stream to a host.
  81 Each entry in the list is tried until a connection is successful.
  82 %h is replaced with server hostname, %p with port to connect to.
  83 The program should read input on stdin and write output to
  84 stdout.
  85
  86 See `tls-checktrust' on how to check trusted root certs.
  87
  88 Also see `tls-success' for what the program should output after
  89 successful negotiation."
  90   :type
  91   '(choice
  92     (const :tag "Default list of commands"
  93            ("gnutls-cli --insecure -p %p %h"
  94             "gnutls-cli --insecure -p %p %h --protocols ssl3"
  95             "openssl s_client -connect %h:%p -no_ssl2 -ign_eof"))
  96     (list :tag "Choose commands"
  97           :value
  98           ("gnutls-cli --insecure -p %p %h"
  99            "gnutls-cli --insecure -p %p %h --protocols ssl3"
 100            "openssl s_client -connect %h:%p -no_ssl2 -ign_eof")
 101           (set :inline t
 102                ;; FIXME: add brief `:tag "..."' descriptions.
 103                ;; (repeat :inline t :tag "Other" (string))
 104                ;; See `tls-checktrust':
 105                (const "gnutls-cli --x509cafile /etc/ssl/certs/ca-certificates.crt -p %p %h")
 106                (const "gnutls-cli --x509cafile /etc/ssl/certs/ca-certificates.crt -p %p %h --protocols ssl3")
 107                (const "openssl s_client -connect %h:%p -CAfile /etc/ssl/certs/ca-certificates.crt -no_ssl2 -ign_eof")
 108                ;; No trust check:
 109                (const "gnutls-cli --insecure -p %p %h")
 110                (const "gnutls-cli --insecure -p %p %h --protocols ssl3")
 111                (const "openssl s_client -connect %h:%p -no_ssl2 -ign_eof"))
 112           (repeat :inline t :tag "Other" (string)))
 113     (list :tag "List of commands"
 114           (repeat :tag "Command" (string))))
 115   :version "22.1"
 116   :group 'tls)
 117
 118 (defcustom tls-process-connection-type nil
 119   "Value for `process-connection-type' to use when starting TLS process."
 120   :version "22.1"
 121   :type 'boolean
 122   :group 'tls)
 123
 124 (defcustom tls-success "- Handshake was completed\\|SSL handshake has read "
 125   "Regular expression indicating completed TLS handshakes.
 126 The default is what GnuTLS's \"gnutls-cli\" or OpenSSL's
 127 \"openssl s_client\" outputs."
 128   :version "22.1"
 129   :type 'regexp
 130   :group 'tls)
 131
 132 (defcustom tls-checktrust nil
 133   "Indicate if certificates should be checked against trusted root certs.
 134 If this is `ask', the user can decide whether to accept an
 135 untrusted certificate.  You may have to adapt `tls-program' in
 136 order to make this feature work properly, i.e., to ensure that
 137 the external program knows about the root certificates you
 138 consider trustworthy, e.g.:
 139
 140 \(setq tls-program
 141       '(\"gnutls-cli --x509cafile /etc/ssl/certs/ca-certificates.crt -p %p %h\"
 142         \"gnutls-cli --x509cafile /etc/ssl/certs/ca-certificates.crt -p %p %h --protocols ssl3\"
 143         \"openssl s_client -connect %h:%p -CAfile /etc/ssl/certs/ca-certificates.crt -no_ssl2 -ign_eof\"))"
 144   :type '(choice (const :tag "Always" t)
 145                  (const :tag "Never" nil)
 146                  (const :tag "Ask" ask))
 147   :version "23.1" ;; No Gnus
 148   :group 'tls)
 149
 150 (defcustom tls-untrusted
 151   "- Peer's certificate is NOT trusted\\|Verify return code: \\([^0] \\|.[^ ]\\)"
 152   "Regular expression indicating failure of TLS certificate verification.
 153 The default is what GnuTLS's \"gnutls-cli\" or OpenSSL's
 154 \"openssl s_client\" return in the event of unsuccessful
 155 verification."
 156   :type 'regexp
 157   :version "23.1" ;; No Gnus
 158   :group 'tls)
 159
 160 (defcustom tls-hostmismatch
 161   "# The hostname in the certificate does NOT match"
 162   "Regular expression indicating a host name mismatch in certificate.
 163 When the host name specified in the certificate doesn't match the
 164 name of the host you are connecting to, gnutls-cli issues a
 165 warning to this effect.  There is no such feature in openssl.  Set
 166 this to nil if you want to ignore host name mismatches."
 167   :type 'regexp
 168   :version "23.1" ;; No Gnus
 169   :group 'tls)
 170
 171 (defcustom tls-certtool-program (executable-find "certtool")
 172   "Name of  GnuTLS certtool.
 173 Used by `tls-certificate-information'."
 174   :version "22.1"
 175   :type 'string
 176   :group 'tls)
 177
 178 (defun tls-certificate-information (der)
 179   "Parse X.509 certificate in DER format into an assoc list."
 180   (let ((certificate (concat "-----BEGIN CERTIFICATE-----\n"
 181                              (base64-encode-string der)
 182                              "\n-----END CERTIFICATE-----\n"))
 183         (exit-code 0))
 184     (with-current-buffer (get-buffer-create " *certtool*")
 185       (erase-buffer)
 186       (insert certificate)
 187       (setq exit-code (condition-case ()
 188                           (call-process-region (point-min) (point-max)
 189                                                tls-certtool-program
 190                                                t (list (current-buffer) nil) t
 191                                                "--certificate-info")
 192                         (error -1)))
 193       (if (/= exit-code 0)
 194           nil
 195         (let ((vals nil))
 196           (goto-char (point-min))
 197           (while (re-search-forward "^\\([^:]+\\): \\(.*\\)" nil t)
 198             (push (cons (match-string 1) (match-string 2)) vals))
 199           (nreverse vals))))))
 200
 201 (defun open-tls-stream (name buffer host port)
 202   "Open a TLS connection for a port to a host.
 203 Returns a subprocess-object to represent the connection.
 204 Input and output work as for subprocesses; `delete-process' closes it.
 205 Args are NAME BUFFER HOST PORT.
 206 NAME is name for process.  It is modified if necessary to make it unique.
 207 BUFFER is the buffer (or buffer name) to associate with the process.
 208  Process output goes at end of that buffer, unless you specify
 209  an output stream or filter function to handle the output.
 210  BUFFER may be also nil, meaning that this process is not associated
 211  with any buffer
 212 Third arg is name of the host to connect to, or its IP address.
 213 Fourth arg PORT is an integer specifying a port to connect to."
 214   (let ((cmds tls-program)
 215         (use-temp-buffer (null buffer))
 216         process cmd done)
 217     (if use-temp-buffer
 218         (setq buffer (generate-new-buffer " TLS"))
 219       ;; BUFFER is a string but does not exist as a buffer object.
 220       (unless (and (get-buffer buffer)
 221                    (buffer-name (get-buffer buffer)))
 222         (generate-new-buffer buffer)))
 223     (with-current-buffer buffer
 224       (message "Opening TLS connection to `%s'..." host)
 225       (while (and (not done) (setq cmd (pop cmds)))
 226         (let ((process-connection-type tls-process-connection-type)
 227               (formatted-cmd
 228                (format-spec
 229                 cmd
 230                 (format-spec-make
 231                  ?h host
 232                  ?p (if (integerp port)
 233                         (int-to-string port)
 234                       port)))))
 235           (message "Opening TLS connection with `%s'..." formatted-cmd)
 236           (setq process (start-process
 237                          name buffer shell-file-name shell-command-switch
 238                          formatted-cmd))
 239           (while (and process
 240                       (memq (process-status process) '(open run))
 241                       (progn
 242                         (goto-char (point-min))
 243                         (not (setq done (re-search-forward
 244                                          tls-success nil t)))))
 245             (unless (accept-process-output process 1)
 246               (sit-for 1)))
 247           (message "Opening TLS connection with `%s'...%s" formatted-cmd
 248                    (if done "done" "failed"))
 249           (if (not done)
 250               (delete-process process)
 251             ;; advance point to after all informational messages that
 252             ;; `openssl s_client' and `gnutls' print
 253             (let ((start-of-data nil))
 254               (while
 255                   (not (setq start-of-data
 256                              ;; the string matching `tls-end-of-info'
 257                              ;; might come in separate chunks from
 258                              ;; `accept-process-output', so start the
 259                              ;; search where `tls-success' ended
 260                              (save-excursion
 261                                (if (re-search-forward tls-end-of-info nil t)
 262                                    (match-end 0)))))
 263                 (accept-process-output process 1))
 264               (if start-of-data
 265                   ;; move point to start of client data
 266                   (goto-char start-of-data)))
 267             (setq done process))))
 268       (when (and done
 269                  (or
 270                   (and tls-checktrust
 271                        (save-excursion
 272                          (goto-char (point-min))
 273                          (re-search-forward tls-untrusted nil t))
 274                        (or
 275                         (and (not (eq tls-checktrust 'ask))
 276                              (message "The certificate presented by `%s' is \
 277 NOT trusted." host))
 278                         (not (yes-or-no-p
 279                               (format "The certificate presented by `%s' is \
 280 NOT trusted. Accept anyway? " host)))))
 281                   (and tls-hostmismatch
 282                        (save-excursion
 283                          (goto-char (point-min))
 284                          (re-search-forward tls-hostmismatch nil t))
 285                        (not (yes-or-no-p
 286                              (format "Host name in certificate doesn't \
 287 match `%s'. Connect anyway? " host))))))
 288         (setq done nil)
 289         (delete-process process))
 290       ;; Delete all the informational messages that could confuse
 291       ;; future uses of `buffer'.
 292       (delete-region (point-min) (point)))
 293     (message "Opening TLS connection to `%s'...%s"
 294              host (if done "done" "failed"))
 295     (when use-temp-buffer
 296       (if done (set-process-buffer process nil))
 297       (kill-buffer buffer))
 298     done))
 299
 300 (provide 'tls)
 301
 302 ;;; tls.el ends here