lisp/scroll-all.el

   1 ;;; scroll-all.el --- scroll all buffers together minor mode
   2
   3 ;; Copyright (C) 1997 Free Software Foundation, Inc.
   4
   5 ;; Author: Gary D. Foster <Gary.Foster@corp.sun.com>
   6 ;; Keywords: scroll crisp brief lock
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26 ;;    This mode allows multiple buffers to be 'locked' so that scrolling
  27 ;;    up or down lines in any buffer causes all the buffers to mirror
  28 ;;    the scrolling.  It hooks into the post-command-hook to check for
  29 ;;    potential scrolling commands and if we're locked, mirrors them in all
  30 ;;    windows.  This allows us to grab line-at-a-time scrolling as well as
  31 ;;    screen-at-a-time scrolling, and doesn't remap any of the keyboard
  32 ;;    commands to do it.
  33
  34 ;; You can enable and disable this mode with the 'scroll-all-mode' command.
  35
  36 ;; Suggestions/ideas from:
  37 ;;    Rick Macdonald <rickm@vsl.com>
  38 ;;    Anders Lindgren <andersl@csd.uu.se>
  39
  40 ;;; Code:
  41
  42 (defun scroll-all-function-all (func arg)
  43   "Apply function FUNC with argument ARG to all visible windows."
  44   (let ((num-windows (count-windows))
  45         (count 1))
  46     (when (> num-windows 1)
  47       (other-window 1)
  48       (while (< count num-windows)
  49         (condition-case nil
  50             (funcall func arg)
  51           ;; Ignore beginning- or end-of-buffer error in other windows.
  52           (error nil)
  53           )
  54         (other-window 1)
  55         (setq count (1+ count))))))
  56
  57 (defun scroll-all-scroll-down-all (arg)
  58   "Scroll down in all visible windows."
  59   (interactive "p")
  60   (scroll-all-function-all 'next-line arg))
  61
  62 (defun scroll-all-scroll-up-all (arg)
  63   "Scroll up in all visible windows."
  64   (interactive "p")
  65   (scroll-all-function-all 'previous-line arg))
  66
  67 (defun scroll-all-page-down-all (arg)
  68   "Page down in all visible windows."
  69   (interactive "P")
  70   (scroll-all-function-all 'scroll-up arg))
  71
  72 (defun scroll-all-page-up-all (arg)
  73   "Page up in all visible windows."
  74   (interactive "P")
  75   (scroll-all-function-all 'scroll-down arg))
  76
  77 (defun scroll-all-beginning-of-buffer-all (arg)
  78   "Go to the beginning of the buffer in all visible windows."
  79   (interactive "P")
  80   (scroll-all-function-all 'beginning-of-buffer arg))
  81
  82 (defun scroll-all-end-of-buffer-all (arg)
  83   "Go to the end of the buffer in all visible windows."
  84   (interactive "P")
  85   (scroll-all-function-all 'end-of-buffer arg))
  86
  87
  88 (defun scroll-all-check-to-scroll ()
  89   "Check `this-command' to see if a scroll is to be done."
  90   (cond ((eq this-command 'next-line)
  91          (call-interactively 'scroll-all-scroll-down-all))
  92         ((eq this-command 'previous-line)
  93          (call-interactively 'scroll-all-scroll-up-all))
  94         ((eq this-command 'scroll-up)
  95          (call-interactively 'scroll-all-page-down-all))
  96         ((eq this-command 'scroll-down)
  97          (call-interactively 'scroll-all-page-up-all))
  98         ((eq this-command 'beginning-of-buffer)
  99          (call-interactively 'scroll-all-beginning-of-buffer-all))
 100         ((eq this-command 'end-of-buffer)
 101          (call-interactively 'scroll-all-end-of-buffer-all))))
 102
 103
 104 ;;;###autoload
 105 (define-minor-mode scroll-all-mode
 106   "Toggle Scroll-All minor mode.
 107 With ARG, turn Scroll-All minor mode on if ARG is positive, off otherwise.
 108 When Scroll-All mode is on, scrolling commands entered in one window
 109 apply to all visible windows in the same frame."
 110   nil " *SL*" nil
 111   :global t
 112   :group 'windows
 113   :group 'scrolling
 114   (if scroll-all-mode
 115       (add-hook 'post-command-hook 'scroll-all-check-to-scroll)
 116     (remove-hook 'post-command-hook 'scroll-all-check-to-scroll)))
 117
 118 (provide 'scroll-all)
 119
 120 ;;; scroll-all.el ends here