lisp/help-fns.el

   1 ;;; help-fns.el --- Complex help functions
   2
   3 ;; Copyright (C) 1985, 1986, 1993, 1994, 1998, 1999, 2000, 2001,
   4 ;;   2002, 2003, 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: help, internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This file contains those help commands which are complicated, and
  29 ;; which may not be used in every session.  For example
  30 ;; `describe-function' will probably be heavily used when doing elisp
  31 ;; programming, but not if just editing C files.  Simpler help commands
  32 ;; are in help.el
  33
  34 ;;; Code:
  35
  36 (require 'help-mode)
  37
  38 ;; Functions
  39
  40 ;;;###autoload
  41 (defun describe-function (function)
  42   "Display the full documentation of FUNCTION (a symbol)."
  43   (interactive
  44    (let ((fn (function-called-at-point))
  45          (enable-recursive-minibuffers t)
  46          val)
  47      (setq val (completing-read (if fn
  48                                     (format "Describe function (default %s): " fn)
  49                                   "Describe function: ")
  50                                 obarray 'fboundp t nil nil
  51                                 (and fn (symbol-name fn))))
  52      (list (if (equal val "")
  53                fn (intern val)))))
  54   (if (null function)
  55       (message "You didn't specify a function")
  56     (help-setup-xref (list #'describe-function function) (interactive-p))
  57     (save-excursion
  58       (with-help-window (help-buffer)
  59         (prin1 function)
  60         ;; Use " is " instead of a colon so that
  61         ;; it is easier to get out the function name using forward-sexp.
  62         (princ " is ")
  63         (describe-function-1 function)
  64         (with-current-buffer standard-output
  65           ;; Return the text we displayed.
  66           (buffer-string))))))
  67
  68 (defun help-split-fundoc (docstring def)
  69   "Split a function DOCSTRING into the actual doc and the usage info.
  70 Return (USAGE . DOC) or nil if there's no usage info.
  71 DEF is the function whose usage we're looking for in DOCSTRING."
  72   ;; Functions can get the calling sequence at the end of the doc string.
  73   ;; In cases where `function' has been fset to a subr we can't search for
  74   ;; function's name in the doc string so we use `fn' as the anonymous
  75   ;; function name instead.
  76   (when (and docstring (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring))
  77     (cons (format "(%s%s"
  78                   ;; Replace `fn' with the actual function name.
  79                   (if (consp def) "anonymous" def)
  80                   (match-string 1 docstring))
  81           (substring docstring 0 (match-beginning 0)))))
  82
  83 (defun help-add-fundoc-usage (docstring arglist)
  84   "Add the usage info to DOCSTRING.
  85 If DOCSTRING already has a usage info, then just return it unchanged.
  86 The usage info is built from ARGLIST.  DOCSTRING can be nil.
  87 ARGLIST can also be t or a string of the form \"(FUN ARG1 ARG2 ...)\"."
  88   (unless (stringp docstring) (setq docstring "Not documented"))
  89   (if (or (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring) (eq arglist t))
  90       docstring
  91     (concat docstring
  92             (if (string-match "\n?\n\\'" docstring)
  93                 (if (< (- (match-end 0) (match-beginning 0)) 2) "\n" "")
  94               "\n\n")
  95             (if (and (stringp arglist)
  96                      (string-match "\\`([^ ]+\\(.*\\))\\'" arglist))
  97                 (concat "(fn" (match-string 1 arglist) ")")
  98               (format "%S" (help-make-usage 'fn arglist))))))
  99
 100 (defun help-function-arglist (def)
 101   ;; Handle symbols aliased to other symbols.
 102   (if (and (symbolp def) (fboundp def)) (setq def (indirect-function def)))
 103   ;; If definition is a macro, find the function inside it.
 104   (if (eq (car-safe def) 'macro) (setq def (cdr def)))
 105   (cond
 106    ((byte-code-function-p def) (aref def 0))
 107    ((eq (car-safe def) 'lambda) (nth 1 def))
 108    ((and (eq (car-safe def) 'autoload) (not (eq (nth 4 def) 'keymap)))
 109     "[Arg list not available until function definition is loaded.]")
 110    (t t)))
 111
 112 (defun help-make-usage (function arglist)
 113   (cons (if (symbolp function) function 'anonymous)
 114         (mapcar (lambda (arg)
 115                   (if (not (symbolp arg))
 116                       (if (and (consp arg) (symbolp (car arg)))
 117                           ;; CL style default values for optional args.
 118                           (cons (intern (upcase (symbol-name (car arg))))
 119                                 (cdr arg))
 120                         arg)
 121                     (let ((name (symbol-name arg)))
 122                       (if (string-match "\\`&" name) arg
 123                         (intern (upcase name))))))
 124                 arglist)))
 125
 126 ;; Could be this, if we make symbol-file do the work below.
 127 ;; (defun help-C-file-name (subr-or-var kind)
 128 ;;   "Return the name of the C file where SUBR-OR-VAR is defined.
 129 ;; KIND should be `var' for a variable or `subr' for a subroutine."
 130 ;;   (symbol-file (if (symbolp subr-or-var) subr-or-var
 131 ;;               (subr-name subr-or-var))
 132 ;;             (if (eq kind 'var) 'defvar 'defun)))
 133 ;;;###autoload
 134 (defun help-C-file-name (subr-or-var kind)
 135   "Return the name of the C file where SUBR-OR-VAR is defined.
 136 KIND should be `var' for a variable or `subr' for a subroutine."
 137   (let ((docbuf (get-buffer-create " *DOC*"))
 138         (name (if (eq 'var kind)
 139                   (concat "V" (symbol-name subr-or-var))
 140                 (concat "F" (subr-name subr-or-var)))))
 141     (with-current-buffer docbuf
 142       (goto-char (point-min))
 143       (if (eobp)
 144           (insert-file-contents-literally
 145            (expand-file-name internal-doc-file-name doc-directory)))
 146       (let ((file (catch 'loop
 147                     (while t
 148                       (let ((pnt (search-forward (concat "\x1f" name "\n"))))
 149                         (re-search-backward "\x1fS\\(.*\\)")
 150                         (let ((file (match-string 1)))
 151                           (if (member file build-files)
 152                               (throw 'loop file)
 153                             (goto-char pnt))))))))
 154         (if (string-match "\\.\\(o\\|obj\\)\\'" file)
 155             (setq file (replace-match ".c" t t file)))
 156         (if (string-match "\\.c\\'" file)
 157             (concat "src/" file)
 158           file)))))
 159
 160 (defface help-argument-name '((((supports :slant italic)) :inherit italic))
 161   "Face to highlight argument names in *Help* buffers."
 162   :group 'help)
 163
 164 (defun help-default-arg-highlight (arg)
 165   "Default function to highlight arguments in *Help* buffers.
 166 It returns ARG in face `help-argument-name'; ARG is also
 167 downcased if it displays differently than the default
 168 face (according to `face-differs-from-default-p')."
 169   (propertize (if (face-differs-from-default-p 'help-argument-name)
 170                   (downcase arg)
 171                 arg)
 172               'face 'help-argument-name))
 173
 174 (defun help-do-arg-highlight (doc args)
 175   (with-syntax-table (make-syntax-table emacs-lisp-mode-syntax-table)
 176     (modify-syntax-entry ?\- "w")
 177     (dolist (arg args doc)
 178       (setq doc (replace-regexp-in-string
 179                  ;; This is heuristic, but covers all common cases
 180                  ;; except ARG1-ARG2
 181                  (concat "\\<"                   ; beginning of word
 182                          "\\(?:[a-z-]*-\\)?"     ; for xxx-ARG
 183                          "\\("
 184                          (regexp-quote arg)
 185                          "\\)"
 186                          "\\(?:es\\|s\\|th\\)?"  ; for ARGth, ARGs
 187                          "\\(?:-[a-z0-9-]+\\)?"  ; for ARG-xxx, ARG-n
 188                          "\\(?:-[{([<`\"].*?\\)?"; for ARG-{x}, (x), <x>, [x], `x'
 189                          "\\>")                  ; end of word
 190                  (help-default-arg-highlight arg)
 191                  doc t t 1)))))
 192
 193 (defun help-highlight-arguments (usage doc &rest args)
 194   (when usage
 195     (with-temp-buffer
 196       (insert usage)
 197       (goto-char (point-min))
 198       (let ((case-fold-search nil)
 199             (next (not (or args (looking-at "\\["))))
 200             (opt nil))
 201         ;; Make a list of all arguments
 202         (skip-chars-forward "^ ")
 203         (while next
 204           (or opt (not (looking-at " &")) (setq opt t))
 205           (if (not (re-search-forward " \\([\\[(]*\\)\\([^] &)\.]+\\)" nil t))
 206               (setq next nil)
 207             (setq args (cons (match-string 2) args))
 208             (when (and opt (string= (match-string 1) "("))
 209               ;; A pesky CL-style optional argument with default value,
 210               ;; so let's skip over it
 211               (search-backward "(")
 212               (goto-char (scan-sexps (point) 1)))))
 213         ;; Highlight aguments in the USAGE string
 214         (setq usage (help-do-arg-highlight (buffer-string) args))
 215         ;; Highlight arguments in the DOC string
 216         (setq doc (and doc (help-do-arg-highlight doc args))))))
 217   ;; Return value is like the one from help-split-fundoc, but highlighted
 218   (cons usage doc))
 219
 220 ;;;###autoload
 221 (defun describe-simplify-lib-file-name (file)
 222   "Simplify a library name FILE to a relative name, and make it a source file."
 223   (if file
 224       ;; Try converting the absolute file name to a library name.
 225       (let ((libname (file-name-nondirectory file)))
 226         ;; Now convert that back to a file name and see if we get
 227         ;; the original one.  If so, they are equivalent.
 228         (if (equal file (locate-file libname load-path '("")))
 229             (if (string-match "[.]elc\\'" libname)
 230                 (substring libname 0 -1)
 231               libname)
 232           file))))
 233
 234 (defun find-source-lisp-file (file-name)
 235   (let* ((elc-file (locate-file (concat file-name
 236                                  (if (string-match "\\.el" file-name)
 237                                      "c"
 238                                    ".elc"))
 239                                  load-path))
 240          (str (if (and elc-file (file-readable-p elc-file))
 241                   (with-temp-buffer
 242                     (insert-file-contents-literally elc-file nil 0 256)
 243                     (buffer-string))))
 244          (src-file (and str
 245                         (string-match ";;; from file \\(.*\\.el\\)" str)
 246                         (match-string 1 str))))
 247     (if (and src-file (file-readable-p src-file))
 248         src-file
 249       file-name)))
 250
 251 (declare-function ad-get-advice-info "advice" (function))
 252
 253 ;;;###autoload
 254 (defun describe-function-1 (function)
 255   (let* ((advised (and (symbolp function) (featurep 'advice)
 256                        (ad-get-advice-info function)))
 257          ;; If the function is advised, use the symbol that has the
 258          ;; real definition, if that symbol is already set up.
 259          (real-function
 260           (or (and advised
 261                    (cdr (assq 'origname advised))
 262                    (fboundp (cdr (assq 'origname advised)))
 263                    (cdr (assq 'origname advised)))
 264               function))
 265          ;; Get the real definition.
 266          (def (if (symbolp real-function)
 267                   (symbol-function real-function)
 268                 function))
 269          file-name string
 270          (beg (if (commandp def) "an interactive " "a "))
 271          (pt1 (with-current-buffer (help-buffer) (point))))
 272     (setq string
 273           (cond ((or (stringp def)
 274                      (vectorp def))
 275                  "a keyboard macro")
 276                 ((subrp def)
 277                  (if (eq 'unevalled (cdr (subr-arity def)))
 278                      (concat beg "special form")
 279                    (concat beg "built-in function")))
 280                 ((byte-code-function-p def)
 281                  (concat beg "compiled Lisp function"))
 282                 ((symbolp def)
 283                  (while (symbolp (symbol-function def))
 284                    (setq def (symbol-function def)))
 285                  (format "an alias for `%s'" def))
 286                 ((eq (car-safe def) 'lambda)
 287                  (concat beg "Lisp function"))
 288                 ((eq (car-safe def) 'macro)
 289                  "a Lisp macro")
 290                 ((eq (car-safe def) 'autoload)
 291                  (setq file-name (nth 1 def))
 292                  (format "%s autoloaded %s"
 293                          (if (commandp def) "an interactive" "an")
 294                          (if (eq (nth 4 def) 'keymap) "keymap"
 295                            (if (nth 4 def) "Lisp macro" "Lisp function"))
 296                          ))
 297                 ((keymapp def)
 298                  (let ((is-full nil)
 299                        (elts (cdr-safe def)))
 300                    (while elts
 301                      (if (char-table-p (car-safe elts))
 302                          (setq is-full t
 303                                elts nil))
 304                      (setq elts (cdr-safe elts)))
 305                    (if is-full
 306                        "a full keymap"
 307                      "a sparse keymap")))
 308                 (t "")))
 309     (princ string)
 310     (with-current-buffer standard-output
 311       (save-excursion
 312         (save-match-data
 313           (if (re-search-backward "alias for `\\([^`']+\\)'" nil t)
 314               (help-xref-button 1 'help-function def)))))
 315     (or file-name
 316         (setq file-name (symbol-file function 'defun)))
 317     (setq file-name (describe-simplify-lib-file-name file-name))
 318     (when (equal file-name "loaddefs.el")
 319       ;; Find the real def site of the preloaded function.
 320       ;; This is necessary only for defaliases.
 321       (let ((location
 322              (condition-case nil
 323                  (find-function-search-for-symbol function nil "loaddefs.el")
 324                (error nil))))
 325         (when location
 326           (with-current-buffer (car location)
 327             (goto-char (cdr location))
 328             (when (re-search-backward
 329                    "^;;; Generated autoloads from \\(.*\\)" nil t)
 330               (setq file-name (match-string 1)))))))
 331     (when (and (null file-name) (subrp def))
 332       ;; Find the C source file name.
 333       (setq file-name (if (get-buffer " *DOC*")
 334                           (help-C-file-name def 'subr)
 335                         'C-source)))
 336     (when file-name
 337       (princ " in `")
 338       ;; We used to add .el to the file name,
 339       ;; but that's completely wrong when the user used load-file.
 340       (princ (if (eq file-name 'C-source) "C source code" file-name))
 341       (princ "'")
 342       ;; See if lisp files are present where they where installed from.
 343       (if (not (eq file-name 'C-source))
 344           (setq file-name (find-source-lisp-file file-name)))
 345
 346       ;; Make a hyperlink to the library.
 347       (with-current-buffer standard-output
 348         (save-excursion
 349           (re-search-backward "`\\([^`']+\\)'" nil t)
 350           (help-xref-button 1 'help-function-def real-function file-name))))
 351     (princ ".")
 352     (with-current-buffer (help-buffer)
 353       (fill-region-as-paragraph (save-excursion (goto-char pt1) (forward-line 0) (point))
 354                                 (point)))
 355     (terpri)(terpri)
 356     (when (commandp function)
 357       (let ((pt2 (with-current-buffer (help-buffer) (point))))
 358       (if (and (eq function 'self-insert-command)
 359                (eq (key-binding "a") 'self-insert-command)
 360                (eq (key-binding "b") 'self-insert-command)
 361                (eq (key-binding "c") 'self-insert-command))
 362           (princ "It is bound to many ordinary text characters.\n")
 363         (let* ((remapped (command-remapping function))
 364                (keys (where-is-internal
 365                       (or remapped function) overriding-local-map nil nil))
 366                non-modified-keys)
 367           ;; Which non-control non-meta keys run this command?
 368           (dolist (key keys)
 369             (if (member (event-modifiers (aref key 0)) '(nil (shift)))
 370                 (push key non-modified-keys)))
 371           (when remapped
 372             (princ "It is remapped to `")
 373             (princ (symbol-name remapped))
 374             (princ "'"))
 375
 376           (when keys
 377               (princ (if remapped ", which is bound to " "It is bound to "))
 378             ;; If lots of ordinary text characters run this command,
 379             ;; don't mention them one by one.
 380             (if (< (length non-modified-keys) 10)
 381                 (princ (mapconcat 'key-description keys ", "))
 382               (dolist (key non-modified-keys)
 383                 (setq keys (delq key keys)))
 384               (if keys
 385                   (progn
 386                     (princ (mapconcat 'key-description keys ", "))
 387                     (princ ", and many ordinary text characters"))
 388                 (princ "many ordinary text characters"))))
 389           (when (or remapped keys non-modified-keys)
 390             (princ ".")
 391               (terpri))))
 392         (with-current-buffer (help-buffer) (fill-region-as-paragraph pt2 (point)))
 393         (terpri)))
 394     (let* ((arglist (help-function-arglist def))
 395            (doc (documentation function))
 396            (usage (help-split-fundoc doc function)))
 397       (with-current-buffer standard-output
 398         ;; If definition is a keymap, skip arglist note.
 399         (unless (keymapp function)
 400           (let* ((use (cond
 401                         (usage (setq doc (cdr usage)) (car usage))
 402                         ((listp arglist)
 403                          (format "%S" (help-make-usage function arglist)))
 404                         ((stringp arglist) arglist)
 405                         ;; Maybe the arglist is in the docstring of a symbol
 406                         ;; this one is aliased to.
 407                         ((let ((fun real-function))
 408                            (while (and (symbolp fun)
 409                                        (setq fun (symbol-function fun))
 410                                        (not (setq usage (help-split-fundoc
 411                                                          (documentation fun)
 412                                                          function)))))
 413                            usage)
 414                          (car usage))
 415                         ((or (stringp def)
 416                              (vectorp def))
 417                          (format "\nMacro: %s" (format-kbd-macro def)))
 418                         (t "[Missing arglist.  Please make a bug report.]")))
 419                  (high (help-highlight-arguments use doc)))
 420             (let ((fill-begin (point)))
 421               (insert (car high) "\n")
 422               (fill-region fill-begin (point)))
 423             (setq doc (cdr high))))
 424         (let* ((obsolete (and
 425                           ;; function might be a lambda construct.
 426                           (symbolp function)
 427                           (get function 'byte-obsolete-info)))
 428                (use (car obsolete)))
 429           (when obsolete
 430             (princ "\nThis function is obsolete")
 431             (when (nth 2 obsolete)
 432               (insert (format " since %s" (nth 2 obsolete))))
 433             (insert (cond ((stringp use) (concat ";\n" use))
 434                           (use (format ";\nuse `%s' instead." use))
 435                           (t "."))
 436                     "\n"))
 437           (insert "\n"
 438                   (or doc "Not documented.")))))))
 439
 440 \f
 441 ;; Variables
 442
 443 ;;;###autoload
 444 (defun variable-at-point (&optional any-symbol)
 445   "Return the bound variable symbol found at or before point.
 446 Return 0 if there is no such symbol.
 447 If ANY-SYMBOL is non-nil, don't insist the symbol be bound."
 448   (or (condition-case ()
 449           (with-syntax-table emacs-lisp-mode-syntax-table
 450             (save-excursion
 451               (or (not (zerop (skip-syntax-backward "_w")))
 452                   (eq (char-syntax (following-char)) ?w)
 453                   (eq (char-syntax (following-char)) ?_)
 454                   (forward-sexp -1))
 455               (skip-chars-forward "'")
 456               (let ((obj (read (current-buffer))))
 457                 (and (symbolp obj) (boundp obj) obj))))
 458         (error nil))
 459       (let* ((str (find-tag-default))
 460              (sym (if str (intern-soft str))))
 461         (if (and sym (or any-symbol (boundp sym)))
 462             sym
 463           (save-match-data
 464             (when (and str (string-match "\\`\\W*\\(.*?\\)\\W*\\'" str))
 465               (setq sym (intern-soft (match-string 1 str)))
 466               (and (or any-symbol (boundp sym)) sym)))))
 467       0))
 468
 469 (defun describe-variable-custom-version-info (variable)
 470   (let ((custom-version (get variable 'custom-version))
 471         (cpv (get variable 'custom-package-version))
 472         (output nil))
 473     (if custom-version
 474         (setq output
 475               (format "This variable was introduced, or its default value was changed, in\nversion %s of Emacs.\n"
 476                       custom-version))
 477       (when cpv
 478         (let* ((package (car-safe cpv))
 479                (version (car (cdr-safe cpv)))
 480                (pkg-versions (assq package customize-package-emacs-version-alist))
 481                (emacsv (cdr (assoc version pkg-versions))))
 482           (if (and package version)
 483               (setq output
 484                     (format (concat "This variable was introduced, or its default value was changed, in\nversion %s of the %s package"
 485                                     (if emacsv
 486                                         (format " that is part of Emacs %s" emacsv))
 487                                     ".\n")
 488                             version package))))))
 489     output))
 490
 491 ;;;###autoload
 492 (defun describe-variable (variable &optional buffer frame)
 493   "Display the full documentation of VARIABLE (a symbol).
 494 Returns the documentation as a string, also.
 495 If VARIABLE has a buffer-local value in BUFFER or FRAME
 496 \(default to the current buffer and current frame),
 497 it is displayed along with the global value."
 498   (interactive
 499    (let ((v (variable-at-point))
 500          (enable-recursive-minibuffers t)
 501          val)
 502      (setq val (completing-read (if (symbolp v)
 503                                     (format
 504                                      "Describe variable (default %s): " v)
 505                                   "Describe variable: ")
 506                                 obarray
 507                                 '(lambda (vv)
 508                                    (or (boundp vv)
 509                                        (get vv 'variable-documentation)))
 510                                 t nil nil
 511                                 (if (symbolp v) (symbol-name v))))
 512      (list (if (equal val "")
 513                v (intern val)))))
 514   (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 515   (unless (frame-live-p frame) (setq frame (selected-frame)))
 516   (if (not (symbolp variable))
 517       (message "You did not specify a variable")
 518     (save-excursion
 519       (let ((valvoid (not (with-current-buffer buffer (boundp variable))))
 520             val val-start-pos locus)
 521         ;; Extract the value before setting up the output buffer,
 522         ;; in case `buffer' *is* the output buffer.
 523         (unless valvoid
 524           (with-selected-frame frame
 525             (with-current-buffer buffer
 526               (setq val (symbol-value variable)
 527                     locus (variable-binding-locus variable)))))
 528         (help-setup-xref (list #'describe-variable variable buffer)
 529                          (interactive-p))
 530         (with-help-window (help-buffer)
 531           (with-current-buffer buffer
 532             (prin1 variable)
 533             ;; Make a hyperlink to the library if appropriate.  (Don't
 534             ;; change the format of the buffer's initial line in case
 535             ;; anything expects the current format.)
 536             (let ((file-name (symbol-file variable 'defvar)))
 537               (setq file-name (describe-simplify-lib-file-name file-name))
 538               (when (equal file-name "loaddefs.el")
 539                 ;; Find the real def site of the preloaded variable.
 540                 (let ((location
 541                        (condition-case nil
 542                            (find-variable-noselect variable file-name)
 543                          (error nil))))
 544                   (when location
 545                     (with-current-buffer (car location)
 546                       (when (cdr location)
 547                         (goto-char (cdr location)))
 548                       (when (re-search-backward
 549                              "^;;; Generated autoloads from \\(.*\\)" nil t)
 550                         (setq file-name (match-string 1)))))))
 551               (when (and (null file-name)
 552                          (integerp (get variable 'variable-documentation)))
 553                 ;; It's a variable not defined in Elisp but in C.
 554                 (setq file-name
 555                       (if (get-buffer " *DOC*")
 556                           (help-C-file-name variable 'var)
 557                         'C-source)))
 558               (if file-name
 559                   (progn
 560                     (princ " is a variable defined in `")
 561                     (princ (if (eq file-name 'C-source) "C source code" file-name))
 562                     (princ "'.\n")
 563                     (with-current-buffer standard-output
 564                       (save-excursion
 565                         (re-search-backward "`\\([^`']+\\)'" nil t)
 566                         (help-xref-button 1 'help-variable-def
 567                                           variable file-name)))
 568                     (if valvoid
 569                         (princ "It is void as a variable.")
 570                       (princ "Its ")))
 571                 (if valvoid
 572                     (princ " is void as a variable.")
 573                   (princ "'s "))))
 574             (if valvoid
 575                 nil
 576               (with-current-buffer standard-output
 577                 (setq val-start-pos (point))
 578                 (princ "value is ")
 579                 (terpri)
 580                 (let ((from (point)))
 581                   (pp val)
 582                   ;; Hyperlinks in variable's value are quite frequently
 583                   ;; inappropriate e.g C-h v <RET> features <RET>
 584                   ;; (help-xref-on-pp from (point))
 585                   (if (< (point) (+ from 20))
 586                       (delete-region (1- from) from)))))
 587             (terpri)
 588
 589             (when locus
 590               (if (bufferp locus)
 591                   (princ (format "%socal in buffer %s; "
 592                                  (if (get variable 'permanent-local)
 593                                      "Permanently l" "L")
 594                                  (buffer-name)))
 595                 (princ (format "It is a frame-local variable; ")))
 596               (if (not (default-boundp variable))
 597                   (princ "globally void")
 598                 (let ((val (default-value variable)))
 599                   (with-current-buffer standard-output
 600                     (princ "global value is ")
 601                     (terpri)
 602                     ;; Fixme: pp can take an age if you happen to
 603                     ;; ask for a very large expression.  We should
 604                     ;; probably print it raw once and check it's a
 605                     ;; sensible size before prettyprinting.  -- fx
 606                     (let ((from (point)))
 607                       (pp val)
 608                       ;; See previous comment for this function.
 609                       ;; (help-xref-on-pp from (point))
 610                       (if (< (point) (+ from 20))
 611                           (delete-region (1- from) from))))))
 612               (terpri))
 613
 614             ;; If the value is large, move it to the end.
 615             (with-current-buffer standard-output
 616               (when (> (count-lines (point-min) (point-max)) 10)
 617                 ;; Note that setting the syntax table like below
 618                 ;; makes forward-sexp move over a `'s' at the end
 619                 ;; of a symbol.
 620                 (set-syntax-table emacs-lisp-mode-syntax-table)
 621                 (goto-char val-start-pos)
 622                 ;; The line below previously read as
 623                 ;; (delete-region (point) (progn (end-of-line) (point)))
 624                 ;; which suppressed display of the buffer local value for
 625                 ;; large values.
 626                 (when (looking-at "value is") (replace-match ""))
 627                 (save-excursion
 628                   (insert "\n\nValue:")
 629                   (set (make-local-variable 'help-button-cache)
 630                        (point-marker)))
 631                 (insert "value is shown ")
 632                 (insert-button "below"
 633                                'action help-button-cache
 634                                'follow-link t
 635                                'help-echo "mouse-2, RET: show value")
 636                 (insert ".\n")))
 637             (terpri)
 638
 639             (let* ((alias (condition-case nil
 640                               (indirect-variable variable)
 641                             (error variable)))
 642                    (obsolete (get variable 'byte-obsolete-variable))
 643                    (use (car obsolete))
 644                    (safe-var (get variable 'safe-local-variable))
 645                    (doc (or (documentation-property variable 'variable-documentation)
 646                             (documentation-property alias 'variable-documentation)))
 647                    (extra-line nil))
 648               ;; Add a note for variables that have been make-var-buffer-local.
 649               (when (and (local-variable-if-set-p variable)
 650                          (or (not (local-variable-p variable))
 651                              (with-temp-buffer
 652                                (local-variable-if-set-p variable))))
 653                 (setq extra-line t)
 654                 (princ "  Automatically becomes buffer-local when set in any fashion.\n"))
 655
 656               ;; Mention if it's an alias
 657               (unless (eq alias variable)
 658                 (setq extra-line t)
 659                 (princ (format "  This variable is an alias for `%s'.\n" alias)))
 660
 661               (when obsolete
 662                 (setq extra-line t)
 663                 (princ "  This variable is obsolete")
 664                 (if (cdr obsolete) (princ (format " since %s" (cdr obsolete))))
 665                 (princ (cond ((stringp use) (concat ";\n  " use))
 666                              (use (format ";\n  use `%s' instead." (car obsolete)))
 667                              (t ".")))
 668                 (terpri))
 669               (when safe-var
 670                 (setq extra-line t)
 671                 (princ "  This variable is safe as a file local variable ")
 672                 (princ "if its value\n  satisfies the predicate ")
 673                 (princ (if (byte-code-function-p safe-var)
 674                            "which is byte-compiled expression.\n"
 675                          (format "`%s'.\n" safe-var))))
 676
 677               (if extra-line (terpri))
 678               (princ "Documentation:\n")
 679               (with-current-buffer standard-output
 680                 (insert (or doc "Not documented as a variable."))))
 681
 682             (let ((customize-label "customize")
 683                   (initialization-file "initialization file"))
 684               ;; All variables can be set; some can be customized
 685               (when (and (symbolp variable) (not (custom-variable-p variable)))
 686                 (terpri)
 687                 (terpri)
 688                 (princ (concat "You can set this variable in your "
 689                                initialization-file "."))
 690                 (with-current-buffer standard-output
 691                   (save-excursion
 692                     (re-search-backward
 693                      (concat "\\(" initialization-file "\\)") nil t)
 694                     (help-xref-button 1 'help-info-variable variable
 695                                       "(emacs)Init File"))))
 696               ;; Make a link to customize if this variable can be customized.
 697               (when (custom-variable-p variable)
 698                 (terpri)
 699                 (terpri)
 700                 (princ (concat "You can " customize-label " this variable"))
 701                 (princ (concat " or set it in your " initialization-file "."))
 702                 (with-current-buffer standard-output
 703                   (save-excursion
 704                     (re-search-backward
 705                      (concat "\\(" customize-label "\\)") nil t)
 706                     (help-xref-button 1 'help-customize-variable variable))
 707                   (save-excursion
 708                     (re-search-backward
 709                      (concat "\\(" initialization-file "\\)") nil t)
 710                     (help-xref-button 1 'help-info-variable variable
 711                                       "(emacs)Init File")
 712                     )
 713                   ))
 714               ;; Note variable's version or package version
 715               (let ((output (describe-variable-custom-version-info variable)))
 716                 (when output
 717                   (terpri)
 718                   (terpri)
 719                   (princ output))))
 720
 721             (save-excursion
 722               (set-buffer standard-output)
 723               ;; Return the text we displayed.
 724               (buffer-string))))))))
 725
 726
 727 ;;;###autoload
 728 (defun describe-syntax (&optional buffer)
 729   "Describe the syntax specifications in the syntax table of BUFFER.
 730 The descriptions are inserted in a help buffer, which is then displayed.
 731 BUFFER defaults to the current buffer."
 732   (interactive)
 733   (setq buffer (or buffer (current-buffer)))
 734   (help-setup-xref (list #'describe-syntax buffer) (interactive-p))
 735   (with-help-window (help-buffer)
 736     (let ((table (with-current-buffer buffer (syntax-table))))
 737       (with-current-buffer standard-output
 738         (describe-vector table 'internal-describe-syntax-value)
 739         (while (setq table (char-table-parent table))
 740           (insert "\nThe parent syntax table is:")
 741           (describe-vector table 'internal-describe-syntax-value))))))
 742
 743 (defun help-describe-category-set (value)
 744   (insert (cond
 745            ((null value) "default")
 746            ((char-table-p value) "deeper char-table ...")
 747            (t (condition-case err
 748                   (category-set-mnemonics value)
 749                 (error "invalid"))))))
 750
 751 ;;;###autoload
 752 (defun describe-categories (&optional buffer)
 753   "Describe the category specifications in the current category table.
 754 The descriptions are inserted in a buffer, which is then displayed.
 755 If BUFFER is non-nil, then describe BUFFER's category table instead.
 756 BUFFER should be a buffer or a buffer name."
 757   (interactive)
 758   (setq buffer (or buffer (current-buffer)))
 759   (help-setup-xref (list #'describe-categories buffer) (interactive-p))
 760   (with-help-window (help-buffer)
 761     (let ((table (with-current-buffer buffer (category-table))))
 762       (with-current-buffer standard-output
 763         (describe-vector table 'help-describe-category-set)
 764         (let ((docs (char-table-extra-slot table 0)))
 765           (if (or (not (vectorp docs)) (/= (length docs) 95))
 766               (insert "Invalid first extra slot in this char table\n")
 767             (insert "Meanings of mnemonic characters are:\n")
 768             (dotimes (i 95)
 769               (let ((elt (aref docs i)))
 770                 (when elt
 771                   (insert (+ i ?\s) ": " elt "\n"))))
 772             (while (setq table (char-table-parent table))
 773               (insert "\nThe parent category table is:")
 774               (describe-vector table 'help-describe-category-set))))))))
 775
 776 (provide 'help-fns)
 777
 778 ;; arch-tag: 9e10331c-ae81-4d13-965d-c4819aaab0b3
 779 ;;; help-fns.el ends here