lisp/isearch.el

   1 ;;; isearch.el --- incremental search minor mode.
   2
   3 ;; Copyright (C) 1992, 1993, 1994 Free Software Foundation, Inc.
   4
   5 ;; Author: Daniel LaLiberte <liberte@cs.uiuc.edu>
   6
   7 ;; |$Date: 1994/12/26 05:09:07 $|$Revision: 1.82 $
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  23 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;;====================================================================
  28 ;; Instructions
  29
  30 ;; For programmed use of isearch-mode, e.g. calling (isearch-forward),
  31 ;; isearch-mode behaves modally and does not return until the search
  32 ;; is completed.  It uses a recursive-edit to behave this way.  Note:
  33 ;; gnus does it wrong: (call-interactively 'isearch-forward).
  34
  35 ;; The key bindings active within isearch-mode are defined below in
  36 ;; `isearch-mode-map' which is given bindings close to the default
  37 ;; characters of the original isearch.el.  With `isearch-mode',
  38 ;; however, you can bind multi-character keys and it should be easier
  39 ;; to add new commands.  One bug though: keys with meta-prefix cannot
  40 ;; be longer than two chars.  Also see minibuffer-local-isearch-map
  41 ;; for bindings active during `isearch-edit-string'.
  42
  43 ;; Note to emacs version 19 users: isearch-mode should work even if
  44 ;; you switch windows with the mouse, in which case isearch-mode is
  45 ;; terminated automatically before the switch.  This is true of lemacs
  46 ;; too, with a few more cleanups I've neglected in this release.
  47 ;; No one has supplied patches for epoch yet.
  48
  49 ;; The search ring and completion commands automatically put you in
  50 ;; the minibuffer to edit the string.  This gives you a chance to
  51 ;; modify the search string before executing the search.  There are
  52 ;; three commands to terminate the editing: C-s and C-r exit the
  53 ;; minibuffer and search forward and reverse respectively, while C-m
  54 ;; exits and does a nonincremental search.
  55
  56 ;; Exiting immediately from isearch uses isearch-edit-string instead
  57 ;; of nonincremental-search, if search-nonincremental-instead is non-nil.
  58 ;; The name of this option should probably be changed if we decide to
  59 ;; keep the behavior.  No point in forcing nonincremental search until
  60 ;; the last possible moment.
  61
  62 ;; TODO
  63 ;; - Integrate the emacs 19 generalized command history.
  64 ;; - Think about incorporating query-replace.
  65 ;; - Hooks and options for failed search.
  66
  67 ;;; Change Log:
  68
  69 ;;; Changes before those recorded in ChangeLog:
  70
  71 ;;; Revision 1.4  92/09/14  16:26:02  liberte
  72 ;;; Added prefix args to isearch-forward, etc. to switch between
  73 ;;;    string and regular expression searching.
  74 ;;; Added some support for lemacs.
  75 ;;; Added general isearch-highlight option - but only for lemacs so far.
  76 ;;; Added support for frame switching in emacs 19.
  77 ;;; Added word search option to isearch-edit-string.
  78 ;;; Renamed isearch-quit to isearch-abort.
  79 ;;; Numerous changes to comments and doc strings.
  80 ;;;
  81 ;;; Revision 1.3  92/06/29  13:10:08  liberte
  82 ;;; Moved modal isearch-mode handling into isearch-mode.
  83 ;;; Got rid of buffer-local isearch variables.
  84 ;;; isearch-edit-string used by ring adjustments, completion, and
  85 ;;; nonincremental searching.  C-s and C-r are additional exit commands.
  86 ;;; Renamed all regex to regexp.
  87 ;;; Got rid of found-start and found-point globals.
  88 ;;; Generalized handling of upper-case chars.
  89
  90 ;;; Revision 1.2  92/05/27  11:33:57  liberte
  91 ;;; Emacs version 19 has a search ring, which is supported here.
  92 ;;; Other fixes found in the version 19 isearch are included here.
  93 ;;;
  94 ;;; Also see variables search-caps-disable-folding,
  95 ;;; search-nonincremental-instead, search-whitespace-regexp, and
  96 ;;; commands isearch-toggle-regexp, isearch-edit-string.
  97 ;;;
  98 ;;; semi-modal isearching is supported.
  99
 100 ;;; Changes for 1.1
 101 ;;; 3/18/92 Fixed invalid-regexp.
 102 ;;; 3/18/92 Fixed yanking in regexps.
 103
 104 ;;; Code:
 105
 106 \f
 107 ;;;========================================================================
 108 ;;; Some additional options and constants.
 109
 110 (defconst search-exit-option t
 111   "*Non-nil means random control characters terminate incremental search.")
 112
 113 (defvar search-slow-window-lines 1
 114   "*Number of lines in slow search display windows.
 115 These are the short windows used during incremental search on slow terminals.
 116 Negative means put the slow search window at the top (normally it's at bottom)
 117 and the value is minus the number of lines.")
 118
 119 (defvar search-slow-speed 1200
 120   "*Highest terminal speed at which to use \"slow\" style incremental search.
 121 This is the style where a one-line window is created to show the line
 122 that the search has reached.")
 123
 124 (defvar search-upper-case 'not-yanks
 125   "*If non-nil, upper case chars disable case fold searching.
 126 That is, upper and lower case chars must match exactly.
 127 This applies no matter where the chars come from, but does not
 128 apply to chars in regexps that are prefixed with `\\'.
 129 If this value is `not-yanks', yanked text is always downcased.")
 130
 131 (defvar search-nonincremental-instead t
 132   "*If non-nil, do a nonincremental search instead if exiting immediately.
 133 Actually, `isearch-edit-string' is called to let you enter the search
 134 string, and RET terminates editing and does a nonincremental search.")
 135
 136 (defconst search-whitespace-regexp "\\s-+"
 137   "*If non-nil, regular expression to match a sequence of whitespace chars.
 138 You might want to use something like \"[ \\t\\r\\n]+\" instead.")
 139
 140 ;; I removed the * from the doc string because highlighting is not
 141 ;; currently a clean thing to do.  Once highlighting is made clean,
 142 ;; this feature can be re-enabled and advertised.
 143 (defvar search-highlight nil
 144   "*Non-nil means incremental search highlights the current match.")
 145
 146 (defvar isearch-mode-hook nil
 147   "Function(s) to call after starting up an incremental search.")
 148
 149 (defvar isearch-mode-end-hook nil
 150   "Function(s) to call after terminating an incremental search.")
 151
 152 ;;;==================================================================
 153 ;;; Search ring.
 154
 155 (defvar search-ring nil
 156   "List of search string sequences.")
 157 (defvar regexp-search-ring nil
 158   "List of regular expression search string sequences.")
 159
 160 (defconst search-ring-max 16
 161   "*Maximum length of search ring before oldest elements are thrown away.")
 162 (defconst regexp-search-ring-max 16
 163   "*Maximum length of regexp search ring before oldest elements are thrown away.")
 164
 165 (defvar search-ring-yank-pointer nil
 166   "Index in `search-ring' of last string reused.
 167 nil if none yet.")
 168 (defvar regexp-search-ring-yank-pointer nil
 169   "Index in `regexp-search-ring' of last string reused.
 170 nil if none yet.")
 171
 172 (defvar search-ring-update nil
 173   "*Non-nil if advancing or retreating in the search ring should cause search.
 174 Default value, nil, means edit the string instead.")
 175
 176 ;;;====================================================
 177 ;;; Define isearch-mode keymap.
 178
 179 (defvar isearch-mode-map nil
 180   "Keymap for isearch-mode.")
 181
 182 (or isearch-mode-map
 183     (let* ((i 0)
 184            (map (make-keymap)))
 185       (or (vectorp (nth 1 map))
 186           (error "The initialization of isearch-mode-map must be updated"))
 187       ;; Give this map a vector 256 long, for dense binding
 188       ;; of a larger range of ordinary characters.
 189       (setcar (cdr map) (make-vector 256 nil))
 190
 191       ;; Make function keys, etc, exit the search.
 192       (define-key map [t] 'isearch-other-control-char)
 193       ;; Control chars, by default, end isearch mode transparently.
 194       ;; We need these explicit definitions because, in a dense keymap,
 195       ;; the binding for t does not affect characters.
 196       ;; We use a dense keymap to save space.
 197       (while (< i ?\ )
 198         (define-key map (make-string 1 i) 'isearch-other-control-char)
 199         (setq i (1+ i)))
 200
 201       ;; Printing chars extend the search string by default.
 202       (setq i ?\ )
 203       (while (< i (length (nth 1 map)))
 204         (define-key map (vector i) 'isearch-printing-char)
 205         (setq i (1+ i)))
 206
 207       ;; To handle local bindings with meta char prefix keys, define
 208       ;; another full keymap.  This must be done for any other prefix
 209       ;; keys as well, one full keymap per char of the prefix key.  It
 210       ;; would be simpler to disable the global keymap, and/or have a
 211       ;; default local key binding for any key not otherwise bound.
 212       (let ((meta-map (make-sparse-keymap)))
 213         (define-key map (char-to-string meta-prefix-char) meta-map)
 214         (define-key map [escape] meta-map))
 215       (define-key map (vector meta-prefix-char t) 'isearch-other-meta-char)
 216
 217       ;; Several non-printing chars change the searching behavior.
 218       (define-key map "\C-s" 'isearch-repeat-forward)
 219       (define-key map "\C-r" 'isearch-repeat-backward)
 220       (define-key map "\177" 'isearch-delete-char)
 221       (define-key map "\C-g" 'isearch-abort)
 222       ;; This assumes \e is the meta-prefix-char.
 223       (or (= ?\e meta-prefix-char)
 224           (error "Inconsistency in isearch.el"))
 225       (define-key map "\e\e\e" 'isearch-cancel)
 226       (define-key map  [escape escape escape] 'isearch-cancel)
 227
 228       (define-key map "\C-q" 'isearch-quote-char)
 229
 230       (define-key map "\r" 'isearch-exit)
 231       (define-key map "\C-j" 'isearch-printing-char)
 232       (define-key map "\t" 'isearch-printing-char)
 233       (define-key map " " 'isearch-whitespace-chars)
 234
 235       (define-key map "\C-w" 'isearch-yank-word)
 236       (define-key map "\C-y" 'isearch-yank-line)
 237
 238       ;; Bind the ASCII-equivalent "function keys" explicitly to nil
 239       ;; so that the default binding does not apply.
 240       ;; As a result, these keys translate thru function-key-map
 241       ;; as normal, and they have the effect of the equivalent ASCII char.
 242       ;; We bind [escape] below.
 243       (define-key map [tab] 'nil)
 244       (define-key map [kp-0] 'nil)
 245       (define-key map [kp-1] 'nil)
 246       (define-key map [kp-2] 'nil)
 247       (define-key map [kp-3] 'nil)
 248       (define-key map [kp-4] 'nil)
 249       (define-key map [kp-5] 'nil)
 250       (define-key map [kp-6] 'nil)
 251       (define-key map [kp-7] 'nil)
 252       (define-key map [kp-8] 'nil)
 253       (define-key map [kp-9] 'nil)
 254       (define-key map [kp-add] 'nil)
 255       (define-key map [kp-subtract] 'nil)
 256       (define-key map [kp-multiply] 'nil)
 257       (define-key map [kp-divide] 'nil)
 258       (define-key map [kp-decimal] 'nil)
 259       (define-key map [kp-separator] 'nil)
 260       (define-key map [kp-equal] 'nil)
 261       (define-key map [kp-tab] 'nil)
 262       (define-key map [kp-space] 'nil)
 263       (define-key map [kp-enter] 'nil)
 264       (define-key map [delete] 'nil)
 265       (define-key map [backspace] 'nil)
 266       (define-key map [return] 'nil)
 267       (define-key map [newline] 'nil)
 268
 269       ;; Define keys for regexp chars * ? |.
 270       ;; Nothing special for + because it matches at least once.
 271       (define-key map "*" 'isearch-*-char)
 272       (define-key map "?" 'isearch-*-char)
 273       (define-key map "|" 'isearch-|-char)
 274
 275 ;;; Turned off because I find I expect to get the global definition--rms.
 276 ;;;      ;; Instead bind C-h to special help command for isearch-mode.
 277 ;;;      (define-key map "\C-h" 'isearch-mode-help)
 278
 279       (define-key map "\M-n" 'isearch-ring-advance)
 280       (define-key map "\M-p" 'isearch-ring-retreat)
 281       (define-key map "\M-y" 'isearch-yank-kill)
 282
 283       (define-key map "\M-\t" 'isearch-complete)
 284
 285       ;; Switching frames should terminate isearch-mode
 286       (define-key map [switch-frame] 'isearch-switch-frame-handler)
 287
 288       (setq isearch-mode-map map)
 289       ))
 290
 291 ;; Some bindings you may want to put in your isearch-mode-hook.
 292 ;; Suggest some alternates...
 293 ;; (define-key isearch-mode-map "\C-t" 'isearch-toggle-case-fold)
 294 ;; (define-key isearch-mode-map "\C-t" 'isearch-toggle-regexp)
 295 ;; (define-key isearch-mode-map "\C-^" 'isearch-edit-string)
 296
 297
 298 (defvar minibuffer-local-isearch-map nil
 299   "Keymap for editing isearch strings in the minibuffer.")
 300
 301 (or minibuffer-local-isearch-map
 302     (let ((map (copy-keymap minibuffer-local-map)))
 303       (define-key map "\r" 'isearch-nonincremental-exit-minibuffer)
 304       (define-key map "\M-n" 'isearch-ring-advance-edit)
 305       (define-key map "\M-p" 'isearch-ring-retreat-edit)
 306       (define-key map "\M-\t" 'isearch-complete-edit)
 307       (define-key map "\C-s" 'isearch-forward-exit-minibuffer)
 308       (define-key map "\C-r" 'isearch-reverse-exit-minibuffer)
 309       (setq minibuffer-local-isearch-map map)
 310       ))
 311
 312 ;;;========================================================
 313 ;; Internal variables declared globally for byte-compiler.
 314 ;; These are all set with setq while isearching
 315 ;; and bound locally while editing the search string.
 316
 317 (defvar isearch-forward nil)    ; Searching in the forward direction.
 318 (defvar isearch-regexp nil)     ; Searching for a regexp.
 319 (defvar isearch-word nil)       ; Searching for words.
 320
 321 (defvar isearch-cmds nil)   ; Stack of search status sets.
 322 (defvar isearch-string "")  ; The current search string.
 323 (defvar isearch-message "") ; text-char-description version of isearch-string
 324
 325 (defvar isearch-success t)              ; Searching is currently successful.
 326 (defvar isearch-invalid-regexp nil)     ; Regexp not well formed.
 327 (defvar isearch-within-brackets nil)    ; Regexp has unclosed [.
 328 (defvar isearch-other-end nil)  ; Start (end) of match if forward (backward).
 329 (defvar isearch-wrapped nil)    ; Searching restarted from the top (bottom).
 330 (defvar isearch-barrier 0)
 331
 332 ; case-fold-search while searching.
 333 ;   either nil, t, or 'yes.  'yes means the same as t except that mixed
 334 ;   case in the search string is ignored.
 335 (defvar isearch-case-fold-search nil)
 336
 337 (defvar isearch-adjusted nil)
 338 (defvar isearch-slow-terminal-mode nil)
 339 ;;; If t, using a small window.
 340 (defvar isearch-small-window nil)
 341 (defvar isearch-opoint 0)
 342 ;;; The window configuration active at the beginning of the search.
 343 (defvar isearch-window-configuration nil)
 344
 345 ;; Flag to indicate a yank occurred, so don't move the cursor.
 346 (defvar isearch-yank-flag nil)
 347
 348 ;;; A function to be called after each input character is processed.
 349 ;;; (It is not called after characters that exit the search.)
 350 ;;; It is only set from an optional argument to `isearch-mode'.
 351 (defvar isearch-op-fun nil)
 352
 353 ;;;  Is isearch-mode in a recursive edit for modal searching.
 354 (defvar isearch-recursive-edit nil)
 355
 356 ;;; Should isearch be terminated after doing one search?
 357 (defvar isearch-nonincremental nil)
 358
 359 ;; New value of isearch-forward after isearch-edit-string.
 360 (defvar isearch-new-forward nil)
 361
 362
 363 ;;;==============================================================
 364 ;; Minor-mode-alist changes - kind of redundant with the
 365 ;; echo area, but if isearching in multiple windows, it can be useful.
 366
 367 (or (assq 'isearch-mode minor-mode-alist)
 368     (nconc minor-mode-alist
 369            (list '(isearch-mode isearch-mode))))
 370
 371 (defvar isearch-mode nil) ;; Name of the minor mode, if non-nil.
 372 (make-variable-buffer-local 'isearch-mode)
 373
 374 (define-key global-map "\C-s" 'isearch-forward)
 375 (define-key esc-map "\C-s" 'isearch-forward-regexp)
 376 (define-key global-map "\C-r" 'isearch-backward)
 377 (define-key esc-map "\C-r" 'isearch-backward-regexp)
 378
 379 ;;;===============================================================
 380 ;;; Entry points to isearch-mode.
 381 ;;; These four functions should replace those in loaddefs.el
 382 ;;; An alternative is to defalias isearch-forward etc to isearch-mode,
 383 ;;; and look at this-command to set the options accordingly.
 384
 385 (defun isearch-forward (&optional regexp-p no-recursive-edit)
 386   "\
 387 Do incremental search forward.
 388 With a prefix argument, do an incremental regular expression search instead.
 389 \\<isearch-mode-map>
 390 As you type characters, they add to the search string and are found.
 391 The following non-printing keys are bound in `isearch-mode-map'.
 392
 393 Type \\[isearch-delete-char] to cancel characters from end of search string.
 394 Type \\[isearch-exit] to exit, leaving point at location found.
 395 Type LFD (C-j) to match end of line.
 396 Type \\[isearch-repeat-forward] to search again forward,\
 397  \\[isearch-repeat-backward] to search again backward.
 398 Type \\[isearch-yank-word] to yank word from buffer onto end of search\
 399  string and search for it.
 400 Type \\[isearch-yank-line] to yank rest of line onto end of search string\
 401  and search for it.
 402 Type \\[isearch-quote-char] to quote control character to search for it.
 403 \\[isearch-abort] while searching or when search has failed cancels input\
 404  back to what has
 405  been found successfully.
 406 \\[isearch-abort] when search is successful aborts and moves point to\
 407  starting point.
 408
 409 Also supported is a search ring of the previous 16 search strings.
 410 Type \\[isearch-ring-advance] to search for the next item in the search ring.
 411 Type \\[isearch-ring-retreat] to search for the previous item in the search\
 412  ring.
 413 Type \\[isearch-complete] to complete the search string using the search ring.
 414
 415 The above keys, bound in `isearch-mode-map', are often controlled by
 416  options; do M-x apropos on search-.* to find them.
 417 Other control and meta characters terminate the search
 418  and are then executed normally (depending on `search-exit-option').
 419
 420 If this function is called non-interactively, it does not return to
 421 the calling function until the search is done."
 422
 423   (interactive "P\np")
 424   (isearch-mode t (not (null regexp-p)) nil (not no-recursive-edit)))
 425
 426 (defun isearch-forward-regexp (&optional not-regexp no-recursive-edit)
 427   "\
 428 Do incremental search forward for regular expression.
 429 With a prefix argument, do a regular string search instead.
 430 Like ordinary incremental search except that your input
 431 is treated as a regexp.  See \\[isearch-forward] for more info."
 432   (interactive "P\np")
 433   (isearch-mode t (null not-regexp) nil (not no-recursive-edit)))
 434
 435 (defun isearch-backward (&optional regexp-p no-recursive-edit)
 436   "\
 437 Do incremental search backward.
 438 With a prefix argument, do a regular expression search instead.
 439 See \\[isearch-forward] for more information."
 440   (interactive "P\np")
 441   (isearch-mode nil (not (null regexp-p)) nil (not no-recursive-edit)))
 442
 443 (defun isearch-backward-regexp (&optional not-regexp no-recursive-edit)
 444   "\
 445 Do incremental search backward for regular expression.
 446 With a prefix argument, do a regular string search instead.
 447 Like ordinary incremental search except that your input
 448 is treated as a regexp.  See \\[isearch-forward] for more info."
 449   (interactive "P\np")
 450   (isearch-mode nil (null not-regexp) nil (not no-recursive-edit)))
 451
 452
 453 (defun isearch-mode-help ()
 454   (interactive)
 455   (describe-function 'isearch-forward)
 456   (isearch-update))
 457
 458 \f
 459 ;;;==================================================================
 460 ;; isearch-mode only sets up incremental search for the minor mode.
 461 ;; All the work is done by the isearch-mode commands.
 462
 463 ;; Not used yet:
 464 ;;(defconst isearch-commands '(isearch-forward isearch-backward
 465 ;;                           isearch-forward-regexp isearch-backward-regexp)
 466 ;;  "List of commands for which isearch-mode does not recursive-edit.")
 467
 468
 469 (defun isearch-mode (forward &optional regexp op-fun recursive-edit word-p)
 470   "Start isearch minor mode.  Called by isearch-forward, etc."
 471
 472   ;; Initialize global vars.
 473   (setq isearch-forward forward
 474         isearch-regexp regexp
 475         isearch-word word-p
 476         isearch-op-fun op-fun
 477         isearch-case-fold-search case-fold-search
 478         isearch-string ""
 479         isearch-message ""
 480         isearch-cmds nil
 481         isearch-success t
 482         isearch-wrapped nil
 483         isearch-barrier (point)
 484         isearch-adjusted nil
 485         isearch-yank-flag nil
 486         isearch-invalid-regexp nil
 487         isearch-within-brackets nil
 488         isearch-slow-terminal-mode (and (<= baud-rate search-slow-speed)
 489                                         (> (window-height)
 490                                            (* 4 search-slow-window-lines)))
 491         isearch-other-end nil
 492         isearch-small-window nil
 493
 494         isearch-opoint (point)
 495         search-ring-yank-pointer nil
 496         regexp-search-ring-yank-pointer nil)
 497   (setq isearch-window-configuration
 498         (if isearch-slow-terminal-mode (current-window-configuration) nil))
 499
 500   (setq isearch-mode " Isearch")  ;; forward? regexp?
 501   (set-buffer-modified-p (buffer-modified-p)) ; update modeline
 502
 503   (isearch-push-state)
 504
 505   (make-local-variable 'overriding-local-map)
 506   (setq overriding-local-map isearch-mode-map)
 507   (isearch-update)
 508   (run-hooks 'isearch-mode-hook)
 509
 510   (setq mouse-leave-buffer-hook '(isearch-done))
 511
 512   ;; isearch-mode can be made modal (in the sense of not returning to
 513   ;; the calling function until searching is completed) by entering
 514   ;; a recursive-edit and exiting it when done isearching.
 515   (if recursive-edit
 516       (let ((isearch-recursive-edit t))
 517         (recursive-edit)))
 518   isearch-success)
 519
 520
 521 ;;;====================================================
 522 ;; Some high level utilities.  Others below.
 523
 524 (defun isearch-update ()
 525   ;; Called after each command to update the display.
 526   (if (null unread-command-events)
 527       (progn
 528         (if (not (input-pending-p))
 529             (isearch-message))
 530         (if (and isearch-slow-terminal-mode
 531                  (not (or isearch-small-window
 532                           (pos-visible-in-window-p))))
 533             (let ((found-point (point)))
 534               (setq isearch-small-window t)
 535               (move-to-window-line 0)
 536               (let ((window-min-height 1))
 537                 (split-window nil (if (< search-slow-window-lines 0)
 538                                       (1+ (- search-slow-window-lines))
 539                                     (- (window-height)
 540                                        (1+ search-slow-window-lines)))))
 541               (if (< search-slow-window-lines 0)
 542                   (progn (vertical-motion (- 1 search-slow-window-lines))
 543                          (set-window-start (next-window) (point))
 544                          (set-window-hscroll (next-window)
 545                                              (window-hscroll))
 546                          (set-window-hscroll (selected-window) 0))
 547                 (other-window 1))
 548               (goto-char found-point)))
 549         (if isearch-other-end
 550             (if (< isearch-other-end (point)) ; isearch-forward?
 551                 (isearch-highlight isearch-other-end (point))
 552               (isearch-highlight (point) isearch-other-end))
 553           (isearch-dehighlight nil))
 554         ))
 555   (setq ;; quit-flag nil  not for isearch-mode
 556    isearch-adjusted nil
 557    isearch-yank-flag nil)
 558   )
 559
 560 (defun isearch-done (&optional nopush edit)
 561   (setq mouse-leave-buffer-hook nil)
 562   ;; Called by all commands that terminate isearch-mode.
 563   ;; If NOPUSH is non-nil, we don't push the string on the search ring.
 564   (setq overriding-local-map nil)
 565   ;; (setq pre-command-hook isearch-old-pre-command-hook) ; for lemacs
 566   (isearch-dehighlight t)
 567   (let ((found-start (window-start (selected-window)))
 568         (found-point (point)))
 569     (if isearch-window-configuration
 570         (set-window-configuration isearch-window-configuration))
 571
 572     (if isearch-small-window
 573         (goto-char found-point)
 574       ;; Exiting the save-window-excursion clobbers window-start; restore it.
 575       (set-window-start (selected-window) found-start t))
 576
 577     ;; If there was movement, mark the starting position.
 578     ;; Maybe should test difference between and set mark iff > threshold.
 579     (if (/= (point) isearch-opoint)
 580         (or (and transient-mark-mode mark-active)
 581             (progn
 582               (push-mark isearch-opoint t)
 583               (or executing-macro (> (minibuffer-depth) 0)
 584                   (message "Mark saved where search started"))))))
 585
 586   (setq isearch-mode nil)
 587   (set-buffer-modified-p (buffer-modified-p))  ;; update modeline
 588
 589   (if (and (> (length isearch-string) 0) (not nopush))
 590       ;; Update the ring data.
 591       (if isearch-regexp
 592           (if (or (null regexp-search-ring)
 593                   (not (string= isearch-string (car regexp-search-ring))))
 594               (progn
 595                 (setq regexp-search-ring
 596                       (cons isearch-string regexp-search-ring))
 597                 (if (> (length regexp-search-ring) regexp-search-ring-max)
 598                     (setcdr (nthcdr (1- search-ring-max) regexp-search-ring)
 599                             nil))))
 600         (if (or (null search-ring)
 601                 (not (string= isearch-string (car search-ring))))
 602             (progn
 603               (setq search-ring (cons isearch-string search-ring))
 604               (if (> (length search-ring) search-ring-max)
 605                   (setcdr (nthcdr (1- search-ring-max) search-ring) nil))))))
 606
 607   (run-hooks 'isearch-mode-end-hook)
 608   (and (not edit) isearch-recursive-edit (exit-recursive-edit)))
 609
 610 ;;;=======================================================
 611 ;;; Switching buffers should first terminate isearch-mode.
 612 ;;; This is done quite differently for each variant of emacs.
 613 ;;; For lemacs, see Exiting in lemacs below
 614
 615 ;; For Emacs 19, the frame switch event is handled.
 616 (defun isearch-switch-frame-handler ()
 617   (interactive) ;; Is this necessary?
 618   ;; First terminate isearch-mode.
 619   (isearch-done)
 620   (handle-switch-frame (car (cdr (isearch-last-command-char)))))
 621
 622 ;;;========================================================
 623
 624 \f
 625 ;;;====================================================
 626 ;; Commands active while inside of the isearch minor mode.
 627
 628 (defun isearch-exit ()
 629   "Exit search normally.
 630 However, if this is the first command after starting incremental
 631 search and `search-nonincremental-instead' is non-nil, do a
 632 nonincremental search instead via `isearch-edit-string'."
 633   (interactive)
 634   (if (and search-nonincremental-instead
 635            (= 0 (length isearch-string)))
 636       (let ((isearch-nonincremental t))
 637         (isearch-edit-string)))
 638   (isearch-done))
 639
 640
 641 (defun isearch-edit-string ()
 642   "Edit the search string in the minibuffer.
 643 The following additional command keys are active while editing.
 644 \\<minibuffer-local-isearch-map>
 645 \\[exit-minibuffer] to resume incremental searching with the edited string.
 646 \\[isearch-nonincremental-exit-minibuffer] to do one nonincremental search.
 647 \\[isearch-forward-exit-minibuffer] to resume isearching forward.
 648 \\[isearch-reverse-exit-minibuffer] to resume isearching backward.
 649 \\[isearch-ring-advance-edit] to replace the search string with the next item in the search ring.
 650 \\[isearch-ring-retreat-edit] to replace the search string with the previous item in the search ring.
 651 \\[isearch-complete-edit] to complete the search string using the search ring.
 652 \\<isearch-mode-map>
 653 If first char entered is \\[isearch-yank-word], then do word search instead."
 654
 655   ;; This code is very hairy for several reasons, explained in the code.
 656   ;; Mainly, isearch-mode must be terminated while editing and then restarted.
 657   ;; If there were a way to catch any change of buffer from the minibuffer,
 658   ;; this could be simplified greatly.
 659   ;; Editing doesn't back up the search point.  Should it?
 660   (interactive)
 661   (condition-case err
 662       (let ((isearch-nonincremental isearch-nonincremental)
 663
 664             ;; Locally bind all isearch global variables to protect them
 665             ;; from recursive isearching.
 666             ;; isearch-string -message and -forward are not bound
 667             ;; so they may be changed.  Instead, save the values.
 668             (isearch-new-string isearch-string)
 669             (isearch-new-message isearch-message)
 670             (isearch-new-forward isearch-forward)
 671             (isearch-new-word isearch-word)
 672
 673             (isearch-regexp isearch-regexp)
 674             (isearch-op-fun isearch-op-fun)
 675             (isearch-cmds isearch-cmds)
 676             (isearch-success isearch-success)
 677             (isearch-wrapped isearch-wrapped)
 678             (isearch-barrier isearch-barrier)
 679             (isearch-adjusted isearch-adjusted)
 680             (isearch-yank-flag isearch-yank-flag)
 681             (isearch-invalid-regexp isearch-invalid-regexp)
 682             (isearch-within-brackets isearch-within-brackets)
 683             (isearch-other-end isearch-other-end)
 684             (isearch-opoint isearch-opoint)
 685             (isearch-slow-terminal-mode isearch-slow-terminal-mode)
 686             (isearch-small-window isearch-small-window)
 687             (isearch-recursive-edit isearch-recursive-edit)
 688             ;; Save current configuration so we can restore it here.
 689             (isearch-window-configuration (current-window-configuration))
 690             )
 691
 692         ;; Actually terminate isearching until editing is done.
 693         ;; This is so that the user can do anything without failure,
 694         ;; like switch buffers and start another isearch, and return.
 695         (condition-case err
 696             (isearch-done t t)
 697           (exit nil))                   ; was recursive editing
 698
 699         (isearch-message) ;; for read-char
 700         (unwind-protect
 701             (let* (;; Why does following read-char echo?
 702                    ;;(echo-keystrokes 0) ;; not needed with above message
 703                    (e (let ((cursor-in-echo-area t))
 704                         (read-event)))
 705                    ;; Binding minibuffer-history-symbol to nil is a work-around
 706                    ;; for some incompatibility with gmhist.
 707                    (minibuffer-history-symbol)
 708                    (message-log-max nil))
 709               ;; If the first character the user types when we prompt them
 710               ;; for a string is the yank-word character, then go into
 711               ;; word-search mode.  Otherwise unread that character and
 712               ;; read a key the normal way.
 713               ;; Word search does not apply (yet) to regexp searches,
 714               ;; no check is made here.
 715               (message (isearch-message-prefix nil nil t))
 716               (if (eq 'isearch-yank-word
 717                       (lookup-key isearch-mode-map (vector e)))
 718                   (setq isearch-word t  ;; so message-prefix is right
 719                         isearch-new-word t)
 720                 (isearch-unread e))
 721               (setq cursor-in-echo-area nil)
 722               (setq isearch-new-string
 723                     (let (junk-ring)
 724                       (read-from-minibuffer
 725                        (isearch-message-prefix nil nil isearch-nonincremental)
 726                        isearch-string
 727                        minibuffer-local-isearch-map nil
 728                        'junk-ring))
 729                     isearch-new-message
 730                     (mapconcat 'isearch-text-char-description
 731                                isearch-new-string "")))
 732           ;; Always resume isearching by restarting it.
 733           (isearch-mode isearch-forward
 734                         isearch-regexp
 735                         isearch-op-fun
 736                         nil
 737                         isearch-word)
 738
 739           ;; Copy new local values to isearch globals
 740           (setq isearch-string isearch-new-string
 741                 isearch-message isearch-new-message
 742                 isearch-forward isearch-new-forward
 743                 isearch-word isearch-new-word))
 744
 745         ;; Empty isearch-string means use default.
 746         (if (= 0 (length isearch-string))
 747             (setq isearch-string (car (if isearch-regexp regexp-search-ring
 748                                         search-ring)))
 749           ;; This used to set the last search string,
 750           ;; but I think it is not right to do that here.
 751           ;; Only the string actually used should be saved.
 752           )
 753
 754         ;; Reinvoke the pending search.
 755         (isearch-push-state)
 756         (isearch-search)
 757         (isearch-update)
 758         (if isearch-nonincremental
 759             (progn
 760               ;; (sit-for 1) ;; needed if isearch-done does: (message "")
 761               (isearch-done))))
 762
 763     (quit  ; handle abort-recursive-edit
 764      (isearch-abort)  ;; outside of let to restore outside global values
 765      )))
 766
 767 (defun isearch-nonincremental-exit-minibuffer ()
 768   (interactive)
 769   (setq isearch-nonincremental t)
 770   (exit-minibuffer))
 771
 772 (defun isearch-forward-exit-minibuffer ()
 773   (interactive)
 774   (setq isearch-new-forward t)
 775   (exit-minibuffer))
 776
 777 (defun isearch-reverse-exit-minibuffer ()
 778   (interactive)
 779   (setq isearch-new-forward nil)
 780   (exit-minibuffer))
 781
 782 (defun isearch-cancel ()
 783   "Terminate the search and go back to the starting point."
 784   (interactive)
 785   (goto-char isearch-opoint)
 786   (isearch-done t)
 787   (signal 'quit nil))  ; and pass on quit signal
 788
 789 (defun isearch-abort ()
 790   "Abort incremental search mode if searching is successful, signalling quit.
 791 Otherwise, revert to previous successful search and continue searching.
 792 Use `isearch-exit' to quit without signalling."
 793   (interactive)
 794 ;;  (ding)  signal instead below, if quitting
 795   (discard-input)
 796   (if isearch-success
 797       ;; If search is successful, move back to starting point
 798       ;; and really do quit.
 799       (progn (goto-char isearch-opoint)
 800              (isearch-done t)   ; exit isearch
 801              (signal 'quit nil))  ; and pass on quit signal
 802     ;; If search is failing, rub out until it is once more successful.
 803     (while (not isearch-success) (isearch-pop-state))
 804     (isearch-update)))
 805
 806
 807 (defun isearch-repeat (direction)
 808   ;; Utility for isearch-repeat-forward and -backward.
 809   (if (eq isearch-forward (eq direction 'forward))
 810       ;; C-s in forward or C-r in reverse.
 811       (if (equal isearch-string "")
 812           ;; If search string is empty, use last one.
 813           (setq isearch-string
 814                 (or (if isearch-regexp
 815                         (car regexp-search-ring)
 816                       (car search-ring))
 817                     "")
 818                 isearch-message
 819                 (mapconcat 'isearch-text-char-description
 820                            isearch-string ""))
 821         ;; If already have what to search for, repeat it.
 822         (or isearch-success
 823             (progn
 824
 825               (goto-char (if isearch-forward (point-min) (point-max)))
 826               (setq isearch-wrapped t))))
 827     ;; C-s in reverse or C-r in forward, change direction.
 828     (setq isearch-forward (not isearch-forward)))
 829
 830   (setq isearch-barrier (point)) ; For subsequent \| if regexp.
 831
 832   (if (equal isearch-string "")
 833       (setq isearch-success t)
 834     (if (and isearch-success (equal (match-end 0) (match-beginning 0)))
 835         ;; If repeating a search that found
 836         ;; an empty string, ensure we advance.
 837         (if (if isearch-forward (eobp) (bobp))
 838             ;; If there's nowhere to advance to, fail (and wrap next time).
 839             (progn
 840               (setq isearch-success nil)
 841               (ding))
 842           (forward-char (if isearch-forward 1 -1))
 843           (isearch-search))
 844       (isearch-search)))
 845
 846   (isearch-push-state)
 847   (isearch-update))
 848
 849 (defun isearch-repeat-forward ()
 850   "Repeat incremental search forwards."
 851   (interactive)
 852   (isearch-repeat 'forward))
 853
 854 (defun isearch-repeat-backward ()
 855   "Repeat incremental search backwards."
 856   (interactive)
 857   (isearch-repeat 'backward))
 858
 859 (defun isearch-toggle-regexp ()
 860   "Toggle regexp searching on or off."
 861   ;; The status stack is left unchanged.
 862   (interactive)
 863   (setq isearch-regexp (not isearch-regexp))
 864   (if isearch-regexp (setq isearch-word nil))
 865   (isearch-update))
 866
 867 (defun isearch-toggle-case-fold ()
 868   "Toggle case folding in searching on or off."
 869   (interactive)
 870   (setq isearch-case-fold-search
 871         (if isearch-case-fold-search nil 'yes))
 872   (let ((message-log-max nil))
 873     (message "%s%s [case %ssensitive]"
 874              (isearch-message-prefix nil nil isearch-nonincremental)
 875              isearch-message
 876              (if isearch-case-fold-search "in" "")))
 877   (setq isearch-adjusted t)
 878   (sit-for 1)
 879   (isearch-update))
 880
 881 (defun isearch-delete-char ()
 882   "Discard last input item and move point back.
 883 If no previous match was done, just beep."
 884   (interactive)
 885   (if (null (cdr isearch-cmds))
 886       (ding)
 887     (isearch-pop-state))
 888   (isearch-update))
 889
 890
 891 (defun isearch-yank (chunk)
 892   ;; Helper for isearch-yank-word and isearch-yank-line
 893   ;; CHUNK should be word, line or kill.
 894   (let ((string (cond
 895                  ((eq chunk 'kill)
 896                   (current-kill 0))
 897                  (t
 898                   (save-excursion
 899                     (and (not isearch-forward) isearch-other-end
 900                          (goto-char isearch-other-end))
 901                     (buffer-substring
 902                      (point)
 903                      (save-excursion
 904                        (cond
 905                         ((eq chunk 'word)
 906                          (forward-word 1))
 907                         ((eq chunk 'line)
 908                          (end-of-line)))
 909                        (point))))))))
 910     ;; Downcase the string if not supposed to case-fold yanked strings.
 911     (if (and isearch-case-fold-search
 912              (eq 'not-yanks search-upper-case))
 913         (setq string (downcase string)))
 914     (if isearch-regexp (setq string (regexp-quote string)))
 915     (setq isearch-string (concat isearch-string string)
 916           isearch-message
 917           (concat isearch-message
 918                   (mapconcat 'isearch-text-char-description
 919                              string ""))
 920           ;; Don't move cursor in reverse search.
 921           isearch-yank-flag t))
 922   (isearch-search-and-update))
 923
 924 (defun isearch-yank-kill ()
 925   "Pull string from kill ring into search string."
 926   (interactive)
 927   (isearch-yank 'kill))
 928
 929 (defun isearch-yank-word ()
 930   "Pull next word from buffer into search string."
 931   (interactive)
 932   (isearch-yank 'word))
 933
 934 (defun isearch-yank-line ()
 935   "Pull rest of line from buffer into search string."
 936   (interactive)
 937   (isearch-yank 'line))
 938
 939
 940 (defun isearch-search-and-update ()
 941   ;; Do the search and update the display.
 942   (if (and (not isearch-success)
 943            ;; unsuccessful regexp search may become
 944            ;;  successful by addition of characters which
 945            ;;  make isearch-string valid
 946            (not isearch-regexp))
 947       nil
 948     ;; In reverse search, adding stuff at
 949     ;; the end may cause zero or many more chars to be
 950     ;; matched, in the string following point.
 951     ;; Allow all those possibilities without moving point as
 952     ;; long as the match does not extend past search origin.
 953     (if (and (not isearch-forward) (not isearch-adjusted)
 954              (condition-case ()
 955                  (looking-at (if isearch-regexp isearch-string
 956                                (regexp-quote isearch-string)))
 957                (error nil))
 958                (or isearch-yank-flag
 959                    (<= (match-end 0)
 960                        (min isearch-opoint isearch-barrier))))
 961         (setq isearch-success t
 962               isearch-invalid-regexp nil
 963               isearch-within-brackets nil
 964               isearch-other-end (match-end 0))
 965       ;; Not regexp, not reverse, or no match at point.
 966       (if (and isearch-other-end (not isearch-adjusted))
 967           (goto-char (if isearch-forward isearch-other-end
 968                        (min isearch-opoint
 969                             isearch-barrier
 970                             (1+ isearch-other-end)))))
 971       (isearch-search)
 972       ))
 973   (isearch-push-state)
 974   (if isearch-op-fun (funcall isearch-op-fun))
 975   (isearch-update))
 976
 977
 978 ;; *, ?, and | chars can make a regexp more liberal.
 979 ;; They can make a regexp match sooner or make it succeed instead of failing.
 980 ;; So go back to place last successful search started
 981 ;; or to the last ^S/^R (barrier), whichever is nearer.
 982 ;; + needs no special handling because the string must match at least once.
 983
 984 (defun isearch-*-char ()
 985   "Handle * and ? specially in regexps."
 986   (interactive)
 987   (if isearch-regexp
 988
 989       (progn
 990         (setq isearch-adjusted t)
 991         (let ((cs (nth (if isearch-forward
 992                            5            ; isearch-other-end
 993                          2)             ; saved (point)
 994                        (car (cdr isearch-cmds)))))
 995           ;; (car isearch-cmds) is after last search;
 996           ;; (car (cdr isearch-cmds)) is from before it.
 997           (setq cs (or cs isearch-barrier))
 998           (goto-char
 999            (if isearch-forward
1000                (max cs isearch-barrier)
1001              (min cs isearch-barrier))))))
1002   (isearch-process-search-char (isearch-last-command-char)))
1003
1004
1005 (defun isearch-|-char ()
1006   "If in regexp search, jump to the barrier."
1007   (interactive)
1008   (if isearch-regexp
1009       (progn
1010         (setq isearch-adjusted t)
1011         (goto-char isearch-barrier)))
1012   (isearch-process-search-char (isearch-last-command-char)))
1013
1014
1015 (defalias 'isearch-other-control-char 'isearch-other-meta-char)
1016
1017 (defun isearch-other-meta-char ()
1018   "Exit the search normally and reread this key sequence.
1019 But only if `search-exit-option' is non-nil, the default.
1020 If it is the symbol `edit', the search string is edited in the minibuffer
1021 and the meta character is unread so that it applies to editing the string."
1022   (interactive)
1023   (cond ((eq search-exit-option 'edit)
1024          (let ((key (this-command-keys)))
1025            (apply 'isearch-unread (listify-key-sequence key)))
1026          (isearch-edit-string))
1027         (search-exit-option
1028          (let* ((key (this-command-keys))
1029                 (main-event (aref key 0))
1030                 window)
1031            (apply 'isearch-unread (listify-key-sequence key))
1032            ;; Properly handle scroll-bar and mode-line clicks
1033            ;; for which a dummy prefix event was generated as (aref key 0).
1034            (and (> (length key) 1)
1035                 (symbolp (aref key 0))
1036                 (listp (aref key 1))
1037                 (not (numberp (posn-point (event-start (aref key 1)))))
1038                 ;; Convert the event back into its raw form,
1039                 ;; with the dummy prefix implicit in the mouse event,
1040                 ;; so it will get split up once again.
1041                 (progn (setq unread-command-events
1042                              (cdr unread-command-events))
1043                        (setq main-event (car unread-command-events))
1044                        (setcar (cdr (event-start main-event))
1045                                (car (nth 1 (event-start main-event))))))
1046            ;; If we got a mouse click, maybe it was read with the buffer
1047            ;; it was clicked on.  If so, that buffer, not the current one,
1048            ;; is in isearch mode.  So end the search in that buffer.
1049            (if (and (listp main-event)
1050                     (setq window (posn-window (event-start main-event)))
1051                     (windowp window))
1052                (save-excursion
1053                  (set-buffer (window-buffer window))
1054                  (isearch-done))
1055              (isearch-done))))
1056         (t;; otherwise nil
1057          (isearch-process-search-string (this-command-keys)
1058                                         (this-command-keys)))))
1059
1060 (defun isearch-quote-char ()
1061   "Quote special characters for incremental search."
1062   (interactive)
1063   (isearch-process-search-char (read-quoted-char (isearch-message t))))
1064
1065 (defun isearch-return-char ()
1066   "Convert return into newline for incremental search.
1067 Obsolete."
1068   (interactive)
1069   (isearch-process-search-char ?\n))
1070
1071 (defun isearch-printing-char ()
1072   "Add this ordinary printing character to the search string and search."
1073   (interactive)
1074   (isearch-process-search-char (isearch-last-command-char)))
1075
1076 (defun isearch-whitespace-chars ()
1077   "Match all whitespace chars, if in regexp mode.
1078 If you want to search for just a space, type C-q SPC."
1079   (interactive)
1080   (if isearch-regexp
1081       (if (and search-whitespace-regexp (not isearch-within-brackets))
1082           (isearch-process-search-string search-whitespace-regexp " ")
1083         (isearch-printing-char))
1084     (progn
1085       ;; This way of doing word search doesn't correctly extend current search.
1086       ;;      (setq isearch-word t)
1087       ;;      (setq isearch-adjusted t)
1088       ;;      (goto-char isearch-barrier)
1089       (isearch-printing-char))))
1090
1091 (defun isearch-process-search-char (char)
1092   ;; Append the char to the search string, update the message and re-search.
1093   (isearch-process-search-string
1094    (isearch-char-to-string char)
1095    (isearch-text-char-description char)))
1096
1097 (defun isearch-process-search-string (string message)
1098   (setq isearch-string (concat isearch-string string)
1099         isearch-message (concat isearch-message message))
1100   (isearch-search-and-update))
1101
1102 \f
1103 ;;===========================================================
1104 ;; Search Ring
1105
1106 (defun isearch-ring-adjust1 (advance)
1107   ;; Helper for isearch-ring-adjust
1108   (let* ((ring (if isearch-regexp regexp-search-ring search-ring))
1109          (length (length ring))
1110          (yank-pointer-name (if isearch-regexp
1111                                 'regexp-search-ring-yank-pointer
1112                               'search-ring-yank-pointer))
1113          (yank-pointer (eval yank-pointer-name)))
1114     (if (zerop length)
1115         ()
1116       (set yank-pointer-name
1117            (setq yank-pointer
1118                  (mod (+ (or yank-pointer 0)
1119                          (if advance -1 1))
1120                       length)))
1121       (setq isearch-string (nth yank-pointer ring)
1122             isearch-message (mapconcat 'isearch-text-char-description
1123                                        isearch-string "")))))
1124
1125 (defun isearch-ring-adjust (advance)
1126   ;; Helper for isearch-ring-advance and isearch-ring-retreat
1127   (if (cdr isearch-cmds)  ;; is there more than one thing on stack?
1128       (isearch-pop-state))
1129   (isearch-ring-adjust1 advance)
1130   (isearch-push-state)
1131   (if search-ring-update
1132       (progn
1133         (isearch-search)
1134         (isearch-update))
1135     (isearch-edit-string)
1136     ))
1137
1138 (defun isearch-ring-advance ()
1139   "Advance to the next search string in the ring."
1140   ;; This could be more general to handle a prefix arg, but who would use it.
1141   (interactive)
1142   (isearch-ring-adjust 'advance))
1143
1144 (defun isearch-ring-retreat ()
1145   "Retreat to the previous search string in the ring."
1146   (interactive)
1147   (isearch-ring-adjust nil))
1148
1149 (defun isearch-ring-advance-edit (n)
1150   "Insert the next element of the search history into the minibuffer."
1151   (interactive "p")
1152   (let* ((yank-pointer-name (if isearch-regexp
1153                                 'regexp-search-ring-yank-pointer
1154                               'search-ring-yank-pointer))
1155          (yank-pointer (eval yank-pointer-name))
1156          (ring (if isearch-regexp regexp-search-ring search-ring))
1157          (length (length ring)))
1158     (if (zerop length)
1159         ()
1160       (set yank-pointer-name
1161            (setq yank-pointer
1162                  (mod (- (or yank-pointer 0) n)
1163                       length)))
1164
1165       (erase-buffer)
1166       (insert (nth yank-pointer ring))
1167       (goto-char (point-max)))))
1168
1169 (defun isearch-ring-retreat-edit (n)
1170   "Inserts the previous element of the search history into the minibuffer."
1171   (interactive "p")
1172   (isearch-ring-advance-edit (- n)))
1173
1174 ;;(defun isearch-ring-adjust-edit (advance)
1175 ;;  "Use the next or previous search string in the ring while in minibuffer."
1176 ;;  (isearch-ring-adjust1 advance)
1177 ;;  (erase-buffer)
1178 ;;  (insert isearch-string))
1179
1180 ;;(defun isearch-ring-advance-edit ()
1181 ;;  (interactive)
1182 ;;  (isearch-ring-adjust-edit 'advance))
1183
1184 ;;(defun isearch-ring-retreat-edit ()
1185 ;;  "Retreat to the previous search string in the ring while in the minibuffer."
1186 ;;  (interactive)
1187 ;;  (isearch-ring-adjust-edit nil))
1188
1189
1190 (defun isearch-complete1 ()
1191   ;; Helper for isearch-complete and isearch-complete-edit
1192   ;; Return t if completion OK, nil if no completion exists.
1193   (let* ((ring (if isearch-regexp regexp-search-ring search-ring))
1194          (alist (mapcar (function (lambda (string) (list string))) ring))
1195          (completion-ignore-case case-fold-search)
1196          (completion (try-completion isearch-string alist)))
1197     (cond
1198      ((eq completion t)
1199       ;; isearch-string stays the same
1200       t)
1201      ((or completion ; not nil, must be a string
1202           (= 0 (length isearch-string))) ; shouldnt have to say this
1203       (if (equal completion isearch-string)  ;; no extension?
1204           (if completion-auto-help
1205               (with-output-to-temp-buffer "*Isearch completions*"
1206                 (display-completion-list
1207                  (all-completions isearch-string alist))))
1208         (setq isearch-string completion))
1209       t)
1210      (t
1211       (message "No completion") ; waits a second if in minibuffer
1212       nil))))
1213
1214 (defun isearch-complete ()
1215   "Complete the search string from the strings on the search ring.
1216 The completed string is then editable in the minibuffer.
1217 If there is no completion possible, say so and continue searching."
1218   (interactive)
1219   (if (isearch-complete1)
1220       (isearch-edit-string)
1221     ;; else
1222     (sit-for 1)
1223     (isearch-update)))
1224
1225 (defun isearch-complete-edit ()
1226   "Same as `isearch-complete' except in the minibuffer."
1227   (interactive)
1228   (setq isearch-string (buffer-string))
1229   (if (isearch-complete1)
1230       (progn
1231         (erase-buffer)
1232         (insert isearch-string))))
1233
1234 \f
1235 ;;;==============================================================
1236 ;; The search status stack (and isearch window-local variables, not used).
1237 ;; Need a structure for this.
1238
1239 (defun isearch-top-state ()
1240   (let ((cmd (car isearch-cmds)))
1241     (setq isearch-string (car cmd)
1242           isearch-message (car (cdr cmd))
1243           isearch-success (nth 3 cmd)
1244           isearch-forward (nth 4 cmd)
1245           isearch-other-end (nth 5 cmd)
1246           isearch-word (nth 6 cmd)
1247           isearch-invalid-regexp (nth 7 cmd)
1248           isearch-wrapped (nth 8 cmd)
1249           isearch-barrier (nth 9 cmd)
1250           isearch-within-brackets (nth 10 cmd)
1251           isearch-case-fold-search (nth 11 cmd))
1252     (goto-char (car (cdr (cdr cmd))))))
1253
1254 (defun isearch-pop-state ()
1255   (setq isearch-cmds (cdr isearch-cmds))
1256   (isearch-top-state)
1257   )
1258
1259 (defun isearch-push-state ()
1260   (setq isearch-cmds
1261         (cons (list isearch-string isearch-message (point)
1262                     isearch-success isearch-forward isearch-other-end
1263                     isearch-word
1264                     isearch-invalid-regexp isearch-wrapped isearch-barrier
1265                     isearch-within-brackets isearch-case-fold-search)
1266               isearch-cmds)))
1267
1268 \f
1269 ;;;==================================================================
1270 ;; Message string
1271
1272 (defun isearch-message (&optional c-q-hack ellipsis)
1273   ;; Generate and print the message string.
1274   (let ((cursor-in-echo-area ellipsis)
1275         (m (concat
1276             (isearch-message-prefix c-q-hack ellipsis isearch-nonincremental)
1277             isearch-message
1278             (isearch-message-suffix c-q-hack ellipsis)
1279             )))
1280     (if c-q-hack
1281         m
1282       (let ((message-log-max nil))
1283         (message "%s" m)))))
1284
1285 (defun isearch-message-prefix (&optional c-q-hack ellipsis nonincremental)
1286   ;; If about to search, and previous search regexp was invalid,
1287   ;; check that it still is.  If it is valid now,
1288   ;; let the message we display while searching say that it is valid.
1289   (and isearch-invalid-regexp ellipsis
1290        (condition-case ()
1291            (progn (re-search-forward isearch-string (point) t)
1292                   (setq isearch-invalid-regexp nil
1293                         isearch-within-brackets nil))
1294          (error nil)))
1295   ;; If currently failing, display no ellipsis.
1296   (or isearch-success (setq ellipsis nil))
1297   (let ((m (concat (if isearch-success "" "failing ")
1298                    (if isearch-wrapped "wrapped ")
1299                    (if isearch-word "word " "")
1300                    (if isearch-regexp "regexp " "")
1301                    (if nonincremental "search" "I-search")
1302                    (if isearch-forward ": " " backward: ")
1303                    )))
1304     (aset m 0 (upcase (aref m 0)))
1305     m))
1306
1307
1308 (defun isearch-message-suffix (&optional c-q-hack ellipsis)
1309   (concat (if c-q-hack "^Q" "")
1310           (if isearch-invalid-regexp
1311               (concat " [" isearch-invalid-regexp "]")
1312             "")))
1313
1314 \f
1315 ;;;========================================================
1316 ;;; Searching
1317
1318 (defun isearch-search ()
1319   ;; Do the search with the current search string.
1320   (isearch-message nil t)
1321   (if (and (eq isearch-case-fold-search t) search-upper-case)
1322       (setq isearch-case-fold-search
1323             (isearch-no-upper-case-p isearch-string isearch-regexp)))
1324   (condition-case lossage
1325       (let ((inhibit-quit nil)
1326             (case-fold-search isearch-case-fold-search))
1327         (if isearch-regexp (setq isearch-invalid-regexp nil))
1328         (setq isearch-within-brackets nil)
1329         (setq isearch-success
1330               (funcall
1331                (cond (isearch-word
1332                       (if isearch-forward
1333                           'word-search-forward 'word-search-backward))
1334                      (isearch-regexp
1335                       (if isearch-forward
1336                           're-search-forward 're-search-backward))
1337                      (t
1338                       (if isearch-forward 'search-forward 'search-backward)))
1339                isearch-string nil t))
1340         (if isearch-success
1341             (setq isearch-other-end
1342                   (if isearch-forward (match-beginning 0) (match-end 0)))))
1343
1344     (quit (isearch-unread ?\C-g)
1345           (setq isearch-success nil))
1346
1347     (invalid-regexp
1348      (setq isearch-invalid-regexp (car (cdr lossage)))
1349      (setq isearch-within-brackets (string-match "\\`Unmatched \\["
1350                                                  isearch-invalid-regexp))
1351      (if (string-match
1352           "\\`Premature \\|\\`Unmatched \\|\\`Invalid "
1353           isearch-invalid-regexp)
1354          (setq isearch-invalid-regexp "incomplete input")))
1355     (error
1356      ;; stack overflow in regexp search.
1357      (setq isearch-invalid-regexp (car (cdr lossage)))))
1358
1359   (if isearch-success
1360       nil
1361     ;; Ding if failed this time after succeeding last time.
1362     (and (nth 3 (car isearch-cmds))
1363          (ding))
1364     (goto-char (nth 2 (car isearch-cmds)))))
1365
1366
1367 \f
1368 ;;;========================================================
1369 ;;; Highlighting
1370
1371 (defvar isearch-overlay nil)
1372
1373 (defun isearch-highlight (beg end)
1374   (if (or (null search-highlight) (null window-system))
1375       nil
1376     (or isearch-overlay (setq isearch-overlay (make-overlay beg end)))
1377     (move-overlay isearch-overlay beg end (current-buffer))
1378     (overlay-put isearch-overlay 'face
1379                  (if (internal-find-face 'isearch nil)
1380                      'isearch 'region))))
1381
1382 (defun isearch-dehighlight (totally)
1383   (if isearch-overlay
1384       (delete-overlay isearch-overlay)))
1385
1386 ;;;===========================================================
1387 ;;; General utilities
1388
1389
1390 (defun isearch-no-upper-case-p (string regexp-flag)
1391   "Return t if there are no upper case chars in STRING.
1392 If REGEXP-FLAG is non-nil, disregard letters preceeded by `\\' (but not `\\\\')
1393 since they have special meaning in a regexp."
1394   (let ((case-fold-search nil))
1395     (not (string-match (if regexp-flag "\\(^\\|\\\\\\\\\\|[^\\]\\)[A-Z]"
1396                          "[A-Z]")
1397                        string))))
1398
1399
1400 ;;;=================================================
1401 ;; Portability functions to support various Emacs versions.
1402
1403 ;; To quiet the byte-compiler.
1404 (defvar unread-command-event)
1405 (defvar unread-command-events)
1406 (defvar last-command-event)
1407
1408 (defun isearch-char-to-string (c)
1409   (make-string 1 c))
1410
1411 (defun isearch-text-char-description (c)
1412   (if (and (integerp c) (or (< c ?\ ) (= c ?\^?)))
1413       (text-char-description c)
1414     (isearch-char-to-string c)))
1415
1416 ;; General function to unread characters or events.
1417 (defun isearch-unread (&rest char-or-events)
1418   (setq unread-command-events
1419         (append char-or-events unread-command-events)))
1420
1421 (defun isearch-last-command-char ()
1422   ;; General function to return the last command character.
1423   last-command-char)
1424
1425 ;;; isearch.el ends here