lisp/double.el

   1 ;;; double.el - Support for keyboard remapping with double clicking.
   2
   3 ;; Copyright (C) 1994 Free Software Foundation, Inc.
   4
   5 ;; Author: Per Abrahamsen <abraham@iesd.auc.dk>
   6 ;; Keywords: i18n
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; This mode is intended for use with languages that adds a small
  27 ;; number of extra letters not available on the keyboard.
  28 ;;
  29 ;; Examples includes Scandinavian and German with an US keyboard.
  30 ;;
  31 ;; The idea is that certain keys are overloaded.  When you press it
  32 ;; once it will insert one string, and when you press it twice the
  33 ;; string will be replaced by another.  This can be used for mapping
  34 ;; keys on a US keyboard to generate characters according to the local
  35 ;; keyboard convention when pressed once, and according to US keyboard
  36 ;; convetion when pressed twice.
  37 ;;
  38 ;; To use this mode, you must define the variable `double-map' and
  39 ;; then enable double mode with `M-x double-mode'.  Read the
  40 ;; documentation for both of them.
  41 ;;
  42 ;; The default mapping is for getting Danish/Norwegian keyboard layout
  43 ;; using ISO Latin 1 on a US keyboard.
  44 ;;
  45 ;; Imprtant node: While I would like to hear comments, bug reports,
  46 ;; suggestions, please do @strong{not} expect me to put other mappings
  47 ;; that the default into this file.  There are billions and billions
  48 ;; of such mappings, and just supporting the most common would
  49 ;; increase the size of this nice small file manyfold.
  50
  51 ;;; ChangeLog:
  52
  53 ;; * 1994-06-21         Per Abrahamsen
  54 ;;      Added `double-prefix-only'.
  55 ;; * 1994-02-28         Per Abrahamsen
  56 ;;      Use 127 instead of 'delete to delete a character.
  57 ;; * 1994-02-03         Per Abrahamsen
  58 ;;      Created.
  59
  60 ;;; Code:
  61
  62 (defvar double-map
  63   '((?\; "\346" ";")
  64     (?\' "\370" "'")
  65     (?\[ "\345" "[")
  66     (?\: "\306" ":")
  67     (?\" "\330" "\"")
  68     (?\{ "\305" "{"))
  69   "Alist of key translations activated by double mode.
  70
  71 Each entry is a list with three elements:
  72 1. The key activating the translation.
  73 2. The string to be inserted when the key is pressed once.
  74 3. The string to be inserted when the key is pressed twice.")
  75
  76 (defvar double-prefix-only t
  77   "*Non-nil means that Double mode mapping only works for prefix keys.
  78 That is, for any key `X' in `double-map',  `X' alone will be mapped
  79 but not `C-u X' or `ESC X' since the X is not the prefix key.")
  80
  81 ;;; Read Event
  82
  83 (defvar double-last-event nil)
  84 ;; The last key that generated a double key event.
  85
  86 (defun double-read-event (prompt)
  87   ;; Read an event
  88   (if isearch-mode (isearch-update))
  89   (if prompt
  90       (prog2 (message "%s%c" prompt double-last-event)
  91           (read-event)
  92         (message ""))
  93     (read-event)))
  94
  95 (global-set-key [ignore] '(lambda () (interactive)))
  96
  97 (or (boundp 'isearch-mode-map)
  98     (load-library "isearch"))
  99
 100 (define-key isearch-mode-map [ignore]
 101   (function (lambda () (interactive) (isearch-update))))
 102
 103 (defun double-translate-key (prompt)
 104   ;; Translate input events using double map.
 105   (let ((key last-input-char))
 106     (cond (unread-command-events
 107            ;; Artificial event, ignore it.
 108            (vector key))
 109           ((and double-prefix-only
 110                 (> (length (this-command-keys)) 1))
 111            ;; This is not a prefix key, ignore it.
 112            (vector key))
 113           ((eq key 'magic-start)
 114            ;; End of generated event.  See if he will repeat it...
 115            (let ((new (double-read-event prompt))
 116                  (entry (assoc double-last-event double-map)))
 117              (if (eq new double-last-event)
 118                  (progn
 119                    (setq unread-command-events
 120                          (append (make-list (1- (length (nth 1 entry)))
 121                                             127)
 122                                  (nth 2 entry)
 123                                  '(magic-end)))
 124                    (vector 127))
 125                (setq unread-command-events (list new))
 126                [ignore])))
 127           ((eq key 'magic-end)
 128            ;; End of double event.  Ignore.
 129            [ignore])
 130           (t
 131            ;; New key.
 132            (let ((exp (nth 1 (assoc key double-map))))
 133              (setq double-last-event key)
 134              (setq unread-command-events
 135                    (append (substring exp 1) '(magic-start)))
 136              (vector (aref exp 0)))))))
 137
 138 ;;; Key Translation Map
 139
 140 (defvar default-key-translation-map
 141   (or key-translation-map (make-sparse-keymap))
 142   "Key translation you want to have effect, regardless of Double mode.
 143 This defaults to the value of `key-translation-map' when double was
 144 first loaded.")
 145
 146 (make-variable-buffer-local 'key-translation-map)
 147
 148 (defun double-setup ()
 149   ;; Setup key-translation-map as indicated by `double-map'.
 150   (setq key-translation-map (copy-keymap default-key-translation-map))
 151   (mapcar (function (lambda (entry)
 152             (define-key key-translation-map (vector (nth 0 entry))
 153                         'double-translate-key)))
 154           (append double-map '((magic-start) (magic-end)))))
 155
 156 ;;; Mode
 157
 158 (defvar double-mode nil)
 159 ;; Indicator for the double mode.
 160   (make-variable-buffer-local 'double-mode)
 161
 162 (or (assq 'double-mode minor-mode-alist)
 163     (setq minor-mode-alist
 164           (cons '(double-mode " Double") minor-mode-alist)))
 165
 166 ;; This feature seemed useless and it confused describe-mode,
 167 ;;  so I deleted it.
 168 ;;;(defvar double-mode-name "Double")
 169 ;;;;; Name of current double mode.
 170 ;;; (make-variable-buffer-local 'double-mode-name)
 171
 172 ;;;###autoload
 173 (defun double-mode (arg)
 174   "Toggle Double mode.
 175 With prefix arg, turn Double mode on iff arg is positive.
 176
 177 When Double mode is on, some keys will insert will insert different
 178 strings when pressed twice.  See variable `double-map' for details."
 179   (interactive "P")
 180   (if (or (and (null arg) double-mode)
 181           (<= (prefix-numeric-value arg) 0))
 182       ;; Turn it off
 183       (if double-mode
 184           (progn
 185             (let ((double-map))
 186               (double-setup))
 187             (setq double-mode nil)
 188             (set-buffer-modified-p (buffer-modified-p))))
 189     ;;Turn it on
 190     (if double-mode
 191         ()
 192       (double-setup)
 193       (setq double-mode t)
 194       (set-buffer-modified-p (buffer-modified-p)))))
 195
 196 (provide 'double)
 197
 198 ;;; double.el ends here
 199