lisp/mail/emacsbug.el

   1 ;;; emacsbug.el --- command to report Emacs bugs to appropriate mailing list
   2
   3 ;; Copyright (C) 1985, 1994, 1997-1998, 2000-2012
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: K. Shane Hartman
   7 ;; Maintainer: FSF
   8 ;; Keywords: maint mail
   9 ;; Package: emacs
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; `M-x report-emacs-bug' starts an email note to the Emacs maintainers
  29 ;; describing a problem.  You need to be able to send mail from Emacs
  30 ;; to complete the process.  Alternatively, compose the bug report in
  31 ;; Emacs then paste it into your normal mail client.
  32
  33 ;;; Code:
  34
  35 (require 'sendmail)
  36 (require 'message)
  37
  38 (defgroup emacsbug nil
  39   "Sending Emacs bug reports."
  40   :group 'maint
  41   :group 'mail)
  42
  43 (define-obsolete-variable-alias 'report-emacs-bug-pretest-address
  44   'report-emacs-bug-address "24.1")
  45
  46 (defcustom report-emacs-bug-address "bug-gnu-emacs@gnu.org"
  47   "Address of mailing list for GNU Emacs bugs."
  48   :group 'emacsbug
  49   :type 'string)
  50
  51 (defcustom report-emacs-bug-no-confirmation nil
  52   "If non-nil, suppress the confirmations asked for the sake of novice users."
  53   :group 'emacsbug
  54   :type 'boolean)
  55
  56 (defcustom report-emacs-bug-no-explanations nil
  57   "If non-nil, suppress the explanations given for the sake of novice users."
  58   :group 'emacsbug
  59   :type 'boolean)
  60
  61 ;; User options end here.
  62
  63 (defvar report-emacs-bug-tracker-url "http://debbugs.gnu.org/cgi/"
  64   "Base URL of the GNU bugtracker.
  65 Used for querying duplicates and linking to existing bugs.")
  66
  67 (defvar report-emacs-bug-orig-text nil
  68   "The automatically-created initial text of the bug report.")
  69
  70 (defvar report-emacs-bug-send-command nil
  71   "Name of the command to send the bug report, as a string.")
  72 (make-variable-buffer-local 'report-emacs-bug-send-command)
  73
  74 (defvar report-emacs-bug-send-hook nil
  75   "Hook run before sending the bug report.")
  76 (make-variable-buffer-local 'report-emacs-bug-send-hook)
  77
  78 (declare-function x-server-vendor "xfns.c" (&optional terminal))
  79 (declare-function x-server-version "xfns.c" (&optional terminal))
  80 (declare-function message-sort-headers "message" ())
  81 (defvar message-strip-special-text-properties)
  82
  83 (defun report-emacs-bug-can-use-osx-open ()
  84   "Return non-nil if the OS X \"open\" command is available for mailing."
  85   (and (featurep 'ns)
  86        (equal (executable-find "open") "/usr/bin/open")
  87        (memq system-type '(darwin))))
  88
  89 ;; FIXME this duplicates much of the logic from browse-url-can-use-xdg-open.
  90 (defun report-emacs-bug-can-use-xdg-email ()
  91   "Return non-nil if the \"xdg-email\" command can be used.
  92 xdg-email is a desktop utility that calls your preferred mail client.
  93 This requires you to be running either Gnome, KDE, or Xfce4."
  94   (and (getenv "DISPLAY")
  95        (executable-find "xdg-email")
  96        (or (getenv "GNOME_DESKTOP_SESSION_ID")
  97            ;; GNOME_DESKTOP_SESSION_ID is deprecated, check on Dbus also.
  98            (condition-case nil
  99                (eq 0 (call-process
 100                       "dbus-send" nil nil nil
 101                                   "--dest=org.gnome.SessionManager"
 102                                   "--print-reply"
 103                                   "/org/gnome/SessionManager"
 104                                   "org.gnome.SessionManager.CanShutdown"))
 105              (error nil))
 106            (equal (getenv "KDE_FULL_SESSION") "true")
 107            ;; FIXME? browse-url-can-use-xdg-open also accepts LXDE.
 108            ;; Is that no good here, or just overlooked?
 109            (condition-case nil
 110                (eq 0 (call-process
 111                       "/bin/sh" nil nil nil
 112                       "-c"
 113                       ;; FIXME use string-match rather than grep.
 114                       "xprop -root _DT_SAVE_MODE|grep xfce4"))
 115              (error nil)))))
 116
 117 (defun report-emacs-bug-insert-to-mailer ()
 118   "Send the message to your preferred mail client.
 119 This requires either the OS X \"open\" command, or the freedesktop
 120 \"xdg-email\" command to be available."
 121   (interactive)
 122   (save-excursion
 123     ;; FIXME? use mail-fetch-field?
 124     (let* ((to (progn
 125                  (goto-char (point-min))
 126                  (forward-line)
 127                  (and (looking-at "^To: \\(.*\\)")
 128                       (match-string-no-properties 1))))
 129            (subject (progn
 130                       (forward-line)
 131                       (and (looking-at "^Subject: \\(.*\\)")
 132                            (match-string-no-properties 1))))
 133            (body (progn
 134                    (forward-line 2)
 135                    (if (> (point-max) (point))
 136                        (buffer-substring-no-properties (point) (point-max))))))
 137       (if (and to subject body)
 138           (if (report-emacs-bug-can-use-osx-open)
 139               (start-process "/usr/bin/open" nil "open"
 140                              (concat "mailto:" to
 141                                      "?subject=" (url-hexify-string subject)
 142                                      "&body=" (url-hexify-string body)))
 143             (start-process "xdg-email" nil "xdg-email"
 144                            "--subject" subject
 145                            "--body" body
 146                            (concat "mailto:" to)))
 147         (error "Subject, To or body not found")))))
 148
 149 ;;;###autoload
 150 (defun report-emacs-bug (topic &optional recent-keys)
 151   "Report a bug in GNU Emacs.
 152 Prompts for bug subject.  Leaves you in a mail buffer."
 153   ;; This strange form ensures that (recent-keys) is the value before
 154   ;; the bug subject string is read.
 155   (interactive (reverse (list (recent-keys) (read-string "Bug Subject: "))))
 156   ;; The syntax `version;' is preferred to `[version]' because the
 157   ;; latter could be mistakenly stripped by mailing software.
 158   (if (eq system-type 'ms-dos)
 159       (setq topic (concat emacs-version "; " topic))
 160     (when (string-match "^\\(\\([.0-9]+\\)*\\)\\.[0-9]+$" emacs-version)
 161       (setq topic (concat (match-string 1 emacs-version) "; " topic))))
 162   (let ((from-buffer (current-buffer))
 163         ;; Put these properties on semantically-void text.
 164         ;; report-emacs-bug-hook deletes these regions before sending.
 165         (prompt-properties '(field emacsbug-prompt
 166                              intangible but-helpful
 167                              rear-nonsticky t))
 168         (can-insert-mail (or (report-emacs-bug-can-use-xdg-email)
 169                              (report-emacs-bug-can-use-osx-open)))
 170         user-point message-end-point)
 171     (setq message-end-point
 172           (with-current-buffer (get-buffer-create "*Messages*")
 173             (point-max-marker)))
 174     (compose-mail report-emacs-bug-address topic)
 175     ;; The rest of this does not execute if the user was asked to
 176     ;; confirm and said no.
 177     (when (eq major-mode 'message-mode)
 178       ;; Message-mode sorts the headers before sending.  We sort now so
 179       ;; that report-emacs-bug-orig-text remains valid.  (Bug#5178)
 180       (message-sort-headers)
 181       ;; Stop message-mode stealing the properties we will add.
 182       (set (make-local-variable 'message-strip-special-text-properties) nil))
 183     (rfc822-goto-eoh)
 184     (forward-line 1)
 185     (let ((signature (buffer-substring (point) (point-max))))
 186       (delete-region (point) (point-max))
 187       (insert signature)
 188       (backward-char (length signature)))
 189     (unless report-emacs-bug-no-explanations
 190       ;; Insert warnings for novice users.
 191       (if (not (equal "bug-gnu-emacs@gnu.org" report-emacs-bug-address))
 192           (insert (format "The report will be sent to %s.\n\n"
 193                           report-emacs-bug-address))
 194         (insert "This bug report will be sent to the ")
 195         (insert-button
 196          "Bug-GNU-Emacs"
 197          'face 'link
 198          'help-echo (concat "mouse-2, RET: Follow this link")
 199          'action (lambda (button)
 200                    (browse-url "http://lists.gnu.org/archive/html/bug-gnu-emacs/"))
 201          'follow-link t)
 202         (insert " mailing list\nand the GNU bug tracker at ")
 203         (insert-button
 204          "debbugs.gnu.org"
 205          'face 'link
 206          'help-echo (concat "mouse-2, RET: Follow this link")
 207          'action (lambda (button)
 208                    (browse-url "http://debbugs.gnu.org/"))
 209          'follow-link t)
 210
 211         (insert ".  Please check that
 212 the From: line contains a valid email address.  After a delay of up
 213 to one day, you should receive an acknowledgement at that address.
 214
 215 Please write in English if possible, as the Emacs maintainers
 216 usually do not have translators for other languages.\n\n")))
 217
 218     (insert "Please describe exactly what actions triggered the bug, and\n"
 219             "the precise symptoms of the bug.  If you can, give a recipe\n"
 220             "starting from `emacs -Q':\n\n")
 221     (add-text-properties (save-excursion
 222                            (rfc822-goto-eoh)
 223                            (line-beginning-position 2))
 224                          (point)
 225                          prompt-properties)
 226     (setq user-point (point))
 227     (insert "\n\n")
 228
 229     (insert "If Emacs crashed, and you have the Emacs process in the gdb debugger,\n"
 230             "please include the output from the following gdb commands:\n"
 231             "    `bt full' and `xbacktrace'.\n")
 232
 233     (let ((debug-file (expand-file-name "DEBUG" data-directory)))
 234       (if (file-readable-p debug-file)
 235           (insert "For information about debugging Emacs, please read the file\n"
 236                   debug-file ".\n")))
 237     (add-text-properties (1+ user-point) (point) prompt-properties)
 238
 239     (insert "\n\nIn " (emacs-version) "\n")
 240     (if (fboundp 'x-server-vendor)
 241         (condition-case nil
 242             ;; This is used not only for X11 but also W32 and others.
 243             (insert "Windowing system distributor `" (x-server-vendor)
 244                     "', version "
 245                     (mapconcat 'number-to-string (x-server-version) ".") "\n")
 246           (error t)))
 247     (when (and system-configuration-options
 248                (not (equal system-configuration-options "")))
 249       (insert "Configured using:\n `configure "
 250               system-configuration-options "'\n\n")
 251       (fill-region (line-beginning-position -1) (point)))
 252     (insert "Important settings:\n")
 253     (mapc
 254      (lambda (var)
 255        (insert (format "  value of $%s: %s\n" var (getenv var))))
 256      '("LC_ALL" "LC_COLLATE" "LC_CTYPE" "LC_MESSAGES"
 257        "LC_MONETARY" "LC_NUMERIC" "LC_TIME" "LANG" "XMODIFIERS"))
 258     (insert (format "  locale-coding-system: %s\n" locale-coding-system))
 259     (insert (format "  default enable-multibyte-characters: %s\n"
 260                     (default-value 'enable-multibyte-characters)))
 261     (insert "\n")
 262     (insert (format "Major mode: %s\n"
 263                     (format-mode-line
 264                      (buffer-local-value 'mode-name from-buffer)
 265                      nil nil from-buffer)))
 266     (insert "\n")
 267     (insert "Minor modes in effect:\n")
 268     (dolist (mode minor-mode-list)
 269       (and (boundp mode) (buffer-local-value mode from-buffer)
 270            (insert (format "  %s: %s\n" mode
 271                            (buffer-local-value mode from-buffer)))))
 272     (insert "\n")
 273     (insert "Recent input:\n")
 274     (let ((before-keys (point)))
 275       (insert (mapconcat (lambda (key)
 276                            (if (or (integerp key)
 277                                    (symbolp key)
 278                                    (listp key))
 279                                (single-key-description key)
 280                              (prin1-to-string key nil)))
 281                          (or recent-keys (recent-keys))
 282                          " "))
 283       (save-restriction
 284         (narrow-to-region before-keys (point))
 285         (goto-char before-keys)
 286         (while (progn (move-to-column 50) (not (eobp)))
 287           (search-forward " " nil t)
 288           (insert "\n"))))
 289     (let ((message-buf (get-buffer "*Messages*")))
 290       (if message-buf
 291           (let (beg-pos
 292                 (end-pos message-end-point))
 293             (with-current-buffer message-buf
 294               (goto-char end-pos)
 295               (forward-line -10)
 296               (setq beg-pos (point)))
 297             (insert "\n\nRecent messages:\n")
 298             (insert-buffer-substring message-buf beg-pos end-pos))))
 299     ;; After Recent messages, to avoid the messages produced by
 300     ;; list-load-path-shadows.
 301     (unless (looking-back "\n")
 302       (insert "\n"))
 303     (insert "\n")
 304     (insert "Load-path shadows:\n")
 305     (message "Checking for load-path shadows...")
 306     (let ((shadows (list-load-path-shadows t)))
 307       (message "Checking for load-path shadows...done")
 308       (insert (if (zerop (length shadows))
 309                   "None found.\n"
 310                 shadows)))
 311     (insert (format "\nFeatures:\n%s\n" features))
 312     (fill-region (line-beginning-position 0) (point))
 313     ;; This is so the user has to type something in order to send easily.
 314     (use-local-map (nconc (make-sparse-keymap) (current-local-map)))
 315     (define-key (current-local-map) "\C-c\C-i" 'report-emacs-bug-info)
 316     (if can-insert-mail
 317         (define-key (current-local-map) "\C-cm"
 318           'report-emacs-bug-insert-to-mailer))
 319     (setq report-emacs-bug-send-command (get mail-user-agent 'sendfunc)
 320           report-emacs-bug-send-hook (get mail-user-agent 'hookvar))
 321     (if report-emacs-bug-send-command
 322         (setq report-emacs-bug-send-command
 323               (symbol-name report-emacs-bug-send-command)))
 324     (unless report-emacs-bug-no-explanations
 325       (with-output-to-temp-buffer "*Bug Help*"
 326         (princ "While in the mail buffer:\n\n")
 327         (if report-emacs-bug-send-command
 328             (princ (substitute-command-keys
 329                     (format "  Type \\[%s] to send the bug report.\n"
 330                             report-emacs-bug-send-command))))
 331         (princ (substitute-command-keys
 332                 "  Type \\[kill-buffer] RET to cancel (don't send it).\n"))
 333         (if can-insert-mail
 334             (princ (substitute-command-keys
 335                     "  Type \\[report-emacs-bug-insert-to-mailer] to copy text to your preferred mail program.\n")))
 336         (terpri)
 337         (princ (substitute-command-keys
 338                 "  Type \\[report-emacs-bug-info] to visit in Info the Emacs Manual section
 339     about when and how to write a bug report, and what
 340     information you should include to help fix the bug.")))
 341       (shrink-window-if-larger-than-buffer (get-buffer-window "*Bug Help*")))
 342     ;; Make it less likely people will send empty messages.
 343     (if report-emacs-bug-send-hook
 344         (add-hook report-emacs-bug-send-hook 'report-emacs-bug-hook nil t))
 345     (goto-char (point-max))
 346     (skip-chars-backward " \t\n")
 347     (make-local-variable 'report-emacs-bug-orig-text)
 348     (setq report-emacs-bug-orig-text
 349           (buffer-substring-no-properties (point-min) (point)))
 350     (goto-char user-point)))
 351
 352 (defun report-emacs-bug-info ()
 353   "Go to the Info node on reporting Emacs bugs."
 354   (interactive)
 355   (info "(emacs)Bugs"))
 356
 357 ;; It's the default mail mode, so it seems OK to use its features.
 358 (autoload 'message-bogus-recipient-p "message")
 359 (defvar message-send-mail-function)
 360
 361 (defun report-emacs-bug-hook ()
 362   "Do some checking before sending a bug report."
 363   (save-excursion
 364     (goto-char (point-max))
 365     (skip-chars-backward " \t\n")
 366     (and (= (- (point) (point-min))
 367             (length report-emacs-bug-orig-text))
 368          (string-equal (buffer-substring-no-properties (point-min) (point))
 369                        report-emacs-bug-orig-text)
 370          (error "No text entered in bug report"))
 371     ;; Warning for novice users.
 372     (unless (or report-emacs-bug-no-confirmation
 373                 (yes-or-no-p
 374                  "Send this bug report to the Emacs maintainers? "))
 375       (goto-char (point-min))
 376       (if (search-forward "To: ")
 377           (delete-region (point) (line-end-position)))
 378       (if report-emacs-bug-send-hook
 379           (kill-local-variable report-emacs-bug-send-hook))
 380       (with-output-to-temp-buffer "*Bug Help*"
 381         (princ (substitute-command-keys
 382                 (format "\
 383 You invoked the command M-x report-emacs-bug,
 384 but you decided not to mail the bug report to the Emacs maintainers.
 385
 386 If you want to mail it to someone else instead,
 387 please insert the proper e-mail address after \"To: \",
 388 and send the mail again%s."
 389                         (if report-emacs-bug-send-command
 390                             (format " using \\[%s]"
 391                                     report-emacs-bug-send-command)
 392                           "")))))
 393       (error "M-x report-emacs-bug was cancelled, please read *Bug Help* buffer"))
 394     ;; Query the user for the SMTP method, so that we can skip
 395     ;; questions about From header validity if the user is going to
 396     ;; use mailclient, anyway.
 397     (when (or (and (derived-mode-p 'message-mode)
 398                    (eq message-send-mail-function 'sendmail-query-once))
 399               (and (not (derived-mode-p 'message-mode))
 400                    (eq send-mail-function 'sendmail-query-once)))
 401       (sendmail-query-user-about-smtp)
 402       (when (derived-mode-p 'message-mode)
 403         (setq message-send-mail-function (message-default-send-mail-function))))
 404     (or report-emacs-bug-no-confirmation
 405         ;; mailclient.el does not need a valid From
 406         (if (derived-mode-p 'message-mode)
 407             (eq message-send-mail-function 'message-send-mail-with-mailclient)
 408           (eq send-mail-function 'mailclient-send-it))
 409         ;; Not narrowing to the headers, but that's OK.
 410         (let ((from (mail-fetch-field "From")))
 411           (and (or (not from)
 412                    (message-bogus-recipient-p from)
 413                    ;; This is the default user-mail-address.  On today's
 414                    ;; systems, it seems more likely to be wrong than right,
 415                    ;; since most people don't run their own mail server.
 416                    (string-match (format "\\<%s@%s\\>"
 417                                          (regexp-quote (user-login-name))
 418                                          (regexp-quote (system-name)))
 419                                  from))
 420                (not (yes-or-no-p
 421                      (format "Is `%s' really your email address? " from)))
 422                (error "Please edit the From address and try again"))))
 423     ;; Delete the uninteresting text that was just to help fill out the report.
 424     (rfc822-goto-eoh)
 425     (forward-line 1)
 426     (let ((pos (1- (point))))
 427       (while (setq pos (text-property-any pos (point-max)
 428                                           'field 'emacsbug-prompt))
 429         (delete-region pos (field-end (1+ pos)))))))
 430
 431
 432 ;; Querying the bug database
 433
 434 (defvar report-emacs-bug-bug-alist nil)
 435 (make-variable-buffer-local 'report-emacs-bug-bug-alist)
 436 (defvar report-emacs-bug-choice-widget nil)
 437 (make-variable-buffer-local 'report-emacs-bug-choice-widget)
 438
 439 (defun report-emacs-bug-create-existing-bugs-buffer (bugs keywords)
 440   (switch-to-buffer (get-buffer-create "*Existing Emacs Bugs*"))
 441   (setq buffer-read-only t)
 442   (let ((inhibit-read-only t))
 443     (erase-buffer)
 444     (setq report-emacs-bug-bug-alist bugs)
 445     (widget-insert (propertize (concat "Already known bugs ("
 446                                        keywords "):\n\n")
 447                                'face 'bold))
 448     (if bugs
 449         (setq report-emacs-bug-choice-widget
 450               (apply 'widget-create 'radio-button-choice
 451                      :value (caar bugs)
 452                      (let (items)
 453                        (dolist (bug bugs)
 454                          (push (list
 455                                 'url-link
 456                                 :format (concat "Bug#" (number-to-string (nth 2 bug))
 457                                                 ": " (cadr bug) "\n    %[%v%]\n")
 458                                 ;; FIXME: Why is only the link of the
 459                                 ;; active item clickable?
 460                                 (car bug))
 461                                items))
 462                        (nreverse items))))
 463       (widget-insert "No bugs matching your keywords found.\n"))
 464     (widget-insert "\n")
 465     (widget-create 'push-button
 466                    :notify (lambda (&rest ignore)
 467                              ;; TODO: Do something!
 468                              (message "Reporting new bug!"))
 469                    "Report new bug")
 470     (when bugs
 471       (widget-insert " ")
 472       (widget-create 'push-button
 473                      :notify (lambda (&rest ignore)
 474                                (let ((val (widget-value report-emacs-bug-choice-widget)))
 475                                  ;; TODO: Do something!
 476                                  (message "Appending to bug %s!"
 477                                           (nth 2 (assoc val report-emacs-bug-bug-alist)))))
 478                      "Append to chosen bug"))
 479     (widget-insert " ")
 480     (widget-create 'push-button
 481                    :notify (lambda (&rest ignore)
 482                              (kill-buffer))
 483                    "Quit reporting bug")
 484     (widget-insert "\n"))
 485   (use-local-map widget-keymap)
 486   (widget-setup)
 487   (goto-char (point-min)))
 488
 489 (defun report-emacs-bug-parse-query-results (status keywords)
 490   (goto-char (point-min))
 491   (let (buglist)
 492     (while (re-search-forward "<a href=\"bugreport\\.cgi\\?bug=\\([[:digit:]]+\\)\">\\([^<]+\\)</a>" nil t)
 493       (let ((number (match-string 1))
 494             (subject (match-string 2)))
 495         (when (not (string-match "^#" subject))
 496           (push (list
 497                  ;; first the bug URL
 498                  (concat report-emacs-bug-tracker-url
 499                          "bugreport.cgi?bug=" number)
 500                  ;; then the subject and number
 501                  subject (string-to-number number))
 502                 buglist))))
 503     (report-emacs-bug-create-existing-bugs-buffer (nreverse buglist) keywords)))
 504
 505 ;;;###autoload
 506 (defun report-emacs-bug-query-existing-bugs (keywords)
 507   "Query for KEYWORDS at `report-emacs-bug-tracker-url', and return the result.
 508 The result is an alist with items of the form (URL SUBJECT NO)."
 509   (interactive "sBug keywords (comma separated): ")
 510   (url-retrieve (concat report-emacs-bug-tracker-url
 511                         "pkgreport.cgi?include=subject%3A"
 512                         (replace-regexp-in-string "[[:space:]]+" "+" keywords)
 513                         ";package=emacs")
 514                 'report-emacs-bug-parse-query-results (list keywords)))
 515
 516 (provide 'emacsbug)
 517
 518 ;;; emacsbug.el ends here