lisp/dired-x.el

   1 ;;; dired-x.el --- extra Dired functionality -*-byte-compile-dynamic: t;-*-
   2
   3 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   4 ;;      Lawrence R. Dodd <dodd@roebling.poly.edu>
   5 ;; Maintainer: Romain Francoise <rfrancoise@gnu.org>
   6 ;; Version: 2.37+
   7 ;; Date: 1994/08/18 19:27:42
   8 ;; Keywords: dired extensions files
   9
  10 ;; Copyright (C) 1993, 1994, 1997, 2001, 2002, 2003, 2004,
  11 ;;   2005, 2006, 2007 Free Software Foundation, Inc.
  12
  13 ;; This file is part of GNU Emacs.
  14
  15 ;; GNU Emacs is free software; you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation; either version 2, or (at your option)
  18 ;; any later version.
  19
  20 ;; GNU Emacs is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  27 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  28 ;; Boston, MA 02110-1301, USA.
  29
  30 ;;; Commentary:
  31
  32 ;; This is Sebastian Kremer's excellent dired-x.el (Dired Extra), version
  33 ;; 1.191, hacked up for GNU Emacs.  Redundant or conflicting material has
  34 ;; been removed or renamed in order to work properly with dired of GNU
  35 ;; Emacs.  All suggestions or comments are most welcomed.
  36
  37 ;;
  38 ;; Please, PLEASE, *PLEASE* see the info pages.
  39 ;;
  40
  41 ;; BUGS: Type M-x dired-x-submit-report and a report will be generated.
  42
  43 ;; INSTALLATION: In your ~/.emacs,
  44 ;;
  45 ;; (add-hook 'dired-load-hook
  46 ;;           (function (lambda ()
  47 ;;                       (load "dired-x")
  48 ;;                       ;; Set variables here.  For example:
  49 ;;                       ;; (setq dired-guess-shell-gnutar "gtar")
  50 ;;                       ;; (dired-omit-mode 1)
  51 ;;                       )))
  52 ;;
  53 ;; At load time dired-x.el will install itself, redefine some functions, and
  54 ;; bind some dired keys.  *Please* see the info pages for more details.
  55
  56 ;; *Please* see the info pages for more details.
  57
  58 ;; User defined variables:
  59 ;;
  60 ;;      dired-bind-vm
  61 ;;      dired-vm-read-only-folders
  62 ;;      dired-bind-jump
  63 ;;      dired-bind-info
  64 ;;      dired-bind-man
  65 ;;      dired-x-hands-off-my-keys
  66 ;;      dired-find-subdir
  67 ;;      dired-enable-local-variables
  68 ;;      dired-local-variables-file
  69 ;;      dired-guess-shell-gnutar
  70 ;;      dired-guess-shell-gzip-quiet
  71 ;;      dired-guess-shell-znew-switches
  72 ;;      dired-guess-shell-alist-user
  73 ;;      dired-clean-up-buffers-too
  74 ;;      dired-omit-mode
  75 ;;      dired-omit-files
  76 ;;      dired-omit-extensions
  77 ;;      dired-omit-size-limit
  78 ;;
  79 ;; To find out more about these variables, load this file, put your cursor at
  80 ;; the end of any of the variable names, and hit C-h v [RET].  *Please* see
  81 ;; the info pages for more details.
  82
  83 ;; When loaded this code redefines the following functions of GNU Emacs
  84 ;;
  85 ;;   Function                         Found in this file of GNU Emacs
  86 ;;   --------                         -------------------------------
  87 ;;   dired-clean-up-after-deletion    ../lisp/dired.el
  88 ;;   dired-find-buffer-nocreate       ../lisp/dired.el
  89 ;;   dired-initial-position           ../lisp/dired.el
  90 ;;
  91 ;;   dired-add-entry                  ../lisp/dired-aux.el
  92 ;;   dired-read-shell-command         ../lisp/dired-aux.el
  93
  94 \f
  95 ;;; Code:
  96
  97 ;; LOAD.
  98
  99 ;; This is a no-op if dired-x is being loaded via `dired-load-hook'.  It is
 100 ;; here in case the user has autoloaded dired-x via the dired-jump key binding
 101 ;; (instead of autoloading to dired as is suggested in the info-pages).
 102
 103 (require 'dired)
 104
 105 ;; We will redefine some functions and also need some macros so we need to
 106 ;; load dired stuff of GNU Emacs.
 107
 108 (require 'dired-aux)
 109
 110 (defvar vm-folder-directory)
 111 (eval-when-compile (require 'man))
 112
 113 ;;; User-defined variables.
 114
 115 (defgroup dired-x nil
 116   "Extended directory editing (dired-x)."
 117   :group 'dired)
 118
 119 (defgroup dired-keys nil
 120   "Dired keys customizations."
 121   :prefix "dired-"
 122   :group 'dired-x)
 123
 124 (defcustom dired-bind-vm nil
 125   "*Non-nil means \"V\" runs `dired-vm', otherwise \"V\" runs `dired-rmail'.
 126 Also, RMAIL files contain -*- rmail -*- at the top so \"f\",
 127 `dired-advertised-find-file', will run rmail."
 128   :type 'boolean
 129   :group 'dired-keys)
 130
 131 (defcustom dired-bind-jump t
 132   "*Non-nil means bind `dired-jump' to C-x C-j, otherwise do not."
 133   :type 'boolean
 134   :group 'dired-keys)
 135
 136 (defcustom dired-bind-man t
 137   "*Non-nil means bind `dired-man' to \"N\" in dired-mode, otherwise do not."
 138   :type 'boolean
 139   :group 'dired-keys)
 140
 141 (defcustom dired-bind-info t
 142   "*Non-nil means bind `dired-info' to \"I\" in dired-mode, otherwise do not."
 143   :type 'boolean
 144   :group 'dired-keys)
 145
 146 (defcustom dired-vm-read-only-folders nil
 147   "*If non-nil, \\[dired-vm] will visit all folders read-only.
 148 If neither nil nor t, e.g. the symbol `if-file-read-only', only
 149 files not writable by you are visited read-only.
 150
 151 Read-only folders only work in VM 5, not in VM 4."
 152   :type '(choice (const :tag "off" nil)
 153                  (const :tag "on" t)
 154                  (other :tag "non-writable only" if-file-read-only))
 155   :group 'dired-x)
 156
 157 (define-minor-mode dired-omit-mode
 158   "Toggle Dired-Omit mode.
 159 With numeric ARG, enable Dired-Omit mode if ARG is positive, disable
 160 otherwise.  Enabling and disabling is buffer-local.
 161 If enabled, \"uninteresting\" files are not listed.
 162 Uninteresting files are those whose filenames match regexp `dired-omit-files',
 163 plus those ending with extensions in `dired-omit-extensions'."
 164   :group 'dired-x
 165   (if dired-omit-mode
 166       ;; This will mention how many lines were omitted:
 167       (let ((dired-omit-size-limit nil)) (dired-omit-expunge))
 168     (revert-buffer)))
 169
 170 ;; For backward compatibility
 171 (defvaralias 'dired-omit-files-p 'dired-omit-mode)
 172 (make-obsolete-variable 'dired-omit-files-p 'dired-omit-mode)
 173
 174 (defcustom dired-omit-files "^\\.?#\\|^\\.$\\|^\\.\\.$"
 175   "*Filenames matching this regexp will not be displayed.
 176 This only has effect when `dired-omit-mode' is t.  See interactive function
 177 `dired-omit-mode' \(\\[dired-omit-mode]\) and variable
 178 `dired-omit-extensions'.  The default is to omit  `.', `..', auto-save
 179 files and lock files."
 180   :type 'regexp
 181   :group 'dired-x)
 182
 183 (defcustom dired-find-subdir nil           ; t is pretty near to DWIM...
 184   "*If non-nil, Dired always finds a directory in a buffer of its own.
 185 If nil, Dired finds the directory as a subdirectory in some other buffer
 186 if it is present as one.
 187
 188 If there are several dired buffers for a directory, the most recently
 189 used is chosen.
 190
 191 Dired avoids switching to the current buffer, so that if you have
 192 a normal and a wildcard buffer for the same directory, \\[dired] will
 193 toggle between those two."
 194   :type 'boolean
 195   :group 'dired-x)
 196
 197 (defcustom dired-omit-size-limit 30000
 198   "*Maximum size for the \"omitting\" feature.
 199 If nil, there is no maximum size."
 200   :type '(choice (const :tag "no maximum" nil) integer)
 201   :group 'dired-x)
 202
 203 (defcustom dired-enable-local-variables t
 204   "*Control use of local-variables lists in Dired.
 205 The value can be t, nil or something else.
 206 A value of t means local-variables lists are obeyed;
 207 nil means they are ignored; anything else means query.
 208
 209 This temporarily overrides the value of `enable-local-variables' when listing
 210 a directory.  See also `dired-local-variables-file'."
 211   :type 'boolean
 212   :group 'dired-x)
 213
 214 (defcustom dired-guess-shell-gnutar (when (or (eq system-type 'gnu)
 215                                               (eq system-type 'gnu/linux))
 216                                       "tar")
 217   "*If non-nil, name of GNU tar executable.
 218 \(E.g., \"tar\" or \"gtar\").  The `z' switch will be used with it for
 219 compressed or gzip'ed tar files.  If you don't have GNU tar, set this
 220 to nil: a pipe using `zcat' or `gunzip -c' will be used."
 221   :type '(choice (const :tag "Not GNU tar" nil)
 222                  (string :tag "Command name"))
 223   :group 'dired-x)
 224
 225 (defcustom dired-guess-shell-gzip-quiet t
 226   "*Non-nil says pass -q to gzip overriding verbose GZIP environment."
 227   :type 'boolean
 228   :group 'dired-x)
 229
 230 (defcustom dired-guess-shell-znew-switches nil
 231   "*If non-nil, then string of switches passed to `znew', example: \"-K\"."
 232   :type '(choice (const :tag "None" nil)
 233                  (string :tag "Switches"))
 234   :group 'dired-x)
 235
 236 (defcustom dired-clean-up-buffers-too t
 237   "*Non-nil means offer to kill buffers visiting files and dirs deleted in Dired."
 238   :type 'boolean
 239   :group 'dired-x)
 240
 241 ;;; KEY BINDINGS.
 242
 243 (define-key dired-mode-map "\M-o" 'dired-omit-mode)
 244 (define-key dired-mode-map "*O" 'dired-mark-omitted)
 245 (define-key dired-mode-map "\M-(" 'dired-mark-sexp)
 246 (define-key dired-mode-map "*(" 'dired-mark-sexp)
 247 (define-key dired-mode-map "*." 'dired-mark-extension)
 248 (define-key dired-mode-map "\M-!" 'dired-smart-shell-command)
 249 (define-key dired-mode-map "w" 'dired-copy-filename-as-kill)
 250 (define-key dired-mode-map "\M-G" 'dired-goto-subdir)
 251 (define-key dired-mode-map "F" 'dired-do-find-marked-files)
 252 (define-key dired-mode-map "Y"  'dired-do-relsymlink)
 253 (define-key dired-mode-map "%Y" 'dired-do-relsymlink-regexp)
 254 (define-key dired-mode-map "V" 'dired-do-run-mail)
 255
 256 (if dired-bind-man
 257     (define-key dired-mode-map "N" 'dired-man))
 258
 259 (if dired-bind-info
 260     (define-key dired-mode-map "I" 'dired-info))
 261
 262 ;;; MENU BINDINGS
 263
 264 (let ((menu-bar (lookup-key dired-mode-map [menu-bar])))
 265   (let ((menu (lookup-key menu-bar [operate])))
 266     (define-key-after
 267       menu
 268       [find-files]
 269       '(menu-item
 270         "Find files"
 271         dired-do-find-marked-files
 272         :help "Find current or marked files")
 273       'delete)
 274     (define-key-after
 275       menu
 276       [relsymlink]
 277       '(menu-item
 278         "Relative symlink to..."
 279         dired-do-relsymlink
 280         :visible (fboundp 'make-symbolic-link)
 281         :help "Make relative symbolic links for current or marked files")
 282       'symlink))
 283   (let ((menu (lookup-key menu-bar [mark])))
 284     (define-key-after
 285       menu
 286       [flag-extension]
 287       '(menu-item
 288         "Flag extension..."
 289         dired-flag-extension
 290         :help "Flag files with a certain extension for deletion")
 291       'garbage-files)
 292     (define-key-after
 293       menu
 294       [mark-extension]
 295       '(menu-item
 296         "Mark extension..."
 297         dired-mark-extension
 298         :help "Mark files with a certain extension")
 299       'symlinks)
 300     (define-key-after
 301       menu
 302       [mark-omitted]
 303       '(menu-item
 304         "Mark omitted"
 305         dired-mark-omitted
 306         :help "Mark files matching `dired-omit-files' and `dired-omit-extensions'")
 307       'mark-extension))
 308   (let ((menu (lookup-key menu-bar [regexp])))
 309     (define-key-after
 310       menu
 311       [relsymlink-regexp]
 312       '(menu-item
 313         "Relative symlink..."
 314         dired-do-relsymlink-regexp
 315         :visible (fboundp 'make-symbolic-link)
 316         :help "Make relative symbolic links for files matching regexp")
 317       'symlink))
 318   (let ((menu (lookup-key menu-bar [immediate])))
 319     (define-key-after
 320       menu
 321       [omit-mode]
 322       '(menu-item
 323         "Omit mode" dired-omit-mode
 324         :button (:toggle . dired-omit-mode)
 325         :help "Enable or disable omitting \"uninteresting\" files")
 326       'dashes)))
 327
 328 ;;; GLOBAL BINDING.
 329 (if dired-bind-jump
 330     (progn
 331       (define-key global-map "\C-x\C-j" 'dired-jump)
 332       (define-key global-map "\C-x4\C-j" 'dired-jump-other-window)))
 333
 334 \f
 335 ;;; Install into appropriate hooks.
 336
 337 (add-hook 'dired-mode-hook 'dired-extra-startup)
 338 (add-hook 'dired-after-readin-hook 'dired-omit-expunge)
 339
 340 (defun dired-extra-startup ()
 341   "Automatically put on `dired-mode-hook' to get extra Dired features:
 342 \\<dired-mode-map>
 343   \\[dired-do-run-mail]\t-- run mail on folder (see `dired-bind-vm')
 344   \\[dired-info]\t-- run info on file
 345   \\[dired-man]\t-- run man on file
 346   \\[dired-do-find-marked-files]\t-- visit all marked files simultaneously
 347   \\[dired-omit-mode]\t-- toggle omitting of files
 348   \\[dired-mark-sexp]\t-- mark by Lisp expression
 349   \\[dired-copy-filename-as-kill]\t-- copy the file or subdir names into the kill ring;
 350   \t   you can feed it to other commands using \\[yank]
 351
 352 For more features, see variables
 353
 354   `dired-bind-vm'
 355   `dired-bind-jump'
 356   `dired-bind-info'
 357   `dired-bind-man'
 358   `dired-vm-read-only-folders'
 359   `dired-omit-mode'
 360   `dired-omit-files'
 361   `dired-omit-extensions'
 362   `dired-omit-size-limit'
 363   `dired-find-subdir'
 364   `dired-enable-local-variables'
 365   `dired-local-variables-file'
 366   `dired-guess-shell-gnutar'
 367   `dired-guess-shell-gzip-quiet'
 368   `dired-guess-shell-znew-switches'
 369   `dired-guess-shell-alist-user'
 370   `dired-clean-up-buffers-too'
 371
 372 See also functions
 373
 374   `dired-flag-extension'
 375   `dired-virtual'
 376   `dired-jump'
 377   `dired-man'
 378   `dired-vm'
 379   `dired-rmail'
 380   `dired-info'
 381   `dired-do-find-marked-files'"
 382   (interactive)
 383
 384   ;; These must be done in each new dired buffer.
 385   (dired-hack-local-variables)
 386   (dired-omit-startup))
 387
 388 \f
 389 ;;; BUFFER CLEANING.
 390
 391 ;; REDEFINE.
 392 (defun dired-clean-up-after-deletion (fn)
 393   "Clean up after a deleted file or directory FN.
 394 Remove expanded subdir of deleted dir, if any."
 395   (save-excursion (and (cdr dired-subdir-alist)
 396                        (dired-goto-subdir fn)
 397                        (dired-kill-subdir)))
 398
 399   ;; Offer to kill buffer of deleted file FN.
 400   (if dired-clean-up-buffers-too
 401       (progn
 402         (let ((buf (get-file-buffer fn)))
 403           (and buf
 404                (funcall (function y-or-n-p)
 405                         (format "Kill buffer of %s, too? "
 406                                 (file-name-nondirectory fn)))
 407                (save-excursion ; you never know where kill-buffer leaves you
 408                  (kill-buffer buf))))
 409         (let ((buf-list (dired-buffers-for-dir (expand-file-name fn)))
 410               (buf nil))
 411           (and buf-list
 412                (y-or-n-p (format "Kill dired buffer%s of %s, too? "
 413                                  (dired-plural-s (length buf-list))
 414                                  (file-name-nondirectory fn)))
 415                (while buf-list
 416                  (save-excursion (kill-buffer (car buf-list)))
 417                  (setq buf-list (cdr buf-list)))))))
 418   ;; Anything else?
 419   )
 420
 421 \f
 422 ;;; EXTENSION MARKING FUNCTIONS.
 423
 424 ;;; Mark files with some extension.
 425 (defun dired-mark-extension (extension &optional marker-char)
 426   "Mark all files with a certain EXTENSION for use in later commands.
 427 A `.' is *not* automatically prepended to the string entered."
 428   ;; EXTENSION may also be a list of extensions instead of a single one.
 429   ;; Optional MARKER-CHAR is marker to use.
 430   (interactive "sMarking extension: \nP")
 431   (or (listp extension)
 432       (setq extension (list extension)))
 433   (dired-mark-files-regexp
 434    (concat ".";; don't match names with nothing but an extension
 435            "\\("
 436            (mapconcat 'regexp-quote extension "\\|")
 437            "\\)$")
 438    marker-char))
 439
 440 (defun dired-flag-extension (extension)
 441   "In dired, flag all files with a certain EXTENSION for deletion.
 442 A `.' is *not* automatically prepended to the string entered."
 443   (interactive "sFlagging extension: ")
 444   (dired-mark-extension extension dired-del-marker))
 445
 446 ;;; Define some unpopular file extensions.  Used for cleaning and omitting.
 447
 448 (defvar dired-patch-unclean-extensions
 449   '(".rej" ".orig")
 450   "List of extensions of dispensable files created by the `patch' program.")
 451
 452 (defvar dired-tex-unclean-extensions
 453   '(".toc" ".log" ".aux");; these are already in completion-ignored-extensions
 454   "List of extensions of dispensable files created by TeX.")
 455
 456 (defvar dired-latex-unclean-extensions
 457   '(".idx" ".lof" ".lot" ".glo")
 458   "List of extensions of dispensable files created by LaTeX.")
 459
 460 (defvar dired-bibtex-unclean-extensions
 461   '(".blg" ".bbl")
 462   "List of extensions of dispensable files created by BibTeX.")
 463
 464 (defvar dired-texinfo-unclean-extensions
 465   '(".cp" ".cps" ".fn" ".fns" ".ky" ".kys" ".pg" ".pgs"
 466     ".tp" ".tps" ".vr" ".vrs")
 467   "List of extensions of dispensable files created by texinfo.")
 468
 469 (defun dired-clean-patch ()
 470   "Flag dispensable files created by patch for deletion.
 471 See variable `dired-patch-unclean-extensions'."
 472   (interactive)
 473   (dired-flag-extension dired-patch-unclean-extensions))
 474
 475 (defun dired-clean-tex ()
 476   "Flag dispensable files created by [La]TeX etc. for deletion.
 477 See variables `dired-tex-unclean-extensions',
 478 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 479 `dired-texinfo-unclean-extensions'."
 480   (interactive)
 481   (dired-flag-extension (append dired-texinfo-unclean-extensions
 482                                 dired-latex-unclean-extensions
 483                                 dired-bibtex-unclean-extensions
 484                                 dired-tex-unclean-extensions)))
 485
 486 (defun dired-very-clean-tex ()
 487   "Flag dispensable files created by [La]TeX *and* \".dvi\" for deletion.
 488 See variables `dired-texinfo-unclean-extensions',
 489 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 490 `dired-texinfo-unclean-extensions'."
 491   (interactive)
 492   (dired-flag-extension (append dired-texinfo-unclean-extensions
 493                                 dired-latex-unclean-extensions
 494                                 dired-bibtex-unclean-extensions
 495                                 dired-tex-unclean-extensions
 496                                 (list ".dvi"))))
 497 \f
 498 ;;; JUMP.
 499
 500 ;;;###autoload
 501 (defun dired-jump (&optional other-window)
 502   "Jump to dired buffer corresponding to current buffer.
 503 If in a file, dired the current directory and move to file's line.
 504 If in Dired already, pop up a level and goto old directory's line.
 505 In case the proper dired file line cannot be found, refresh the dired
 506 buffer and try again."
 507   (interactive "P")
 508   (let* ((file buffer-file-name)
 509          (dir (if file (file-name-directory file) default-directory)))
 510     (if (eq major-mode 'dired-mode)
 511         (progn
 512           (setq dir (dired-current-directory))
 513           (dired-up-directory other-window)
 514           (or (dired-goto-file dir)
 515               ;; refresh and try again
 516               (progn
 517                 (dired-insert-subdir (file-name-directory dir))
 518                 (dired-goto-file dir))))
 519       (if other-window
 520           (dired-other-window dir)
 521         (dired dir))
 522       (if file
 523           (or (dired-goto-file file)
 524               ;; refresh and try again
 525               (progn
 526                 (dired-insert-subdir (file-name-directory file))
 527                 (dired-goto-file file))
 528               ;; Toggle omitting, if it is on, and try again.
 529               (if dired-omit-mode
 530                   (progn
 531                     (dired-omit-mode)
 532                     (dired-goto-file file))))))))
 533
 534 (defun dired-jump-other-window ()
 535   "Like \\[dired-jump] (`dired-jump') but in other window."
 536   (interactive)
 537   (dired-jump t))
 538 \f
 539 ;;; OMITTING.
 540
 541 ;;; Enhanced omitting of lines from directory listings.
 542 ;;; Marked files are never omitted.
 543
 544 ;; should probably get rid of this and always use 'no-dir.
 545 ;; sk 28-Aug-1991 09:37
 546 (defvar dired-omit-localp 'no-dir
 547   "The LOCALP argument `dired-omit-expunge' passes to `dired-get-filename'.
 548 If it is `no-dir', omitting is much faster, but you can only match
 549 against the non-directory part of the file name.  Set it to nil if you
 550 need to match the entire file name.")
 551
 552 ;; \017=^O for Omit - other packages can chose other control characters.
 553 (defvar dired-omit-marker-char ?\017
 554   "Temporary marker used by dired-omit.
 555 Should never be used as marker by the user or other packages.")
 556
 557 (defun dired-omit-startup ()
 558   (or (assq 'dired-omit-mode minor-mode-alist)
 559       (setq minor-mode-alist
 560             (append '((dired-omit-mode
 561                        (:eval (if (eq major-mode 'dired-mode)
 562                                   " Omit" ""))))
 563                     minor-mode-alist))))
 564
 565 (defun dired-mark-omitted ()
 566   "Mark files matching `dired-omit-files' and `dired-omit-extensions'."
 567   (interactive)
 568   (let ((dired-omit-mode nil)) (revert-buffer)) ;; Show omitted files
 569   (dired-mark-unmarked-files (dired-omit-regexp) nil nil dired-omit-localp))
 570
 571 (defvar dired-omit-extensions
 572   (append completion-ignored-extensions
 573           dired-latex-unclean-extensions
 574           dired-bibtex-unclean-extensions
 575           dired-texinfo-unclean-extensions)
 576   "If non-nil, a list of extensions \(strings\) to omit from Dired listings.
 577 Defaults to elements of `completion-ignored-extensions',
 578 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions', and
 579 `dired-texinfo-unclean-extensions'.
 580
 581 See interactive function `dired-omit-mode' \(\\[dired-omit-mode]\) and
 582 variables `dired-omit-mode' and `dired-omit-files'.")
 583
 584 (defun dired-omit-expunge (&optional regexp)
 585   "Erases all unmarked files matching REGEXP.
 586 Does nothing if global variable `dired-omit-mode' is nil, or if called
 587   non-interactively and buffer is bigger than `dired-omit-size-limit'.
 588 If REGEXP is nil or not specified, uses `dired-omit-files', and also omits
 589   filenames ending in `dired-omit-extensions'.
 590 If REGEXP is the empty string, this function is a no-op.
 591
 592 This functions works by temporarily binding `dired-marker-char' to
 593 `dired-omit-marker-char' and calling `dired-do-kill-lines'."
 594   (interactive "sOmit files (regexp): ")
 595   (if (and dired-omit-mode
 596            (or (interactive-p)
 597                (not dired-omit-size-limit)
 598                (< (buffer-size) dired-omit-size-limit)
 599                (progn
 600                  (message "Not omitting: directory larger than %d characters."
 601                           dired-omit-size-limit)
 602                  (setq dired-omit-mode nil)
 603                  nil)))
 604       (let ((omit-re (or regexp (dired-omit-regexp)))
 605             (old-modified-p (buffer-modified-p))
 606             count)
 607         (or (string= omit-re "")
 608             (let ((dired-marker-char dired-omit-marker-char))
 609               (message "Omitting...")
 610               (if (dired-mark-unmarked-files omit-re nil nil dired-omit-localp)
 611                   (progn
 612                     (setq count (dired-do-kill-lines nil "Omitted %d line%s."))
 613                     (force-mode-line-update))
 614                 (message "(Nothing to omit)"))))
 615         ;; Try to preserve modified state of buffer.  So `%*' doesn't appear
 616         ;; in mode-line of omitted buffers.
 617         (set-buffer-modified-p (and old-modified-p
 618                                     (save-excursion
 619                                       (goto-char (point-min))
 620                                       (re-search-forward dired-re-mark nil t))))
 621         count)))
 622
 623 (defun dired-omit-regexp ()
 624   (concat (if dired-omit-files (concat "\\(" dired-omit-files "\\)") "")
 625           (if (and dired-omit-files dired-omit-extensions) "\\|" "")
 626           (if dired-omit-extensions
 627               (concat ".";; a non-extension part should exist
 628                       "\\("
 629                       (mapconcat 'regexp-quote dired-omit-extensions "\\|")
 630                       "\\)$")
 631             "")))
 632
 633 ;; Returns t if any work was done, nil otherwise.
 634 (defun dired-mark-unmarked-files (regexp msg &optional unflag-p localp)
 635   "Mark unmarked files matching REGEXP, displaying MSG.
 636 REGEXP is matched against the entire file name.
 637 Does not re-mark files which already have a mark.
 638 With prefix argument, unflag all those files.
 639 Optional fourth argument LOCALP is as in `dired-get-filename'."
 640   (interactive "P")
 641   (let ((dired-marker-char (if unflag-p ?\s dired-marker-char)))
 642     (dired-mark-if
 643      (and
 644       ;; not already marked
 645       (looking-at " ")
 646       ;; uninteresting
 647       (let ((fn (dired-get-filename localp t)))
 648         (and fn (string-match regexp fn))))
 649      msg)))
 650
 651 ;;; REDEFINE.
 652 (defun dired-omit-new-add-entry (filename &optional marker-char relative)
 653   ;; This redefines dired-aux.el's dired-add-entry to avoid calling ls for
 654   ;; files that are going to be omitted anyway.
 655   (if dired-omit-mode
 656       ;; perhaps return t without calling ls
 657       (let ((omit-re (dired-omit-regexp)))
 658         (if (or (string= omit-re "")
 659                 (not
 660                  (string-match omit-re
 661                                (cond
 662                                 ((eq 'no-dir dired-omit-localp)
 663                                  filename)
 664                                 ((eq t dired-omit-localp)
 665                                  (dired-make-relative filename))
 666                                 (t
 667                                  (dired-make-absolute
 668                                   filename
 669                                   (file-name-directory filename)))))))
 670             ;; if it didn't match, go ahead and add the entry
 671             (dired-omit-old-add-entry filename marker-char relative)
 672           ;; dired-add-entry returns t for success, perhaps we should
 673           ;; return file-exists-p
 674           t))
 675     ;; omitting is not turned on at all
 676     (dired-omit-old-add-entry filename marker-char relative)))
 677
 678 ;;; REDEFINE.
 679 ;;; Redefine dired-aux.el's version of `dired-add-entry'
 680 ;;; Save old defun if not already done:
 681 (or (fboundp 'dired-omit-old-add-entry)
 682     (fset 'dired-omit-old-add-entry (symbol-function 'dired-add-entry)))
 683 ;; Redefine it.
 684 (fset 'dired-add-entry 'dired-omit-new-add-entry)
 685
 686 \f
 687 ;;; VIRTUAL DIRED MODE.
 688
 689 ;;; For browsing `ls -lR' listings in a dired-like fashion.
 690
 691 (defalias 'virtual-dired 'dired-virtual)
 692 (defun dired-virtual (dirname &optional switches)
 693   "Put this buffer into Virtual Dired mode.
 694
 695 In Virtual Dired mode, all commands that do not actually consult the
 696 filesystem will work.
 697
 698 This is useful if you want to peruse and move around in an ls -lR
 699 output file, for example one you got from an ftp server.  With
 700 ange-ftp, you can even dired a directory containing an ls-lR file,
 701 visit that file and turn on virtual dired mode.  But don't try to save
 702 this file, as dired-virtual indents the listing and thus changes the
 703 buffer.
 704
 705 If you have save a Dired buffer in a file you can use \\[dired-virtual] to
 706 resume it in a later session.
 707
 708 Type \\<dired-mode-map>\\[revert-buffer] \
 709 in the Virtual Dired buffer and answer `y' to convert
 710 the virtual to a real dired buffer again.  You don't have to do this, though:
 711 you can relist single subdirs using \\[dired-do-redisplay]."
 712
 713   ;; DIRNAME is the top level directory of the buffer.  It will become
 714   ;; its `default-directory'.  If nil, the old value of
 715   ;; default-directory is used.
 716
 717   ;; Optional SWITCHES are the ls switches to use.
 718
 719   ;; Shell wildcards will be used if there already is a `wildcard'
 720   ;; line in the buffer (thus it is a saved Dired buffer), but there
 721   ;; is no other way to get wildcards.  Insert a `wildcard' line by
 722   ;; hand if you want them.
 723
 724   (interactive
 725    (list (read-string "Virtual Dired directory: " (dired-virtual-guess-dir))))
 726   (goto-char (point-min))
 727   (or (looking-at "  ")
 728       ;; if not already indented, do it now:
 729       (indent-region (point-min) (point-max) 2))
 730   (or dirname (setq dirname default-directory))
 731   (setq dirname (expand-file-name (file-name-as-directory dirname)))
 732   (setq default-directory dirname)      ; contains no wildcards
 733   (let ((wildcard (save-excursion
 734                     (goto-char (point-min))
 735                     (forward-line 1)
 736                     (and (looking-at "^  wildcard ")
 737                          (buffer-substring (match-end 0)
 738                                            (progn (end-of-line) (point)))))))
 739   (if wildcard
 740         (setq dirname (expand-file-name wildcard default-directory))))
 741   ;; If raw ls listing (not a saved old dired buffer), give it a
 742   ;; decent subdir headerline:
 743   (goto-char (point-min))
 744   (or (looking-at dired-subdir-regexp)
 745       (insert "  "
 746               (directory-file-name (file-name-directory default-directory))
 747               ":\n"))
 748   (dired-mode dirname (or switches dired-listing-switches))
 749   (setq mode-name "Virtual Dired"
 750         revert-buffer-function 'dired-virtual-revert)
 751   (set (make-local-variable 'dired-subdir-alist) nil)
 752   (dired-build-subdir-alist)
 753   (goto-char (point-min))
 754   (dired-initial-position dirname))
 755
 756 (defun dired-virtual-guess-dir ()
 757   "Guess and return appropriate working directory of this buffer.
 758 The buffer is assumed to be in Dired or ls -lR format.  The guess is
 759 based upon buffer contents.  If nothing could be guessed, returns
 760 nil."
 761
 762   (let ((regexp "^\\(  \\)?\\([^ \n\r]*\\)\\(:\\)[\n\r]")
 763         (subexpr 2))
 764     (goto-char (point-min))
 765     (cond ((looking-at regexp)
 766            ;; If a saved dired buffer, look to which dir and
 767            ;; perhaps wildcard it belongs:
 768            (let ((dir (buffer-substring (match-beginning subexpr)
 769                                         (match-end subexpr))))
 770              (file-name-as-directory dir)))
 771           ;; Else no match for headerline found.  It's a raw ls listing.
 772           ;; In raw ls listings the directory does not have a headerline
 773           ;; try parent of first subdir, if any
 774           ((re-search-forward regexp nil t)
 775            (file-name-directory
 776             (directory-file-name
 777              (file-name-as-directory
 778               (buffer-substring (match-beginning subexpr)
 779                                 (match-end subexpr))))))
 780           (t                            ; if all else fails
 781            nil))))
 782
 783
 784 (defun dired-virtual-revert (&optional arg noconfirm)
 785   (if (not
 786        (y-or-n-p "Cannot revert a Virtual Dired buffer - switch to Real Dired mode? "))
 787       (error "Cannot revert a Virtual Dired buffer")
 788     (setq mode-name "Dired"
 789           revert-buffer-function 'dired-revert)
 790     (revert-buffer)))
 791
 792 ;; A zero-arg version of dired-virtual.
 793 (defun dired-virtual-mode ()
 794   "Put current buffer into Virtual Dired mode (see `dired-virtual').
 795 Useful on `magic-mode-alist' with the regexp
 796
 797   \"^  \\\\(/[^ /]+\\\\)+/?:$\"
 798
 799 to put saved dired buffers automatically into Virtual Dired mode.
 800
 801 Also useful for `auto-mode-alist' like this:
 802
 803   (add-to-list 'auto-mode-alist
 804                '(\"[^/]\\\\.dired\\\\'\" . dired-virtual-mode))"
 805   (interactive)
 806   (dired-virtual (dired-virtual-guess-dir)))
 807
 808 \f
 809 ;;; SMART SHELL.
 810
 811 ;;; An Emacs buffer can have but one working directory, stored in the
 812 ;;; buffer-local variable `default-directory'.  A Dired buffer may have
 813 ;;; several subdirectories inserted, but still has but one working directory:
 814 ;;; that of the top level Dired directory in that buffer.  For some commands
 815 ;;; it is appropriate that they use the current Dired directory instead of
 816 ;;; `default-directory', e.g., `find-file' and `compile'.  This is a general
 817 ;;; mechanism is provided for special handling of the working directory in
 818 ;;; special major modes.
 819
 820 ;; It's easier to add to this alist than redefine function
 821 ;; default-directory while keeping the old information.
 822 (defconst default-directory-alist
 823   '((dired-mode . (if (fboundp 'dired-current-directory)
 824                       (dired-current-directory)
 825                     default-directory)))
 826   "Alist of major modes and their opinion on `default-directory'.
 827 This is given as a Lisp expression to evaluate.  A resulting value of
 828 nil is ignored in favor of `default-directory'.")
 829
 830 (defun dired-default-directory ()
 831   "Usage like variable `default-directory'.
 832 Knows about the special cases in variable `default-directory-alist'."
 833   (or (eval (cdr (assq major-mode default-directory-alist)))
 834       default-directory))
 835
 836 (defun dired-smart-shell-command (cmd &optional insert)
 837   "Like function `shell-command', but in the current Virtual Dired directory."
 838   (interactive (list (read-from-minibuffer "Shell command: "
 839                                            nil nil nil 'shell-command-history)
 840                      current-prefix-arg))
 841   (let ((default-directory (dired-default-directory)))
 842     (shell-command cmd insert)))
 843
 844 \f
 845 ;;; LOCAL VARIABLES FOR DIRED BUFFERS.
 846
 847 ;;; Brief Description:
 848 ;;;
 849 ;;; * `dired-extra-startup' is part of the `dired-mode-hook'.
 850 ;;;
 851 ;;; * `dired-extra-startup' calls `dired-hack-local-variables'
 852 ;;;
 853 ;;; * `dired-hack-local-variables' checks the value of
 854 ;;;   `dired-local-variables-file'
 855 ;;;
 856 ;;; * Check if `dired-local-variables-file' is a non-nil string and is a
 857 ;;;   filename found in the directory of the Dired Buffer being created.
 858 ;;;
 859 ;;; * If `dired-local-variables-file' satisfies the above, then temporarily
 860 ;;;   include it in the Dired Buffer at the bottom.
 861 ;;;
 862 ;;; * Set `enable-local-variables' temporarily to the user variable
 863 ;;;   `dired-enable-local-variables' and run `hack-local-variables' on the
 864 ;;;   Dired Buffer.
 865
 866 (defvar dired-local-variables-file (convert-standard-filename ".dired")
 867   "Filename, as string, containing local dired buffer variables to be hacked.
 868 If this file found in current directory, then it will be inserted into dired
 869 buffer and `hack-local-variables' will be run.  See Info node
 870 `(emacs)File Variables' for more information on local variables.
 871 See also `dired-enable-local-variables'.")
 872
 873 (defun dired-hack-local-variables ()
 874   "Evaluate local variables in `dired-local-variables-file' for dired buffer."
 875   (if (and dired-local-variables-file
 876            (stringp dired-local-variables-file)
 877            (file-exists-p dired-local-variables-file))
 878       (let ((opoint (point-max))
 879             buffer-read-only
 880             ;; In case user has `enable-local-variables' set to nil we
 881             ;; override it locally with dired's variable.
 882             (enable-local-variables dired-enable-local-variables))
 883         ;; Insert 'em.
 884         (save-excursion
 885           (goto-char opoint)
 886           (insert "\^L\n")
 887           (insert-file-contents dired-local-variables-file))
 888         ;; Hack 'em.
 889         (let ((buffer-file-name dired-local-variables-file))
 890           (hack-local-variables))
 891         ;; Make sure that the modeline shows the proper information.
 892         (dired-sort-set-modeline)
 893         ;; Delete this stuff: `eobp' is used to find last subdir by dired.el.
 894         (delete-region opoint (point-max)))))
 895
 896 (defun dired-omit-here-always ()
 897   "Create `dired-local-variables-file' for omitting and reverts directory.
 898 Sets `dired-omit-mode' to t in a local variables file that is readable by
 899 dired."
 900   (interactive)
 901   (if (file-exists-p dired-local-variables-file)
 902       (message "File `./%s' already exists." dired-local-variables-file)
 903
 904     ;; Create `dired-local-variables-file'.
 905     (save-excursion
 906       (set-buffer (get-buffer-create " *dot-dired*"))
 907       (erase-buffer)
 908       (insert "Local Variables:\ndired-omit-mode: t\nEnd:\n")
 909       (write-file dired-local-variables-file)
 910       (kill-buffer (current-buffer)))
 911
 912     ;; Run extra-hooks and revert directory.
 913     (dired-extra-startup)
 914     (dired-revert)))
 915
 916 \f
 917 ;;; GUESS SHELL COMMAND.
 918
 919 ;;; Brief Description:
 920 ;;;
 921 ;;; `dired-do-shell-command' is bound to `!' by dired.el.
 922 ;;;
 923 ;;; * Redefine `dired-do-shell-command' so it calls
 924 ;;;   `dired-guess-shell-command'.
 925 ;;;
 926 ;;; * `dired-guess-shell-command' calls `dired-guess-default' with list of
 927 ;;;    marked files.
 928 ;;;
 929 ;;; * Parse `dired-guess-shell-alist-user' and
 930 ;;;   `dired-guess-shell-alist-default' (in that order) for the first REGEXP
 931 ;;;   that matches the first file in the file list.
 932 ;;;
 933 ;;; * If the REGEXP matches all the entries of the file list then evaluate
 934 ;;;   COMMAND, which is either a string or a Lisp expression returning a
 935 ;;;   string.  COMMAND may be a list of commands.
 936 ;;;
 937 ;;; * Return this command to `dired-guess-shell-command' which prompts user
 938 ;;;   with it.  The list of commands is temporarily put into the history list.
 939 ;;;   If a command is used successfully then it is stored permanently in
 940 ;;;   `dired-shell-command-history'.
 941
 942 ;;; Guess what shell command to apply to a file.
 943 (defvar dired-shell-command-history nil
 944   "History list for commands that read dired-shell commands.")
 945
 946 ;;; Default list of shell commands.
 947
 948 ;;; NOTE: Use `gunzip -c' instead of `zcat' on `.gz' files.  Some do not
 949 ;;; install GNU zip's version of zcat.
 950
 951 (defvar dired-guess-shell-alist-default
 952   (list
 953    (list "\\.tar$"
 954          '(if dired-guess-shell-gnutar
 955               (concat dired-guess-shell-gnutar " xvf")
 956             "tar xvf")
 957          ;; Extract files into a separate subdirectory
 958          '(if dired-guess-shell-gnutar
 959               (concat "mkdir " (file-name-sans-extension file)
 960                       "; " dired-guess-shell-gnutar " -C "
 961                       (file-name-sans-extension file) " -xvf")
 962             (concat "mkdir " (file-name-sans-extension file)
 963                     "; tar -C " (file-name-sans-extension file) " -xvf"))
 964          ;; List archive contents.
 965          '(if dired-guess-shell-gnutar
 966               (concat dired-guess-shell-gnutar " tvf")
 967             "tar tvf"))
 968
 969    ;; REGEXPS for compressed archives must come before the .Z rule to
 970    ;; be recognized:
 971    (list "\\.tar\\.Z$"
 972          ;; Untar it.
 973          '(if dired-guess-shell-gnutar
 974               (concat dired-guess-shell-gnutar " zxvf")
 975             (concat "zcat * | tar xvf -"))
 976          ;; Optional conversion to gzip format.
 977          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 978                   " " dired-guess-shell-znew-switches))
 979
 980    ;; gzip'ed archives
 981    (list "\\.t\\(ar\\.\\)?gz$"
 982          '(if dired-guess-shell-gnutar
 983               (concat dired-guess-shell-gnutar " zxvf")
 984             (concat "gunzip -qc * | tar xvf -"))
 985          ;; Extract files into a separate subdirectory
 986          '(if dired-guess-shell-gnutar
 987               (concat "mkdir " (file-name-sans-extension file)
 988                       "; " dired-guess-shell-gnutar " -C "
 989                       (file-name-sans-extension file) " -zxvf")
 990             (concat "mkdir " (file-name-sans-extension file)
 991                     "; gunzip -qc * | tar -C "
 992                     (file-name-sans-extension file) " -xvf -"))
 993          ;; Optional decompression.
 994          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q" ""))
 995          ;; List archive contents.
 996          '(if dired-guess-shell-gnutar
 997               (concat dired-guess-shell-gnutar " ztvf")
 998             (concat "gunzip -qc * | tar tvf -")))
 999
1000    ;; bzip2'ed archives
1001    (list "\\.t\\(ar\\.bz2\\|bz\\)$"
1002          "bunzip2 -c * | tar xvf -"
1003          ;; Extract files into a separate subdirectory
1004          '(concat "mkdir " (file-name-sans-extension file)
1005                   "; bunzip2 -c * | tar -C "
1006                   (file-name-sans-extension file) " -xvf -")
1007          ;; Optional decompression.
1008          "bunzip2")
1009
1010    '("\\.shar\\.Z$" "zcat * | unshar")
1011    '("\\.shar\\.g?z$" "gunzip -qc * | unshar")
1012
1013    '("\\.e?ps$" "ghostview" "xloadimage" "lpr")
1014    (list "\\.e?ps\\.g?z$" "gunzip -qc * | ghostview -"
1015          ;; Optional decompression.
1016          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1017    (list "\\.e?ps\\.Z$" "zcat * | ghostview -"
1018          ;; Optional conversion to gzip format.
1019          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1020                   " " dired-guess-shell-znew-switches))
1021
1022    '("\\.patch$" "cat * | patch")
1023    (list "\\.patch\\.g?z$" "gunzip -qc * | patch"
1024          ;; Optional decompression.
1025          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1026    (list "\\.patch\\.Z$" "zcat * | patch"
1027          ;; Optional conversion to gzip format.
1028          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1029                   " " dired-guess-shell-znew-switches))
1030
1031    ;; The following four extensions are useful with dired-man ("N" key)
1032    (list "\\.\\(?:[0-9]\\|man\\)$" '(progn (require 'man)
1033                                            (if (Man-support-local-filenames)
1034                                                "man -l"
1035                                              "cat * | tbl | nroff -man -h")))
1036    (list "\\.\\(?:[0-9]\\|man\\)\\.g?z$" '(progn (require 'man)
1037                                                  (if (Man-support-local-filenames)
1038                                                      "man -l"
1039                                                    "gunzip -qc * | tbl | nroff -man -h"))
1040          ;; Optional decompression.
1041          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1042    (list "\\.[0-9]\\.Z$" '(progn (require 'man)
1043                                  (if (Man-support-local-filenames)
1044                                      "man -l"
1045                                    "zcat * | tbl | nroff -man -h"))
1046          ;; Optional conversion to gzip format.
1047          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1048                   " " dired-guess-shell-znew-switches))
1049    '("\\.pod$" "perldoc" "pod2man * | nroff -man")
1050
1051    '("\\.dvi$" "xdvi" "dvips")          ; preview and printing
1052    '("\\.au$" "play")                   ; play Sun audiofiles
1053    '("\\.mpe?g$\\|\\.avi$" "xine -p")
1054    '("\\.wav$" "play")
1055    '("\\.uu$" "uudecode")               ; for uudecoded files
1056    '("\\.hqx$" "mcvert")
1057    '("\\.sh$" "sh")                     ; execute shell scripts
1058    '("\\.xbm$" "bitmap")                ; view X11 bitmaps
1059    '("\\.gp$" "gnuplot")
1060    '("\\.p[bgpn]m$" "xloadimage")
1061    '("\\.gif$" "xloadimage")            ; view gif pictures
1062    '("\\.tif$" "xloadimage")
1063    '("\\.png$" "display")               ; xloadimage 4.1 doesn't grok PNG
1064    '("\\.jpe?g$" "xloadimage")
1065    '("\\.fig$" "xfig")                  ; edit fig pictures
1066    '("\\.out$" "xgraph")                ; for plotting purposes.
1067    '("\\.tex$" "latex" "tex")
1068    '("\\.texi\\(nfo\\)?$" "makeinfo" "texi2dvi")
1069    '("\\.pdf$" "xpdf")
1070    '("\\.doc$" "antiword" "strings")
1071    '("\\.rpm$" "rpm -qilp" "rpm -ivh")
1072    '("\\.dia$" "dia")
1073    '("\\.mgp$" "mgp")
1074
1075    ;; Some other popular archivers.
1076    (list "\\.zip$" "unzip" "unzip -l"
1077          ;; Extract files into a separate subdirectory
1078          '(concat "unzip" (if dired-guess-shell-gzip-quiet " -q")
1079                   " -d " (file-name-sans-extension file)))
1080    '("\\.zoo$" "zoo x//")
1081    '("\\.lzh$" "lharc x")
1082    '("\\.arc$" "arc x")
1083    '("\\.shar$" "unshar")
1084
1085    ;; Compression.
1086    (list "\\.g?z$" '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1087    (list "\\.dz$" "dictunzip")
1088    (list "\\.bz2$" "bunzip2")
1089    (list "\\.Z$" "uncompress"
1090          ;; Optional conversion to gzip format.
1091          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1092                   " " dired-guess-shell-znew-switches))
1093
1094    '("\\.sign?$" "gpg --verify"))
1095
1096   "Default alist used for shell command guessing.
1097 See `dired-guess-shell-alist-user'.")
1098
1099 (defcustom dired-guess-shell-alist-user nil
1100   "User-defined alist of rules for suggested commands.
1101 These rules take precedence over the predefined rules in the variable
1102 `dired-guess-shell-alist-default' (to which they are prepended).
1103
1104 Each element of this list looks like
1105
1106     \(REGEXP COMMAND...\)
1107
1108 where each COMMAND can either be a string or a Lisp expression that evaluates
1109 to a string.  If several COMMANDs are given, the first one will be the default
1110 and the rest will be added temporarily to the history and can be retrieved
1111 with \\[previous-history-element] (M-p) .
1112
1113 You can set this variable in your ~/.emacs.  For example, to add rules for
1114 `.foo' and `.bar' files, write
1115
1116  \(setq dired-guess-shell-alist-user
1117        (list (list \"\\\\.foo\\\\'\" \"FOO-COMMAND\");; fixed rule
1118               ;; possibly more rules ...
1119               (list \"\\\\.bar\\\'\";; rule with condition test
1120                     '(if condition
1121                           \"BAR-COMMAND-1\"
1122                         \"BAR-COMMAND-2\")))\)"
1123   :group 'dired-x
1124   :type '(alist :key-type regexp :value-type (repeat sexp)))
1125
1126 (defun dired-guess-default (files)
1127   "Guess a shell commands for FILES.  Return command or list of commands.
1128 See `dired-guess-shell-alist-user'."
1129
1130   (let* ((case-fold-search t)
1131          ;; Prepend the user's alist to the default alist.
1132          (alist (append dired-guess-shell-alist-user
1133                         dired-guess-shell-alist-default))
1134          (file (car files))
1135          (flist (cdr files))
1136          elt regexp cmds)
1137
1138     ;; Find the first match in the alist for first file in FILES.
1139     (while alist
1140       (setq elt (car alist)
1141             regexp (car elt)
1142             alist (cdr alist))
1143       (if (string-match regexp file)
1144           (setq cmds (cdr elt)
1145                 alist nil)))
1146
1147     ;; If more than one file, see if all of FILES match regular expression.
1148     (while (and flist
1149                 (string-match regexp (car flist)))
1150       (setq flist (cdr flist)))
1151
1152     ;; If flist is still non-nil, then do not guess since this means that not
1153     ;; all the files in FILES were matched by the regexp.
1154     (setq cmds (and (not flist) cmds))
1155
1156     ;; Return commands or nil if flist is still non-nil.
1157     ;; Evaluate the commands in order that any logical testing will be done.
1158     (cond ((not (cdr cmds))
1159            (eval (car cmds))) ; single command
1160           (t
1161            (mapcar (function eval) cmds)))))
1162
1163 (defun dired-guess-shell-command (prompt files)
1164   "Ask user with PROMPT for a shell command, guessing a default from FILES."
1165
1166   (let ((default (dired-guess-default files))
1167         default-list old-history val (failed t))
1168
1169     (if (null default)
1170         ;; Nothing to guess
1171         (read-from-minibuffer prompt nil nil nil 'dired-shell-command-history)
1172
1173       ;; Save current history list
1174       (setq old-history dired-shell-command-history)
1175
1176       (if (listp default)
1177
1178           ;; More than one guess
1179           (setq default-list default
1180                 default (car default)
1181                 prompt (concat
1182                         prompt
1183                         (format "{%d guesses} " (length default-list))))
1184
1185         ;; Just one guess
1186         (setq default-list (list default)))
1187
1188       ;; Push all guesses onto history so that they can be retrieved with M-p
1189       ;; and put the first guess in the prompt but not in the initial value.
1190       (setq dired-shell-command-history
1191             (append default-list dired-shell-command-history)
1192             prompt (concat prompt (format "[%s] " default)))
1193
1194       ;; The unwind-protect returns VAL, and we too.
1195       (unwind-protect
1196           ;; BODYFORM
1197           (progn
1198             (setq val (read-from-minibuffer prompt nil nil nil
1199                                             'dired-shell-command-history)
1200                   failed nil)
1201             ;; If we got a return, then use default.
1202             (if (equal val "")
1203                 (setq val default))
1204             val)
1205
1206         ;; UNWINDFORMS
1207         ;; Undo pushing onto the history list so that an aborted
1208         ;; command doesn't get the default in the next command.
1209         (setq dired-shell-command-history old-history)
1210         (if (not failed)
1211             (or (equal val (car-safe dired-shell-command-history))
1212                 (setq dired-shell-command-history
1213                       (cons val dired-shell-command-history))))))))
1214
1215
1216 ;;; REDEFINE.
1217 ;;; Redefine dired-aux.el's version:
1218 (defun dired-read-shell-command (prompt arg files)
1219   "Read a dired shell command prompting with PROMPT (using read-string).
1220 ARG is the prefix arg and may be used to indicate in the prompt which
1221   files are affected.
1222 This is an extra function so that you can redefine it."
1223   (dired-mark-pop-up
1224    nil 'shell files
1225    'dired-guess-shell-command
1226    (format prompt (dired-mark-prompt arg files)) ; PROMPT
1227    files))                                       ; FILES
1228
1229 \f
1230 ;;; RELATIVE SYMBOLIC LINKS.
1231
1232 (defvar dired-keep-marker-relsymlink ?S
1233   "See variable `dired-keep-marker-move'.")
1234
1235 (defun dired-make-relative-symlink (file1 file2 &optional ok-if-already-exists)
1236   "Make a symbolic link (pointing to FILE1) in FILE2.
1237 The link is relative (if possible), for example
1238
1239     \"/vol/tex/bin/foo\" \"/vol/local/bin/foo\"
1240
1241 results in
1242
1243     \"../../tex/bin/foo\" \"/vol/local/bin/foo\""
1244   (interactive "FRelSymLink: \nFRelSymLink %s: \np")
1245   (let (name1 name2 len1 len2 (index 0) sub)
1246     (setq file1 (expand-file-name file1)
1247           file2 (expand-file-name file2)
1248           len1 (length file1)
1249           len2 (length file2))
1250     ;; Find common initial file name components:
1251     (let (next)
1252       (while (and (setq next (string-match "/" file1 index))
1253                   (setq next (1+ next))
1254                   (< next (min len1 len2))
1255                   ;; For the comparison, both substrings must end in
1256                   ;; `/', so NEXT is *one plus* the result of the
1257                   ;; string-match.
1258                   ;; E.g., consider the case of linking "/tmp/a/abc"
1259                   ;; to "/tmp/abc" erroneously giving "/tmp/a" instead
1260                   ;; of "/tmp/" as common initial component
1261                   (string-equal (substring file1 0 next)
1262                                 (substring file2 0 next)))
1263         (setq index next))
1264       (setq name2 file2
1265             sub (substring file1 0 index)
1266             name1 (substring file1 index)))
1267     (if (string-equal sub "/")
1268         ;; No common initial file name found
1269         (setq name1 file1)
1270       ;; Else they have a common parent directory
1271       (let ((tem (substring file2 index))
1272             (start 0)
1273             (count 0))
1274         ;; Count number of slashes we must compensate for ...
1275         (while (setq start (string-match "/" tem start))
1276           (setq count (1+ count)
1277                 start (1+ start)))
1278         ;; ... and prepend a "../" for each slash found:
1279         (while (> count 0)
1280           (setq count (1- count)
1281                 name1 (concat "../" name1)))))
1282     (make-symbolic-link
1283      (directory-file-name name1)        ; must not link to foo/
1284                                         ; (trailing slash!)
1285      name2 ok-if-already-exists)))
1286
1287 ;;;###autoload
1288 (defun dired-do-relsymlink (&optional arg)
1289    "Relative symlink all marked (or next ARG) files into a directory.
1290 Otherwise make a relative symbolic link to the current file.
1291 This creates relative symbolic links like
1292
1293     foo -> ../bar/foo
1294
1295 not absolute ones like
1296
1297     foo -> /ugly/file/name/that/may/change/any/day/bar/foo
1298
1299 For absolute symlinks, use \\[dired-do-symlink]."
1300   (interactive "P")
1301   (dired-do-create-files 'relsymlink (function dired-make-relative-symlink)
1302                            "RelSymLink" arg dired-keep-marker-relsymlink))
1303
1304 (defun dired-do-relsymlink-regexp (regexp newname &optional arg whole-name)
1305   "RelSymlink all marked files containing REGEXP to NEWNAME.
1306 See functions `dired-do-rename-regexp' and `dired-do-relsymlink'
1307 for more info."
1308   (interactive (dired-mark-read-regexp "RelSymLink"))
1309   (dired-do-create-files-regexp
1310    (function dired-make-relative-symlink)
1311    "RelSymLink" arg regexp newname whole-name dired-keep-marker-relsymlink))
1312
1313 \f
1314 ;;; VISIT ALL MARKED FILES SIMULTANEOUSLY.
1315
1316 ;;; Brief Description:
1317 ;;;
1318 ;;; `dired-do-find-marked-files' is bound to `F' by dired-x.el.
1319 ;;;
1320 ;;; * Use `dired-get-marked-files' to collect the marked files in the current
1321 ;;;   Dired Buffer into a list of filenames `FILE-LIST'.
1322 ;;;
1323 ;;; * Pass FILE-LIST to `dired-simultaneous-find-file' all with
1324 ;;;   `dired-do-find-marked-files''s prefix argument NOSELECT.
1325 ;;;
1326 ;;; * `dired-simultaneous-find-file' runs through FILE-LIST decrementing the
1327 ;;;   list each time.
1328 ;;;
1329 ;;; * If NOSELECT is non-nil then just run `find-file-noselect'  on each
1330 ;;;   element of FILE-LIST.
1331 ;;;
1332 ;;; * If NOSELECT is nil then calculate the `size' of the window for each file
1333 ;;;   by dividing the `window-height' by length of FILE-LIST.  Thus, `size' is
1334 ;;;   cognizant of the window-configuration.
1335 ;;;
1336 ;;; * If `size' is too small abort, otherwise run `find-file' on each element
1337 ;;;   of FILE-LIST giving each a window of height `size'.
1338
1339 (defun dired-do-find-marked-files (&optional noselect)
1340   "Find all marked files displaying all of them simultaneously.
1341 With optional NOSELECT just find files but do not select them.
1342
1343 The current window is split across all files marked, as evenly as possible.
1344 Remaining lines go to bottom-most window.  The number of files that can be
1345 displayed this way is restricted by the height of the current window and
1346 `window-min-height'.
1347
1348 To keep dired buffer displayed, type \\[split-window-vertically] first.
1349 To display just marked files, type \\[delete-other-windows] first."
1350
1351   (interactive "P")
1352   (dired-simultaneous-find-file (dired-get-marked-files) noselect))
1353
1354 (defun dired-simultaneous-find-file (file-list noselect)
1355
1356   "Visit all files in FILE-LIST and display them simultaneously.
1357 The current window is split across all files in FILE-LIST, as evenly as
1358 possible.  Remaining lines go to the bottom-most window.  The number of
1359 files that can be displayed this way is restricted by the height of the
1360 current window and the variable `window-min-height'.  With non-nil
1361 NOSELECT the files are merely found but not selected."
1362
1363   ;; We don't make this function interactive because it is usually too clumsy
1364   ;; to specify FILE-LIST interactively unless via dired.
1365
1366   (let (size)
1367
1368     (if noselect
1369         ;; Do not select the buffer.
1370         (find-file-noselect (car file-list))
1371
1372       ;; We will have to select the buffer.  Calculate and check window size.
1373       (setq size (/ (window-height) (length file-list)))
1374       (or (<= window-min-height size)
1375           (error "Too many files to visit simultaneously.  Try C-u prefix"))
1376       (find-file (car file-list)))
1377
1378     ;; Decrement.
1379     (setq file-list (cdr file-list))
1380
1381     (while file-list
1382
1383       (if noselect
1384           ;; Do not select the buffer.
1385           (find-file-noselect (car file-list))
1386
1387         ;; Vertically split off a window of desired size.  Upper window will
1388         ;; have SIZE lines.  Select lower (larger) window.  We split it again.
1389         (select-window (split-window nil size))
1390         (find-file (car file-list)))
1391
1392       ;; Decrement.
1393       (setq file-list (cdr file-list)))))
1394
1395 \f
1396 ;;; MISCELLANEOUS COMMANDS.
1397
1398 ;;; Run man on files.
1399
1400 (defun dired-man ()
1401   "Run man on this file.  Display old buffer if buffer name matches filename.
1402 Uses `man.el' of \\[manual-entry] fame."
1403   (interactive)
1404   (require 'man)
1405   (let* ((file (dired-get-filename))
1406          (manual-program (replace-regexp-in-string "\\*" "%s"
1407                           (dired-guess-shell-command
1408                            "Man command: " (list file)))))
1409     (Man-getpage-in-background file)))
1410
1411 ;;; Run Info on files.
1412
1413 (defun dired-info ()
1414   "Run info on this file."
1415   (interactive)
1416   (info (dired-get-filename)))
1417
1418 ;;; Run mail on mail folders.
1419
1420 ;; Avoid compiler warning.
1421 (eval-when-compile
1422   (when (not (fboundp 'vm-visit-folder))
1423     (defun vm-visit-folder (file &optional arg)
1424       nil)))
1425
1426 (defun dired-vm (&optional read-only)
1427   "Run VM on this file.
1428 With prefix arg, visit folder read-only (this requires at least VM 5).
1429 See also variable `dired-vm-read-only-folders'."
1430   (interactive "P")
1431   (let ((dir (dired-current-directory))
1432         (fil (dired-get-filename)))
1433     ;; take care to supply 2nd arg only if requested - may still run VM 4!
1434     (cond (read-only (vm-visit-folder fil t))
1435           ((eq t dired-vm-read-only-folders) (vm-visit-folder fil t))
1436           ((null dired-vm-read-only-folders) (vm-visit-folder fil))
1437           (t (vm-visit-folder fil (not (file-writable-p fil)))))
1438     ;; so that pressing `v' inside VM does prompt within current directory:
1439     (set (make-local-variable 'vm-folder-directory) dir)))
1440
1441 (defun dired-rmail ()
1442   "Run RMAIL on this file."
1443   (interactive)
1444   (rmail (dired-get-filename)))
1445
1446 (defun dired-do-run-mail ()
1447   "If `dired-bind-vm' is t, then function `dired-vm', otherwise `dired-rmail'."
1448   (interactive)
1449   (if dired-bind-vm
1450       ;; Read mail folder using vm.
1451       (dired-vm)
1452     ;; Read mail folder using rmail.
1453     (dired-rmail)))
1454
1455 \f
1456 ;;; MISCELLANEOUS INTERNAL FUNCTIONS.
1457
1458 (or (fboundp 'dired-old-find-buffer-nocreate)
1459     (fset 'dired-old-find-buffer-nocreate
1460           (symbol-function 'dired-find-buffer-nocreate)))
1461
1462 ;;; REDEFINE.
1463 ;;; Redefines dired.el's version of `dired-find-buffer-nocreate'
1464 (defun dired-find-buffer-nocreate (dirname &optional mode)
1465   (if (and dired-find-subdir
1466            ;; don't try to find a wildcard as a subdirectory
1467            (string-equal dirname (file-name-directory dirname)))
1468       (let* ((cur-buf (current-buffer))
1469              (buffers (nreverse
1470                        (dired-buffers-for-dir (expand-file-name dirname))))
1471              (cur-buf-matches (and (memq cur-buf buffers)
1472                                    ;; wildcards must match, too:
1473                                    (equal dired-directory dirname))))
1474         ;; We don't want to switch to the same buffer---
1475         (setq buffers (delq cur-buf buffers));;need setq with delq
1476         (or (car (sort buffers (function dired-buffer-more-recently-used-p)))
1477             ;; ---unless it's the only possibility:
1478             (and cur-buf-matches cur-buf)))
1479     (dired-old-find-buffer-nocreate dirname mode)))
1480
1481 ;; This should be a builtin
1482 (defun dired-buffer-more-recently-used-p (buffer1 buffer2)
1483   "Return t if BUFFER1 is more recently used than BUFFER2."
1484   (if (equal buffer1 buffer2)
1485       nil
1486     (let ((more-recent nil)
1487           (list (buffer-list)))
1488       (while (and list
1489                   (not (setq more-recent (equal buffer1 (car list))))
1490                   (not (equal buffer2 (car list))))
1491         (setq list (cdr list)))
1492       more-recent)))
1493
1494 ;;; Same thing as `dired-buffers-for-dir' of dired.el? - lrd 11/23/93
1495 ;;; (defun dired-buffers-for-dir-exact (dir)
1496 ;;; ;; Return a list of buffers that dired DIR (a directory or wildcard)
1497 ;;; ;; at top level, or as subdirectory.
1498 ;;; ;; Top level matches must match the wildcard part too, if any.
1499 ;;; ;; The list is in reverse order of buffer creation, most recent last.
1500 ;;; ;; As a side effect, killed dired buffers for DIR are removed from
1501 ;;; ;; dired-buffers.
1502 ;;;   (let ((alist dired-buffers) result elt)
1503 ;;;     (while alist
1504 ;;;       (setq elt (car alist)
1505 ;;;             alist (cdr alist))
1506 ;;;       (let ((buf (cdr elt)))
1507 ;;;         (if (buffer-name buf)
1508 ;;;             ;; Top level must match exactly against dired-directory in
1509 ;;;             ;; case one of them is a wildcard.
1510 ;;;             (if (or (equal dir (save-excursion (set-buffer buf)
1511 ;;;                                                dired-directory))
1512 ;;;                     (assoc dir (save-excursion (set-buffer buf)
1513 ;;;                                                dired-subdir-alist)))
1514 ;;;                 (setq result (cons buf result)))
1515 ;;;           ;; else buffer is killed - clean up:
1516 ;;;           (setq dired-buffers (delq elt dired-buffers)))))
1517 ;;;     result))
1518
1519 ;;; REDEFINE.
1520 ;;; Redefines dired.el's version of `dired-initial-position'
1521 (defun dired-initial-position (dirname)
1522   "Where point should go in a new listing of DIRNAME.
1523 Point assumed at beginning of new subdir line.
1524 You may redefine this function as you wish, e.g. like in `dired-x.el'."
1525   (end-of-line)
1526   (if dired-find-subdir (dired-goto-subdir dirname)) ; new
1527   (if dired-trivial-filenames (dired-goto-next-nontrivial-file)))
1528
1529 \f
1530 ;; Does anyone use this? - lrd 6/29/93.
1531 ;; Apparently people do use it. - lrd 12/22/97.
1532 (defun dired-mark-sexp (predicate &optional unflag-p)
1533   "Mark files for which PREDICATE returns non-nil.
1534 With a prefix arg, unflag those files instead.
1535
1536 PREDICATE is a lisp expression that can refer to the following symbols:
1537
1538     inode  [integer] the inode of the file (only for ls -i output)
1539     s      [integer] the size of the file for ls -s output
1540                      (usually in blocks or, with -k, in KByte)
1541     mode   [string]  file permission bits, e.g. \"-rw-r--r--\"
1542     nlink  [integer] number of links to file
1543     uid    [string]  owner
1544     gid    [string]  group  (If the gid is not displayed by ls,
1545                      this will still be set (to the same as uid))
1546     size   [integer] file size in bytes
1547     time   [string]  the time that ls displays, e.g. \"Feb 12 14:17\"
1548     name   [string]  the name of the file
1549     sym    [string]  if file is a symbolic link, the linked-to name, else \"\"
1550
1551 For example, use
1552
1553         (equal 0 size)
1554
1555 to mark all zero length files."
1556   ;; Using sym="" instead of nil avoids the trap of
1557   ;; (string-match "foo" sym) into which a user would soon fall.
1558   ;; Give `equal' instead of `=' in the example, as this works on
1559   ;; integers and strings.
1560   (interactive "xMark if (lisp expr): \nP")
1561   (message "%s" predicate)
1562   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char))
1563         inode s mode nlink uid gid size time name sym)
1564     (dired-mark-if
1565      (save-excursion
1566        (and
1567         ;; Sets vars
1568         ;;                inode s mode nlink uid gid size time name sym
1569
1570         ;; according to current file line.  Returns t for success, nil if
1571         ;; there is no file line.  Upon success, all variables are set, either
1572         ;; to nil or the appropriate value, so they need not be initialized.
1573         ;; Moves point within the current line.
1574         (if (dired-move-to-filename)
1575             (let (pos
1576                   (mode-len 10) ; length of mode string
1577                   ;; like in dired.el, but with subexpressions \1=inode, \2=s:
1578                   (dired-re-inode-size "\\s *\\([0-9]*\\)\\s *\\([0-9]*\\) ?"))
1579               (beginning-of-line)
1580               (forward-char 2)
1581               (if (looking-at dired-re-inode-size)
1582                   (progn
1583                     (goto-char (match-end 0))
1584                     (setq inode (string-to-number (buffer-substring (match-beginning 1)
1585                                                                     (match-end 1)))
1586                           s (string-to-number (buffer-substring (match-beginning 2)
1587                                                                 (match-end 2)))))
1588                 (setq inode nil
1589                       s nil))
1590               (setq mode (buffer-substring (point) (+ mode-len (point))))
1591               (forward-char mode-len)
1592               (setq nlink (read (current-buffer)))
1593               ;; Karsten Wenger <kw@cis.uni-muenchen.de> fixed uid.
1594               (setq uid (buffer-substring (+ (point) 1)
1595                                           (progn (forward-word 1) (point))))
1596               (re-search-forward directory-listing-before-filename-regexp)
1597               (goto-char (match-beginning 1))
1598               (forward-char -1)
1599               (setq size (string-to-number (buffer-substring (save-excursion
1600                                                                (backward-word 1)
1601                                                                (setq pos (point)))
1602                                                              (point))))
1603               (goto-char pos)
1604               (backward-word 1)
1605               ;; if no gid is displayed, gid will be set to uid
1606               ;; but user will then not reference it anyway in PREDICATE.
1607               (setq gid (buffer-substring (save-excursion
1608                                             (forward-word 1) (point))
1609                                           (point))
1610                     time (buffer-substring (match-beginning 1)
1611                                            (1- (dired-move-to-filename)))
1612                     name (buffer-substring (point)
1613                                            (or
1614                                             (dired-move-to-end-of-filename t)
1615                                             (point)))
1616                     sym  (progn
1617                            (if (looking-at " -> ")
1618                                (buffer-substring
1619                                 (progn (forward-char 4) (point))
1620                                 (progn (end-of-line) (point)))
1621                              "")))
1622               t)
1623           nil)
1624                       (eval predicate)))
1625      (format "'%s file" predicate))))
1626
1627 \f
1628 ;;; FIND FILE AT POINT.
1629
1630 (defvar dired-x-hands-off-my-keys t
1631   "*Non-nil means don't bind `dired-x-find-file' over `find-file' on keyboard.
1632 Similarly for `dired-x-find-file-other-window' over `find-file-other-window'.
1633 If you change this variable after `dired-x.el' is loaded then do
1634 \\[dired-x-bind-find-file].")
1635
1636 ;;; Bind `dired-x-find-file{-other-window}' over wherever
1637 ;;; `find-file{-other-window}' is bound?
1638 (defun dired-x-bind-find-file ()
1639   "Bind `dired-x-find-file' in place of `find-file' \(or reverse\).
1640 Similarly for `dired-x-find-file-other-window' and `find-file-other-window'.
1641 Binding direction based on `dired-x-hands-off-my-keys'.
1642 This function is part of `after-init-hook'."
1643   (interactive)
1644   (if (interactive-p)
1645       (setq dired-x-hands-off-my-keys
1646             (not (y-or-n-p "Bind dired-x-find-file over find-file? "))))
1647   (cond ((not dired-x-hands-off-my-keys)
1648          (substitute-key-definition 'find-file
1649                                     'dired-x-find-file
1650                                     (current-global-map))
1651          (substitute-key-definition 'find-file-other-window
1652                                     'dired-x-find-file-other-window
1653                                     (current-global-map)))
1654         (t
1655          (substitute-key-definition 'dired-x-find-file
1656                                     'find-file
1657                                     (current-global-map))
1658          (substitute-key-definition 'dired-x-find-file-other-window
1659                                     'find-file-other-window
1660                                     (current-global-map))))
1661   ;; Clear mini-buffer.
1662   (message nil))
1663
1664 ;;; Now call it so binding is correct and put on `after-init-hook' in case
1665 ;;; user changes binding.
1666 (dired-x-bind-find-file)
1667 (add-hook 'after-init-hook 'dired-x-bind-find-file)
1668
1669 (defun dired-x-find-file (filename)
1670   "Edit file FILENAME.
1671 May create a new window, or reuse an existing one.
1672 See the function `display-buffer'.
1673
1674 Identical to `find-file' except when called interactively, with a prefix arg
1675 \(e.g., \\[universal-argument]\), in which case it guesses filename near point.
1676 Useful for editing file mentioned in buffer you are viewing,
1677 or to test if that file exists.  Use minibuffer after snatching filename."
1678   (interactive (list (read-filename-at-point "Find file: ")))
1679   (find-file (expand-file-name filename)))
1680
1681 (defun dired-x-find-file-other-window (filename)
1682   "Edit file FILENAME, in another window.
1683 May create a new window, or reuse an existing one.
1684 See the function `display-buffer'.
1685
1686 Identical to `find-file-other-window' except when called interactively, with a
1687 prefix arg \(e.g., \\[universal-argument]\), in which case it guesses filename near point.
1688 Useful for editing file mentioned in buffer you are viewing,
1689 or to test if that file exists.  Use minibuffer after snatching filename."
1690   (interactive (list (read-filename-at-point "Find file: ")))
1691   (find-file-other-window (expand-file-name filename)))
1692
1693 ;;; Internal functions.
1694
1695 ;; Fixme: This should probably use `thing-at-point'.  -- fx
1696 (defun dired-filename-at-point ()
1697   "Get the filename closest to point, but do not change position.
1698 Has a preference for looking backward when not directly on a symbol.  Not
1699 perfect - point must be in middle of or end of filename."
1700
1701   (let ((filename-chars "-.[:alnum:]_/:$+@")
1702         start end filename prefix)
1703
1704     (save-excursion
1705       ;; First see if just past a filename.
1706       (if (not (eobp))
1707           (if (looking-at "[] \t\n[{}()]") ; whitespace or some parens
1708               (progn
1709                 (skip-chars-backward " \n\t\r({[]})")
1710                 (if (not (bobp))
1711                     (backward-char 1)))))
1712
1713       (if (string-match (concat "[" filename-chars "]")
1714                         (char-to-string (following-char)))
1715           (progn
1716             (if (re-search-backward (concat "[^" filename-chars "]") nil t)
1717                 (forward-char)
1718               (goto-char (point-min)))
1719             (setq start (point))
1720             (setq prefix
1721                   (and (string-match
1722                         "^\\w+@"
1723                         (buffer-substring start (line-beginning-position)))
1724                        "/"))
1725             (goto-char start)
1726             (if (string-match "[/~]" (char-to-string (preceding-char)))
1727                 (setq start (1- start)))
1728             (re-search-forward (concat "\\=[" filename-chars "]*") nil t))
1729
1730         (error "No file found around point!"))
1731
1732       ;; Return string.
1733       (expand-file-name (concat prefix (buffer-substring start (point)))))))
1734
1735 (defun read-filename-at-point (prompt)
1736   "Return filename prompting with PROMPT with completion.
1737 If `current-prefix-arg' is non-nil, uses name at point as guess."
1738   (if current-prefix-arg
1739       (let ((guess (dired-filename-at-point)))
1740         (read-file-name prompt
1741                         (file-name-directory guess)
1742                         guess
1743                         nil (file-name-nondirectory guess)))
1744     (read-file-name prompt default-directory)))
1745 \f
1746 ;;; BUG REPORTS
1747
1748 ;; Fixme: get rid of this later.
1749
1750 ;;; This section is provided for reports.  It uses Barry A. Warsaw's
1751 ;;; reporter.el which is bundled with GNU Emacs v19.
1752
1753 (defconst dired-x-help-address "bug-gnu-emacs@gnu.org"
1754   "Address(es) accepting submission of reports on dired-x.el.")
1755
1756 (defconst dired-x-variable-list
1757   (list
1758    'dired-bind-vm
1759    'dired-vm-read-only-folders
1760    'dired-bind-jump
1761    'dired-bind-info
1762    'dired-bind-man
1763    'dired-find-subdir
1764    'dired-enable-local-variables
1765    'dired-local-variables-file
1766    'dired-guess-shell-gnutar
1767    'dired-guess-shell-gzip-quiet
1768    'dired-guess-shell-znew-switches
1769    'dired-guess-shell-alist-user
1770    'dired-clean-up-buffers-too
1771    'dired-omit-mode
1772    'dired-omit-files
1773    'dired-omit-extensions
1774    )
1775   "List of variables to be appended to reports sent by `dired-x-submit-report'.")
1776
1777 (defun dired-x-submit-report ()
1778   "Submit via `reporter.el' a bug report on program.
1779 Send report on `dired-x-file' version `dired-x-version,' to
1780 `dired-x-maintainer' at address `dired-x-help-address' listing
1781 variables `dired-x-variable-list' in the message."
1782   (interactive)
1783
1784   (reporter-submit-bug-report
1785    dired-x-help-address                 ; address
1786    "dired-x"                            ; pkgname
1787    dired-x-variable-list                ; varlist
1788    nil nil                              ; pre-/post-hooks
1789    ""))
1790
1791 \f
1792 ;; As Barry Warsaw would say: "This might be useful..."
1793 (provide 'dired-x)
1794
1795 ;; arch-tag: 71a43ba2-7a00-4793-a028-0613dd7765ae
1796 ;;; dired-x.el ends here