lisp/tmm.el

   1 ;;; tmm.el --- text mode access to menu-bar  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 1994-1996, 2000-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Ilya Zakharevich <ilya@math.mps.ohio-state.edu>
   6 ;; Maintainer: FSF
   7 ;; Keywords: convenience
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This package provides text mode access to the menu bar.
  27
  28 ;;; Code:
  29
  30 (require 'electric)
  31
  32 (defgroup tmm nil
  33   "Text mode access to menu-bar."
  34   :prefix "tmm-"
  35   :group 'menu)
  36
  37 ;;; The following will be localized, added only to pacify the compiler.
  38 (defvar tmm-short-cuts)
  39 (defvar tmm-old-mb-map nil)
  40 (defvar tmm-c-prompt nil)
  41 (defvar tmm-km-list)
  42 (defvar tmm-next-shortcut-digit)
  43 (defvar tmm-table-undef)
  44
  45 ;;;###autoload (define-key global-map "\M-`" 'tmm-menubar)
  46 ;;;###autoload (define-key global-map [menu-bar mouse-1] 'tmm-menubar-mouse)
  47
  48 ;;;###autoload
  49 (defun tmm-menubar (&optional x-position)
  50   "Text-mode emulation of looking and choosing from a menubar.
  51 See the documentation for `tmm-prompt'.
  52 X-POSITION, if non-nil, specifies a horizontal position within the menu bar;
  53 we make that menu bar item (the one at that position) the default choice."
  54   (interactive)
  55   (run-hooks 'menu-bar-update-hook)
  56   ;; Obey menu-bar-final-items; put those items last.
  57   (let ((menu-bar '())
  58         (menu-end '())
  59         menu-bar-item)
  60     (map-keymap
  61      (lambda (key binding)
  62        (push (cons key binding)
  63              ;; If KEY is the name of an item that we want to put last,
  64              ;; move it to the end.
  65              (if (memq key menu-bar-final-items)
  66                  menu-end
  67                menu-bar)))
  68      (tmm-get-keybind [menu-bar]))
  69     (setq menu-bar `(keymap ,@(nreverse menu-bar) ,@(nreverse menu-end)))
  70     (if x-position
  71         (let ((column 0))
  72           (catch 'done
  73             (map-keymap
  74              (lambda (key binding)
  75                (when (> column x-position)
  76                  (setq menu-bar-item key)
  77                  (throw 'done nil))
  78                (pcase binding
  79                  ((or `(,(and (pred stringp) name) . ,_) ;Simple menu item.
  80                       `(menu-item ,name ,_cmd            ;Extended menu item.
  81                         . ,(and props
  82                                 (guard (let ((visible
  83                                               (plist-get props :visible)))
  84                                          (or (null visible)
  85                                              (eval visible)))))))
  86                   (setq column (+ column (length name) 1)))))
  87              menu-bar))))
  88     (tmm-prompt menu-bar nil menu-bar-item)))
  89
  90 ;;;###autoload
  91 (defun tmm-menubar-mouse (event)
  92   "Text-mode emulation of looking and choosing from a menubar.
  93 This command is used when you click the mouse in the menubar
  94 on a console which has no window system but does have a mouse.
  95 See the documentation for `tmm-prompt'."
  96   (interactive "e")
  97   (tmm-menubar (car (posn-x-y (event-start event)))))
  98
  99 (defcustom tmm-mid-prompt "==>"
 100   "String to insert between shortcut and menu item.
 101 If nil, there will be no shortcuts.  It should not consist only of spaces,
 102 or else the correct item might not be found in the `*Completions*' buffer."
 103   :type 'string
 104   :group 'tmm)
 105
 106 (defvar tmm-mb-map nil
 107   "A place to store minibuffer map.")
 108
 109 (defcustom tmm-completion-prompt
 110   "Press PageUp key to reach this buffer from the minibuffer.
 111 Alternatively, you can use Up/Down keys (or your History keys) to change
 112 the item in the minibuffer, and press RET when you are done, or press the
 113 marked letters to pick up your choice.  Type C-g or ESC ESC ESC to cancel.
 114 "
 115   "Help text to insert on the top of the completion buffer.
 116 To save space, you can set this to nil,
 117 in which case the standard introduction text is deleted too."
 118   :type '(choice string (const nil))
 119   :group 'tmm)
 120
 121 (defcustom tmm-shortcut-style '(downcase upcase)
 122   "What letters to use as menu shortcuts.
 123 Must be either one of the symbols `downcase' or `upcase',
 124 or else a list of the two in the order you prefer."
 125   :type '(choice (const downcase)
 126                  (const upcase)
 127                  (repeat (choice (const downcase) (const upcase))))
 128   :group 'tmm)
 129
 130 (defcustom tmm-shortcut-words 2
 131   "How many successive words to try for shortcuts, nil means all.
 132 If you use only one of `downcase' or `upcase' for `tmm-shortcut-style',
 133 specify nil for this variable."
 134   :type '(choice integer (const nil))
 135   :group 'tmm)
 136
 137 (defface tmm-inactive
 138   '((t :inherit shadow))
 139   "Face used for inactive menu items."
 140   :group 'tmm)
 141
 142 (defun tmm--completion-table (items)
 143   (lambda (string pred action)
 144     (if (eq action 'metadata)
 145         '(metadata (display-sort-function . identity))
 146       (complete-with-action action items string pred))))
 147
 148 ;;;###autoload
 149 (defun tmm-prompt (menu &optional in-popup default-item)
 150   "Text-mode emulation of calling the bindings in keymap.
 151 Creates a text-mode menu of possible choices.  You can access the elements
 152 in the menu in two ways:
 153    *)  via history mechanism from minibuffer;
 154    *)  Or via completion-buffer that is automatically shown.
 155 The last alternative is currently a hack, you cannot use mouse reliably.
 156
 157 MENU is like the MENU argument to `x-popup-menu': either a
 158 keymap or an alist of alists.
 159 DEFAULT-ITEM, if non-nil, specifies an initial default choice.
 160 Its value should be an event that has a binding in MENU."
 161   ;; If the optional argument IN-POPUP is t,
 162   ;; then MENU is an alist of elements of the form (STRING . VALUE).
 163   ;; That is used for recursive calls only.
 164   (let ((gl-str "Menu bar")  ;; The menu bar itself is not a menu keymap
 165                                         ; so it doesn't have a name.
 166         tmm-km-list out history history-len tmm-table-undef tmm-c-prompt
 167         tmm-old-mb-map tmm-short-cuts
 168         chosen-string choice
 169         (not-menu (not (keymapp menu))))
 170     (run-hooks 'activate-menubar-hook)
 171     ;; Compute tmm-km-list from MENU.
 172     ;; tmm-km-list is an alist of (STRING . MEANING).
 173     ;; It has no other elements.
 174     ;; The order of elements in tmm-km-list is the order of the menu bar.
 175     (if (not not-menu)
 176         (map-keymap (lambda (k v) (tmm-get-keymap (cons k v))) menu)
 177       (dolist (elt menu)
 178         (cond
 179          ((stringp elt) (setq gl-str elt))
 180          ((listp elt) (tmm-get-keymap elt not-menu))
 181          ((vectorp elt)
 182           (dotimes (i (length elt))
 183             (tmm-get-keymap (cons i (aref elt i)) not-menu))))))
 184     (setq tmm-km-list (nreverse tmm-km-list))
 185     ;; Choose an element of tmm-km-list; put it in choice.
 186     (if (and not-menu (= 1 (length tmm-km-list)))
 187         ;; If this is the top-level of an x-popup-menu menu,
 188         ;; and there is just one pane, choose that one silently.
 189         ;; This way we only ask the user one question,
 190         ;; for which element of that pane.
 191         (setq choice (cdr (car tmm-km-list)))
 192       (unless tmm-km-list
 193         (error "Empty menu reached"))
 194       (and tmm-km-list
 195            (let ((index-of-default 0))
 196              (if tmm-mid-prompt
 197                  (setq tmm-km-list (tmm-add-shortcuts tmm-km-list))
 198                t)
 199              ;; Find the default item's index within the menu bar.
 200              ;; We use this to decide the initial minibuffer contents
 201              ;; and initial history position.
 202              (if default-item
 203                  (let ((tail menu) visible)
 204                    (while (and tail
 205                                (not (eq (car-safe (car tail)) default-item)))
 206                      ;; Be careful to count only the elements of MENU
 207                      ;; that actually constitute menu bar items.
 208                      (if (and (consp (car tail))
 209                               (or (stringp (car-safe (cdr (car tail))))
 210                                   (and
 211                                    (eq (car-safe (cdr (car tail))) 'menu-item)
 212                                    (progn
 213                                      (setq visible
 214                                            (plist-get
 215                                             (nthcdr 4 (car tail)) :visible))
 216                                      (or (not visible) (eval visible))))))
 217                          (setq index-of-default (1+ index-of-default)))
 218                      (setq tail (cdr tail)))))
 219              (let ((prompt (concat "^." (regexp-quote tmm-mid-prompt))))
 220                (setq history
 221                      (reverse (delq nil
 222                                     (mapcar
 223                                      (lambda (elt)
 224                                        (if (string-match prompt (car elt))
 225                                            (car elt)))
 226                                      tmm-km-list)))))
 227              (setq history-len (length history))
 228              (setq history (append history history history history))
 229              (setq tmm-c-prompt (nth (- history-len 1 index-of-default) history))
 230              (setq out
 231                    (if default-item
 232                        (car (nth index-of-default tmm-km-list))
 233                      (minibuffer-with-setup-hook #'tmm-add-prompt
 234                        (completing-read
 235                         (concat gl-str
 236                                 " (up/down to change, PgUp to menu): ")
 237                         (tmm--completion-table tmm-km-list) nil t nil
 238                         (cons 'history
 239                               (- (* 2 history-len) index-of-default))))))))
 240       (setq choice (cdr (assoc out tmm-km-list)))
 241       (and (null choice)
 242            (string-prefix-p tmm-c-prompt out)
 243            (setq out (substring out (length tmm-c-prompt))
 244                  choice (cdr (assoc out tmm-km-list))))
 245       (and (null choice) out
 246            (setq out (try-completion out tmm-km-list)
 247                  choice (cdr (assoc  out tmm-km-list)))))
 248     ;; CHOICE is now (STRING . MEANING).  Separate the two parts.
 249     (setq chosen-string (car choice))
 250     (setq choice (cdr choice))
 251     (cond (in-popup
 252            ;; We just did the inner level of a -popup menu.
 253            choice)
 254           ;; We just did the outer level.  Do the inner level now.
 255           (not-menu (tmm-prompt choice t))
 256           ;; We just handled a menu keymap and found another keymap.
 257           ((keymapp choice)
 258            (if (symbolp choice)
 259                (setq choice (indirect-function choice)))
 260            (condition-case nil
 261                (require 'mouse)
 262              (error nil))
 263            (tmm-prompt choice))
 264           ;; We just handled a menu keymap and found a command.
 265           (choice
 266            (if chosen-string
 267                (progn
 268                  (setq last-command-event chosen-string)
 269                  (call-interactively choice))
 270              choice)))))
 271
 272 (defun tmm-add-shortcuts (list)
 273   "Add shortcuts to cars of elements of the list.
 274 Takes a list of lists with a string as car, returns list with
 275 shortcuts added to these cars.
 276 Stores a list of all the shortcuts in the free variable `tmm-short-cuts'."
 277   (let ((tmm-next-shortcut-digit ?0))
 278     (mapcar 'tmm-add-one-shortcut (reverse list))))
 279
 280 (defsubst tmm-add-one-shortcut (elt)
 281 ;; uses the free vars tmm-next-shortcut-digit and tmm-short-cuts
 282   (cond
 283    ((eq (cddr elt) 'ignore)
 284     (cons (concat " " (make-string (length tmm-mid-prompt) ?\-)
 285                   (car elt))
 286           (cdr elt)))
 287    (t
 288     (let* ((str (car elt))
 289            (paren (string-match "(" str))
 290            (pos 0) (word 0) char)
 291       (catch 'done                             ; ??? is this slow?
 292         (while (and (or (not tmm-shortcut-words)   ; no limit on words
 293                         (< word tmm-shortcut-words)) ; try n words
 294                     (setq pos (string-match "\\w+" str pos)) ; get next word
 295                     (not (and paren (> pos paren)))) ; don't go past "(binding.."
 296           (if (or (= pos 0)
 297                   (/= (aref str (1- pos)) ?.)) ; avoid file extensions
 298               (let ((shortcut-style
 299                      (if (listp tmm-shortcut-style) ; convert to list
 300                          tmm-shortcut-style
 301                        (list tmm-shortcut-style))))
 302                 (while shortcut-style ; try upcase and downcase variants
 303                   (setq char (funcall (car shortcut-style) (aref str pos)))
 304                   (if (not (memq char tmm-short-cuts)) (throw 'done char))
 305                   (setq shortcut-style (cdr shortcut-style)))))
 306           (setq word (1+ word))
 307           (setq pos (match-end 0)))
 308         (while (<= tmm-next-shortcut-digit ?9) ; no letter shortcut, pick a digit
 309           (setq char tmm-next-shortcut-digit)
 310           (setq tmm-next-shortcut-digit (1+ tmm-next-shortcut-digit))
 311           (if (not (memq char tmm-short-cuts)) (throw 'done char)))
 312         (setq char nil))
 313       (if char (setq tmm-short-cuts (cons char tmm-short-cuts)))
 314       (cons (concat (if char (concat (char-to-string char) tmm-mid-prompt)
 315                       ;; keep them lined up in columns
 316                       (make-string (1+ (length tmm-mid-prompt)) ?\s))
 317                     str)
 318             (cdr elt))))))
 319
 320 ;; This returns the old map.
 321 (defun tmm-define-keys (minibuffer)
 322   (let ((map (make-sparse-keymap)))
 323     (suppress-keymap map t)
 324     (dolist (c tmm-short-cuts)
 325       (if (listp tmm-shortcut-style)
 326           (define-key map (char-to-string c) 'tmm-shortcut)
 327         ;; only one kind of letters are shortcuts, so map both upcase and
 328         ;; downcase input to the same
 329         (define-key map (char-to-string (downcase c)) 'tmm-shortcut)
 330         (define-key map (char-to-string (upcase c)) 'tmm-shortcut)))
 331     (if minibuffer
 332         (progn
 333           (define-key map [pageup] 'tmm-goto-completions)
 334           (define-key map [prior] 'tmm-goto-completions)
 335           (define-key map "\ev" 'tmm-goto-completions)
 336           (define-key map "\C-n" 'next-history-element)
 337           (define-key map "\C-p" 'previous-history-element)))
 338     (prog1 (current-local-map)
 339       (use-local-map (append map (current-local-map))))))
 340
 341 (defun tmm-completion-delete-prompt ()
 342   (with-current-buffer standard-output
 343   (goto-char (point-min))
 344     (delete-region (point) (search-forward "Possible completions are:\n"))))
 345
 346 (defun tmm-remove-inactive-mouse-face ()
 347   "Remove the mouse-face property from inactive menu items."
 348   (let ((inhibit-read-only t)
 349         (inactive-string
 350          (concat " " (make-string (length tmm-mid-prompt) ?\-)))
 351         next)
 352     (save-excursion
 353       (goto-char (point-min))
 354       (while (not (eobp))
 355         (setq next (next-single-char-property-change (point) 'mouse-face))
 356         (when (looking-at inactive-string)
 357           (remove-text-properties (point) next '(mouse-face))
 358           (add-text-properties (point) next '(face tmm-inactive)))
 359         (goto-char next)))
 360     (set-buffer-modified-p nil)))
 361
 362 (defun tmm-add-prompt ()
 363   (unless tmm-c-prompt
 364     (error "No active menu entries"))
 365   (setq tmm-old-mb-map (tmm-define-keys t))
 366   ;; Get window and hide it for electric mode to get correct size
 367   (or tmm-completion-prompt
 368       (add-hook 'completion-setup-hook
 369                 'tmm-completion-delete-prompt 'append))
 370   (unwind-protect
 371       (minibuffer-completion-help)
 372     (remove-hook 'completion-setup-hook 'tmm-completion-delete-prompt))
 373   (with-current-buffer "*Completions*"
 374     (tmm-remove-inactive-mouse-face)
 375     (when tmm-completion-prompt
 376       (let ((inhibit-read-only t))
 377         (goto-char (point-min))
 378         (insert tmm-completion-prompt))))
 379   (insert tmm-c-prompt))
 380
 381 (defun tmm-shortcut ()
 382   "Choose the shortcut that the user typed."
 383   (interactive)
 384   (let ((c last-command-event) s)
 385     (if (symbolp tmm-shortcut-style)
 386         (setq c (funcall tmm-shortcut-style c)))
 387     (if (memq c tmm-short-cuts)
 388         (if (equal (buffer-name) "*Completions*")
 389             (progn
 390               (goto-char (point-min))
 391               (re-search-forward
 392                (concat "\\(^\\|[ \t]\\)" (char-to-string c) tmm-mid-prompt))
 393               (choose-completion))
 394           ;; In minibuffer
 395           (delete-region (minibuffer-prompt-end) (point-max))
 396           (dolist (elt tmm-km-list)
 397             (if (string=
 398                  (substring (car elt) 0
 399                             (min (1+ (length tmm-mid-prompt))
 400                                  (length (car elt))))
 401                  (concat (char-to-string c) tmm-mid-prompt))
 402                 (setq s (car elt))))
 403           (insert s)
 404           (exit-minibuffer)))))
 405
 406 (defun tmm-goto-completions ()
 407   "Jump to the completions buffer."
 408   (interactive)
 409   (let ((prompt-end (minibuffer-prompt-end)))
 410     (setq tmm-c-prompt (buffer-substring prompt-end (point-max)))
 411     ;; FIXME: Why?
 412     (delete-region prompt-end (point-max)))
 413   (switch-to-buffer-other-window "*Completions*")
 414   (search-forward tmm-c-prompt)
 415   (search-backward tmm-c-prompt))
 416
 417 (defun tmm-get-keymap (elt &optional in-x-menu)
 418   "Prepend (DOCSTRING EVENT BINDING) to free variable `tmm-km-list'.
 419 The values are deduced from the argument ELT, that should be an
 420 element of keymap, an `x-popup-menu' argument, or an element of
 421 `x-popup-menu' argument (when IN-X-MENU is not-nil).
 422 This function adds the element only if it is not already present.
 423 It uses the free variable `tmm-table-undef' to keep undefined keys."
 424   (let (km str plist filter visible enable (event (car elt)))
 425     (setq elt (cdr elt))
 426     (if (eq elt 'undefined)
 427         (setq tmm-table-undef (cons (cons event nil) tmm-table-undef))
 428       (unless (assoc event tmm-table-undef)
 429         (cond ((if (listp elt)
 430                    (or (keymapp elt) (eq (car elt) 'lambda))
 431                  (and (symbolp elt) (fboundp elt)))
 432                (setq km elt))
 433
 434               ((if (listp (cdr-safe elt))
 435                    (or (keymapp (cdr-safe elt))
 436                        (eq (car (cdr-safe elt)) 'lambda))
 437                  (and (symbolp (cdr-safe elt)) (fboundp (cdr-safe elt))))
 438                (setq km (cdr elt))
 439                (and (stringp (car elt)) (setq str (car elt))))
 440
 441               ((if (listp (cdr-safe (cdr-safe elt)))
 442                    (or (keymapp (cdr-safe (cdr-safe elt)))
 443                        (eq (car (cdr-safe (cdr-safe elt))) 'lambda))
 444                  (and (symbolp (cdr-safe (cdr-safe elt)))
 445                       (fboundp (cdr-safe (cdr-safe elt)))))
 446                (setq km (cddr elt))
 447                (and (stringp (car elt)) (setq str (car elt))))
 448
 449               ((eq (car-safe elt) 'menu-item)
 450                ;; (menu-item TITLE COMMAND KEY ...)
 451                (setq plist (cdr-safe (cdr-safe (cdr-safe elt))))
 452                (when (consp (car-safe plist))
 453                  (setq plist (cdr-safe plist)))
 454                (setq km (nth 2 elt))
 455                (setq str (eval (nth 1 elt)))
 456                (setq filter (plist-get plist :filter))
 457                (if filter
 458                    (setq km (funcall filter km)))
 459                (setq visible (plist-get plist :visible))
 460                (if visible
 461                    (setq km (and (eval visible) km)))
 462                (setq enable (plist-get plist :enable))
 463                (if enable
 464                    (setq km (if (eval enable) km 'ignore))))
 465
 466               ((if (listp (cdr-safe (cdr-safe (cdr-safe elt))))
 467                    (or (keymapp (cdr-safe (cdr-safe (cdr-safe elt))))
 468                        (eq (car (cdr-safe (cdr-safe (cdr-safe elt)))) 'lambda))
 469                  (and (symbolp (cdr-safe (cdr-safe (cdr-safe elt))))
 470                       (fboundp (cdr-safe (cdr-safe (cdr-safe elt))))))
 471                                         ; New style of easy-menu
 472                (setq km (cdr (cddr elt)))
 473                (and (stringp (car elt)) (setq str (car elt))))
 474
 475               ((stringp event)          ; x-popup or x-popup element
 476                (setq str event)
 477                (setq event nil)
 478                (setq km (if (or in-x-menu (stringp (car-safe elt)))
 479                             elt (cons 'keymap elt)))))
 480         (unless (or (eq km 'ignore) (null str))
 481           (let ((binding (where-is-internal km nil t)))
 482             (when binding
 483               (setq binding (key-description binding))
 484               ;; Try to align the keybindings.
 485               (let ((colwidth (min 30 (- (/ (window-width) 2) 10))))
 486                 (setq str
 487                       (concat str
 488                               (make-string (max 2 (- colwidth
 489                                                      (string-width str)
 490                                                      (string-width binding)))
 491                                            ?\s)
 492                               binding)))))))
 493       (and km (stringp km) (setq str km))
 494       ;; Verify that the command is enabled;
 495       ;; if not, don't mention it.
 496       (when (and km (symbolp km) (get km 'menu-enable))
 497           (setq km (if (eval (get km 'menu-enable)) km 'ignore)))
 498       (and km str
 499            (or (assoc str tmm-km-list)
 500                (push (cons str (cons event km)) tmm-km-list))))))
 501
 502 (defun tmm-get-keybind (keyseq)
 503   "Return the current binding of KEYSEQ, merging prefix definitions.
 504 If KEYSEQ is a prefix key that has local and global bindings,
 505 we merge them into a single keymap which shows the proper order of the menu.
 506 However, for the menu bar itself, the value does not take account
 507 of `menu-bar-final-items'."
 508   (lookup-key (cons 'keymap (nreverse (current-active-maps))) keyseq))
 509
 510 (provide 'tmm)
 511
 512 ;;; tmm.el ends here