configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003, 2004,
   8 dnl    2005, 2006, 2007, 2008, 2009, 2010
   9 dnl    Free Software Foundation, Inc.
  10 dnl
  11 dnl  This file is part of GNU Emacs.
  12 dnl
  13 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  14 dnl  it under the terms of the GNU General Public License as published by
  15 dnl  the Free Software Foundation, either version 3 of the License, or
  16 dnl  (at your option) any later version.
  17 dnl
  18 dnl  GNU Emacs is distributed in the hope that it will be useful,
  19 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 dnl  GNU General Public License for more details.
  22 dnl
  23 dnl  You should have received a copy of the GNU General Public License
  24 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 AC_PREREQ(2.65)
  27 AC_INIT(emacs, 24.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  41 '${datadir}/emacs/site-lisp'
  42 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  43 etcdir='${datadir}/emacs/${version}/etc'
  44 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  45 docdir='${datadir}/emacs/${version}/etc'
  46 gamedir='${localstatedir}/games/emacs'
  47
  48 gameuser=games
  49
  50 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  51 dnl Create a new --with option that defaults to being disabled.
  52 dnl NAME is the base name of the option.  The shell variable with_NAME
  53 dnl   will be set to either the user's value (if the option is
  54 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  55 dnl   option is not specified).  Note that the shell variable name is
  56 dnl   constructed as autoconf does, by replacing non-alphanumeric
  57 dnl   characters with "_".
  58 dnl HELP-STRING is the help text for the option.
  59 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  60   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  61     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  62 ])dnl
  63
  64 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  65 dnl Create a new --with option that defaults to being enabled.  NAME
  66 dnl   is the base name of the option.  The shell variable with_NAME
  67 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  68 dnl   'yes' (if the option is not specified).  Note that the shell
  69 dnl   variable name is constructed as autoconf does, by replacing
  70 dnl   non-alphanumeric characters with "_".
  71 dnl HELP-STRING is the help text for the option.
  72 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  73   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  74    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  75 ])dnl
  76
  77 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  78 if test "$with_pop" = yes; then
  79    AC_DEFINE(MAIL_USE_POP)
  80 fi
  81 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  82
  83 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  84 if test "$with_kerberos" != no; then
  85    AC_DEFINE(KERBEROS)
  86 fi
  87 AH_TEMPLATE(KERBEROS,
  88             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  89
  90 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  91 if test "${with_kerberos5}" != no; then
  92   if test "${with_kerberos}" = no; then
  93     with_kerberos=yes
  94     AC_DEFINE(KERBEROS)
  95   fi
  96   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  97 fi
  98
  99 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 100 dnl FIXME hesiod support may not be present, so it seems like an error
 101 dnl to define, or at least use, this unconditionally.
 102 if test "$with_hesiod" != no; then
 103   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 104 fi
 105
 106 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 107 if test "$with_mmdf" != no; then
 108    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 109 fi
 110
 111 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 112 if test "$with_mail_unlink" != no; then
 113    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 114 fi
 115
 116 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 117     [string giving default POP mail host])],
 118     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 119
 120 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 121
 122 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 123 if test "$with_sync_input" = yes; then
 124    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 125 fi
 126
 127 dnl FIXME currently it is not the last.
 128 dnl This should be the last --with option, because --with-x is
 129 dnl added later on when we find the path of X, and it's best to
 130 dnl keep them together visually.
 131 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 132  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 133 [         case "${withval}" in
 134             y | ye | yes )      val=gtk ;;
 135             n | no )            val=no  ;;
 136             l | lu | luc | luci | lucid )       val=lucid ;;
 137             a | at | ath | athe | athen | athena )      val=athena ;;
 138             m | mo | mot | moti | motif )       val=motif ;;
 139             g | gt | gtk  )     val=gtk ;;
 140             gtk3  )     val=gtk3 ;;
 141             * )
 142 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 143 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 144 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 145             ;;
 146           esac
 147           with_x_toolkit=$val
 148 ])
 149
 150 dnl _ON results in a '--without' option in the --help output, so
 151 dnl the help text should refer to "don't compile", etc.
 152 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 153 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 154 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 155 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 156 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 157 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 158
 159 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 160 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 161 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 162
 163 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 164 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 165 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 166 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 167
 168 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 169 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 170 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 171 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 172
 173 ## For the times when you want to build Emacs but don't have
 174 ## a suitable makeinfo, and can live without the manuals.
 175 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 176 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 177
 178 ## This is an option because I do not know if all info/man support
 179 ## compressed files, nor how to test if they do so.
 180 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 181 if test $with_compress_info = yes; then
 182    GZIP_INFO=yes
 183 else
 184    GZIP_INFO=
 185 fi
 186 AC_SUBST(GZIP_INFO)
 187
 188 AC_ARG_WITH([pkg-config-prog],dnl
 189 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 190                   [path to pkg-config for finding GTK and librsvg])])
 191 if test "X${with_pkg_config_prog}" != X; then
 192    if test "${with_pkg_config_prog}" != yes; then
 193       PKG_CONFIG="${with_pkg_config_prog}"
 194    fi
 195 fi
 196
 197 CRT_DIR=
 198 AC_ARG_WITH([crt-dir],dnl
 199 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 200 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 201 CRT_DIR="${with_crt_dir}"
 202
 203 AC_ARG_WITH([gnustep-conf],dnl
 204 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 205 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 206   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 207 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 208      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 209
 210 AC_ARG_ENABLE(ns-self-contained,
 211 [AS_HELP_STRING([--disable-ns-self-contained],
 212                 [disable self contained build under NeXTstep])],
 213    EN_NS_SELF_CONTAINED=$enableval,
 214    EN_NS_SELF_CONTAINED=yes)
 215
 216 AC_ARG_ENABLE(asserts,
 217 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 218       USE_XASSERTS=$enableval,
 219       USE_XASSERTS=no)
 220
 221 AC_ARG_ENABLE(maintainer-mode,
 222 [AS_HELP_STRING([--enable-maintainer-mode],
 223                 [enable make rules and dependencies not useful (and sometimes
 224                  confusing) to the casual installer])],
 225       USE_MAINTAINER_MODE=$enableval,
 226       USE_MAINTAINER_MODE=no)
 227 if test $USE_MAINTAINER_MODE = yes; then
 228   MAINT=
 229 else
 230   MAINT=#
 231 fi
 232 AC_SUBST(MAINT)
 233
 234 AC_ARG_ENABLE(locallisppath,
 235 [AS_HELP_STRING([--enable-locallisppath=PATH],
 236                 [directories Emacs should search for lisp files specific
 237                  to this site])],
 238 if test "${enableval}" = "no"; then
 239   locallisppath=
 240 elif test "${enableval}" != "yes"; then
 241   locallisppath=${enableval}
 242 fi)
 243
 244 AC_ARG_ENABLE(checking,
 245 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 246                 [enable expensive run-time checks.  With LIST,
 247                  enable only specific categories of checks.
 248                  Categories are: all,yes,no.
 249                  Flags are: stringbytes, stringoverrun, stringfreelist,
 250                  xmallocoverrun, conslist])],
 251 [ac_checking_flags="${enableval}"],[])
 252 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 253 for check in $ac_checking_flags
 254 do
 255         case $check in
 256         # these set all the flags to specific states
 257         yes)            ac_enable_checking=1 ;;
 258         no)             ac_enable_checking= ;
 259                         ac_gc_check_stringbytes= ;
 260                         ac_gc_check_string_overrun= ;
 261                         ac_gc_check_string_free_list= ;
 262                         ac_xmalloc_overrun= ;
 263                         ac_gc_check_cons_list= ;;
 264         all)            ac_enable_checking=1 ;
 265                         ac_gc_check_stringbytes=1 ;
 266                         ac_gc_check_string_overrun=1 ;
 267                         ac_gc_check_string_free_list=1 ;
 268                         ac_xmalloc_overrun=1 ;
 269                         ac_gc_check_cons_list=1 ;;
 270         # these enable particular checks
 271         stringbytes)    ac_gc_check_stringbytes=1 ;;
 272         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 273         stringfreelist) ac_gc_check_string_free_list=1 ;;
 274         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 275         conslist)       ac_gc_check_cons_list=1 ;;
 276         *)      AC_MSG_ERROR(unknown check category $check) ;;
 277         esac
 278 done
 279 IFS="$ac_save_IFS"
 280
 281 if test x$ac_enable_checking != x ; then
 282   AC_DEFINE(ENABLE_CHECKING, 1,
 283 [Enable expensive run-time checking of data types?])
 284 fi
 285 if test x$ac_gc_check_stringbytes != x ; then
 286   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 287 [Define this temporarily to hunt a bug.  If defined, the size of
 288    strings is redundantly recorded in sdata structures so that it can
 289    be compared to the sizes recorded in Lisp strings.])
 290 fi
 291 if test x$ac_gc_check_stringoverrun != x ; then
 292   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 293 [Define this to check for short string overrun.])
 294 fi
 295 if test x$ac_gc_check_string_free_list != x ; then
 296   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 297 [Define this to check the string free list.])
 298 fi
 299 if test x$ac_xmalloc_overrun != x ; then
 300   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 301 [Define this to check for malloc buffer overrun.])
 302 fi
 303 if test x$ac_gc_check_cons_list != x ; then
 304   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 305 [Define this to check for errors in cons list.])
 306 fi
 307
 308 AC_ARG_ENABLE(profiling,
 309 [AS_HELP_STRING([--enable-profiling],
 310                 [build emacs with profiling support.
 311                  This might not work on all platforms])],
 312 [ac_enable_profiling="${enableval}"],[])
 313 if test x$ac_enable_profiling != x ; then
 314    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 315    PROFILING_LDFLAGS="-pg"
 316 else
 317    PROFILING_CFLAGS=
 318    PROFILING_LDFLAGS=
 319 fi
 320
 321 AC_ARG_ENABLE(autodepend,
 322 [AS_HELP_STRING([--enable-autodepend],
 323                 [automatically generate dependencies to .h-files.
 324                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 325                  found])],
 326 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 327
 328 #### Make srcdir absolute, if it isn't already.  It's important to
 329 #### avoid running the path through pwd unnecessarily, since pwd can
 330 #### give you automounter prefixes, which can go away.  We do all this
 331 #### so Emacs can find its files when run uninstalled.
 332 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 333 unset CDPATH
 334 case "${srcdir}" in
 335   /* ) ;;
 336   . )
 337     ## We may be able to use the $PWD environment variable to make this
 338     ## absolute.  But sometimes PWD is inaccurate.
 339     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 340     ## but that tested only for a well-formed and valid PWD,
 341     ## it did not object when PWD was well-formed and valid but just wrong.
 342     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 343     then
 344       srcdir="$PWD"
 345     else
 346       srcdir="`(cd ${srcdir}; pwd)`"
 347     fi
 348   ;;
 349   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 350 esac
 351
 352 #### Check if the source directory already has a configured system in it.
 353 if test `pwd` != `(cd ${srcdir} && pwd)` \
 354    && test -f "${srcdir}/src/config.h" ; then
 355   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 356    as a build directory right now; it has been configured in its own
 357    right.  To configure in another directory as well, you MUST
 358    use GNU make.  If you do not have GNU make, then you must
 359    now do `make distclean' in ${srcdir},
 360    and then run $0 again.]])
 361 fi
 362
 363 #### Given the configuration name, set machfile and opsysfile to the
 364 #### names of the m/*.h and s/*.h files we should use.
 365
 366 ### Canonicalize the configuration name.
 367
 368 AC_CANONICAL_HOST
 369 canonical=$host
 370 configuration=${host_alias-${build_alias-$host}}
 371
 372 dnl This used to use changequote, but, apart from `changequote is evil'
 373 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 374 dnl the great gob of text.  Thus it's not processed for possible expansion.
 375 dnl Just make sure the brackets remain balanced.
 376 dnl
 377 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 378 dnl indicated by comments.
 379 dnl quotation begins
 380 [
 381
 382 ### If you add support for a new configuration, add code to this
 383 ### switch statement to recognize your configuration name and select
 384 ### the appropriate operating system and machine description files.
 385
 386 ### You would hope that you could choose an m/*.h file pretty much
 387 ### based on the machine portion of the configuration name, and an s/*.h
 388 ### file based on the operating system portion.  However, it turns out
 389 ### that each m/*.h file is pretty manufacturer-specific - for
 390 ### example mips.h is MIPS
 391 ### So we basically have to have a special case for each
 392 ### configuration name.
 393 ###
 394 ### As far as handling version numbers on operating systems is
 395 ### concerned, make sure things will fail in a fixable way.  If
 396 ### /etc/MACHINES doesn't say anything about version numbers, be
 397 ### prepared to handle anything reasonably.  If version numbers
 398 ### matter, be sure /etc/MACHINES says something about it.
 399
 400 machine='' opsys='' unported=no
 401 case "${canonical}" in
 402
 403   ## FreeBSD ports
 404   *-*-freebsd* )
 405     opsys=freebsd
 406     case "${canonical}" in
 407       alpha*)           machine=alpha ;;
 408       amd64-*|x86_64-*) machine=amdx86-64 ;;
 409       arm*)             machine=arm ;;
 410       ia64-*)           machine=ia64 ;;
 411       i[3456]86-*)      machine=intel386 ;;
 412       powerpc-*)        machine=macppc ;;
 413       sparc-*)          machine=sparc ;;
 414       sparc64-*)        machine=sparc ;;
 415     esac
 416   ;;
 417
 418   ## FreeBSD kernel + glibc based userland
 419   *-*-kfreebsd*gnu* )
 420     opsys=gnu-kfreebsd
 421     case "${canonical}" in
 422       alpha*)           machine=alpha ;;
 423       amd64-*|x86_64-*) machine=amdx86-64 ;;
 424       ia64-*)           machine=ia64 ;;
 425       i[3456]86-*)      machine=intel386 ;;
 426       powerpc-*)        machine=macppc ;;
 427       sparc-*)          machine=sparc ;;
 428       sparc64-*)        machine=sparc ;;
 429     esac
 430   ;;
 431
 432   ## NetBSD ports
 433   *-*-netbsd* )
 434     opsys=netbsd
 435     case "${canonical}" in
 436       alpha*)      machine=alpha ;;
 437       x86_64-*)    machine=amdx86-64 ;;
 438       arm-*)       machine=arm ;;
 439       hppa-*)      machine=hp800 ;;
 440       i[3456]86-*) machine=intel386 ;;
 441       m68k-*)      machine=m68k ;;
 442       powerpc-*)   machine=macppc ;;
 443       mips-*)      machine=mips ;;
 444       mipse[bl]-*) machine=mips ;;
 445       sparc*-)     machine=sparc ;;
 446       vax-*)       machine=vax ;;
 447     esac
 448   ;;
 449
 450   ## OpenBSD ports
 451   *-*-openbsd* )
 452     opsys=openbsd
 453     case "${canonical}" in
 454       alpha*)    machine=alpha ;;
 455       x86_64-*)  machine=amdx86-64 ;;
 456       arm-*)     machine=arm ;;
 457       hppa-*)    machine=hp800 ;;
 458       i386-*)    machine=intel386 ;;
 459       powerpc-*) machine=macppc ;;
 460       sparc*)    machine=sparc ;;
 461       vax-*)     machine=vax ;;
 462     esac
 463   ;;
 464
 465   alpha*-*-linux-gnu* )
 466     machine=alpha opsys=gnu-linux
 467   ;;
 468
 469   arm*-*-linux-gnu* )
 470     machine=arm opsys=gnu-linux
 471   ;;
 472
 473   ## Apple Darwin / Mac OS X
 474   *-apple-darwin* )
 475     case "${canonical}" in
 476       i[3456]86-* )  machine=intel386 ;;
 477       powerpc-* )    machine=macppc ;;
 478       x86_64-* )     machine=amdx86-64 ;;
 479       * )            unported=yes ;;
 480     esac
 481     opsys=darwin
 482     # Define CPP as follows to make autoconf work correctly.
 483     CPP="${CC-cc} -E -no-cpp-precomp"
 484     # Use fink packages if available.
 485     if test -d /sw/include && test -d /sw/lib; then
 486       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 487       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 488       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 489     fi
 490   ;;
 491
 492   ## HP 9000 series 700 and 800, running HP/UX
 493   hppa*-hp-hpux10.2* )
 494     machine=hp800 opsys=hpux10-20
 495   ;;
 496   hppa*-hp-hpux1[1-9]* )
 497     machine=hp800 opsys=hpux11
 498     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 499   ;;
 500
 501   hppa*-*-linux-gnu* )
 502     machine=hp800 opsys=gnu-linux
 503   ;;
 504
 505   ## IBM machines
 506   s390-*-linux-gnu* )
 507     machine=ibms390 opsys=gnu-linux
 508   ;;
 509   s390x-*-linux-gnu* )
 510     machine=ibms390x opsys=gnu-linux
 511   ;;
 512   rs6000-ibm-aix4.[23]* )
 513     machine=ibmrs6000 opsys=aix4-2
 514   ;;
 515   powerpc-ibm-aix4.[23]*  )
 516     machine=ibmrs6000 opsys=aix4-2
 517   ;;
 518   rs6000-ibm-aix[56]* )
 519     machine=ibmrs6000 opsys=aix4-2
 520   ;;
 521   powerpc-ibm-aix[56]*  )
 522     machine=ibmrs6000 opsys=aix4-2
 523   ;;
 524
 525   ## Macintosh PowerPC
 526   powerpc*-*-linux-gnu* )
 527     machine=macppc opsys=gnu-linux
 528   ;;
 529
 530   ## Silicon Graphics machines
 531   ## Iris 4D
 532   mips-sgi-irix6.5 )
 533     machine=iris4d opsys=irix6-5
 534     # Without defining _LANGUAGE_C, things get masked out in the headers
 535     # so that, for instance, grepping for `free' in stdlib.h fails and
 536     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 537     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 538     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 539   ;;
 540
 541   ## Suns
 542   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 543     machine=sparc opsys=gnu-linux
 544   ;;
 545
 546   *-sun-solaris* \
 547     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 548     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 549     case "${canonical}" in
 550       i[3456]86-*-* )     machine=intel386 ;;
 551       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 552       sparc* )          machine=sparc ;;
 553       * )               unported=yes ;;
 554     esac
 555     case "${canonical}" in
 556       *-sunos5.6* | *-solaris2.6* )
 557                 opsys=sol2-6
 558                 NON_GNU_CPP=/usr/ccs/lib/cpp
 559                 RANLIB="ar -ts"
 560                 ;;
 561       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 562                 opsys=sol2-6
 563                 emacs_check_sunpro_c=yes
 564                 NON_GNU_CPP=/usr/ccs/lib/cpp
 565                 ;;
 566       *-sunos5* | *-solaris* )
 567                 opsys=sol2-10
 568                 emacs_check_sunpro_c=yes
 569                 NON_GNU_CPP=/usr/ccs/lib/cpp
 570                 ;;
 571     esac
 572     ## Watch out for a compiler that we know will not work.
 573     case "${canonical}" in
 574      *-solaris* | *-sunos5* )
 575                 if [ "x$CC" = x/usr/ucb/cc ]; then
 576                   ## /usr/ucb/cc doesn't work;
 577                   ## we should find some other compiler that does work.
 578                   unset CC
 579                 fi
 580                 ;;
 581       *) ;;
 582     esac
 583   ;;
 584
 585   ## IA-64
 586   ia64*-*-linux* )
 587     machine=ia64 opsys=gnu-linux
 588   ;;
 589
 590   ## Intel 386 machines where we don't care about the manufacturer.
 591   i[3456]86-*-* )
 592     machine=intel386
 593     case "${canonical}" in
 594       *-cygwin )                opsys=cygwin ;;
 595       *-darwin* )               opsys=darwin
 596                                 CPP="${CC-cc} -E -no-cpp-precomp"
 597                                 ;;
 598       *-linux-gnu* )            opsys=gnu-linux ;;
 599       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 600       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 601       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 602       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 603     esac
 604   ;;
 605
 606   ## m68k Linux-based GNU system
 607   m68k-*-linux-gnu* )
 608     machine=m68k opsys=gnu-linux
 609   ;;
 610
 611   ## Mips Linux-based GNU system
 612   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 613     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 614     machine=mips opsys=gnu-linux
 615   ;;
 616
 617   ## AMD x86-64 Linux-based GNU system
 618   x86_64-*-linux-gnu* )
 619     machine=amdx86-64 opsys=gnu-linux
 620   ;;
 621
 622   ## Tensilica Xtensa Linux-based GNU system
 623   xtensa*-*-linux-gnu* )
 624     machine=xtensa opsys=gnu-linux
 625     ;;
 626
 627   ## SuperH Linux-based GNU system
 628   sh[34]*-*-linux-gnu* )
 629     machine=sh3 opsys=gnu-linux
 630   ;;
 631
 632   * )
 633     unported=yes
 634   ;;
 635 esac
 636
 637 ### If the code above didn't choose an operating system, just choose
 638 ### an operating system based on the configuration name.  You really
 639 ### only want to use this when you have no idea what the right
 640 ### operating system is; if you know what operating systems a machine
 641 ### runs, it's cleaner to make it explicit in the case statement
 642 ### above.
 643 if test x"${opsys}" = x; then
 644   case "${canonical}" in
 645     *-gnu* )                            opsys=gnu ;;
 646     * )
 647       unported=yes
 648     ;;
 649   esac
 650 fi
 651
 652 ]
 653 dnl quotation ends
 654
 655 if test $unported = yes; then
 656   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 657 Check `etc/MACHINES' for recognized configuration names.])
 658 fi
 659
 660 machfile="m/${machine}.h"
 661 opsysfile="s/${opsys}.h"
 662
 663
 664 #### Choose a compiler.
 665 test -n "$CC" && cc_specified=yes
 666
 667 # Save the value of CFLAGS that the user specified.
 668 SPECIFIED_CFLAGS="$CFLAGS"
 669
 670 dnl Sets GCC=yes if using gcc.
 671 AC_PROG_CC
 672
 673 # On Suns, sometimes $CPP names a directory.
 674 if test -n "$CPP" && test -d "$CPP"; then
 675   CPP=
 676 fi
 677
 678 ## If not using gcc, and on Solaris, and no CPP specified, see if
 679 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 680 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 681  test x"$CPP" = x; then
 682   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 683   AC_CACHE_VAL(emacs_cv_sunpro_c,
 684   [AC_TRY_LINK([],
 685 [#ifndef __SUNPRO_C
 686 fail;
 687 #endif
 688 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 689   AC_MSG_RESULT($emacs_cv_sunpro_c)
 690
 691   if test x"$emacs_cv_sunpro_c" = xyes; then
 692     NON_GNU_CPP="$CC -E -Xs"
 693   fi
 694 fi
 695
 696 #### Some systems specify a CPP to use unless we are using GCC.
 697 #### Now that we know whether we are using GCC, we can decide whether
 698 #### to use that one.
 699 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 700 then
 701   CPP="$NON_GNU_CPP"
 702 fi
 703
 704 #### Some systems specify a CC to use unless we are using GCC.
 705 #### Now that we know whether we are using GCC, we can decide whether
 706 #### to use that one.
 707 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 708   test x$cc_specified != xyes
 709 then
 710   CC="$NON_GNU_CC"
 711 fi
 712
 713 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 714 then
 715   CC="$CC $GCC_TEST_OPTIONS"
 716 fi
 717
 718 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 719 then
 720   CC="$CC $NON_GCC_TEST_OPTIONS"
 721 fi
 722
 723 dnl checks for Unix variants
 724 AC_USE_SYSTEM_EXTENSIONS
 725
 726 ### Use -Wno-pointer-sign if the compiler supports it
 727 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 728 SAVE_CFLAGS="$CFLAGS"
 729 CFLAGS="$CFLAGS -Wno-pointer-sign"
 730 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 731 if test $has_option = yes; then
 732    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 733 fi
 734 AC_MSG_RESULT($has_option)
 735 CFLAGS="$SAVE_CFLAGS"
 736 unset has_option
 737 unset SAVE_CFLAGS
 738
 739 ### Use -Wdeclaration-after-statement if the compiler supports it
 740 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 741 SAVE_CFLAGS="$CFLAGS"
 742 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 743 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 744 if test $has_option = yes; then
 745    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 746 fi
 747 AC_MSG_RESULT($has_option)
 748 CFLAGS="$SAVE_CFLAGS"
 749 unset has_option
 750 unset SAVE_CFLAGS
 751
 752 #### Some other nice autoconf tests.
 753
 754 dnl checks for programs
 755 AC_PROG_CPP
 756 AC_PROG_INSTALL
 757 if test "x$RANLIB" = x; then
 758   AC_PROG_RANLIB
 759 fi
 760
 761 ## Although we're running on an amd64 kernel, we're actually compiling for
 762 ## the x86 architecture.  The user should probably have provided an
 763 ## explicit --build to `configure', but if everything else than the kernel
 764 ## is running in i386 mode, we can help them out.
 765 if test "$machine" = "amdx86-64"; then
 766   AC_CHECK_DECL([i386])
 767   if test "$ac_cv_have_decl_i386" = "yes"; then
 768     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 769     machine=intel386
 770     machfile="m/${machine}.h"
 771   fi
 772 fi
 773
 774 AC_PATH_PROG(INSTALL_INFO, install-info)
 775 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 776 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 777 dnl Don't use GZIP, which is used by gzip for additional parameters.
 778 AC_PATH_PROG(GZIP_PROG, gzip)
 779
 780
 781 ## Need makeinfo >= 4.6 (?) to build the manuals.
 782 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 783 dnl By this stage, configure has already checked for egrep and set EGREP,
 784 dnl or exited with an error if no egrep was found.
 785 if test "$MAKEINFO" != "no" && \
 786   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 787    MAKEINFO=no
 788 fi
 789
 790 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 791 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 792 ## therefore in the category of "special tools" not normally required, which
 793 ## configure does not have to check for (eg autoconf itself).
 794 ## In a Bazaar checkout on the other hand, the manuals are not included.
 795 ## So makeinfo is a requirement to build from Bazaar, and configure
 796 ## should test for it as it does for any other build requirement.
 797 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 798 ## with pre-built manuals, from a Bazaar checkout.
 799 if test "$MAKEINFO" = "no"; then
 800   if test "x${with_makeinfo}" = "xno"; then
 801     MAKEINFO=off
 802   elif test ! -e $srcdir/info/emacs; then
 803     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 804 source tree does not seem to have pre-built manuals in the `info' directory.
 805 Either install a suitable version of makeinfo, or re-run configure
 806 with the `--without-makeinfo' option to build without the manuals.] )
 807   fi
 808 fi
 809
 810 dnl Add our options to ac_link now, after it is set up.
 811
 812 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 813 then
 814   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 815 fi
 816
 817 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 818 then
 819   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 820 fi
 821
 822 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 823 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 824 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 825 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 826 dnl if not built to support GNU ld.
 827
 828 late_LDFLAGS=$LDFLAGS
 829 if test "$GCC" = yes; then
 830   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 831 else
 832   LDFLAGS="$LDFLAGS -znocombreloc"
 833 fi
 834
 835 AC_MSG_CHECKING([for -znocombreloc])
 836 AC_LINK_IFELSE([main(){return 0;}],
 837   [AC_MSG_RESULT(yes)],
 838   LDFLAGS=$late_LDFLAGS
 839   [AC_MSG_RESULT(no)])
 840
 841 #### Extract some information from the operating system and machine files.
 842
 843 AC_CHECKING([the machine- and system-dependent files to find out
 844  - which libraries the lib-src programs will want, and
 845  - whether the GNU malloc routines are usable])
 846
 847 ### First figure out CFLAGS (which we use for running the compiler here)
 848 ### and REAL_CFLAGS (which we use for real compilation).
 849 ### The two are the same except on a few systems, where they are made
 850 ### different to work around various lossages.  For example,
 851 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 852 ### as implying static linking.
 853
 854 ### If the CFLAGS env var is specified, we use that value
 855 ### instead of the default.
 856
 857 ### It's not important that this name contain the PID; you can't run
 858 ### two configures in the same directory and have anything work
 859 ### anyway.
 860 tempcname="conftest.c"
 861
 862 echo '
 863 #include "'${srcdir}'/src/'${opsysfile}'"
 864 #include "'${srcdir}'/src/'${machfile}'"
 865
 866 configure___ LIBX=-lX11
 867
 868 #ifdef CANNOT_DUMP
 869 configure___ cannot_dump=yes
 870 #else
 871 configure___ cannot_dump=no
 872 #endif
 873
 874 #ifdef SYSTEM_MALLOC
 875 configure___ system_malloc=yes
 876 #else
 877 configure___ system_malloc=no
 878 #endif
 879
 880 #ifdef USE_MMAP_FOR_BUFFERS
 881 configure___ use_mmap_for_buffers=yes
 882 #else
 883 configure___ use_mmap_for_buffers=no
 884 #endif
 885
 886 #ifndef C_OPTIMIZE_SWITCH
 887 #ifdef __GNUC__
 888 #define C_OPTIMIZE_SWITCH -O2
 889 #else
 890 #define C_OPTIMIZE_SWITCH -O
 891 #endif
 892 #endif
 893
 894 #ifndef C_WARNINGS_SWITCH
 895 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 896 #endif
 897
 898 #ifdef THIS_IS_CONFIGURE
 899
 900 /* Get the CFLAGS for tests in configure.  */
 901 #ifdef __GNUC__
 902 configure___ CFLAGS=-g C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 903 #else
 904 configure___ CFLAGS='${SPECIFIED_CFLAGS}'
 905 #endif
 906
 907 #else /* not THIS_IS_CONFIGURE */
 908
 909 /* Get the CFLAGS for real compilation.  */
 910 #ifdef __GNUC__
 911 configure___ REAL_CFLAGS=-g C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH ${PROFILING_CFLAGS} '${SPECIFIED_CFLAGS}'
 912 #else
 913 configure___ REAL_CFLAGS='${SPECIFIED_CFLAGS}'
 914 #endif
 915
 916 #endif /* not THIS_IS_CONFIGURE */
 917 ' > ${tempcname}
 918
 919 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 920
 921 # The value of CPP is a quoted variable reference, so we need to do this
 922 # to get its actual value...
 923 CPP=`eval "echo $CPP"`
 924 [eval `${CPP} -Isrc ${tempcname} \
 925        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 926 if test "x$SPECIFIED_CFLAGS" = x; then
 927   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 928          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 929 else
 930   REAL_CFLAGS="$CFLAGS"
 931 fi]
 932 rm ${tempcname}
 933
 934
 935 AC_SUBST(cannot_dump)
 936
 937 UNEXEC_OBJ=unexelf.o
 938 case "$opsys" in
 939   aix4-2)
 940    UNEXEC_OBJ=unexaix.o
 941    ;;
 942   cygwin)
 943    UNEXEC_OBJ=unexcw.o
 944    ;;
 945   darwin)
 946    UNEXEC_OBJ=unexmacosx.o
 947    ;;
 948   hpux10-20 | hpux11)
 949    UNEXEC_OBJ=unexhp9k800.o
 950    ;;
 951   sol2-10)
 952    # Use the Solaris dldump() function, called from unexsol.c, to dump
 953    # emacs, instead of the generic ELF dump code found in unexelf.c.
 954    # The resulting binary has a complete symbol table, and is better
 955    # for debugging and other observability tools (debuggers, pstack, etc).
 956    #
 957    # If you encounter a problem using dldump(), please consider sending
 958    # a message to the OpenSolaris tools-linking mailing list:
 959    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 960    #
 961    # It is likely that dldump() works with older Solaris too, but this has
 962    # not been tested, so for now this change is for Solaris 10 or newer.
 963    UNEXEC_OBJ=unexsol.o
 964    ;;
 965 esac
 966
 967 LD_SWITCH_SYSTEM=
 968 case "$opsys" in
 969   freebsd)
 970    ## Let `ld' find image libs and similar things in /usr/local/lib.
 971    ## The system compiler, GCC, has apparently been modified to not
 972    ## look there, contrary to what a stock GCC would do.
 973    LD_SWITCH_SYSTEM=-L/usr/local/lib
 974    ;;
 975
 976   gnu-linux)
 977    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 978    test "$machine" = "mips" && LD_SWITCH_SYSTEM="-G 0"
 979    ;;
 980
 981   netbsd)
 982    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 983    ;;
 984
 985   openbsd)
 986    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 987    ## otherwise Emacs dumps core on elf systems.
 988    LD_SWITCH_SYSTEM="-Z"
 989    ;;
 990 esac
 991 AC_SUBST(LD_SWITCH_SYSTEM)
 992
 993 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 994
 995 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 996 ## which has not been defined yet.  When this was handled with cpp,
 997 ## it was expanded to null when configure sourced the s/*.h file.
 998 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 999 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1000 ## (or somesuch), but because it is supposed to go at the _front_
1001 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1002 ## Compare with the gnu-linux case below, which added to the end
1003 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1004 ## LD_SWITCH_SYSTEM_TEMACS.
1005 case "$opsys" in
1006   netbsd|openbsd)
1007    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
1008    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
1009 esac
1010
1011
1012 C_SWITCH_MACHINE=
1013 if test "$machine" = "alpha"; then
1014   AC_CHECK_DECL([__ELF__])
1015   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1016     ## With ELF, make sure that all common symbols get allocated to in the
1017     ## data section.  Otherwise, the dump of temacs may miss variables in
1018     ## the shared library that have been initialized.  For example, with
1019     ## GNU libc, __malloc_initialized would normally be resolved to the
1020     ## shared library's .bss section, which is fatal.
1021     if test "x$GCC" = "xyes"; then
1022       C_SWITCH_MACHINE="-fno-common"
1023     else
1024       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
1025     fi
1026   else
1027     UNEXEC_OBJ=unexalpha.o
1028   fi
1029 fi
1030 AC_SUBST(C_SWITCH_MACHINE)
1031
1032 AC_SUBST(UNEXEC_OBJ)
1033
1034 C_SWITCH_SYSTEM=
1035 ## Some programs in src produce warnings saying certain subprograms
1036 ## are too complex and need a MAXMEM value greater than 2000 for
1037 ## additional optimization.  --nils@exp-math.uni-essen.de
1038 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1039   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1040 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1041 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1042 AC_SUBST(C_SWITCH_SYSTEM)
1043
1044
1045 LIBS_SYSTEM=
1046 case "$opsys" in
1047   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1048   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1049
1050   freebsd) LIBS_SYSTEM="-lutil" ;;
1051
1052   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1053
1054   sol2*) LIBS_SYSTEM="-lsocket -lnsl -lkstat" ;;
1055
1056   ## Motif needs -lgen.
1057   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1058 esac
1059 AC_SUBST(LIBS_SYSTEM)
1060
1061
1062 ### Make sure subsequent tests use flags consistent with the build flags.
1063
1064 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1065   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1066 else
1067   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1068 fi
1069
1070 dnl For AC_FUNC_GETLOADAVG, at least:
1071 AC_CONFIG_LIBOBJ_DIR(src)
1072
1073 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1074 AC_SYS_LARGEFILE
1075
1076
1077 ## If user specified a crt-dir, use that unconditionally.
1078 if test "X$CRT_DIR" = "X"; then
1079
1080   case "$canonical" in
1081     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1082     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1083     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1084     ## For anything else (eg /usr/lib32), it is up the user to specify
1085     ## the location (bug#5655).
1086     ## Test for crtn.o, not just the directory, because sometimes the
1087     ## directory exists but does not have the relevant files (bug#1287).
1088     ## FIXME better to test for binary compatibility somehow.
1089     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1090     ;;
1091
1092     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1093   esac
1094
1095   case "$opsys" in
1096     hpux10-20) CRT_DIR=/lib ;;
1097   esac
1098
1099   ## Default is /usr/lib.
1100   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1101
1102 else
1103
1104   ## Some platforms don't use any of these files, so it is not
1105   ## appropriate to put this test outside the if block.
1106   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1107     AC_MSG_ERROR([crt*.o not found in specified location.])
1108
1109 fi
1110
1111 AC_SUBST(CRT_DIR)
1112
1113 LIB_MATH=-lm
1114 LIB_STANDARD=
1115 START_FILES=
1116
1117 case $opsys in
1118   cygwin )
1119     LIB_MATH=
1120     START_FILES='ecrt0.o'
1121     ;;
1122   darwin )
1123     ## Adding -lm confuses the dynamic linker, so omit it.
1124     LIB_MATH=
1125     START_FILES='pre-crt0.o'
1126     ;;
1127   freebsd )
1128     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1129     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1130     ;;
1131   gnu-linux | gnu-kfreebsd )
1132     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1133     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1134     ;;
1135   hpux10-20 | hpux11 )
1136     LIB_STANDARD=-lc
1137     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1138     ;;
1139   netbsd | openbsd )
1140     if test -f $CRT_DIR/crti.o; then
1141         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1142         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1143     else
1144         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1145         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1146     fi
1147     ;;
1148 esac
1149
1150 AC_SUBST(LIB_MATH)
1151 AC_SUBST(START_FILES)
1152
1153 dnl This function definition taken from Gnome 2.0
1154 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1155 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1156 dnl also defines GSTUFF_PKG_ERRORS on error
1157 AC_DEFUN([PKG_CHECK_MODULES], [
1158   succeeded=no
1159
1160   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1161
1162   if test "$PKG_CONFIG" = "no" ; then
1163      ifelse([$4], , [AC_MSG_ERROR([
1164       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1165   else
1166      PKG_CONFIG_MIN_VERSION=0.9.0
1167      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1168         AC_MSG_CHECKING(for $2)
1169
1170         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1171             AC_MSG_RESULT(yes)
1172             succeeded=yes
1173
1174             AC_MSG_CHECKING($1_CFLAGS)
1175             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1176             AC_MSG_RESULT($$1_CFLAGS)
1177
1178             AC_MSG_CHECKING($1_LIBS)
1179             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1180             AC_MSG_RESULT($$1_LIBS)
1181         else
1182             AC_MSG_RESULT(no)
1183             $1_CFLAGS=""
1184             $1_LIBS=""
1185             ## If we have a custom action on failure, don't print errors, but
1186             ## do set a variable so people can do so.
1187             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1188             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1189         fi
1190
1191         AC_SUBST($1_CFLAGS)
1192         AC_SUBST($1_LIBS)
1193      else
1194         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1195         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1196      fi
1197   fi
1198
1199   if test $succeeded = yes; then
1200      ifelse([$3], , :, [$3])
1201   else
1202      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1203   fi
1204 ])
1205
1206
1207 if test "${with_sound}" != "no"; then
1208   # Sound support for GNU/Linux and the free BSDs.
1209   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1210   # Emulation library used on NetBSD.
1211   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1212   AC_SUBST(LIBSOUND)
1213
1214   ALSA_REQUIRED=1.0.0
1215   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1216   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1217   if test $HAVE_ALSA = yes; then
1218     SAVE_CFLAGS="$CFLAGS"
1219     SAVE_LDFLAGS="$LDFLAGS"
1220     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1221     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1222     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1223                     emacs_alsa_normal=yes,
1224                     emacs_alsa_normal=no)
1225     if test "$emacs_alsa_normal" != yes; then
1226       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1227                      [snd_lib_error_set_handler (0);],
1228                      emacs_alsa_subdir=yes,
1229                      emacs_alsa_subdir=no)
1230       if test "$emacs_alsa_subdir" != yes; then
1231         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1232       fi
1233       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1234     fi
1235
1236     CFLAGS="$SAVE_CFLAGS"
1237     LDFLAGS="$SAVE_LDFLAGS"
1238     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1239     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1240     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1241   fi
1242   AC_SUBST(CFLAGS_SOUND)
1243 fi
1244
1245 dnl checks for header files
1246 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1247   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1248   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1249   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1250   sys/utsname.h pwd.h utmp.h)
1251
1252 AC_MSG_CHECKING(if personality LINUX32 can be set)
1253 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1254                emacs_cv_personality_linux32=yes,
1255                emacs_cv_personality_linux32=no)
1256 AC_MSG_RESULT($emacs_cv_personality_linux32)
1257
1258 if test $emacs_cv_personality_linux32 = yes; then
1259   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1260             [Define to 1 if personality LINUX32 can be set.])
1261 fi
1262
1263 dnl On Solaris 8 there's a compilation warning for term.h because
1264 dnl it doesn't define `bool'.
1265 AC_CHECK_HEADERS(term.h, , , -)
1266 AC_HEADER_STDC
1267 AC_HEADER_TIME
1268 AC_CHECK_DECLS([sys_siglist])
1269 if test $ac_cv_have_decl_sys_siglist != yes; then
1270   # For Tru64, at least:
1271   AC_CHECK_DECLS([__sys_siglist])
1272   if test $ac_cv_have_decl___sys_siglist = yes; then
1273     AC_DEFINE(sys_siglist, __sys_siglist,
1274               [Define to any substitute for sys_siglist.])
1275   fi
1276 fi
1277 AC_HEADER_SYS_WAIT
1278
1279 dnl Some systems have utime.h but don't declare the struct anyplace.
1280 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1281 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1282 #include <sys/time.h>
1283 #include <time.h>
1284 #else
1285 #ifdef HAVE_SYS_TIME_H
1286 #include <sys/time.h>
1287 #else
1288 #include <time.h>
1289 #endif
1290 #endif
1291 #ifdef HAVE_UTIME_H
1292 #include <utime.h>
1293 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1294   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1295 if test $emacs_cv_struct_utimbuf = yes; then
1296   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1297 fi
1298
1299 dnl checks for typedefs
1300 AC_TYPE_SIGNAL
1301
1302 dnl Check for speed_t typedef.
1303 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1304   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1305     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1306 if test $emacs_cv_speed_t = yes; then
1307   AC_DEFINE(HAVE_SPEED_T, 1,
1308            [Define to 1 if `speed_t' is declared by <termios.h>.])
1309 fi
1310
1311 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1312 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1313 #include <sys/time.h>
1314 #include <time.h>
1315 #else
1316 #ifdef HAVE_SYS_TIME_H
1317 #include <sys/time.h>
1318 #else
1319 #include <time.h>
1320 #endif
1321 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1322   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1323 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1324 if test $emacs_cv_struct_timeval = yes; then
1325   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1326 fi
1327
1328 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1329 AC_TRY_COMPILE([#include <math.h>],
1330 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1331   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1332 HAVE_EXCEPTION=$emacs_cv_struct_exception
1333 if test $emacs_cv_struct_exception != yes; then
1334   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1335 fi
1336
1337 AC_CHECK_HEADERS(sys/socket.h)
1338 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1339 #if HAVE_SYS_SOCKET_H
1340 #include <sys/socket.h>
1341 #endif])
1342
1343 dnl checks for structure members
1344 AC_STRUCT_TM
1345 AC_STRUCT_TIMEZONE
1346 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1347                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1348                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1349                 [#include <time.h>])
1350 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1351                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1352                   struct ifreq.ifr_addr], , ,
1353                  [AC_INCLUDES_DEFAULT
1354 #if HAVE_SYS_SOCKET_H
1355 #include <sys/socket.h>
1356 #endif
1357 #if HAVE_NET_IF_H
1358 #include <net/if.h>
1359 #endif])
1360
1361 dnl checks for compiler characteristics
1362
1363 dnl Testing __STDC__ to determine prototype support isn't good enough.
1364 dnl DEC C, for instance, doesn't define it with default options, and
1365 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1366 dnl and void *.
1367 AC_C_PROTOTYPES
1368 AC_C_VOLATILE
1369 AC_C_CONST
1370 dnl This isn't useful because we can't turn on use of `inline' unless
1371 dnl the compiler groks `extern inline'.
1372 dnl AC_C_INLINE
1373 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1374   [AC_TRY_COMPILE(, [void * foo;],
1375                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1376 if test $emacs_cv_void_star = yes; then
1377   AC_DEFINE(POINTER_TYPE, void)
1378 else
1379   AC_DEFINE(POINTER_TYPE, char)
1380 fi
1381 AH_TEMPLATE(POINTER_TYPE,
1382             [Define as `void' if your compiler accepts `void *'; otherwise
1383              define as `char'.])dnl
1384
1385
1386
1387 dnl This could be used for targets which can have both byte sexes.
1388 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1389 dnl AC_C_BIGENDIAN
1390
1391 dnl check for Make feature
1392 AC_PROG_MAKE_SET
1393
1394 DEPFLAGS=
1395 MKDEPDIR=":"
1396 deps_frag=deps.mk
1397 dnl check for GNU Make if we have GCC and autodepend is on.
1398 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1399    AC_MSG_CHECKING([whether we are using GNU Make])
1400    HAVE_GNU_MAKE=no
1401    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1402    if test "x$testval" != x; then
1403       HAVE_GNU_MAKE=yes
1404    else
1405       ac_enable_autodepend=no
1406    fi
1407    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1408    if test $HAVE_GNU_MAKE = yes; then
1409       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1410       SAVE_CFLAGS="$CFLAGS"
1411       CFLAGS="$CFLAGS -MMD -MF deps.d"
1412       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1413       CFLAGS="$SAVE_CFLAGS"
1414       test -f deps.d || ac_enable_autodepend=no
1415       rm -rf deps.d
1416       AC_MSG_RESULT([$ac_enable_autodepend])
1417    fi
1418    if test $ac_enable_autodepend = yes; then
1419       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1420       ## In parallel builds, another make might create depdir between
1421       ## the first test and mkdir, so stick another test on the end.
1422       ## Or use mkinstalldirs?  mkdir -p is not portable.
1423       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1424       deps_frag=autodeps.mk
1425    fi
1426 fi
1427 deps_frag=$srcdir/src/$deps_frag
1428 AC_SUBST(MKDEPDIR)
1429 AC_SUBST(DEPFLAGS)
1430 AC_SUBST_FILE(deps_frag)
1431
1432
1433 dnl checks for operating system services
1434 AC_SYS_LONG_FILE_NAMES
1435
1436 #### Choose a window system.
1437
1438 AC_PATH_X
1439 if test "$no_x" = yes; then
1440   window_system=none
1441 else
1442   window_system=x11
1443 fi
1444
1445 ## Workaround for bug in autoconf <= 2.62.
1446 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1447 ## No need to do anything special for these standard directories.
1448 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1449
1450    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1451
1452 fi
1453
1454 LD_SWITCH_X_SITE_AUX=
1455 LD_SWITCH_X_SITE_AUX_RPATH=
1456 if test "${x_libraries}" != NONE; then
1457   if test -n "${x_libraries}"; then
1458     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1459     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1460     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1461   fi
1462   x_default_search_path=""
1463   x_search_path=${x_libraries}
1464   if test -z "${x_search_path}"; then
1465     x_search_path=/usr/lib
1466   fi
1467   for x_library in `echo ${x_search_path}: | \
1468                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1469     x_search_path="\
1470 ${x_library}/X11/%L/%T/%N%C%S:\
1471 ${x_library}/X11/%l/%T/%N%C%S:\
1472 ${x_library}/X11/%T/%N%C%S:\
1473 ${x_library}/X11/%L/%T/%N%S:\
1474 ${x_library}/X11/%l/%T/%N%S:\
1475 ${x_library}/X11/%T/%N%S"
1476     if test x"${x_default_search_path}" = x; then
1477       x_default_search_path=${x_search_path}
1478     else
1479       x_default_search_path="${x_search_path}:${x_default_search_path}"
1480     fi
1481   done
1482 fi
1483 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1484 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1485
1486 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1487   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1488 fi
1489
1490 if test x"${x_includes}" = x; then
1491   bitmapdir=/usr/include/X11/bitmaps
1492 else
1493   # accumulate include directories that have X11 bitmap subdirectories
1494   bmd_acc="dummyval"
1495   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1496     if test -d "${bmd}/X11/bitmaps"; then
1497       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1498     fi
1499     if test -d "${bmd}/bitmaps"; then
1500       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1501     fi
1502   done
1503   if test ${bmd_acc} != "dummyval"; then
1504     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1505   fi
1506 fi
1507
1508 HAVE_NS=no
1509 NS_IMPL_COCOA=no
1510 NS_IMPL_GNUSTEP=no
1511 tmp_CPPFLAGS="$CPPFLAGS"
1512 tmp_CFLAGS="$CFLAGS"
1513 CPPFLAGS="$CPPFLAGS -x objective-c"
1514 CFLAGS="$CFLAGS -x objective-c"
1515 TEMACS_LDFLAGS2="\${LDFLAGS}"
1516 dnl I don't think it's especially important, but src/Makefile.in
1517 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1518 dnl trailing "/" to it, so now we do it here.
1519 if test "${with_ns}" != no; then
1520   if test "${opsys}" = darwin; then
1521      NS_IMPL_COCOA=yes
1522      ns_appdir=`pwd`/nextstep/Emacs.app/
1523      ns_appbindir=${ns_appdir}Contents/MacOS/
1524      ns_appresdir=${ns_appdir}Contents/Resources
1525      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1526   elif test -f $GNUSTEP_CONFIG_FILE; then
1527      NS_IMPL_GNUSTEP=yes
1528      ns_appdir=`pwd`/nextstep/Emacs.app/
1529      ns_appbindir=${ns_appdir}
1530      ns_appresdir=${ns_appdir}Resources
1531      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1532      dnl FIXME sourcing this several times in subshells seems inefficient.
1533      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1534      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1535      dnl I seemed to need these as well with GNUstep-startup 0.25.
1536      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1537      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1538      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1539        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1540      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1541        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1542      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1543      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1544      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1545      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1546      LIB_STANDARD=
1547      START_FILES=
1548      TEMACS_LDFLAGS2=
1549   fi
1550   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1551                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1552   files are missing or cannot be compiled.])])
1553   NS_HAVE_NSINTEGER=yes
1554   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1555                                      [NSInteger i;])],
1556                     ns_have_nsinteger=yes,
1557                     ns_have_nsinteger=no)
1558   if test $ns_have_nsinteger = no; then
1559     NS_HAVE_NSINTEGER=no
1560   fi
1561 fi
1562 AC_SUBST(TEMACS_LDFLAGS2)
1563
1564 ns_frag=/dev/null
1565 NS_OBJ=
1566 NS_SUPPORT=
1567 if test "${HAVE_NS}" = yes; then
1568   window_system=nextstep
1569   with_xft=no
1570   # set up packaging dirs
1571   exec_prefix=${ns_appbindir}
1572   libexecdir=${ns_appbindir}/libexec
1573   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1574      prefix=${ns_appresdir}
1575   fi
1576   ns_frag=$srcdir/src/ns.mk
1577   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1578   NS_SUPPORT="\${lispsource}emacs-lisp/easymenu.elc \${lispsource}term/ns-win.elc"
1579 fi
1580 CFLAGS="$tmp_CFLAGS"
1581 CPPFLAGS="$tmp_CPPFLAGS"
1582 AC_SUBST(NS_OBJ)
1583 AC_SUBST(NS_SUPPORT)
1584 AC_SUBST(LIB_STANDARD)
1585 AC_SUBST_FILE(ns_frag)
1586
1587 case "${window_system}" in
1588   x11 )
1589     HAVE_X_WINDOWS=yes
1590     HAVE_X11=yes
1591     case "${with_x_toolkit}" in
1592       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1593       motif ) USE_X_TOOLKIT=MOTIF ;;
1594       gtk ) with_gtk=yes
1595 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1596 dnl USE_X_TOOLKIT is set.
1597             USE_X_TOOLKIT=none ;;
1598       gtk3 ) with_gtk3=yes
1599              USE_X_TOOLKIT=none ;;
1600       no ) USE_X_TOOLKIT=none ;;
1601 dnl If user did not say whether to use a toolkit, make this decision later:
1602 dnl use the toolkit if we have gtk, or X11R5 or newer.
1603       * ) USE_X_TOOLKIT=maybe ;;
1604     esac
1605   ;;
1606   nextstep | none )
1607     HAVE_X_WINDOWS=no
1608     HAVE_X11=no
1609     USE_X_TOOLKIT=none
1610   ;;
1611 esac
1612
1613 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1614    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1615    if test "$HAVE_XSERVER" = true ||
1616       test -n "$DISPLAY" ||
1617       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1618         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1619 were found.  You should install the relevant development files for X
1620 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1621 sure you have development files for image handling, i.e.
1622 tiff, gif, jpeg, png and xpm.
1623 If you are sure you want Emacs compiled without X window support, pass
1624   --without-x
1625 to configure.])
1626    fi
1627 fi
1628
1629 ### If we're using X11, we should use the X menu package.
1630 HAVE_MENUS=no
1631 case ${HAVE_X11} in
1632   yes ) HAVE_MENUS=yes ;;
1633 esac
1634
1635 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1636 # Assume not, until told otherwise.
1637 GNU_MALLOC=yes
1638 doug_lea_malloc=yes
1639 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1640 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1641 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1642                emacs_cv_var___after_morecore_hook,
1643 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1644   emacs_cv_var___after_morecore_hook=yes,
1645   emacs_cv_var___after_morecore_hook=no)])
1646 if test $emacs_cv_var___after_morecore_hook = no; then
1647   doug_lea_malloc=no
1648 fi
1649
1650 if test "${system_malloc}" = "yes"; then
1651   GNU_MALLOC=no
1652   GNU_MALLOC_reason="
1653     (The GNU allocators don't work with this system configuration.)"
1654   GMALLOC_OBJ=
1655   VMLIMIT_OBJ=
1656 else
1657   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1658   VMLIMIT_OBJ=vm-limit.o
1659 fi
1660 AC_SUBST(GMALLOC_OBJ)
1661 AC_SUBST(VMLIMIT_OBJ)
1662
1663 if test "$doug_lea_malloc" = "yes" ; then
1664   if test "$GNU_MALLOC" = yes ; then
1665     GNU_MALLOC_reason="
1666       (Using Doug Lea's new malloc from the GNU C Library.)"
1667   fi
1668   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1669             [Define to 1 if you are using the GNU C Library.])
1670
1671   ## Use mmap directly for allocating larger buffers.
1672   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1673   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1674   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1675   case "$opsys" in
1676     gnu*) REL_ALLOC=no ;;
1677   esac
1678 fi
1679
1680 if test x"${REL_ALLOC}" = x; then
1681   REL_ALLOC=${GNU_MALLOC}
1682 fi
1683
1684 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1685 dnl the system configuration file (s/*.h) to turn the use of mmap
1686 dnl in the relocating allocator on.
1687
1688 AC_FUNC_MMAP
1689 if test $use_mmap_for_buffers = yes; then
1690   REL_ALLOC=no
1691 fi
1692
1693 LIBS="$LIBS_SYSTEM $LIBS"
1694
1695 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1696 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1697 AC_CHECK_LIB(dnet, dnet_ntoa)
1698 dnl This causes -lresolv to get used in subsequent tests,
1699 dnl which causes failures on some systems such as HPUX 9.
1700 dnl AC_CHECK_LIB(resolv, gethostbyname)
1701
1702 dnl FIXME replace main with a function we actually want from this library.
1703 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1704
1705 AC_CHECK_LIB(pthreads, cma_open)
1706
1707 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1708 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1709 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1710 ## added to LIBS in configure would never contain the pthreads part,
1711 ## but the value used in Makefiles might.  FIXME?
1712 ##
1713 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1714 ## be harmless on older versions of X where it happens to exist.
1715 test "$opsys" = "aix4-2" && \
1716   test $ac_cv_lib_pthreads_cma_open = yes && \
1717   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1718
1719 dnl Check for need for bigtoc support on IBM AIX
1720
1721 case ${host_os} in
1722 aix*)
1723   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1724     case $GCC in
1725     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1726     *) gdb_cv_bigtoc=-bbigtoc ;;
1727     esac
1728
1729     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1730     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1731   ])
1732   ;;
1733 esac
1734
1735 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1736 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1737 # REAL_CPPFLAGS later on.
1738
1739 REAL_CPPFLAGS="$CPPFLAGS"
1740
1741 if test "${HAVE_X11}" = "yes"; then
1742   DEFS="$C_SWITCH_X_SITE $DEFS"
1743   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1744   LIBS="$LIBX $LIBS"
1745   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1746   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1747
1748   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1749   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1750   # but it's more convenient here to set LD_RUN_PATH
1751   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1752   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1753     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1754     export LD_RUN_PATH
1755   fi
1756
1757   if test "${opsys}" = "gnu-linux"; then
1758     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1759     AC_TRY_LINK([],
1760      [XOpenDisplay ("foo");],
1761      [xlinux_first_failure=no],
1762      [xlinux_first_failure=yes])
1763     if test "${xlinux_first_failure}" = "yes"; then
1764       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1765       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1766       OLD_CPPFLAGS="$CPPFLAGS"
1767       OLD_LIBS="$LIBS"
1768       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1769       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1770       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1771       LIBS="$LIBS -b i486-linuxaout"
1772       AC_TRY_LINK([],
1773        [XOpenDisplay ("foo");],
1774        [xlinux_second_failure=no],
1775        [xlinux_second_failure=yes])
1776       if test "${xlinux_second_failure}" = "yes"; then
1777         # If we get the same failure with -b, there is no use adding -b.
1778         # So take it out.  This plays safe.
1779         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1780         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1781         CPPFLAGS="$OLD_CPPFLAGS"
1782         LIBS="$OLD_LIBS"
1783         AC_MSG_RESULT(no)
1784       else
1785         AC_MSG_RESULT(yes)
1786       fi
1787     else
1788       AC_MSG_RESULT(no)
1789     fi
1790   fi
1791
1792   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1793   # header files included from there.
1794   AC_MSG_CHECKING(for Xkb)
1795   AC_TRY_LINK([#include <X11/Xlib.h>
1796 #include <X11/XKBlib.h>],
1797         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1798         emacs_xkb=yes, emacs_xkb=no)
1799   AC_MSG_RESULT($emacs_xkb)
1800   if test $emacs_xkb = yes; then
1801     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1802   fi
1803
1804   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1805 XScreenNumberOfScreen XSetWMProtocols)
1806 fi
1807
1808 if test "${window_system}" = "x11"; then
1809   AC_MSG_CHECKING(X11 version 6)
1810   AC_CACHE_VAL(emacs_cv_x11_version_6,
1811   [AC_TRY_LINK([#include <X11/Xlib.h>],
1812 [#if XlibSpecificationRelease < 6
1813 fail;
1814 #endif
1815 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1816   if test $emacs_cv_x11_version_6 = yes; then
1817     AC_MSG_RESULT(6 or newer)
1818     AC_DEFINE(HAVE_X11R6, 1,
1819               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1820   else
1821     AC_MSG_RESULT(before 6)
1822   fi
1823 fi
1824
1825
1826 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1827 HAVE_RSVG=no
1828 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1829   if test "${with_rsvg}" != "no"; then
1830     RSVG_REQUIRED=2.11.0
1831     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1832
1833     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1834     AC_SUBST(RSVG_CFLAGS)
1835     AC_SUBST(RSVG_LIBS)
1836
1837     if test ".${RSVG_CFLAGS}" != "."; then
1838       HAVE_RSVG=yes
1839       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1840       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1841       LIBS="$RSVG_LIBS $LIBS"
1842     fi
1843   fi
1844 fi
1845
1846
1847 HAVE_GTK=no
1848 if test "${with_gtk3}" = "yes"; then
1849   GLIB_REQUIRED=2.6
1850   GTK_REQUIRED=2.90
1851   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1852
1853   dnl Checks for libraries.
1854   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1855   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1856      AC_MSG_ERROR($GTK_PKG_ERRORS)
1857   fi
1858 fi
1859
1860 if test "$pkg_check_gtk" != "yes"; then
1861   HAVE_GTK=no
1862 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1863   GLIB_REQUIRED=2.6
1864   GTK_REQUIRED=2.6
1865   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1866
1867   dnl Checks for libraries.
1868   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1869   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1870      AC_MSG_ERROR($GTK_PKG_ERRORS)
1871   fi
1872 fi
1873 fi
1874
1875 GTK_OBJ=
1876 if test x"$pkg_check_gtk" = xyes; then
1877
1878   AC_SUBST(GTK_CFLAGS)
1879   AC_SUBST(GTK_LIBS)
1880   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1881   CFLAGS="$CFLAGS $GTK_CFLAGS"
1882   LIBS="$GTK_LIBS $LIBS"
1883   dnl Try to compile a simple GTK program.
1884   GTK_COMPILES=no
1885   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1886   if test "${GTK_COMPILES}" != "yes"; then
1887     if test "$USE_X_TOOLKIT" != "maybe"; then
1888       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1889     fi
1890   else
1891     HAVE_GTK=yes
1892     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1893     GTK_OBJ=gtkutil.o
1894     USE_X_TOOLKIT=none
1895     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1896       :
1897     else
1898       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1899        closing open displays.  This is no problem if you just use
1900        one display, but if you use more than one and close one of them
1901        Emacs may crash.]])
1902       sleep 3
1903     fi
1904   fi
1905
1906 fi
1907 AC_SUBST(GTK_OBJ)
1908
1909
1910 if test "${HAVE_GTK}" = "yes"; then
1911
1912   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1913   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1914   if test "$with_toolkit_scroll_bars" != no; then
1915     with_toolkit_scroll_bars=yes
1916   fi
1917
1918   dnl  Check if we have the old file selection dialog declared and
1919   dnl  in the link library.  In 2.x it may be in the library,
1920   dnl  but not declared if deprecated featured has been selected out.
1921   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1922   HAVE_GTK_FILE_SELECTION=no
1923   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1924                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1925 #include <gtk/gtk.h>])
1926   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1927     AC_CHECK_FUNCS(gtk_file_selection_new)
1928   fi
1929
1930   dnl Check if pthreads are available.  Emacs only needs this when using
1931   dnl gtk_file_chooser under Gnome.
1932     HAVE_GTK_AND_PTHREAD=no
1933     AC_CHECK_HEADERS(pthread.h)
1934     if test "$ac_cv_header_pthread_h"; then
1935       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1936     fi
1937     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1938       case "${canonical}" in
1939         *-hpux*) ;;
1940         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1941       esac
1942       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1943                [Define to 1 if you have GTK and pthread (-lpthread).])
1944     fi
1945
1946   dnl Check for functions introduced in 2.14 and later.
1947   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1948                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1949                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1950                  gtk_orientable_set_orientation)
1951
1952 fi
1953
1954 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1955 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1956 dnl also not configured.
1957 HAVE_DBUS=no
1958 DBUS_OBJ=
1959 if test "${with_dbus}" = "yes"; then
1960    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1961    if test "$HAVE_DBUS" = yes; then
1962      LIBS="$LIBS $DBUS_LIBS"
1963      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1964      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1965      DBUS_OBJ=dbusbind.o
1966    fi
1967 fi
1968 AC_SUBST(DBUS_OBJ)
1969
1970 dnl GConf has been tested under GNU/Linux only.
1971 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1972 HAVE_GCONF=no
1973 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1974    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1975    if test "$HAVE_GCONF" = yes; then
1976       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1977    fi
1978 fi
1979
1980 dnl SELinux is available for GNU/Linux only.
1981 HAVE_LIBSELINUX=no
1982 LIBSELINUX_LIBS=
1983 if test "${with_selinux}" = "yes"; then
1984    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1985    if test "$HAVE_LIBSELINUX" = yes; then
1986       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1987       LIBSELINUX_LIBS=-lselinux
1988    fi
1989 fi
1990 AC_SUBST(LIBSELINUX_LIBS)
1991
1992 dnl Do not put whitespace before the #include statements below.
1993 dnl Older compilers (eg sunos4 cc) choke on it.
1994 HAVE_XAW3D=no
1995 LUCID_LIBW=
1996 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1997   if test "$with_xaw3d" != no; then
1998     AC_MSG_CHECKING(for xaw3d)
1999     AC_CACHE_VAL(emacs_cv_xaw3d,
2000     [AC_TRY_LINK([
2001 #include <X11/Intrinsic.h>
2002 #include <X11/Xaw3d/Simple.h>],
2003       [],
2004       emacs_cv_xaw3d=yes,
2005       emacs_cv_xaw3d=no)])
2006   else
2007     emacs_cv_xaw3d=no
2008   fi
2009   if test $emacs_cv_xaw3d = yes; then
2010     AC_MSG_RESULT([yes; using Lucid toolkit])
2011     USE_X_TOOLKIT=LUCID
2012     HAVE_XAW3D=yes
2013     LUCID_LIBW=-lXaw3d
2014     AC_DEFINE(HAVE_XAW3D, 1,
2015               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2016   else
2017     AC_MSG_RESULT(no)
2018     AC_MSG_CHECKING(for libXaw)
2019     AC_CACHE_VAL(emacs_cv_xaw,
2020     [AC_TRY_LINK([
2021 #include <X11/Intrinsic.h>
2022 #include <X11/Xaw/Simple.h>],
2023       [],
2024       emacs_cv_xaw=yes,
2025       emacs_cv_xaw=no)])
2026     if test $emacs_cv_xaw = yes; then
2027       AC_MSG_RESULT([yes; using Lucid toolkit])
2028       USE_X_TOOLKIT=LUCID
2029       LUCID_LIBW=-lXaw
2030     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2031       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2032     else
2033       AC_MSG_RESULT([no; do not use toolkit by default])
2034       USE_X_TOOLKIT=none
2035     fi
2036   fi
2037 fi
2038
2039 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2040
2041 LIBXTR6=
2042 if test "${USE_X_TOOLKIT}" != "none"; then
2043   AC_MSG_CHECKING(X11 toolkit version)
2044   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2045   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2046 [#if XtSpecificationRelease < 6
2047 fail;
2048 #endif
2049 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2050   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2051   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2052     AC_MSG_RESULT(6 or newer)
2053     AC_DEFINE(HAVE_X11XTR6, 1,
2054               [Define to 1 if you have the X11R6 or newer version of Xt.])
2055     LIBXTR6="-lSM -lICE"
2056     case "$opsys" in
2057       ## Use libw.a along with X11R6 Xt.
2058       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2059     esac
2060   else
2061     AC_MSG_RESULT(before 6)
2062   fi
2063
2064 dnl If using toolkit, check whether libXmu.a exists.
2065 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2066   OLDLIBS="$LIBS"
2067   if test x$HAVE_X11XTR6 = xyes; then
2068     LIBS="-lXt -lSM -lICE $LIBS"
2069   else
2070     LIBS="-lXt $LIBS"
2071   fi
2072   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2073   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2074 fi
2075 AC_SUBST(LIBXTR6)
2076
2077 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2078 dnl Why not just test for libxmu in the normal way?
2079 LIBXMU=-lXmu
2080 case "$machine" in
2081   ## These machines don't supply Xmu.
2082   hpux* | aix4-2 )
2083     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2084     ;;
2085 esac
2086 AC_SUBST(LIBXMU)
2087
2088 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2089 if test "${HAVE_X11}" = "yes"; then
2090   if test "${USE_X_TOOLKIT}" != "none"; then
2091     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2092   fi
2093 fi
2094
2095 LIBXP=
2096 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2097   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2098   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2099     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2100 int x = 5;
2101 #else
2102 Motif version prior to 2.1.
2103 #endif],
2104     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2105   if test $emacs_cv_motif_version_2_1 = yes; then
2106     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2107   else
2108     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2109     # We put this in CFLAGS temporarily to precede other -I options
2110     # that might be in CFLAGS temporarily.
2111     # We put this in CPPFLAGS where it precedes the other -I options.
2112     OLD_CPPFLAGS=$CPPFLAGS
2113     OLD_CFLAGS=$CFLAGS
2114     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2115     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2116     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2117       [int x = 5;],
2118       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2119     if test $emacs_cv_lesstif = yes; then
2120       # Make sure this -I option remains in CPPFLAGS after it is set
2121       # back to REAL_CPPFLAGS.
2122       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2123       # have those other -I options anyway.  Ultimately, having this
2124       # directory ultimately in CPPFLAGS will be enough.
2125       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2126       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2127     else
2128       CFLAGS=$OLD_CFLAGS
2129       CPPFLAGS=$OLD_CPPFLAGS
2130     fi
2131   fi
2132 fi
2133
2134 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2135 dnl using Motif or Xaw3d is available, and unless
2136 dnl --with-toolkit-scroll-bars=no was specified.
2137
2138 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2139             [Define to 1 if we should use toolkit scroll bars.])dnl
2140 USE_TOOLKIT_SCROLL_BARS=no
2141 if test "${with_toolkit_scroll_bars}" != "no"; then
2142   if test "${USE_X_TOOLKIT}" != "none"; then
2143     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2144       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2145       HAVE_XAW3D=no
2146       USE_TOOLKIT_SCROLL_BARS=yes
2147     elif test "${HAVE_XAW3D}" = "yes"; then
2148       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2149       USE_TOOLKIT_SCROLL_BARS=yes
2150     fi
2151   elif test "${HAVE_GTK}" = "yes"; then
2152     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2153     USE_TOOLKIT_SCROLL_BARS=yes
2154   elif test "${HAVE_NS}" = "yes"; then
2155     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2156     USE_TOOLKIT_SCROLL_BARS=yes
2157   fi
2158 fi
2159
2160 dnl See if XIM is available.
2161 AC_TRY_COMPILE([
2162           #include <X11/Xlib.h>
2163           #include <X11/Xresource.h>],
2164          [XIMProc  callback;],
2165          [HAVE_XIM=yes
2166          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2167          HAVE_XIM=no)
2168
2169 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2170
2171 if test "${with_xim}" != "no"; then
2172   AC_DEFINE(USE_XIM, 1,
2173             [Define to 1 if we should use XIM, if it is available.])
2174 fi
2175
2176
2177 if test "${HAVE_XIM}" != "no"; then
2178   late_CFLAGS=$CFLAGS
2179   if test "$GCC" = yes; then
2180     CFLAGS="$CFLAGS --pedantic-errors"
2181   fi
2182   AC_TRY_COMPILE([
2183 #include <X11/Xlib.h>
2184 #include <X11/Xresource.h>],
2185 [Display *display;
2186 XrmDatabase db;
2187 char *res_name;
2188 char *res_class;
2189 XIMProc  callback;
2190 XPointer *client_data;
2191 #ifndef __GNUC__
2192 /* If we're not using GCC, it's probably not XFree86, and this is
2193    probably right, but we can't use something like --pedantic-errors.  */
2194 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2195                                            char*, XIMProc, XPointer*);
2196 #endif
2197 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2198    client_data);],
2199     [emacs_cv_arg6_star=yes])
2200   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2201          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2202 either XPointer or XPointer*.])dnl
2203   if test "$emacs_cv_arg6_star" = yes; then
2204     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2205   else
2206     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2207   fi
2208   CFLAGS=$late_CFLAGS
2209 fi
2210
2211 ### Start of font-backend (under any platform) section.
2212 # (nothing here yet -- this is a placeholder)
2213 ### End of font-backend (under any platform) section.
2214
2215 ### Start of font-backend (under X11) section.
2216 if test "${HAVE_X11}" = "yes"; then
2217    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2218
2219    ## Use -lXft if available, unless `--with-xft=no'.
2220    HAVE_XFT=maybe
2221     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2222       with_xft="no";
2223     fi
2224     if test "x${with_xft}" != "xno"; then
2225
2226       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2227       ## Because xftfont.c uses XRenderQueryExtension, we also
2228       ## need to link to -lXrender.
2229       HAVE_XRENDER=no
2230       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2231       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2232         OLD_CPPFLAGS="$CPPFLAGS"
2233         OLD_CFLAGS="$CFLAGS"
2234         OLD_LIBS="$LIBS"
2235         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2236         CFLAGS="$CFLAGS $XFT_CFLAGS"
2237         XFT_LIBS="-lXrender $XFT_LIBS"
2238         LIBS="$XFT_LIBS $LIBS"
2239         AC_CHECK_HEADER(X11/Xft/Xft.h,
2240           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2241
2242         if test "${HAVE_XFT}" = "yes"; then
2243           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2244             AC_SUBST(XFT_LIBS)
2245           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2246         else
2247           CPPFLAGS="$OLD_CPPFLAGS"
2248           CFLAGS="$OLD_CFLAGS"
2249           LIBS="$OLD_LIBS"
2250         fi                        # "${HAVE_XFT}" = "yes"
2251       fi                          # "$HAVE_XFT" != no
2252     fi                            # "x${with_xft}" != "xno"
2253
2254     dnl For the "Does Emacs use" message at the end.
2255     if test "$HAVE_XFT" != "yes"; then
2256        HAVE_XFT=no
2257     fi
2258
2259
2260     HAVE_FREETYPE=no
2261     ## We used to allow building with FreeType and without Xft.
2262     ## However, the ftx font backend driver is not in good shape.
2263     if test "${HAVE_XFT}" = "yes"; then
2264       dnl As we use Xft, we anyway use freetype.
2265       dnl There's no need for additional CFLAGS and LIBS.
2266       HAVE_FREETYPE=yes
2267       FONTCONFIG_CFLAGS=
2268       FONTCONFIG_LIBS=
2269     fi
2270
2271     HAVE_LIBOTF=no
2272     if test "${HAVE_FREETYPE}" = "yes"; then
2273       AC_DEFINE(HAVE_FREETYPE, 1,
2274                 [Define to 1 if using the freetype and fontconfig libraries.])
2275       if test "${with_libotf}" != "no"; then
2276         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2277                           HAVE_LIBOTF=no)
2278         if test "$HAVE_LIBOTF" = "yes"; then
2279           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2280           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2281                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2282                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2283           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2284             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2285                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2286           fi
2287         fi
2288       fi
2289     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2290     dnl Does the new font backend require it, or can it work without it?
2291     fi
2292
2293     HAVE_M17N_FLT=no
2294     if test "${HAVE_LIBOTF}" = yes; then
2295       if test "${with_m17n_flt}" != "no"; then
2296         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2297         if test "$HAVE_M17N_FLT" = "yes"; then
2298           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2299         fi
2300       fi
2301     fi
2302 else
2303     HAVE_XFT=no
2304     HAVE_FREETYPE=no
2305     HAVE_LIBOTF=no
2306     HAVE_M17N_FLT=no
2307 fi
2308
2309 ### End of font-backend (under X11) section.
2310
2311 AC_SUBST(FREETYPE_CFLAGS)
2312 AC_SUBST(FREETYPE_LIBS)
2313 AC_SUBST(FONTCONFIG_CFLAGS)
2314 AC_SUBST(FONTCONFIG_LIBS)
2315 AC_SUBST(LIBOTF_CFLAGS)
2316 AC_SUBST(LIBOTF_LIBS)
2317 AC_SUBST(M17N_FLT_CFLAGS)
2318 AC_SUBST(M17N_FLT_LIBS)
2319
2320 ### Use -lXpm if available, unless `--with-xpm=no'.
2321 HAVE_XPM=no
2322 LIBXPM=
2323 if test "${HAVE_X11}" = "yes"; then
2324   if test "${with_xpm}" != "no"; then
2325     AC_CHECK_HEADER(X11/xpm.h,
2326       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2327     if test "${HAVE_XPM}" = "yes"; then
2328       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2329       AC_EGREP_CPP(no_return_alloc_pixels,
2330       [#include "X11/xpm.h"
2331 #ifndef XpmReturnAllocPixels
2332 no_return_alloc_pixels
2333 #endif
2334       ], HAVE_XPM=no, HAVE_XPM=yes)
2335
2336       if test "${HAVE_XPM}" = "yes"; then
2337         AC_MSG_RESULT(yes)
2338       else
2339         AC_MSG_RESULT(no)
2340       fi
2341     fi
2342   fi
2343
2344   if test "${HAVE_XPM}" = "yes"; then
2345     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2346     LIBXPM=-lXpm
2347   fi
2348 fi
2349 AC_SUBST(LIBXPM)
2350
2351 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2352 HAVE_JPEG=no
2353 LIBJPEG=
2354 if test "${HAVE_X11}" = "yes"; then
2355   if test "${with_jpeg}" != "no"; then
2356     dnl Checking for jpeglib.h can lose because of a redefinition of
2357     dnl  HAVE_STDLIB_H.
2358     AC_CHECK_HEADER(jerror.h,
2359       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2360   fi
2361
2362   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2363   if test "${HAVE_JPEG}" = "yes"; then
2364     AC_DEFINE(HAVE_JPEG)
2365     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2366         [#include <jpeglib.h>
2367          version=JPEG_LIB_VERSION
2368 ],
2369         [AC_DEFINE(HAVE_JPEG)],
2370         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2371         HAVE_JPEG=no])
2372   fi
2373   if test "${HAVE_JPEG}" = "yes"; then
2374     LIBJPEG=-ljpeg
2375   fi
2376 fi
2377 AC_SUBST(LIBJPEG)
2378
2379 ### Use -lpng if available, unless `--with-png=no'.
2380 HAVE_PNG=no
2381 LIBPNG=
2382 if test "${HAVE_X11}" = "yes"; then
2383   if test "${with_png}" != "no"; then
2384     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2385     # in /usr/include/libpng.
2386     AC_CHECK_HEADERS(png.h libpng/png.h)
2387     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2388       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2389     fi
2390   fi
2391
2392   if test "${HAVE_PNG}" = "yes"; then
2393     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2394     LIBPNG="-lpng -lz -lm"
2395   fi
2396 fi
2397 AC_SUBST(LIBPNG)
2398
2399 ### Use -ltiff if available, unless `--with-tiff=no'.
2400 HAVE_TIFF=no
2401 LIBTIFF=
2402 if test "${HAVE_X11}" = "yes"; then
2403   if test "${with_tiff}" != "no"; then
2404     AC_CHECK_HEADER(tiffio.h,
2405       [tifflibs="-lz -lm"
2406       # At least one tiff package requires the jpeg library.
2407       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2408       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2409   fi
2410
2411   if test "${HAVE_TIFF}" = "yes"; then
2412     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2413     dnl FIXME -lz -lm, as per libpng?
2414     LIBTIFF=-ltiff
2415   fi
2416 fi
2417 AC_SUBST(LIBTIFF)
2418
2419 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2420 HAVE_GIF=no
2421 LIBGIF=
2422 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2423   AC_CHECK_HEADER(gif_lib.h,
2424 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2425 # Earlier versions can crash Emacs.
2426     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2427
2428   if test "$HAVE_GIF" = yes; then
2429     LIBGIF=-lgif
2430   elif test "$HAVE_GIF" = maybe; then
2431 # If gif_lib.h but no libgif, try libungif.
2432     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2433     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2434   fi
2435
2436   if test "${HAVE_GIF}" = "yes"; then
2437     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2438   fi
2439 fi
2440 AC_SUBST(LIBGIF)
2441
2442 dnl Check for required libraries.
2443 if test "${HAVE_X11}" = "yes"; then
2444   MISSING=""
2445   WITH_NO=""
2446   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2447     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2448   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2449     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2450   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2451     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2452   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2453     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2454   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2455     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2456
2457   if test "X${MISSING}" != X; then
2458     AC_MSG_ERROR([The following required libraries were not found:
2459     $MISSING
2460 Maybe some development libraries/packages are missing?
2461 If you don't want to link with them give
2462     $WITH_NO
2463 as options to configure])
2464   fi
2465 fi
2466
2467 ### Use -lgpm if available, unless `--with-gpm=no'.
2468 HAVE_GPM=no
2469 LIBGPM=
2470 MOUSE_SUPPORT=
2471 if test "${with_gpm}" != "no"; then
2472   AC_CHECK_HEADER(gpm.h,
2473     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2474
2475   if test "${HAVE_GPM}" = "yes"; then
2476     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2477     LIBGPM=-lgpm
2478     ## May be reset below.
2479     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2480   fi
2481 fi
2482 AC_SUBST(LIBGPM)
2483
2484 dnl Check for malloc/malloc.h on darwin
2485 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2486
2487 C_SWITCH_X_SYSTEM=
2488 ### Use NeXTstep API to implement GUI.
2489 if test "${HAVE_NS}" = "yes"; then
2490   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2491   if test "${NS_IMPL_COCOA}" = "yes"; then
2492     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2493     GNU_OBJC_CFLAGS=
2494   fi
2495   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2496     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2497     # See also .m.o rule in Makefile.in */
2498     # FIXME: are all these flags really needed?  Document here why.  */
2499     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2500     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2501   fi
2502   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2503     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2504   fi
2505   # We also have mouse menus.
2506   HAVE_MENUS=yes
2507   OTHER_FILES=ns-app
2508 fi
2509
2510
2511 ### Use session management (-lSM -lICE) if available
2512 HAVE_X_SM=no
2513 LIBXSM=
2514 if test "${HAVE_X11}" = "yes"; then
2515   AC_CHECK_HEADER(X11/SM/SMlib.h,
2516     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2517
2518   if test "${HAVE_X_SM}" = "yes"; then
2519     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2520     LIBXSM="-lSM -lICE"
2521     case "$LIBS" in
2522       *-lSM*) ;;
2523       *)      LIBS="$LIBXSM $LIBS" ;;
2524     esac
2525   fi
2526 fi
2527 AC_SUBST(LIBXSM)
2528
2529 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2530 AC_CACHE_CHECK(whether netdb declares h_errno,
2531                emacs_cv_netdb_declares_h_errno,
2532 [AC_TRY_LINK([#include <netdb.h>],
2533   [return h_errno;],
2534   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2535 if test $emacs_cv_netdb_declares_h_errno = yes; then
2536   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2537 fi
2538
2539 AC_FUNC_ALLOCA
2540
2541 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2542 dnl FIXME is there an autoconf test that does the right thing, without
2543 dnl needing to call A_M_E afterwards?
2544 if test x"$ac_cv_func_alloca_works" != xyes; then
2545    AC_MSG_ERROR( [a system implementation of alloca is required] )
2546 fi
2547
2548 # fmod, logb, and frexp are found in -lm on most systems.
2549 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2550 AC_CHECK_LIB(m, sqrt)
2551
2552 # Check for mail-locking functions in a "mail" library.  Probably this should
2553 # have the same check as for liblockfile below.
2554 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2555 if test $have_mail = yes; then
2556   LIBS_MAIL=-lmail
2557   LIBS="$LIBS_MAIL $LIBS"
2558   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2559 else
2560   LIBS_MAIL=
2561 fi
2562 dnl Debian, at least:
2563 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2564 if test $have_lockfile = yes; then
2565    LIBS_MAIL=-llockfile
2566    LIBS="$LIBS_MAIL $LIBS"
2567    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2568 else
2569 # If we have the shared liblockfile, assume we must use it for mail
2570 # locking (e.g. Debian).  If we couldn't link against liblockfile
2571 # (no liblockfile.a installed), ensure that we don't need to.
2572   dnl This works for files generally, not just executables.
2573   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2574   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2575                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2576   if test $ac_cv_prog_liblockfile = yes; then
2577     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2578 This probably means that movemail could lose mail.
2579 There may be a `development' package to install containing liblockfile.])
2580   fi
2581 fi
2582 AC_CHECK_FUNCS(touchlock)
2583 AC_CHECK_HEADERS(maillock.h)
2584 AC_SUBST(LIBS_MAIL)
2585
2586 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2587 ## interlock access to the mail spool.  The alternative is a lock file named
2588 ## /usr/spool/mail/$USER.lock.
2589 mail_lock=no
2590 case "$opsys" in
2591   aix4-2) mail_lock="lockf" ;;
2592
2593   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2594
2595   ## On GNU/Linux systems, both methods are used by various mail programs.
2596   ## I assume most people are using newer mailers that have heard of flock.
2597   ## Change this if you need to.
2598   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2599   ## configure gets the right answers, and that means *NOT* using flock.
2600   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2601   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2602   ## Debian maintainer hasn't provided a clean fix for Emacs.
2603   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2604   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2605   ## correct logic.  -- fx
2606   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2607   ## liblockfile is a Free Software replacement for libmail, used on
2608   ## Debian systems and elsewhere. -rfr.
2609   gnu-*)
2610     mail_lock="flock"
2611     if test $have_mail = yes || test $have_lockfile = yes; then
2612       test $ac_cv_header_maillock_h = yes && mail_lock=no
2613     fi
2614     ;;
2615 esac
2616
2617 BLESSMAIL_TARGET=
2618 case "$mail_lock" in
2619   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2620
2621   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2622
2623   *) BLESSMAIL_TARGET="need-blessmail" ;;
2624 esac
2625 AC_SUBST(BLESSMAIL_TARGET)
2626
2627
2628 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2629 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2630 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2631 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2632 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2633 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2634 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2635 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2636 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2637 cfmakeraw cfsetspeed isnan copysign)
2638
2639 AC_CHECK_HEADERS(sys/un.h)
2640
2641 AC_FUNC_MKTIME
2642 if test "$ac_cv_func_working_mktime" = no; then
2643   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2644 fi
2645
2646 AC_FUNC_GETLOADAVG
2647
2648 AC_FUNC_FSEEKO
2649
2650 # Configure getopt.
2651 m4_include([m4/getopt.m4])
2652 gl_GETOPT_IFELSE([
2653   gl_GETOPT_SUBSTITUTE_HEADER
2654   gl_PREREQ_GETOPT
2655   GETOPTOBJS='getopt.o getopt1.o'
2656 ])
2657 AC_SUBST(GETOPTOBJS)
2658
2659 AC_FUNC_GETPGRP
2660
2661 AC_FUNC_STRFTIME
2662
2663 # UNIX98 PTYs.
2664 AC_CHECK_FUNCS(grantpt)
2665
2666 # PTY-related GNU extensions.
2667 AC_CHECK_FUNCS(getpt)
2668
2669 # Check this now, so that we will NOT find the above functions in ncurses.
2670 # That is because we have not set up to link ncurses in lib-src.
2671 # It's better to believe a function is not available
2672 # than to expect to find it in ncurses.
2673 # Also we need tputs and friends to be able to build at all.
2674 have_tputs_et_al=true
2675 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2676 if test "$have_tputs_et_al" != true; then
2677   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2678 Maybe some development libraries/packages are missing?  Try installing
2679 libncurses-dev(el), libterminfo-dev(el) or similar.])
2680 fi
2681 # Must define this when any termcap library is found.
2682 AC_DEFINE(HAVE_LIBNCURSES, 1,
2683           [Define to 1 if you have the `ncurses' library (-lncurses).])
2684 ## FIXME This was the cpp logic, but I am not sure it is right.
2685 ## The above test has not necessarily found libncurses.
2686 HAVE_LIBNCURSES=yes
2687
2688 ## Use terminfo instead of termcap?
2689 ## Note only system files NOT using terminfo are:
2690 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2691 ## darwin|gnu without ncurses.
2692 TERMINFO=no
2693 LIBS_TERMCAP=
2694 case "$opsys" in
2695   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2696   ## hpux10-20: Use the system provided termcap(3) library.
2697   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2698   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2699   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2700
2701   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2702   ##  The ncurses library has been moved out of the System framework in
2703   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2704   ##  option to use it.
2705   darwin|gnu*)
2706     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2707     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2708       TERMINFO=yes
2709       LIBS_TERMCAP="-lncurses"
2710     fi
2711     ;;
2712
2713   freebsd)
2714     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2715     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2716     [AC_TRY_LINK([#include <osreldate.h>],
2717 [#if __FreeBSD_version < 400000
2718 fail;
2719 #endif
2720 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2721
2722     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2723
2724     if test $emacs_cv_freebsd_terminfo = yes; then
2725       TERMINFO=yes
2726       LIBS_TERMCAP="-lncurses"
2727     else
2728       LIBS_TERMCAP="-ltermcap"
2729     fi
2730     ;;
2731
2732   netbsd)
2733     if test $ac_cv_search_tputs = -lterminfo; then
2734       TERMINFO=yes
2735       LIBS_TERMCAP="-lterminfo"
2736     else
2737       LIBS_TERMCAP="-ltermcap"
2738     fi
2739     ;;
2740
2741 esac
2742
2743 case "$opsys" in
2744   ## hpux: Make sure we get select from libc rather than from libcurses
2745   ##  because libcurses on HPUX 10.10 has a broken version of select.
2746   ##  We used to use -lc -lcurses, but this may be cleaner.
2747   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2748
2749   openbsd) LIBS_TERMCAP="-lncurses" ;;
2750
2751   ## Must use system termcap, if we use any termcap.  It does special things.
2752   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2753 esac
2754
2755 TERMCAP_OBJ=tparam.o
2756 if test $TERMINFO = yes; then
2757   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2758
2759   ## Default used to be -ltermcap.  Add a case above if need something else.
2760   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2761
2762   TERMCAP_OBJ=terminfo.o
2763 fi
2764 AC_SUBST(LIBS_TERMCAP)
2765 AC_SUBST(TERMCAP_OBJ)
2766
2767
2768 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2769 resolv=no
2770 AC_TRY_LINK([#include <netinet/in.h>
2771 #include <arpa/nameser.h>
2772 #include <resolv.h>],
2773     [return res_init();],
2774     have_res_init=yes, have_res_init=no)
2775 if test "$have_res_init" = no; then
2776   OLIBS="$LIBS"
2777   LIBS="$LIBS -lresolv"
2778   AC_MSG_CHECKING(for res_init with -lresolv)
2779   AC_TRY_LINK([#include <netinet/in.h>
2780 #include <arpa/nameser.h>
2781 #include <resolv.h>],
2782     [return res_init();],
2783     have_res_init=yes, have_res_init=no)
2784   AC_MSG_RESULT($have_res_init)
2785   if test "$have_res_init" = yes ; then
2786     resolv=yes
2787   fi
2788   LIBS="$OLIBS"
2789 fi
2790
2791 if test "$have_res_init" = yes; then
2792   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2793 fi
2794
2795 # Do we need the Hesiod library to provide the support routines?
2796 LIBHESIOD=
2797 if test "$with_hesiod" != no ; then
2798   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2799   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2800      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2801                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2802   if test "$resolv" = yes ; then
2803     RESOLVLIB=-lresolv
2804   else
2805     RESOLVLIB=
2806   fi
2807   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2808         hesiod=yes, :, $RESOLVLIB)])
2809
2810   if test x"$hesiod" = xyes; then
2811     AC_DEFINE(HAVE_LIBHESIOD, 1,
2812               [Define to 1 if you have the hesiod library (-lhesiod).])
2813     LIBHESIOD=-lhesiod
2814   fi
2815 fi
2816 AC_SUBST(LIBHESIOD)
2817
2818 # Do we need libresolv (due to res_init or Hesiod)?
2819 if test "$resolv" = yes ; then
2820   AC_DEFINE(HAVE_LIBRESOLV, 1,
2821             [Define to 1 if you have the resolv library (-lresolv).])
2822   LIBRESOLV=-lresolv
2823 else
2824   LIBRESOLV=
2825 fi
2826 AC_SUBST(LIBRESOLV)
2827
2828 # These tell us which Kerberos-related libraries to use.
2829 COM_ERRLIB=
2830 CRYPTOLIB=
2831 KRB5LIB=
2832 DESLIB=
2833 KRB4LIB=
2834
2835 if test "${with_kerberos}" != no; then
2836   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2837   if test $have_com_err = yes; then
2838     COM_ERRLIB=-lcom_err
2839     LIBS="$COM_ERRLIB $LIBS"
2840     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2841   fi
2842   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2843   if test $have_crypto = yes; then
2844     CRYPTOLIB=-lcrypto
2845     LIBS="$CRYPTOLIB $LIBS"
2846     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2847   fi
2848   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2849   if test $have_k5crypto = yes; then
2850     CRYPTOLIB=-lk5crypto
2851     LIBS="$CRYPTOLIB $LIBS"
2852     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2853   fi
2854   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2855   if test $have_krb5=yes; then
2856     KRB5LIB=-lkrb5
2857     LIBS="$KRB5LIB $LIBS"
2858     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2859   fi
2860   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2861   if test "${with_kerberos5}" = no; then
2862     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2863     if test $have_des425 = yes; then
2864       DESLIB=-ldes425
2865       LIBS="$DESLIB $LIBS"
2866       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2867     else
2868       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2869       if test $have_des = yes; then
2870         DESLIB=-ldes
2871         LIBS="$DESLIB $LIBS"
2872         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2873       fi
2874     fi
2875     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2876     if test $have_krb4 = yes; then
2877       KRB4LIB=-lkrb4
2878       LIBS="$KRB4LIB $LIBS"
2879       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2880     else
2881       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2882       if test $have_krb = yes; then
2883         KRB4LIB=-lkrb
2884         LIBS="$KRB4LIB $LIBS"
2885         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2886       fi
2887     fi
2888   fi
2889
2890   if test "${with_kerberos5}" != no; then
2891     AC_CHECK_HEADERS(krb5.h,
2892       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2893                         [#include <krb5.h>])])
2894   else
2895     AC_CHECK_HEADERS(des.h,,
2896                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2897                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2898     AC_CHECK_HEADERS(krb.h,,
2899                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2900                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2901   fi
2902   AC_CHECK_HEADERS(com_err.h)
2903 fi
2904
2905 AC_SUBST(COM_ERRLIB)
2906 AC_SUBST(CRYPTOLIB)
2907 AC_SUBST(KRB5LIB)
2908 AC_SUBST(DESLIB)
2909 AC_SUBST(KRB4LIB)
2910
2911 # Solaris requires -lintl if you want strerror (which calls dgettext)
2912 # to return localized messages.
2913 AC_CHECK_LIB(intl, dgettext)
2914
2915 AC_MSG_CHECKING(whether localtime caches TZ)
2916 AC_CACHE_VAL(emacs_cv_localtime_cache,
2917 [if test x$ac_cv_func_tzset = xyes; then
2918 AC_TRY_RUN([#include <time.h>
2919 extern char **environ;
2920 unset_TZ ()
2921 {
2922   char **from, **to;
2923   for (to = from = environ; (*to = *from); from++)
2924     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2925       to++;
2926 }
2927 char TZ_GMT0[] = "TZ=GMT0";
2928 char TZ_PST8[] = "TZ=PST8";
2929 main()
2930 {
2931   time_t now = time ((time_t *) 0);
2932   int hour_GMT0, hour_unset;
2933   if (putenv (TZ_GMT0) != 0)
2934     exit (1);
2935   hour_GMT0 = localtime (&now)->tm_hour;
2936   unset_TZ ();
2937   hour_unset = localtime (&now)->tm_hour;
2938   if (putenv (TZ_PST8) != 0)
2939     exit (1);
2940   if (localtime (&now)->tm_hour == hour_GMT0)
2941     exit (1);
2942   unset_TZ ();
2943   if (localtime (&now)->tm_hour != hour_unset)
2944     exit (1);
2945   exit (0);
2946 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2947 [# If we have tzset, assume the worst when cross-compiling.
2948 emacs_cv_localtime_cache=yes])
2949 else
2950         # If we lack tzset, report that localtime does not cache TZ,
2951         # since we can't invalidate the cache if we don't have tzset.
2952         emacs_cv_localtime_cache=no
2953 fi])dnl
2954 AC_MSG_RESULT($emacs_cv_localtime_cache)
2955 if test $emacs_cv_localtime_cache = yes; then
2956   AC_DEFINE(LOCALTIME_CACHE, 1,
2957             [Define to 1 if localtime caches TZ.])
2958 fi
2959
2960 if test "x$HAVE_TIMEVAL" = xyes; then
2961   AC_CHECK_FUNCS(gettimeofday)
2962   if test $ac_cv_func_gettimeofday = yes; then
2963     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2964                    emacs_cv_gettimeofday_two_arguments,
2965     [AC_TRY_COMPILE([
2966 #ifdef TIME_WITH_SYS_TIME
2967 #include <sys/time.h>
2968 #include <time.h>
2969 #else
2970 #ifdef HAVE_SYS_TIME_H
2971 #include <sys/time.h>
2972 #else
2973 #include <time.h>
2974 #endif
2975 #endif],
2976       [struct timeval time;
2977        gettimeofday (&time, 0);],
2978       emacs_cv_gettimeofday_two_arguments=yes,
2979       emacs_cv_gettimeofday_two_arguments=no)])
2980     if test $emacs_cv_gettimeofday_two_arguments = no; then
2981       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2982                 [Define to 1 if gettimeofday accepts only one argument.])
2983     fi
2984   fi
2985 fi
2986
2987 ok_so_far=yes
2988 AC_CHECK_FUNC(socket, , ok_so_far=no)
2989 if test $ok_so_far = yes; then
2990   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2991 fi
2992 if test $ok_so_far = yes; then
2993   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2994 fi
2995 if test $ok_so_far = yes; then
2996 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2997   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2998             [Define to 1 if you have inet sockets.])
2999 fi
3000
3001 AC_CHECK_HEADERS(sys/ioctl.h)
3002
3003 if test -f /usr/lpp/X11/bin/smt.exp; then
3004   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3005             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3006 fi
3007
3008 AC_MSG_CHECKING(whether system supports dynamic ptys)
3009 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3010   AC_MSG_RESULT(yes)
3011   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3012 else
3013   AC_MSG_RESULT(no)
3014 fi
3015
3016 AC_FUNC_FORK
3017
3018 dnl Adapted from Haible's version.
3019 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3020   [AC_TRY_LINK([#include <langinfo.h>],
3021     [char* cs = nl_langinfo(CODESET);],
3022     emacs_cv_langinfo_codeset=yes,
3023     emacs_cv_langinfo_codeset=no)
3024   ])
3025 if test $emacs_cv_langinfo_codeset = yes; then
3026   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3027     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3028 fi
3029
3030 AC_CHECK_TYPES(size_t)
3031
3032 AC_TYPE_MBSTATE_T
3033
3034 dnl Restrict could probably be used effectively other than in regex.c.
3035 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
3036   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
3037                   emacs_cv_c_restrict=yes,
3038                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
3039                                   emacs_cv_c_restrict=__restrict,
3040                                   emacs_cv_c_restrict=no)])])
3041 case "$emacs_cv_c_restrict" in
3042   yes) emacs_restrict=restrict;;
3043   no) emacs_restrict="";;
3044   *) emacs_restrict="$emacs_cv_c_restrict";;
3045 esac
3046 if test "$emacs_restrict" != __restrict; then
3047   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
3048     [Define to compiler's equivalent of C99 restrict keyword.
3049      Don't define if equivalent is `__restrict'.])
3050 fi
3051
3052 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3053   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
3054                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3055 if test "$emacs_cv_c_restrict_arr" = yes; then
3056   AC_DEFINE(__restrict_arr, __restrict,
3057     [Define to compiler's equivalent of C99 restrict keyword in array
3058      declarations.  Define as empty for no equivalent.])
3059 fi
3060
3061 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3062 dnl how the tty code is related to POSIX and/or other versions of termios.
3063 dnl The following looks like a useful start.
3064 dnl
3065 dnl AC_SYS_POSIX_TERMIOS
3066 dnl if test $ac_cv_sys_posix_termios = yes; then
3067 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3068 dnl                                and macros for terminal control.])
3069 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3070 dnl fi
3071
3072 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3073
3074 # Set up the CFLAGS for real compilation, so we can substitute it.
3075 CFLAGS="$REAL_CFLAGS"
3076 CPPFLAGS="$REAL_CPPFLAGS"
3077
3078 ## Hack to detect a buggy GCC version.
3079 if test "x$GCC" = xyes \
3080    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3081    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3082    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3083    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3084 fi
3085
3086 #### Find out which version of Emacs this is.
3087 [version=`grep 'const char emacs_version' ${srcdir}/src/emacs.c \
3088          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
3089 if test x"${version}" = x; then
3090   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/src/emacs.c'.])
3091 fi
3092 if test x"${version}" != x"$PACKAGE_VERSION"; then
3093   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/src/emacs.c'.])
3094 fi
3095
3096 ### Specify what sort of things we'll be editing into Makefile and config.h.
3097 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3098 AC_SUBST(version)
3099 AC_SUBST(configuration)
3100 ## Unused?
3101 AC_SUBST(canonical)
3102 AC_SUBST(srcdir)
3103 AC_SUBST(prefix)
3104 AC_SUBST(exec_prefix)
3105 AC_SUBST(bindir)
3106 AC_SUBST(datadir)
3107 AC_SUBST(sharedstatedir)
3108 AC_SUBST(libexecdir)
3109 AC_SUBST(mandir)
3110 AC_SUBST(infodir)
3111 AC_SUBST(lispdir)
3112 AC_SUBST(locallisppath)
3113 AC_SUBST(lisppath)
3114 AC_SUBST(x_default_search_path)
3115 AC_SUBST(etcdir)
3116 AC_SUBST(archlibdir)
3117 AC_SUBST(docdir)
3118 AC_SUBST(bitmapdir)
3119 AC_SUBST(gamedir)
3120 AC_SUBST(gameuser)
3121 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3122 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3123 ## end of LIBX_BASE, but nothing ever set it.
3124 AC_SUBST(LD_SWITCH_X_SITE)
3125 AC_SUBST(C_SWITCH_X_SITE)
3126 AC_SUBST(C_SWITCH_X_SYSTEM)
3127 AC_SUBST(CFLAGS)
3128 ## Used in lwlib/Makefile.in.
3129 AC_SUBST(X_TOOLKIT_TYPE)
3130 AC_SUBST(machfile)
3131 AC_SUBST(opsysfile)
3132 AC_SUBST(GETLOADAVG_LIBS)
3133 AC_SUBST(ns_appdir)
3134 AC_SUBST(ns_appbindir)
3135 AC_SUBST(ns_appresdir)
3136 AC_SUBST(ns_appsrc)
3137 AC_SUBST(GNU_OBJC_CFLAGS)
3138 AC_SUBST(OTHER_FILES)
3139
3140 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3141                    [Define to the canonical Emacs configuration name.])
3142 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3143                    [Define to the options passed to configure.])
3144 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3145                    [Define to the used machine dependent file.])
3146 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3147                    [Define to the used os dependent file.])
3148
3149 XMENU_OBJ=
3150 XOBJ=
3151 FONT_OBJ=
3152 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3153   AC_DEFINE(HAVE_X_WINDOWS, 1,
3154             [Define to 1 if you want to use the X window system.])
3155   XMENU_OBJ=xmenu.o
3156   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3157   FONT_OBJ=xfont.o
3158   if test "$HAVE_XFT" = "yes"; then
3159     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3160   elif test "$HAVE_FREETYPE" = "yes"; then
3161     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3162   fi
3163   AC_SUBST(FONT_OBJ)
3164 fi
3165 AC_SUBST(XMENU_OBJ)
3166 AC_SUBST(XOBJ)
3167 AC_SUBST(FONT_OBJ)
3168
3169 WIDGET_OBJ=
3170 MOTIF_LIBW=
3171 if test "${USE_X_TOOLKIT}" != "none" ; then
3172   WIDGET_OBJ=widget.o
3173   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3174   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3175     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3176   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3177     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3178     MOTIF_LIBW=-lXm
3179     case "$opsys" in
3180       gnu-linux)
3181         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3182         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3183         ;;
3184
3185       unixware)
3186         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3187         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3188         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3189         ;;
3190
3191       aix4-2)
3192         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3193         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3194         ;;
3195     esac
3196     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3197   fi
3198 fi
3199 AC_SUBST(WIDGET_OBJ)
3200
3201 TOOLKIT_LIBW=
3202 case "$USE_X_TOOLKIT" in
3203   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3204   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3205   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3206 esac
3207 AC_SUBST(TOOLKIT_LIBW)
3208
3209 if test "$USE_X_TOOLKIT" = "none"; then
3210   LIBXT_OTHER="\$(LIBXSM)"
3211   OLDXMENU_TARGET="really-oldXMenu"
3212 else
3213   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3214   OLDXMENU_TARGET="really-lwlib"
3215 fi
3216 AC_SUBST(LIBXT_OTHER)
3217
3218 ## The X Menu stuff is present in the X10 distribution, but missing
3219 ## from X11.  If we have X10, just use the installed library;
3220 ## otherwise, use our own copy.
3221 if test "${HAVE_X11}" = "yes" ; then
3222   AC_DEFINE(HAVE_X11, 1,
3223             [Define to 1 if you want to use version 11 of X windows.
3224              Otherwise, Emacs expects to use version 10.])
3225
3226   if test "$USE_X_TOOLKIT" = "none"; then
3227     OLDXMENU="\${oldXMenudir}libXMenu11.a"
3228   else
3229     OLDXMENU="\${lwlibdir}liblw.a"
3230   fi
3231   LIBXMENU="\$(OLDXMENU)"
3232   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3233   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3234 else
3235   ## For a syntactically valid Makefile; not actually used for anything.
3236   ## See comments in src/Makefile.in.
3237   OLDXMENU=nothing
3238   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3239   if test "${HAVE_X_WINDOWS}" = "yes"; then
3240     LIBXMENU="-lXMenu"
3241   else
3242     LIBXMENU=
3243   fi
3244   LIBX_OTHER=
3245   OLDXMENU_DEPS=
3246 fi
3247
3248 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3249   OLDXMENU_TARGET=
3250   OLDXMENU=nothing
3251   LIBXMENU=
3252   OLDXMENU_DEPS=
3253 fi
3254
3255 AC_SUBST(OLDXMENU_TARGET)
3256 AC_SUBST(OLDXMENU)
3257 AC_SUBST(LIBXMENU)
3258 AC_SUBST(LIBX_OTHER)
3259 AC_SUBST(OLDXMENU_DEPS)
3260
3261 if test "${HAVE_MENUS}" = "yes" ; then
3262   AC_DEFINE(HAVE_MENUS, 1,
3263             [Define to 1 if you have mouse menus.
3264              (This is automatic if you use X, but the option to specify it remains.)
3265              It is also defined with other window systems that support xmenu.c.])
3266 fi
3267
3268 if test "${GNU_MALLOC}" = "yes" ; then
3269   AC_DEFINE(GNU_MALLOC, 1,
3270             [Define to 1 if you want to use the GNU memory allocator.])
3271 fi
3272
3273 RALLOC_OBJ=
3274 if test "${REL_ALLOC}" = "yes" ; then
3275   AC_DEFINE(REL_ALLOC, 1,
3276             [Define REL_ALLOC if you want to use the relocating allocator for
3277              buffer space.])
3278
3279   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3280 fi
3281 AC_SUBST(RALLOC_OBJ)
3282
3283 if test "$opsys" = "cygwin"; then
3284   CYGWIN_OBJ="sheap.o"
3285   ## Cygwin differs because of its unexec().
3286   PRE_ALLOC_OBJ=
3287   POST_ALLOC_OBJ=lastfile.o
3288 else
3289   CYGWIN_OBJ=
3290   PRE_ALLOC_OBJ=lastfile.o
3291   POST_ALLOC_OBJ=
3292 fi
3293 AC_SUBST(CYGWIN_OBJ)
3294 AC_SUBST(PRE_ALLOC_OBJ)
3295 AC_SUBST(POST_ALLOC_OBJ)
3296
3297
3298 case "$opsys" in
3299   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3300
3301   darwin)
3302    ## The -headerpad option tells ld (see man page) to leave room at the
3303    ## end of the header for adding load commands.  Needed for dumping.
3304    ## 0x690 is the total size of 30 segment load commands (at 56
3305    ## each); under Cocoa 31 commands are required.
3306    if test "$HAVE_NS" = "yes"; then
3307      libs_nsgui="-framework AppKit"
3308      headerpad_extra=6C8
3309    else
3310      libs_nsgui=
3311      headerpad_extra=690
3312    fi
3313    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3314
3315    ## This is here because src/Makefile.in did some extra fiddling around
3316    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3317    ##   #ifndef LD_SWITCH_SYSTEM
3318    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3319    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3320    ## not using gcc, darwin system not on an alpha (ie darwin, since
3321    ## darwin + alpha does not occur).
3322    ## Because this was done in src/Makefile.in, the resulting part of
3323    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3324    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3325    ## rather than LD_SWITCH_SYSTEM.
3326    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3327      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3328    ;;
3329
3330   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3331   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3332   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3333   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3334   ## had different values in configure (in ac_link) and src/Makefile.in.
3335   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3336   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3337
3338   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3339 esac
3340
3341 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3342   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3343 fi
3344
3345 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3346
3347
3348 LINKER=
3349 ORDINARY_LINK=
3350 case "$opsys" in
3351   ## gnu: GNU needs its own crt0.
3352   aix4-2|darwin|gnu|usg5-4|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3353
3354   cygwin) LINKER="\$(CC)" ;;
3355
3356   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3357   ## library search parth, i.e. it won't search /usr/lib for libc and
3358   ## friends.  Using -nostartfiles instead avoids this problem, and
3359   ## will also work on earlier NetBSD releases.
3360   netbsd|openbsd) LINKER="\$(CC) -nostartfiles" ;;
3361
3362   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3363   ##   MkLinux/LinuxPPC needs this.
3364   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3365   gnu-*)
3366     case "$machine" in
3367       macppc|ibms390x) LINKER="\$(CC) -nostdlib" ;;
3368     esac
3369     ;;
3370 esac
3371
3372
3373 PRE_EDIT_LDFLAGS=
3374 POST_EDIT_LDFLAGS=
3375 if test "x$ORDINARY_LINK" = "xyes"; then
3376
3377   LINKER="\$(CC)"
3378   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3379
3380 ## The system files defining neither ORDINARY_LINK nor LINKER are:
3381 ## (bsd-common), freebsd, gnu-* not on macppc|ibms390x, hpux*.
3382 elif test "x$GCC" = "xyes" && test "x$LINKER" = "x"; then
3383
3384   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3385   ## places that are difficult to figure out at make time.  Fortunately,
3386   ## these same versions allow you to pass arbitrary flags on to the
3387   ## linker, so there is no reason not to use it as a linker.
3388   ##
3389   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3390   ## searching for libraries in its internal directories, so we have to
3391   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3392   LINKER="\$(CC) -nostdlib"
3393   ## GCC passes any argument prefixed with -Xlinker directly to the linker.
3394   ## See prefix-args.c for an explanation of why we do not do this with the
3395   ## shell''s ``for'' construct.  Note that sane people do not have '.' in
3396   ## their paths, so we must use ./prefix-args.
3397   ## TODO either make prefix-args check ORDINARY_LINK internally,
3398   ## or remove it altogether (bug#6184), removing the need for this hack.
3399   PRE_EDIT_LDFLAGS='`./prefix-args -Xlinker'
3400   POST_EDIT_LDFLAGS='`'
3401 fi
3402 AC_SUBST(PRE_EDIT_LDFLAGS)
3403 AC_SUBST(POST_EDIT_LDFLAGS)
3404
3405 test "x$LINKER" = "x" && LINKER=ld
3406 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3407 test "$NS_IMPL_GNUSTEP" = "yes" && LINKER="\$(CC) -rdynamic"
3408
3409 AC_SUBST(LINKER)
3410
3411
3412 ## FIXME? The logic here is not precisely the same as that above.
3413 ## There is no check here for a pre-defined LINKER.
3414 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3415 LIB_GCC=
3416 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3417
3418   case "$opsys" in
3419     ## cygwin: don't link against static libgcc.
3420     cygwin|freebsd|netbsd|openbsd) LIB_GCC= ;;
3421
3422     gnu-*)
3423       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3424       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3425       ## Note that m/arm.h never bothered to undefine LIB_GCC first.
3426       if test "$machine" = "arm"; then
3427         LIB_GCC="-lgcc_s"
3428       else
3429         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3430         ## immediately undefine it again and redefine it to empty.
3431         ## Was the C_SWITCH_X_SITE part really necessary?
3432 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3433         LIB_GCC=
3434       fi
3435       ;;
3436
3437     ## Ask GCC where to find libgcc.a.
3438     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3439   esac
3440 fi                              dnl if $GCC
3441 AC_SUBST(LIB_GCC)
3442
3443
3444 TOOLTIP_SUPPORT=
3445 WINDOW_SUPPORT=
3446 ## If we're using X11/GNUstep, define some consequences.
3447 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3448   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3449   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3450   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3451   TOOLTIP_SUPPORT="\${lispsource}mouse.elc"
3452
3453   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3454   test "$HAVE_X_WINDOWS" = "yes" && \
3455     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3456
3457 fi
3458 AC_SUBST(MOUSE_SUPPORT)
3459 AC_SUBST(TOOLTIP_SUPPORT)
3460 AC_SUBST(WINDOW_SUPPORT)
3461
3462
3463 AH_TOP([/* GNU Emacs site configuration template file.
3464    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
3465      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
3466
3467 This file is part of GNU Emacs.
3468
3469 GNU Emacs is free software: you can redistribute it and/or modify
3470 it under the terms of the GNU General Public License as published by
3471 the Free Software Foundation, either version 3 of the License, or
3472 (at your option) any later version.
3473
3474 GNU Emacs is distributed in the hope that it will be useful,
3475 but WITHOUT ANY WARRANTY; without even the implied warranty of
3476 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3477 GNU General Public License for more details.
3478
3479 You should have received a copy of the GNU General Public License
3480 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3481
3482
3483 /* No code in Emacs #includes config.h twice, but some bits of code
3484    intended to work with other packages as well (like gmalloc.c)
3485    think they can include it as many times as they like.  */
3486 #ifndef EMACS_CONFIG_H
3487 #define EMACS_CONFIG_H
3488 ])dnl
3489
3490 AH_BOTTOM([
3491 /* Define AMPERSAND_FULL_NAME if you use the convention
3492    that & in the full name stands for the login id.  */
3493 /* Turned on June 1996 supposing nobody will mind it.  */
3494 #define AMPERSAND_FULL_NAME
3495
3496 /* Define HAVE_SOUND if we have sound support.  We know it works
3497    and compiles only on the specified platforms.   For others,
3498    it probably doesn't make sense to try.  */
3499
3500 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
3501 #ifdef HAVE_MACHINE_SOUNDCARD_H
3502 #define HAVE_SOUND 1
3503 #endif
3504 #ifdef HAVE_SYS_SOUNDCARD_H
3505 #define HAVE_SOUND 1
3506 #endif
3507 #ifdef HAVE_SOUNDCARD_H
3508 #define HAVE_SOUND 1
3509 #endif
3510 #ifdef HAVE_ALSA
3511 #define HAVE_SOUND 1
3512 #endif
3513 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
3514
3515 /* If using GNU, then support inline function declarations.  */
3516 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3517    generally, because even if non-gcc compilers accept `inline', they
3518    may reject `extern inline'.  */
3519 #if defined (__GNUC__) && defined (OPTIMIZE)
3520 #define INLINE __inline__
3521 #else
3522 #define INLINE
3523 #endif
3524
3525 /* `subprocesses' should be defined if you want to
3526    have code for asynchronous subprocesses
3527    (as used in M-x compile and M-x shell).
3528    Only MSDOS does not support this (it overrides
3529    this in its config_opsysfile below).  */
3530
3531 #define subprocesses
3532
3533 /* Include the os and machine dependent files.  */
3534 #include config_opsysfile
3535 #include config_machfile
3536
3537 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
3538   (There is probably a better place to do this, but right now the Cocoa
3539    side does this in s/darwin.h and we cannot
3540    parallel this exactly since GNUstep is multi-OS.  */
3541 #ifdef HAVE_NS
3542 # ifdef NS_IMPL_GNUSTEP
3543 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3544 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
3545 #  define SYSTEM_PURESIZE_EXTRA 30000
3546 # endif /* NS_IMPL_GNUSTEP */
3547 #endif /* HAVE_NS */
3548
3549 /* SIGTYPE is the macro we actually use.  */
3550 #ifndef SIGTYPE
3551 #define SIGTYPE RETSIGTYPE
3552 #endif
3553
3554 #ifdef emacs /* Don't do this for lib-src.  */
3555 /* Tell regex.c to use a type compatible with Emacs.  */
3556 #define RE_TRANSLATE_TYPE Lisp_Object
3557 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3558 #ifdef make_number
3559 /* If make_number is a macro, use it.  */
3560 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3561 #else
3562 /* If make_number is a function, avoid it.  */
3563 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3564 #endif
3565 #endif
3566
3567 /* Avoid link-time collision with system mktime if we will use our own.  */
3568 #if ! HAVE_MKTIME || BROKEN_MKTIME
3569 #define mktime emacs_mktime
3570 #endif
3571
3572 #define my_strftime nstrftime   /* for strftime.c */
3573
3574 /* Some of the files of Emacs which are intended for use with other
3575    programs assume that if you have a config.h file, you must declare
3576    the type of getenv.  */
3577 extern char *getenv ();
3578
3579 /* These default definitions are good for almost all machines.
3580    The exceptions override them in m/MACHINE.h.  */
3581
3582 #ifndef BITS_PER_CHAR
3583 #define BITS_PER_CHAR 8
3584 #endif
3585
3586 #ifndef BITS_PER_SHORT
3587 #define BITS_PER_SHORT 16
3588 #endif
3589
3590 /* Note that lisp.h uses this in a preprocessor conditional, so it
3591    would not work to use sizeof.  That being so, we do all of them
3592    without sizeof, for uniformity's sake.  */
3593 #ifndef BITS_PER_INT
3594 #define BITS_PER_INT 32
3595 #endif
3596
3597 #ifndef BITS_PER_LONG
3598 #ifdef _LP64
3599 #define BITS_PER_LONG 64
3600 #else
3601 #define BITS_PER_LONG 32
3602 #endif
3603 #endif
3604
3605 /* Define if the compiler supports function prototypes.  It may do so
3606    but not define __STDC__ (e.g. DEC C by default) or may define it as
3607    zero.  */
3608 #undef PROTOTYPES
3609 /* For mktime.c:  */
3610 #ifndef __P
3611 # if defined PROTOTYPES
3612 #  define __P(args) args
3613 # else
3614 #  define __P(args) ()
3615 # endif  /* GCC.  */
3616 #endif /* __P */
3617
3618 #ifdef HAVE_STRING_H
3619 #include <string.h>
3620 #endif
3621
3622 #ifdef HAVE_STRINGS_H
3623 #include <strings.h>  /* May be needed for bcopy & al.  */
3624 #endif
3625
3626 #ifdef HAVE_STDLIB_H
3627 #include <stdlib.h>
3628 #endif
3629
3630 #ifdef HAVE_ALLOCA_H
3631 # include <alloca.h>
3632 #elif defined __GNUC__
3633 # define alloca __builtin_alloca
3634 #elif defined _AIX
3635 # define alloca __alloca
3636 #else
3637 # include <stddef.h>
3638 # ifdef  __cplusplus
3639 extern "C"
3640 # endif
3641 void *alloca (size_t);
3642 #endif
3643
3644 #ifndef HAVE_SIZE_T
3645 typedef unsigned size_t;
3646 #endif
3647
3648 /* Define HAVE_X_I18N if we have usable i18n support.  */
3649
3650 #ifdef HAVE_X11R6
3651 #define HAVE_X_I18N
3652 #endif
3653
3654 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
3655
3656 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
3657 #define HAVE_X11R6_XIM
3658 #endif
3659
3660 #if defined __GNUC__ && (__GNUC__ > 2 \
3661                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3662 #define NO_RETURN       __attribute__ ((__noreturn__))
3663 #else
3664 #define NO_RETURN       /* nothing */
3665 #endif
3666
3667 /* These won't be used automatically yet.  We also need to know, at least,
3668    that the stack is continuous.  */
3669 #ifdef __GNUC__
3670 #  ifndef GC_SETJMP_WORKS
3671   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3672 #    define GC_SETJMP_WORKS 1
3673 #  endif
3674 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3675 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3676 #  endif
3677 #endif
3678
3679 #ifndef HAVE_BCOPY
3680 #define bcopy(a,b,s) memcpy (b,a,s)
3681 #endif
3682 #ifndef HAVE_BZERO
3683 #define bzero(a,s) memset (a,0,s)
3684 #endif
3685 #ifndef HAVE_BCMP
3686 #define BCMP memcmp
3687 #endif
3688
3689 #endif /* EMACS_CONFIG_H */
3690
3691 /*
3692 Local Variables:
3693 mode: c
3694 End:
3695 */
3696 ])dnl
3697
3698 #### Report on what we decided to do.
3699 #### Report GTK as a toolkit, even if it doesn't use Xt.
3700 #### It makes printing result more understandable as using GTK sets
3701 #### toolkit_scroll_bars to yes by default.
3702 if test "${HAVE_GTK}" = "yes"; then
3703   USE_X_TOOLKIT=GTK
3704 fi
3705
3706 echo "
3707 Configured for \`${canonical}'.
3708
3709   Where should the build process find the source code?    ${srcdir}
3710   What operating system and machine description files should Emacs use?
3711         \`${opsysfile}' and \`${machfile}'
3712   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3713   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3714   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3715   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3716   What window system should Emacs use?                    ${window_system}
3717   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3718
3719 if test -n "${x_includes}"; then
3720 echo "  Where do we find X Windows header files?                ${x_includes}"
3721 else
3722 echo "  Where do we find X Windows header files?                Standard dirs"
3723 fi
3724 if test -n "${x_libraries}"; then
3725 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3726 else
3727 echo "  Where do we find X Windows libraries?                   Standard dirs"
3728 fi
3729
3730 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3731 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3732 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3733 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3734 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3735 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3736 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3737 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3738 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3739 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3740 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3741
3742 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3743 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3744 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3745 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3746
3747 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3748 echo
3749
3750 if test $USE_XASSERTS = yes; then
3751    echo "  Compiling with asserts turned on."
3752    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3753 fi
3754
3755 echo
3756
3757 if test "$HAVE_NS" = "yes"; then
3758    echo
3759    echo "You must run \"make install\" in order to test the built application.
3760 The installed application will go to nextstep/Emacs.app and can be
3761 run or moved from there."
3762    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3763       echo "The application will be fully self-contained."
3764     else
3765       echo "The lisp resources for the application will be installed under ${prefix}.
3766 You may need to run \"make install\" with sudo.  The application will fail
3767 to run if these resources are not installed."
3768    fi
3769    echo
3770 fi
3771
3772 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3773   echo "D-Bus integration has been tested for GNU/Linux only."
3774   echo
3775 fi
3776
3777
3778 # Remove any trailing slashes in these variables.
3779 [test "${prefix}" != NONE &&
3780   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3781 test "${exec_prefix}" != NONE &&
3782   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3783
3784 dnl You might wonder (I did) why epaths.h is generated by running make,
3785 dnl rather than just letting configure generate it from epaths.in.
3786 dnl One reason is that the various paths are not fully expanded (see above);
3787 dnl eg gamedir=${prefix}/var/games/emacs.
3788 dnl Secondly, the GNU Coding standards require that one should be able
3789 dnl to run `make prefix=/some/where/else' and override the values set
3790 dnl by configure.  This also explains the `move-if-change' test and
3791 dnl the use of force in the `epaths-force' rule in Makefile.in.
3792 AC_OUTPUT(Makefile lib-src/Makefile oldXMenu/Makefile \
3793         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3794         doc/lispref/Makefile src/Makefile \
3795         lwlib/Makefile lisp/Makefile leim/Makefile, [
3796
3797 ### Make the necessary directories, if they don't exist.
3798 for dir in etc lisp ; do
3799   test -d ${dir} || mkdir ${dir}
3800 done
3801
3802 echo creating src/epaths.h
3803 ${MAKE-make} epaths-force
3804
3805 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3806   echo creating src/.gdbinit
3807   echo source $srcdir/src/.gdbinit > src/.gdbinit
3808 fi
3809
3810 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3811
3812 m4_if(dnl       Do not change this comment
3813    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3814 )dnl