lisp/tmm.el

   1 ;;; tmm.el --- text mode access to menu-bar
   2
   3 ;; Copyright (C) 1994, 1995, 1996, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Ilya Zakharevich <ilya@math.mps.ohio-state.edu>
   7 ;; Maintainer: FSF
   8 ;; Keywords: convenience
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This package provides text mode access to the menu bar.
  28
  29 ;;; Code:
  30
  31 (require 'electric)
  32
  33 (defgroup tmm nil
  34   "Text mode access to menu-bar."
  35   :prefix "tmm-"
  36   :group 'menu)
  37
  38 ;;; The following will be localized, added only to pacify the compiler.
  39 (defvar tmm-short-cuts)
  40 (defvar tmm-old-mb-map nil)
  41 (defvar tmm-old-comp-map)
  42 (defvar tmm-c-prompt nil)
  43 (defvar tmm-km-list)
  44 (defvar tmm-next-shortcut-digit)
  45 (defvar tmm-table-undef)
  46
  47 ;;;###autoload (define-key global-map "\M-`" 'tmm-menubar)
  48 ;;;###autoload (define-key global-map [menu-bar mouse-1] 'tmm-menubar-mouse)
  49
  50 ;;;###autoload
  51 (defun tmm-menubar (&optional x-position)
  52   "Text-mode emulation of looking and choosing from a menubar.
  53 See the documentation for `tmm-prompt'.
  54 X-POSITION, if non-nil, specifies a horizontal position within the menu bar;
  55 we make that menu bar item (the one at that position) the default choice."
  56   (interactive)
  57   (run-hooks 'menu-bar-update-hook)
  58   ;; Obey menu-bar-final-items; put those items last.
  59   (let ((menu-bar (tmm-get-keybind [menu-bar]))
  60         menu-bar-item)
  61     (let ((list menu-bar-final-items))
  62       (while list
  63         (let ((item (car list)))
  64           ;; ITEM is the name of an item that we want to put last.
  65           ;; Find it in MENU-BAR and move it to the end.
  66           (let ((this-one (assq item menu-bar)))
  67             (setq menu-bar (append (delq this-one menu-bar)
  68                                    (list this-one)))))
  69         (setq list (cdr list))))
  70     (if x-position
  71         (let ((tail menu-bar) (column 0)
  72               this-one name visible)
  73           (while (and tail (<= column x-position))
  74             (setq this-one (car tail))
  75             (if (and (consp this-one)
  76                      (consp (cdr this-one))
  77                      (setq name  ;simple menu
  78                            (cond ((stringp (nth 1  this-one))
  79                                   (nth 1  this-one))
  80                                  ;extended menu
  81                                  ((stringp (nth 2 this-one))
  82                                   (setq visible (plist-get
  83                                                  (nthcdr 4 this-one) :visible))
  84                                   (unless (and visible (not (eval visible)))
  85                                     (nth 2 this-one))))))
  86                 (setq column (+ column (length name) 1)))
  87             (setq tail (cdr tail)))
  88           (setq menu-bar-item (car this-one))))
  89     (tmm-prompt menu-bar nil menu-bar-item)))
  90
  91 ;;;###autoload
  92 (defun tmm-menubar-mouse (event)
  93   "Text-mode emulation of looking and choosing from a menubar.
  94 This command is used when you click the mouse in the menubar
  95 on a console which has no window system but does have a mouse.
  96 See the documentation for `tmm-prompt'."
  97   (interactive "e")
  98   (tmm-menubar (car (posn-x-y (event-start event)))))
  99
 100 (defcustom tmm-mid-prompt "==>"
 101   "String to insert between shortcut and menu item.
 102 If nil, there will be no shortcuts. It should not consist only of spaces,
 103 or else the correct item might not be found in the `*Completions*' buffer."
 104   :type 'string
 105   :group 'tmm)
 106
 107 (defvar tmm-mb-map nil
 108   "A place to store minibuffer map.")
 109
 110 (defcustom tmm-completion-prompt
 111   "Press PageUp key to reach this buffer from the minibuffer.
 112 Alternatively, you can use Up/Down keys (or your History keys) to change
 113 the item in the minibuffer, and press RET when you are done, or press the
 114 marked letters to pick up your choice.  Type C-g or ESC ESC ESC to cancel.
 115 "
 116   "Help text to insert on the top of the completion buffer.
 117 To save space, you can set this to nil,
 118 in which case the standard introduction text is deleted too."
 119   :type '(choice string (const nil))
 120   :group 'tmm)
 121
 122 (defcustom tmm-shortcut-style '(downcase upcase)
 123   "What letters to use as menu shortcuts.
 124 Must be either one of the symbols `downcase' or `upcase',
 125 or else a list of the two in the order you prefer."
 126   :type '(choice (const downcase)
 127                  (const upcase)
 128                  (repeat (choice (const downcase) (const upcase))))
 129   :group 'tmm)
 130
 131 (defcustom tmm-shortcut-words 2
 132   "How many successive words to try for shortcuts, nil means all.
 133 If you use only one of `downcase' or `upcase' for `tmm-shortcut-style',
 134 specify nil for this variable."
 135   :type '(choice integer (const nil))
 136   :group 'tmm)
 137
 138 (defface tmm-inactive
 139   '((t :inherit shadow))
 140   "Face used for inactive menu items."
 141   :group 'tmm)
 142
 143 ;;;###autoload
 144 (defun tmm-prompt (menu &optional in-popup default-item)
 145   "Text-mode emulation of calling the bindings in keymap.
 146 Creates a text-mode menu of possible choices.  You can access the elements
 147 in the menu in two ways:
 148    *)  via history mechanism from minibuffer;
 149    *)  Or via completion-buffer that is automatically shown.
 150 The last alternative is currently a hack, you cannot use mouse reliably.
 151
 152 MENU is like the MENU argument to `x-popup-menu': either a
 153 keymap or an alist of alists.
 154 DEFAULT-ITEM, if non-nil, specifies an initial default choice.
 155 Its value should be an event that has a binding in MENU."
 156   ;; If the optional argument IN-POPUP is t,
 157   ;; then MENU is an alist of elements of the form (STRING . VALUE).
 158   ;; That is used for recursive calls only.
 159   (let ((gl-str "Menu bar")  ;; The menu bar itself is not a menu keymap
 160                                         ; so it doesn't have a name.
 161         tmm-km-list out history history-len tmm-table-undef tmm-c-prompt
 162         tmm-old-mb-map tmm-old-comp-map tmm-short-cuts
 163         chosen-string choice
 164         (not-menu (not (keymapp menu))))
 165     (run-hooks 'activate-menubar-hook)
 166     ;; Compute tmm-km-list from MENU.
 167     ;; tmm-km-list is an alist of (STRING . MEANING).
 168     ;; It has no other elements.
 169     ;; The order of elements in tmm-km-list is the order of the menu bar.
 170     (mapc (lambda (elt)
 171             (if (stringp elt)
 172                 (setq gl-str elt)
 173               (cond
 174                ((listp elt) (tmm-get-keymap elt not-menu))
 175                ((vectorp elt)
 176                 (dotimes (i (length elt))
 177                   (tmm-get-keymap (cons i (aref elt i)) not-menu))))))
 178             menu)
 179     ;; Choose an element of tmm-km-list; put it in choice.
 180     (if (and not-menu (= 1 (length tmm-km-list)))
 181         ;; If this is the top-level of an x-popup-menu menu,
 182         ;; and there is just one pane, choose that one silently.
 183         ;; This way we only ask the user one question,
 184         ;; for which element of that pane.
 185         (setq choice (cdr (car tmm-km-list)))
 186       (unless tmm-km-list
 187         (error "Empty menu reached"))
 188       (and tmm-km-list
 189            (let ((index-of-default 0))
 190              (if tmm-mid-prompt
 191                  (setq tmm-km-list (tmm-add-shortcuts tmm-km-list))
 192                t)
 193              ;; Find the default item's index within the menu bar.
 194              ;; We use this to decide the initial minibuffer contents
 195              ;; and initial history position.
 196              (if default-item
 197                  (let ((tail menu) visible)
 198                    (while (and tail
 199                                (not (eq (car-safe (car tail)) default-item)))
 200                      ;; Be careful to count only the elements of MENU
 201                      ;; that actually constitute menu bar items.
 202                      (if (and (consp (car tail))
 203                               (or (stringp (car-safe (cdr (car tail))))
 204                                   (and
 205                                    (eq (car-safe (cdr (car tail))) 'menu-item)
 206                                    (progn
 207                                      (setq visible
 208                                            (plist-get
 209                                             (nthcdr 4 (car tail)) :visible))
 210                                      (or (not visible) (eval visible))))))
 211                          (setq index-of-default (1+ index-of-default)))
 212                      (setq tail (cdr tail)))))
 213              (let ((prompt (concat "^." (regexp-quote tmm-mid-prompt))))
 214                (setq history
 215                      (reverse (delq nil
 216                                     (mapcar
 217                                      (lambda (elt)
 218                                        (if (string-match prompt (car elt))
 219                                            (car elt)))
 220                                      tmm-km-list)))))
 221              (setq history-len (length history))
 222              (setq history (append history history history history))
 223              (setq tmm-c-prompt (nth (- history-len 1 index-of-default) history))
 224              (add-hook 'minibuffer-setup-hook 'tmm-add-prompt)
 225              (if default-item
 226                  (setq out (car (nth index-of-default tmm-km-list)))
 227                (save-excursion
 228                  (unwind-protect
 229                      (setq out
 230                            (completing-read
 231                             (concat gl-str
 232                                     " (up/down to change, PgUp to menu): ")
 233                             tmm-km-list nil t nil
 234                             (cons 'history
 235                                   (- (* 2 history-len) index-of-default))))
 236                    (remove-hook 'minibuffer-setup-hook 'tmm-add-prompt)
 237                    (if (get-buffer "*Completions*")
 238                        (with-current-buffer "*Completions*"
 239                          (use-local-map tmm-old-comp-map)
 240                          (bury-buffer (current-buffer)))))))))
 241       (setq choice (cdr (assoc out tmm-km-list)))
 242       (and (null choice)
 243            (> (length out) (length tmm-c-prompt))
 244            (string= (substring out 0 (length tmm-c-prompt)) tmm-c-prompt)
 245            (setq out (substring out (length tmm-c-prompt))
 246                  choice (cdr (assoc out tmm-km-list))))
 247       (and (null choice) out
 248            (setq out (try-completion out tmm-km-list)
 249                  choice (cdr (assoc  out tmm-km-list)))))
 250     ;; CHOICE is now (STRING . MEANING).  Separate the two parts.
 251     (setq chosen-string (car choice))
 252     (setq choice (cdr choice))
 253     (cond (in-popup
 254            ;; We just did the inner level of a -popup menu.
 255            choice)
 256           ;; We just did the outer level.  Do the inner level now.
 257           (not-menu (tmm-prompt choice t))
 258           ;; We just handled a menu keymap and found another keymap.
 259           ((keymapp choice)
 260            (if (symbolp choice)
 261                (setq choice (indirect-function choice)))
 262            (condition-case nil
 263                (require 'mouse)
 264              (error nil))
 265            (tmm-prompt choice))
 266           ;; We just handled a menu keymap and found a command.
 267           (choice
 268            (if chosen-string
 269                (progn
 270                  (setq last-command-event chosen-string)
 271                  (call-interactively choice))
 272              choice)))))
 273
 274 (defun tmm-add-shortcuts (list)
 275   "Adds shortcuts to cars of elements of the list.
 276 Takes a list of lists with a string as car, returns list with
 277 shortcuts added to these cars.
 278 Stores a list of all the shortcuts in the free variable `tmm-short-cuts'."
 279   (let ((tmm-next-shortcut-digit ?0))
 280     (mapcar 'tmm-add-one-shortcut (reverse list))))
 281
 282 (defsubst tmm-add-one-shortcut (elt)
 283 ;; uses the free vars tmm-next-shortcut-digit and tmm-short-cuts
 284   (cond
 285    ((eq (cddr elt) 'ignore)
 286     (cons (concat " " (make-string (length tmm-mid-prompt) ?\-)
 287                   (car elt))
 288           (cdr elt)))
 289    (t
 290     (let* ((str (car elt))
 291            (paren (string-match "(" str))
 292            (pos 0) (word 0) char)
 293       (catch 'done                             ; ??? is this slow?
 294         (while (and (or (not tmm-shortcut-words)   ; no limit on words
 295                         (< word tmm-shortcut-words)) ; try n words
 296                     (setq pos (string-match "\\w+" str pos)) ; get next word
 297                     (not (and paren (> pos paren)))) ; don't go past "(binding.."
 298           (if (or (= pos 0)
 299                   (/= (aref str (1- pos)) ?.)) ; avoid file extensions
 300               (let ((shortcut-style
 301                      (if (listp tmm-shortcut-style) ; convert to list
 302                          tmm-shortcut-style
 303                        (list tmm-shortcut-style))))
 304                 (while shortcut-style ; try upcase and downcase variants
 305                   (setq char (funcall (car shortcut-style) (aref str pos)))
 306                   (if (not (memq char tmm-short-cuts)) (throw 'done char))
 307                   (setq shortcut-style (cdr shortcut-style)))))
 308           (setq word (1+ word))
 309           (setq pos (match-end 0)))
 310         (while (<= tmm-next-shortcut-digit ?9) ; no letter shortcut, pick a digit
 311           (setq char tmm-next-shortcut-digit)
 312           (setq tmm-next-shortcut-digit (1+ tmm-next-shortcut-digit))
 313           (if (not (memq char tmm-short-cuts)) (throw 'done char)))
 314         (setq char nil))
 315       (if char (setq tmm-short-cuts (cons char tmm-short-cuts)))
 316       (cons (concat (if char (concat (char-to-string char) tmm-mid-prompt)
 317                       ;; keep them lined up in columns
 318                       (make-string (1+ (length tmm-mid-prompt)) ?\s))
 319                     str)
 320             (cdr elt))))))
 321
 322 ;; This returns the old map.
 323 (defun tmm-define-keys (minibuffer)
 324   (let ((map (make-sparse-keymap)))
 325     (suppress-keymap map t)
 326     (mapc
 327      (lambda (c)
 328        (if (listp tmm-shortcut-style)
 329            (define-key map (char-to-string c) 'tmm-shortcut)
 330          ;; only one kind of letters are shortcuts, so map both upcase and
 331          ;; downcase input to the same
 332          (define-key map (char-to-string (downcase c)) 'tmm-shortcut)
 333          (define-key map (char-to-string (upcase c)) 'tmm-shortcut)))
 334      tmm-short-cuts)
 335     (if minibuffer
 336         (progn
 337           (define-key map [pageup] 'tmm-goto-completions)
 338           (define-key map [prior] 'tmm-goto-completions)
 339           (define-key map "\ev" 'tmm-goto-completions)
 340           (define-key map "\C-n" 'next-history-element)
 341           (define-key map "\C-p" 'previous-history-element)))
 342     (prog1 (current-local-map)
 343       (use-local-map (append map (current-local-map))))))
 344
 345 (defun tmm-completion-delete-prompt ()
 346   (set-buffer standard-output)
 347   (goto-char (point-min))
 348   (delete-region (point) (search-forward "Possible completions are:\n")))
 349
 350 (defun tmm-remove-inactive-mouse-face ()
 351   "Remove the mouse-face property from inactive menu items."
 352   (let ((inhibit-read-only t)
 353         (inactive-string
 354          (concat " " (make-string (length tmm-mid-prompt) ?\-)))
 355         next)
 356     (save-excursion
 357       (goto-char (point-min))
 358       (while (not (eobp))
 359         (setq next (next-single-char-property-change (point) 'mouse-face))
 360         (when (looking-at inactive-string)
 361           (remove-text-properties (point) next '(mouse-face))
 362           (add-text-properties (point) next '(face tmm-inactive)))
 363         (goto-char next)))
 364     (set-buffer-modified-p nil)))
 365
 366 (defun tmm-add-prompt ()
 367   (remove-hook 'minibuffer-setup-hook 'tmm-add-prompt)
 368   (add-hook 'minibuffer-exit-hook 'tmm-delete-map nil t)
 369   (unless tmm-c-prompt
 370     (error "No active menu entries"))
 371   (let ((win (selected-window)))
 372     (setq tmm-old-mb-map (tmm-define-keys t))
 373     ;; Get window and hide it for electric mode to get correct size
 374     (save-window-excursion
 375       (let ((completions
 376              (mapcar 'car minibuffer-completion-table)))
 377         (or tmm-completion-prompt
 378             (add-hook 'completion-setup-hook
 379                       'tmm-completion-delete-prompt 'append))
 380         (unwind-protect
 381             (with-output-to-temp-buffer "*Completions*"
 382               (display-completion-list completions))
 383           (remove-hook 'completion-setup-hook 'tmm-completion-delete-prompt)))
 384       (set-buffer "*Completions*")
 385       (tmm-remove-inactive-mouse-face)
 386       (when tmm-completion-prompt
 387         (let ((buffer-read-only nil))
 388           (goto-char (point-min))
 389           (insert tmm-completion-prompt))))
 390     (save-selected-window
 391       (other-window 1)                  ; Electric-pop-up-window does
 392                                         ; not work in minibuffer
 393       (Electric-pop-up-window "*Completions*")
 394       (with-current-buffer "*Completions*"
 395         (setq tmm-old-comp-map (tmm-define-keys nil))))
 396     (insert tmm-c-prompt)))
 397
 398 (defun tmm-delete-map ()
 399   (remove-hook 'minibuffer-exit-hook 'tmm-delete-map t)
 400   (if tmm-old-mb-map
 401       (use-local-map tmm-old-mb-map)))
 402
 403 (defun tmm-shortcut ()
 404   "Choose the shortcut that the user typed."
 405   (interactive)
 406   (let ((c last-command-event) s)
 407     (if (symbolp tmm-shortcut-style)
 408         (setq c (funcall tmm-shortcut-style c)))
 409     (if (memq c tmm-short-cuts)
 410         (if (equal (buffer-name) "*Completions*")
 411             (progn
 412               (goto-char (point-min))
 413               (re-search-forward
 414                (concat "\\(^\\|[ \t]\\)" (char-to-string c) tmm-mid-prompt))
 415               (choose-completion))
 416           ;; In minibuffer
 417           (delete-region (minibuffer-prompt-end) (point-max))
 418           (mapc (lambda (elt)
 419                   (if (string=
 420                        (substring (car elt) 0
 421                                   (min (1+ (length tmm-mid-prompt))
 422                                        (length (car elt))))
 423                        (concat (char-to-string c) tmm-mid-prompt))
 424                       (setq s (car elt))))
 425                   tmm-km-list)
 426           (insert s)
 427           (exit-minibuffer)))))
 428
 429 (defun tmm-goto-completions ()
 430   (interactive)
 431   (let ((prompt-end (minibuffer-prompt-end)))
 432     (setq tmm-c-prompt (buffer-substring prompt-end (point-max)))
 433     (delete-region prompt-end (point-max)))
 434   (switch-to-buffer-other-window "*Completions*")
 435   (search-forward tmm-c-prompt)
 436   (search-backward tmm-c-prompt))
 437
 438 (defun tmm-get-keymap (elt &optional in-x-menu)
 439   "Prepends (DOCSTRING EVENT BINDING) to free variable `tmm-km-list'.
 440 The values are deduced from the argument ELT, that should be an
 441 element of keymap, an `x-popup-menu' argument, or an element of
 442 `x-popup-menu' argument (when IN-X-MENU is not-nil).
 443 This function adds the element only if it is not already present.
 444 It uses the free variable `tmm-table-undef' to keep undefined keys."
 445   (let (km str plist filter visible enable (event (car elt)))
 446     (setq elt (cdr elt))
 447     (if (eq elt 'undefined)
 448         (setq tmm-table-undef (cons (cons event nil) tmm-table-undef))
 449       (unless (assoc event tmm-table-undef)
 450         (cond ((if (listp elt)
 451                    (or (keymapp elt) (eq (car elt) 'lambda))
 452                  (and (symbolp elt) (fboundp elt)))
 453                (setq km elt))
 454
 455               ((if (listp (cdr-safe elt))
 456                    (or (keymapp (cdr-safe elt))
 457                        (eq (car (cdr-safe elt)) 'lambda))
 458                  (and (symbolp (cdr-safe elt)) (fboundp (cdr-safe elt))))
 459                (setq km (cdr elt))
 460                (and (stringp (car elt)) (setq str (car elt))))
 461
 462               ((if (listp (cdr-safe (cdr-safe elt)))
 463                    (or (keymapp (cdr-safe (cdr-safe elt)))
 464                        (eq (car (cdr-safe (cdr-safe elt))) 'lambda))
 465                  (and (symbolp (cdr-safe (cdr-safe elt)))
 466                                (fboundp (cdr-safe (cdr-safe elt)))))
 467                (setq km (cddr elt))
 468                (and (stringp (car elt)) (setq str (car elt))))
 469
 470               ((eq (car-safe elt) 'menu-item)
 471                ;; (menu-item TITLE COMMAND KEY ...)
 472                (setq plist (cdr-safe (cdr-safe (cdr-safe elt))))
 473                (when (consp (car-safe plist))
 474                  (setq plist (cdr-safe plist)))
 475                (setq km (nth 2 elt))
 476                (setq str (eval (nth 1 elt)))
 477                (setq filter (plist-get plist :filter))
 478                (if filter
 479                    (setq km (funcall filter km)))
 480                (setq visible (plist-get plist :visible))
 481                (if visible
 482                    (setq km (and (eval visible) km)))
 483                (setq enable (plist-get plist :enable))
 484                (if enable
 485                    (setq km (if (eval enable) km 'ignore))))
 486
 487               ((if (listp (cdr-safe (cdr-safe (cdr-safe elt))))
 488                    (or (keymapp (cdr-safe (cdr-safe (cdr-safe elt))))
 489                        (eq (car (cdr-safe (cdr-safe (cdr-safe elt)))) 'lambda))
 490                  (and (symbolp (cdr-safe (cdr-safe (cdr-safe elt))))
 491                       (fboundp (cdr-safe (cdr-safe (cdr-safe elt))))))
 492                                          ; New style of easy-menu
 493                (setq km (cdr (cddr elt)))
 494                (and (stringp (car elt)) (setq str (car elt))))
 495
 496               ((stringp event)          ; x-popup or x-popup element
 497                (if (or in-x-menu (stringp (car-safe elt)))
 498                    (setq str event event nil km elt)
 499                  (setq str event event nil km (cons 'keymap elt)))))
 500         (unless (eq km 'ignore)
 501           (let ((binding (where-is-internal km nil t)))
 502             (when binding
 503               (setq binding (key-description binding))
 504               ;; Try to align the keybindings.
 505               (let ((colwidth (min 30 (- (/ (window-width) 2) 10))))
 506                 (setq str
 507                       (concat str
 508                               (make-string (max 2 (- colwidth
 509                                                      (string-width str)
 510                                                      (string-width binding)))
 511                                            ?\s)
 512                               binding)))))))
 513       (and km (stringp km) (setq str km))
 514       ;; Verify that the command is enabled;
 515       ;; if not, don't mention it.
 516       (when (and km (symbolp km) (get km 'menu-enable))
 517           (setq km (if (eval (get km 'menu-enable)) km 'ignore)))
 518       (and km str
 519            (or (assoc str tmm-km-list)
 520                (push (cons str (cons event km)) tmm-km-list))))))
 521
 522 (defun tmm-get-keybind (keyseq)
 523   "Return the current binding of KEYSEQ, merging prefix definitions.
 524 If KEYSEQ is a prefix key that has local and global bindings,
 525 we merge them into a single keymap which shows the proper order of the menu.
 526 However, for the menu bar itself, the value does not take account
 527 of `menu-bar-final-items'."
 528   (let (allbind bind minorbind localbind globalbind)
 529     (setq bind (key-binding keyseq))
 530     ;; If KEYSEQ is a prefix key, then BIND is either nil
 531     ;; or a symbol defined as a keymap (which satisfies keymapp).
 532     (if (keymapp bind)
 533         (setq bind nil))
 534     ;; If we have a non-keymap definition, return that.
 535     (or bind
 536         (progn
 537           ;; Otherwise, it is a prefix, so make a list of the subcommands.
 538           ;; Make a list of all the bindings in all the keymaps.
 539           (setq minorbind (mapcar 'cdr (minor-mode-key-binding keyseq)))
 540           (setq localbind (local-key-binding keyseq))
 541           (setq globalbind (copy-sequence (cdr (global-key-binding keyseq))))
 542
 543           ;; If items have been redefined/undefined locally, remove them from
 544           ;; the global list.
 545           (dolist (minor minorbind)
 546             (dolist (item (cdr minor))
 547               (setq globalbind (assq-delete-all (car-safe item) globalbind))))
 548           (dolist (item (cdr localbind))
 549             (setq globalbind (assq-delete-all (car-safe item) globalbind)))
 550
 551           (setq globalbind (cons 'keymap globalbind))
 552           (setq allbind (cons globalbind (cons localbind minorbind)))
 553
 554           ;; Merge all the elements of ALLBIND into one keymap.
 555           (mapc (lambda (in)
 556                   (if (and (symbolp in) (keymapp in))
 557                       (setq in (symbol-function in)))
 558                   (and in (keymapp in)
 559                        (if (keymapp bind)
 560                            (setq bind (nconc bind (copy-sequence (cdr in))))
 561                          (setq bind (copy-sequence in)))))
 562                   allbind)
 563           ;; Return that keymap.
 564           bind))))
 565
 566 ;; Huh?  What's that about?  --Stef
 567 (add-hook 'calendar-load-hook (lambda () (require 'cal-menu)))
 568
 569 (provide 'tmm)
 570
 571 ;; arch-tag: e7ddbdb6-4b95-4da3-afbe-ad6063d112f4
 572 ;;; tmm.el ends here