lisp/delsel.el

   1 ;;; delsel.el --- delete selection if you insert
   2
   3 ;; Copyright (C) 1992, 1997, 1998 Free Software Foundation, Inc.
   4
   5 ;; Author: Matthieu Devin <devin@lucid.com>
   6 ;; Maintainer: FSF
   7 ;; Created: 14 Jul 92
   8 ;; Keywords: convenience emulations
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; This file makes the active region be pending delete, meaning that
  30 ;; text inserted while the region is active will replace the region contents.
  31 ;; This is a popular behavior of personal computers text editors.
  32
  33 ;; Interface:
  34
  35 ;; Commands which will delete the selection need a 'delete-selection
  36 ;; property on their symbols; commands which insert text but don't
  37 ;; have this property won't delete the selction.  It can be one of
  38 ;; the values:
  39 ;;  'yank
  40 ;;      For commands which do a yank; ensures the region about to be
  41 ;;      deleted isn't yanked.
  42 ;;  'supersede
  43 ;;      Delete the active region and ignore the current command,
  44 ;;      i.e. the command will just delete the region.
  45 ;;  'kill
  46 ;;      `kill-region' is used on the selection, rather than
  47 ;;      `delete-region'.  (Text selected with the mouse will typically
  48 ;;      be yankable anyhow.)
  49 ;;  non-nil
  50 ;;      The normal case: delete the active region prior to executing
  51 ;;      the command which will insert replacement text.
  52
  53 ;;; Code:
  54
  55 ;;;###autoload
  56 (defalias 'pending-delete-mode 'delete-selection-mode)
  57
  58 ;;;###autoload
  59 (define-minor-mode delete-selection-mode
  60   "Toggle Delete Selection mode.
  61 With prefix ARG, turn Delete Selection mode on if and only if ARG is
  62 positive.
  63
  64 When Delete Selection mode is enabled, Transient Mark mode is also
  65 enabled and typed text replaces the selection if the selection is
  66 active.  Otherwise, typed text is just inserted at point regardless of
  67 any selection."
  68   :global t :group 'editing-basics
  69   (if (not delete-selection-mode)
  70       (remove-hook 'pre-command-hook 'delete-selection-pre-hook)
  71     (add-hook 'pre-command-hook 'delete-selection-pre-hook)
  72     (transient-mark-mode t)))
  73
  74 (defun delete-active-region (&optional killp)
  75   (if killp
  76       (kill-region (point) (mark))
  77     (delete-region (point) (mark)))
  78   (setq mark-active nil)
  79   (run-hooks 'deactivate-mark-hook)
  80   t)
  81
  82 (defun delete-selection-pre-hook ()
  83   (when (and delete-selection-mode transient-mark-mode mark-active
  84              (not buffer-read-only))
  85     (let ((type (and (symbolp this-command)
  86                      (get this-command 'delete-selection))))
  87       (cond ((eq type 'kill)
  88              (delete-active-region t))
  89             ((eq type 'yank)
  90              ;; Before a yank command,
  91              ;; make sure we don't yank the same region
  92              ;; that we are going to delete.
  93              ;; That would make yank a no-op.
  94              (when (string= (buffer-substring-no-properties (point) (mark))
  95                             (car kill-ring))
  96                (current-kill 1))
  97              (delete-active-region))
  98             ((eq type 'supersede)
  99              (delete-active-region)
 100              (setq this-command 'ignore))
 101             (type
 102              (delete-active-region))))))
 103
 104 (put 'self-insert-command 'delete-selection t)
 105 (put 'self-insert-iso 'delete-selection t)
 106
 107 (put 'yank 'delete-selection 'yank)
 108 (put 'clipboard-yank 'delete-selection 'yank)
 109 (put 'insert-register 'delete-selection t)
 110
 111 (put 'delete-backward-char 'delete-selection 'supersede)
 112 (put 'backward-delete-char-untabify 'delete-selection 'supersede)
 113 (put 'delete-char 'delete-selection 'supersede)
 114
 115 (put 'newline-and-indent 'delete-selection t)
 116 (put 'newline 'delete-selection t)
 117 (put 'open-line 'delete-selection 'kill)
 118
 119 (put 'insert-parentheses 'delete-selection t)
 120
 121 ;; This is very useful for cancelling a selection in the minibuffer without
 122 ;; aborting the minibuffer.
 123 (defun minibuffer-keyboard-quit ()
 124   "Abort recursive edit.
 125 In Delete Selection mode, if the mark is active, just deactivate it;
 126 then it takes a second \\[keyboard-quit] to abort the minibuffer."
 127   (interactive)
 128   (if (and delete-selection-mode transient-mark-mode mark-active)
 129       (setq deactivate-mark t)
 130     (abort-recursive-edit)))
 131
 132 (define-key minibuffer-local-map "\C-g" 'minibuffer-keyboard-quit)
 133 (define-key minibuffer-local-ns-map "\C-g" 'minibuffer-keyboard-quit)
 134 (define-key minibuffer-local-completion-map "\C-g" 'minibuffer-keyboard-quit)
 135 (define-key minibuffer-local-must-match-map "\C-g" 'minibuffer-keyboard-quit)
 136 (define-key minibuffer-local-isearch-map "\C-g" 'minibuffer-keyboard-quit)
 137
 138 (defun delsel-unload-hook ()
 139   (define-key minibuffer-local-map "\C-g" 'abort-recursive-edit)
 140   (define-key minibuffer-local-ns-map "\C-g" 'abort-recursive-edit)
 141   (define-key minibuffer-local-completion-map "\C-g" 'abort-recursive-edit)
 142   (define-key minibuffer-local-must-match-map "\C-g" 'abort-recursive-edit)
 143   (define-key minibuffer-local-isearch-map "\C-g" 'abort-recursive-edit))
 144
 145 (provide 'delsel)
 146
 147 ;;; delsel.el ends here