lisp/tool-bar.el

   1 ;;; tool-bar.el --- setting up the tool bar
   2 ;;
   3 ;; Copyright (C) 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5 ;;
   6 ;; Author: Dave Love <fx@gnu.org>
   7 ;; Keywords: mouse frames
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Provides `tool-bar-mode' to control display of the tool-bar and
  27 ;; bindings for the global tool bar with convenience functions
  28 ;; `tool-bar-add-item' and `tool-bar-add-item-from-menu'.
  29
  30 ;; The normal global binding for [tool-bar] (below) uses the value of
  31 ;; `tool-bar-map' as the actual keymap to define the tool bar.  Modes
  32 ;; may either bind items under the [tool-bar] prefix key of the local
  33 ;; map to add to the global bar or may set `tool-bar-map'
  34 ;; buffer-locally to override it.  (Some items are removed from the
  35 ;; global bar in modes which have `special' as their `mode-class'
  36 ;; property.)
  37
  38 ;; Todo: Somehow make tool bars easily customizable by the naive?
  39
  40 ;;; Code:
  41
  42 ;; The autoload cookie doesn't work when preloading.
  43 ;; Deleting it means invoking this command won't work
  44 ;; when you are on a tty.  I hope that won't cause too much trouble -- rms.
  45 (define-minor-mode tool-bar-mode
  46   "Toggle use of the tool bar.
  47 With numeric ARG, display the tool bar if and only if ARG is positive.
  48
  49 See `tool-bar-add-item' and `tool-bar-add-item-from-menu' for
  50 conveniently adding tool bar items."
  51   :init-value nil
  52   :global t
  53   :group 'mouse
  54   :group 'frames
  55   (if tool-bar-mode
  56       (progn
  57         (dolist (frame (frame-list))
  58           (if (display-graphic-p frame)
  59               (set-frame-parameter frame 'tool-bar-lines 1)))
  60         (if (= 1 (length (default-value 'tool-bar-map))) ; not yet setup
  61             (tool-bar-setup)))
  62     (modify-all-frames-parameters (list (cons 'tool-bar-lines 0)))))
  63
  64 ;;;###autoload
  65 ;; Used in the Show/Hide menu, to have the toggle reflect the current frame.
  66 (defun toggle-tool-bar-mode-from-frame (&optional arg)
  67   "Toggle tool bar on or off, based on the status of the current frame.
  68 See `tool-bar-mode' for more information."
  69   (interactive (list (or current-prefix-arg 'toggle)))
  70   (if (eq arg 'toggle)
  71       (tool-bar-mode (if (> (frame-parameter nil 'tool-bar-lines) 0) 0 1))
  72     (tool-bar-mode arg)))
  73
  74 ;;;###autoload
  75 ;; We want to pretend the toolbar by standard is on, as this will make
  76 ;; customize consider disabling the toolbar a customization, and save
  77 ;; that.  We could do this for real by setting :init-value above, but
  78 ;; that would turn on the toolbar in MS Windows where it is currently
  79 ;; useless, and it would overwrite disabling the tool bar from X
  80 ;; resources.  If anyone want to implement this in a cleaner way,
  81 ;; please do so.
  82 ;; -- Per Abrahamsen <abraham@dina.kvl.dk> 2002-02-21.
  83 (put 'tool-bar-mode 'standard-value '(t))
  84
  85 (defvar tool-bar-map (make-sparse-keymap)
  86   "Keymap for the tool bar.
  87 Define this locally to override the global tool bar.")
  88
  89 (global-set-key [tool-bar]
  90                 '(menu-item "tool bar" ignore
  91                             :filter tool-bar-make-keymap))
  92
  93 (declare-function image-mask-p "image.c" (spec &optional frame))
  94
  95 (defun tool-bar-make-keymap (&optional ignore)
  96   "Generate an actual keymap from `tool-bar-map'.
  97 Its main job is to figure out which images to use based on the display's
  98 color capability and based on the available image libraries."
  99   (mapcar (lambda (bind)
 100             (let (image-exp plist)
 101               (when (and (eq (car-safe (cdr-safe bind)) 'menu-item)
 102                          ;; For the format of menu-items, see node
 103                          ;; `Extended Menu Items' in the Elisp manual.
 104                          (setq plist (nthcdr (if (consp (nth 4 bind)) 5 4)
 105                                              bind))
 106                          (setq image-exp (plist-get plist :image))
 107                          (consp image-exp)
 108                          (not (eq (car image-exp) 'image))
 109                          (fboundp (car image-exp)))
 110                 (if (not (display-images-p))
 111                     (setq bind nil)
 112                   (let ((image (eval image-exp)))
 113                     (unless (and image (image-mask-p image))
 114                       (setq image (append image '(:mask heuristic))))
 115                     (setq bind (copy-sequence bind)
 116                           plist (nthcdr (if (consp (nth 4 bind)) 5 4)
 117                                         bind))
 118                     (plist-put plist :image image))))
 119               bind))
 120           tool-bar-map))
 121
 122 (defconst tool-bar-find-image-cache (make-hash-table :weakness t :test 'equal))
 123
 124 (defun tool-bar-find-image (specs)
 125   "Like `find-image' but with caching."
 126   (or (gethash specs tool-bar-find-image-cache)
 127       (puthash specs (find-image specs) tool-bar-find-image-cache)))
 128
 129 ;;;###autoload
 130 (defun tool-bar-add-item (icon def key &rest props)
 131   "Add an item to the tool bar.
 132 ICON names the image, DEF is the key definition and KEY is a symbol
 133 for the fake function key in the menu keymap.  Remaining arguments
 134 PROPS are additional items to add to the menu item specification.  See
 135 Info node `(elisp)Tool Bar'.  Items are added from left to right.
 136
 137 ICON is the base name of a file containing the image to use.  The
 138 function will first try to use low-color/ICON.xpm if `display-color-cells'
 139 is less or equal to 256, then ICON.xpm, then ICON.pbm, and finally
 140 ICON.xbm, using `find-image'.
 141
 142 Use this function only to make bindings in the global value of `tool-bar-map'.
 143 To define items in any other map, use `tool-bar-local-item'."
 144   (apply 'tool-bar-local-item icon def key tool-bar-map props))
 145
 146 ;;;###autoload
 147 (defun tool-bar-local-item (icon def key map &rest props)
 148   "Add an item to the tool bar in map MAP.
 149 ICON names the image, DEF is the key definition and KEY is a symbol
 150 for the fake function key in the menu keymap.  Remaining arguments
 151 PROPS are additional items to add to the menu item specification.  See
 152 Info node `(elisp)Tool Bar'.  Items are added from left to right.
 153
 154 ICON is the base name of a file containing the image to use.  The
 155 function will first try to use low-color/ICON.xpm if `display-color-cells'
 156 is less or equal to 256, then ICON.xpm, then ICON.pbm, and finally
 157 ICON.xbm, using `find-image'."
 158   (let* ((fg (face-attribute 'tool-bar :foreground))
 159          (bg (face-attribute 'tool-bar :background))
 160          (colors (nconc (if (eq fg 'unspecified) nil (list :foreground fg))
 161                         (if (eq bg 'unspecified) nil (list :background bg))))
 162          (xpm-spec (list :type 'xpm :file (concat icon ".xpm")))
 163          (xpm-lo-spec (list :type 'xpm :file
 164                             (concat "low-color/" icon ".xpm")))
 165          (pbm-spec (append (list :type 'pbm :file
 166                                  (concat icon ".pbm")) colors))
 167          (xbm-spec (append (list :type 'xbm :file
 168                                  (concat icon ".xbm")) colors))
 169          (image-exp `(tool-bar-find-image
 170                       (cond ((not (display-color-p))
 171                              ',(list pbm-spec xbm-spec xpm-lo-spec xpm-spec))
 172                             ((< (display-color-cells) 256)
 173                              ',(list xpm-lo-spec xpm-spec pbm-spec xbm-spec))
 174                             (t
 175                              ',(list xpm-spec pbm-spec xbm-spec))))))
 176     (define-key-after map (vector key)
 177       `(menu-item ,(symbol-name key) ,def :image ,image-exp ,@props))))
 178
 179 ;;;###autoload
 180 (defun tool-bar-add-item-from-menu (command icon &optional map &rest props)
 181   "Define tool bar binding for COMMAND in keymap MAP using the given ICON.
 182 This makes a binding for COMMAND in `tool-bar-map', copying its
 183 binding from the menu bar in MAP (which defaults to `global-map'), but
 184 modifies the binding by adding an image specification for ICON.  It
 185 finds ICON just like `tool-bar-add-item'.  PROPS are additional
 186 properties to add to the binding.
 187
 188 MAP must contain appropriate binding for `[menu-bar]' which holds a keymap.
 189
 190 Use this function only to make bindings in the global value of `tool-bar-map'.
 191 To define items in any other map, use `tool-bar-local-item-from-menu'."
 192   (apply 'tool-bar-local-item-from-menu command icon
 193          (default-value 'tool-bar-map) map props))
 194
 195 ;;;###autoload
 196 (defun tool-bar-local-item-from-menu (command icon in-map &optional from-map &rest props)
 197   "Define local tool bar binding for COMMAND using the given ICON.
 198 This makes a binding for COMMAND in IN-MAP, copying its binding from
 199 the menu bar in FROM-MAP (which defaults to `global-map'), but
 200 modifies the binding by adding an image specification for ICON.  It
 201 finds ICON just like `tool-bar-add-item'.  PROPS are additional
 202 properties to add to the binding.
 203
 204 FROM-MAP must contain appropriate binding for `[menu-bar]' which
 205 holds a keymap."
 206   (unless from-map
 207     (setq from-map global-map))
 208   (let* ((menu-bar-map (lookup-key from-map [menu-bar]))
 209          (keys (where-is-internal command menu-bar-map))
 210          (fg (face-attribute 'tool-bar :foreground))
 211          (bg (face-attribute 'tool-bar :background))
 212          (colors (nconc (if (eq fg 'unspecified) nil (list :foreground fg))
 213                         (if (eq bg 'unspecified) nil (list :background bg))))
 214          (xpm-spec (list :type 'xpm :file (concat icon ".xpm")))
 215          (xpm-lo-spec (list :type 'xpm :file
 216                             (concat "low-color/" icon ".xpm")))
 217          (pbm-spec (append (list :type 'pbm :file
 218                                  (concat icon ".pbm")) colors))
 219          (xbm-spec (append (list :type 'xbm :file
 220                                  (concat icon ".xbm")) colors))
 221          (image-exp `(tool-bar-find-image
 222                       (cond ((not (display-color-p))
 223                              ',(list pbm-spec xbm-spec xpm-lo-spec xpm-spec))
 224                             ((< (display-color-cells) 256)
 225                              ',(list xpm-lo-spec xpm-spec pbm-spec xbm-spec))
 226                             (t
 227                              ',(list xpm-spec pbm-spec xbm-spec)))))
 228          submap key)
 229     ;; We'll pick up the last valid entry in the list of keys if
 230     ;; there's more than one.
 231     (dolist (k keys)
 232       ;; We're looking for a binding of the command in a submap of
 233       ;; the menu bar map, so the key sequence must be two or more
 234       ;; long.
 235       (if (and (vectorp k)
 236                (> (length k) 1))
 237           (let ((m (lookup-key menu-bar-map (substring k 0 -1)))
 238                 ;; Last element in the bound key sequence:
 239                 (kk (aref k (1- (length k)))))
 240             (if (and (keymapp m)
 241                      (symbolp kk))
 242                 (setq submap m
 243                       key kk)))))
 244     (when (and (symbolp submap) (boundp submap))
 245       (setq submap (eval submap)))
 246     (let ((defn (assq key (cdr submap))))
 247       (if (eq (cadr defn) 'menu-item)
 248           (define-key-after in-map (vector key)
 249             (append (cdr defn) (list :image image-exp) props))
 250         (setq defn (cdr defn))
 251         (define-key-after in-map (vector key)
 252           (let ((rest (cdr defn)))
 253             ;; If the rest of the definition starts
 254             ;; with a list of menu cache info, get rid of that.
 255             (if (and (consp rest) (consp (car rest)))
 256                 (setq rest (cdr rest)))
 257             (append `(menu-item ,(car defn) ,rest)
 258                     (list :image image-exp) props)))))))
 259
 260 ;;; Set up some global items.  Additions/deletions up for grabs.
 261
 262 (defun tool-bar-setup ()
 263   ;; People say it's bad to have EXIT on the tool bar, since users
 264   ;; might inadvertently click that button.
 265   ;;(tool-bar-add-item-from-menu 'save-buffers-kill-emacs "exit")
 266   (tool-bar-add-item-from-menu 'find-file "new")
 267   (tool-bar-add-item-from-menu 'menu-find-file-existing "open")
 268   (tool-bar-add-item-from-menu 'dired "diropen")
 269   (tool-bar-add-item-from-menu 'kill-this-buffer "close")
 270   (tool-bar-add-item-from-menu 'save-buffer "save" nil
 271                                :visible '(or buffer-file-name
 272                                              (not (eq 'special
 273                                                       (get major-mode
 274                                                            'mode-class)))))
 275   (tool-bar-add-item-from-menu 'write-file "saveas" nil
 276                                :visible '(or buffer-file-name
 277                                              (not (eq 'special
 278                                                       (get major-mode
 279                                                            'mode-class)))))
 280   (tool-bar-add-item-from-menu 'undo "undo" nil
 281                                :visible '(not (eq 'special (get major-mode
 282                                                                 'mode-class))))
 283   (tool-bar-add-item-from-menu (lookup-key menu-bar-edit-menu [cut])
 284                                "cut" nil
 285                                :visible '(not (eq 'special (get major-mode
 286                                                                 'mode-class))))
 287   (tool-bar-add-item-from-menu (lookup-key menu-bar-edit-menu [copy])
 288                                "copy")
 289   (tool-bar-add-item-from-menu (lookup-key menu-bar-edit-menu [paste])
 290                                "paste" nil
 291                                :visible '(not (eq 'special (get major-mode
 292                                                                 'mode-class))))
 293   (tool-bar-add-item-from-menu 'nonincremental-search-forward "search")
 294   ;;(tool-bar-add-item-from-menu 'ispell-buffer "spell")
 295
 296   ;; There's no icon appropriate for News and we need a command rather
 297   ;; than a lambda for Read Mail.
 298   ;;(tool-bar-add-item-from-menu 'compose-mail "mail/compose")
 299
 300   (tool-bar-add-item-from-menu 'print-buffer "print")
 301
 302   ;; tool-bar-add-item-from-menu itself operates on
 303   ;; (default-value 'tool-bar-map), but when we don't use that function,
 304   ;; we must explicitly operate on the default value.
 305
 306   (let ((tool-bar-map (default-value 'tool-bar-map)))
 307     (tool-bar-add-item "preferences" 'customize 'customize
 308                        :help "Edit preferences (customize)")
 309
 310     (tool-bar-add-item "help" (lambda ()
 311                                 (interactive)
 312                                 (popup-menu menu-bar-help-menu))
 313                        'help
 314                        :help "Pop up the Help menu")))
 315
 316
 317 (provide 'tool-bar)
 318 ;; arch-tag: 15f30f0a-d0d7-4d50-bbb7-f48fd0c8582f
 319 ;;; tool-bar.el ends here