lisp/gnus/nnimap.el

   1 ;;; nnimap.el --- imap backend for Gnus
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005 Free Software Foundation, Inc.
   5
   6 ;; Author: Simon Josefsson <jas@pdc.kth.se>
   7 ;;         Jim Radford <radford@robby.caltech.edu>
   8 ;; Keywords: mail
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Todo, major things:
  30 ;;
  31 ;;   o Fix Gnus to view correct number of unread/total articles in group buffer
  32 ;;   o Fix Gnus to handle leading '.' in group names (fixed?)
  33 ;;   o Finish disconnected mode (moving articles between mailboxes unplugged)
  34 ;;   o Sieve
  35 ;;   o MIME (partial article fetches)
  36 ;;   o Split to other backends, different split rules for different
  37 ;;     servers/inboxes
  38 ;;
  39 ;; Todo, minor things:
  40 ;;
  41 ;;   o Don't require half of Gnus -- backends should be standalone
  42 ;;   o Verify that we don't use IMAP4rev1 specific things (RFC2060 App B)
  43 ;;   o Dont uid fetch 1,* in nnimap-retrive-groups (slow)
  44 ;;   o Split up big fetches (1,* header especially) in smaller chunks
  45 ;;   o What do I do with gnus-newsgroup-*?
  46 ;;   o Tell Gnus about new groups (how can we tell?)
  47 ;;   o Respooling (fix Gnus?) (unnecessary?)
  48 ;;   o Add support for the following: (if applicable)
  49 ;;       request-list-newsgroups, request-regenerate
  50 ;;       list-active-group,
  51 ;;       request-associate-buffer, request-restore-buffer,
  52 ;;   o Do The Right Thing when UIDVALIDITY changes (what's the right thing?)
  53 ;;   o Support RFC2221 (Login referrals)
  54 ;;   o IMAP2BIS compatibility? (RFC2061)
  55 ;;   o ACAP stuff (perhaps a different project, would be nice to ACAPify
  56 ;;     .newsrc.eld)
  57 ;;   o What about Gnus's article editing, can we support it?  NO!
  58 ;;   o Use \Draft to support the draft group??
  59 ;;   o Duplicate suppression
  60 ;;   o Rewrite UID SEARCH UID X as UID FETCH X (UID) for those with slow servers
  61
  62 ;;; Code:
  63
  64 (require 'imap)
  65 (require 'nnoo)
  66 (require 'nnmail)
  67 (require 'nnheader)
  68 (require 'mm-util)
  69 (require 'gnus)
  70 (require 'gnus-range)
  71 (require 'gnus-start)
  72 (require 'gnus-int)
  73
  74 (eval-when-compile (require 'cl))
  75
  76 (nnoo-declare nnimap)
  77
  78 (defconst nnimap-version "nnimap 1.0")
  79
  80 (defgroup nnimap nil
  81   "Reading IMAP mail with Gnus."
  82   :group 'gnus)
  83
  84 (defvoo nnimap-address nil
  85   "Address of physical IMAP server.  If nil, use the virtual server's name.")
  86
  87 (defvoo nnimap-server-port nil
  88   "Port number on physical IMAP server.
  89 If nil, defaults to 993 for TLS/SSL connections and 143 otherwise.")
  90
  91 ;; Splitting variables
  92
  93 (defcustom nnimap-split-crosspost t
  94   "If non-nil, do crossposting if several split methods match the mail.
  95 If nil, the first match found will be used."
  96   :group 'nnimap
  97   :type 'boolean)
  98
  99 (defcustom nnimap-split-inbox nil
 100   "Name of mailbox to split mail from.
 101
 102 Mail is read from this mailbox and split according to rules in
 103 `nnimap-split-rule'.
 104
 105 This can be a string or a list of strings."
 106   :group 'nnimap
 107   :type '(choice (string)
 108                  (repeat string)))
 109
 110 (define-widget 'nnimap-strict-function 'function
 111   "This widget only matches values that are functionp.
 112
 113 Warning: This means that a value that is the symbol of a not yet
 114 loaded function will not match.  Use with care."
 115   :match 'nnimap-strict-function-match)
 116
 117 (defun nnimap-strict-function-match (widget value)
 118   "Ignoring WIDGET, match if VALUE is a function."
 119   (functionp value))
 120
 121 (defcustom nnimap-split-rule nil
 122   "Mail will be split according to these rules.
 123
 124 Mail is read from mailbox(es) specified in `nnimap-split-inbox'.
 125
 126 If you'd like, for instance, one mail group for mail from the
 127 \"gnus-imap\" mailing list, one group for junk mail and leave
 128 everything else in the incoming mailbox, you could do something like
 129 this:
 130
 131 \(setq nnimap-split-rule '((\"INBOX.gnus-imap\"   \"From:.*gnus-imap\")
 132                           (\"INBOX.junk\"        \"Subject:.*buy\")))
 133
 134 As you can see, `nnimap-split-rule' is a list of lists, where the
 135 first element in each \"rule\" is the name of the IMAP mailbox (or the
 136 symbol `junk' if you want to remove the mail), and the second is a
 137 regexp that nnimap will try to match on the header to find a fit.
 138
 139 The second element can also be a function.  In that case, it will be
 140 called narrowed to the headers with the first element of the rule as
 141 the argument.  It should return a non-nil value if it thinks that the
 142 mail belongs in that group.
 143
 144 This variable can also have a function as its value, the function will
 145 be called with the headers narrowed and should return a group where it
 146 thinks the article should be splitted to.  See `nnimap-split-fancy'.
 147
 148 To allow for different split rules on different virtual servers, and
 149 even different split rules in different inboxes on the same server,
 150 the syntax of this variable have been extended along the lines of:
 151
 152 \(setq nnimap-split-rule
 153       '((\"my1server\"    (\".*\"    ((\"ding\"    \"ding@gnus.org\")
 154                                   (\"junk\"    \"From:.*Simon\")))
 155         (\"my2server\"    (\"INBOX\" nnimap-split-fancy))
 156         (\"my[34]server\" (\".*\"    ((\"private\" \"To:.*Simon\")
 157                                   (\"junk\"    my-junk-func)))))
 158
 159 The virtual server name is in fact a regexp, so that the same rules
 160 may apply to several servers.  In the example, the servers
 161 \"my3server\" and \"my4server\" both use the same rules.  Similarly,
 162 the inbox string is also a regexp.  The actual splitting rules are as
 163 before, either a function, or a list with group/regexp or
 164 group/function elements."
 165   :group 'nnimap
 166   :type '(choice :tag "Rule type"
 167                  (repeat :menu-tag "Single-server"
 168                          :tag "Single-server list"
 169                          (list (string :tag "Mailbox")
 170                                (choice :tag "Predicate"
 171                                        (regexp :tag "A regexp")
 172                                        (nnimap-strict-function :tag "A function"))))
 173                  (choice :menu-tag "A function"
 174                          :tag "A function"
 175                          (function-item nnimap-split-fancy)
 176                          (function-item nnmail-split-fancy)
 177                          (nnimap-strict-function :tag "User-defined function"))
 178                  (repeat :menu-tag "Multi-server (extended)"
 179                          :tag "Multi-server list"
 180                          (list (regexp :tag "Server regexp")
 181                                (list (regexp :tag "Incoming Mailbox regexp")
 182                                      (repeat :tag "Rules for matching server(s) and mailbox(es)"
 183                                              (list (string :tag "Destination mailbox")
 184                                                    (choice :tag "Predicate"
 185                                                            (regexp :tag "A Regexp")
 186                                                            (nnimap-strict-function :tag "A Function")))))))))
 187
 188 (defcustom nnimap-split-predicate "UNSEEN UNDELETED"
 189   "The predicate used to find articles to split.
 190 If you use another IMAP client to peek on articles but always would
 191 like nnimap to split them once it's started, you could change this to
 192 \"UNDELETED\". Other available predicates are available in
 193 RFC2060 section 6.4.4."
 194   :group 'nnimap
 195   :type 'string)
 196
 197 (defcustom nnimap-split-fancy nil
 198   "Like the variable `nnmail-split-fancy'."
 199   :group 'nnimap
 200   :type 'sexp)
 201
 202 (defvar nnimap-split-download-body-default nil
 203   "Internal variable with default value for `nnimap-split-download-body'.")
 204
 205 (defcustom nnimap-split-download-body 'default
 206   "Whether to download entire articles during splitting.
 207 This is generally not required, and will slow things down considerably.
 208 You may need it if you want to use an advanced splitting function that
 209 analyzes the body before splitting the article.
 210 If this variable is nil, bodies will not be downloaded; if this
 211 variable is the symbol `default' the default behaviour is
 212 used (which currently is nil, unless you use a statistical
 213 spam.el test); if this variable is another non-nil value bodies
 214 will be downloaded."
 215   :version "22.1"
 216   :group 'nnimap
 217   :type '(choice (const :tag "Let system decide" deault)
 218                  boolean))
 219
 220 ;; Performance / bug workaround variables
 221
 222 (defcustom nnimap-close-asynchronous t
 223   "Close mailboxes asynchronously in `nnimap-close-group'.
 224 This means that errors caught by nnimap when closing the mailbox will
 225 not prevent Gnus from updating the group status, which may be harmful.
 226 However, it increases speed."
 227   :version "22.1"
 228   :type 'boolean
 229   :group 'nnimap)
 230
 231 (defcustom nnimap-dont-close t
 232   "Never close mailboxes.
 233 This increases the speed of closing mailboxes (quiting group) but may
 234 decrease the speed of selecting another mailbox later.  Re-selecting
 235 the same mailbox will be faster though."
 236   :version "22.1"
 237   :type 'boolean
 238   :group 'nnimap)
 239
 240 (defcustom nnimap-retrieve-groups-asynchronous t
 241   "Send asynchronous STATUS commands for each mailbox before checking mail.
 242 If you have mailboxes that rarely receives mail, this speeds up new
 243 mail checking.  It works by first sending STATUS commands for each
 244 mailbox, and then only checking groups which has a modified UIDNEXT
 245 more carefully for new mail.
 246
 247 In summary, the default is O((1-p)*k+p*n) and changing it to nil makes
 248 it O(n).  If p is small, then the default is probably faster."
 249   :version "22.1"
 250   :type 'boolean
 251   :group 'nnimap)
 252
 253 (defvoo nnimap-need-unselect-to-notice-new-mail nil
 254   "Unselect mailboxes before looking for new mail in them.
 255 Some servers seem to need this under some circumstances.")
 256
 257 ;; Authorization / Privacy variables
 258
 259 (defvoo nnimap-auth-method nil
 260   "Obsolete.")
 261
 262 (defvoo nnimap-stream nil
 263   "How nnimap will connect to the server.
 264
 265 The default, nil, will try to use the \"best\" method the server can
 266 handle.
 267
 268 Change this if
 269
 270 1) you want to connect with TLS/SSL.  The TLS/SSL integration
 271    with IMAP is suboptimal so you'll have to tell it
 272    specifically.
 273
 274 2) your server is more capable than your environment -- i.e. your
 275    server accept Kerberos login's but you haven't installed the
 276    `imtest' program or your machine isn't configured for Kerberos.
 277
 278 Possible choices: gssapi, kerberos4, starttls, tls, ssl, network, shell.
 279 See also `imap-streams' and `imap-stream-alist'.")
 280
 281 (defvoo nnimap-authenticator nil
 282   "How nnimap authenticate itself to the server.
 283
 284 The default, nil, will try to use the \"best\" method the server can
 285 handle.
 286
 287 There is only one reason for fiddling with this variable, and that is
 288 if your server is more capable than your environment -- i.e. you
 289 connect to a server that accept Kerberos login's but you haven't
 290 installed the `imtest' program or your machine isn't configured for
 291 Kerberos.
 292
 293 Possible choices: gssapi, kerberos4, digest-md5, cram-md5, login, anonymous.
 294 See also `imap-authenticators' and `imap-authenticator-alist'")
 295
 296 (defvoo nnimap-directory (nnheader-concat gnus-directory "overview/")
 297   "Directory to keep NOV cache files for nnimap groups.
 298 See also `nnimap-nov-file-name'.")
 299
 300 (defvoo nnimap-nov-file-name "nnimap."
 301   "NOV cache base filename.
 302 The group name and `nnimap-nov-file-name-suffix' will be appended.  A
 303 typical complete file name would be
 304 ~/News/overview/nnimap.pdc.INBOX.ding.nov, or
 305 ~/News/overview/nnimap/pdc/INBOX/ding/nov if
 306 `nnmail-use-long-file-names' is nil")
 307
 308 (defvoo nnimap-nov-file-name-suffix ".novcache"
 309   "Suffix for NOV cache base filename.")
 310
 311 (defvoo nnimap-nov-is-evil gnus-agent
 312   "If non-nil, never generate or use a local nov database for this backend.
 313 Using nov databases should speed up header fetching considerably.
 314 However, it will invoke a UID SEARCH UID command on the server, and
 315 some servers implement this command inefficiently by opening each and
 316 every message in the group, thus making it quite slow.
 317 Unlike other backends, you do not need to take special care if you
 318 flip this variable.")
 319
 320 (defvoo nnimap-search-uids-not-since-is-evil nil
 321   "If non-nil, avoid \"UID SEARCH UID ... NOT SINCE\" queries when expiring.
 322 Instead, use \"UID SEARCH SINCE\" to prune the list of expirable
 323 articles within Gnus.  This seems to be faster on Courier in some cases.")
 324
 325 (defvoo nnimap-expunge-on-close 'always ; 'ask, 'never
 326   "Whether to expunge a group when it is closed.
 327 When a IMAP group with articles marked for deletion is closed, this
 328 variable determine if nnimap should actually remove the articles or
 329 not.
 330
 331 If always, nnimap always perform a expunge when closing the group.
 332 If never, nnimap never expunges articles marked for deletion.
 333 If ask, nnimap will ask you if you wish to expunge marked articles.
 334
 335 When setting this variable to `never', you can only expunge articles
 336 by using `G x' (gnus-group-nnimap-expunge) from the Group buffer.")
 337
 338 (defvoo nnimap-list-pattern "*"
 339   "A string LIMIT or list of strings with mailbox wildcards used to limit available groups.
 340 See below for available wildcards.
 341
 342 The LIMIT string can be a cons cell (REFERENCE . LIMIT), where
 343 REFERENCE will be passed as the first parameter to LIST/LSUB.  The
 344 semantics of this are server specific, on the University of Washington
 345 server you can specify a directory.
 346
 347 Example:
 348  '(\"INBOX\" \"mail/*\" (\"~friend/mail/\" . \"list/*\"))
 349
 350 There are two wildcards * and %. * matches everything, % matches
 351 everything in the current hierarchy.")
 352
 353 (defvoo nnimap-news-groups nil
 354   "IMAP support a news-like mode, also known as bulletin board mode,
 355 where replies is sent via IMAP instead of SMTP.
 356
 357 This variable should contain a regexp matching groups where you wish
 358 replies to be stored to the mailbox directly.
 359
 360 Example:
 361   '(\"^[^I][^N][^B][^O][^X].*$\")
 362
 363 This will match all groups not beginning with \"INBOX\".
 364
 365 Note that there is nothing technically different between mail-like and
 366 news-like mailboxes.  If you wish to have a group with todo items or
 367 similar which you wouldn't want to set up a mailing list for, you can
 368 use this to make replies go directly to the group.")
 369
 370 (defvoo nnimap-expunge-search-string "UID %s NOT SINCE %s"
 371   "IMAP search command to use for articles that are to be expired.
 372 The first %s is replaced by a UID set of articles to search on,
 373 and the second %s is replaced by a date criterium.
 374
 375 One useful (and perhaps the only useful) value to change this to would
 376 be `UID %s NOT SENTSINCE %s' to make nnimap use the Date: header
 377 instead of the internal date of messages.  See section 6.4.4 of RFC
 378 2060 for more information on valid strings.")
 379
 380 (defvoo nnimap-importantize-dormant t
 381   "If non-nil, mark \"dormant\" articles as \"ticked\" for other IMAP clients.
 382 Note that within Gnus, dormant articles will still (only) be
 383 marked as ticked.  This is to make \"dormant\" articles stand out,
 384 just like \"ticked\" articles, in other IMAP clients.")
 385
 386 (defvoo nnimap-server-address nil
 387   "Obsolete.  Use `nnimap-address'.")
 388
 389 (defcustom nnimap-authinfo-file "~/.authinfo"
 390   "Authorization information for IMAP servers.  In .netrc format."
 391   :type
 392   '(choice file
 393            (repeat :tag "Entries"
 394                    :menu-tag "Inline"
 395                    (list :format "%v"
 396                          :value ("" ("login" . "") ("password" . ""))
 397                          (string :tag "Host")
 398                          (checklist :inline t
 399                                     (cons :format "%v"
 400                                           (const :format "" "login")
 401                                           (string :format "Login: %v"))
 402                                     (cons :format "%v"
 403                                           (const :format "" "password")
 404                                           (string :format "Password: %v"))))))
 405   :group 'nnimap)
 406
 407 (defcustom nnimap-prune-cache t
 408   "If non-nil, nnimap check whether articles still exist on server before using data stored in NOV cache."
 409   :type 'boolean
 410   :group 'nnimap)
 411
 412 (defvar nnimap-request-list-method 'imap-mailbox-list
 413   "Method to use to request a list of all folders from the server.
 414 If this is 'imap-mailbox-lsub, then use a server-side subscription list to
 415 restrict visible folders.")
 416
 417 (defcustom nnimap-debug nil
 418   "If non-nil, random debug spews are placed in *nnimap-debug* buffer.
 419 Note that username, passwords and other privacy sensitive
 420 information (such as e-mail) may be stored in the *nnimap-debug*
 421 buffer.  It is not written to disk, however.  Do not enable this
 422 variable unless you are comfortable with that."
 423   :group 'nnimap
 424   :type 'boolean)
 425
 426 ;; Internal variables:
 427
 428 (defvar nnimap-debug-buffer "*nnimap-debug*")
 429 (defvar nnimap-mailbox-info (gnus-make-hashtable 997))
 430 (defvar nnimap-current-move-server nil)
 431 (defvar nnimap-current-move-group nil)
 432 (defvar nnimap-current-move-article nil)
 433 (defvar nnimap-length)
 434 (defvar nnimap-progress-chars '(?| ?/ ?- ?\\))
 435 (defvar nnimap-progress-how-often 20)
 436 (defvar nnimap-counter)
 437 (defvar nnimap-server-buffer-alist nil) ;; Map server name to buffers.
 438 (defvar nnimap-current-server nil) ;; Current server
 439 (defvar nnimap-server-buffer nil) ;; Current servers' buffer
 440
 441 \f
 442
 443 (nnoo-define-basics nnimap)
 444
 445 ;; Utility functions:
 446
 447 (defsubst nnimap-get-server-buffer (server)
 448   "Return buffer for SERVER, if nil use current server."
 449   (cadr (assoc (or server nnimap-current-server) nnimap-server-buffer-alist)))
 450
 451 (defun nnimap-possibly-change-server (server)
 452   "Return buffer for SERVER, changing the current server as a side-effect.
 453 If SERVER is nil, uses the current server."
 454   (setq nnimap-current-server (or server nnimap-current-server)
 455         nnimap-server-buffer (nnimap-get-server-buffer nnimap-current-server)))
 456
 457 (defun nnimap-verify-uidvalidity (group server)
 458   "Verify stored uidvalidity match current one in GROUP on SERVER."
 459   (let* ((gnusgroup (gnus-group-prefixed-name
 460                      group (gnus-server-to-method
 461                             (format "nnimap:%s" server))))
 462          (new-uidvalidity (imap-mailbox-get 'uidvalidity))
 463          (old-uidvalidity (gnus-group-get-parameter gnusgroup 'uidvalidity))
 464          (dir (file-name-as-directory (expand-file-name nnimap-directory)))
 465          (nameuid (nnheader-translate-file-chars
 466                    (concat nnimap-nov-file-name
 467                            (if (equal server "")
 468                                "unnamed"
 469                              server) "." group "." old-uidvalidity
 470                            nnimap-nov-file-name-suffix) t))
 471          (file (if (or nnmail-use-long-file-names
 472                        (file-exists-p (expand-file-name nameuid dir)))
 473                    (expand-file-name nameuid dir)
 474                  (expand-file-name
 475                   (mm-encode-coding-string
 476                    (nnheader-replace-chars-in-string nameuid ?. ?/)
 477                    nnmail-pathname-coding-system)
 478                   dir))))
 479     (if old-uidvalidity
 480         (if (not (equal old-uidvalidity new-uidvalidity))
 481             ;; uidvalidity clash
 482             (gnus-delete-file file)
 483           (gnus-group-set-parameter gnusgroup 'uidvalidity new-uidvalidity)
 484           t)
 485       (gnus-group-add-parameter gnusgroup (cons 'uidvalidity new-uidvalidity))
 486       t)))
 487
 488 (defun nnimap-before-find-minmax-bugworkaround ()
 489   "Function called before iterating through mailboxes with
 490 `nnimap-find-minmax-uid'."
 491   (when nnimap-need-unselect-to-notice-new-mail
 492     ;; XXX this is for UoW imapd problem, it doesn't notice new mail in
 493     ;; currently selected mailbox without a re-select/examine.
 494     (or (null (imap-current-mailbox nnimap-server-buffer))
 495         (imap-mailbox-unselect nnimap-server-buffer))))
 496
 497 (defun nnimap-find-minmax-uid (group &optional examine)
 498   "Find lowest and highest active article number in GROUP.
 499 If EXAMINE is non-nil the group is selected read-only."
 500   (with-current-buffer nnimap-server-buffer
 501     (when (or (string= group (imap-current-mailbox))
 502               (imap-mailbox-select group examine))
 503       (let (minuid maxuid)
 504         (when (> (imap-mailbox-get 'exists) 0)
 505           (imap-fetch "1,*" "UID" nil 'nouidfetch)
 506           (imap-message-map (lambda (uid Uid)
 507                               (setq minuid (if minuid (min minuid uid) uid)
 508                                     maxuid (if maxuid (max maxuid uid) uid)))
 509                             'UID))
 510         (list (imap-mailbox-get 'exists) minuid maxuid)))))
 511
 512 (defun nnimap-possibly-change-group (group &optional server)
 513   "Make GROUP the current group, and SERVER the current server."
 514   (when (nnimap-possibly-change-server server)
 515     (with-current-buffer nnimap-server-buffer
 516       (if (or (null group) (imap-current-mailbox-p group))
 517           imap-current-mailbox
 518         (if (imap-mailbox-select group)
 519             (if (or (nnimap-verify-uidvalidity
 520                      group (or server nnimap-current-server))
 521                     (zerop (imap-mailbox-get 'exists group))
 522                     t ;; for OGnus to see if ignoring uidvalidity
 523                     ;; changes has any bad effects.
 524                     (yes-or-no-p
 525                      (format
 526                       "nnimap: Group %s is not uidvalid.  Continue? " group)))
 527                 imap-current-mailbox
 528               (imap-mailbox-unselect)
 529               (error "nnimap: Group %s is not uid-valid" group))
 530           (nnheader-report 'nnimap (imap-error-text)))))))
 531
 532 (defun nnimap-replace-whitespace (string)
 533   "Return STRING with all whitespace replaced with space."
 534   (when string
 535     (while (string-match "[\r\n\t]+" string)
 536       (setq string (replace-match " " t t string)))
 537     string))
 538
 539 ;; Required backend functions
 540
 541 (defun nnimap-retrieve-headers-progress ()
 542   "Hook to insert NOV line for current article into `nntp-server-buffer'."
 543   (and (numberp nnmail-large-newsgroup)
 544        (zerop (% (incf nnimap-counter) nnimap-progress-how-often))
 545        (> nnimap-length nnmail-large-newsgroup)
 546        (nnheader-message 6 "nnimap: Retrieving headers... %c"
 547                          (nth (/ (% nnimap-counter
 548                                     (* (length nnimap-progress-chars)
 549                                        nnimap-progress-how-often))
 550                                  nnimap-progress-how-often)
 551                               nnimap-progress-chars)))
 552   (with-current-buffer nntp-server-buffer
 553     (let (headers lines chars uid mbx)
 554       (with-current-buffer nnimap-server-buffer
 555         (setq uid imap-current-message
 556               mbx imap-current-mailbox
 557               headers (nnimap-demule
 558                        (if (imap-capability 'IMAP4rev1)
 559                            ;; xxx don't just use car? alist doesn't contain
 560                            ;; anything else now, but it might...
 561                            (nth 2 (car (imap-message-get uid 'BODYDETAIL)))
 562                          (imap-message-get uid 'RFC822.HEADER)))
 563               lines (imap-body-lines (imap-message-body imap-current-message))
 564               chars (imap-message-get imap-current-message 'RFC822.SIZE)))
 565       (nnheader-insert-nov
 566        (with-temp-buffer
 567          (buffer-disable-undo)
 568          (insert headers)
 569          (let ((head (nnheader-parse-naked-head)))
 570            (mail-header-set-number head uid)
 571            (mail-header-set-chars head chars)
 572            (mail-header-set-lines head lines)
 573            (mail-header-set-xref
 574             head (format "%s %s:%d" (system-name) mbx uid))
 575            head))))))
 576
 577 (defun nnimap-retrieve-which-headers (articles fetch-old)
 578   "Get a range of articles to fetch based on ARTICLES and FETCH-OLD."
 579   (with-current-buffer nnimap-server-buffer
 580     (if (numberp (car-safe articles))
 581         (imap-search
 582          (concat "UID "
 583                  (imap-range-to-message-set
 584                   (gnus-compress-sequence
 585                    (append (gnus-uncompress-sequence
 586                             (and fetch-old
 587                                  (cons (if (numberp fetch-old)
 588                                            (max 1 (- (car articles) fetch-old))
 589                                          1)
 590                                        (1- (car articles)))))
 591                            articles)))))
 592       (mapcar (lambda (msgid)
 593                 (imap-search
 594                  (format "HEADER Message-Id \"%s\"" msgid)))
 595               articles))))
 596
 597 (defun nnimap-group-overview-filename (group server)
 598   "Make file name for GROUP on SERVER."
 599   (let* ((dir (file-name-as-directory (expand-file-name nnimap-directory)))
 600          (uidvalidity (gnus-group-get-parameter
 601                        (gnus-group-prefixed-name
 602                         group (gnus-server-to-method
 603                                (format "nnimap:%s" server)))
 604                        'uidvalidity))
 605          (name (nnheader-translate-file-chars
 606                 (concat nnimap-nov-file-name
 607                         (if (equal server "")
 608                             "unnamed"
 609                           server) "." group nnimap-nov-file-name-suffix) t))
 610          (nameuid (nnheader-translate-file-chars
 611                    (concat nnimap-nov-file-name
 612                            (if (equal server "")
 613                                "unnamed"
 614                              server) "." group "." uidvalidity
 615                            nnimap-nov-file-name-suffix) t))
 616          (oldfile (if (or nnmail-use-long-file-names
 617                           (file-exists-p (expand-file-name name dir)))
 618                       (expand-file-name name dir)
 619                     (expand-file-name
 620                      (mm-encode-coding-string
 621                       (nnheader-replace-chars-in-string name ?. ?/)
 622                       nnmail-pathname-coding-system)
 623                      dir)))
 624          (newfile (if (or nnmail-use-long-file-names
 625                           (file-exists-p (expand-file-name nameuid dir)))
 626                       (expand-file-name nameuid dir)
 627                     (expand-file-name
 628                      (mm-encode-coding-string
 629                       (nnheader-replace-chars-in-string nameuid ?. ?/)
 630                       nnmail-pathname-coding-system)
 631                      dir))))
 632     (when (and (file-exists-p oldfile) (not (file-exists-p newfile)))
 633       (message "nnimap: Upgrading novcache filename...")
 634       (sit-for 1)
 635       (gnus-make-directory (file-name-directory newfile))
 636       (unless (ignore-errors (rename-file oldfile newfile) t)
 637         (if (ignore-errors (copy-file oldfile newfile) t)
 638             (delete-file oldfile)
 639           (error "Can't rename `%s' to `%s'" oldfile newfile))))
 640     newfile))
 641
 642 (defun nnimap-retrieve-headers-from-file (group server)
 643   (with-current-buffer nntp-server-buffer
 644     (let ((nov (nnimap-group-overview-filename group server)))
 645       (when (file-exists-p nov)
 646         (mm-insert-file-contents nov)
 647         (set-buffer-modified-p nil)
 648         (let ((min (ignore-errors (goto-char (point-min))
 649                                   (read (current-buffer))))
 650               (max (ignore-errors (goto-char (point-max))
 651                                   (forward-line -1)
 652                                   (read (current-buffer)))))
 653           (if (and (numberp min) (numberp max))
 654               (cons min max)
 655             ;; junk, remove it, it's saved later
 656             (erase-buffer)
 657             nil))))))
 658
 659 (defun nnimap-retrieve-headers-from-server (articles group server)
 660   (with-current-buffer nnimap-server-buffer
 661     (let ((imap-fetch-data-hook '(nnimap-retrieve-headers-progress))
 662           (nnimap-length (gnus-range-length articles))
 663           (nnimap-counter 0))
 664       (imap-fetch (imap-range-to-message-set articles)
 665                   (concat "(UID RFC822.SIZE BODY "
 666                           (let ((headers
 667                                  (append '(Subject From Date Message-Id
 668                                                    References In-Reply-To Xref)
 669                                          (copy-sequence
 670                                           nnmail-extra-headers))))
 671                             (if (imap-capability 'IMAP4rev1)
 672                                 (format "BODY.PEEK[HEADER.FIELDS %s])" headers)
 673                               (format "RFC822.HEADER.LINES %s)" headers)))))
 674       (with-current-buffer nntp-server-buffer
 675         (sort-numeric-fields 1 (point-min) (point-max)))
 676       (and (numberp nnmail-large-newsgroup)
 677            (> nnimap-length nnmail-large-newsgroup)
 678            (nnheader-message 6 "nnimap: Retrieving headers...done")))))
 679
 680 (defun nnimap-dont-use-nov-p (group server)
 681   (or gnus-nov-is-evil nnimap-nov-is-evil
 682       (unless (and (gnus-make-directory
 683                     (file-name-directory
 684                      (nnimap-group-overview-filename group server)))
 685                    (file-writable-p
 686                     (nnimap-group-overview-filename group server)))
 687         (message "nnimap: Nov cache not writable, %s"
 688                  (nnimap-group-overview-filename group server)))))
 689
 690 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 691   (when (nnimap-possibly-change-group group server)
 692     (with-current-buffer nntp-server-buffer
 693       (erase-buffer)
 694       (if (nnimap-dont-use-nov-p group server)
 695           (nnimap-retrieve-headers-from-server
 696            (gnus-compress-sequence articles) group server)
 697         (let (uids cached low high)
 698           (when (setq uids (nnimap-retrieve-which-headers articles fetch-old)
 699                       low (car uids)
 700                       high (car (last uids)))
 701             (if (setq cached (nnimap-retrieve-headers-from-file group server))
 702                 (progn
 703                   ;; fetch articles with uids before cache block
 704                   (when (< low (car cached))
 705                     (goto-char (point-min))
 706                     (nnimap-retrieve-headers-from-server
 707                      (cons low (1- (car cached))) group server))
 708                   ;; fetch articles with uids after cache block
 709                   (when (> high (cdr cached))
 710                     (goto-char (point-max))
 711                     (nnimap-retrieve-headers-from-server
 712                      (cons (1+ (cdr cached)) high) group server))
 713                   (when nnimap-prune-cache
 714                     ;; remove nov's for articles which has expired on server
 715                     (goto-char (point-min))
 716                     (dolist (uid (gnus-set-difference articles uids))
 717                       (when (re-search-forward (format "^%d\t" uid) nil t)
 718                         (gnus-delete-line)))))
 719               ;; nothing cached, fetch whole range from server
 720               (nnimap-retrieve-headers-from-server
 721                (cons low high) group server))
 722             (when (buffer-modified-p)
 723               (nnmail-write-region
 724                (point-min) (point-max)
 725                (nnimap-group-overview-filename group server) nil 'nomesg))
 726             (nnheader-nov-delete-outside-range low high))))
 727       'nov)))
 728
 729 (defun nnimap-open-connection (server)
 730   (if (not (imap-open nnimap-address nnimap-server-port nnimap-stream
 731                       nnimap-authenticator nnimap-server-buffer))
 732       (nnheader-report 'nnimap "Can't open connection to server %s" server)
 733     (unless (or (imap-capability 'IMAP4 nnimap-server-buffer)
 734                 (imap-capability 'IMAP4rev1 nnimap-server-buffer))
 735       (imap-close nnimap-server-buffer)
 736       (nnheader-report 'nnimap "Server %s is not IMAP4 compliant" server))
 737     (let* ((list (progn (gnus-message 7 "Parsing authinfo file `%s'."
 738                                       nnimap-authinfo-file)
 739                         (gnus-parse-netrc nnimap-authinfo-file)))
 740            (port (if nnimap-server-port
 741                      (int-to-string nnimap-server-port)
 742                    "imap"))
 743            (alist (or (gnus-netrc-machine list server port "imap")
 744                       (gnus-netrc-machine list server port "imaps")
 745                       (gnus-netrc-machine list
 746                                           (or nnimap-server-address
 747                                               nnimap-address)
 748                                           port "imap")
 749                       (gnus-netrc-machine list
 750                                           (or nnimap-server-address
 751                                               nnimap-address)
 752                                           port "imaps")))
 753            (user (gnus-netrc-get alist "login"))
 754            (passwd (gnus-netrc-get alist "password")))
 755       (if (imap-authenticate user passwd nnimap-server-buffer)
 756           (prog1
 757               (push (list server nnimap-server-buffer)
 758                     nnimap-server-buffer-alist)
 759             (nnimap-possibly-change-server server))
 760         (imap-close nnimap-server-buffer)
 761         (kill-buffer nnimap-server-buffer)
 762         (nnheader-report 'nnimap "Could not authenticate to %s" server)))))
 763
 764 (deffoo nnimap-open-server (server &optional defs)
 765   (nnheader-init-server-buffer)
 766   (if (nnimap-server-opened server)
 767       t
 768     (unless (assq 'nnimap-server-buffer defs)
 769       (push (list 'nnimap-server-buffer (concat " *nnimap* " server)) defs))
 770     ;; translate `nnimap-server-address' to `nnimap-address' in defs
 771     ;; for people that configured nnimap with a very old version
 772     (unless (assq 'nnimap-address defs)
 773       (if (assq 'nnimap-server-address defs)
 774           (push (list 'nnimap-address
 775                       (cadr (assq 'nnimap-server-address defs))) defs)
 776         (push (list 'nnimap-address server) defs)))
 777     (nnoo-change-server 'nnimap server defs)
 778     (or nnimap-server-buffer
 779         (setq nnimap-server-buffer (cadr (assq 'nnimap-server-buffer defs))))
 780     (with-current-buffer (get-buffer-create nnimap-server-buffer)
 781       (nnoo-change-server 'nnimap server defs))
 782     (or (and nnimap-server-buffer
 783              (imap-opened nnimap-server-buffer)
 784              (if (with-current-buffer nnimap-server-buffer
 785                    (memq imap-state '(auth select examine)))
 786                  t
 787                (imap-close nnimap-server-buffer)
 788                (nnimap-open-connection server)))
 789         (nnimap-open-connection server))))
 790
 791 (deffoo nnimap-server-opened (&optional server)
 792   "Whether SERVER is opened.
 793 If SERVER is the current virtual server, and the connection to the
 794 physical server is alive, this function return a non-nil value.  If
 795 SERVER is nil, it is treated as the current server."
 796   ;; clean up autologouts??
 797   (and (or server nnimap-current-server)
 798        (nnoo-server-opened 'nnimap (or server nnimap-current-server))
 799        (imap-opened (nnimap-get-server-buffer server))))
 800
 801 (deffoo nnimap-close-server (&optional server)
 802   "Close connection to server and free all resources connected to it.
 803 Return nil if the server couldn't be closed for some reason."
 804   (let ((server (or server nnimap-current-server)))
 805     (when (or (nnimap-server-opened server)
 806               (imap-opened (nnimap-get-server-buffer server)))
 807       (imap-close (nnimap-get-server-buffer server))
 808       (kill-buffer (nnimap-get-server-buffer server))
 809       (setq nnimap-server-buffer nil
 810             nnimap-current-server nil
 811             nnimap-server-buffer-alist
 812             (delq server nnimap-server-buffer-alist)))
 813     (nnoo-close-server 'nnimap server)))
 814
 815 (deffoo nnimap-request-close ()
 816   "Close connection to all servers and free all resources that the backend have reserved.
 817 All buffers that have been created by that
 818 backend should be killed.  (Not the nntp-server-buffer, though.) This
 819 function is generally only called when Gnus is shutting down."
 820   (mapcar (lambda (server) (nnimap-close-server (car server)))
 821           nnimap-server-buffer-alist)
 822   (setq nnimap-server-buffer-alist nil))
 823
 824 (deffoo nnimap-status-message (&optional server)
 825   "This function returns the last error message from server."
 826   (when (nnimap-possibly-change-server server)
 827     (nnoo-status-message 'nnimap server)))
 828
 829 (defun nnimap-demule (string)
 830   ;; BEWARE: we used to use string-as-multibyte here which is braindead
 831   ;; because it will turn accidental emacs-mule-valid byte sequences
 832   ;; into multibyte chars.  --Stef
 833   ;; Reverted, braindead got 7.5 out of 10 on imdb, so it can't be
 834   ;; that bad. --Simon
 835   (funcall (if (and (fboundp 'string-as-multibyte)
 836                     (subrp (symbol-function 'string-as-multibyte)))
 837                'string-as-multibyte
 838              'identity)
 839            (or string "")))
 840
 841 (defun nnimap-make-callback (article gnus-callback buffer)
 842   "Return a callback function."
 843   `(lambda ()
 844      (nnimap-callback ,article ,gnus-callback ,buffer)))
 845
 846 (defun nnimap-callback (article gnus-callback buffer)
 847   (when (eq article (imap-current-message))
 848     (remove-hook 'imap-fetch-data-hook
 849                  (nnimap-make-callback article gnus-callback buffer))
 850     (with-current-buffer buffer
 851       (insert
 852        (with-current-buffer nnimap-server-buffer
 853          (nnimap-demule
 854           (if (imap-capability 'IMAP4rev1)
 855               ;; xxx don't just use car? alist doesn't contain
 856               ;; anything else now, but it might...
 857               (nth 2 (car (imap-message-get article 'BODYDETAIL)))
 858             (imap-message-get article 'RFC822)))))
 859       (nnheader-ms-strip-cr)
 860       (funcall gnus-callback t))))
 861
 862 (defun nnimap-request-article-part (article part prop &optional
 863                                             group server to-buffer detail)
 864   (when (nnimap-possibly-change-group group server)
 865     (let ((article (if (stringp article)
 866                        (car-safe (imap-search
 867                                   (format "HEADER Message-Id \"%s\"" article)
 868                                   nnimap-server-buffer))
 869                      article)))
 870       (when article
 871         (gnus-message 10 "nnimap: Fetching (part of) article %d from %s..."
 872                       article (or group imap-current-mailbox
 873                                   gnus-newsgroup-name))
 874         (if (not nnheader-callback-function)
 875             (with-current-buffer (or to-buffer nntp-server-buffer)
 876               (erase-buffer)
 877               (let ((data (imap-fetch article part prop nil
 878                                       nnimap-server-buffer)))
 879                 (insert (nnimap-demule (if detail
 880                                            (nth 2 (car data))
 881                                          data))))
 882               (nnheader-ms-strip-cr)
 883               (gnus-message
 884                10 "nnimap: Fetching (part of) article %d from %s...done"
 885                article (or group imap-current-mailbox gnus-newsgroup-name))
 886               (if (bobp)
 887                   (nnheader-report 'nnimap "No such article %d in %s: %s"
 888                                    article (or group imap-current-mailbox
 889                                                gnus-newsgroup-name)
 890                                    (imap-error-text nnimap-server-buffer))
 891                 (cons group article)))
 892           (add-hook 'imap-fetch-data-hook
 893                     (nnimap-make-callback article
 894                                           nnheader-callback-function
 895                                           nntp-server-buffer))
 896           (imap-fetch-asynch article part nil nnimap-server-buffer)
 897           (cons group article))))))
 898
 899 (deffoo nnimap-asynchronous-p ()
 900   t)
 901
 902 (deffoo nnimap-request-article (article &optional group server to-buffer)
 903   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 904       (nnimap-request-article-part
 905        article "BODY.PEEK[]" 'BODYDETAIL group server to-buffer 'detail)
 906     (nnimap-request-article-part
 907      article "RFC822.PEEK" 'RFC822 group server to-buffer)))
 908
 909 (deffoo nnimap-request-head (article &optional group server to-buffer)
 910   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 911       (nnimap-request-article-part
 912        article "BODY.PEEK[HEADER]" 'BODYDETAIL group server to-buffer 'detail)
 913     (nnimap-request-article-part
 914      article "RFC822.HEADER" 'RFC822.HEADER group server to-buffer)))
 915
 916 (deffoo nnimap-request-body (article &optional group server to-buffer)
 917   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 918       (nnimap-request-article-part
 919        article "BODY.PEEK[TEXT]" 'BODYDETAIL group server to-buffer 'detail)
 920     (nnimap-request-article-part
 921      article "RFC822.TEXT.PEEK" 'RFC822.TEXT group server to-buffer)))
 922
 923 (deffoo nnimap-request-group (group &optional server fast)
 924   (nnimap-request-update-info-internal
 925    group
 926    (gnus-get-info (gnus-group-prefixed-name
 927                    group (gnus-server-to-method (format "nnimap:%s" server))))
 928    server)
 929   (when (nnimap-possibly-change-group group server)
 930     (nnimap-before-find-minmax-bugworkaround)
 931     (let (info)
 932       (cond (fast group)
 933             ((null (setq info (nnimap-find-minmax-uid group t)))
 934              (nnheader-report 'nnimap "Could not get active info for %s"
 935                               group))
 936             (t
 937              (nnheader-insert "211 %d %d %d %s\n" (or (nth 0 info) 0)
 938                               (max 1 (or (nth 1 info) 1))
 939                               (or (nth 2 info) 0) group)
 940              (nnheader-report 'nnimap "Group %s selected" group)
 941              t)))))
 942
 943 (defun nnimap-update-unseen (group &optional server)
 944   "Update the unseen count in `nnimap-mailbox-info'."
 945   (gnus-sethash
 946    (gnus-group-prefixed-name group server)
 947    (let ((old (gnus-gethash-safe (gnus-group-prefixed-name group server)
 948                                  nnimap-mailbox-info)))
 949      (list (nth 0 old) (nth 1 old)
 950            (imap-mailbox-status group 'unseen nnimap-server-buffer)
 951            (nth 3 old)))
 952    nnimap-mailbox-info))
 953
 954 (defun nnimap-close-group (group &optional server)
 955   (with-current-buffer nnimap-server-buffer
 956     (when (and (imap-opened)
 957                (nnimap-possibly-change-group group server))
 958       (nnimap-update-unseen group server)
 959       (case nnimap-expunge-on-close
 960         (always (progn
 961                   (imap-mailbox-expunge nnimap-close-asynchronous)
 962                   (unless nnimap-dont-close
 963                     (imap-mailbox-close nnimap-close-asynchronous))))
 964         (ask (if (and (imap-search "DELETED")
 965                       (gnus-y-or-n-p (format "Expunge articles in group `%s'? "
 966                                              imap-current-mailbox)))
 967                  (progn
 968                    (imap-mailbox-expunge nnimap-close-asynchronous)
 969                    (unless nnimap-dont-close
 970                      (imap-mailbox-close nnimap-close-asynchronous)))
 971                (imap-mailbox-unselect)))
 972         (t (imap-mailbox-unselect)))
 973       (not imap-current-mailbox))))
 974
 975 (defun nnimap-pattern-to-list-arguments (pattern)
 976   (mapcar (lambda (p)
 977             (cons (car-safe p) (or (cdr-safe p) p)))
 978           (if (and (listp pattern)
 979                    (listp (cdr pattern)))
 980               pattern
 981             (list pattern))))
 982
 983 (deffoo nnimap-request-list (&optional server)
 984   (when (nnimap-possibly-change-server server)
 985     (with-current-buffer nntp-server-buffer
 986       (erase-buffer))
 987     (gnus-message 5 "nnimap: Generating active list%s..."
 988                   (if (> (length server) 0) (concat " for " server) ""))
 989     (nnimap-before-find-minmax-bugworkaround)
 990     (with-current-buffer nnimap-server-buffer
 991       (dolist (pattern (nnimap-pattern-to-list-arguments nnimap-list-pattern))
 992         (dolist (mbx (funcall nnimap-request-list-method
 993                               (cdr pattern) (car pattern)))
 994           (or (member "\\NoSelect" (imap-mailbox-get 'list-flags mbx))
 995               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
 996                 (when info
 997                   (with-current-buffer nntp-server-buffer
 998                     (insert (format "\"%s\" %d %d y\n"
 999                                     mbx (or (nth 2 info) 0)
1000                                     (max 1 (or (nth 1 info) 1)))))))))))
1001     (gnus-message 5 "nnimap: Generating active list%s...done"
1002                   (if (> (length server) 0) (concat " for " server) ""))
1003     t))
1004
1005 (deffoo nnimap-request-post (&optional server)
1006   (let ((success t))
1007     (dolist (mbx (message-unquote-tokens
1008                   (message-tokenize-header
1009                    (message-fetch-field "Newsgroups") ", ")) success)
1010       (let ((to-newsgroup (gnus-group-prefixed-name mbx gnus-command-method)))
1011         (or (gnus-active to-newsgroup)
1012             (gnus-activate-group to-newsgroup)
1013             (if (gnus-y-or-n-p (format "No such group: %s.  Create it? "
1014                                        to-newsgroup))
1015                 (or (and (gnus-request-create-group
1016                           to-newsgroup gnus-command-method)
1017                          (gnus-activate-group to-newsgroup nil nil
1018                                               gnus-command-method))
1019                     (error "Couldn't create group %s" to-newsgroup)))
1020             (error "No such group: %s" to-newsgroup))
1021         (unless (nnimap-request-accept-article mbx (nth 1 gnus-command-method))
1022           (setq success nil))))))
1023
1024 ;; Optional backend functions
1025
1026 (defun nnimap-string-lessp-numerical (s1 s2)
1027   "Return t if first arg string is less than second in numerical order."
1028   (cond ((string= s1 s2)
1029          nil)
1030         ((> (length s1) (length s2))
1031          nil)
1032         ((< (length s1) (length s2))
1033          t)
1034         ((< (string-to-number (substring s1 0 1))
1035             (string-to-number (substring s2 0 1)))
1036          t)
1037         ((> (string-to-number (substring s1 0 1))
1038             (string-to-number (substring s2 0 1)))
1039          nil)
1040         (t
1041          (nnimap-string-lessp-numerical (substring s1 1) (substring s2 1)))))
1042
1043 (deffoo nnimap-retrieve-groups (groups &optional server)
1044   (when (nnimap-possibly-change-server server)
1045     (gnus-message 5 "nnimap: Checking mailboxes...")
1046     (with-current-buffer nntp-server-buffer
1047       (erase-buffer)
1048       (nnimap-before-find-minmax-bugworkaround)
1049       (let (asyncgroups slowgroups)
1050         (if (null nnimap-retrieve-groups-asynchronous)
1051             (setq slowgroups groups)
1052           (dolist (group groups)
1053             (gnus-message 9 "nnimap: Quickly checking mailbox %s" group)
1054             (add-to-list (if (gnus-gethash-safe
1055                               (gnus-group-prefixed-name group server)
1056                               nnimap-mailbox-info)
1057                              'asyncgroups
1058                            'slowgroups)
1059                          (list group (imap-mailbox-status-asynch
1060                                       group '(uidvalidity uidnext unseen)
1061                                       nnimap-server-buffer))))
1062           (dolist (asyncgroup asyncgroups)
1063             (let ((group (nth 0 asyncgroup))
1064                   (tag   (nth 1 asyncgroup))
1065                   new old)
1066               (when (imap-ok-p (imap-wait-for-tag tag nnimap-server-buffer))
1067                 (if (or (not (string=
1068                               (nth 0 (gnus-gethash (gnus-group-prefixed-name
1069                                                     group server)
1070                                                    nnimap-mailbox-info))
1071                               (imap-mailbox-get 'uidvalidity group
1072                                                 nnimap-server-buffer)))
1073                         (not (string=
1074                               (nth 1 (gnus-gethash (gnus-group-prefixed-name
1075                                                     group server)
1076                                                    nnimap-mailbox-info))
1077                               (imap-mailbox-get 'uidnext group
1078                                                 nnimap-server-buffer))))
1079                     (push (list group) slowgroups)
1080                   (insert (nth 3 (gnus-gethash (gnus-group-prefixed-name
1081                                                 group server)
1082                                                nnimap-mailbox-info))))))))
1083         (dolist (group slowgroups)
1084           (if nnimap-retrieve-groups-asynchronous
1085               (setq group (car group)))
1086           (gnus-message 7 "nnimap: Mailbox %s modified" group)
1087           (imap-mailbox-put 'uidnext nil group nnimap-server-buffer)
1088           (or (member "\\NoSelect" (imap-mailbox-get 'list-flags group
1089                                                      nnimap-server-buffer))
1090               (let* ((info (nnimap-find-minmax-uid group 'examine))
1091                      (str (format "\"%s\" %d %d y\n" group
1092                                   (or (nth 2 info) 0)
1093                                   (max 1 (or (nth 1 info) 1)))))
1094                 (when (> (or (imap-mailbox-get 'recent group
1095                                                nnimap-server-buffer) 0)
1096                          0)
1097                   (push (list (cons group 0)) nnmail-split-history))
1098                 (insert str)
1099                 (when nnimap-retrieve-groups-asynchronous
1100                   (gnus-sethash
1101                    (gnus-group-prefixed-name group server)
1102                    (list (or (imap-mailbox-get
1103                               'uidvalidity group nnimap-server-buffer)
1104                              (imap-mailbox-status
1105                               group 'uidvalidity nnimap-server-buffer))
1106                          (or (imap-mailbox-get
1107                               'uidnext group nnimap-server-buffer)
1108                              (imap-mailbox-status
1109                               group 'uidnext nnimap-server-buffer))
1110                          (or (imap-mailbox-get
1111                               'unseen group nnimap-server-buffer)
1112                              (imap-mailbox-status
1113                               group 'unseen nnimap-server-buffer))
1114                          str)
1115                    nnimap-mailbox-info)))))))
1116     (gnus-message 5 "nnimap: Checking mailboxes...done")
1117     'active))
1118
1119 (deffoo nnimap-request-update-info-internal (group info &optional server)
1120   (when (nnimap-possibly-change-group group server)
1121     (when info ;; xxx what does this mean? should we create a info?
1122       (with-current-buffer nnimap-server-buffer
1123         (gnus-message 5 "nnimap: Updating info for %s..."
1124                       (gnus-info-group info))
1125
1126         (when (nnimap-mark-permanent-p 'read)
1127           (let (seen unseen)
1128             ;; read info could contain articles marked unread by other
1129             ;; imap clients!  we correct this
1130             (setq seen (gnus-uncompress-range (gnus-info-read info))
1131                   unseen (imap-search "UNSEEN UNDELETED")
1132                   seen (gnus-set-difference seen unseen)
1133                   ;; seen might lack articles marked as read by other
1134                   ;; imap clients! we correct this
1135                   seen (append seen (imap-search "SEEN"))
1136                   ;; remove dupes
1137                   seen (sort seen '<)
1138                   seen (gnus-compress-sequence seen t)
1139                   ;; we can't return '(1) since this isn't a "list of ranges",
1140                   ;; and we can't return '((1)) since g-list-of-unread-articles
1141                   ;; is buggy so we return '((1 . 1)).
1142                   seen (if (and (integerp (car seen))
1143                                 (null (cdr seen)))
1144                            (list (cons (car seen) (car seen)))
1145                          seen))
1146             (gnus-info-set-read info seen)))
1147
1148         (mapcar (lambda (pred)
1149                   (when (or (eq (cdr pred) 'recent)
1150                             (and (nnimap-mark-permanent-p (cdr pred))
1151                                  (member (nnimap-mark-to-flag (cdr pred))
1152                                          (imap-mailbox-get 'flags))))
1153                     (gnus-info-set-marks
1154                      info
1155                      (gnus-update-alist-soft
1156                       (cdr pred)
1157                       (gnus-compress-sequence
1158                        (imap-search (nnimap-mark-to-predicate (cdr pred))))
1159                       (gnus-info-marks info))
1160                      t)))
1161                 gnus-article-mark-lists)
1162
1163         (when nnimap-importantize-dormant
1164           ;; nnimap mark dormant article as ticked too (for other clients)
1165           ;; so we remove that mark for gnus since we support dormant
1166           (gnus-info-set-marks
1167            info
1168            (gnus-update-alist-soft
1169             'tick
1170             (gnus-remove-from-range
1171              (cdr-safe (assoc 'tick (gnus-info-marks info)))
1172              (cdr-safe (assoc 'dormant (gnus-info-marks info))))
1173             (gnus-info-marks info))
1174            t))
1175
1176         (gnus-message 5 "nnimap: Updating info for %s...done"
1177                       (gnus-info-group info))
1178
1179         info))))
1180
1181 (deffoo nnimap-request-type (group &optional article)
1182   (if (and nnimap-news-groups (string-match nnimap-news-groups group))
1183       'news
1184     'mail))
1185
1186 (deffoo nnimap-request-set-mark (group actions &optional server)
1187   (when (nnimap-possibly-change-group group server)
1188     (with-current-buffer nnimap-server-buffer
1189       (let (action)
1190         (gnus-message 7 "nnimap: Setting marks in %s..." group)
1191         (while (setq action (pop actions))
1192           (let ((range (nth 0 action))
1193                 (what  (nth 1 action))
1194                 (cmdmarks (nth 2 action))
1195                 marks)
1196             ;; bookmark can't be stored (not list/range
1197             (setq cmdmarks (delq 'bookmark cmdmarks))
1198             ;; killed can't be stored (not list/range
1199             (setq cmdmarks (delq 'killed cmdmarks))
1200             ;; unsent are for nndraft groups only
1201             (setq cmdmarks (delq 'unsent cmdmarks))
1202             ;; cache flags are pointless on the server
1203             (setq cmdmarks (delq 'cache cmdmarks))
1204             ;; seen flags are local to each gnus
1205             (setq cmdmarks (delq 'seen cmdmarks))
1206             ;; recent marks can't be set
1207             (setq cmdmarks (delq 'recent cmdmarks))
1208             (when nnimap-importantize-dormant
1209               ;; flag dormant articles as ticked
1210               (if (memq 'dormant cmdmarks)
1211                   (setq cmdmarks (cons 'tick cmdmarks))))
1212             ;; remove stuff we are forbidden to store
1213             (mapcar (lambda (mark)
1214                       (if (imap-message-flag-permanent-p
1215                            (nnimap-mark-to-flag mark))
1216                           (setq marks (cons mark marks))))
1217                     cmdmarks)
1218             (when (and range marks)
1219               (cond ((eq what 'del)
1220                      (imap-message-flags-del
1221                       (imap-range-to-message-set range)
1222                       (nnimap-mark-to-flag marks nil t)))
1223                     ((eq what 'add)
1224                      (imap-message-flags-add
1225                       (imap-range-to-message-set range)
1226                       (nnimap-mark-to-flag marks nil t)))
1227                     ((eq what 'set)
1228                      (imap-message-flags-set
1229                       (imap-range-to-message-set range)
1230                       (nnimap-mark-to-flag marks nil t)))))))
1231         (gnus-message 7 "nnimap: Setting marks in %s...done" group))))
1232   nil)
1233
1234 (defun nnimap-split-fancy ()
1235   "Like the function `nnmail-split-fancy', but uses `nnimap-split-fancy'."
1236   (let ((nnmail-split-fancy nnimap-split-fancy))
1237     (nnmail-split-fancy)))
1238
1239 (defun nnimap-split-to-groups (rules)
1240   ;; tries to match all rules in nnimap-split-rule against content of
1241   ;; nntp-server-buffer, returns a list of groups that matched.
1242   (with-current-buffer nntp-server-buffer
1243     ;; Fold continuation lines.
1244     (goto-char (point-min))
1245     (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
1246       (replace-match " " t t))
1247     (if (functionp rules)
1248         (funcall rules)
1249       (let (to-groups regrepp)
1250         (catch 'split-done
1251           (dolist (rule rules to-groups)
1252             (let ((group (car rule))
1253                   (regexp (cadr rule)))
1254               (goto-char (point-min))
1255               (when (and (if (stringp regexp)
1256                              (progn
1257                                (if (not (stringp group))
1258                                    (setq group (eval group))
1259                                  (setq regrepp
1260                                        (string-match "\\\\[0-9&]" group)))
1261                                (re-search-forward regexp nil t))
1262                            (funcall regexp group))
1263                          ;; Don't enter the article into the same group twice.
1264                          (not (assoc group to-groups)))
1265                 (push (if regrepp
1266                           (nnmail-expand-newtext group)
1267                         group)
1268                       to-groups)
1269                 (or nnimap-split-crosspost
1270                     (throw 'split-done to-groups))))))))))
1271
1272 (defun nnimap-assoc-match (key alist)
1273   (let (element)
1274     (while (and alist (not element))
1275       (if (string-match (car (car alist)) key)
1276           (setq element (car alist)))
1277       (setq alist (cdr alist)))
1278     element))
1279
1280 (defun nnimap-split-find-rule (server inbox)
1281   (if (and (listp nnimap-split-rule) (listp (car nnimap-split-rule))
1282            (list (cdar nnimap-split-rule)) (listp (cadar nnimap-split-rule)))
1283       ;; extended format
1284       (cadr (nnimap-assoc-match inbox (cdr (nnimap-assoc-match
1285                                             server nnimap-split-rule))))
1286     nnimap-split-rule))
1287
1288 (defun nnimap-split-find-inbox (server)
1289   (if (listp nnimap-split-inbox)
1290       nnimap-split-inbox
1291     (list nnimap-split-inbox)))
1292
1293 (defun nnimap-split-articles (&optional group server)
1294   (when (nnimap-possibly-change-server server)
1295     (with-current-buffer nnimap-server-buffer
1296       (let (rule inbox removeorig (inboxes (nnimap-split-find-inbox server)))
1297         ;; iterate over inboxes
1298         (while (and (setq inbox (pop inboxes))
1299                     (nnimap-possibly-change-group inbox)) ;; SELECT
1300           ;; find split rule for this server / inbox
1301           (when (setq rule (nnimap-split-find-rule server inbox))
1302             ;; iterate over articles
1303             (dolist (article (imap-search nnimap-split-predicate))
1304               (when (if (if (eq nnimap-split-download-body 'default)
1305                             nnimap-split-download-body-default
1306                           nnimap-split-download-body)
1307                         (and (nnimap-request-article article)
1308                              (with-current-buffer nntp-server-buffer (mail-narrow-to-head)))
1309                       (nnimap-request-head article))
1310                 ;; copy article to right group(s)
1311                 (setq removeorig nil)
1312                 (dolist (to-group (nnimap-split-to-groups rule))
1313                   (cond ((eq to-group 'junk)
1314                          (message "IMAP split removed %s:%s:%d" server inbox
1315                                   article)
1316                          (setq removeorig t))
1317                         ((imap-message-copy (number-to-string article)
1318                                             to-group nil 'nocopyuid)
1319                          (message "IMAP split moved %s:%s:%d to %s" server
1320                                   inbox article to-group)
1321                          (setq removeorig t)
1322                          (when nnmail-cache-accepted-message-ids
1323                            (with-current-buffer nntp-server-buffer
1324                              (let (msgid)
1325                                (and (setq msgid
1326                                           (nnmail-fetch-field "message-id"))
1327                                     (nnmail-cache-insert msgid
1328                                                          to-group
1329                                                          (nnmail-fetch-field "subject"))))))
1330                          ;; Add the group-art list to the history list.
1331                          (push (list (cons to-group 0)) nnmail-split-history))
1332                         (t
1333                          (message "IMAP split failed to move %s:%s:%d to %s"
1334                                   server inbox article to-group))))
1335                 (if (if (eq nnimap-split-download-body 'default)
1336                         nnimap-split-download-body-default
1337                       nnimap-split-download-body)
1338                     (widen))
1339                 ;; remove article if it was successfully copied somewhere
1340                 (and removeorig
1341                      (imap-message-flags-add (format "%d" article)
1342                                              "\\Seen \\Deleted")))))
1343           (when (imap-mailbox-select inbox) ;; just in case
1344             ;; todo: UID EXPUNGE (if available) to remove splitted articles
1345             (imap-mailbox-expunge)
1346             (imap-mailbox-close)))
1347         (when nnmail-cache-accepted-message-ids
1348           (nnmail-cache-close))
1349         t))))
1350
1351 (deffoo nnimap-request-scan (&optional group server)
1352   (nnimap-split-articles group server))
1353
1354 (deffoo nnimap-request-newgroups (date &optional server)
1355   (when (nnimap-possibly-change-server server)
1356     (with-current-buffer nntp-server-buffer
1357       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s..."
1358                     (if (> (length server) 0) " on " "") server)
1359       (erase-buffer)
1360       (nnimap-before-find-minmax-bugworkaround)
1361       (dolist (pattern (nnimap-pattern-to-list-arguments
1362                         nnimap-list-pattern))
1363         (dolist (mbx (imap-mailbox-lsub (cdr pattern) (car pattern) nil
1364                                         nnimap-server-buffer))
1365           (or (catch 'found
1366                 (dolist (mailbox (imap-mailbox-get 'list-flags mbx
1367                                                    nnimap-server-buffer))
1368                   (if (string= (downcase mailbox) "\\noselect")
1369                       (throw 'found t)))
1370                 nil)
1371               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
1372                 (when info
1373                   (insert (format "\"%s\" %d %d y\n"
1374                                   mbx (or (nth 2 info) 0)
1375                                   (max 1 (or (nth 1 info) 1)))))))))
1376       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s...done"
1377                     (if (> (length server) 0) " on " "") server))
1378     t))
1379
1380 (deffoo nnimap-request-create-group (group &optional server args)
1381   (when (nnimap-possibly-change-server server)
1382     (or (imap-mailbox-status group 'uidvalidity nnimap-server-buffer)
1383         (imap-mailbox-create group nnimap-server-buffer)
1384         (nnheader-report 'nnimap "%S"
1385                          (imap-error-text nnimap-server-buffer)))))
1386
1387 (defun nnimap-time-substract (time1 time2)
1388   "Return TIME for TIME1 - TIME2."
1389   (let* ((ms (- (car time1) (car time2)))
1390          (ls (- (nth 1 time1) (nth 1 time2))))
1391     (if (< ls 0)
1392         (list (- ms 1) (+ (expt 2 16) ls))
1393       (list ms ls))))
1394
1395 (eval-when-compile (require 'parse-time))
1396 (defun nnimap-date-days-ago (daysago)
1397   "Return date, in format \"3-Aug-1998\", for DAYSAGO days ago."
1398   (require 'parse-time)
1399   (let* ((time (nnimap-time-substract (current-time) (days-to-time daysago)))
1400          (date (format-time-string
1401                 (format "%%d-%s-%%Y"
1402                         (capitalize (car (rassoc (nth 4 (decode-time time))
1403                                                  parse-time-months))))
1404                 time)))
1405     (if (eq ?0 (string-to-char date))
1406         (substring date 1)
1407       date)))
1408
1409 (defun nnimap-request-expire-articles-progress ()
1410   (gnus-message 5 "nnimap: Marking article %d for deletion..."
1411                 imap-current-message))
1412
1413 (defun nnimap-expiry-target (arts group server)
1414   (unless (eq nnmail-expiry-target 'delete)
1415     (with-temp-buffer
1416       (dolist (art arts)
1417         (nnimap-request-article art group server (current-buffer))
1418         ;; hints for optimization in `nnimap-request-accept-article'
1419         (let ((nnimap-current-move-article art)
1420               (nnimap-current-move-group group)
1421               (nnimap-current-move-server server))
1422           (nnmail-expiry-target-group nnmail-expiry-target group))))
1423     ;; It is not clear if `nnmail-expiry-target' somehow cause the
1424     ;; current group to be changed or not, so we make sure here.
1425     (nnimap-possibly-change-group group server)))
1426
1427 ;; Notice that we don't actually delete anything, we just mark them deleted.
1428 (deffoo nnimap-request-expire-articles (articles group &optional server force)
1429   (let ((artseq (gnus-compress-sequence articles)))
1430     (when (and artseq (nnimap-possibly-change-group group server))
1431       (with-current-buffer nnimap-server-buffer
1432         (let ((days (or (and nnmail-expiry-wait-function
1433                              (funcall nnmail-expiry-wait-function group))
1434                         nnmail-expiry-wait)))
1435           (cond ((or force (eq days 'immediate))
1436                  (let ((oldarts (imap-search
1437                                  (concat "UID "
1438                                          (imap-range-to-message-set artseq)))))
1439                    (when oldarts
1440                      (nnimap-expiry-target oldarts group server)
1441                      (when (imap-message-flags-add
1442                             (imap-range-to-message-set
1443                              (gnus-compress-sequence oldarts)) "\\Deleted")
1444                        (setq articles (gnus-set-difference
1445                                        articles oldarts))))))
1446                 ((and nnimap-search-uids-not-since-is-evil (numberp days))
1447                  (let* ((all-new-articles
1448                          (gnus-compress-sequence
1449                           (imap-search (format "SINCE %s"
1450                                                (nnimap-date-days-ago days)))))
1451                         (oldartseq
1452                          (gnus-range-difference artseq all-new-articles))
1453                         (oldarts (gnus-uncompress-range oldartseq)))
1454                    (when oldarts
1455                      (nnimap-expiry-target oldarts group server)
1456                      (when (imap-message-flags-add
1457                             (imap-range-to-message-set oldartseq)
1458                             "\\Deleted")
1459                        (setq articles (gnus-set-difference
1460                                        articles oldarts))))))
1461                 ((numberp days)
1462                  (let ((oldarts (imap-search
1463                                  (format nnimap-expunge-search-string
1464                                          (imap-range-to-message-set artseq)
1465                                          (nnimap-date-days-ago days))))
1466                        (imap-fetch-data-hook
1467                         '(nnimap-request-expire-articles-progress)))
1468                    (when oldarts
1469                      (nnimap-expiry-target oldarts group server)
1470                      (when (imap-message-flags-add
1471                             (imap-range-to-message-set
1472                              (gnus-compress-sequence oldarts)) "\\Deleted")
1473                        (setq articles (gnus-set-difference
1474                                        articles oldarts)))))))))))
1475   ;; return articles not deleted
1476   articles)
1477
1478 (deffoo nnimap-request-move-article (article group server
1479                                              accept-form &optional last)
1480   (when (nnimap-possibly-change-server server)
1481     (save-excursion
1482       (let ((buf (get-buffer-create " *nnimap move*"))
1483             (nnimap-current-move-article article)
1484             (nnimap-current-move-group group)
1485             (nnimap-current-move-server nnimap-current-server)
1486             result)
1487         (and (nnimap-request-article article group server)
1488              (save-excursion
1489                (set-buffer buf)
1490                (buffer-disable-undo (current-buffer))
1491                (insert-buffer-substring nntp-server-buffer)
1492                (setq result (eval accept-form))
1493                (kill-buffer buf)
1494                result)
1495              (imap-message-flags-add
1496               (imap-range-to-message-set (list article))
1497               "\\Deleted" 'silent nnimap-server-buffer))
1498         result))))
1499
1500 (deffoo nnimap-request-accept-article (group &optional server last)
1501   (when (nnimap-possibly-change-server server)
1502     (let (uid)
1503       (if (setq uid
1504                 (if (string= nnimap-current-server nnimap-current-move-server)
1505                     ;; moving article within same server, speed it up...
1506                     (and (nnimap-possibly-change-group
1507                           nnimap-current-move-group)
1508                          (imap-message-copy (number-to-string
1509                                              nnimap-current-move-article)
1510                                             group 'dontcreate nil
1511                                             nnimap-server-buffer))
1512                   (with-current-buffer (current-buffer)
1513                     (goto-char (point-min))
1514                     ;; remove any 'From blabla' lines, some IMAP servers
1515                     ;; reject the entire message otherwise.
1516                     (when (looking-at "^From[^:]")
1517                       (delete-region (point) (progn (forward-line) (point))))
1518                     ;; turn into rfc822 format (\r\n eol's)
1519                     (while (search-forward "\n" nil t)
1520                       (replace-match "\r\n"))
1521                     (when nnmail-cache-accepted-message-ids
1522                       (nnmail-cache-insert (nnmail-fetch-field "message-id")
1523                                            group
1524                                            (nnmail-fetch-field "subject"))))
1525                   (when (and last nnmail-cache-accepted-message-ids)
1526                     (nnmail-cache-close))
1527                   ;; this 'or' is for Cyrus server bug
1528                   (or (null (imap-current-mailbox nnimap-server-buffer))
1529                       (imap-mailbox-unselect nnimap-server-buffer))
1530                   (imap-message-append group (current-buffer) nil nil
1531                                        nnimap-server-buffer)))
1532           (cons group (nth 1 uid))
1533         (nnheader-report 'nnimap (imap-error-text nnimap-server-buffer))))))
1534
1535 (deffoo nnimap-request-delete-group (group force &optional server)
1536   (when (nnimap-possibly-change-server server)
1537     (with-current-buffer nnimap-server-buffer
1538       (if force
1539           (or (null (imap-mailbox-status group 'uidvalidity))
1540               (imap-mailbox-delete group))
1541         ;; UNSUBSCRIBE?
1542         t))))
1543
1544 (deffoo nnimap-request-rename-group (group new-name &optional server)
1545   (when (nnimap-possibly-change-server server)
1546     (imap-mailbox-rename group new-name nnimap-server-buffer)))
1547
1548 (defun nnimap-expunge (mailbox server)
1549   (when (nnimap-possibly-change-group mailbox server)
1550     (imap-mailbox-expunge nil nnimap-server-buffer)))
1551
1552 (defun nnimap-acl-get (mailbox server)
1553   (when (nnimap-possibly-change-server server)
1554     (and (imap-capability 'ACL nnimap-server-buffer)
1555          (imap-mailbox-acl-get mailbox nnimap-server-buffer))))
1556
1557 (defun nnimap-acl-edit (mailbox method old-acls new-acls)
1558   (when (nnimap-possibly-change-server (cadr method))
1559     (unless (imap-capability 'ACL nnimap-server-buffer)
1560       (error "Your server does not support ACL editing"))
1561     (with-current-buffer nnimap-server-buffer
1562       ;; delete all removed identifiers
1563       (mapcar (lambda (old-acl)
1564                 (unless (assoc (car old-acl) new-acls)
1565                   (or (imap-mailbox-acl-delete (car old-acl) mailbox)
1566                       (error "Can't delete ACL for %s" (car old-acl)))))
1567               old-acls)
1568       ;; set all changed acl's
1569       (mapcar (lambda (new-acl)
1570                 (let ((new-rights (cdr new-acl))
1571                       (old-rights (cdr (assoc (car new-acl) old-acls))))
1572                   (unless (and old-rights new-rights
1573                                (string= old-rights new-rights))
1574                     (or (imap-mailbox-acl-set (car new-acl) new-rights mailbox)
1575                         (error "Can't set ACL for %s to %s" (car new-acl)
1576                                new-rights)))))
1577               new-acls)
1578       t)))
1579
1580 \f
1581 ;;; Internal functions
1582
1583 ;;
1584 ;; This is confusing.
1585 ;;
1586 ;; mark      => read, tick, draft, reply etc
1587 ;; flag      => "\\Seen", "\\Flagged", "\\Draft", "gnus-expire" etc
1588 ;; predicate => "SEEN", "FLAGGED", "DRAFT", "KEYWORD gnus-expire" etc
1589 ;;
1590 ;; Mark should not really contain 'read since it's not a "mark" in the Gnus
1591 ;; world, but we cheat.  Mark == gnus-article-mark-lists + '(read . read).
1592 ;;
1593
1594 (defconst nnimap-mark-to-predicate-alist
1595   (mapcar
1596    (lambda (pair)                       ; cdr is the mark
1597      (or (assoc (cdr pair)
1598                 '((read . "SEEN")
1599                   (tick . "FLAGGED")
1600                   (draft . "DRAFT")
1601                   (recent . "RECENT")
1602                   (reply . "ANSWERED")))
1603          (cons (cdr pair)
1604                (format "KEYWORD gnus-%s" (symbol-name (cdr pair))))))
1605    (cons '(read . read) gnus-article-mark-lists)))
1606
1607 (defun nnimap-mark-to-predicate (pred)
1608   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP predicate.
1609 This is a string such as \"SEEN\", \"FLAGGED\", \"KEYWORD gnus-expire\",
1610 to be used within a IMAP SEARCH query."
1611   (cdr (assq pred nnimap-mark-to-predicate-alist)))
1612
1613 (defconst nnimap-mark-to-flag-alist
1614   (mapcar
1615    (lambda (pair)
1616      (or (assoc (cdr pair)
1617                 '((read . "\\Seen")
1618                   (tick . "\\Flagged")
1619                   (draft . "\\Draft")
1620                   (recent . "\\Recent")
1621                   (reply . "\\Answered")))
1622          (cons (cdr pair)
1623                (format "gnus-%s" (symbol-name (cdr pair))))))
1624    (cons '(read . read) gnus-article-mark-lists)))
1625
1626 (defun nnimap-mark-to-flag-1 (preds)
1627   (if (and (not (null preds)) (listp preds))
1628       (cons (nnimap-mark-to-flag (car preds))
1629             (nnimap-mark-to-flag (cdr preds)))
1630     (cdr (assoc preds nnimap-mark-to-flag-alist))))
1631
1632 (defun nnimap-mark-to-flag (preds &optional always-list make-string)
1633   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP flag.
1634 This is a string such as \"\\Seen\", \"\\Flagged\", \"gnus-expire\", to
1635 be used in a STORE FLAGS command."
1636   (let ((result (nnimap-mark-to-flag-1 preds)))
1637     (setq result (if (and (or make-string always-list)
1638                           (not (listp result)))
1639                      (list result)
1640                    result))
1641     (if make-string
1642         (mapconcat (lambda (flag)
1643                      (if (listp flag)
1644                          (mapconcat 'identity flag " ")
1645                        flag))
1646                    result " ")
1647       result)))
1648
1649 (defun nnimap-mark-permanent-p (mark &optional group)
1650   "Return t iff MARK can be permanently (between IMAP sessions) saved on articles, in GROUP."
1651   (imap-message-flag-permanent-p (nnimap-mark-to-flag mark)))
1652
1653 (when nnimap-debug
1654   (require 'trace)
1655   (buffer-disable-undo (get-buffer-create nnimap-debug-buffer))
1656   (mapcar (lambda (f) (trace-function-background f nnimap-debug-buffer))
1657           '(
1658             nnimap-possibly-change-server
1659             nnimap-verify-uidvalidity
1660             nnimap-find-minmax-uid
1661             nnimap-before-find-minmax-bugworkaround
1662             nnimap-possibly-change-group
1663             ;;nnimap-replace-whitespace
1664             nnimap-retrieve-headers-progress
1665             nnimap-retrieve-which-headers
1666             nnimap-group-overview-filename
1667             nnimap-retrieve-headers-from-file
1668             nnimap-retrieve-headers-from-server
1669             nnimap-retrieve-headers
1670             nnimap-open-connection
1671             nnimap-open-server
1672             nnimap-server-opened
1673             nnimap-close-server
1674             nnimap-request-close
1675             nnimap-status-message
1676             ;;nnimap-demule
1677             nnimap-request-article-part
1678             nnimap-request-article
1679             nnimap-request-head
1680             nnimap-request-body
1681             nnimap-request-group
1682             nnimap-close-group
1683             nnimap-pattern-to-list-arguments
1684             nnimap-request-list
1685             nnimap-request-post
1686             nnimap-retrieve-groups
1687             nnimap-request-update-info-internal
1688             nnimap-request-type
1689             nnimap-request-set-mark
1690             nnimap-split-to-groups
1691             nnimap-split-find-rule
1692             nnimap-split-find-inbox
1693             nnimap-split-articles
1694             nnimap-request-scan
1695             nnimap-request-newgroups
1696             nnimap-request-create-group
1697             nnimap-time-substract
1698             nnimap-date-days-ago
1699             nnimap-request-expire-articles-progress
1700             nnimap-request-expire-articles
1701             nnimap-request-move-article
1702             nnimap-request-accept-article
1703             nnimap-request-delete-group
1704             nnimap-request-rename-group
1705             gnus-group-nnimap-expunge
1706             gnus-group-nnimap-edit-acl
1707             gnus-group-nnimap-edit-acl-done
1708             nnimap-group-mode-hook
1709             nnimap-mark-to-predicate
1710             nnimap-mark-to-flag-1
1711             nnimap-mark-to-flag
1712             nnimap-mark-permanent-p
1713             )))
1714
1715 (provide 'nnimap)
1716
1717 ;; arch-tag: 2b001f20-3ff9-4094-a0ad-46807c1ba70b
1718 ;;; nnimap.el ends here