lisp/gnus/nnheader.el

   1 ;;; nnheader.el --- header access macros for Gnus and its backends
   2
   3 ;; Copyright (C) 1987, 1988, 1989, 1990, 1993, 1994,
   4 ;;   1995, 1996, 1997, 1998, 2000, 2001, 2002, 2003,
   5 ;;   2004, 2005 Free Software Foundation, Inc.
   6
   7 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   8 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   9 ;; Keywords: news
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;;; Code:
  31
  32 (eval-when-compile (require 'cl))
  33
  34 (defvar nnmail-extra-headers)
  35
  36 ;; Requiring `gnus-util' at compile time creates a circular
  37 ;; dependency between nnheader.el and gnus-util.el.
  38 ;;(eval-when-compile (require 'gnus-util))
  39
  40 (require 'mail-utils)
  41 (require 'mm-util)
  42 (require 'gnus-util)
  43 (eval-and-compile
  44   (autoload 'gnus-sorted-intersection "gnus-range")
  45   (autoload 'gnus-intersection "gnus-range")
  46   (autoload 'gnus-sorted-complement "gnus-range")
  47   (autoload 'gnus-sorted-difference "gnus-range"))
  48
  49 (defcustom gnus-verbose-backends 7
  50   "Integer that says how verbose the Gnus backends should be.
  51 The higher the number, the more messages the Gnus backends will flash
  52 to say what it's doing.  At zero, the Gnus backends will be totally
  53 mute; at five, they will display most important messages; and at ten,
  54 they will keep on jabbering all the time."
  55   :group 'gnus-start
  56   :type 'integer)
  57
  58 (defcustom gnus-nov-is-evil nil
  59   "If non-nil, Gnus backends will never output headers in the NOV format."
  60   :group 'gnus-server
  61   :type 'boolean)
  62
  63 (defvar nnheader-max-head-length 8192
  64   "*Max length of the head of articles.
  65
  66 Value is an integer, nil, or t.  nil means read in chunks of a file
  67 indefinitely until a complete head is found\; t means always read the
  68 entire file immediately, disregarding `nnheader-head-chop-length'.
  69
  70 Integer values will in effect be rounded up to the nearest multiple of
  71 `nnheader-head-chop-length'.")
  72
  73 (defvar nnheader-head-chop-length 2048
  74   "*Length of each read operation when trying to fetch HEAD headers.")
  75
  76 (defvar nnheader-read-timeout
  77   (if (string-match "windows-nt\\|os/2\\|emx\\|cygwin"
  78                     (symbol-name system-type))
  79       ;; http://thread.gmane.org/v9655t3pjo.fsf@marauder.physik.uni-ulm.de
  80       ;;
  81       ;; IIRC, values lower than 1.0 didn't/don't work on Windows/DOS.
  82       ;;
  83       ;; There should probably be a runtime test to determine the timing
  84       ;; resolution, or a primitive to report it.  I don't know off-hand
  85       ;; what's possible.  Perhaps better, maybe the Windows/DOS primitive
  86       ;; could round up non-zero timeouts to a minimum of 1.0?
  87       1.0
  88     0.1)
  89   "How long nntp should wait between checking for the end of output.
  90 Shorter values mean quicker response, but are more CPU intensive.")
  91
  92 (defvar nnheader-file-name-translation-alist
  93   (let ((case-fold-search t))
  94     (cond
  95      ((string-match "windows-nt\\|os/2\\|emx\\|cygwin"
  96                     (symbol-name system-type))
  97       (append (mapcar (lambda (c) (cons c ?_))
  98                       '(?: ?* ?\" ?< ?> ??))
  99               (if (string-match "windows-nt\\|cygwin"
 100                                 (symbol-name system-type))
 101                   nil
 102                 '((?+ . ?-)))))
 103      (t nil)))
 104   "*Alist that says how to translate characters in file names.
 105 For instance, if \":\" is invalid as a file character in file names
 106 on your system, you could say something like:
 107
 108 \(setq nnheader-file-name-translation-alist '((?: . ?_)))")
 109
 110 (defvar nnheader-directory-separator-character
 111   (string-to-char (substring (file-name-as-directory ".") -1))
 112   "*A character used to a directory separator.")
 113
 114 (eval-and-compile
 115   (autoload 'nnmail-message-id "nnmail")
 116   (autoload 'mail-position-on-field "sendmail")
 117   (autoload 'message-remove-header "message")
 118   (autoload 'gnus-point-at-eol "gnus-util")
 119   (autoload 'gnus-buffer-live-p "gnus-util"))
 120
 121 ;;; Header access macros.
 122
 123 ;; These macros may look very much like the ones in GNUS 4.1.  They
 124 ;; are, in a way, but you should note that the indices they use have
 125 ;; been changed from the internal GNUS format to the NOV format.  The
 126 ;; makes it possible to read headers from XOVER much faster.
 127 ;;
 128 ;; The format of a header is now:
 129 ;; [number subject from date id references chars lines xref extra]
 130 ;;
 131 ;; (That next-to-last entry is defined as "misc" in the NOV format,
 132 ;; but Gnus uses it for xrefs.)
 133
 134 (defmacro mail-header-number (header)
 135   "Return article number in HEADER."
 136   `(aref ,header 0))
 137
 138 (defmacro mail-header-set-number (header number)
 139   "Set article number of HEADER to NUMBER."
 140   `(aset ,header 0 ,number))
 141
 142 (defmacro mail-header-subject (header)
 143   "Return subject string in HEADER."
 144   `(aref ,header 1))
 145
 146 (defmacro mail-header-set-subject (header subject)
 147   "Set article subject of HEADER to SUBJECT."
 148   `(aset ,header 1 ,subject))
 149
 150 (defmacro mail-header-from (header)
 151   "Return author string in HEADER."
 152   `(aref ,header 2))
 153
 154 (defmacro mail-header-set-from (header from)
 155   "Set article author of HEADER to FROM."
 156   `(aset ,header 2 ,from))
 157
 158 (defmacro mail-header-date (header)
 159   "Return date in HEADER."
 160   `(aref ,header 3))
 161
 162 (defmacro mail-header-set-date (header date)
 163   "Set article date of HEADER to DATE."
 164   `(aset ,header 3 ,date))
 165
 166 (defalias 'mail-header-message-id 'mail-header-id)
 167 (defmacro mail-header-id (header)
 168   "Return Id in HEADER."
 169   `(aref ,header 4))
 170
 171 (defalias 'mail-header-set-message-id 'mail-header-set-id)
 172 (defmacro mail-header-set-id (header id)
 173   "Set article Id of HEADER to ID."
 174   `(aset ,header 4 ,id))
 175
 176 (defmacro mail-header-references (header)
 177   "Return references in HEADER."
 178   `(aref ,header 5))
 179
 180 (defmacro mail-header-set-references (header ref)
 181   "Set article references of HEADER to REF."
 182   `(aset ,header 5 ,ref))
 183
 184 (defmacro mail-header-chars (header)
 185   "Return number of chars of article in HEADER."
 186   `(aref ,header 6))
 187
 188 (defmacro mail-header-set-chars (header chars)
 189   "Set number of chars in article of HEADER to CHARS."
 190   `(aset ,header 6 ,chars))
 191
 192 (defmacro mail-header-lines (header)
 193   "Return lines in HEADER."
 194   `(aref ,header 7))
 195
 196 (defmacro mail-header-set-lines (header lines)
 197   "Set article lines of HEADER to LINES."
 198   `(aset ,header 7 ,lines))
 199
 200 (defmacro mail-header-xref (header)
 201   "Return xref string in HEADER."
 202   `(aref ,header 8))
 203
 204 (defmacro mail-header-set-xref (header xref)
 205   "Set article XREF of HEADER to xref."
 206   `(aset ,header 8 ,xref))
 207
 208 (defmacro mail-header-extra (header)
 209   "Return the extra headers in HEADER."
 210   `(aref ,header 9))
 211
 212 (defmacro mail-header-set-extra (header extra)
 213   "Set the extra headers in HEADER to EXTRA."
 214   `(aset ,header 9 ',extra))
 215
 216 (defsubst make-mail-header (&optional init)
 217   "Create a new mail header structure initialized with INIT."
 218   (make-vector 10 init))
 219
 220 (defsubst make-full-mail-header (&optional number subject from date id
 221                                            references chars lines xref
 222                                            extra)
 223   "Create a new mail header structure initialized with the parameters given."
 224   (vector number subject from date id references chars lines xref extra))
 225
 226 ;; fake message-ids: generation and detection
 227
 228 (defvar nnheader-fake-message-id 1)
 229
 230 (defsubst nnheader-generate-fake-message-id ()
 231   (concat "fake+none+" (int-to-string (incf nnheader-fake-message-id))))
 232
 233 (defsubst nnheader-fake-message-id-p (id)
 234   (save-match-data                     ; regular message-id's are <.*>
 235     (string-match "\\`fake\\+none\\+[0-9]+\\'" id)))
 236
 237 ;; Parsing headers and NOV lines.
 238
 239 (defsubst nnheader-remove-cr-followed-by-lf ()
 240   (goto-char (point-max))
 241   (while (search-backward "\r\n" nil t)
 242     (delete-char 1)))
 243
 244 (defsubst nnheader-header-value ()
 245   (skip-chars-forward " \t")
 246   (buffer-substring (point) (gnus-point-at-eol)))
 247
 248 (defun nnheader-parse-naked-head (&optional number)
 249   ;; This function unfolds continuation lines in this buffer
 250   ;; destructively.  When this side effect is unwanted, use
 251   ;; `nnheader-parse-head' instead of this function.
 252   (let ((case-fold-search t)
 253         (buffer-read-only nil)
 254         (cur (current-buffer))
 255         (p (point-min))
 256         in-reply-to lines ref)
 257     (nnheader-remove-cr-followed-by-lf)
 258     (ietf-drums-unfold-fws)
 259     (subst-char-in-region (point-min) (point-max) ?\t ? )
 260     (goto-char p)
 261     (insert "\n")
 262     (prog1
 263         ;; This implementation of this function, with nine
 264         ;; search-forwards instead of the one re-search-forward and a
 265         ;; case (which basically was the old function) is actually
 266         ;; about twice as fast, even though it looks messier.  You
 267         ;; can't have everything, I guess.  Speed and elegance don't
 268         ;; always go hand in hand.
 269         (vector
 270          ;; Number.
 271          (or number 0)
 272          ;; Subject.
 273          (progn
 274            (goto-char p)
 275            (if (search-forward "\nsubject:" nil t)
 276                (nnheader-header-value) "(none)"))
 277          ;; From.
 278          (progn
 279            (goto-char p)
 280            (if (search-forward "\nfrom:" nil t)
 281                (nnheader-header-value) "(nobody)"))
 282          ;; Date.
 283          (progn
 284            (goto-char p)
 285            (if (search-forward "\ndate:" nil t)
 286                (nnheader-header-value) ""))
 287          ;; Message-ID.
 288          (progn
 289            (goto-char p)
 290            (if (search-forward "\nmessage-id:" nil t)
 291                (buffer-substring
 292                 (1- (or (search-forward "<" (gnus-point-at-eol) t)
 293                         (point)))
 294                 (or (search-forward ">" (gnus-point-at-eol) t) (point)))
 295              ;; If there was no message-id, we just fake one to make
 296              ;; subsequent routines simpler.
 297              (nnheader-generate-fake-message-id)))
 298          ;; References.
 299          (progn
 300            (goto-char p)
 301            (if (search-forward "\nreferences:" nil t)
 302                (nnheader-header-value)
 303              ;; Get the references from the in-reply-to header if
 304              ;; there were no references and the in-reply-to header
 305              ;; looks promising.
 306              (if (and (search-forward "\nin-reply-to:" nil t)
 307                       (setq in-reply-to (nnheader-header-value))
 308                       (string-match "<[^\n>]+>" in-reply-to))
 309                  (let (ref2)
 310                    (setq ref (substring in-reply-to (match-beginning 0)
 311                                         (match-end 0)))
 312                    (while (string-match "<[^\n>]+>"
 313                                         in-reply-to (match-end 0))
 314                      (setq ref2 (substring in-reply-to (match-beginning 0)
 315                                            (match-end 0)))
 316                      (when (> (length ref2) (length ref))
 317                        (setq ref ref2)))
 318                    ref)
 319                nil)))
 320          ;; Chars.
 321          0
 322          ;; Lines.
 323          (progn
 324            (goto-char p)
 325            (if (search-forward "\nlines: " nil t)
 326                (if (numberp (setq lines (read cur)))
 327                    lines 0)
 328              0))
 329          ;; Xref.
 330          (progn
 331            (goto-char p)
 332            (and (search-forward "\nxref:" nil t)
 333                 (nnheader-header-value)))
 334          ;; Extra.
 335          (when nnmail-extra-headers
 336            (let ((extra nnmail-extra-headers)
 337                  out)
 338              (while extra
 339                (goto-char p)
 340                (when (search-forward
 341                       (concat "\n" (symbol-name (car extra)) ":") nil t)
 342                  (push (cons (car extra) (nnheader-header-value))
 343                        out))
 344                (pop extra))
 345              out)))
 346       (goto-char p)
 347       (delete-char 1))))
 348
 349 (defun nnheader-parse-head (&optional naked)
 350   (let ((cur (current-buffer)) num beg end)
 351     (when (if naked
 352               (setq num 0
 353                     beg (point-min)
 354                     end (point-max))
 355             (goto-char (point-min))
 356             ;; Search to the beginning of the next header.  Error
 357             ;; messages do not begin with 2 or 3.
 358             (when (re-search-forward "^[23][0-9]+ " nil t)
 359               (end-of-line)
 360               (setq num (read cur)
 361                     beg (point)
 362                     end (if (search-forward "\n.\n" nil t)
 363                             (- (point) 2)
 364                           (point)))))
 365       (with-temp-buffer
 366         (insert-buffer-substring cur beg end)
 367         (nnheader-parse-naked-head num)))))
 368
 369 (defmacro nnheader-nov-skip-field ()
 370   '(search-forward "\t" eol 'move))
 371
 372 (defmacro nnheader-nov-field ()
 373   '(buffer-substring (point) (if (nnheader-nov-skip-field) (1- (point)) eol)))
 374
 375 (defmacro nnheader-nov-read-integer ()
 376   '(prog1
 377        (if (eq (char-after) ?\t)
 378            0
 379          (let ((num (condition-case nil
 380                         (read (current-buffer))
 381                       (error nil))))
 382            (if (numberp num) num 0)))
 383      (or (eobp) (forward-char 1))))
 384
 385 (defmacro nnheader-nov-parse-extra ()
 386   '(let (out string)
 387      (while (not (memq (char-after) '(?\n nil)))
 388        (setq string (nnheader-nov-field))
 389        (when (string-match "^\\([^ :]+\\): " string)
 390          (push (cons (intern (match-string 1 string))
 391                      (substring string (match-end 0)))
 392                out)))
 393      out))
 394
 395 (defmacro nnheader-nov-read-message-id ()
 396   '(let ((id (nnheader-nov-field)))
 397      (if (string-match "^<[^>]+>$" id)
 398          id
 399        (nnheader-generate-fake-message-id))))
 400
 401 (defun nnheader-parse-nov ()
 402   (let ((eol (gnus-point-at-eol)))
 403     (vector
 404      (nnheader-nov-read-integer)        ; number
 405      (nnheader-nov-field)               ; subject
 406      (nnheader-nov-field)               ; from
 407      (nnheader-nov-field)               ; date
 408      (nnheader-nov-read-message-id)     ; id
 409      (nnheader-nov-field)               ; refs
 410      (nnheader-nov-read-integer)        ; chars
 411      (nnheader-nov-read-integer)        ; lines
 412      (if (eq (char-after) ?\n)
 413          nil
 414        (if (looking-at "Xref: ")
 415            (goto-char (match-end 0)))
 416        (nnheader-nov-field))            ; Xref
 417      (nnheader-nov-parse-extra))))      ; extra
 418
 419 (defun nnheader-insert-nov (header)
 420   (princ (mail-header-number header) (current-buffer))
 421   (let ((p (point)))
 422     (insert
 423      "\t"
 424      (or (mail-header-subject header) "(none)") "\t"
 425      (or (mail-header-from header) "(nobody)") "\t"
 426      (or (mail-header-date header) "") "\t"
 427      (or (mail-header-id header)
 428          (nnmail-message-id))
 429      "\t"
 430      (or (mail-header-references header) "") "\t")
 431     (princ (or (mail-header-chars header) 0) (current-buffer))
 432     (insert "\t")
 433     (princ (or (mail-header-lines header) 0) (current-buffer))
 434     (insert "\t")
 435     (when (mail-header-xref header)
 436       (insert "Xref: " (mail-header-xref header)))
 437     (when (or (mail-header-xref header)
 438               (mail-header-extra header))
 439       (insert "\t"))
 440     (when (mail-header-extra header)
 441       (let ((extra (mail-header-extra header)))
 442         (while extra
 443           (insert (symbol-name (caar extra))
 444                   ": " (cdar extra) "\t")
 445           (pop extra))))
 446     (insert "\n")
 447     (backward-char 1)
 448     (while (search-backward "\n" p t)
 449       (delete-char 1))
 450     (forward-line 1)))
 451
 452 (defun nnheader-parse-overview-file (file)
 453   "Parse FILE and return a list of headers."
 454   (mm-with-unibyte-buffer
 455     (nnheader-insert-file-contents file)
 456     (goto-char (point-min))
 457     (let (headers)
 458       (while (not (eobp))
 459         (push (nnheader-parse-nov) headers)
 460         (forward-line 1))
 461       (nreverse headers))))
 462
 463 (defun nnheader-write-overview-file (file headers)
 464   "Write HEADERS to FILE."
 465   (with-temp-file file
 466     (mapcar 'nnheader-insert-nov headers)))
 467
 468 (defun nnheader-insert-header (header)
 469   (insert
 470    "Subject: " (or (mail-header-subject header) "(none)") "\n"
 471    "From: " (or (mail-header-from header) "(nobody)") "\n"
 472    "Date: " (or (mail-header-date header) "") "\n"
 473    "Message-ID: " (or (mail-header-id header) (nnmail-message-id)) "\n"
 474    "References: " (or (mail-header-references header) "") "\n"
 475    "Lines: ")
 476   (princ (or (mail-header-lines header) 0) (current-buffer))
 477   (insert "\n\n"))
 478
 479 (defun nnheader-insert-article-line (article)
 480   (goto-char (point-min))
 481   (insert "220 ")
 482   (princ article (current-buffer))
 483   (insert " Article retrieved.\n")
 484   (search-forward "\n\n" nil 'move)
 485   (delete-region (point) (point-max))
 486   (forward-char -1)
 487   (insert "."))
 488
 489 (defun nnheader-nov-delete-outside-range (beg end)
 490   "Delete all NOV lines that lie outside the BEG to END range."
 491   ;; First we find the first wanted line.
 492   (nnheader-find-nov-line beg)
 493   (delete-region (point-min) (point))
 494   ;; Then we find the last wanted line.
 495   (when (nnheader-find-nov-line end)
 496     (forward-line 1))
 497   (delete-region (point) (point-max)))
 498
 499 (defun nnheader-find-nov-line (article)
 500   "Put point at the NOV line that start with ARTICLE.
 501 If ARTICLE doesn't exist, put point where that line
 502 would have been.  The function will return non-nil if
 503 the line could be found."
 504   ;; This function basically does a binary search.
 505   (let ((max (point-max))
 506         (min (goto-char (point-min)))
 507         (cur (current-buffer))
 508         (prev (point-min))
 509         num found)
 510     (while (not found)
 511       (goto-char (+ min (/ (- max min) 2)))
 512       (beginning-of-line)
 513       (if (or (= (point) prev)
 514               (eobp))
 515           (setq found t)
 516         (setq prev (point))
 517         (while (and (not (numberp (setq num (read cur))))
 518                     (not (eobp)))
 519           (gnus-delete-line))
 520         (cond ((> num article)
 521                (setq max (point)))
 522               ((< num article)
 523                (setq min (point)))
 524               (t
 525                (setq found 'yes)))))
 526     ;; We may be at the first line.
 527     (when (and (not num)
 528                (not (eobp)))
 529       (setq num (read cur)))
 530     ;; Now we may have found the article we're looking for, or we
 531     ;; may be somewhere near it.
 532     (when (and (not (eq found 'yes))
 533                (not (eq num article)))
 534       (setq found (point))
 535       (while (and (< (point) max)
 536                   (or (not (numberp num))
 537                       (< num article)))
 538         (forward-line 1)
 539         (setq found (point))
 540         (or (eobp)
 541             (= (setq num (read cur)) article)))
 542       (unless (eq num article)
 543         (goto-char found)))
 544     (beginning-of-line)
 545     (eq num article)))
 546
 547 ;; Various cruft the backends and Gnus need to communicate.
 548
 549 (defvar nntp-server-buffer nil)
 550 (defvar nntp-process-response nil)
 551 (defvar news-reply-yank-from nil)
 552 (defvar news-reply-yank-message-id nil)
 553
 554 (defvar nnheader-callback-function nil)
 555
 556 (defun nnheader-init-server-buffer ()
 557   "Initialize the Gnus-backend communication buffer."
 558   (save-excursion
 559     (unless (gnus-buffer-live-p nntp-server-buffer)
 560       (setq nntp-server-buffer (get-buffer-create " *nntpd*")))
 561     (set-buffer nntp-server-buffer)
 562     (mm-enable-multibyte)
 563     (erase-buffer)
 564     (kill-all-local-variables)
 565     (setq case-fold-search t)           ;Should ignore case.
 566     (set (make-local-variable 'nntp-process-response) nil)
 567     t))
 568
 569 ;;; Various functions the backends use.
 570
 571 (defun nnheader-file-error (file)
 572   "Return a string that says what is wrong with FILE."
 573   (format
 574    (cond
 575     ((not (file-exists-p file))
 576      "%s does not exist")
 577     ((file-directory-p file)
 578      "%s is a directory")
 579     ((not (file-readable-p file))
 580      "%s is not readable"))
 581    file))
 582
 583 (defun nnheader-insert-head (file)
 584   "Insert the head of the article."
 585   (when (file-exists-p file)
 586     (if (eq nnheader-max-head-length t)
 587         ;; Just read the entire file.
 588         (nnheader-insert-file-contents file)
 589       ;; Read 1K blocks until we find a separator.
 590       (let ((beg 0)
 591             format-alist)
 592         (while (and (eq nnheader-head-chop-length
 593                         (nth 1 (nnheader-insert-file-contents
 594                                 file nil beg
 595                                 (incf beg nnheader-head-chop-length))))
 596                     (prog1 (not (search-forward "\n\n" nil t))
 597                       (goto-char (point-max)))
 598                     (or (null nnheader-max-head-length)
 599                         (< beg nnheader-max-head-length))))))
 600     t))
 601
 602 (defun nnheader-article-p ()
 603   "Say whether the current buffer looks like an article."
 604   (goto-char (point-min))
 605   (if (not (search-forward "\n\n" nil t))
 606       nil
 607     (narrow-to-region (point-min) (1- (point)))
 608     (goto-char (point-min))
 609     (while (looking-at "[a-zA-Z][^ \t]+:.*\n\\([ \t].*\n\\)*\\|From .*\n")
 610       (goto-char (match-end 0)))
 611     (prog1
 612         (eobp)
 613       (widen))))
 614
 615 (defun nnheader-insert-references (references message-id)
 616   "Insert a References header based on REFERENCES and MESSAGE-ID."
 617   (if (and (not references) (not message-id))
 618       ;; This is invalid, but not all articles have Message-IDs.
 619       ()
 620     (mail-position-on-field "References")
 621     (let ((begin (gnus-point-at-bol))
 622           (fill-column 78)
 623           (fill-prefix "\t"))
 624       (when references
 625         (insert references))
 626       (when (and references message-id)
 627         (insert " "))
 628       (when message-id
 629         (insert message-id))
 630       ;; Fold long References lines to conform to RFC1036 (sort of).
 631       ;; The region must end with a newline to fill the region
 632       ;; without inserting extra newline.
 633       (fill-region-as-paragraph begin (1+ (point))))))
 634
 635 (defun nnheader-replace-header (header new-value)
 636   "Remove HEADER and insert the NEW-VALUE."
 637   (save-excursion
 638     (save-restriction
 639       (nnheader-narrow-to-headers)
 640       (prog1
 641           (message-remove-header header)
 642         (goto-char (point-max))
 643         (insert header ": " new-value "\n")))))
 644
 645 (defun nnheader-narrow-to-headers ()
 646   "Narrow to the head of an article."
 647   (widen)
 648   (narrow-to-region
 649    (goto-char (point-min))
 650    (if (search-forward "\n\n" nil t)
 651        (1- (point))
 652      (point-max)))
 653   (goto-char (point-min)))
 654
 655 (defun nnheader-remove-body ()
 656   "Remove the body from an article in this current buffer."
 657   (goto-char (point-min))
 658   (when (re-search-forward "\n\r?\n" nil t)
 659     (delete-region (point) (point-max))))
 660
 661 (defun nnheader-set-temp-buffer (name &optional noerase)
 662   "Set-buffer to an empty (possibly new) buffer called NAME with undo disabled."
 663   (set-buffer (get-buffer-create name))
 664   (buffer-disable-undo)
 665   (unless noerase
 666     (erase-buffer))
 667   (current-buffer))
 668
 669 (eval-when-compile (defvar jka-compr-compression-info-list))
 670 (defvar nnheader-numerical-files
 671   (if (boundp 'jka-compr-compression-info-list)
 672       (concat "\\([0-9]+\\)\\("
 673               (mapconcat (lambda (i) (aref i 0))
 674                          jka-compr-compression-info-list "\\|")
 675               "\\)?")
 676     "[0-9]+$")
 677   "Regexp that match numerical files.")
 678
 679 (defvar nnheader-numerical-short-files (concat "^" nnheader-numerical-files)
 680   "Regexp that matches numerical file names.")
 681
 682 (defvar nnheader-numerical-full-files (concat "/" nnheader-numerical-files)
 683   "Regexp that matches numerical full file names.")
 684
 685 (defsubst nnheader-file-to-number (file)
 686   "Take a FILE name and return the article number."
 687   (if (string= nnheader-numerical-short-files "^[0-9]+$")
 688       (string-to-number file)
 689     (string-match nnheader-numerical-short-files file)
 690     (string-to-number (match-string 0 file))))
 691
 692 (defvar nnheader-directory-files-is-safe
 693   (or (eq system-type 'windows-nt)
 694       (and (not (featurep 'xemacs))
 695            (> emacs-major-version 20)))
 696   "If non-nil, Gnus believes `directory-files' is safe.
 697 It has been reported numerous times that `directory-files' fails with
 698 an alarming frequency on NFS mounted file systems. If it is nil,
 699 `nnheader-directory-files-safe' is used.")
 700
 701 (defun nnheader-directory-files-safe (&rest args)
 702   "Execute `directory-files' twice and returns the longer result."
 703   (let ((first (apply 'directory-files args))
 704         (second (apply 'directory-files args)))
 705     (if (> (length first) (length second))
 706         first
 707       second)))
 708
 709 (defun nnheader-directory-articles (dir)
 710   "Return a list of all article files in directory DIR."
 711   (mapcar 'nnheader-file-to-number
 712           (if nnheader-directory-files-is-safe
 713               (directory-files
 714                dir nil nnheader-numerical-short-files t)
 715             (nnheader-directory-files-safe
 716              dir nil nnheader-numerical-short-files t))))
 717
 718 (defun nnheader-article-to-file-alist (dir)
 719   "Return an alist of article/file pairs in DIR."
 720   (mapcar (lambda (file) (cons (nnheader-file-to-number file) file))
 721           (if nnheader-directory-files-is-safe
 722               (directory-files
 723                dir nil nnheader-numerical-short-files t)
 724             (nnheader-directory-files-safe
 725              dir nil nnheader-numerical-short-files t))))
 726
 727 (defun nnheader-fold-continuation-lines ()
 728   "Fold continuation lines in the current buffer."
 729   (nnheader-replace-regexp "\\(\r?\n[ \t]+\\)+" " "))
 730
 731 (defun nnheader-translate-file-chars (file &optional full)
 732   "Translate FILE into something that can be a file name.
 733 If FULL, translate everything."
 734   (if (null nnheader-file-name-translation-alist)
 735       ;; No translation is necessary.
 736       file
 737     (let* ((i 0)
 738            trans leaf path len)
 739       (if full
 740           ;; Do complete translation.
 741           (setq leaf (copy-sequence file)
 742                 path ""
 743                 i (if (and (< 1 (length leaf)) (eq ?: (aref leaf 1)))
 744                       2 0))
 745         ;; We translate -- but only the file name.  We leave the directory
 746         ;; alone.
 747         (if (and (featurep 'xemacs)
 748                  (memq system-type '(cygwin32 win32 w32 mswindows windows-nt
 749                                               cygwin)))
 750             ;; This is needed on NT and stuff, because
 751             ;; file-name-nondirectory is not enough to split
 752             ;; file names, containing ':', e.g.
 753             ;; "d:\\Work\\News\\nntp+news.fido7.ru:fido7.ru.gnu.SCORE"
 754             ;;
 755             ;; we are trying to correctly split such names:
 756             ;; "d:file.name" -> "a:" "file.name"
 757             ;; "aaa:bbb.ccc" -> "" "aaa:bbb.ccc"
 758             ;; "d:aaa\\bbb:ccc"   -> "d:aaa\\" "bbb:ccc"
 759             ;; etc.
 760             ;; to translate then only the file name part.
 761             (progn
 762               (setq leaf file
 763                     path "")
 764               (if (string-match "\\(^\\w:\\|[/\\]\\)\\([^/\\]+\\)$" file)
 765                   (setq leaf (substring file (match-beginning 2))
 766                         path (substring file 0 (match-beginning 2)))))
 767           ;; Emacs DTRT, says andrewi.
 768           (setq leaf (file-name-nondirectory file)
 769                 path (file-name-directory file))))
 770       (setq len (length leaf))
 771       (while (< i len)
 772         (when (setq trans (cdr (assq (aref leaf i)
 773                                      nnheader-file-name-translation-alist)))
 774           (aset leaf i trans))
 775         (incf i))
 776       (concat path leaf))))
 777
 778 (defun nnheader-report (backend &rest args)
 779   "Report an error from the BACKEND.
 780 The first string in ARGS can be a format string."
 781   (set (intern (format "%s-status-string" backend))
 782        (if (< (length args) 2)
 783            (car args)
 784          (apply 'format args)))
 785   nil)
 786
 787 (defun nnheader-get-report (backend)
 788   "Get the most recent report from BACKEND."
 789   (condition-case ()
 790       (nnheader-message 5 "%s" (symbol-value (intern (format "%s-status-string"
 791                                                              backend))))
 792     (error (nnheader-message 5 ""))))
 793
 794 (defun nnheader-insert (format &rest args)
 795   "Clear the communication buffer and insert FORMAT and ARGS into the buffer.
 796 If FORMAT isn't a format string, it and all ARGS will be inserted
 797 without formatting."
 798   (save-excursion
 799     (set-buffer nntp-server-buffer)
 800     (erase-buffer)
 801     (if (string-match "%" format)
 802         (insert (apply 'format format args))
 803       (apply 'insert format args))
 804     t))
 805
 806 (defsubst nnheader-replace-chars-in-string (string from to)
 807   (mm-subst-char-in-string from to string))
 808
 809 (defun nnheader-replace-duplicate-chars-in-string (string from to)
 810   "Replace characters in STRING from FROM to TO."
 811   (let ((string (substring string 0))   ;Copy string.
 812         (len (length string))
 813         (idx 0) prev i)
 814     ;; Replace all occurrences of FROM with TO.
 815     (while (< idx len)
 816       (setq i (aref string idx))
 817       (when (and (eq prev from) (= i from))
 818         (aset string (1- idx) to)
 819         (aset string idx to))
 820       (setq prev i)
 821       (setq idx (1+ idx)))
 822     string))
 823
 824 (defun nnheader-file-to-group (file &optional top)
 825   "Return a group name based on FILE and TOP."
 826   (nnheader-replace-chars-in-string
 827    (if (not top)
 828        file
 829      (condition-case ()
 830          (substring (expand-file-name file)
 831                     (length
 832                      (expand-file-name
 833                       (file-name-as-directory top))))
 834        (error "")))
 835    nnheader-directory-separator-character ?.))
 836
 837 (defun nnheader-message (level &rest args)
 838   "Message if the Gnus backends are talkative."
 839   (if (or (not (numberp gnus-verbose-backends))
 840           (<= level gnus-verbose-backends))
 841       (apply 'message args)
 842     (apply 'format args)))
 843
 844 (defun nnheader-be-verbose (level)
 845   "Return whether the backends should be verbose on LEVEL."
 846   (or (not (numberp gnus-verbose-backends))
 847       (<= level gnus-verbose-backends)))
 848
 849 (defvar nnheader-pathname-coding-system 'iso-8859-1
 850   "*Coding system for file name.")
 851
 852 (defun nnheader-group-pathname (group dir &optional file)
 853   "Make file name for GROUP."
 854   (concat
 855    (let ((dir (file-name-as-directory (expand-file-name dir))))
 856      ;; If this directory exists, we use it directly.
 857      (file-name-as-directory
 858       (if (file-directory-p (concat dir group))
 859           (expand-file-name group dir)
 860         ;; If not, we translate dots into slashes.
 861         (expand-file-name (mm-encode-coding-string
 862                            (nnheader-replace-chars-in-string group ?. ?/)
 863                            nnheader-pathname-coding-system)
 864                           dir))))
 865    (cond ((null file) "")
 866          ((numberp file) (int-to-string file))
 867          (t file))))
 868
 869 (defun nnheader-concat (dir &rest files)
 870   "Concat DIR as directory to FILES."
 871   (apply 'concat (file-name-as-directory dir) files))
 872
 873 (defun nnheader-ms-strip-cr ()
 874   "Strip ^M from the end of all lines."
 875   (save-excursion
 876     (nnheader-remove-cr-followed-by-lf)))
 877
 878 (defun nnheader-file-size (file)
 879   "Return the file size of FILE or 0."
 880   (or (nth 7 (file-attributes file)) 0))
 881
 882 (defun nnheader-find-etc-directory (package &optional file first)
 883   "Go through `load-path' and find the \"../etc/PACKAGE\" directory.
 884 This function will look in the parent directory of each `load-path'
 885 entry, and look for the \"etc\" directory there.
 886 If FILE, find the \".../etc/PACKAGE\" file instead.
 887 If FIRST is non-nil, return the directory or the file found at the
 888 first.  Otherwise, find the newest one, though it may take a time."
 889   (let ((path load-path)
 890         dir results)
 891     ;; We try to find the dir by looking at the load path,
 892     ;; stripping away the last component and adding "etc/".
 893     (while path
 894       (if (and (car path)
 895                (file-exists-p
 896                 (setq dir (concat
 897                            (file-name-directory
 898                             (directory-file-name (car path)))
 899                            "etc/" package
 900                            (if file "" "/"))))
 901                (or file (file-directory-p dir)))
 902           (progn
 903             (or (member dir results)
 904                 (push dir results))
 905             (setq path (if first nil (cdr path))))
 906         (setq path (cdr path))))
 907     (if (or first (not (cdr results)))
 908         (car results)
 909       (car (sort results 'file-newer-than-file-p)))))
 910
 911 (eval-when-compile
 912   (defvar ange-ftp-path-format)
 913   (defvar efs-path-regexp))
 914 (defun nnheader-re-read-dir (path)
 915   "Re-read directory PATH if PATH is on a remote system."
 916   (if (and (fboundp 'efs-re-read-dir) (boundp 'efs-path-regexp))
 917       (when (string-match efs-path-regexp path)
 918         (efs-re-read-dir path))
 919     (when (and (fboundp 'ange-ftp-re-read-dir) (boundp 'ange-ftp-path-format))
 920       (when (string-match (car ange-ftp-path-format) path)
 921         (ange-ftp-re-read-dir path)))))
 922
 923 (defvar nnheader-file-coding-system 'raw-text
 924   "Coding system used in file backends of Gnus.")
 925
 926 (defun nnheader-insert-file-contents (filename &optional visit beg end replace)
 927   "Like `insert-file-contents', q.v., but only reads in the file.
 928 A buffer may be modified in several ways after reading into the buffer due
 929 to advanced Emacs features, such as file-name-handlers, format decoding,
 930 find-file-hooks, etc.
 931   This function ensures that none of these modifications will take place."
 932   (let ((coding-system-for-read nnheader-file-coding-system))
 933     (mm-insert-file-contents filename visit beg end replace)))
 934
 935 (defun nnheader-insert-nov-file (file first)
 936   (let ((size (nth 7 (file-attributes file)))
 937         (cutoff (* 32 1024)))
 938     (when size
 939       (if (< size cutoff)
 940           ;; If the file is small, we just load it.
 941           (nnheader-insert-file-contents file)
 942         ;; We start on the assumption that FIRST is pretty recent.  If
 943         ;; not, we just insert the rest of the file as well.
 944         (let (current)
 945           (nnheader-insert-file-contents file nil (- size cutoff) size)
 946           (goto-char (point-min))
 947           (delete-region (point) (or (search-forward "\n" nil 'move) (point)))
 948           (setq current (ignore-errors (read (current-buffer))))
 949           (if (and (numberp current)
 950                    (< current first))
 951               t
 952             (delete-region (point-min) (point-max))
 953             (nnheader-insert-file-contents file)))))))
 954
 955 (defun nnheader-find-file-noselect (&rest args)
 956   "Open a file with some variables bound.
 957 See `find-file-noselect' for the arguments."
 958   (let* ((format-alist nil)
 959          (auto-mode-alist (mm-auto-mode-alist))
 960          (default-major-mode 'fundamental-mode)
 961          (enable-local-variables nil)
 962          (after-insert-file-functions nil)
 963          (enable-local-eval nil)
 964          (coding-system-for-read nnheader-file-coding-system)
 965          (ffh (if (boundp 'find-file-hook)
 966                   'find-file-hook
 967                 'find-file-hooks))
 968          (val (symbol-value ffh)))
 969     (set ffh nil)
 970     (unwind-protect
 971         (apply 'find-file-noselect args)
 972       (set ffh val))))
 973
 974 (defun nnheader-directory-regular-files (dir)
 975   "Return a list of all regular files in DIR."
 976   (let ((files (directory-files dir t))
 977         out)
 978     (while files
 979       (when (file-regular-p (car files))
 980         (push (car files) out))
 981       (pop files))
 982     (nreverse out)))
 983
 984 (defun nnheader-directory-files (&rest args)
 985   "Same as `directory-files', but prune \".\" and \"..\"."
 986   (let ((files (apply 'directory-files args))
 987         out)
 988     (while files
 989       (unless (member (file-name-nondirectory (car files)) '("." ".."))
 990         (push (car files) out))
 991       (pop files))
 992     (nreverse out)))
 993
 994 (defmacro nnheader-skeleton-replace (from &optional to regexp)
 995   `(let ((new (generate-new-buffer " *nnheader replace*"))
 996          (cur (current-buffer))
 997          (start (point-min)))
 998      (set-buffer cur)
 999      (goto-char (point-min))
1000      (while (,(if regexp 're-search-forward 'search-forward)
1001              ,from nil t)
1002        (insert-buffer-substring
1003         cur start (prog1 (match-beginning 0) (set-buffer new)))
1004        (goto-char (point-max))
1005        ,(when to `(insert ,to))
1006        (set-buffer cur)
1007        (setq start (point)))
1008      (insert-buffer-substring
1009       cur start (prog1 (point-max) (set-buffer new)))
1010      (copy-to-buffer cur (point-min) (point-max))
1011      (kill-buffer (current-buffer))
1012      (set-buffer cur)))
1013
1014 (defun nnheader-replace-string (from to)
1015   "Do a fast replacement of FROM to TO from point to `point-max'."
1016   (nnheader-skeleton-replace from to))
1017
1018 (defun nnheader-replace-regexp (from to)
1019   "Do a fast regexp replacement of FROM to TO from point to `point-max'."
1020   (nnheader-skeleton-replace from to t))
1021
1022 (defun nnheader-strip-cr ()
1023   "Strip all \r's from the current buffer."
1024   (nnheader-skeleton-replace "\r"))
1025
1026 (defalias 'nnheader-run-at-time 'run-at-time)
1027 (defalias 'nnheader-cancel-timer 'cancel-timer)
1028 (defalias 'nnheader-cancel-function-timers 'cancel-function-timers)
1029 (defalias 'nnheader-string-as-multibyte 'string-as-multibyte)
1030
1031 (defun nnheader-accept-process-output (process)
1032   (accept-process-output
1033    process
1034    (truncate nnheader-read-timeout)
1035    (truncate (* (- nnheader-read-timeout
1036                    (truncate nnheader-read-timeout))
1037                 1000))))
1038
1039 (when (featurep 'xemacs)
1040   (require 'nnheaderxm))
1041
1042 (run-hooks 'nnheader-load-hook)
1043
1044 (provide 'nnheader)
1045
1046 ;;; arch-tag: a9c4b7d9-52ae-4ec9-b196-dfd93124d202
1047 ;;; nnheader.el ends here