lisp/url/url-handlers.el

   1 ;;; url-handlers.el --- file-name-handler stuff for URL loading
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2004,
   4 ;;   2005 Free Software Foundation, Inc.
   5
   6 ;; Keywords: comm, data, processes, hypermedia
   7
   8 ;; This file is part of GNU Emacs.
   9 ;;
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 ;; (require 'url)
  30 (eval-when-compile (require 'url-parse))
  31 ;; (require 'url-util)
  32 (eval-when-compile (require 'mm-decode))
  33 ;; (require 'mailcap)
  34 ;; The following functions in the byte compiler's warnings are known not
  35 ;; to cause any real problem for the following reasons:
  36 ;; - mm-save-part-to-file, mm-destroy-parts: always used
  37 ;;   after mm-dissect-buffer and defined in the same file.
  38 ;; The following are autoloaded instead of `require'd to avoid eagerly
  39 ;; loading all of URL when turning on url-handler-mode in the .emacs.
  40 (autoload 'url-retrieve-synchronously "url" "Retrieve url synchronously.")
  41 (autoload 'url-expand-file-name "url-expand" "Convert url to a fully specified url, and canonicalize it.")
  42 (autoload 'mm-dissect-buffer "mm-decode" "Dissect the current buffer and return a list of MIME handles.")
  43 (autoload 'url-scheme-get-property "url-methods" "Get property of a URL SCHEME.")
  44
  45 (eval-when-compile
  46   (require 'cl))
  47
  48 ;; Implementation status
  49 ;; ---------------------
  50 ;; Function                             Status
  51 ;; ------------------------------------------------------------
  52 ;; add-name-to-file                     Needs DAV Bindings
  53 ;; copy-file                            Broken (assumes 1st item is URL)
  54 ;; delete-directory                     Finished (DAV)
  55 ;; delete-file                          Finished (DAV)
  56 ;; diff-latest-backup-file
  57 ;; directory-file-name                  unnecessary (what about VMS)?
  58 ;; directory-files                      Finished (DAV)
  59 ;; dired-call-process
  60 ;; dired-compress-file
  61 ;; dired-uncache
  62 ;; expand-file-name                     Finished
  63 ;; file-accessible-directory-p
  64 ;; file-attributes                      Finished, better with DAV
  65 ;; file-directory-p                     Needs DAV, finished
  66 ;; file-executable-p                    Finished
  67 ;; file-exists-p                        Finished
  68 ;; file-local-copy
  69 ;; file-modes
  70 ;; file-name-all-completions            Finished (DAV)
  71 ;; file-name-as-directory
  72 ;; file-name-completion                 Finished (DAV)
  73 ;; file-name-directory
  74 ;; file-name-nondirectory
  75 ;; file-name-sans-versions              why?
  76 ;; file-newer-than-file-p
  77 ;; file-ownership-preserved-p           No way to know
  78 ;; file-readable-p                      Finished
  79 ;; file-regular-p                       !directory_p
  80 ;; file-symlink-p                       Needs DAV bindings
  81 ;; file-truename                        Needs DAV bindings
  82 ;; file-writable-p                      Check for LOCK?
  83 ;; find-backup-file-name                why?
  84 ;; get-file-buffer                      why?
  85 ;; insert-directory                     Use DAV
  86 ;; insert-file-contents                 Finished
  87 ;; load
  88 ;; make-directory                       Finished (DAV)
  89 ;; make-symbolic-link                   Needs DAV bindings
  90 ;; rename-file                          Finished (DAV)
  91 ;; set-file-modes                       Use mod_dav specific executable flag?
  92 ;; set-visited-file-modtime             Impossible?
  93 ;; shell-command                        Impossible?
  94 ;; unhandled-file-name-directory
  95 ;; vc-registered                        Finished (DAV)
  96 ;; verify-visited-file-modtime
  97 ;; write-region
  98
  99 (defvar url-handler-regexp
 100   "\\`\\(https?\\|ftp\\|file\\|nfs\\)://"
 101   "*A regular expression for matching  URLs handled by file-name-handler-alist.
 102 Some valid URL protocols just do not make sense to visit interactively
 103 \(about, data, info, irc, mailto, etc\).  This regular expression
 104 avoids conflicts with local files that look like URLs \(Gnus is
 105 particularly bad at this\).")
 106
 107 ;;;###autoload
 108 (define-minor-mode url-handler-mode
 109   "Use URL to handle URL-like file names."
 110   :global t :group 'url
 111   (if (not (boundp 'file-name-handler-alist))
 112       ;; Can't be turned ON anyway.
 113       (setq url-handler-mode nil)
 114     ;; Remove old entry, if any.
 115     (setq file-name-handler-alist
 116           (delq (rassq 'url-file-handler file-name-handler-alist)
 117                 file-name-handler-alist))
 118     (if url-handler-mode
 119         (push (cons url-handler-regexp 'url-file-handler)
 120               file-name-handler-alist))))
 121
 122 (defun url-run-real-handler (operation args)
 123   (let ((inhibit-file-name-handlers (cons 'url-file-handler
 124                                           (if (eq operation inhibit-file-name-operation)
 125                                               inhibit-file-name-handlers)))
 126         (inhibit-file-name-operation operation))
 127     (apply operation args)))
 128
 129 (defun url-file-handler (operation &rest args)
 130   "Function called from the `file-name-handler-alist' routines.
 131 OPERATION is what needs to be done (`file-exists-p', etc).  ARGS are
 132 the arguments that would have been passed to OPERATION."
 133   (let ((fn (or (get operation 'url-file-handlers)
 134                 (intern-soft (format "url-%s" operation))))
 135         (val nil)
 136         (hooked nil))
 137     (if (and fn (fboundp fn))
 138         (setq hooked t
 139               val (apply fn args))
 140       (setq hooked nil
 141             val (url-run-real-handler operation args)))
 142     (url-debug 'handlers "%s %S%S => %S" (if hooked "Hooked" "Real")
 143                operation args val)
 144     val))
 145
 146 (defun url-file-handler-identity (&rest args)
 147   ;; Identity function
 148   (car args))
 149
 150 ;; These are operations that we can fully support
 151 (put 'file-readable-p 'url-file-handlers 'url-file-exists-p)
 152 (put 'substitute-in-file-name 'url-file-handlers 'url-file-handler-identity)
 153 (put 'file-name-absolute-p 'url-file-handlers (lambda (&rest ignored) t))
 154 (put 'expand-file-name 'url-file-handlers 'url-handler-expand-file-name)
 155
 156 ;; These are operations that we do not support yet (DAV!!!)
 157 (put 'file-writable-p 'url-file-handlers 'ignore)
 158 (put 'file-symlink-p 'url-file-handlers 'ignore)
 159 ;; Just like for ange-ftp: let's not waste time trying to look for RCS/foo,v
 160 ;; files and such since we can't do anything clever with them anyway.
 161 (put 'vc-registered 'url-file-handlers 'ignore)
 162
 163 (defun url-handler-expand-file-name (file &optional base)
 164   (if (file-name-absolute-p file)
 165       (expand-file-name file "/")
 166     (url-expand-file-name file base)))
 167
 168 ;; The actual implementation
 169 ;;;###autoload
 170 (defun url-copy-file (url newname &optional ok-if-already-exists keep-time)
 171   "Copy URL to NEWNAME.  Both args must be strings.
 172 Signals a `file-already-exists' error if file NEWNAME already exists,
 173 unless a third argument OK-IF-ALREADY-EXISTS is supplied and non-nil.
 174 A number as third arg means request confirmation if NEWNAME already exists.
 175 This is what happens in interactive use with M-x.
 176 Fourth arg KEEP-TIME non-nil means give the new file the same
 177 last-modified time as the old one.  (This works on only some systems.)
 178 A prefix arg makes KEEP-TIME non-nil."
 179   (if (and (file-exists-p newname)
 180            (not ok-if-already-exists))
 181       (error "Opening output file: File already exists, %s" newname))
 182   (let ((buffer (url-retrieve-synchronously url))
 183         (handle nil))
 184     (if (not buffer)
 185         (error "Opening input file: No such file or directory, %s" url))
 186     (with-current-buffer buffer
 187       (setq handle (mm-dissect-buffer t)))
 188     (mm-save-part-to-file handle newname)
 189     (kill-buffer buffer)
 190     (mm-destroy-parts handle)))
 191
 192 ;;;###autoload
 193 (defun url-file-local-copy (url &rest ignored)
 194   "Copy URL into a temporary file on this machine.
 195 Returns the name of the local copy, or nil, if FILE is directly
 196 accessible."
 197   (let ((filename (make-temp-name "url")))
 198     (url-copy-file url filename)
 199     filename))
 200
 201 ;;;###autoload
 202 (defun url-insert-file-contents (url &optional visit beg end replace)
 203   (let ((buffer (url-retrieve-synchronously url))
 204         (handle nil)
 205         (charset nil)
 206         (data nil))
 207     (if (not buffer)
 208         (error "Opening input file: No such file or directory, %s" url))
 209     (if visit (setq buffer-file-name url))
 210     (with-current-buffer buffer
 211       (setq handle (mm-dissect-buffer t))
 212       (set-buffer (mm-handle-buffer handle))
 213       (setq data (if beg (buffer-substring beg end)
 214                    (buffer-string))))
 215     (kill-buffer buffer)
 216     (mm-destroy-parts handle)
 217     (if replace (delete-region (point-min) (point-max)))
 218     (save-excursion
 219       (setq charset (mail-content-type-get (mm-handle-type handle)
 220                                              'charset))
 221       (let ((start (point)))
 222         (if charset
 223             (insert (mm-decode-string data (mm-charset-to-coding-system charset)))
 224           (progn
 225             (insert data)
 226             (decode-coding-inserted-region start (point) url visit beg end replace)))))
 227     (list url (length data))))
 228
 229 (defun url-file-name-completion (url directory)
 230   (error "Unimplemented"))
 231
 232 (defun url-file-name-all-completions (file directory)
 233   (error "Unimplemented"))
 234
 235 ;; All other handlers map onto their respective backends.
 236 (defmacro url-handlers-create-wrapper (method args)
 237   `(defun ,(intern (format "url-%s" method)) ,args
 238      ,(format "URL file-name-handler wrapper for `%s' call.\n---\n%s" method
 239               (or (documentation method t) "No original documentation."))
 240      (setq url (url-generic-parse-url url))
 241      (when (url-type url)
 242        (funcall (url-scheme-get-property (url-type url) (quote ,method))
 243                 ,@(remove '&rest (remove '&optional args))))))
 244
 245 (url-handlers-create-wrapper file-exists-p (url))
 246 (url-handlers-create-wrapper file-attributes (url &optional id-format))
 247 (url-handlers-create-wrapper file-symlink-p (url))
 248 (url-handlers-create-wrapper file-writable-p (url))
 249 (url-handlers-create-wrapper file-directory-p (url))
 250 (url-handlers-create-wrapper file-executable-p (url))
 251 (url-handlers-create-wrapper directory-files (url &optional full match nosort))
 252 (url-handlers-create-wrapper file-truename (url &optional counter prev-dirs))
 253
 254 (add-hook 'find-file-hook 'url-handlers-set-buffer-mode)
 255
 256 (defun url-handlers-set-buffer-mode ()
 257   "Set correct modes for the current buffer if visiting a remote file."
 258   (and (stringp buffer-file-name)
 259        (string-match url-handler-regexp buffer-file-name)
 260        (auto-save-mode 0)))
 261
 262 (provide 'url-handlers)
 263
 264 ;; arch-tag: 7300b99c-cc83-42ff-9147-79b2723c62ac
 265 ;;; url-handlers.el ends here