lisp/diff.el

   1 ;;; diff.el --- run `diff' in compilation-mode
   2
   3 ;; Copyright (C) 1992, 1994, 1996, 2001, 2002, 2003, 2004,
   4 ;;   2005 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: unix, tools
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This package helps you explore differences between files, using the
  29 ;; UNIX command diff(1).  The commands are `diff' and `diff-backup'.
  30 ;; You can specify options with `diff-switches'.
  31
  32 ;;; Code:
  33
  34 (defgroup diff nil
  35   "Comparing files with `diff'."
  36   :group 'tools)
  37
  38 ;;;###autoload
  39 (defcustom diff-switches "-c"
  40   "*A string or list of strings specifying switches to be passed to diff."
  41   :type '(choice string (repeat string))
  42   :group 'diff)
  43
  44 ;;;###autoload
  45 (defcustom diff-command "diff"
  46   "*The command to use to run diff."
  47   :type 'string
  48   :group 'diff)
  49
  50 (defvar diff-old-temp-file nil
  51   "This is the name of a temp file to be deleted after diff finishes.")
  52 (defvar diff-new-temp-file nil
  53   "This is the name of a temp file to be deleted after diff finishes.")
  54
  55 ;; prompt if prefix arg present
  56 (defun diff-switches ()
  57   (if current-prefix-arg
  58       (read-string "Diff switches: "
  59                    (if (stringp diff-switches)
  60                        diff-switches
  61                      (mapconcat 'identity diff-switches " ")))))
  62
  63 (defun diff-sentinel (code)
  64   "Code run when the diff process exits.
  65 CODE is the exit code of the process.  It should be 0 iff no diffs were found."
  66   (if diff-old-temp-file (delete-file diff-old-temp-file))
  67   (if diff-new-temp-file (delete-file diff-new-temp-file))
  68   (save-excursion
  69     (goto-char (point-max))
  70     (insert (format "\nDiff finished%s.  %s\n"
  71                     (if (equal 0 code) " (no differences)" "")
  72                     (current-time-string)))))
  73
  74 ;;;###autoload
  75 (defun diff (old new &optional switches no-async)
  76   "Find and display the differences between OLD and NEW files.
  77 Interactively the current buffer's file name is the default for NEW
  78 and a backup file for NEW is the default for OLD.
  79 If NO-ASYNC is non-nil, call diff synchronously.
  80 With prefix arg, prompt for diff switches."
  81   (interactive
  82    (let (oldf newf)
  83      (setq newf (buffer-file-name)
  84            newf (if (and newf (file-exists-p newf))
  85                     (read-file-name
  86                      (concat "Diff new file (default "
  87                              (file-name-nondirectory newf) "): ")
  88                      nil newf t)
  89                   (read-file-name "Diff new file: " nil nil t)))
  90      (setq oldf (file-newest-backup newf)
  91            oldf (if (and oldf (file-exists-p oldf))
  92                     (read-file-name
  93                      (concat "Diff original file (default "
  94                              (file-name-nondirectory oldf) "): ")
  95                      (file-name-directory oldf) oldf t)
  96                   (read-file-name "Diff original file: "
  97                                   (file-name-directory newf) nil t)))
  98      (list oldf newf (diff-switches))))
  99   (setq new (expand-file-name new)
 100         old (expand-file-name old))
 101   (or switches (setq switches diff-switches)) ; If not specified, use default.
 102   (let* ((old-alt (file-local-copy old))
 103         (new-alt (file-local-copy new))
 104          (command
 105           (mapconcat 'identity
 106                      `(,diff-command
 107                        ;; Use explicitly specified switches
 108                        ,@(if (listp switches) switches (list switches))
 109                        ,@(if (or old-alt new-alt)
 110                              (list "-L" old "-L" new))
 111                        ,(shell-quote-argument (or old-alt old))
 112                        ,(shell-quote-argument (or new-alt new)))
 113                      " "))
 114          (buf (get-buffer-create "*Diff*"))
 115          (thisdir default-directory)
 116          proc)
 117     (save-excursion
 118       (display-buffer buf)
 119       (set-buffer buf)
 120       (setq buffer-read-only nil)
 121       (buffer-disable-undo (current-buffer))
 122       (erase-buffer)
 123       (buffer-enable-undo (current-buffer))
 124       (diff-mode)
 125       (set (make-local-variable 'revert-buffer-function)
 126            `(lambda (ignore-auto noconfirm)
 127               (diff ',old ',new ',switches ',no-async)))
 128       (set (make-local-variable 'diff-old-temp-file) old-alt)
 129       (set (make-local-variable 'diff-new-temp-file) new-alt)
 130       (setq default-directory thisdir)
 131       (insert command "\n")
 132       (if (and (not no-async) (fboundp 'start-process))
 133           (progn
 134             (setq proc (start-process "Diff" buf shell-file-name
 135                                       shell-command-switch command))
 136             (set-process-sentinel
 137              proc (lambda (proc msg)
 138                     (with-current-buffer (process-buffer proc)
 139                       (diff-sentinel (process-exit-status proc))))))
 140         ;; Async processes aren't available.
 141         (diff-sentinel
 142          (call-process shell-file-name nil buf nil
 143                        shell-command-switch command))))
 144     buf))
 145
 146 ;;;###autoload
 147 (defun diff-backup (file &optional switches)
 148   "Diff this file with its backup file or vice versa.
 149 Uses the latest backup, if there are several numerical backups.
 150 If this file is a backup, diff it with its original.
 151 The backup file is the first file given to `diff'.
 152 With prefix arg, prompt for diff switches."
 153   (interactive (list (read-file-name "Diff (file with backup): ")
 154                      (diff-switches)))
 155   (let (bak ori)
 156     (if (backup-file-name-p file)
 157         (setq bak file
 158               ori (file-name-sans-versions file))
 159       (setq bak (or (diff-latest-backup-file file)
 160                     (error "No backup found for %s" file))
 161             ori file))
 162     (diff bak ori switches)))
 163
 164 (defun diff-latest-backup-file (fn)     ; actually belongs into files.el
 165   "Return the latest existing backup of FILE, or nil."
 166   (let ((handler (find-file-name-handler fn 'diff-latest-backup-file)))
 167     (if handler
 168         (funcall handler 'diff-latest-backup-file fn)
 169       (file-newest-backup fn))))
 170
 171 (provide 'diff)
 172
 173 ;;; arch-tag: 7de2c29b-7ea5-4b85-9b9d-72dd860de2bd
 174 ;;; diff.el ends here