lisp/ls-lisp.el

   1 ;;; ls-lisp.el --- emulate insert-directory completely in Emacs Lisp
   2
   3 ;; Copyright (C) 1992, 1994, 2000 Free Software Foundation, Inc.
   4
   5 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   6 ;; Modified by: Francis J. Wright <F.J.Wright@maths.qmw.ac.uk>
   7 ;; Maintainer: FSF
   8 ;; Keywords: unix, dired
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; OVERVIEW ==========================================================
  30
  31 ;; This file redefines the function `insert-directory' to implement it
  32 ;; directly from Emacs lisp, without running ls in a subprocess.  It
  33 ;; is useful if you cannot afford to fork Emacs on a real memory UNIX,
  34 ;; under VMS or other non-UNIX platforms if you don't have the ls
  35 ;; program, or if you want a different format from what ls offers.
  36
  37 ;; This function can use regexps instead of shell wildcards.  If you
  38 ;; enter regexps remember to double each $ sign.  For example, to
  39 ;; include files *.el, enter `.*\.el$$', resulting in the regexp
  40 ;; `.*\.el$'.
  41
  42 ;; RESTRICTIONS ======================================================
  43
  44 ;; * A few obscure ls switches are still ignored: see the docstring of
  45 ;; `insert-directory'.
  46
  47 ;; * Generally only numeric uid/gid.
  48
  49 ;; TO DO =============================================================
  50
  51 ;; Complete handling of F switch (if/when possible).
  52
  53 ;; FJW: May be able to sort much faster by consing the sort key onto
  54 ;; the front of each list element, sorting and then stripping the key
  55 ;; off again!
  56
  57 ;;; History:
  58
  59 ;; Written originally by Sebastian Kremer <sk@thp.uni-koeln.de>
  60 ;; Revised by Andrew Innes and Geoff Volker (and maybe others).
  61
  62 ;; Modified by Francis J. Wright <F.J.Wright@maths.qmw.ac.uk>, mainly
  63 ;; to support many more ls options, "platform emulation", hooks for
  64 ;; external symbolic link support and more robust sorting.
  65
  66 ;;; Code:
  67
  68 (eval-when-compile (require 'cl))
  69
  70 (defgroup ls-lisp nil
  71   "Emulate the ls program completely in Emacs Lisp."
  72   :version "21.1"
  73   :group 'dired)
  74
  75 (defcustom ls-lisp-emulation
  76   (cond ((eq system-type 'macos) 'MacOS)
  77         ;; ((eq system-type 'windows-nt) 'MS-Windows)
  78         ((memq system-type
  79                '(hpux dgux usg-unix-v unisoft-unix rtu irix berkeley-unix))
  80          'UNIX))                        ; very similar to GNU
  81   ;; Anything else defaults to nil, meaning GNU.
  82   "*Platform to emulate: GNU (default), MacOS, MS-Windows, UNIX.
  83 Corresponding value is one of the atoms: nil, MacOS, MS-Windows, UNIX.
  84 Sets default values for: `ls-lisp-ignore-case', `ls-lisp-dirs-first',
  85 `ls-lisp-verbosity'.  Need not match actual platform.  Changing this
  86 option will have no effect until you restart Emacs."
  87   :type '(choice (const :tag "GNU" nil)
  88                  (const MacOS)
  89                  (const MS-Windows)
  90                  (const UNIX))
  91   :group 'ls-lisp)
  92
  93 (defcustom ls-lisp-ignore-case
  94   ;; Name change for consistency with other option names.
  95   (or (memq ls-lisp-emulation '(MS-Windows MacOS))
  96       (and (boundp 'ls-lisp-dired-ignore-case) ls-lisp-dired-ignore-case))
  97   "*Non-nil causes ls-lisp alphabetic sorting to ignore case."
  98   :type 'boolean
  99   :group 'ls-lisp)
 100
 101 (defcustom ls-lisp-dirs-first (eq ls-lisp-emulation 'MS-Windows)
 102   "*Non-nil causes ls-lisp to sort directories first in any ordering.
 103 \(Or last if it is reversed.)  Follows Microsoft Windows Explorer."
 104   ;; Functionality suggested by Chris McMahan <cmcmahan@one.net>
 105   :type 'boolean
 106   :group 'ls-lisp)
 107
 108 (defcustom ls-lisp-verbosity
 109   (cond ((eq ls-lisp-emulation 'MacOS) nil)
 110         ((eq ls-lisp-emulation 'MS-Windows)
 111          (if (and (fboundp 'w32-using-nt) (w32-using-nt))
 112              '(links)))                 ; distinguish NT/2K from 9x
 113         ((eq ls-lisp-emulation 'UNIX) '(links uid)) ; UNIX ls
 114         (t '(links uid gid)))           ; GNU ls
 115   "*A list of optional file attributes that ls-lisp should display.
 116 It should contain none or more of the symbols: links, uid, gid.
 117 nil (or an empty list) means display none of them.
 118
 119 Concepts come from UNIX: `links' means count of names associated with
 120 the file\; `uid' means user (owner) identifier\; `gid' means group
 121 identifier.
 122
 123 If emulation is MacOS then default is nil\;
 124 if emulation is MS-Windows then default is `(links)' if platform is
 125 Windows NT/2K, nil otherwise\;
 126 if emulation is UNIX then default is `(links uid)'\;
 127 if emulation is GNU then default is `(links uid gid)'."
 128   ;; Functionality suggested by Howard Melman <howard@silverstream.com>
 129   :type '(set (const :tag "Show Link Count" links)
 130               (const :tag "Show User" uid)
 131               (const :tag "Show Group" gid))
 132   :group 'ls-lisp)
 133
 134 (defcustom ls-lisp-use-insert-directory-program
 135   (not (memq system-type '(macos ms-dos windows-nt)))
 136   "*Non-nil causes ls-lisp to revert back to using `insert-directory-program'.
 137 This is useful on platforms where ls-lisp is dumped into Emacs, such as
 138 Microsoft Windows, but you would still like to use a program to list
 139 the contents of a directory."
 140   :type 'boolean
 141   :group 'ls-lisp)
 142
 143 ;;; Autoloaded because it is let-bound in `recover-session', `mail-recover-1'.
 144 ;;;###autoload
 145 (defcustom ls-lisp-support-shell-wildcards t
 146   "*Non-nil means ls-lisp treats file patterns as shell wildcards.
 147 Otherwise they are treated as Emacs regexps (for backward compatibility)."
 148   :type 'boolean
 149   :group 'ls-lisp)
 150
 151 (defcustom ls-lisp-format-time-list
 152   '("%b %e %H:%M"
 153     "%b %e  %Y")
 154   "*List of `format-time-string' specs to display file time stamps.
 155 They are used whenever a locale is not specified to use instead.
 156
 157 Syntax:  (EARLY-TIME-FORMAT OLD-TIME-FORMAT)
 158
 159 The EARLY-TIME-FORMAT is used if file has been modified within the
 160 current year. The OLD-TIME-FORMAT is used for older files.  To use ISO
 161 8601 dates, you could set:
 162
 163 \(setq ls-lisp-format-time-list
 164        '(\"%Y-%m-%d %H:%M\"
 165          \"%Y-%m-%d      \"))"
 166   :type '(list (string :tag "Early time format")
 167                (string :tag "Old time format"))
 168   :group 'ls-lisp)
 169
 170 (defvar original-insert-directory nil
 171   "This holds the original function definition of `insert-directory'.")
 172
 173 ;; Remember the original insert-directory function
 174 (or (featurep 'ls-lisp)  ; FJW: unless this file is being reloaded!
 175     (setq original-insert-directory (symbol-function 'insert-directory)))
 176
 177 ;; This stub is to allow ls-lisp to parse symbolic links via another
 178 ;; library such as w32-symlinks.el from
 179 ;; http://centaur.maths.qmw.ac.uk/Emacs/:
 180 (defun ls-lisp-parse-symlink (file-name)
 181   "This stub may be redefined to parse FILE-NAME as a symlink.
 182 It should return nil or the link target as a string."
 183   nil)
 184
 185 \f
 186 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 187
 188 (defun insert-directory (file switches &optional wildcard full-directory-p)
 189   "Insert directory listing for FILE, formatted according to SWITCHES.
 190 Leaves point after the inserted text.
 191 SWITCHES may be a string of options, or a list of strings.
 192 Optional third arg WILDCARD means treat FILE as shell wildcard.
 193 Optional fourth arg FULL-DIRECTORY-P means file is a directory and
 194 switches do not contain `d', so that a full listing is expected.
 195
 196 This version of the function comes from `ls-lisp.el'.
 197 If the value of `ls-lisp-use-insert-directory-program' is non-nil then
 198 it works exactly like the version from `files.el' and runs a directory
 199 listing program whose name is in the variable
 200 `insert-directory-program'; if also WILDCARD is non-nil then it runs
 201 the shell specified by `shell-file-name'.  If the value of
 202 `ls-lisp-use-insert-directory-program' is nil then it runs a Lisp
 203 emulation.
 204
 205 The Lisp emulation does not run any external programs or shells.  It
 206 supports ordinary shell wildcards if `ls-lisp-support-shell-wildcards'
 207 is non-nil; otherwise, it interprets wildcards as regular expressions
 208 to match file names.  It does not support all `ls' switches -- those
 209 that work are: A a c i r S s t u U X g G B C R and F partly."
 210   (if ls-lisp-use-insert-directory-program
 211       (funcall original-insert-directory
 212                file switches wildcard full-directory-p)
 213     ;; We need the directory in order to find the right handler.
 214     (let ((handler (find-file-name-handler (expand-file-name file)
 215                                            'insert-directory)))
 216       (if handler
 217           (funcall handler 'insert-directory file switches
 218                    wildcard full-directory-p)
 219         ;; Convert SWITCHES to a list of characters.
 220         (setq switches (delete ?- (append switches nil)))
 221         (if wildcard
 222             (setq wildcard
 223                   (if ls-lisp-support-shell-wildcards
 224                       (wildcard-to-regexp (file-name-nondirectory file))
 225                     (file-name-nondirectory file))
 226                   file (file-name-directory file))
 227           (if (memq ?B switches) (setq wildcard "[^~]\\'")))
 228         (ls-lisp-insert-directory
 229          file switches (ls-lisp-time-index switches)
 230          wildcard full-directory-p)
 231         ;; Try to insert the amount of free space.
 232         (save-excursion
 233           (goto-char (point-min))
 234           ;; First find the line to put it on.
 235           (when (re-search-forward "^total" nil t)
 236             (let ((available (get-free-disk-space ".")))
 237               (when available
 238                 ;; Replace "total" with "total used", to avoid confusion.
 239                 (replace-match "total used in directory")
 240                 (end-of-line)
 241                 (insert " available " available)))))))))
 242
 243 (defun ls-lisp-insert-directory
 244   (file switches time-index wildcard full-directory-p)
 245   "Insert directory listing for FILE, formatted according to SWITCHES.
 246 Leaves point after the inserted text.  This is an internal function
 247 optionally called by the `ls-lisp.el' version of `insert-directory'.
 248 It is called recursively if the -R switch is used.
 249 SWITCHES is a *list* of characters.  TIME-INDEX is the time index into
 250 file-attributes according to SWITCHES.  WILDCARD is nil or an *Emacs
 251 regexp*.  FULL-DIRECTORY-P means file is a directory and SWITCHES does
 252 not contain `d', so that a full listing is expected."
 253   ;; Sometimes we get ".../foo*/" as FILE.  While the shell and
 254   ;; `ls' don't mind, we certainly do, because it makes us think
 255   ;; there is no wildcard, only a directory name.
 256   (if (and ls-lisp-support-shell-wildcards
 257            (string-match "[[?*]" file))
 258       (progn
 259         (or (not (eq (aref file (1- (length file))) ?/))
 260             (setq file (substring file 0 (1- (length file)))))
 261         (setq wildcard t)))
 262   (if (or wildcard full-directory-p)
 263       (let* ((dir (file-name-as-directory file))
 264              (default-directory dir)    ; so that file-attributes works
 265              (file-alist
 266               (directory-files-and-attributes dir nil wildcard t))
 267              (now (current-time))
 268              (sum 0)
 269              ;; do all bindings here for speed
 270              total-line files elt short file-size fil attr)
 271         (cond ((memq ?A switches)
 272                (setq file-alist
 273                      (ls-lisp-delete-matching "^\\.\\.?$" file-alist)))
 274               ((not (memq ?a switches))
 275                ;; if neither -A  nor -a, flush . files
 276                (setq file-alist
 277                      (ls-lisp-delete-matching "^\\." file-alist))))
 278         (setq file-alist
 279               (ls-lisp-handle-switches file-alist switches))
 280         (if (memq ?C switches)          ; column (-C) format
 281             (ls-lisp-column-format file-alist)
 282           (setq total-line (cons (point) (car-safe file-alist)))
 283           (setq files file-alist)
 284           (while files                  ; long (-l) format
 285             (setq elt (car files)
 286                   files (cdr files)
 287                   short (car elt)
 288                   attr (cdr elt)
 289                   file-size (nth 7 attr))
 290             (and attr
 291                  (setq sum (+ file-size
 292                               ;; Even if neither SUM nor file's size
 293                               ;; overflow, their sum could.
 294                               (if (or (< sum (- 134217727 file-size))
 295                                       (floatp sum)
 296                                       (floatp file-size))
 297                                   sum
 298                                 (float sum))))
 299                  (insert (ls-lisp-format short attr file-size
 300                                          switches time-index now))))
 301           ;; Insert total size of all files:
 302           (save-excursion
 303             (goto-char (car total-line))
 304             (or (cdr total-line)
 305                 ;; Shell says ``No match'' if no files match
 306                 ;; the wildcard; let's say something similar.
 307                 (insert "(No match)\n"))
 308             (insert (format "total %.0f\n" (fceiling (/ sum 1024.0))))))
 309         (if (memq ?R switches)
 310             ;; List the contents of all directories recursively.
 311             ;; cadr of each element of `file-alist' is t for
 312             ;; directory, string (name linked to) for symbolic
 313             ;; link, or nil.
 314             (while file-alist
 315               (setq elt (car file-alist)
 316                     file-alist (cdr file-alist))
 317               (when (and (eq (cadr elt) t) ; directory
 318                          (not (string-match "\\`\\.\\.?\\'" (car elt))))
 319                 (setq elt (expand-file-name (car elt) dir))
 320                 (insert "\n" elt ":\n")
 321                 (ls-lisp-insert-directory
 322                  elt switches time-index wildcard full-directory-p)))))
 323     ;; If not full-directory-p, FILE *must not* end in /, as
 324     ;; file-attributes will not recognize a symlink to a directory,
 325     ;; so must make it a relative filename as ls does:
 326     (if (eq (aref file (1- (length file))) ?/)
 327         (setq file (substring file 0 -1)))
 328     (let ((fattr (file-attributes file)))
 329       (if fattr
 330           (insert (ls-lisp-format file fattr (nth 7 fattr)
 331                                   switches time-index (current-time)))
 332         (message "%s: doesn't exist or is inaccessible" file)
 333         (ding) (sit-for 2)))))          ; to show user the message!
 334
 335 (defun ls-lisp-column-format (file-alist)
 336   "Insert the file names (only) in FILE-ALIST into the current buffer.
 337 Format in columns, sorted vertically, following GNU ls -C.
 338 Responds to the window width as ls should but may not!"
 339   (let (files fmt ncols collen (nfiles 0) (colwid 0))
 340     ;; Count number of files as `nfiles', build list of filenames as
 341     ;; `files', and find maximum filename length as `colwid':
 342     (let (file len)
 343       (while file-alist
 344         (setq nfiles (1+ nfiles)
 345               file (caar file-alist)
 346               files (cons file files)
 347               file-alist (cdr file-alist)
 348               len (length file))
 349         (if (> len colwid) (setq colwid len))))
 350     (setq files (nreverse files)
 351           colwid (+ 2 colwid)           ; 2 character column gap
 352           fmt (format "%%-%ds" colwid)  ; print format
 353           ncols (/ (window-width) colwid) ; no of columns
 354           collen (/ nfiles ncols))      ; floor of column length
 355     (if (> nfiles (* collen ncols)) (setq collen (1+ collen)))
 356     ;; Output the file names in columns, sorted vertically:
 357     (let ((i 0) j)
 358       (while (< i collen)
 359         (setq j i)
 360         (while (< j nfiles)
 361           (insert (format fmt (nth j files)))
 362           (setq j (+ j collen)))
 363         ;; FJW: This is completely unnecessary, but I don't like
 364         ;; trailing white space...
 365         (delete-region (point) (progn (skip-chars-backward " \t") (point)))
 366         (insert ?\n)
 367         (setq i (1+ i))))))
 368
 369 (defun ls-lisp-delete-matching (regexp list)
 370   "Delete all elements matching REGEXP from LIST, return new list."
 371   ;; Should perhaps use setcdr for efficiency.
 372   (let (result)
 373     (while list
 374       (or (string-match regexp (caar list))
 375           (setq result (cons (car list) result)))
 376       (setq list (cdr list)))
 377     result))
 378
 379 (defsubst ls-lisp-string-lessp (s1 s2)
 380   "Return t if string S1 is less than string S2 in lexicographic order.
 381 Case is significant if `ls-lisp-ignore-case' is nil.
 382 Unibyte strings are converted to multibyte for comparison."
 383   (let ((u (compare-strings s1 0 nil s2 0 nil ls-lisp-ignore-case)))
 384     (and (numberp u) (< u 0))))
 385
 386 (defun ls-lisp-handle-switches (file-alist switches)
 387   "Return new FILE-ALIST sorted according to SWITCHES.
 388 SWITCHES is a list of characters.  Default sorting is alphabetic."
 389   ;; FILE-ALIST's elements are (FILE . FILE-ATTRIBUTES).
 390   (or (memq ?U switches)                ; unsorted
 391       ;; Catch and ignore unexpected sorting errors
 392       (condition-case err
 393           (setq file-alist
 394                 (let (index)
 395                   ;; Copy file-alist in case of error
 396                   (sort (copy-sequence file-alist) ; modifies its argument!
 397                         (cond ((memq ?S switches)
 398                                (lambda (x y) ; sorted on size
 399                                  ;; 7th file attribute is file size
 400                                  ;; Make largest file come first
 401                                  (< (nth 7 (cdr y))
 402                                     (nth 7 (cdr x)))))
 403                               ((setq index (ls-lisp-time-index switches))
 404                                (lambda (x y) ; sorted on time
 405                                  (ls-lisp-time-lessp (nth index (cdr y))
 406                                                      (nth index (cdr x)))))
 407                               ((memq ?X switches)
 408                                (lambda (x y) ; sorted on extension
 409                                  (ls-lisp-string-lessp
 410                                   (ls-lisp-extension (car x))
 411                                   (ls-lisp-extension (car y)))))
 412                               (t
 413                                (lambda (x y) ; sorted alphabetically
 414                                  (ls-lisp-string-lessp (car x) (car y))))))))
 415         (error (message "Unsorted (ls-lisp sorting error) - %s"
 416                         (error-message-string err))
 417                (ding) (sit-for 2))))    ; to show user the message!
 418   (if (memq ?F switches)                ; classify switch
 419       (setq file-alist (mapcar 'ls-lisp-classify file-alist)))
 420   (if ls-lisp-dirs-first
 421   ;; Re-sort directories first, without otherwise changing the
 422   ;; ordering, and reverse whole list.  cadr of each element of
 423   ;; `file-alist' is t for directory, string (name linked to) for
 424   ;; symbolic link, or nil.
 425       (let (el dirs files)
 426         (while file-alist
 427           (if (eq (cadr (setq el (car file-alist))) t) ; directory
 428               (setq dirs (cons el dirs))
 429             (setq files (cons el files)))
 430           (setq file-alist (cdr file-alist)))
 431         (setq file-alist
 432               (if (memq ?U switches)    ; unsorted order is reversed
 433                   (nconc dirs files)
 434                 (nconc files dirs)
 435                 ))))
 436   ;; Finally reverse file alist if necessary.
 437   ;; (eq below MUST compare `(not (memq ...))' to force comparison of
 438   ;; `t' or `nil', rather than list tails!)
 439   (if (eq (eq (not (memq ?U switches))  ; unsorted order is reversed
 440               (not (memq ?r switches))) ; reversed sort order requested
 441           ls-lisp-dirs-first)           ; already reversed
 442       (nreverse file-alist)
 443     file-alist))
 444
 445 (defun ls-lisp-classify (filedata)
 446   "Append a character to each file name indicating the file type.
 447 Also, for regular files that are executable, append `*'.
 448 The file type indicators are `/' for directories, `@' for symbolic
 449 links, `|' for FIFOs, `=' for sockets, and nothing for regular files.
 450 \[But FIFOs and sockets are not recognised.]
 451 FILEDATA has the form (filename . `file-attributes').  Its `cadr' is t
 452 for directory, string (name linked to) for symbolic link, or nil."
 453   (let ((dir (cadr filedata)) (file-name (car filedata)))
 454     (cond ((or dir
 455                ;; Parsing .lnk files here is perhaps overkill!
 456                (setq dir (ls-lisp-parse-symlink file-name)))
 457            (cons
 458             (concat file-name (if (eq dir t) "/" "@"))
 459             (cdr filedata)))
 460           ((string-match "x" (nth 9 filedata))
 461            (cons
 462             (concat file-name "*")
 463             (cdr filedata)))
 464           (t filedata))))
 465
 466 (defun ls-lisp-extension (filename)
 467   "Return extension of FILENAME (ignoring any version extension)
 468 FOLLOWED by null and full filename, SOLELY for full alpha sort."
 469   ;; Force extension sort order: `no ext' then `null ext' then `ext'
 470   ;; to agree with GNU ls.
 471   (concat
 472    (let* ((i (length filename)) end)
 473      (if (= (aref filename (1- i)) ?.) ; null extension
 474          "\0"
 475        (while (and (>= (setq i (1- i)) 0)
 476                    (/= (aref filename i) ?.)))
 477        (if (< i 0) "\0\0"               ; no extension
 478          (if (/= (aref filename (1+ i)) ?~)
 479              (substring filename (1+ i))
 480            ;; version extension found -- ignore it
 481            (setq end i)
 482            (while (and (>= (setq i (1- i)) 0)
 483                        (/= (aref filename i) ?.)))
 484            (if (< i 0) "\0\0"   ; no extension
 485              (substring filename (1+ i) end))))
 486        )) "\0" filename))
 487
 488 ;; From Roland McGrath.  Can use this to sort on time.
 489 (defun ls-lisp-time-lessp (time0 time1)
 490   "Return t if time TIME0 is earlier than time TIME1."
 491   (let ((hi0 (car time0)) (hi1 (car time1)))
 492     (or (< hi0 hi1)
 493         (and (= hi0 hi1)
 494              (< (cadr time0) (cadr time1))))))
 495
 496 (defun ls-lisp-format (file-name file-attr file-size switches time-index now)
 497   "Format one line of long ls output for file FILE-NAME.
 498 FILE-ATTR and FILE-SIZE give the file's attributes and size.
 499 SWITCHES, TIME-INDEX and NOW give the full switch list and time data."
 500   (let ((file-type (nth 0 file-attr))
 501         ;; t for directory, string (name linked to)
 502         ;; for symbolic link, or nil.
 503         (drwxrwxrwx (nth 8 file-attr))) ; attribute string ("drwxrwxrwx")
 504     (and (null file-type)
 505          ;; Maybe no kernel support for symlinks, so...
 506          (setq file-type (ls-lisp-parse-symlink file-name))
 507          (aset drwxrwxrwx 0 ?l)) ; symbolic link - update attribute string
 508     (concat (if (memq ?i switches)      ; inode number
 509                 (format " %6d" (nth 10 file-attr)))
 510             ;; nil is treated like "" in concat
 511             (if (memq ?s switches)      ; size in K
 512                 (format " %4.0f" (fceiling (/ file-size 1024.0))))
 513             drwxrwxrwx                  ; attribute string
 514             (if (memq 'links ls-lisp-verbosity)
 515                 (format " %3d" (nth 1 file-attr))) ; link count
 516             ;; Numeric uid/gid are more confusing than helpful;
 517             ;; Emacs should be able to make strings of them.
 518             ;; They tend to be bogus on non-UNIX platforms anyway so
 519             ;; optionally hide them.
 520             (if (memq 'uid ls-lisp-verbosity)
 521                 ;; (user-login-name uid) works on Windows NT but not
 522                 ;; on 9x and maybe not on some other platforms, so...
 523                 (let ((uid (nth 2 file-attr)))
 524                   (if (= uid (user-uid))
 525                       (format " %-8s" (user-login-name))
 526                     (format " %-8d" uid))))
 527             (if (not (memq ?G switches)) ; GNU ls -- shows group by default
 528                 (if (or (memq ?g switches) ; UNIX ls -- no group by default
 529                         (memq 'gid ls-lisp-verbosity))
 530                     (if (memq system-type '(macos windows-nt ms-dos))
 531                         ;; No useful concept of group...
 532                         " root"
 533                       (let* ((gid (nth 3 file-attr))
 534                              (group (user-login-name gid)))
 535                         (if group
 536                             (format " %-8s" group)
 537                           (format " %-8d" gid))))))
 538             (ls-lisp-format-file-size file-size (memq ?h switches))
 539             " "
 540             (ls-lisp-format-time file-attr time-index now)
 541             " "
 542             file-name
 543             (if (stringp file-type)     ; is a symbolic link
 544                 (concat " -> " file-type))
 545             "\n"
 546             )))
 547
 548 (defun ls-lisp-time-index (switches)
 549   "Return time index into file-attributes according to ls SWITCHES list.
 550 Return nil if no time switch found."
 551   ;; FJW: Default of nil is IMPORTANT and used in `ls-lisp-handle-switches'!
 552   (cond ((memq ?c switches) 6)          ; last mode change
 553         ((memq ?t switches) 5)          ; last modtime
 554         ((memq ?u switches) 4)))        ; last access
 555
 556 (defun ls-lisp-time-to-seconds (time)
 557   "Convert TIME to a floating point number."
 558   (+ (* (car time) 65536.0)
 559      (cadr time)
 560      (/ (or (nth 2 time) 0) 1000000.0)))
 561
 562 (defun ls-lisp-format-time (file-attr time-index now)
 563   "Format time for file with attributes FILE-ATTR according to TIME-INDEX.
 564 Use the same method as ls to decide whether to show time-of-day or year,
 565 depending on distance between file date and NOW.
 566 All ls time options, namely c, t and u, are handled."
 567   (let* ((time (nth (or time-index 5) file-attr)) ; default is last modtime
 568          (diff (- (ls-lisp-time-to-seconds time)
 569                   (ls-lisp-time-to-seconds now)))
 570          ;; Consider a time to be recent if it is within the past six
 571          ;; months.  A Gregorian year has 365.2425 * 24 * 60 * 60 ==
 572          ;; 31556952 seconds on the average, and half of that is 15778476.
 573          ;; Write the constant explicitly to avoid roundoff error.
 574          (past-cutoff -15778476)) ; half a Gregorian year
 575     (condition-case nil
 576         ;; Use traditional time format in the C or POSIX locale,
 577         ;; ISO-style time format otherwise, so columns line up.
 578         (let ((locale system-time-locale))
 579           (if (not locale)
 580               (let ((vars '("LC_ALL" "LC_TIME" "LANG")))
 581                 (while (and vars (not (setq locale (getenv (car vars)))))
 582                   (setq vars (cdr vars)))))
 583           (if (member locale '("C" "POSIX"))
 584               (setq locale nil))
 585           (format-time-string
 586            (if (and (<= past-cutoff diff) (<= diff 0))
 587                (if locale "%m-%d %H:%M" (nth 0 ls-lisp-format-time-list))
 588              (if locale "%Y-%m-%d " (nth 1 ls-lisp-format-time-list)))
 589            time))
 590       (error "Unk  0  0000"))))
 591
 592 (defun ls-lisp-format-file-size (file-size human-readable)
 593   (if (or (not human-readable)
 594           (< file-size 1024))
 595       (format (if (floatp file-size) " %8.0f" " %8d") file-size)
 596     (do ((file-size (/ file-size 1024.0) (/ file-size 1024.0))
 597          ;; kilo, mega, giga, tera, peta, exa
 598          (post-fixes (list "k" "M" "G" "T" "P" "E") (cdr post-fixes)))
 599         ((< file-size 1024) (format " %7.0f%s"  file-size (car post-fixes))))))
 600
 601 (provide 'ls-lisp)
 602
 603 ;;; ls-lisp.el ends here