lisp/cus-face.el

   1 ;;; cus-face.el --- customization support for faces
   2 ;;
   3 ;; Copyright (C) 1996, 1997, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5 ;;
   6 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   7 ;; Keywords: help, faces
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27 ;;
  28 ;; See `custom.el'.
  29
  30 ;;; Code:
  31
  32 (defalias 'custom-facep 'facep)
  33
  34 ;;; Declaring a face.
  35
  36 (defun custom-declare-face (face spec doc &rest args)
  37   "Like `defface', but FACE is evaluated as a normal argument."
  38   (unless (get face 'face-defface-spec)
  39     (when (fboundp 'facep)
  40       (unless (facep face)
  41         ;; If the user has already created the face, respect that.
  42         (let ((value (or (get face 'saved-face) spec))
  43               (have-window-system (memq initial-window-system '(x w32))))
  44           ;; Create global face.
  45           (make-empty-face face)
  46           ;; Create frame-local faces
  47           (dolist (frame (frame-list))
  48             (face-spec-set-2 face frame value)
  49             (when (memq (window-system frame) '(x w32 mac))
  50               (setq have-window-system t)))
  51           ;; When making a face after frames already exist
  52           (if have-window-system
  53               (make-face-x-resource-internal face)))))
  54     ;; Don't record SPEC until we see it causes no errors.
  55     (put face 'face-defface-spec spec)
  56     (push (cons 'defface face) current-load-list)
  57     (when (and doc (null (face-documentation face)))
  58       (set-face-documentation face (purecopy doc)))
  59     (custom-handle-all-keywords face args 'custom-face)
  60     (run-hooks 'custom-define-hook))
  61   face)
  62
  63 ;;; Face attributes.
  64
  65 (defconst custom-face-attributes
  66   '((:family
  67      (string :tag "Font Family"
  68              :help-echo "Font family or fontset alias name."))
  69
  70     (:width
  71      (choice :tag "Width"
  72              :help-echo "Font width."
  73              :value normal              ; default
  74              (const :tag "compressed" condensed)
  75              (const :tag "condensed" condensed)
  76              (const :tag "demiexpanded" semi-expanded)
  77              (const :tag "expanded" expanded)
  78              (const :tag "extracondensed" extra-condensed)
  79              (const :tag "extraexpanded" extra-expanded)
  80              (const :tag "medium" normal)
  81              (const :tag "narrow" condensed)
  82              (const :tag "normal" normal)
  83              (const :tag "regular" normal)
  84              (const :tag "semicondensed" semi-condensed)
  85              (const :tag "semiexpanded" semi-expanded)
  86              (const :tag "ultracondensed" ultra-condensed)
  87              (const :tag "ultraexpanded" ultra-expanded)
  88              (const :tag "wide" extra-expanded)))
  89
  90     (:height
  91      (choice :tag "Height"
  92              :help-echo "Face's font height."
  93              :value 1.0                 ; default
  94              (integer :tag "Height in 1/10 pt")
  95              (number :tag "Scale" 1.0)))
  96
  97     (:weight
  98      (choice :tag "Weight"
  99              :help-echo "Font weight."
 100              :value normal              ; default
 101              (const :tag "black" ultra-bold)
 102              (const :tag "bold" bold)
 103              (const :tag "book" semi-light)
 104              (const :tag "demibold" semi-bold)
 105              (const :tag "extralight" extra-light)
 106              (const :tag "extrabold" extra-bold)
 107              (const :tag "heavy" extra-bold)
 108              (const :tag "light" light)
 109              (const :tag "medium" normal)
 110              (const :tag "normal" normal)
 111              (const :tag "regular" normal)
 112              (const :tag "semibold" semi-bold)
 113              (const :tag "semilight" semi-light)
 114              (const :tag "ultralight" ultra-light)
 115              (const :tag "ultrabold" ultra-bold)))
 116
 117     (:slant
 118      (choice :tag "Slant"
 119              :help-echo "Font slant."
 120              :value normal              ; default
 121              (const :tag "italic" italic)
 122              (const :tag "oblique" oblique)
 123              (const :tag "normal" normal)
 124              (const :tag "roman" roman)))
 125
 126     (:underline
 127      (choice :tag "Underline"
 128              :help-echo "Control text underlining."
 129              (const :tag "Off" nil)
 130              (const :tag "On" t)
 131              (color :tag "Colored")))
 132
 133     (:overline
 134      (choice :tag "Overline"
 135              :help-echo "Control text overlining."
 136              (const :tag "Off" nil)
 137              (const :tag "On" t)
 138              (color :tag "Colored")))
 139
 140     (:strike-through
 141      (choice :tag "Strike-through"
 142              :help-echo "Control text strike-through."
 143              (const :tag "Off" nil)
 144              (const :tag "On" t)
 145              (color :tag "Colored")))
 146
 147     (:box
 148      ;; Fixme: this can probably be done better.
 149      (choice :tag "Box around text"
 150              :help-echo "Control box around text."
 151              (const :tag "Off" nil)
 152              (list :tag "Box"
 153                    :value (:line-width 2 :color "grey75" :style released-button)
 154                    (const :format "" :value :line-width)
 155                    (integer :tag "Width")
 156                    (const :format "" :value :color)
 157                    (choice :tag "Color" (const :tag "*" nil) color)
 158                    (const :format "" :value :style)
 159                    (choice :tag "Style"
 160                            (const :tag "Raised" released-button)
 161                            (const :tag "Sunken" pressed-button)
 162                            (const :tag "None" nil))))
 163      ;; filter to make value suitable for customize
 164      (lambda (real-value)
 165        (and real-value
 166             (let ((lwidth
 167                    (or (and (consp real-value)
 168                             (plist-get real-value :line-width))
 169                        (and (integerp real-value) real-value)
 170                        1))
 171                   (color
 172                    (or (and (consp real-value) (plist-get real-value :color))
 173                        (and (stringp real-value) real-value)
 174                        nil))
 175                   (style
 176                    (and (consp real-value) (plist-get real-value :style))))
 177               (list :line-width lwidth :color color :style style))))
 178      ;; filter to make customized-value suitable for storing
 179      (lambda (cus-value)
 180        (and cus-value
 181             (let ((lwidth (plist-get cus-value :line-width))
 182                   (color (plist-get cus-value :color))
 183                   (style (plist-get cus-value :style)))
 184               (cond ((and (null color) (null style))
 185                      lwidth)
 186                     ((and (null lwidth) (null style))
 187                      ;; actually can't happen, because LWIDTH is always an int
 188                      color)
 189                     (t
 190                      ;; Keep as a plist, but remove null entries
 191                      (nconc (and lwidth `(:line-width ,lwidth))
 192                             (and color  `(:color ,color))
 193                             (and style  `(:style ,style)))))))))
 194
 195     (:inverse-video
 196      (choice :tag "Inverse-video"
 197              :help-echo "Control whether text should be in inverse-video."
 198              (const :tag "Off" nil)
 199              (const :tag "On" t)))
 200
 201     (:foreground
 202      (color :tag "Foreground"
 203             :help-echo "Set foreground color (name or #RRGGBB hex spec)."))
 204
 205     (:background
 206      (color :tag "Background"
 207             :help-echo "Set background color (name or #RRGGBB hex spec)."))
 208
 209     (:stipple
 210      (choice :tag "Stipple"
 211              :help-echo "Background bit-mask"
 212              (const :tag "None" nil)
 213              (file :tag "File"
 214                    :help-echo "Name of bitmap file."
 215                    :must-match t)))
 216
 217     (:inherit
 218      (repeat :tag "Inherit"
 219              :help-echo "List of faces to inherit attributes from."
 220              (face :Tag "Face" default))
 221      ;; filter to make value suitable for customize
 222      (lambda (real-value)
 223        (cond ((or (null real-value) (eq real-value 'unspecified))
 224               nil)
 225              ((symbolp real-value)
 226               (list real-value))
 227              (t
 228               real-value)))
 229      ;; filter to make customized-value suitable for storing
 230      (lambda (cus-value)
 231        (if (and (consp cus-value) (null (cdr cus-value)))
 232            (car cus-value)
 233          cus-value))))
 234
 235   "Alist of face attributes.
 236
 237 The elements are of the form (KEY TYPE PRE-FILTER POST-FILTER),
 238 where KEY is the name of the attribute, TYPE is a widget type for
 239 editing the attribute, PRE-FILTER is a function to make the attribute's
 240 value suitable for the customization widget, and POST-FILTER is a
 241 function to make the customized value suitable for storing.  PRE-FILTER
 242 and POST-FILTER are optional.
 243
 244 The PRE-FILTER should take a single argument, the attribute value as
 245 stored, and should return a value for customization (using the
 246 customization type TYPE).
 247
 248 The POST-FILTER should also take a single argument, the value after
 249 being customized, and should return a value suitable for setting the
 250 given face attribute.")
 251
 252 (defun custom-face-attributes-get (face frame)
 253   "For FACE on FRAME, return an alternating list describing its attributes.
 254 The list has the form (KEYWORD VALUE KEYWORD VALUE...).
 255 Each keyword should be listed in `custom-face-attributes'.
 256
 257 If FRAME is nil, use the global defaults for FACE."
 258   (let ((attrs custom-face-attributes)
 259         plist)
 260     (while attrs
 261       (let* ((attribute (car (car attrs)))
 262              (value (face-attribute face attribute frame)))
 263         (setq attrs (cdr attrs))
 264         (unless (or (eq value 'unspecified)
 265                     (and (null value) (memq attribute '(:inherit))))
 266           (setq plist (cons attribute (cons value plist))))))
 267     plist))
 268
 269 ;;; Initializing.
 270
 271 (defun custom-set-faces (&rest args)
 272   "Initialize faces according to user preferences.
 273 This associates the settings with the `user' theme.
 274 The arguments should be a list where each entry has the form:
 275
 276   (FACE SPEC [NOW [COMMENT]])
 277
 278 SPEC is stored as the saved value for FACE, as well as the value for the
 279 `user' theme.  The `user' theme is one of the default themes known to Emacs.
 280 See `custom-known-themes' for more information on the known themes.
 281 See `custom-theme-set-faces' for more information on the interplay
 282 between themes and faces.
 283 See `defface' for the format of SPEC.
 284
 285 If NOW is present and non-nil, FACE is created now, according to SPEC.
 286 COMMENT is a string comment about FACE."
 287   (apply 'custom-theme-set-faces 'user args))
 288
 289 (defun custom-theme-set-faces (theme &rest args)
 290   "Initialize faces for theme THEME.
 291 The arguments should be a list where each entry has the form:
 292
 293   (FACE SPEC [NOW [COMMENT]])
 294
 295 SPEC is stored as the saved value for FACE, as well as the value for the
 296 `user' theme.  The `user' theme is one of the default themes known to Emacs.
 297 See `custom-known-themes' for more information on the known themes.
 298 See `custom-theme-set-faces' for more information on the interplay
 299 between themes and faces.
 300 See `defface' for the format of SPEC.
 301
 302 If NOW is present and non-nil, FACE is created now, according to SPEC.
 303 COMMENT is a string comment about FACE.
 304
 305 Several properties of THEME and FACE are used in the process:
 306
 307 If THEME property `theme-immediate' is non-nil, this is equivalent of
 308 providing the NOW argument to all faces in the argument list: FACE is
 309 created now.  The only difference is FACE property `force-face': if NOW
 310 is non-nil, FACE property `force-face' is set to the symbol `rogue', else
 311 if THEME property `theme-immediate' is non-nil, FACE property `force-face'
 312 is set to the symbol `immediate'.
 313
 314 SPEC itself is saved in FACE property `saved-face' and it is stored in
 315 FACE's list property `theme-face' \(using `custom-push-theme')."
 316   (custom-check-theme theme)
 317   (let ((immediate (get theme 'theme-immediate)))
 318     (while args
 319       (let ((entry (car args)))
 320         (if (listp entry)
 321             (let ((face (nth 0 entry))
 322                   (spec (nth 1 entry))
 323                   (now (nth 2 entry))
 324                   (comment (nth 3 entry))
 325                   oldspec)
 326               ;; If FACE is actually an alias, customize the face it
 327               ;; is aliased to.
 328               (if (get face 'face-alias)
 329                   (setq face (get face 'face-alias)))
 330
 331               (setq oldspec (get face 'theme-face))
 332               (when (not (and oldspec (eq 'user (caar oldspec))))
 333                 (put face 'saved-face spec)
 334                 (put face 'saved-face-comment comment))
 335
 336               (custom-push-theme 'theme-face face theme 'set spec)
 337               (when (or now immediate)
 338                 (put face 'force-face (if now 'rogue 'immediate)))
 339               (when (or now immediate (facep face))
 340                 (unless (facep face)
 341                   (make-empty-face face))
 342                 (put face 'face-comment comment)
 343                 (put face 'face-override-spec nil)
 344                 (face-spec-set face spec t))
 345               (setq args (cdr args)))
 346           ;; Old format, a plist of FACE SPEC pairs.
 347           (let ((face (nth 0 args))
 348                 (spec (nth 1 args)))
 349             (if (get face 'face-alias)
 350                 (setq face (get face 'face-alias)))
 351             (put face 'saved-face spec)
 352             (custom-push-theme 'theme-face face theme 'set spec))
 353           (setq args (cdr (cdr args))))))))
 354
 355 ;; XEmacs compability function.  In XEmacs, when you reset a Custom
 356 ;; Theme, you have to specify the theme to reset it to.  We just apply
 357 ;; the next theme.
 358 (defun custom-theme-reset-faces (theme &rest args)
 359   "Reset the specs in THEME of some faces to their specs in other themes.
 360 Each of the arguments ARGS has this form:
 361
 362     (FACE IGNORED)
 363
 364 This means reset FACE.  The argument IGNORED is ignored."
 365   (custom-check-theme theme)
 366   (dolist (arg args)
 367     (custom-push-theme 'theme-face (car arg) theme 'reset)))
 368
 369 (defun custom-reset-faces (&rest args)
 370   "Reset the specs of some faces to their specs in specified themes.
 371 This creates settings in the `user' theme.
 372
 373 Each of the arguments ARGS has this form:
 374
 375     (FACE FROM-THEME)
 376
 377 This means reset FACE to its value in FROM-THEME."
 378   (apply 'custom-theme-reset-faces 'user args))
 379
 380 ;;; The End.
 381
 382 (provide 'cus-face)
 383
 384 ;;; arch-tag: 9a5c4b63-0d27-4c92-a5af-f2c7ed764c2b
 385 ;;; cus-face.el ends here