lisp/type-break.el

   1 ;;; type-break.el --- encourage rests from typing at appropriate intervals
   2
   3 ;; Copyright (C) 1994, 95, 97, 2000, 2004 Free Software Foundation, Inc.
   4
   5 ;; Author: Noah Friedman
   6 ;; Maintainer: Noah Friedman <friedman@splode.com>
   7 ;; Keywords: extensions, timers
   8 ;; Status: Works in GNU Emacs 19.25 or later, some versions of XEmacs
   9 ;; Created: 1994-07-13
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; The docstring for the function `type-break-mode' summarizes most of the
  31 ;; details of the interface.
  32
  33 ;; This package relies on the assumption that you live entirely in Emacs,
  34 ;; as the author does.  If that's not the case for you (e.g. you often
  35 ;; suspend Emacs or work in other windows) then this won't help very much;
  36 ;; it will depend on just how often you switch back to Emacs.  At the very
  37 ;; least, you will want to turn off the keystroke thresholds and rest
  38 ;; interval tracking.
  39
  40 ;; If you prefer not to be queried about taking breaks, but instead just
  41 ;; want to be reminded, do the following:
  42 ;;
  43 ;;   (setq type-break-query-mode nil)
  44 ;;
  45 ;; Or call the command `type-break-query-mode' with a negative prefix
  46 ;; argument.
  47
  48 ;; If you find echo area messages annoying and would prefer to see messages
  49 ;; in the mode line instead, do M-x type-break-mode-line-message-mode
  50 ;; or set the variable of the same name to `t'.
  51
  52 ;; This program can truly cons up a storm because of all the calls to
  53 ;; `current-time' (which always returns 3 fresh conses).  I'm dismayed by
  54 ;; this, but I think the health of my hands is far more important than a
  55 ;; few pages of virtual memory.
  56
  57 ;; This program has no hope of working in Emacs 18.
  58
  59 ;; This package was inspired by Roland McGrath's hanoi-break.el.
  60 ;; Several people contributed feedback and ideas, including
  61 ;;      Roland McGrath <roland@gnu.org>
  62 ;;      Kleanthes Koniaris <kgk@koniaris.com>
  63 ;;      Mark Ashton <mpashton@gnu.org>
  64 ;;      Matt Wilding <wilding@cli.com>
  65 ;;      Robert S. Boyer <boyer@cs.utexas.edu>
  66
  67 ;;; Code:
  68
  69 \f
  70 (defgroup type-break nil
  71   "Encourage the user to take a rest from typing at suitable intervals."
  72   :prefix "type-break"
  73   :group 'keyboard)
  74
  75 ;;;###autoload
  76 (defcustom type-break-mode nil
  77   "Toggle typing break mode.
  78 See the docstring for the `type-break-mode' command for more information.
  79 Setting this variable directly does not take effect;
  80 use either \\[customize] or the function `type-break-mode'."
  81   :set (lambda (symbol value)
  82          (type-break-mode (if value 1 -1)))
  83   :initialize 'custom-initialize-default
  84   :type 'boolean
  85   :group 'type-break
  86   :require 'type-break)
  87
  88 ;;;###autoload
  89 (defcustom type-break-interval (* 60 60)
  90   "*Number of seconds between scheduled typing breaks."
  91   :type 'integer
  92   :group 'type-break)
  93
  94 ;;;###autoload
  95 (defcustom type-break-good-rest-interval (/ type-break-interval 6)
  96   "*Number of seconds of idle time considered to be an adequate typing rest.
  97
  98 When this variable is non-nil, Emacs checks the idle time between
  99 keystrokes.  If this idle time is long enough to be considered a \"good\"
 100 rest from typing, then the next typing break is simply rescheduled for later.
 101
 102 If a break is interrupted before this much time elapses, the user will be
 103 asked whether or not really to interrupt the break."
 104   :type 'integer
 105   :group 'type-break)
 106
 107 ;;;###autoload
 108 (defcustom type-break-good-break-interval nil
 109   "*Number of seconds considered to be an adequate explicit typing rest.
 110
 111 When this variable is non-nil, its value is considered to be a \"good\"
 112 length (in seconds) for a break initiated by the command `type-break',
 113 overriding `type-break-good-rest-interval'.  This provides querying of
 114 break interruptions when `type-break-good-rest-interval' is nil."
 115   :type 'integer
 116   :group 'type-break)
 117
 118 ;;;###autoload
 119 (defcustom type-break-keystroke-threshold
 120   ;; Assuming typing speed is 35wpm (on the average, do you really
 121   ;; type more than that in a minute?  I spend a lot of time reading mail
 122   ;; and simply studying code in buffers) and average word length is
 123   ;; about 5 letters, default upper threshold to the average number of
 124   ;; keystrokes one is likely to type in a break interval.  That way if the
 125   ;; user goes through a furious burst of typing activity, cause a typing
 126   ;; break to be required sooner than originally scheduled.
 127   ;; Conversely, the minimum threshold should be about a fifth of this.
 128   (let* ((wpm 35)
 129          (avg-word-length 5)
 130          (upper (* wpm avg-word-length (/ type-break-interval 60)))
 131          (lower (/ upper 5)))
 132     (cons lower upper))
 133   "*Upper and lower bound on number of keystrokes for considering typing break.
 134 This structure is a pair of numbers (MIN . MAX).
 135
 136 The first number is the minimum number of keystrokes that must have been
 137 entered since the last typing break before considering another one, even if
 138 the scheduled time has elapsed; the break is simply rescheduled until later
 139 if the minimum threshold hasn't been reached.  If this first value is nil,
 140 then there is no minimum threshold; as soon as the scheduled time has
 141 elapsed, the user will always be queried.
 142
 143 The second number is the maximum number of keystrokes that can be entered
 144 before a typing break is requested immediately, pre-empting the originally
 145 scheduled break.  If this second value is nil, then no pre-emptive breaks
 146 will occur; only scheduled ones will.
 147
 148 Keys with bucky bits (shift, control, meta, etc) are counted as only one
 149 keystroke even though they really require multiple keys to generate them.
 150
 151 The command `type-break-guesstimate-keystroke-threshold' can be used to
 152 guess a reasonably good pair of values for this variable."
 153   :type 'sexp
 154   :group 'type-break)
 155
 156 (defcustom type-break-query-mode t
 157   "*Non-nil means ask whether or not to prompt user for breaks.
 158 If so, call the function specified in the value of the variable
 159 `type-break-query-function' to do the asking."
 160   :type 'boolean
 161   :group 'type-break)
 162
 163 (defcustom type-break-query-function 'yes-or-no-p
 164   "*Function to use for making query for a typing break.
 165 It should take a string as an argument, the prompt.
 166 Usually this should be set to `yes-or-no-p' or `y-or-n-p'.
 167
 168 To avoid being queried at all, set `type-break-query-mode' to nil."
 169   :type '(radio function
 170                 (function-item yes-or-no-p)
 171                 (function-item y-or-n-p))
 172   :group 'type-break)
 173
 174 (defcustom type-break-query-interval 60
 175   "*Number of seconds between queries to take a break, if put off.
 176 The user will continue to be prompted at this interval until he or she
 177 finally submits to taking a typing break."
 178   :type 'integer
 179   :group 'type-break)
 180
 181 (defcustom type-break-time-warning-intervals '(300 120 60 30)
 182   "*List of time intervals for warnings about upcoming typing break.
 183 At each of the intervals (specified in seconds) away from a scheduled
 184 typing break, print a warning in the echo area."
 185   :type '(repeat integer)
 186   :group 'type-break)
 187
 188 (defcustom type-break-keystroke-warning-intervals '(300 200 100 50)
 189   "*List of keystroke measurements for warnings about upcoming typing break.
 190 At each of the intervals (specified in keystrokes) away from the upper
 191 keystroke threshold, print a warning in the echo area.
 192 If either this variable or the upper threshold is set, then no warnings
 193 will occur."
 194   :type '(repeat integer)
 195   :group 'type-break)
 196
 197 (defcustom type-break-warning-repeat 40
 198   "*Number of keystrokes for which warnings should be repeated.
 199 That is, for each of this many keystrokes the warning is redisplayed
 200 in the echo area to make sure it's really seen."
 201   :type 'integer
 202   :group 'type-break)
 203
 204 (defcustom type-break-time-stamp-format "[%H:%M] "
 205   "*Timestamp format used to prefix messages.
 206 Format specifiers are as used by `format-time-string'."
 207   :type 'string
 208   :group 'type-break)
 209
 210 (defcustom type-break-demo-functions
 211   '(type-break-demo-boring type-break-demo-life type-break-demo-hanoi)
 212   "*List of functions to consider running as demos during typing breaks.
 213 When a typing break begins, one of these functions is selected randomly
 214 to have Emacs do something interesting.
 215
 216 Any function in this list should start a demo which ceases as soon as a
 217 key is pressed."
 218   :type '(repeat function)
 219   :group 'type-break)
 220
 221 (defcustom type-break-demo-boring-stats nil
 222   "*Show word per minute and keystroke figures in the Boring demo."
 223   :type 'boolean
 224   :group 'type-break)
 225
 226 (defcustom type-break-terse-messages nil
 227   "*Use slightly terser messages."
 228   :type 'boolean
 229   :group 'type-break)
 230
 231 (defcustom type-break-file-name (convert-standard-filename "~/.type-break")
 232   "*Name of file used to save state across sessions."
 233   :type 'file
 234   :group 'type-break)
 235
 236 (defvar type-break-post-command-hook '(type-break-check)
 237   "Hook run indirectly by `post-command-hook' for typing break functions.
 238 This is not really intended to be set by the user, but it's probably
 239 harmless to do so.  Mainly it is used by various parts of the typing break
 240 program to delay actions until after the user has completed some command.
 241 It exists because `post-command-hook' itself is inaccessible while its
 242 functions are being run, and some type-break--related functions want to
 243 remove themselves after running.")
 244
 245 \f
 246 ;; Mode line frobs
 247
 248 (defcustom type-break-mode-line-message-mode nil
 249   "*Non-nil means put type-break related messages in the mode line.
 250 Otherwise, messages typically go in the echo area.
 251
 252 See also `type-break-mode-line-format' and its members."
 253   :type 'boolean
 254   :group 'type-break)
 255
 256 (defvar type-break-mode-line-format
 257   '(type-break-mode-line-message-mode
 258     (""
 259      type-break-mode-line-break-message
 260      type-break-mode-line-warning))
 261   "*Format of messages in the mode line concerning typing breaks.")
 262
 263 (defvar type-break-mode-line-break-message
 264   '(type-break-mode-line-break-message-p
 265     type-break-mode-line-break-string))
 266
 267 (defvar type-break-mode-line-break-message-p nil)
 268 (defvar type-break-mode-line-break-string " *** TAKE A TYPING BREAK NOW ***")
 269
 270 (defvar type-break-mode-line-warning
 271       '(type-break-mode-line-break-message-p
 272         ("")
 273         (type-break-warning-countdown-string
 274          (" *** "
 275           "Break in "
 276           type-break-warning-countdown-string
 277           " "
 278           type-break-warning-countdown-string-type
 279           "***"))))
 280
 281 (defvar type-break-warning-countdown-string nil
 282   "If non-nil, this is a countdown for the next typing break.
 283
 284 This variable, in conjunction with `type-break-warning-countdown-string-type'
 285 \(which indicates whether this value is a number of keystrokes or seconds)
 286 is installed in `mode-line-format' to notify of imminent typing breaks.")
 287
 288 (defvar type-break-warning-countdown-string-type nil
 289   "Indicates the unit type of `type-break-warning-countdown-string'.
 290 It will be either \"seconds\" or \"keystrokes\".")
 291
 292 \f
 293 ;; These are internal variables.  Do not set them yourself.
 294
 295 (defvar type-break-alarm-p nil)
 296 (defvar type-break-keystroke-count 0)
 297 (defvar type-break-time-last-break nil)
 298 (defvar type-break-time-next-break nil)
 299 (defvar type-break-time-last-command (current-time))
 300 (defvar type-break-current-time-warning-interval nil)
 301 (defvar type-break-current-keystroke-warning-interval nil)
 302 (defvar type-break-time-warning-count 0)
 303 (defvar type-break-keystroke-warning-count 0)
 304 (defvar type-break-interval-start nil)
 305
 306 \f
 307 ;;;###autoload
 308 (defun type-break-mode (&optional prefix)
 309   "Enable or disable typing-break mode.
 310 This is a minor mode, but it is global to all buffers by default.
 311
 312 When this mode is enabled, the user is encouraged to take typing breaks at
 313 appropriate intervals; either after a specified amount of time or when the
 314 user has exceeded a keystroke threshold.  When the time arrives, the user
 315 is asked to take a break.  If the user refuses at that time, Emacs will ask
 316 again in a short period of time.  The idea is to give the user enough time
 317 to find a good breaking point in his or her work, but be sufficiently
 318 annoying to discourage putting typing breaks off indefinitely.
 319
 320 A negative prefix argument disables this mode.
 321 No argument or any non-negative argument enables it.
 322
 323 The user may enable or disable this mode by setting the variable of the
 324 same name, though setting it in that way doesn't reschedule a break or
 325 reset the keystroke counter.
 326
 327 If the mode was previously disabled and is enabled as a consequence of
 328 calling this function, it schedules a break with `type-break-schedule' to
 329 make sure one occurs (the user can call that command to reschedule the
 330 break at any time).  It also initializes the keystroke counter.
 331
 332 The variable `type-break-interval' specifies the number of seconds to
 333 schedule between regular typing breaks.  This variable doesn't directly
 334 affect the time schedule; it simply provides a default for the
 335 `type-break-schedule' command.
 336
 337 If set, the variable `type-break-good-rest-interval' specifies the minimum
 338 amount of time which is considered a reasonable typing break.  Whenever
 339 that time has elapsed, typing breaks are automatically rescheduled for
 340 later even if Emacs didn't prompt you to take one first.  Also, if a break
 341 is ended before this much time has elapsed, the user will be asked whether
 342 or not to continue.  A nil value for this variable prevents automatic
 343 break rescheduling, making `type-break-interval' an upper bound on the time
 344 between breaks.  In this case breaks will be prompted for as usual before
 345 the upper bound if the keystroke threshold is reached.
 346
 347 If `type-break-good-rest-interval' is nil and
 348 `type-break-good-break-interval' is set, then confirmation is required to
 349 interrupt a break before `type-break-good-break-interval' seconds
 350 have passed.  This provides for an upper bound on the time between breaks
 351 together with confirmation of interruptions to these breaks.
 352
 353 The variable `type-break-keystroke-threshold' is used to determine the
 354 thresholds at which typing breaks should be considered.  You can use
 355 the command `type-break-guesstimate-keystroke-threshold' to try to
 356 approximate good values for this.
 357
 358 There are several variables that affect how or when warning messages about
 359 imminent typing breaks are displayed.  They include:
 360
 361         `type-break-mode-line-message-mode'
 362         `type-break-time-warning-intervals'
 363         `type-break-keystroke-warning-intervals'
 364         `type-break-warning-repeat'
 365         `type-break-warning-countdown-string'
 366         `type-break-warning-countdown-string-type'
 367
 368 There are several variables that affect if, how, and when queries to begin
 369 a typing break occur.  They include:
 370
 371         `type-break-query-mode'
 372         `type-break-query-function'
 373         `type-break-query-interval'
 374
 375 The command `type-break-statistics' prints interesting things.
 376
 377 Finally, a file (named `type-break-file-name') is used to store information
 378 across Emacs sessions.  This provides recovery of the break status between
 379 sessions and after a crash.  Manual changes to the file may result in
 380 problems."
 381   (interactive "P")
 382   (type-break-check-post-command-hook)
 383
 384   (let ((already-enabled type-break-mode))
 385     (setq type-break-mode (>= (prefix-numeric-value prefix) 0))
 386
 387     (cond
 388      ((and already-enabled type-break-mode)
 389       (and (interactive-p)
 390            (message "Type Break mode is already enabled")))
 391      (type-break-mode
 392       (or global-mode-string
 393           (setq global-mode-string '("")))
 394       (or (assq 'type-break-mode-line-message-mode
 395                 minor-mode-alist)
 396           (setq minor-mode-alist
 397                 (cons type-break-mode-line-format
 398                       minor-mode-alist)))
 399       (type-break-keystroke-reset)
 400       (type-break-mode-line-countdown-or-break nil)
 401
 402       (if (boundp 'save-some-buffers-always)
 403           (add-to-list 'save-some-buffers-always
 404                        (expand-file-name type-break-file-name)))
 405
 406       (setq type-break-time-last-break (type-break-get-previous-time))
 407
 408       ;; schedule according to break time from session file
 409       (type-break-schedule
 410        (let (diff)
 411          (if (and type-break-time-last-break
 412                   (< (setq diff (type-break-time-difference
 413                                  type-break-time-last-break
 414                                  (current-time)))
 415                      type-break-interval))
 416              ;; use the file's value
 417              (progn
 418                (setq type-break-keystroke-count
 419                      (type-break-get-previous-count))
 420                ;; file the time, in case it was read from the auto-save file
 421                (type-break-file-time type-break-interval-start)
 422                (setq type-break-interval-start type-break-time-last-break)
 423                (- type-break-interval diff))
 424            ;; schedule from now
 425            (setq type-break-interval-start (current-time))
 426            (type-break-file-time type-break-interval-start)
 427            type-break-interval))
 428        type-break-interval-start
 429        type-break-interval)
 430
 431       (and (interactive-p)
 432            (message "Type Break mode is enabled and set")))
 433      (t
 434       (type-break-keystroke-reset)
 435       (type-break-mode-line-countdown-or-break nil)
 436       (type-break-cancel-schedule)
 437       (do-auto-save)
 438       (with-current-buffer (find-file-noselect type-break-file-name
 439                                                'nowarn)
 440         (set-buffer-modified-p nil)
 441         (unlock-buffer)
 442         (kill-this-buffer))
 443       (if (boundp 'save-some-buffers-always)
 444           (setq save-some-buffers-always
 445                 (remove (expand-file-name type-break-file-name)
 446                         save-some-buffers-always)))
 447       (and (interactive-p)
 448            (message "Type Break mode is disabled")))))
 449   type-break-mode)
 450
 451 (defun type-break-mode-line-message-mode (&optional prefix)
 452   "Enable or disable warnings in the mode line about typing breaks.
 453
 454 A negative PREFIX argument disables this mode.
 455 No argument or any non-negative argument enables it.
 456
 457 The user may also enable or disable this mode simply by setting the
 458 variable of the same name.
 459
 460 Variables controlling the display of messages in the mode line include:
 461
 462         `mode-line-format'
 463         `global-mode-string'
 464         `type-break-mode-line-break-message'
 465         `type-break-mode-line-warning'"
 466   (interactive "P")
 467   (setq type-break-mode-line-message-mode
 468         (>= (prefix-numeric-value prefix) 0))
 469   (and (interactive-p)
 470        (if type-break-mode-line-message-mode
 471            (message "type-break-mode-line-message-mode is enabled")
 472          (message "type-break-mode-line-message-mode is disabled")))
 473   type-break-mode-line-message-mode)
 474
 475 (defun type-break-query-mode (&optional prefix)
 476   "Enable or disable warnings in the mode line about typing breaks.
 477
 478 When enabled, the user is periodically queried about whether to take a
 479 typing break at that moment.  The function which does this query is
 480 specified by the variable `type-break-query-function'.
 481
 482 A negative PREFIX argument disables this mode.
 483 No argument or any non-negative argument enables it.
 484
 485 The user may also enable or disable this mode simply by setting the
 486 variable of the same name."
 487   (interactive "P")
 488   (setq type-break-query-mode
 489         (>= (prefix-numeric-value prefix) 0))
 490   (and (interactive-p)
 491        (if type-break-query-mode
 492            (message "type-break-query-mode is enabled")
 493          (message "type-break-query-mode is disabled")))
 494   type-break-query-mode)
 495
 496 \f
 497 ;;; session file functions
 498
 499 (defvar type-break-auto-save-file-name
 500   (let ((buffer-file-name type-break-file-name))
 501     (make-auto-save-file-name))
 502   "Auto-save name of `type-break-file-name'.")
 503
 504 (defun type-break-file-time (&optional time)
 505   "File break time in `type-break-file-name', unless the file is locked."
 506   (if (not (stringp (file-locked-p type-break-file-name)))
 507       (with-current-buffer (find-file-noselect type-break-file-name
 508                                                'nowarn)
 509         (let ((inhibit-read-only t))
 510           (erase-buffer)
 511           (insert (format "%s\n\n" (or time type-break-interval-start)))
 512           ;; file saving is left to auto-save
 513           ))))
 514
 515 (defun type-break-file-keystroke-count ()
 516   "File keystroke count in `type-break-file-name', unless the file is locked."
 517   (if (not (stringp (file-locked-p type-break-file-name)))
 518       (with-current-buffer (find-file-noselect type-break-file-name
 519                                                'nowarn)
 520         (save-excursion
 521           (let ((inhibit-read-only t))
 522             (goto-char (point-min))
 523             (forward-line)
 524             (delete-region (point) (save-excursion (end-of-line) (point)))
 525             (insert (format "%s" type-break-keystroke-count))
 526             ;; file saving is left to auto-save
 527             )))))
 528
 529 (defun timep (time)
 530   "If TIME is in the format returned by `current-time' then
 531 return TIME, else return nil."
 532   (and (listp time)
 533        (eq (length time) 3)
 534        (integerp (car time))
 535        (integerp (nth 1 time))
 536        (integerp (nth 2 time))
 537        time))
 538
 539 (defun type-break-choose-file ()
 540   "Return file to read from."
 541   (cond
 542    ((and (file-exists-p type-break-auto-save-file-name)
 543          (file-readable-p type-break-auto-save-file-name))
 544     type-break-auto-save-file-name)
 545    ((and (file-exists-p type-break-file-name)
 546          (file-readable-p type-break-file-name))
 547     type-break-file-name)
 548    (t nil)))
 549
 550 (defun type-break-get-previous-time ()
 551   "Get previous break time from `type-break-file-name'.
 552 Returns nil if the file is missing or if the time breaks with the
 553 `current-time' format."
 554   (let ((file (type-break-choose-file)))
 555     (if file
 556         (timep ;; returns expected format, else nil
 557          (with-current-buffer (find-file-noselect file 'nowarn)
 558            (save-excursion
 559              (goto-char (point-min))
 560              (read (current-buffer))))))))
 561
 562 (defun type-break-get-previous-count ()
 563   "Get previous keystroke count from `type-break-file-name'.
 564 Return 0 if the file is missing or if the form read is not an
 565 integer."
 566   (let ((file (type-break-choose-file)))
 567     (if (and file
 568              (integerp
 569               (setq file
 570                     (with-current-buffer
 571                         (find-file-noselect file 'nowarn)
 572                       (save-excursion
 573                         (goto-char (point-min))
 574                         (forward-line 1)
 575                         (read (current-buffer)))))))
 576         file
 577       0)))
 578
 579 \f
 580 ;;;###autoload
 581 (defun type-break ()
 582   "Take a typing break.
 583
 584 During the break, a demo selected from the functions listed in
 585 `type-break-demo-functions' is run.
 586
 587 After the typing break is finished, the next break is scheduled
 588 as per the function `type-break-schedule'."
 589   (interactive)
 590   (do-auto-save)
 591   (type-break-cancel-schedule)
 592   ;; remove any query scheduled during interactive invocation
 593   (remove-hook 'type-break-post-command-hook 'type-break-do-query)
 594   (let ((continue t)
 595         (start-time (current-time)))
 596     (setq type-break-time-last-break start-time)
 597     (while continue
 598       (save-window-excursion
 599         ;; Eat the screen.
 600         (and (eq (selected-window) (minibuffer-window))
 601              (other-window 1))
 602         (delete-other-windows)
 603         (scroll-right (window-width))
 604         (unless type-break-terse-messages
 605           (message "Press any key to resume from typing break."))
 606
 607         (random t)
 608         (let* ((len (length type-break-demo-functions))
 609                (idx (random len))
 610                (fn (nth idx type-break-demo-functions)))
 611           (condition-case ()
 612               (funcall fn)
 613             (error nil))))
 614
 615       (let ((good-interval (or type-break-good-rest-interval
 616                                type-break-good-break-interval)))
 617         (cond
 618          (good-interval
 619           (let ((break-secs (type-break-time-difference
 620                              start-time (current-time))))
 621             (cond
 622              ((>= break-secs good-interval)
 623               (setq continue nil))
 624              ;; 60 seconds may be too much leeway if the break is only 3
 625              ;; minutes to begin with.  You can just say "no" to the query
 626              ;; below if you're in that much of a hurry.
 627              ;;((> 60 (abs (- break-secs good-interval)))
 628              ;; (setq continue nil))
 629              ((funcall
 630                type-break-query-function
 631                (format
 632                 (if type-break-terse-messages
 633                     "%s%s remaining.  Continue break? "
 634                   "%sYou really ought to rest %s more.  Continue break? ")
 635                 (type-break-time-stamp)
 636                 (type-break-format-time (- good-interval
 637                                            break-secs)))))
 638              (t
 639               (setq continue nil)))))
 640          (t (setq continue nil))))))
 641
 642   (type-break-keystroke-reset)
 643   (type-break-file-time)
 644   (type-break-mode-line-countdown-or-break nil)
 645   (type-break-schedule))
 646
 647 \f
 648 (defun type-break-schedule (&optional time start interval)
 649   "Schedule a typing break for TIME seconds from now.
 650 If time is not specified it defaults to `type-break-interval'.
 651 START and INTERVAL are used when recovering a break.
 652 START is the start of the break (defaults to now).
 653 INTERVAL is the full length of an interval (defaults to TIME)."
 654   (interactive (list (and current-prefix-arg
 655                           (prefix-numeric-value current-prefix-arg))))
 656   (or time (setq time type-break-interval))
 657   (type-break-check-post-command-hook)
 658   (type-break-cancel-schedule)
 659   (type-break-time-warning-schedule time 'reset)
 660   (type-break-run-at-time (max 1 time) nil 'type-break-alarm)
 661   (setq type-break-time-next-break
 662         (type-break-time-sum (or start (current-time))
 663                              (or interval time))))
 664
 665 (defun type-break-cancel-schedule ()
 666   (type-break-cancel-time-warning-schedule)
 667   (type-break-cancel-function-timers 'type-break-alarm)
 668   (setq type-break-alarm-p nil)
 669   (setq type-break-time-next-break nil))
 670
 671 (defun type-break-time-warning-schedule (&optional time resetp)
 672   (let ((type-break-current-time-warning-interval nil))
 673     (type-break-cancel-time-warning-schedule))
 674   (add-hook 'type-break-post-command-hook 'type-break-time-warning 'append)
 675   (cond
 676    (type-break-time-warning-intervals
 677     (and resetp
 678          (setq type-break-current-time-warning-interval
 679                type-break-time-warning-intervals))
 680
 681     (or time
 682         (setq time (type-break-time-difference (current-time)
 683                                                type-break-time-next-break)))
 684
 685     (while (and type-break-current-time-warning-interval
 686                 (> (car type-break-current-time-warning-interval) time))
 687       (setq type-break-current-time-warning-interval
 688             (cdr type-break-current-time-warning-interval)))
 689
 690     (cond
 691      (type-break-current-time-warning-interval
 692       (setq time (- time (car type-break-current-time-warning-interval)))
 693       (setq type-break-current-time-warning-interval
 694             (cdr type-break-current-time-warning-interval))
 695
 696       ;(let (type-break-current-time-warning-interval)
 697       ;  (type-break-cancel-time-warning-schedule))
 698       (type-break-run-at-time (max 1 time) nil 'type-break-time-warning-alarm)
 699
 700       (cond
 701        (resetp
 702         (setq type-break-warning-countdown-string nil))
 703        (t
 704         (setq type-break-warning-countdown-string (number-to-string time))
 705         (setq type-break-warning-countdown-string-type "seconds"))))))))
 706
 707 (defun type-break-cancel-time-warning-schedule ()
 708   (type-break-cancel-function-timers 'type-break-time-warning-alarm)
 709   (remove-hook 'type-break-post-command-hook 'type-break-time-warning)
 710   (setq type-break-current-time-warning-interval
 711         type-break-time-warning-intervals)
 712   (setq type-break-time-warning-count 0) ; avoid warnings after break
 713   (setq type-break-warning-countdown-string nil))
 714
 715 (defun type-break-alarm ()
 716   (type-break-check-post-command-hook)
 717   (setq type-break-alarm-p t)
 718   (type-break-mode-line-countdown-or-break 'break))
 719
 720 (defun type-break-time-warning-alarm ()
 721   (type-break-check-post-command-hook)
 722   (type-break-time-warning-schedule)
 723   (setq type-break-time-warning-count type-break-warning-repeat)
 724   (type-break-time-warning)
 725   (type-break-mode-line-countdown-or-break 'countdown))
 726
 727 \f
 728 (defun type-break-run-tb-post-command-hook ()
 729   (and type-break-mode
 730        (run-hooks 'type-break-post-command-hook)))
 731
 732 (defun type-break-check ()
 733   "Ask to take a typing break if appropriate.
 734 This may be the case either because the scheduled time has come \(and the
 735 minimum keystroke threshold has been reached\) or because the maximum
 736 keystroke threshold has been exceeded."
 737   (type-break-file-keystroke-count)
 738   (let* ((min-threshold (car type-break-keystroke-threshold))
 739          (max-threshold (cdr type-break-keystroke-threshold)))
 740     (and type-break-good-rest-interval
 741          (progn
 742            (and (> (type-break-time-difference
 743                     type-break-time-last-command (current-time))
 744                    type-break-good-rest-interval)
 745                 (progn
 746                   (type-break-keystroke-reset)
 747                   (type-break-mode-line-countdown-or-break nil)
 748                   (setq type-break-time-last-break (current-time))
 749                   (type-break-schedule)))
 750            (setq type-break-time-last-command (current-time))))
 751
 752     (and type-break-keystroke-threshold
 753          (let ((keys (this-command-keys)))
 754            (cond
 755             ;; Ignore mouse motion
 756             ((and (vectorp keys)
 757                   (consp (aref keys 0))
 758                   (memq (car (aref keys 0)) '(mouse-movement))))
 759             (t
 760              (setq type-break-keystroke-count
 761                    (+ type-break-keystroke-count (length keys)))))))
 762
 763     (cond
 764      (type-break-alarm-p
 765       (cond
 766        ((input-pending-p))
 767        ((eq (selected-window) (minibuffer-window)))
 768        ((and min-threshold
 769              (< type-break-keystroke-count min-threshold))
 770         (type-break-schedule))
 771        (t
 772         ;; If keystroke count is within min-threshold of
 773         ;; max-threshold, lower it to reduce the likelihood of an
 774         ;; immediate subsequent query.
 775         (and max-threshold
 776              min-threshold
 777              (< (- max-threshold type-break-keystroke-count) min-threshold)
 778              (progn
 779                (type-break-keystroke-reset)
 780                (setq type-break-keystroke-count min-threshold)))
 781         (type-break-query))))
 782      ((and type-break-keystroke-warning-intervals
 783            max-threshold
 784            (= type-break-keystroke-warning-count 0)
 785            (type-break-check-keystroke-warning)))
 786      ((and max-threshold
 787            (> type-break-keystroke-count max-threshold)
 788            (not (input-pending-p))
 789            (not (eq (selected-window) (minibuffer-window))))
 790       (type-break-keystroke-reset)
 791       (setq type-break-keystroke-count (or min-threshold 0))
 792       (type-break-query)))))
 793
 794 ;; This should return t if warnings were enabled, nil otherwise.
 795 (defun type-break-check-keystroke-warning ()
 796   ;; This is safe because the caller should have checked that the cdr was
 797   ;; non-nil already.
 798   (let ((left (- (cdr type-break-keystroke-threshold)
 799                  type-break-keystroke-count)))
 800     (cond
 801      ((null (car type-break-current-keystroke-warning-interval))
 802       nil)
 803      ((> left (car type-break-current-keystroke-warning-interval))
 804       nil)
 805      (t
 806       (while (and (car type-break-current-keystroke-warning-interval)
 807                   (< left (car type-break-current-keystroke-warning-interval)))
 808         (setq type-break-current-keystroke-warning-interval
 809               (cdr type-break-current-keystroke-warning-interval)))
 810       (setq type-break-keystroke-warning-count type-break-warning-repeat)
 811       (add-hook 'type-break-post-command-hook 'type-break-keystroke-warning)
 812       (setq type-break-warning-countdown-string (number-to-string left))
 813       (setq type-break-warning-countdown-string-type "keystrokes")
 814       (type-break-mode-line-countdown-or-break 'countdown)
 815       t))))
 816
 817 ;; Arrange for a break query to be made, when the user stops typing furiously.
 818 (defun type-break-query ()
 819   (add-hook 'type-break-post-command-hook 'type-break-do-query))
 820
 821 (defun type-break-do-query ()
 822   (cond
 823    ((not type-break-query-mode)
 824     (type-break-noninteractive-query)
 825     (type-break-schedule type-break-query-interval)
 826     (remove-hook 'type-break-post-command-hook 'type-break-do-query))
 827    ((sit-for 2)
 828     (condition-case ()
 829         (cond
 830          ((let ((type-break-mode nil)
 831                 ;; yes-or-no-p sets this-command to exit-minibuffer,
 832                 ;; which hoses undo or yank-pop (if you happened to be
 833                 ;; yanking just when the query occurred).
 834                 (this-command this-command))
 835             ;; Cancel schedule to prevent possibility of a second query
 836             ;; from taking place before this one has even returned.
 837             ;; The condition-case wrapper will reschedule on quit.
 838             (type-break-cancel-schedule)
 839             ;; Also prevent a second query when the break is interrupted.
 840             (remove-hook 'type-break-post-command-hook 'type-break-do-query)
 841             (funcall type-break-query-function
 842                      (format "%s%s"
 843                              (type-break-time-stamp)
 844                              (if type-break-terse-messages
 845                                  "Break now? "
 846                                "Take a break from typing now? "))))
 847           (type-break))
 848          (t
 849           (type-break-schedule type-break-query-interval)))
 850       (quit
 851        (type-break-schedule type-break-query-interval))))))
 852
 853 (defun type-break-noninteractive-query (&optional ignored-args)
 854   "Null query function which doesn't interrupt user and assumes `no'.
 855 It prints a reminder in the echo area to take a break, but doesn't enforce
 856 this or ask the user to start one right now."
 857   (cond
 858    (type-break-mode-line-message-mode)
 859    (t
 860     (beep t)
 861     (message "%sYou should take a typing break now.  Do `M-x type-break'."
 862              (type-break-time-stamp))
 863     (sit-for 1)
 864     (beep t)
 865     ;; return nil so query caller knows to reset reminder, as if user
 866     ;; said "no" in response to yes-or-no-p.
 867     nil)))
 868
 869 (defun type-break-time-warning ()
 870   (cond
 871    ((and (car type-break-keystroke-threshold)
 872          (< type-break-keystroke-count (car type-break-keystroke-threshold))))
 873    ((> type-break-time-warning-count 0)
 874     (let ((timeleft (type-break-time-difference (current-time)
 875                                                 type-break-time-next-break)))
 876       (setq type-break-warning-countdown-string (number-to-string timeleft))
 877       (cond
 878        ((eq (selected-window) (minibuffer-window)))
 879        ;; Do nothing if the command was just a prefix arg, since that will
 880        ;; immediately be followed by some other interactive command.
 881        ;; Otherwise, it is particularly annoying for the sit-for below to
 882        ;; delay redisplay when one types sequences like `C-u -1 C-l'.
 883        ((memq this-command '(digit-argument universal-argument)))
 884        ((not type-break-mode-line-message-mode)
 885         ;; Pause for a moment so any previous message can be seen.
 886         (sit-for 2)
 887         (message "%sWarning: typing break due in %s."
 888                  (type-break-time-stamp)
 889                  (type-break-format-time timeleft))
 890         (setq type-break-time-warning-count
 891               (1- type-break-time-warning-count))))))
 892    (t
 893     (remove-hook 'type-break-post-command-hook 'type-break-time-warning)
 894     (setq type-break-warning-countdown-string nil))))
 895
 896 (defun type-break-keystroke-warning ()
 897   (cond
 898    ((> type-break-keystroke-warning-count 0)
 899     (setq type-break-warning-countdown-string
 900           (number-to-string (- (cdr type-break-keystroke-threshold)
 901                                type-break-keystroke-count)))
 902     (cond
 903      ((eq (selected-window) (minibuffer-window)))
 904      ;; Do nothing if the command was just a prefix arg, since that will
 905      ;; immediately be followed by some other interactive command.
 906      ;; Otherwise, it is particularly annoying for the sit-for below to
 907      ;; delay redisplay when one types sequences like `C-u -1 C-l'.
 908      ((memq this-command '(digit-argument universal-argument)))
 909      ((not type-break-mode-line-message-mode)
 910       (sit-for 2)
 911       (message "%sWarning: typing break due in %s keystrokes."
 912                (type-break-time-stamp)
 913                (- (cdr type-break-keystroke-threshold)
 914                   type-break-keystroke-count))
 915       (setq type-break-keystroke-warning-count
 916             (1- type-break-keystroke-warning-count)))))
 917    (t
 918     (remove-hook 'type-break-post-command-hook
 919                  'type-break-keystroke-warning)
 920     (setq type-break-warning-countdown-string nil))))
 921
 922 (defun type-break-mode-line-countdown-or-break (&optional type)
 923   (cond
 924    ((not type-break-mode-line-message-mode))
 925    ((eq type 'countdown)
 926     ;(setq type-break-mode-line-break-message-p nil)
 927     (add-hook 'type-break-post-command-hook
 928               'type-break-force-mode-line-update 'append))
 929    ((eq type 'break)
 930     ;; Alternate
 931     (setq type-break-mode-line-break-message-p
 932           (not type-break-mode-line-break-message-p))
 933     (remove-hook 'type-break-post-command-hook
 934                  'type-break-force-mode-line-update))
 935    (t
 936     (setq type-break-mode-line-break-message-p nil)
 937     (setq type-break-warning-countdown-string nil)
 938     (remove-hook 'type-break-post-command-hook
 939                  'type-break-force-mode-line-update)))
 940   (type-break-force-mode-line-update))
 941
 942 \f
 943 ;;;###autoload
 944 (defun type-break-statistics ()
 945   "Print statistics about typing breaks in a temporary buffer.
 946 This includes the last time a typing break was taken, when the next one is
 947 scheduled, the keystroke thresholds and the current keystroke count, etc."
 948   (interactive)
 949   (with-output-to-temp-buffer "*Typing Break Statistics*"
 950     (princ (format "Typing break statistics\n-----------------------\n
 951 Typing break mode is currently %s.
 952 Interactive query for breaks is %s.
 953 Warnings of imminent typing breaks in mode line is %s.
 954
 955 Last typing break ended     : %s
 956 Next scheduled typing break : %s\n
 957 Minimum keystroke threshold : %s
 958 Maximum keystroke threshold : %s
 959 Current keystroke count     : %s"
 960                    (if type-break-mode "enabled" "disabled")
 961                    (if type-break-query-mode "enabled" "disabled")
 962                    (if type-break-mode-line-message-mode "enabled" "disabled")
 963                    (if type-break-time-last-break
 964                        (current-time-string type-break-time-last-break)
 965                      "never")
 966                    (if (and type-break-mode type-break-time-next-break)
 967                        (format "%s\t(%s from now)"
 968                                (current-time-string type-break-time-next-break)
 969                                (type-break-format-time
 970                                 (type-break-time-difference
 971                                 (current-time)
 972                                 type-break-time-next-break)))
 973                      "none scheduled")
 974                    (or (car type-break-keystroke-threshold) "none")
 975                    (or (cdr type-break-keystroke-threshold) "none")
 976                    type-break-keystroke-count))))
 977
 978 ;;;###autoload
 979 (defun type-break-guesstimate-keystroke-threshold (wpm &optional wordlen frac)
 980   "Guess values for the minimum/maximum keystroke threshold for typing breaks.
 981
 982 If called interactively, the user is prompted for their guess as to how
 983 many words per minute they usually type.  This value should not be your
 984 maximum WPM, but your average.  Of course, this is harder to gauge since it
 985 can vary considerably depending on what you are doing.  For example, one
 986 tends to type less when debugging a program as opposed to writing
 987 documentation.  (Perhaps a separate program should be written to estimate
 988 average typing speed.)
 989
 990 From that, this command sets the values in `type-break-keystroke-threshold'
 991 based on a fairly simple algorithm involving assumptions about the average
 992 length of words (5).  For the minimum threshold, it uses about a fifth of
 993 the computed maximum threshold.
 994
 995 When called from Lisp programs, the optional args WORDLEN and FRAC can be
 996 used to override the default assumption about average word length and the
 997 fraction of the maximum threshold to which to set the minimum threshold.
 998 FRAC should be the inverse of the fractional value; for example, a value of
 999 2 would mean to use one half, a value of 4 would mean to use one quarter, etc."
1000   (interactive "NOn average, how many words per minute do you type? ")
1001   (let* ((upper (* wpm (or wordlen 5) (/ type-break-interval 60)))
1002          (lower (/ upper (or frac 5))))
1003     (or type-break-keystroke-threshold
1004         (setq type-break-keystroke-threshold (cons nil nil)))
1005     (setcar type-break-keystroke-threshold lower)
1006     (setcdr type-break-keystroke-threshold upper)
1007     (if (interactive-p)
1008         (message "min threshold: %d\tmax threshold: %d" lower upper)
1009       type-break-keystroke-threshold)))
1010
1011 \f
1012 ;;; misc functions
1013
1014 ;; Compute the difference, in seconds, between a and b, two structures
1015 ;; similar to those returned by `current-time'.
1016 ;; Use addition rather than logand since that is more robust; the low 16
1017 ;; bits of the seconds might have been incremented, making it more than 16
1018 ;; bits wide.
1019 (defun type-break-time-difference (a b)
1020   (+ (lsh (- (car b) (car a)) 16)
1021      (- (car (cdr b)) (car (cdr a)))))
1022
1023 ;; Return (in a new list the same in structure to that returned by
1024 ;; `current-time') the sum of the arguments.  Each argument may be a time
1025 ;; list or a single integer, a number of seconds.
1026 ;; This function keeps the high and low 16 bits of the seconds properly
1027 ;; balanced so that the lower value never exceeds 16 bits.  Otherwise, when
1028 ;; the result is passed to `current-time-string' it will toss some of the
1029 ;; "low" bits and format the time incorrectly.
1030 (defun type-break-time-sum (&rest tmlist)
1031   (let ((high 0)
1032         (low 0)
1033         (micro 0)
1034         tem)
1035     (while tmlist
1036       (setq tem (car tmlist))
1037       (setq tmlist (cdr tmlist))
1038       (cond
1039        ((numberp tem)
1040         (setq low (+ low tem)))
1041        (t
1042         (setq high  (+ high  (or (car tem) 0)))
1043         (setq low   (+ low   (or (car (cdr tem)) 0)))
1044         (setq micro (+ micro (or (car (cdr (cdr tem))) 0))))))
1045
1046     (and (>= micro 1000000)
1047          (progn
1048            (setq tem (/ micro 1000000))
1049            (setq low (+ low tem))
1050            (setq micro (- micro (* tem 1000000)))))
1051
1052     (setq tem (lsh low -16))
1053     (and (> tem 0)
1054          (progn
1055            (setq low (logand low 65535))
1056            (setq high (+ high tem))))
1057
1058     (list high low micro)))
1059
1060 (defun type-break-time-stamp (&optional when)
1061   (if (fboundp 'format-time-string)
1062       (format-time-string type-break-time-stamp-format when)
1063     ;; Emacs 19.28 and prior do not have format-time-string.
1064     ;; In that case, result is not customizable.  Upgrade today!
1065     (format "[%s] " (substring (current-time-string when) 11 16))))
1066
1067 (defun type-break-format-time (secs)
1068   (let ((mins (/ secs 60)))
1069     (cond
1070      ((= mins 1) (format "%d minute" mins))
1071      ((> mins 0) (format "%d minutes" mins))
1072      ((= secs 1) (format "%d second" secs))
1073      (t (format "%d seconds" secs)))))
1074
1075 (defun type-break-keystroke-reset ()
1076   (setq type-break-interval-start (current-time)) ; not a keystroke
1077   (setq type-break-keystroke-count 0)
1078   (setq type-break-keystroke-warning-count 0)
1079   (setq type-break-current-keystroke-warning-interval
1080         type-break-keystroke-warning-intervals)
1081   (remove-hook 'type-break-post-command-hook 'type-break-keystroke-warning))
1082
1083 (defun type-break-force-mode-line-update (&optional all)
1084   "Force the mode-line of the current buffer to be redisplayed.
1085 With optional non-nil ALL, force redisplay of all mode-lines."
1086   (and all (save-excursion (set-buffer (other-buffer))))
1087   (set-buffer-modified-p (buffer-modified-p)))
1088
1089 ;; If an exception occurs in Emacs while running the post command hook, the
1090 ;; value of that hook is clobbered.  This is because the value of the
1091 ;; variable is temporarily set to nil while it's running to prevent
1092 ;; recursive application, but it also means an exception aborts the routine
1093 ;; of restoring it.  This function is called from the timers to restore it,
1094 ;; just in case.
1095 (defun type-break-check-post-command-hook ()
1096   (add-hook 'post-command-hook 'type-break-run-tb-post-command-hook 'append))
1097
1098 \f
1099 ;;; Timer wrapper functions
1100 ;;;
1101 ;;; These shield type-break from variations in the interval timer packages
1102 ;;; for different versions of Emacs.
1103
1104 (defun type-break-run-at-time (time repeat function)
1105   (condition-case nil (or (require 'timer) (require 'itimer)) (error nil))
1106   (cond ((fboundp 'run-at-time)
1107          (run-at-time time repeat function))
1108         ((fboundp 'start-timer)
1109          (let ((name (if (symbolp function)
1110                          (symbol-name function)
1111                        "type-break")))
1112            (start-timer name function time repeat)))
1113         ((fboundp 'start-itimer)
1114          (let ((name (if (symbolp function)
1115                          (symbol-name function)
1116                        "type-break")))
1117            (start-itimer name function time repeat)))))
1118
1119 (defvar timer-dont-exit)
1120 (defun type-break-cancel-function-timers (function)
1121   (cond ((fboundp 'cancel-function-timers)
1122          (let ((timer-dont-exit t))
1123            (cancel-function-timers function)))
1124         ((fboundp 'delete-timer)
1125          (let ((list timer-list))
1126            (while list
1127              (and (eq (funcall 'timer-function (car list)) function)
1128                   (delete-timer (car list)))
1129              (setq list (cdr list)))))
1130         ((fboundp 'delete-itimer)
1131          (with-no-warnings
1132           (let ((list itimer-list))
1133             (while list
1134               (and (eq (funcall 'itimer-function (car list)) function)
1135                    (delete-itimer (car list)))
1136               (setq list (cdr list))))))))
1137
1138 \f
1139 ;;; Demo wrappers
1140
1141 ;; This is a wrapper around hanoi that calls it with an arg large enough to
1142 ;; make the largest discs possible that will fit in the window.
1143 ;; Also, clean up the *Hanoi* buffer after we're done.
1144 (defun type-break-demo-hanoi ()
1145   "Take a hanoiing typing break."
1146   (and (get-buffer "*Hanoi*")
1147        (kill-buffer "*Hanoi*"))
1148   (condition-case ()
1149       (progn
1150         (hanoi (/ (window-width) 8))
1151         ;; Wait for user to come back.
1152         (read-char)
1153         (kill-buffer "*Hanoi*"))
1154     (quit
1155      ;; eat char
1156      (read-char)
1157      (and (get-buffer "*Hanoi*")
1158           (kill-buffer "*Hanoi*")))))
1159
1160 ;; This is a wrapper around life that calls it with a `sleep' arg to make
1161 ;; it run a little more leisurely.
1162 ;; Also, clean up the *Life* buffer after we're done.
1163 (defun type-break-demo-life ()
1164   "Take a typing break and get a life."
1165   (let ((continue t))
1166     (while continue
1167       (setq continue nil)
1168       (and (get-buffer "*Life*")
1169            (kill-buffer "*Life*"))
1170       (condition-case ()
1171           (progn
1172             (life 3)
1173             ;; wait for user to return
1174             (read-char)
1175             (kill-buffer "*Life*"))
1176         (life-extinct
1177          (message "%s" (get 'life-extinct 'error-message))
1178          (sit-for 3)
1179          ;; restart demo
1180          (setq continue t))
1181         (quit
1182          (and (get-buffer "*Life*")
1183               (kill-buffer "*Life*")))))))
1184
1185 ;; Boring demo, but doesn't use many cycles
1186 (defun type-break-demo-boring ()
1187   "Boring typing break demo."
1188   (let ((rmsg (if type-break-terse-messages
1189                   ""
1190                 "Press any key to resume from typing break"))
1191         (buffer-name "*Typing Break Buffer*")
1192         lines elapsed timeleft tmsg)
1193     (condition-case ()
1194         (progn
1195           (switch-to-buffer (get-buffer-create buffer-name))
1196           (buffer-disable-undo (current-buffer))
1197           (setq lines (/ (window-body-height) 2))
1198           (unless type-break-terse-messages (setq lines (1- lines)))
1199           (if type-break-demo-boring-stats
1200               (setq lines (- lines 2)))
1201           (setq lines (make-string lines ?\C-j))
1202           (while (not (input-pending-p))
1203             (erase-buffer)
1204             (setq elapsed (type-break-time-difference
1205                            type-break-time-last-break
1206                            (current-time)))
1207             (let ((good-interval (or type-break-good-rest-interval
1208                                      type-break-good-break-interval)))
1209               (cond
1210                (good-interval
1211                 (setq timeleft (- good-interval elapsed))
1212                 (if (> timeleft 0)
1213                     (setq tmsg
1214                           (format (if type-break-terse-messages
1215                                       "Break remaining: %s"
1216                                     "You should rest for %s more")
1217                                   (type-break-format-time timeleft)))
1218                   (setq tmsg
1219                         (format (if type-break-terse-messages
1220                                     "Break complete (%s elapsed in total)"
1221                                   "Typing break has lasted %s")
1222                                 (type-break-format-time elapsed)))))
1223                (t
1224                 (setq tmsg
1225                       (format (if type-break-terse-messages
1226                                   "Break has lasted %s"
1227                                 "Typing break has lasted %s")
1228                               (type-break-format-time elapsed))))))
1229             (insert lines
1230                     (make-string (/ (- (window-width) (length tmsg)) 2) ?\ )
1231                     tmsg)
1232             (if (> (length rmsg) 0)
1233                 (insert "\n"
1234                         (make-string (/ (- (window-width) (length rmsg)) 2)
1235                                      ?\ )
1236                         rmsg))
1237             (if type-break-demo-boring-stats
1238                 (let*
1239                     ((message
1240                       (format
1241                        (if type-break-terse-messages
1242                            "Since last break: %s keystrokes\n"
1243                          "Since your last break you've typed %s keystrokes\n")
1244                        type-break-keystroke-count))
1245                      (column-spaces
1246                       (make-string (/ (- (window-width) (length message)) 2)
1247                                    ?\ ))
1248                      (wpm (/ (/ (float type-break-keystroke-count) 5)
1249                              (/ (type-break-time-difference
1250                                  type-break-interval-start
1251                                  type-break-time-last-break)
1252                                 60.0))))
1253                   (insert "\n\n" column-spaces message)
1254                   (if type-break-terse-messages
1255                       (insert (format "                  %s%.2f wpm"
1256                                       column-spaces
1257                                       wpm))
1258                     (setq message
1259                           (format "at an average of %.2f words per minute"
1260                                   wpm))
1261                     (insert
1262                      (make-string (/ (- (window-width) (length message)) 2)
1263                                   ?\ )
1264                      message))))
1265             (goto-char (point-min))
1266             (sit-for 60))
1267           (read-char)
1268           (kill-buffer buffer-name))
1269       (quit
1270        (and (get-buffer buffer-name)
1271             (kill-buffer buffer-name))))))
1272
1273 \f
1274 (provide 'type-break)
1275
1276 (if type-break-mode
1277     (type-break-mode 1))
1278
1279 ;;; arch-tag: 943a2eb3-07e6-420b-993f-96e4796f5fd0
1280 ;;; type-break.el ends here