lisp/info-xref.el

   1 ;;; info-xref.el --- check external references in an Info document
   2
   3 ;; Copyright (C) 2003, 2004 Free Software Foundation, Inc.
   4
   5 ;; Author: Kevin Ryde <user42@zip.com.au>
   6 ;; Keywords: docs
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This file implements some simple checking of external cross references in
  28 ;; info files, by attempting to visit the nodes specified.
  29 ;;
  30 ;; "makeinfo" checks references internal to a document, but not external
  31 ;; references, which makes it rather easy for mistakes to creep in or node
  32 ;; name changes to go unnoticed.  `Info-validate' doesn't check external
  33 ;; references either.
  34 ;;
  35 ;; `M-x info-xref-check' checks one file.  When invoked from an Info-mode or
  36 ;; texinfo-mode buffer, the current info file is the default at the prompt.
  37 ;;
  38 ;; `M-x info-xref-check-all' looks at everything in the normal info path.
  39 ;; This might be a lot of files but it's a good way to check the consistency
  40 ;; of the whole system.
  41 ;;
  42 ;; Results are shown in a buffer.  The format is a bit rough, but hopefully
  43 ;; there won't be too many problems normally, and correcting them is a
  44 ;; manual process anyway, a case of finding the right spot in the original
  45 ;; .texi and finding what node it ought to point to.
  46 ;;
  47 ;; When a target info file doesn't exist there's clearly no way to validate
  48 ;; node references within it.  A message is given for missing target files
  49 ;; (once per source document), it could be simply that the target hasn't
  50 ;; been installed, or it could be a mistake in the reference.
  51 ;;
  52 ;; Indirect info files are understood, just pass the top-level foo.info to
  53 ;; `info-xref-check' and it traverses all sub-files.  Compressed info files
  54 ;; are accepted too, as usual for `Info-mode'.
  55 ;;
  56 ;; `info-xref-check-all' is rather permissive in what it considers an info
  57 ;; file.  It has to be since info files don't necessarily have a ".info"
  58 ;; suffix (eg. this is usual for the emacs manuals).  One consequence of
  59 ;; this is that if for instance there's a source code directory in
  60 ;; `Info-directory-list' then a lot of extraneous files might be read, which
  61 ;; will be time consuming but should be harmless.
  62 ;;
  63 ;; `M-x info-xref-check-all-custom' is a related command, it goes through
  64 ;; all info document references in customizable variables, checking them
  65 ;; like info file cross references.
  66
  67 ;;; Code:
  68
  69 (require 'info)
  70
  71 (defconst info-xref-results-buffer "*info-xref results*"
  72   "Name of the buffer for info-xref results.")
  73
  74 ;;;###autoload
  75 (defun info-xref-check (filename)
  76   "Check external references in FILENAME, an info document."
  77   (interactive
  78    (list
  79     (let* ((default-filename
  80              (cond ((eq major-mode 'Info-mode)
  81                     Info-current-file)
  82                    ((eq major-mode 'texinfo-mode)
  83                     ;; look for @setfilename like makeinfo.el does
  84                     (save-excursion
  85                       (goto-char (point-min))
  86                       (if (re-search-forward
  87                            "^@setfilename[ \t]+\\([^ \t\n]+\\)[ \t]*"
  88                            (line-beginning-position 100) t)
  89                           (expand-file-name (match-string 1)))))))
  90            (prompt (if default-filename
  91                        (format "Info file (%s): " default-filename)
  92                      "Info file: ")))
  93       (read-file-name prompt nil default-filename t))))
  94   (info-xref-check-list (list filename)))
  95
  96 ;;;###autoload
  97 (defun info-xref-check-all ()
  98   "Check external references in all info documents in the usual path.
  99 The usual path is `Info-directory-list' and `Info-additional-directory-list'."
 100   (interactive)
 101   (info-xref-check-list (info-xref-all-info-files)))
 102
 103 ;; An alternative to trying to get only top-level files here would be to
 104 ;; simply return all files, and have info-xref-check-list not follow
 105 ;; Indirect:.  The current way seems a bit nicer though, because it gets the
 106 ;; proper top-level filename into the error messages, and suppresses
 107 ;; duplicate "not available" messages for all subfiles of a single document.
 108
 109 (defun info-xref-all-info-files ()
 110   "Return a list of all available info files.
 111 Only top-level files are returned, subfiles are excluded.
 112
 113 Since info files don't have to have a .info suffix, all files in the
 114 relevant directories are considered, which might mean a lot of extraneous
 115 things are returned if for instance a source code directory is in the path."
 116
 117   (info-initialize) ;; establish Info-directory-list
 118   (apply 'nconc
 119          (mapcar
 120           (lambda (dir)
 121             (let ((result nil))
 122               (dolist (name (directory-files dir t))
 123                 (unless (or (file-directory-p name) (info-xref-subfile-p name))
 124                   (push name result)))
 125               (nreverse result)))
 126           (append Info-directory-list Info-additional-directory-list))))
 127
 128 (defun info-xref-subfile-p (filename)
 129   "Return t if FILENAME is an info subfile.
 130 If removing the last \"-<NUM>\" from the filename gives a file that exists,
 131 then consider FILENAME a subfile.  This is an imperfect test, we probably
 132 should open up the purported top file and see what subfiles it says."
 133   (and (string-match "\\`\\(\\([^-]*-\\)*[^-]*\\)-[0-9]+\\(.*\\)\\'" filename)
 134        (file-exists-p (concat (match-string 1 filename)
 135                               (match-string 3 filename)))))
 136
 137
 138 ;; Some dynamic variables are used to share information with sub-functions
 139 ;; below.
 140 ;;
 141 ;; info-xref-filename - current top-level filename, eg. /usr/info/foo.info.gz
 142 ;;
 143 ;; info-xref-filename-header - a heading message for the current top-level
 144 ;;     filename, or "" when it's been printed.
 145 ;;
 146 ;; info-xref-good - count of good cross references.
 147 ;;
 148 ;; info-xref-bad - count of bad cross references.
 149 ;;
 150 ;; info-xref-xfile-alist - indexed by "(foo)" with value nil or t according
 151 ;;     to whether "(foo)" exists or not.  This is used to suppress duplicate
 152 ;;     messages about foo not being available.  (Duplicates within one
 153 ;;     top-level file that is.)
 154
 155 (defun info-xref-check-list (filename-list)
 156   "Check external references in info documents in FILENAME-LIST."
 157   (pop-to-buffer info-xref-results-buffer t)
 158   (erase-buffer)
 159   (let ((info-xref-good 0)
 160         (info-xref-bad  0))
 161     (dolist (info-xref-filename filename-list)
 162       (let ((info-xref-filename-heading
 163              (format "In file %s:\n" info-xref-filename))
 164             (info-xref-xfile-alist nil))
 165         (with-temp-message (format "Looking at %s" info-xref-filename)
 166           (with-temp-buffer
 167             (info-insert-file-contents info-xref-filename)
 168             (goto-char (point-min))
 169             (if (re-search-forward "\^_\nIndirect:\n" nil t)
 170                 (let ((dir (file-name-directory info-xref-filename)))
 171                   (while (looking-at "\\(.*\\): [0-9]+\n")
 172                     (let ((subfile (match-string 1)))
 173                       (with-temp-buffer
 174                         (info-insert-file-contents
 175                          (expand-file-name subfile dir))
 176                         (info-xref-check-buffer)))
 177                     (forward-line)))
 178               (info-xref-check-buffer))))))
 179     (insert (format "done, %d good, %d bad\n" info-xref-good info-xref-bad))))
 180
 181 (defun info-xref-check-buffer ()
 182   "Check external references in the info file in the current buffer.
 183 This should be the raw file contents, not `Info-mode'."
 184   (goto-char (point-min))
 185   (while (re-search-forward
 186           "\\*[Nn]ote[ \n\t]+[^:]*:[ \n\t]+\\(\\(([^)]*)\\)[^.,]+\\)[.,]"
 187           nil t)
 188     (let* ((file (match-string 2))
 189            (node ;; Canonicalize spaces: we could use "[\t\n ]+" but
 190             ;; we try to avoid uselessly replacing " " with " ".
 191             (replace-regexp-in-string "[\t\n][\t\n ]*\\| [\t\n ]+" " "
 192                                       (match-string 1) t t)))
 193       (if (string-equal "()" file)
 194           (info-xref-output "Empty filename part: %s\n" node)
 195         ;; see if the file exists, if we haven't tried it before
 196         (unless (assoc file info-xref-xfile-alist)
 197           (let ((found (info-xref-goto-node-p file)))
 198             (push (cons file found) info-xref-xfile-alist)
 199             (unless found
 200               (info-xref-output "Not available to check: %s\n" file))))
 201         ;; if the file exists, try the node
 202         (when (cdr (assoc file info-xref-xfile-alist))
 203           (if (info-xref-goto-node-p node)
 204               (setq info-xref-good (1+ info-xref-good))
 205             (setq info-xref-bad (1+ info-xref-bad))
 206             (info-xref-output "No such node: %s\n" node)))))))
 207
 208 (defun info-xref-output (str &rest args)
 209   "Emit a `format'-ed message STR+ARGS to the info-xref output buffer."
 210   (with-current-buffer info-xref-results-buffer
 211     (insert info-xref-filename-heading
 212             (apply 'format str args))
 213     (setq info-xref-filename-heading "")
 214     ;; all this info-xref can be pretty slow, display now so the user can
 215     ;; see some progress
 216     (sit-for 0)))
 217
 218 ;; When asking Info-goto-node to fork, *info* needs to be the current
 219 ;; buffer, otherwise it seems to clone the current buffer but then do the
 220 ;; goto-node in plain *info*.
 221 ;;
 222 ;; We only fork if *info* already exists, if it doesn't then we can create
 223 ;; and destroy just that instead of a new name.
 224 ;;
 225 ;; If Info-goto-node can't find the file, then no new buffer is created.  If
 226 ;; it finds the file but not the node, then a buffer is created.  Handle
 227 ;; this difference by checking before killing.
 228 ;;
 229 (defun info-xref-goto-node-p (node)
 230   "Return t if it's possible to go to the given NODE."
 231   (let ((oldbuf (current-buffer)))
 232     (save-excursion
 233       (save-window-excursion
 234         (prog1
 235             (condition-case err
 236                 (progn
 237                   (Info-goto-node node
 238                                   (when (get-buffer "*info*")
 239                                     (set-buffer "*info*")
 240                                     "xref - temporary"))
 241                   t)
 242               (error nil))
 243           (unless (equal (current-buffer) oldbuf)
 244             (kill-buffer (current-buffer))))))))
 245
 246 ;;;###autoload
 247 (defun info-xref-check-all-custom ()
 248   "Check info references in all customize groups and variables.
 249 `custom-manual' and `info-link' entries in the `custom-links' list are checked.
 250
 251 `custom-load' autoloads for all symbols are loaded in order to get all the
 252 link information.  This will be a lot of lisp packages loaded, and can take
 253 quite a while."
 254
 255   (interactive)
 256   (pop-to-buffer info-xref-results-buffer t)
 257   (erase-buffer)
 258   (let ((info-xref-filename-heading ""))
 259
 260     ;; `custom-load-symbol' is not used, since it quietly ignores errors,
 261     ;; but we want to show them (since they may mean incomplete checking).
 262     ;;
 263     ;; Just one pass through mapatoms is made.  There shouldn't be any new
 264     ;; custom-loads setup by packages loaded.
 265     ;;
 266     (info-xref-output "Loading custom-load autoloads ...\n")
 267     (require 'cus-start)
 268     (require 'cus-load)
 269     (let ((viper-mode nil)) ;; tell viper.el not to ask about viperizing
 270       (mapatoms
 271        (lambda (symbol)
 272          (dolist (load (get symbol 'custom-loads))
 273            (cond ((symbolp load)
 274                   (condition-case cause (require load)
 275                     (error
 276                      (info-xref-output "Symbol `%s': cannot require '%s: %s\n"
 277                                        symbol load cause))))
 278                  ;; skip if previously loaded
 279                  ((assoc load load-history))
 280                  ((assoc (locate-library load) load-history))
 281                  (t
 282                   (condition-case cause (load load)
 283                     (error
 284                      (info-xref-output "Symbol `%s': cannot load \"%s\": %s\n"
 285                                        symbol load cause)))))))))
 286
 287     ;; Don't bother to check whether the info file exists as opposed to just
 288     ;; a missing node.  If you have the lisp then you should have the
 289     ;; documentation, so missing node name will be the usual fault.
 290     ;;
 291     (info-xref-output "\nChecking custom-links references ...\n")
 292     (let ((good 0)
 293           (bad  0))
 294       (mapatoms
 295        (lambda (symbol)
 296          (dolist (link (get symbol 'custom-links))
 297            (when (memq (car link) '(custom-manual info-link))
 298              (if (info-xref-goto-node-p (cadr link))
 299                  (setq good (1+ good))
 300                (setq bad (1+ bad))
 301                ;; symbol-file gives nil for preloaded variables, would need
 302                ;; to copy what describe-variable does to show the right place
 303                (info-xref-output "Symbol `%s' (in %s): cannot goto node: %s\n"
 304                                  symbol (symbol-file symbol) (cadr link)))))))
 305       (info-xref-output "%d good, %d bad\n" good bad))))
 306
 307 (provide 'info-xref)
 308
 309 ;;; arch-tag: 69d4d528-69ed-4cc2-8eb4-c666a0c1d5ac
 310 ;;; info-xref.el ends here