lisp/info-look.el

   1 ;;; info-look.el --- major-mode-sensitive Info index lookup facility
   2 ;; An older version of this was known as libc.el.
   3
   4 ;; Copyright (C) 1995,96,97,98,99,2001,03,04  Free Software Foundation, Inc.
   5
   6 ;; Author: Ralph Schleicher <rs@nunatak.allgaeu.org>
   7 ;;         (did not show signs of life (Nov 2001)  -stef)
   8 ;; Keywords: help languages
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Really cool code to lookup info indexes.
  30 ;; Try especially info-lookup-symbol (aka C-h S).
  31
  32 ;;; Code:
  33
  34 (require 'info)
  35
  36 (defgroup info-lookup nil
  37   "Major mode sensitive help agent."
  38   :group 'help :group 'languages)
  39
  40 (defvar info-lookup-mode nil
  41   "Symbol of the current buffer's help mode.
  42 Help is provided according to the buffer's major mode if value is nil.
  43 Automatically becomes buffer local when set in any fashion.")
  44 (make-variable-buffer-local 'info-lookup-mode)
  45
  46 (defcustom info-lookup-other-window-flag t
  47   "Non-nil means pop up the Info buffer in another window."
  48   :group 'info-lookup :type 'boolean)
  49
  50 (defcustom info-lookup-highlight-face 'highlight
  51   "Face for highlighting looked up help items.
  52 Setting this variable to nil disables highlighting."
  53   :group 'info-lookup :type 'face)
  54
  55 (defvar info-lookup-highlight-overlay nil
  56   "Overlay object used for highlighting.")
  57
  58 (defcustom info-lookup-file-name-alist
  59   '(("\\`ac\\(local\\|site\\|include\\)\\.m4\\'" . autoconf-mode))
  60   "Alist of file names handled specially.
  61 List elements are cons cells of the form
  62
  63     (REGEXP . MODE)
  64
  65 If a file name matches REGEXP, then use help mode MODE instead of the
  66 buffer's major mode."
  67   :group 'info-lookup :type '(repeat (cons (string :tag "Regexp")
  68                                            (symbol :tag "Mode"))))
  69
  70 (defvar info-lookup-history nil
  71   "History of previous input lines.")
  72
  73 (defvar info-lookup-alist nil
  74   "Alist of known help topics.
  75 Cons cells are of the form
  76
  77     (HELP-TOPIC . HELP-DATA)
  78
  79 HELP-TOPIC is the symbol of a help topic.
  80 HELP-DATA is a HELP-TOPIC's public data set.
  81  Value is an alist with elements of the form
  82
  83     (HELP-MODE REGEXP IGNORE-CASE DOC-SPEC PARSE-RULE OTHER-MODES)
  84
  85 HELP-MODE is a mode's symbol.
  86 REGEXP is a regular expression matching those help items whose
  87  documentation can be looked up via DOC-SPEC.
  88 IGNORE-CASE is non-nil if help items are case insensitive.
  89 DOC-SPEC is a list of documentation specifications of the form
  90
  91     (INFO-NODE TRANS-FUNC PREFIX SUFFIX)
  92
  93 INFO-NODE is the name (including file name part) of an Info index.
  94 TRANS-FUNC is a function translating index entries into help items;
  95  nil means add only those index entries matching REGEXP, a string
  96  means prepend string to the first word of all index entries.
  97 PREFIX and SUFFIX are parts of a regular expression.  If one of
  98  them is non-nil then search the help item's Info node for the
  99  first occurrence of the regular expression `PREFIX ITEM SUFFIX'.
 100  ITEM will be highlighted with `info-lookup-highlight-face' if this
 101  variable is not nil.
 102 PARSE-RULE is either the symbol name of a function or a regular
 103  expression for guessing the default help item at point.  Fuzzy
 104  regular expressions like \"[_a-zA-Z0-9]+\" do a better job if
 105  there are no clear delimiters; do not try to write too complex
 106  expressions.  PARSE-RULE defaults to REGEXP.
 107 OTHER-MODES is a list of cross references to other help modes.")
 108
 109 (defsubst info-lookup->topic-value (topic)
 110   (cdr (assoc topic info-lookup-alist)))
 111
 112 (defsubst info-lookup->mode-value (topic mode)
 113   (assoc mode (info-lookup->topic-value topic)))
 114
 115 (defsubst info-lookup->regexp (topic mode)
 116   (nth 1 (info-lookup->mode-value topic mode)))
 117
 118 (defsubst info-lookup->ignore-case (topic mode)
 119   (nth 2 (info-lookup->mode-value topic mode)))
 120
 121 (defsubst info-lookup->doc-spec (topic mode)
 122   (nth 3 (info-lookup->mode-value topic mode)))
 123
 124 (defsubst info-lookup->parse-rule (topic mode)
 125   (nth 4 (info-lookup->mode-value topic mode)))
 126
 127 (defsubst info-lookup->other-modes (topic mode)
 128   (nth 5 (info-lookup->mode-value topic mode)))
 129
 130 (defun info-lookup-add-help (&rest arg)
 131   "Add or update a help specification.
 132 Function arguments are one or more options of the form
 133
 134     KEYWORD ARGUMENT
 135
 136 KEYWORD is either `:topic', `:mode', `:regexp', `:ignore-case',
 137  `:doc-spec', `:parse-rule', or `:other-modes'.
 138 ARGUMENT has a value as explained in the documentation of the
 139  variable `info-lookup-alist'.
 140
 141 If no topic or mode option has been specified, then the help topic defaults
 142 to `symbol', and the help mode defaults to the current major mode."
 143   (apply 'info-lookup-add-help* nil arg))
 144
 145 (defun info-lookup-maybe-add-help (&rest arg)
 146   "Add a help specification iff none is defined.
 147 See the documentation of the function `info-lookup-add-help'
 148 for more details."
 149   (apply 'info-lookup-add-help* t arg))
 150
 151 (defun info-lookup-add-help* (maybe &rest arg)
 152   (let (topic mode regexp ignore-case doc-spec
 153               parse-rule other-modes keyword value)
 154     (setq topic 'symbol
 155           mode major-mode
 156           regexp "\\w+")
 157     (while arg
 158       (setq keyword (car arg))
 159       (or (symbolp keyword)
 160           (error "Junk in argument list \"%S\"" arg))
 161       (setq arg (cdr arg))
 162       (and (null arg)
 163            (error "Keyword \"%S\" is missing an argument" keyword))
 164       (setq value (car arg)
 165             arg (cdr arg))
 166       (cond ((eq keyword :topic)
 167              (setq topic value))
 168             ((eq keyword :mode)
 169              (setq mode value))
 170             ((eq keyword :regexp)
 171              (setq regexp value))
 172             ((eq keyword :ignore-case)
 173              (setq ignore-case value))
 174             ((eq keyword :doc-spec)
 175              (setq doc-spec value))
 176             ((eq keyword :parse-rule)
 177              (setq parse-rule value))
 178             ((eq keyword :other-modes)
 179              (setq other-modes value))
 180             (t
 181              (error "Unknown keyword \"%S\"" keyword))))
 182     (or (and maybe (info-lookup->mode-value topic mode))
 183         (let* ((data (list regexp ignore-case doc-spec parse-rule other-modes))
 184                (topic-cell (or (assoc topic info-lookup-alist)
 185                                (car (setq info-lookup-alist
 186                                           (cons (cons topic nil)
 187                                                 info-lookup-alist)))))
 188                (mode-cell (assoc mode topic-cell)))
 189           (if (null mode-cell)
 190               (setcdr topic-cell (cons (cons mode data) (cdr topic-cell)))
 191             (setcdr mode-cell data))))
 192     nil))
 193
 194 (defvar info-lookup-cache nil
 195   "Cache storing data maintained automatically by the program.
 196 Value is an alist with cons cell of the form
 197
 198     (HELP-TOPIC . ((HELP-MODE INITIALIZED COMPLETIONS REFER-MODES) ...))
 199
 200 HELP-TOPIC is the symbol of a help topic.
 201 HELP-MODE is a mode's symbol.
 202 INITIALIZED is nil if HELP-MODE is uninitialized, t if
 203  HELP-MODE is initialized, and `0' means HELP-MODE is
 204  initialized but void.
 205 COMPLETIONS is an alist of documented help items.
 206 REFER-MODES is a list of other help modes to use.")
 207
 208 (defsubst info-lookup->cache (topic)
 209   (or (assoc topic info-lookup-cache)
 210       (car (setq info-lookup-cache
 211                  (cons (cons topic nil)
 212                        info-lookup-cache)))))
 213
 214 (defun info-lookup->topic-cache (topic)
 215   (cdr (info-lookup->cache topic)))
 216
 217 (defun info-lookup->mode-cache (topic mode)
 218   (assoc mode (info-lookup->topic-cache topic)))
 219
 220 (defun info-lookup->initialized (topic mode)
 221   (nth 1 (info-lookup->mode-cache topic mode)))
 222
 223 (defun info-lookup->completions (topic mode)
 224   (or (info-lookup->initialized topic mode)
 225       (info-lookup-setup-mode topic mode))
 226   (nth 2 (info-lookup->mode-cache topic mode)))
 227
 228 (defun info-lookup->refer-modes (topic mode)
 229   (or (info-lookup->initialized topic mode)
 230       (info-lookup-setup-mode topic mode))
 231   (nth 3 (info-lookup->mode-cache topic mode)))
 232
 233 (defun info-lookup->all-modes (topic mode)
 234   (cons mode (info-lookup->refer-modes topic mode)))
 235
 236 (defun info-lookup-quick-all-modes (topic mode)
 237   (cons mode (info-lookup->other-modes topic mode)))
 238
 239 ;;;###autoload
 240 (defun info-lookup-reset ()
 241   "Throw away all cached data.
 242 This command is useful if the user wants to start at the beginning without
 243 quitting Emacs, for example, after some Info documents were updated on the
 244 system."
 245   (interactive)
 246   (setq info-lookup-cache nil))
 247
 248 ;;;###autoload
 249 (defun info-lookup-symbol (symbol &optional mode)
 250   "Display the definition of SYMBOL, as found in the relevant manual.
 251 When this command is called interactively, it reads SYMBOL from the minibuffer.
 252 In the minibuffer, use M-n to yank the default argument value
 253 into the minibuffer so you can edit it.
 254 The default symbol is the one found at point.
 255
 256 With prefix arg a query for the symbol help mode is offered."
 257   (interactive
 258    (info-lookup-interactive-arguments 'symbol current-prefix-arg))
 259   (info-lookup 'symbol symbol mode))
 260
 261 ;;;###autoload
 262 (defun info-lookup-file (file &optional mode)
 263   "Display the documentation of a file.
 264 When this command is called interactively, it reads FILE from the minibuffer.
 265 In the minibuffer, use M-n to yank the default file name
 266 into the minibuffer so you can edit it.
 267 The default file name is the one found at point.
 268
 269 With prefix arg a query for the file help mode is offered."
 270   (interactive
 271    (info-lookup-interactive-arguments 'file current-prefix-arg))
 272   (info-lookup 'file file mode))
 273
 274 (defun info-lookup-interactive-arguments (topic &optional query)
 275   "Read and return argument value (and help mode) for help topic TOPIC.
 276 If optional argument QUERY is non-nil, query for the help mode."
 277   (let* ((mode (cond (query
 278                       (info-lookup-change-mode topic))
 279                      ((info-lookup->mode-value topic (info-lookup-select-mode))
 280                       info-lookup-mode)
 281                      ((info-lookup-change-mode topic))))
 282          (completions (info-lookup->completions topic mode))
 283          (default (info-lookup-guess-default topic mode))
 284          (completion-ignore-case (info-lookup->ignore-case topic mode))
 285          (enable-recursive-minibuffers t)
 286          (value (completing-read
 287                  (if default
 288                      (format "Describe %s (default %s): " topic default)
 289                    (format "Describe %s: " topic))
 290                  completions nil nil nil 'info-lookup-history default)))
 291     (list (if (equal value "") default value) mode)))
 292
 293 (defun info-lookup-select-mode ()
 294   (when (and (not info-lookup-mode) (buffer-file-name))
 295     (let ((file-name (file-name-nondirectory (buffer-file-name)))
 296           (file-name-alist info-lookup-file-name-alist))
 297       (while (and (not info-lookup-mode) file-name-alist)
 298         (when (string-match (caar file-name-alist) file-name)
 299           (setq info-lookup-mode (cdar file-name-alist)))
 300         (setq file-name-alist (cdr file-name-alist)))))
 301   (or info-lookup-mode (setq info-lookup-mode major-mode)))
 302
 303 (defun info-lookup-change-mode (topic)
 304   (let* ((completions (mapcar (lambda (arg)
 305                                 (cons (symbol-name (car arg)) (car arg)))
 306                               (info-lookup->topic-value topic)))
 307          (mode (completing-read
 308                 (format "Use %s help mode: " topic)
 309                 completions nil t nil 'info-lookup-history)))
 310     (or (setq mode (cdr (assoc mode completions)))
 311         (error "No %s help available" topic))
 312     (or (info-lookup->mode-value topic mode)
 313         (error "No %s help available for `%s'" topic mode))
 314     (setq info-lookup-mode mode)))
 315
 316 (defun info-lookup (topic item mode)
 317   "Display the documentation of a help item."
 318   (or mode (setq mode (info-lookup-select-mode)))
 319   (or (info-lookup->mode-value topic mode)
 320       (error "No %s help available for `%s'" topic mode))
 321   (let* ((completions (info-lookup->completions topic mode))
 322          (ignore-case (info-lookup->ignore-case topic mode))
 323          (entry (or (assoc (if ignore-case (downcase item) item) completions)
 324                     (assoc-string item completions t)
 325                     (error "Not documented as a %s: %s" topic (or item ""))))
 326          (modes (info-lookup->all-modes topic mode))
 327          (window (selected-window))
 328          found doc-spec node prefix suffix doc-found)
 329     (if (or (not info-lookup-other-window-flag)
 330             (eq (current-buffer) (get-buffer "*info*")))
 331         (info)
 332       (progn
 333         (save-window-excursion (info))
 334         ;; Determine whether or not the Info buffer is visible in
 335         ;; another frame on the same display.  If it is, simply raise
 336         ;; that frame.  Otherwise, display it in another window.
 337         (let* ((window (get-buffer-window "*info*" t))
 338                (info-frame (and window (window-frame window))))
 339           (if (and info-frame
 340                    (display-multi-frame-p)
 341                    (memq info-frame (frames-on-display-list))
 342                    (not (eq info-frame (selected-frame))))
 343             (select-frame info-frame)
 344           (switch-to-buffer-other-window "*info*")))))
 345     (while (and (not found) modes)
 346       (setq doc-spec (info-lookup->doc-spec topic (car modes)))
 347       (while (and (not found) doc-spec)
 348         (setq node (nth 0 (car doc-spec))
 349               prefix (nth 2 (car doc-spec))
 350               suffix (nth 3 (car doc-spec)))
 351         (when (condition-case error-data
 352                   (progn
 353                     (Info-goto-node node)
 354                     (setq doc-found t))
 355                 (error
 356                  (message "Cannot access Info node %s" node)
 357                  (sit-for 1)
 358                  nil))
 359           (condition-case nil
 360               (progn
 361                 ;; Don't use Info-menu, it forces case-fold-search to t
 362                 (let ((case-fold-search nil))
 363                   (re-search-forward
 364                    (concat "^\\* " (regexp-quote (or (cdr entry) (car entry)))
 365                            ":")))
 366                 (Info-follow-nearest-node)
 367                 (setq found t)
 368                 (if (or prefix suffix)
 369                     (let ((case-fold-search
 370                            (info-lookup->ignore-case topic (car modes)))
 371                           (buffer-read-only nil))
 372                       (goto-char (point-min))
 373                       (re-search-forward
 374                        (concat prefix (regexp-quote (car entry)) suffix))
 375                       (goto-char (match-beginning 0))
 376                       (and (display-color-p) info-lookup-highlight-face
 377                            ;; Search again for ITEM so that the first
 378                            ;; occurrence of ITEM will be highlighted.
 379                            (re-search-forward (regexp-quote (car entry)))
 380                            (let ((start (match-beginning 0))
 381                                  (end (match-end 0)))
 382                              (if (overlayp info-lookup-highlight-overlay)
 383                                  (move-overlay info-lookup-highlight-overlay
 384                                                start end (current-buffer))
 385                                (setq info-lookup-highlight-overlay
 386                                      (make-overlay start end))))
 387                            (overlay-put info-lookup-highlight-overlay
 388                                         'face info-lookup-highlight-face)))))
 389             (error nil)))
 390         (setq doc-spec (cdr doc-spec)))
 391       (setq modes (cdr modes)))
 392     ;; Alert the user if case was munged, and do this after bringing up the
 393     ;; info buffer since that can print messages
 394     (unless (or ignore-case
 395                 (string-equal item (car entry)))
 396       (message "Found in different case: %s" (car entry)))
 397     (or doc-found
 398         (error "Info documentation for lookup was not found"))
 399     ;; Don't leave the Info buffer if the help item couldn't be looked up.
 400     (if (and info-lookup-other-window-flag found)
 401         (select-window window))))
 402
 403 (defun info-lookup-setup-mode (topic mode)
 404   "Initialize the internal data structure."
 405   (or (info-lookup->initialized topic mode)
 406       (let (cell data (initialized 0) completions refer-modes)
 407         (if (not (info-lookup->mode-value topic mode))
 408             (message "No %s help available for `%s'" topic mode)
 409           ;; Recursively setup cross references.
 410           ;; But refer only to non-void modes.
 411           (dolist (arg (info-lookup->other-modes topic mode))
 412             (or (info-lookup->initialized topic arg)
 413                 (info-lookup-setup-mode topic arg))
 414             (and (eq (info-lookup->initialized topic arg) t)
 415                  (setq refer-modes (cons arg refer-modes))))
 416           (setq refer-modes (nreverse refer-modes))
 417           ;; Build the full completion alist.
 418           (setq completions
 419                 (nconc (condition-case nil
 420                            (info-lookup-make-completions topic mode)
 421                          (error nil))
 422                        (apply 'append
 423                               (mapcar (lambda (arg)
 424                                         (info-lookup->completions topic arg))
 425                                       refer-modes))))
 426           (setq initialized t))
 427         ;; Update `info-lookup-cache'.
 428         (setq cell (info-lookup->mode-cache topic mode)
 429               data (list initialized completions refer-modes))
 430         (if (not cell)
 431             (setcdr (info-lookup->cache topic)
 432                     (cons (cons mode data) (info-lookup->topic-cache topic)))
 433           (setcdr cell data))
 434         initialized)))
 435
 436 (defun info-lookup-make-completions (topic mode)
 437   "Create a unique alist from all index entries."
 438   (let ((doc-spec (info-lookup->doc-spec topic mode))
 439         (regexp (concat "^\\(" (info-lookup->regexp topic mode)
 440                         "\\)\\([ \t].*\\)?$"))
 441         node trans entry item prefix result doc-found
 442         (buffer (get-buffer-create " temp-info-look")))
 443     (with-current-buffer buffer
 444       (Info-mode))
 445     (while doc-spec
 446       (setq node (nth 0 (car doc-spec))
 447             trans (cond ((eq (nth 1 (car doc-spec)) nil)
 448                          (lambda (arg)
 449                            (if (string-match regexp arg)
 450                                (match-string 1 arg))))
 451                         ((stringp (nth 1 (car doc-spec)))
 452                          (setq prefix (nth 1 (car doc-spec)))
 453                          (lambda (arg)
 454                            (if (string-match "^\\([^: \t\n]+\\)" arg)
 455                                (concat prefix (match-string 1 arg)))))
 456                         (t (nth 1 (car doc-spec)))))
 457       (with-current-buffer buffer
 458         (message "Processing Info node `%s'..." node)
 459         (when (condition-case error-data
 460                   (progn
 461                     (Info-goto-node node)
 462                     (setq doc-found t))
 463                 (error
 464                  (message "Cannot access Info node `%s'" node)
 465                  (sit-for 1)
 466                  nil))
 467           (condition-case nil
 468               (progn
 469                 (goto-char (point-min))
 470                 (and (search-forward "\n* Menu:" nil t)
 471                      (while (re-search-forward "\n\\* \\(.*\\): " nil t)
 472                        (setq entry (match-string 1)
 473                              item (funcall trans entry))
 474                        ;; `trans' can return nil if the regexp doesn't match.
 475                        (when (and item
 476                                   ;; Sometimes there's more than one Menu:
 477                                   (not (string= entry "Menu")))
 478                          (and (info-lookup->ignore-case topic mode)
 479                               (setq item (downcase item)))
 480                          (and (string-equal entry item)
 481                               (setq entry nil))
 482                          (and (or (assoc item result)
 483                                   (setq result (cons (cons item entry)
 484                                                      result))))))))
 485             (error nil))))
 486       (message "Processing Info node `%s'...done" node)
 487       (setq doc-spec (cdr doc-spec)))
 488     (or doc-found
 489         (error "Info documentation for lookup was not found"))
 490     result))
 491
 492 (defun info-lookup-guess-default (topic mode)
 493   "Return a guess for a symbol to look up, based on text around point.
 494 Try all related modes applicable to TOPIC and MODE.
 495 Return nil if there is nothing appropriate in the buffer near point."
 496   (let ((modes (info-lookup->all-modes topic mode))
 497         guess)
 498     (while (and (not guess) modes)
 499       (setq guess (info-lookup-guess-default* topic (car modes))
 500             modes (cdr modes)))
 501     ;; Collapse whitespace characters.
 502     (when guess
 503       (let ((pos 0))
 504         (while (string-match "[ \t\n]+" guess pos)
 505           (setq pos (1+ (match-beginning 0)))
 506           (setq guess (replace-match " " t t guess)))))
 507     guess))
 508
 509 (defun info-lookup-guess-default* (topic mode)
 510   (let ((case-fold-search (info-lookup->ignore-case topic mode))
 511         (rule (or (info-lookup->parse-rule topic mode)
 512                   (info-lookup->regexp topic mode)))
 513         (start (point)) end regexp subexp result)
 514     (save-excursion
 515       (if (symbolp rule)
 516           (setq result (funcall rule))
 517         (if (consp rule)
 518             (setq regexp (car rule)
 519                   subexp (cdr rule))
 520           (setq regexp rule
 521                 subexp 0))
 522         ;; If at start of symbol, don't go back to end of previous one.
 523         (if (save-match-data
 524               (looking-at "[ \t\n]"))
 525             (skip-chars-backward " \t\n"))
 526         (setq end (point))
 527         (while (and (re-search-backward regexp nil t)
 528                     (looking-at regexp)
 529                     (>= (match-end 0) end))
 530           (setq result (match-string subexp)))
 531         (if (not result)
 532             (progn
 533               (goto-char start)
 534               (skip-chars-forward " \t\n")
 535               (and (looking-at regexp)
 536                    (setq result (match-string subexp)))))))
 537     result))
 538
 539 (defun info-lookup-guess-c-symbol ()
 540   "Get the C symbol at point."
 541   (condition-case nil
 542       (progn
 543         (skip-syntax-backward "w_")
 544         (let ((start (point)) prefix name)
 545           ;; Test for a leading `struct', `union', or `enum' keyword
 546           ;; but ignore names like `foo_struct'.
 547           (setq prefix (and (< (skip-chars-backward " \t\n") 0)
 548                             (< (skip-chars-backward "_a-zA-Z0-9") 0)
 549                             (looking-at "\\(struct\\|union\\|enum\\)\\s ")
 550                             (concat (match-string 1) " ")))
 551           (goto-char start)
 552           (and (looking-at "[_a-zA-Z][_a-zA-Z0-9]*")
 553                (setq name (match-string 0)))
 554           ;; Caveat!  Look forward if point is at `struct' etc.
 555           (and (not prefix)
 556                (or (string-equal name "struct")
 557                    (string-equal name "union")
 558                    (string-equal name "enum"))
 559                (looking-at "[a-z]+\\s +\\([_a-zA-Z][_a-zA-Z0-9]*\\)")
 560                (setq prefix (concat name " ")
 561                      name (match-string 1)))
 562           (and (or prefix name)
 563                (concat prefix name))))
 564     (error nil)))
 565
 566 ;;;###autoload
 567 (defun info-complete-symbol (&optional mode)
 568   "Perform completion on symbol preceding point."
 569   (interactive)
 570   (info-complete 'symbol
 571                  (or mode
 572                      (if (info-lookup->mode-value
 573                           'symbol (info-lookup-select-mode))
 574                          info-lookup-mode
 575                        (info-lookup-change-mode 'symbol)))))
 576
 577 ;;;###autoload
 578 (defun info-complete-file (&optional mode)
 579   "Perform completion on file preceding point."
 580   (interactive)
 581   (info-complete 'file
 582                  (or mode
 583                      (if (info-lookup->mode-value
 584                           'file (info-lookup-select-mode))
 585                          info-lookup-mode
 586                        (info-lookup-change-mode 'file)))))
 587
 588 (defun info-complete (topic mode)
 589   "Try to complete a help item."
 590   (barf-if-buffer-read-only)
 591   (or mode (setq mode (info-lookup-select-mode)))
 592   (or (info-lookup->mode-value topic mode)
 593       (error "No %s completion available for `%s'" topic mode))
 594   (let ((modes (info-lookup-quick-all-modes topic mode))
 595         (start (point))
 596         try)
 597     (while (and (not try) modes)
 598       (setq mode (car modes)
 599             modes (cdr modes)
 600             try (info-lookup-guess-default* topic mode))
 601       (goto-char start))
 602     (and (not try)
 603          (error "Found no %S to complete" topic))
 604     (let ((completions (info-lookup->completions topic mode))
 605           (completion-ignore-case (info-lookup->ignore-case topic mode))
 606           completion)
 607       (setq completion (try-completion try completions))
 608       (cond ((not completion)
 609              (ding)
 610              (message "No match"))
 611             ((stringp completion)
 612              (or (assoc completion completions)
 613                  (setq completion (completing-read
 614                                    (format "Complete %S: " topic)
 615                                    completions nil t completion
 616                                    info-lookup-history)))
 617              ;; Find the original symbol and zap it.
 618              (end-of-line)
 619              (while (and (search-backward try nil t)
 620                          (< start (point))))
 621              (replace-match "")
 622              (insert completion))
 623             (t
 624              (message "%s is complete"
 625                       (capitalize (prin1-to-string topic))))))))
 626
 627 \f
 628 ;;; Initialize some common modes.
 629
 630 (info-lookup-maybe-add-help
 631  :mode 'c-mode :topic 'symbol
 632  :regexp "\\(struct \\|union \\|enum \\)?[_a-zA-Z][_a-zA-Z0-9]*"
 633  :doc-spec '(("(libc)Function Index" nil
 634               "^[ \t]+- \\(Function\\|Macro\\): .*\\<" "\\>")
 635              ("(libc)Variable Index" nil
 636               "^[ \t]+- \\(Variable\\|Macro\\): .*\\<" "\\>")
 637              ("(libc)Type Index" nil
 638               "^[ \t]+- Data Type: \\<" "\\>")
 639              ("(termcap)Var Index" nil
 640               "^[ \t]*`" "'"))
 641  :parse-rule 'info-lookup-guess-c-symbol)
 642
 643 (info-lookup-maybe-add-help
 644  :mode 'c-mode :topic 'file
 645  :regexp "[_a-zA-Z0-9./+-]+"
 646  :doc-spec '(("(libc)File Index")))
 647
 648 (info-lookup-maybe-add-help
 649  :mode 'bison-mode
 650  :regexp "[:;|]\\|%\\([%{}]\\|[_a-z]+\\)\\|YY[_A-Z]+\\|yy[_a-z]+"
 651  :doc-spec '(("(bison)Index" nil
 652               "`" "'"))
 653  :parse-rule "[:;|]\\|%\\([%{}]\\|[_a-zA-Z][_a-zA-Z0-9]*\\)"
 654  :other-modes '(c-mode))
 655
 656 (info-lookup-maybe-add-help
 657  :mode 'makefile-mode
 658  :regexp "\\$[^({]\\|\\.[_A-Z]*\\|[_a-zA-Z][_a-zA-Z0-9-]*"
 659  :doc-spec '(("(make)Name Index" nil
 660               "^[ \t]*`" "'")
 661              ("(automake)Macro and Variable Index" nil
 662               "^[ \t]*`" "'"))
 663  :parse-rule "\\$[^({]\\|\\.[_A-Z]*\\|[_a-zA-Z0-9-]+"
 664  :other-modes '(automake-mode))
 665
 666 (info-lookup-maybe-add-help
 667  :mode 'texinfo-mode
 668  :regexp "@\\([a-zA-Z]+\\|[^a-zA-Z]\\)"
 669  :doc-spec '(("(texinfo)Command and Variable Index"
 670               ;; Ignore Emacs commands and prepend a `@'.
 671               (lambda (item)
 672                 (if (string-match "^\\([a-zA-Z]+\\|[^a-zA-Z]\\)\\( .*\\)?$" item)
 673                     (concat "@" (match-string 1 item))))
 674               "`" "'")))
 675
 676 (info-lookup-maybe-add-help
 677  :mode 'm4-mode
 678  :regexp "[_a-zA-Z][_a-zA-Z0-9]*"
 679  :doc-spec '(("(m4)Macro index"))
 680  :parse-rule "[_a-zA-Z0-9]+")
 681
 682 (info-lookup-maybe-add-help
 683  :mode 'autoconf-mode
 684  :regexp "A[CM]_[_A-Z0-9]+"
 685  :doc-spec '(;; Autoconf Macro Index entries are without an "AC_" prefix,
 686              ;; but with "AH_" or "AU_" for those.  So add "AC_" if there
 687              ;; isn't already an "A._".
 688              ("(autoconf)Autoconf Macro Index"
 689               (lambda (item)
 690                 (if (string-match "^A._" item) item (concat "AC_" item)))
 691               "^[ \t]+- \\(Macro\\|Variable\\): .*\\<" "\\>")
 692              ;; M4 Macro Index entries are without "AS_" prefixes, and
 693              ;; mostly without "m4_" prefixes.  "dnl" is an exception, not
 694              ;; wanting any prefix.  So AS_ is added back to upper-case
 695              ;; names, m4_ to others which don't already an m4_.
 696              ("(autoconf)M4 Macro Index"
 697               (lambda (item)
 698                 (let ((case-fold-search nil))
 699                   (cond ((or (string-equal item "dnl")
 700                              (string-match "^m4_" item))
 701                          item)
 702                         ((string-match "^[A-Z0-9_]+$" item)
 703                          (concat "AS_" item))
 704                         (t
 705                          (concat "m4_" item)))))
 706               "^[ \t]+- Macro: .*\\<" "\\>")
 707              ;; Autotest Macro Index entries are without "AT_".
 708              ("(autoconf)Autotest Macro Index" "AT_"
 709               "^[ \t]+- Macro: .*\\<" "\\>")
 710              ;; This is for older versions (probably pre autoconf 2.5x):
 711              ("(autoconf)Macro Index" "AC_"
 712               "^[ \t]+- \\(Macro\\|Variable\\): .*\\<" "\\>")
 713              ;; Automake has index entries for its notes on various autoconf
 714              ;; macros (eg. AC_PROG_CC).  Ensure this is after the autoconf
 715              ;; index, so as to prefer the autoconf docs.
 716              ("(automake)Macro and Variable Index" nil
 717               "^[ \t]*`" "'"))
 718  ;; Autoconf symbols are M4 macros.  Thus use M4's parser.
 719  :parse-rule 'ignore
 720  :other-modes '(m4-mode))
 721
 722 (info-lookup-maybe-add-help
 723  :mode 'awk-mode
 724  :regexp "[_a-zA-Z]+"
 725  :doc-spec '(("(gawk)Index"
 726               (lambda (item)
 727                 (let ((case-fold-search nil))
 728                   (cond
 729                    ;; `BEGIN' and `END'.
 730                    ((string-match "^\\([A-Z]+\\) special pattern\\b" item)
 731                     (match-string 1 item))
 732                    ;; `if', `while', `do', ...
 733                    ((string-match "^\\([a-z]+\\) statement\\b" item)
 734                     (if (not (string-equal (match-string 1 item) "control"))
 735                         (match-string 1 item)))
 736                    ;; `NR', `NF', ...
 737                    ((string-match "^[A-Z]+$" item)
 738                     item)
 739                    ;; Built-in functions (matches to many entries).
 740                    ((string-match "^[a-z]+$" item)
 741                     item))))
 742               "`" "\\([ \t]*([^)]*)\\)?'")))
 743
 744 (info-lookup-maybe-add-help
 745  :mode 'perl-mode
 746  :regexp "[$@%][^a-zA-Z]\\|\\$\\^[A-Z]\\|[$@%]?[a-zA-Z][_a-zA-Z0-9]*"
 747  :doc-spec '(("(perl5)Function Index"
 748               (lambda (item)
 749                 (if (string-match "^\\([a-zA-Z0-9]+\\)" item)
 750                     (match-string 1 item)))
 751               "^" "\\b")
 752              ("(perl5)Variable Index"
 753               (lambda (item)
 754                 ;; Work around bad formatted array variables.
 755                 (let ((sym (cond ((or (string-match "^\\$\\(.\\|@@\\)$" item)
 756                                       (string-match "^\\$\\^[A-Z]$" item))
 757                                   item)
 758                                  ((string-match
 759                                    "^\\([$%@]\\|@@\\)?[_a-zA-Z0-9]+" item)
 760                                   (match-string 0 item))
 761                                  (t ""))))
 762                   (if (string-match "@@" sym)
 763                       (setq sym (concat (substring sym 0 (match-beginning 0))
 764                                         (substring sym (1- (match-end 0))))))
 765                   (if (string-equal sym "") nil sym)))
 766               "^" "\\b"))
 767  :parse-rule "[$@%]?\\([_a-zA-Z0-9]+\\|[^a-zA-Z]\\)")
 768
 769 (info-lookup-maybe-add-help
 770  :mode 'cperl-mode
 771  :regexp "[$@%][^a-zA-Z]\\|\\$\\^[A-Z]\\|[$@%]?[a-zA-Z][_a-zA-Z0-9]*"
 772  :other-modes '(perl-mode))
 773
 774 (info-lookup-maybe-add-help
 775  :mode 'latex-mode
 776  :regexp "\\\\\\([a-zA-Z]+\\|[^a-zA-Z]\\)"
 777  :doc-spec '(("(latex)Command Index" nil
 778               "`" "\\({[^}]*}\\)?'")))
 779
 780 (info-lookup-maybe-add-help
 781  :mode 'emacs-lisp-mode
 782  :regexp "[^][()'\" \t\n]+"
 783  :doc-spec '(;; Commands with key sequences appear in nodes as `foo' and
 784              ;; those without as `M-x foo'.
 785              ("(emacs)Command Index"  nil "`\\(M-x[ \t\n]+\\)?" "'")
 786              ;; Variables normally appear in nodes as just `foo'.
 787              ("(emacs)Variable Index" nil "`" "'")
 788              ;; Almost all functions, variables, etc appear in nodes as
 789              ;; " - Function: foo" etc.  A small number of aliases and
 790              ;; symbols appear only as `foo', and will miss out on exact
 791              ;; positions.  Allowing `foo' would hit too many false matches
 792              ;; for things that should go to Function: etc, and those latter
 793              ;; are much more important.  Perhaps this could change if some
 794              ;; sort of fallback match scheme existed.
 795              ("(elisp)Index"          nil "^ - .*: " "\\( \\|$\\)")))
 796
 797 (info-lookup-maybe-add-help
 798  :mode 'lisp-interaction-mode
 799  :regexp "[^][()'\" \t\n]+"
 800  :parse-rule 'ignore
 801  :other-modes '(emacs-lisp-mode))
 802
 803 (info-lookup-maybe-add-help
 804  :mode 'lisp-mode
 805  :regexp "[^()'\" \t\n]+"
 806  :parse-rule 'ignore
 807  :other-modes '(emacs-lisp-mode))
 808
 809 (info-lookup-maybe-add-help
 810  :mode 'scheme-mode
 811  :regexp "[^()`',\" \t\n]+"
 812  :ignore-case t
 813  ;; Aubrey Jaffer's rendition from <URL:ftp://ftp-swiss.ai.mit.edu/pub/scm>
 814  :doc-spec '(("(r5rs)Index" nil
 815               "^[ \t]+- [^:]+:[ \t]*" "\\b")))
 816
 817 (info-lookup-maybe-add-help
 818  :mode 'octave-mode
 819  :regexp "[_a-zA-Z0-9]+"
 820  :doc-spec '(("(octave)Function Index" nil
 821               "^ - [^:]+:[ ]+\\(\\[[^=]*=[ ]+\\)?" nil)
 822              ("(octave)Variable Index" nil "^ - [^:]+:[ ]+" nil)
 823              ;; Catch lines of the form "xyz statement"
 824              ("(octave)Concept Index"
 825               (lambda (item)
 826                 (cond
 827                  ((string-match "^\\([A-Z]+\\) statement\\b" item)
 828                     (match-string 1 item))
 829                  (t nil)))
 830               nil; "^ - [^:]+:[ ]+" don't think this prefix is useful here.
 831               nil)))
 832
 833 (info-lookup-maybe-add-help
 834  :mode 'maxima-mode
 835  :ignore-case t
 836  :regexp "[a-zA-Z_%]+"
 837  :doc-spec '( ("(maxima)Function and Variable Index" nil
 838                "^ - [^:]+:[ ]+\\(\\[[^=]*=[ ]+\\)?" nil)))
 839
 840 (info-lookup-maybe-add-help
 841  :mode 'inferior-maxima-mode
 842  :other-modes '(maxima-mode))
 843
 844 ;; coreutils and bash builtins overlap in places, eg. printf, so there's a
 845 ;; question which should come first.  Some of the coreutils descriptions are
 846 ;; more detailed, but if bash is usually /bin/sh on a GNU system then the
 847 ;; builtins will be what's normally run.
 848 ;;
 849 ;; Maybe special variables like $? should be matched as $?, not just ?.
 850 ;; This would avoid a clash between variable $! and negation !, or variable
 851 ;; $# and comment # (though comment # is not currently indexed in bash).
 852 ;; Unfortunately if $? etc is the symbol, then we wouldn't be taken to the
 853 ;; exact spot in the relevant node, since the bash manual has just `?' etc
 854 ;; there.  Maybe an extension to the prefix/suffix scheme could help this.
 855
 856 (info-lookup-maybe-add-help
 857  :mode 'sh-mode :topic 'symbol
 858  ;; bash has "." and ":" in its index, but those chars will probably never
 859  ;; work in info, so don't bother matching them in the regexp.
 860  :regexp "\\([a-zA-Z0-9_-]+\\|[!{}@*#?$]\\|\\[\\[?\\|]]?\\)"
 861  :doc-spec '(("(bash)Builtin Index"       nil "^`" "[ .']")
 862              ("(bash)Reserved Word Index" nil "^`" "[ .']")
 863              ("(bash)Variable Index"      nil "^`" "[ .']")
 864              ;; coreutils (version 4.5.10) doesn't have a separate program
 865              ;; index, so exclude extraneous stuff (most of it) by demanding
 866              ;; "[a-z]+" in the trans-func.
 867              ("(coreutils)Index"
 868               (lambda (item) (if (string-match "\\`[a-z]+\\'" item) item)))
 869              ;; diff (version 2.8.1) has only a few programs, index entries
 870              ;; are things like "foo invocation".
 871              ("(diff)Index"
 872               (lambda (item)
 873                 (if (string-match "\\`\\([a-z]+\\) invocation\\'" item)
 874                     (match-string 1 item))))
 875              ;; there's no plain "sed" index entry as such, mung another
 876              ;; hopefully unique one to get to the invocation section
 877              ("(sed)Concept Index"
 878               (lambda (item)
 879                 (if (string-equal item "Standard input, processing as input")
 880                     "sed")))
 881              ;; there's no plain "awk" or "gawk" index entries, mung other
 882              ;; hopefully unique ones to get to the command line options
 883              ("(gawk)Index"
 884               (lambda (item)
 885                 (cond ((string-equal item "gawk, extensions, disabling")
 886                        "awk")
 887                       ((string-equal item "gawk, versions of, information about, printing")
 888                        "gawk"))))))
 889
 890 ;; This misses some things which occur as node names but not in the
 891 ;; index.  Unfortunately it also picks up the wrong one of multiple
 892 ;; entries for the same term in some cases.  --fx
 893 (info-lookup-maybe-add-help
 894  :mode 'cfengine-mode
 895  :regexp "[[:alnum:]_]+\\(:?()\\)?"
 896  :doc-spec '(("(cfengine-Reference)Variable Index"
 897               (lambda (item)
 898                 ;; Index entries may be like `IsPlain()'
 899                 (if (string-match "\\([[:alnum:]_]+\\)()" item)
 900                     (match-string 1 item)
 901                   item))
 902               ;; This gets functions in evaluated classes.  Other
 903               ;; possible patterns don't seem to work too well.
 904               "`" "(")))
 905 \f
 906 (provide 'info-look)
 907
 908 ;;; arch-tag: 0f1e3ea3-32a2-4461-bbab-3cff93539a74
 909 ;;; info-look.el ends here