lisp/autorevert.el

   1 ;;; autorevert.el --- revert buffers when files on disk change
   2
   3 ;; Copyright (C) 1997, 1998, 1999, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Anders Lindgren <andersl@andersl.com>
   6 ;; Keywords: convenience
   7 ;; Created: 1997-06-01
   8 ;; Date: 1999-11-30
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Introduction:
  30 ;;
  31 ;; Whenever a file that Emacs is editing has been changed by another
  32 ;; program the user normally has to execute the command `revert-buffer'
  33 ;; to load the new content of the file into Emacs.
  34 ;;
  35 ;; This package contains two minor modes: Global Auto-Revert Mode and
  36 ;; Auto-Revert Mode.  Both modes automatically revert buffers
  37 ;; whenever the corresponding files have been changed on disk.
  38 ;;
  39 ;; Auto-Revert Mode can be activated for individual buffers.  Global
  40 ;; Auto-Revert Mode applies to all file buffers. (If the user option
  41 ;; `global-auto-revert-non-file-buffers' is non-nil, it also applies
  42 ;; to some non-file buffers.  This option is disabled by default.)
  43 ;; Since checking a remote file is too slow, these modes do not check
  44 ;; or revert remote files.
  45 ;;
  46 ;; Both modes operate by checking the time stamp of all files at
  47 ;; intervals of `auto-revert-interval'.  The default is every five
  48 ;; seconds.  The check is aborted whenever the user actually uses
  49 ;; Emacs.  You should never even notice that this package is active
  50 ;; (except that your buffers will be reverted, of course).
  51 ;;
  52 ;; After reverting a file buffer, Auto Revert Mode normally puts point
  53 ;; at the same position that a regular manual revert would.  However,
  54 ;; there is one exception to this rule.  If point is at the end of the
  55 ;; buffer before reverting, it stays at the end.  Similarly if point
  56 ;; is displayed at the end of a file buffer in any window, it will stay
  57 ;; at the end of the buffer in that window, even if the window is not
  58 ;; selected.  This way, you can use Auto Revert Mode to `tail' a file.
  59 ;; Just put point at the end of the buffer and it will stay there.
  60 ;; These rules apply to file buffers. For non-file buffers, the
  61 ;; behavior may be mode dependent.
  62
  63 ;; Usage:
  64 ;;
  65 ;; Go to the appropriate buffer and press:
  66 ;;   M-x auto-revert-mode RET
  67 ;;
  68 ;; To activate Global Auto-Revert Mode, press:
  69 ;;   M-x global-auto-revert-mode RET
  70 ;;
  71 ;; To activate Global Auto-Revert Mode every time Emacs is started
  72 ;; customise the option `global-auto-revert-mode' or the following
  73 ;; line could be added to your ~/.emacs:
  74 ;;   (global-auto-revert-mode 1)
  75 ;;
  76 ;; The function `turn-on-auto-revert-mode' could be added to any major
  77 ;; mode hook to activate Auto-Revert Mode for all buffers in that
  78 ;; mode.  For example, the following line will activate Auto-Revert
  79 ;; Mode in all C mode buffers:
  80 ;;
  81 ;; (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)
  82
  83 ;;; Code:
  84
  85 ;; Dependencies:
  86
  87 (require 'timer)
  88
  89 (eval-when-compile (require 'cl))
  90
  91
  92 ;; Custom Group:
  93 ;;
  94 ;; The two modes will be placed next to Auto Save Mode under the
  95 ;; Files group under Emacs.
  96
  97 (defgroup auto-revert nil
  98   "Revert individual buffers when files on disk change.
  99
 100 Auto-Revert Mode can be activated for individual buffer.
 101 Global Auto-Revert Mode applies to all buffers."
 102   :group 'files
 103   :group 'convenience)
 104
 105
 106 ;; Variables:
 107
 108 ;; Autoload for the benefit of `make-mode-line-mouse-sensitive'.
 109 ;;;###autoload
 110 (defvar auto-revert-mode nil
 111   "*Non-nil when Auto-Revert Mode is active.
 112 Never set this variable directly, use the command `auto-revert-mode' instead.")
 113 (put 'auto-revert-mode 'permanent-local t)
 114
 115 (defvar auto-revert-timer nil
 116   "Timer used by Auto-Revert Mode.")
 117
 118 (defcustom auto-revert-interval 5
 119   "Time, in seconds, between Auto-Revert Mode file checks.
 120 The value may be an integer or floating point number.
 121
 122 If a timer is already active, there are two ways to make sure
 123 that the new value will take effect immediately.  You can set
 124 this variable through Custom or you can call the command
 125 `auto-revert-set-timer' after setting the variable.  Otherwise,
 126 the new value will take effect the first time Auto Revert Mode
 127 calls `auto-revert-set-timer' for internal reasons or in your
 128 next editing session."
 129   :group 'auto-revert
 130   :type 'number
 131   :set (lambda (variable value)
 132          (set-default variable value)
 133          (and (boundp 'auto-revert-timer)
 134               auto-revert-timer
 135               (auto-revert-set-timer))))
 136
 137 (defcustom auto-revert-stop-on-user-input t
 138   "When non-nil Auto-Revert Mode stops checking files on user input."
 139   :group 'auto-revert
 140   :type 'boolean)
 141
 142 (defcustom auto-revert-verbose t
 143   "When nil, Auto-Revert Mode will not generate any messages.
 144 When non-nil, a message is generated whenever a file is reverted."
 145   :group 'auto-revert
 146   :type 'boolean)
 147
 148 (defcustom auto-revert-mode-text " ARev"
 149   "String to display in the mode line when Auto-Revert Mode is active.
 150
 151 \(When the string is not empty, make sure that it has a leading space.)"
 152   :tag "Auto Revert Mode Text"          ; To separate it from `global-...'
 153   :group 'auto-revert
 154   :type 'string)
 155
 156 (defcustom auto-revert-mode-hook nil
 157   "Functions to run when Auto-Revert Mode is activated."
 158   :tag "Auto Revert Mode Hook"          ; To separate it from `global-...'
 159   :group 'auto-revert
 160   :type 'hook)
 161
 162 (defcustom global-auto-revert-mode-text ""
 163   "String to display when Global Auto-Revert Mode is active.
 164
 165 The default is nothing since when this mode is active this text doesn't
 166 vary over time, or between buffers.  Hence mode line text
 167 would only waste precious space."
 168   :group 'auto-revert
 169   :type 'string)
 170
 171 (defcustom global-auto-revert-mode-hook nil
 172   "Hook called when Global Auto-Revert Mode is activated."
 173   :group 'auto-revert
 174   :type 'hook)
 175
 176 (defcustom global-auto-revert-non-file-buffers nil
 177   "When nil, Global Auto-Revert mode operates only on file-visiting buffers.
 178
 179 When non-nil, both file buffers and buffers with a custom
 180 `revert-buffer-function' and a `buffer-stale-function' are
 181 reverted by Global Auto-Revert mode.  These include the Buffer
 182 List buffer, and Dired buffers showing complete local
 183 directories.  Dired buffers do not auto-revert as a result of
 184 changes in subdirectories or in the contents, size, modes, etc.,
 185 of files.  You may still sometimes want to revert them manually.
 186
 187 Use this option with care since it could lead to excessive auto-reverts.
 188 For more information, see Info node `(emacs-xtra)Autorevert'."
 189   :group 'auto-revert
 190   :type 'boolean
 191   :link '(info-link "(emacs-xtra)Autorevert"))
 192
 193 (defcustom global-auto-revert-ignore-modes '()
 194   "List of major modes Global Auto-Revert Mode should not check."
 195   :group 'auto-revert
 196   :type '(repeat sexp))
 197
 198 (defcustom auto-revert-load-hook nil
 199   "Functions to run when Auto-Revert Mode is first loaded."
 200   :tag "Load Hook"
 201   :group 'auto-revert
 202   :type 'hook)
 203
 204 (defcustom auto-revert-check-vc-info nil
 205   "If non-nil Auto Revert Mode reliably updates version control info.
 206 Auto Revert Mode updates version control info whenever the buffer
 207 needs reverting, regardless of the value of this variable.
 208 However, the version control state can change without changes to
 209 the work file.  If the change is made from the current Emacs
 210 session, all info is updated.  But if, for instance, a new
 211 version is checked in from outside the current Emacs session, the
 212 version control number in the mode line, as well as other version
 213 control related information, may not be properly updated.  If you
 214 are worried about this, set this variable to a non-nil value.
 215
 216 This currently works by automatically updating the version
 217 control info every `auto-revert-interval' seconds.  Nevertheless,
 218 it should not cause excessive CPU usage on a reasonably fast
 219 machine, if it does not apply to too many version controlled
 220 buffers.  CPU usage depends on the version control system"
 221   :group 'auto-revert
 222   :type 'boolean
 223   :version "21.4")
 224
 225 (defvar global-auto-revert-ignore-buffer nil
 226   "*When non-nil, Global Auto-Revert Mode will not revert this buffer.
 227
 228 This variable becomes buffer local when set in any fashion.")
 229 (make-variable-buffer-local 'global-auto-revert-ignore-buffer)
 230
 231 ;; Internal variables:
 232
 233 (defvar auto-revert-buffer-list '()
 234   "List of buffers in Auto-Revert Mode.
 235
 236 Note that only Auto-Revert Mode, never Global Auto-Revert Mode, adds
 237 buffers to this list.
 238
 239 The timer function `auto-revert-buffers' is responsible for purging
 240 the list of old buffers.")
 241
 242 (defvar auto-revert-remaining-buffers '()
 243   "Buffers not checked when user input stopped execution.")
 244
 245
 246 ;; Functions:
 247
 248 ;;;###autoload
 249 (define-minor-mode auto-revert-mode
 250   "Toggle reverting buffer when file on disk changes.
 251
 252 With arg, turn Auto Revert mode on if and only if arg is positive.
 253 This is a minor mode that affects only the current buffer.
 254 Use `global-auto-revert-mode' to automatically revert all buffers."
 255   nil auto-revert-mode-text nil
 256   (if auto-revert-mode
 257       (if (not (memq (current-buffer) auto-revert-buffer-list))
 258           (push (current-buffer) auto-revert-buffer-list))
 259     (setq auto-revert-buffer-list
 260           (delq (current-buffer) auto-revert-buffer-list)))
 261   (auto-revert-set-timer)
 262   (when auto-revert-mode
 263     (auto-revert-buffers)))
 264
 265
 266 ;;;###autoload
 267 (defun turn-on-auto-revert-mode ()
 268   "Turn on Auto-Revert Mode.
 269
 270 This function is designed to be added to hooks, for example:
 271   (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)"
 272   (auto-revert-mode 1))
 273
 274
 275 ;;;###autoload
 276 (define-minor-mode global-auto-revert-mode
 277   "Revert any buffer when file on disk changes.
 278
 279 With arg, turn Auto Revert mode on globally if and only if arg is positive.
 280 This is a minor mode that affects all buffers.
 281 Use `auto-revert-mode' to revert a particular buffer."
 282   :global t :group 'auto-revert :lighter global-auto-revert-mode-text
 283   (auto-revert-set-timer)
 284   (when global-auto-revert-mode
 285     (auto-revert-buffers)))
 286
 287
 288 (defun auto-revert-set-timer ()
 289   "Restart or cancel the timer used by Auto-Revert Mode.
 290 If such a timer is active, cancel it.  Start a new timer if
 291 Global Auto-Revert Mode is active or if Auto-Revert Mode is active
 292 in some buffer.  Restarting the timer ensures that Auto-Revert Mode
 293 will use an up-to-date value of `auto-revert-interval'"
 294   (interactive)
 295   (if (timerp auto-revert-timer)
 296       (cancel-timer auto-revert-timer))
 297   (setq auto-revert-timer
 298         (if (or global-auto-revert-mode auto-revert-buffer-list)
 299             (run-with-timer auto-revert-interval
 300                             auto-revert-interval
 301                             'auto-revert-buffers)
 302           nil)))
 303
 304 (defun auto-revert-active-p ()
 305   "Check if auto-revert is active (in current buffer or globally)."
 306   (or auto-revert-mode
 307       (and
 308        global-auto-revert-mode
 309        (not global-auto-revert-ignore-buffer)
 310        (not (memq major-mode
 311                   global-auto-revert-ignore-modes)))))
 312
 313 (defun auto-revert-handler ()
 314   "Revert current buffer, if appropriate.
 315 This is an internal function used by Auto-Revert Mode."
 316   (unless (buffer-modified-p)
 317     (let ((buffer (current-buffer)) revert eob eoblist)
 318       (or (and buffer-file-name
 319                (not (file-remote-p buffer-file-name))
 320                (file-readable-p buffer-file-name)
 321                (not (verify-visited-file-modtime buffer))
 322                (setq revert t))
 323           (and (or auto-revert-mode global-auto-revert-non-file-buffers)
 324                revert-buffer-function
 325                (boundp 'buffer-stale-function)
 326                (functionp buffer-stale-function)
 327                (setq revert (funcall buffer-stale-function t))))
 328       (when revert
 329         (when (and auto-revert-verbose
 330                    (not (eq revert 'fast)))
 331           (message "Reverting buffer `%s'." (buffer-name)))
 332         ;; If point (or a window point) is at the end of the buffer,
 333         ;; we want to keep it at the end after reverting.  This allows
 334         ;; to tail a file.
 335         (when buffer-file-name
 336           (setq eob (eobp))
 337           (walk-windows
 338            #'(lambda (window)
 339                (and (eq (window-buffer window) buffer)
 340                     (= (window-point window) (point-max))
 341                     (push window eoblist)))
 342            'no-mini t))
 343         (revert-buffer 'ignore-auto 'dont-ask 'preserve-modes)
 344         (when buffer-file-name
 345           (when eob (goto-char (point-max)))
 346           (dolist (window eoblist)
 347             (set-window-point window (point-max)))))
 348       ;; `preserve-modes' avoids changing the (minor) modes.  But we
 349       ;; do want to reset the mode for VC, so we do it manually.
 350       (when (or revert auto-revert-check-vc-info)
 351         (vc-find-file-hook)))))
 352
 353 (defun auto-revert-buffers ()
 354   "Revert buffers as specified by Auto-Revert and Global Auto-Revert Mode.
 355
 356 Should `global-auto-revert-mode' be active all file buffers are checked.
 357
 358 Should `auto-revert-mode' be active in some buffers, those buffers
 359 are checked.
 360
 361 Non-file buffers that have a custom `revert-buffer-function' and
 362 a `buffer-stale-function' are reverted either when Auto-Revert
 363 Mode is active in that buffer, or when the variable
 364 `global-auto-revert-non-file-buffers' is non-nil and Global
 365 Auto-Revert Mode is active.
 366
 367 This function stops whenever there is user input.  The buffers not
 368 checked are stored in the variable `auto-revert-remaining-buffers'.
 369
 370 To avoid starvation, the buffers in `auto-revert-remaining-buffers'
 371 are checked first the next time this function is called.
 372
 373 This function is also responsible for removing buffers no longer in
 374 Auto-Revert mode from `auto-revert-buffer-list', and for canceling
 375 the timer when no buffers need to be checked."
 376   (let ((bufs (if global-auto-revert-mode
 377                   (buffer-list)
 378                 auto-revert-buffer-list))
 379         (remaining '())
 380         (new '()))
 381     ;; Partition `bufs' into two halves depending on whether or not
 382     ;; the buffers are in `auto-revert-remaining-buffers'.  The two
 383     ;; halves are then re-joined with the "remaining" buffers at the
 384     ;; head of the list.
 385     (dolist (buf auto-revert-remaining-buffers)
 386       (if (memq buf bufs)
 387           (push buf remaining)))
 388     (dolist (buf bufs)
 389       (if (not (memq buf remaining))
 390           (push buf new)))
 391     (setq bufs (nreverse (nconc new remaining)))
 392     (while (and bufs
 393                 (not (and auto-revert-stop-on-user-input
 394                           (input-pending-p))))
 395       (let ((buf (car bufs)))
 396         (if (buffer-name buf)           ; Buffer still alive?
 397             (with-current-buffer buf
 398               ;; Test if someone has turned off Auto-Revert Mode in a
 399               ;; non-standard way, for example by changing major mode.
 400               (if (and (not auto-revert-mode)
 401                        (memq buf auto-revert-buffer-list))
 402                   (setq auto-revert-buffer-list
 403                         (delq buf auto-revert-buffer-list)))
 404               (when (auto-revert-active-p) (auto-revert-handler)))
 405           ;; Remove dead buffer from `auto-revert-buffer-list'.
 406           (setq auto-revert-buffer-list
 407                 (delq buf auto-revert-buffer-list))))
 408       (setq bufs (cdr bufs)))
 409     (setq auto-revert-remaining-buffers bufs)
 410     ;; Check if we should cancel the timer.
 411     (when (and (not global-auto-revert-mode)
 412                (null auto-revert-buffer-list))
 413       (cancel-timer auto-revert-timer)
 414       (setq auto-revert-timer nil))))
 415
 416
 417 ;; The end:
 418 (provide 'autorevert)
 419
 420 (run-hooks 'auto-revert-load-hook)
 421
 422 ;;; arch-tag: f6bcb07b-4841-477e-9e44-b18678e58876
 423 ;;; autorevert.el ends here