lisp/abbrev.el

   1 ;;; abbrev.el --- abbrev mode commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1992 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: abbrev convenience
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This facility is documented in the Emacs Manual.
  28
  29 ;;; Code:
  30
  31 (defcustom only-global-abbrevs nil
  32   "*t means user plans to use global abbrevs only.
  33 This makes the commands that normally define mode-specific abbrevs
  34 define global abbrevs instead."
  35   :type 'boolean
  36   :group 'abbrev-mode
  37   :group 'convenience)
  38
  39 (defun abbrev-mode (&optional arg)
  40   "Toggle Abbrev mode in the current buffer.
  41 With argument ARG, turn abbrev mode on iff ARG is positive.
  42 In Abbrev mode, inserting an abbreviation causes it to expand
  43 and be replaced by its expansion."
  44   (interactive "P")
  45   (setq abbrev-mode
  46         (if (null arg) (not abbrev-mode)
  47           (> (prefix-numeric-value arg) 0)))
  48   (force-mode-line-update))
  49
  50 (defcustom abbrev-mode nil
  51   "Enable or disable Abbrev mode.
  52 Non-nil means automatically expand abbrevs as they are inserted.
  53
  54 Setting this variable with `setq' changes it for the current buffer.
  55 Changing it with \\[customize] sets the default value.
  56 Interactively, use the command `abbrev-mode'
  57 to enable or disable Abbrev mode in the current buffer."
  58   :type 'boolean
  59   :group 'abbrev-mode)
  60
  61 \f
  62 (defvar edit-abbrevs-map nil
  63   "Keymap used in `edit-abbrevs'.")
  64 (if edit-abbrevs-map
  65     nil
  66   (setq edit-abbrevs-map (make-sparse-keymap))
  67   (define-key edit-abbrevs-map "\C-x\C-s" 'edit-abbrevs-redefine)
  68   (define-key edit-abbrevs-map "\C-c\C-c" 'edit-abbrevs-redefine))
  69
  70 (defun kill-all-abbrevs ()
  71   "Undefine all defined abbrevs."
  72   (interactive)
  73   (let ((tables abbrev-table-name-list))
  74     (while tables
  75       (clear-abbrev-table (symbol-value (car tables)))
  76       (setq tables (cdr tables)))))
  77
  78 (defun copy-abbrev-table (table)
  79   "Make a new abbrev-table with the same abbrevs as TABLE."
  80   (let ((new-table (make-abbrev-table)))
  81     (mapatoms
  82      (lambda (symbol)
  83        (define-abbrev new-table
  84          (symbol-name symbol)
  85          (symbol-value symbol)
  86          (symbol-function symbol)))
  87      table)
  88     new-table))
  89
  90 (defun insert-abbrevs ()
  91   "Insert after point a description of all defined abbrevs.
  92 Mark is set after the inserted text."
  93   (interactive)
  94   (push-mark
  95    (save-excursion
  96     (let ((tables abbrev-table-name-list))
  97       (while tables
  98         (insert-abbrev-table-description (car tables) t)
  99         (setq tables (cdr tables))))
 100     (point))))
 101
 102 (defun list-abbrevs (&optional local)
 103   "Display a list of defined abbrevs.
 104 If LOCAL is non-nil, interactively when invoked with a
 105 prefix arg, display only local, i.e. mode-specific, abbrevs.
 106 Otherwise display all abbrevs."
 107   (interactive "P")
 108   (display-buffer (prepare-abbrev-list-buffer local)))
 109
 110 (defun abbrev-table-name (table)
 111   "Value is the name of abbrev table TABLE."
 112   (let ((tables abbrev-table-name-list)
 113         found)
 114     (while (and (not found) tables)
 115       (when (eq (symbol-value (car tables)) table)
 116         (setq found (car tables)))
 117       (setq tables (cdr tables)))
 118     found))
 119
 120 (defun prepare-abbrev-list-buffer (&optional local)
 121   (save-excursion
 122     (let ((table local-abbrev-table))
 123       (set-buffer (get-buffer-create "*Abbrevs*"))
 124       (erase-buffer)
 125       (if local
 126           (insert-abbrev-table-description (abbrev-table-name table) t)
 127         (dolist (table abbrev-table-name-list)
 128           (insert-abbrev-table-description table t)))
 129       (goto-char (point-min))
 130       (set-buffer-modified-p nil)
 131       (edit-abbrevs-mode)
 132       (current-buffer))))
 133
 134 (defun edit-abbrevs-mode ()
 135   "Major mode for editing the list of abbrev definitions.
 136 \\{edit-abbrevs-map}"
 137   (interactive)
 138   (setq major-mode 'edit-abbrevs-mode)
 139   (setq mode-name "Edit-Abbrevs")
 140   (use-local-map edit-abbrevs-map))
 141
 142 (defun edit-abbrevs ()
 143   "Alter abbrev definitions by editing a list of them.
 144 Selects a buffer containing a list of abbrev definitions.
 145 You can edit them and type \\<edit-abbrevs-map>\\[edit-abbrevs-redefine] to redefine abbrevs
 146 according to your editing.
 147 Buffer contains a header line for each abbrev table,
 148  which is the abbrev table name in parentheses.
 149 This is followed by one line per abbrev in that table:
 150 NAME   USECOUNT   EXPANSION   HOOK
 151 where NAME and EXPANSION are strings with quotes,
 152 USECOUNT is an integer, and HOOK is any valid function
 153 or may be omitted (it is usually omitted)."
 154   (interactive)
 155   (switch-to-buffer (prepare-abbrev-list-buffer)))
 156
 157 (defun edit-abbrevs-redefine ()
 158   "Redefine abbrevs according to current buffer contents."
 159   (interactive)
 160   (define-abbrevs t)
 161   (set-buffer-modified-p nil))
 162
 163 (defun define-abbrevs (&optional arg)
 164   "Define abbrevs according to current visible buffer contents.
 165 See documentation of `edit-abbrevs' for info on the format of the
 166 text you must have in the buffer.
 167 With argument, eliminate all abbrev definitions except
 168 the ones defined from the buffer now."
 169   (interactive "P")
 170   (if arg (kill-all-abbrevs))
 171   (save-excursion
 172    (goto-char (point-min))
 173    (while (and (not (eobp)) (re-search-forward "^(" nil t))
 174      (let* ((buf (current-buffer))
 175             (table (read buf))
 176             abbrevs name hook exp count)
 177        (forward-line 1)
 178        (while (progn (forward-line 1)
 179                      (not (eolp)))
 180          (setq name (read buf) count (read buf) exp (read buf))
 181          (skip-chars-backward " \t\n\f")
 182          (setq hook (if (not (eolp)) (read buf)))
 183          (skip-chars-backward " \t\n\f")
 184          (setq abbrevs (cons (list name exp hook count) abbrevs)))
 185        (define-abbrev-table table abbrevs)))))
 186
 187 (defun read-abbrev-file (&optional file quietly)
 188   "Read abbrev definitions from file written with `write-abbrev-file'.
 189 Optional argument FILE is the name of the file to read;
 190 it defaults to the value of `abbrev-file-name'.
 191 Optional second argument QUIETLY non-nil means don't display a message."
 192   (interactive "fRead abbrev file: ")
 193   (load (if (and file (> (length file) 0)) file abbrev-file-name)
 194         nil quietly)
 195   (setq abbrevs-changed nil))
 196
 197 (defun quietly-read-abbrev-file (&optional file)
 198   "Read abbrev definitions from file written with write-abbrev-file.
 199 Optional argument FILE is the name of the file to read;
 200 it defaults to the value of `abbrev-file-name'.
 201 Does not display any message."
 202   ;(interactive "fRead abbrev file: ")
 203   (read-abbrev-file file t))
 204
 205 (defun write-abbrev-file (&optional file)
 206   "Write all user-level abbrev definitions to a file of Lisp code.
 207 This does not include system abbrevs; it includes only the abbrev tables
 208 listed in listed in `abbrev-table-name-list'.
 209 The file written can be loaded in another session to define the same abbrevs.
 210 The argument FILE is the file name to write.  If omitted or nil, the file
 211 specified in `abbrev-file-name' is used."
 212   (interactive
 213    (list
 214     (read-file-name "Write abbrev file: "
 215                     (file-name-directory (expand-file-name abbrev-file-name))
 216                     abbrev-file-name)))
 217   (or (and file (> (length file) 0))
 218       (setq file abbrev-file-name))
 219   (let ((coding-system-for-write 'emacs-mule))
 220     (with-temp-file file
 221       (insert ";;-*-coding: emacs-mule;-*-\n")
 222       (dolist (table abbrev-table-name-list)
 223         (insert-abbrev-table-description table nil)))))
 224 \f
 225 (defun add-mode-abbrev (arg)
 226   "Define mode-specific abbrev for last word(s) before point.
 227 Argument is how many words before point form the expansion;
 228 or zero means the region is the expansion.
 229 A negative argument means to undefine the specified abbrev.
 230 Reads the abbreviation in the minibuffer.
 231
 232 Don't use this function in a Lisp program; use `define-abbrev' instead."
 233   (interactive "p")
 234   (add-abbrev
 235    (if only-global-abbrevs
 236        global-abbrev-table
 237      (or local-abbrev-table
 238          (error "No per-mode abbrev table")))
 239    "Mode" arg))
 240
 241 (defun add-global-abbrev (arg)
 242   "Define global (all modes) abbrev for last word(s) before point.
 243 The prefix argument specifies the number of words before point that form the
 244 expansion; or zero means the region is the expansion.
 245 A negative argument means to undefine the specified abbrev.
 246 This command uses the minibuffer to read the abbreviation.
 247
 248 Don't use this function in a Lisp program; use `define-abbrev' instead."
 249   (interactive "p")
 250   (add-abbrev global-abbrev-table "Global" arg))
 251
 252 (defun add-abbrev (table type arg)
 253   (let ((exp (and (>= arg 0)
 254                   (buffer-substring-no-properties
 255                    (point)
 256                    (if (= arg 0) (mark)
 257                      (save-excursion (forward-word (- arg)) (point))))))
 258         name)
 259     (setq name
 260           (read-string (format (if exp "%s abbrev for \"%s\": "
 261                                  "Undefine %s abbrev: ")
 262                                type exp)))
 263     (set-text-properties 0 (length name) nil name)
 264     (if (or (null exp)
 265             (not (abbrev-expansion name table))
 266             (y-or-n-p (format "%s expands to \"%s\"; redefine? "
 267                               name (abbrev-expansion name table))))
 268         (define-abbrev table (downcase name) exp))))
 269
 270 (defun inverse-add-mode-abbrev (arg)
 271   "Define last word before point as a mode-specific abbrev.
 272 With prefix argument N, defines the Nth word before point.
 273 This command uses the minibuffer to read the expansion.
 274 Expands the abbreviation after defining it."
 275   (interactive "p")
 276   (inverse-add-abbrev
 277    (if only-global-abbrevs
 278        global-abbrev-table
 279      (or local-abbrev-table
 280          (error "No per-mode abbrev table")))
 281    "Mode" arg))
 282
 283 (defun inverse-add-global-abbrev (arg)
 284   "Define last word before point as a global (mode-independent) abbrev.
 285 With prefix argument N, defines the Nth word before point.
 286 This command uses the minibuffer to read the expansion.
 287 Expands the abbreviation after defining it."
 288   (interactive "p")
 289   (inverse-add-abbrev global-abbrev-table "Global" arg))
 290
 291 (defun inverse-add-abbrev (table type arg)
 292   (let (name exp start end)
 293     (save-excursion
 294       (forward-word (1+ (- arg)))
 295       (setq end (point))
 296       (backward-word 1)
 297       (setq start (point)
 298             name (buffer-substring-no-properties start end)))
 299
 300     (setq exp (read-string (format "%s expansion for \"%s\": " type name)
 301                            nil nil nil t))
 302     (when (or (not (abbrev-expansion name table))
 303               (y-or-n-p (format "%s expands to \"%s\"; redefine? "
 304                                 name (abbrev-expansion name table))))
 305       (define-abbrev table (downcase name) exp)
 306       (save-excursion
 307         (goto-char end)
 308         (expand-abbrev)))))
 309
 310 (defun abbrev-prefix-mark (&optional arg)
 311   "Mark current point as the beginning of an abbrev.
 312 Abbrev to be expanded starts here rather than at beginning of word.
 313 This way, you can expand an abbrev with a prefix: insert the prefix,
 314 use this command, then insert the abbrev.  This command inserts a
 315 temporary hyphen after the prefix \(until the intended abbrev
 316 expansion occurs).
 317 If the prefix is itself an abbrev, this command expands it, unless
 318 ARG is non-nil.  Interactively, ARG is the prefix argument."
 319   (interactive "P")
 320   (or arg (expand-abbrev))
 321   (setq abbrev-start-location (point-marker)
 322         abbrev-start-location-buffer (current-buffer))
 323   (insert "-"))
 324
 325 (defun expand-region-abbrevs (start end &optional noquery)
 326   "For abbrev occurrence in the region, offer to expand it.
 327 The user is asked to type y or n for each occurrence.
 328 A prefix argument means don't query; expand all abbrevs.
 329 If called from a Lisp program, arguments are START END &optional NOQUERY."
 330   (interactive "r\nP")
 331   (save-excursion
 332     (goto-char start)
 333     (let ((lim (- (point-max) end))
 334           pnt string)
 335       (while (and (not (eobp))
 336                   (progn (forward-word 1)
 337                          (<= (setq pnt (point)) (- (point-max) lim))))
 338         (if (abbrev-expansion
 339              (setq string
 340                    (buffer-substring-no-properties
 341                     (save-excursion (forward-word -1) (point))
 342                     pnt)))
 343             (if (or noquery (y-or-n-p (format "Expand `%s'? " string)))
 344                 (expand-abbrev)))))))
 345
 346 ;;; arch-tag: dbd6f3ae-dfe3-40ba-b00f-f9e3ff960df5
 347 ;;; abbrev.el ends here