| blob | b3c517fc8beaae211fe7ad0f826e839d19ea991e |
1 dnl Autoconf script for GNU Emacs
2 dnl To rebuild the `configure' script from this, execute the command
3 dnl autoconf
4 dnl in the directory containing this script.
5 dnl
6 dnl Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003
7 dnl Free Software Foundation, Inc.
8 dnl
9 dnl This file is part of GNU Emacs.
10 dnl
11 dnl GNU Emacs is free software; you can redistribute it and/or modify
12 dnl it under the terms of the GNU General Public License as published by
13 dnl the Free Software Foundation; either version 2, or (at your option)
14 dnl any later version.
15 dnl
16 dnl GNU Emacs is distributed in the hope that it will be useful,
17 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
18 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
19 dnl GNU General Public License for more details.
20 dnl
21 dnl You should have received a copy of the GNU General Public License
22 dnl along with GNU Emacs; see the file COPYING. If not, write to the
23 dnl Free Software Foundation, Inc., 59 Temple Place - Suite 330,
24 dnl Boston, MA 02111-1307, USA.
26 AC_PREREQ(2.54)dnl
27 AC_INIT(src/lisp.h)
28 AC_CONFIG_HEADER(src/config.h:src/config.in)
30 dnl Support for --program-prefix, --program-suffix and
31 dnl --program-transform-name options
32 AC_ARG_PROGRAM
34 lispdir='${datadir}/emacs/${version}/lisp'
35 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
36 '${datadir}/emacs/site-lisp:${datadir}/emacs/${version}/leim'
37 lisppath='${locallisppath}:${lispdir}'
38 etcdir='${datadir}/emacs/${version}/etc'
39 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
40 docdir='${datadir}/emacs/${version}/etc'
41 gamedir='${localstatedir}/games/emacs'
43 gameuser=games
45 AC_ARG_WITH(gcc,
46 [ --without-gcc don't use GCC to compile Emacs if GCC is found])
47 AC_ARG_WITH(pop,
48 [ --without-pop don't support POP mail retrieval with movemail],
49 [if test "$withval" = yes; then
50 AC_DEFINE(MAIL_USE_POP)
51 else :
52 fi],
53 AC_DEFINE(MAIL_USE_POP))
54 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
55 AC_ARG_WITH(kerberos,
56 [ --with-kerberos support Kerberos-authenticated POP],
57 [AC_DEFINE(KERBEROS)])
58 AH_TEMPLATE(KERBEROS,
59 [Define to support Kerberos-authenticated POP mail retrieval.])dnl
60 AC_ARG_WITH(kerberos5,
61 [ --with-kerberos5 support Kerberos version 5 authenticated POP],
62 [if test "${with_kerberos5+set}" = set; then
63 if test "${with_kerberos+set}" != set; then
64 with_kerberos=yes
65 AC_DEFINE(KERBEROS)
66 fi
67 fi
68 AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])])
69 AC_ARG_WITH(hesiod,
70 [ --with-hesiod support Hesiod to get the POP server host],
71 [AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])])
73 AC_ARG_WITH(sound,
74 [ --without-sound don't compile with sound support])
76 dnl This should be the last --with option, because --with-x is
77 dnl added later on when we find the path of X, and it's best to
78 dnl keep them together visually.
79 AC_ARG_WITH(x-toolkit,
80 [ --with-x-toolkit=KIT use an X toolkit
81 (KIT = yes/lucid/athena/motif/gtk/no)],
82 [ case "${withval}" in
83 y | ye | yes ) val=athena ;;
84 n | no ) val=no ;;
85 l | lu | luc | luci | lucid ) val=lucid ;;
86 a | at | ath | athe | athen | athena ) val=athena ;;
87 m | mo | mot | moti | motif ) val=motif ;;
88 g | gt | gtk ) val=gtk ;;
89 dnl These don't currently work.
90 dnl o | op | ope | open | open- | open-l | open-lo \
91 dnl | open-loo | open-look ) val=open-look ;;
92 * )
93 dnl AC_MSG_ERROR([the `--with-x-toolkit' option is supposed to have a value
94 dnl which is `yes', `no', `lucid', `athena', `motif' or `open-look'.])
95 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid\;
96 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
97 Currently, `yes', `athena' and `lucid' are synonyms.])
98 ;;
99 esac
100 with_x_toolkit=$val
101 ])
102 AC_ARG_WITH(xpm,
103 [ --with-xpm use -lXpm for displaying XPM images])
104 AC_ARG_WITH(jpeg,
105 [ --with-jpeg use -ljpeg for displaying JPEG images])
106 AC_ARG_WITH(tiff,
107 [ --with-tiff use -ltiff for displaying TIFF images])
108 AC_ARG_WITH(gif,
109 [ --with-gif use -lungif for displaying GIF images])
110 AC_ARG_WITH(png,
111 [ --with-png use -lpng for displaying PNG images])
112 AC_ARG_WITH(gtk,
113 [ --with-gtk use GTK (same as --with-x-toolkit=gtk)])
114 AC_ARG_WITH(pkg-config-prog,
115 [ --with-pkg-config-prog Path to pkg-config to use for finding GTK])
116 AC_ARG_WITH(toolkit-scroll-bars,
117 [ --without-toolkit-scroll-bars
118 don't use Motif or Xaw3d scroll bars])
119 AC_ARG_WITH(xim,
120 [ --without-xim don't use X11 XIM])
121 AC_ARG_WITH(carbon,
122 [ --without-carbon don't use Carbon GUI on Mac OS X])
123 AC_ARG_ENABLE(carbon-app,
124 [[ --enable-carbon-app[=DIR] [DIR=/Application]
125 specify install directory for Emacs.app on Mac OS X]],
126 [ carbon_appdir_x=${enableval}])
128 #### Make srcdir absolute, if it isn't already. It's important to
129 #### avoid running the path through pwd unnecessarily, since pwd can
130 #### give you automounter prefixes, which can go away. We do all this
131 #### so Emacs can find its files when run uninstalled.
132 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
133 unset CDPATH
134 case "${srcdir}" in
135 /* ) ;;
136 . )
137 ## We may be able to use the $PWD environment variable to make this
138 ## absolute. But sometimes PWD is inaccurate.
139 ## Note: we used to use ${PWD} at the end instead of `pwd`,
140 ## but that tested only for a well-formed and valid PWD,
141 ## it did not object when PWD was well-formed and valid but just wrong.
142 if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`" ;
143 then
144 srcdir="$PWD"
145 else
146 srcdir="`(cd ${srcdir}; pwd)`"
147 fi
148 ;;
149 * ) srcdir="`(cd ${srcdir}; pwd)`" ;;
150 esac
152 #### Check if the source directory already has a configured system in it.
153 if test `pwd` != `(cd ${srcdir} && pwd)` \
154 && test -f "${srcdir}/src/config.h" ; then
155 AC_MSG_WARN([[The directory tree `${srcdir}' is being used
156 as a build directory right now; it has been configured in its own
157 right. To configure in another directory as well, you MUST
158 use GNU make. If you do not have GNU make, then you must
159 now do `make distclean' in ${srcdir},
160 and then run $0 again.]])
162 [extrasub='/^VPATH[ ]*=/c\
163 vpath %.c $(srcdir)\
164 vpath %.h $(srcdir)\
165 vpath %.y $(srcdir)\
166 vpath %.l $(srcdir)\
167 vpath %.s $(srcdir)\
168 vpath %.in $(srcdir)\
169 vpath %.texi $(srcdir)']
170 fi
172 #### Given the configuration name, set machfile and opsysfile to the
173 #### names of the m/*.h and s/*.h files we should use.
175 ### Canonicalize the configuration name.
177 AC_CANONICAL_HOST
178 canonical=$host
179 configuration=${host_alias-$host}
181 dnl This used to use changequote, but, apart from `changequote is evil'
182 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
183 dnl the great gob of text. Thus it's not processed for possible expansion.
184 dnl Just make sure the brackets remain balanced.
185 [
187 ### If you add support for a new configuration, add code to this
188 ### switch statement to recognize your configuration name and select
189 ### the appropriate operating system and machine description files.
191 ### You would hope that you could choose an m/*.h file pretty much
192 ### based on the machine portion of the configuration name, and an s-
193 ### file based on the operating system portion. However, it turns out
194 ### that each m/*.h file is pretty manufacturer-specific - for
195 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
196 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
197 ### machines. So we basically have to have a special case for each
198 ### configuration name.
199 ###
200 ### As far as handling version numbers on operating systems is
201 ### concerned, make sure things will fail in a fixable way. If
202 ### /etc/MACHINES doesn't say anything about version numbers, be
203 ### prepared to handle anything reasonably. If version numbers
204 ### matter, be sure /etc/MACHINES says something about it.
205 ###
206 ### Eric Raymond says we should accept strings like "sysvr4" to mean
207 ### "System V Release 4"; he writes, "The old convention encouraged
208 ### confusion between `system' and `release' levels'."
210 machine='' opsys='' unported=no
211 case "${canonical}" in
213 ## FreeBSD ports
214 *-*-freebsd* )
215 opsys=freebsd
216 case "${canonical}" in
217 alpha*-*-freebsd*) machine=alpha ;;
218 i[3456]86-*-freebsd*) machine=intel386 ;;
219 esac
220 ;;
222 ## NetBSD ports
223 *-*-netbsd* )
224 opsys=netbsd
225 case "${canonical}" in
226 alpha*-*-netbsd*) machine=alpha ;;
227 i[3456]86-*-netbsd*) machine=intel386 ;;
228 m68k-*-netbsd*)
229 # This is somewhat bogus.
230 machine=hp9000s300 ;;
231 powerpc-apple-netbsd*) machine=macppc ;;
232 mips-*-netbsd*) machine=pmax ;;
233 mipsel-*-netbsd*) machine=pmax ;;
234 mipseb-*-netbsd*) machine=pmax ;;
235 ns32k-*-netbsd*) machine=ns32000 ;;
236 powerpc-*-netbsd*) machine=macppc ;;
237 sparc*-*-netbsd*) machine=sparc ;;
238 vax-*-netbsd*) machine=vax ;;
239 arm-*-netbsd*) machine=arm ;;
240 esac
241 ;;
243 ## OpenBSD ports
244 *-*-openbsd* )
245 opsys=openbsd
246 case "${canonical}" in
247 alpha*-*-openbsd*) machine=alpha ;;
248 i386-*-openbsd*) machine=intel386 ;;
249 m68k-*-openbsd*) machine=hp9000s300 ;;
250 mipsel-*-openbsd*) machine=pmax ;;
251 ns32k-*-openbsd*) machine=ns32000 ;;
252 sparc-*-openbsd*) machine=sparc ;;
253 vax-*-openbsd*) machine=vax ;;
254 esac
255 ;;
257 ## Acorn RISCiX:
258 arm-acorn-riscix1.1* )
259 machine=acorn opsys=riscix1-1
260 ;;
261 arm-acorn-riscix1.2* | arm-acorn-riscix )
262 ## This name is riscix12 instead of riscix1.2
263 ## to avoid a file name conflict on MSDOS.
264 machine=acorn opsys=riscix12
265 ;;
267 ## BSDI ports
268 *-*-bsdi* )
269 opsys=bsdi
270 case "${canonical}" in
271 i[345]86-*-bsdi*) machine=intel386 ;;
272 sparc-*-bsdi*) machine=sparc ;;
273 powerpc-*-bsdi*) machine=macppc ;;
274 esac
275 case "${canonical}" in
276 *-*-bsd386* | *-*-bsdi1* ) opsys=bsd386 ;;
277 *-*-bsdi2.0* ) opsys=bsdos2 ;;
278 *-*-bsdi2* ) opsys=bsdos2-1 ;;
279 *-*-bsdi3* ) opsys=bsdos3 ;;
280 *-*-bsdi[45]* ) opsys=bsdos4 ;;
281 esac
282 ;;
284 ## Alliant machines
285 ## Strictly speaking, we need the version of the alliant operating
286 ## system to choose the right machine file, but currently the
287 ## configuration name doesn't tell us enough to choose the right
288 ## one; we need to give alliants their own operating system name to
289 ## do this right. When someone cares, they can help us.
290 fx80-alliant-* )
291 machine=alliant4 opsys=bsd4-2
292 ;;
293 i860-alliant-* )
294 machine=alliant-2800 opsys=bsd4-3
295 ;;
297 ## Alpha (DEC) machines.
298 alpha*-dec-osf* )
299 machine=alpha opsys=osf1
300 # This is needed to find X11R6.1 libraries for certain tests.
301 NON_GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
302 GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
303 # NON_GNU_CPP is necessary on 5.0 to avoid mangling src/Makefile
304 # due to non-traditional preprocessing with the current compiler
305 # defaults. OSF 4 can also have that compiler version, and there
306 # seems always to have been a usable /usr/bin/cpp.
307 NON_GNU_CPP=/usr/bin/cpp
308 case "${canonical}" in
309 alpha*-dec-osf[5-9]*)
310 opsys=osf5-0 ;;
311 esac
312 ;;
314 alpha*-*-linux-gnu* )
315 machine=alpha opsys=gnu-linux
316 ;;
318 arm*-*-linux-gnu* )
319 machine=arm opsys=gnu-linux
320 ;;
322 ppc-*-linux | \
323 powerpc-*-linux* )
324 machine=macppc opsys=gnu-linux
325 ;;
327 ## Altos 3068
328 m68*-altos-sysv* )
329 machine=altos opsys=usg5-2
330 ;;
332 ## Amdahl UTS
333 580-amdahl-sysv* )
334 machine=amdahl opsys=usg5-2-2
335 ;;
337 ## Apollo, Domain/OS
338 m68*-apollo-* )
339 machine=apollo opsys=bsd4-3
340 ;;
342 ## AT&T 3b2, 3b5, 3b15, 3b20
343 we32k-att-sysv* )
344 machine=att3b opsys=usg5-2-2
345 ;;
347 ## AT&T 3b1 - The Mighty Unix PC!
348 m68*-att-sysv* )
349 machine=7300 opsys=usg5-2-2
350 ;;
352 ## Bull dpx20
353 rs6000-bull-bosx* )
354 machine=ibmrs6000 opsys=aix3-2
355 ;;
357 ## Bull dpx2
358 m68*-bull-sysv3* )
359 machine=dpx2 opsys=usg5-3
360 ;;
362 ## Bull sps7
363 m68*-bull-sysv2* )
364 machine=sps7 opsys=usg5-2
365 ;;
367 ## CCI 5/32, 6/32 -- see "Tahoe".
369 ## Celerity
370 ## I don't know what configuration name to use for this; config.sub
371 ## doesn't seem to know anything about it. Hey, Celerity users, get
372 ## in touch with us!
373 celerity-celerity-bsd* )
374 machine=celerity opsys=bsd4-2
375 ;;
377 ## Clipper
378 ## What operating systems does this chip run that Emacs has been
379 ## tested on?
380 clipper-* )
381 machine=clipper
382 ## We'll use the catch-all code at the bottom to guess the
383 ## operating system.
384 ;;
386 ## Compaq Nonstop
387 mips-compaq-nonstopux* )
388 machine=nonstopux opsys=nonstopux
389 ;;
391 ## Convex
392 *-convex-bsd* | *-convex-convexos* )
393 machine=convex opsys=bsd4-3
394 ## Prevents spurious white space in makefiles - d.m.cooke@larc.nasa.gov
395 NON_GNU_CPP="cc -E -P"
396 ;;
398 ## Cubix QBx/386
399 i[3456]86-cubix-sysv* )
400 machine=intel386 opsys=usg5-3
401 ;;
403 ## Cydra 5
404 cydra*-cydrome-sysv* )
405 machine=cydra5 opsys=usg5-3
406 ;;
408 ## Data General AViiON Machines
409 ## DG changed naming conventions with the release of 5.4.4.10, they
410 ## dropped the initial 5.4 but left the intervening R. Because of the
411 ## R this shouldn't conflict with older versions of the OS (which I
412 ## think were named like dgux4.*). In addition, DG new AViiONs series
413 ## uses either Motorola M88k or Intel Pentium CPUs.
414 m88k-dg-dguxR4.* | m88k-dg-dgux4* )
415 machine=aviion opsys=dgux4
416 ;;
417 m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
418 ## This name is dgux5-4-3 instead of dgux5-4r3
419 ## to avoid a file name conflict on MSDOS.
420 machine=aviion opsys=dgux5-4-3
421 ;;
422 m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
423 machine=aviion opsys=dgux5-4r2
424 ;;
425 m88k-dg-dgux* )
426 machine=aviion opsys=dgux
427 ;;
429 ## Data General AViiON Intel (x86) Machines
430 ## Exists from 5.4.3 (current i586-dg-dguxR4.11)
431 ## Ehud Karni, 1998-may-30, ehud@unix.simonwiesel.co.il
432 i[345]86-dg-dguxR4* )
433 machine=aviion-intel opsys=dgux4
434 ;;
436 ## DECstations
437 mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
438 machine=pmax opsys=bsd4-2
439 ;;
440 mips-dec-ultrix4.[12]* | mips-dec-bsd* )
441 machine=pmax opsys=bsd4-3
442 ;;
443 mips-dec-ultrix* )
444 machine=pmax opsys=ultrix4-3
445 ;;
446 mips-dec-osf* )
447 machine=pmax opsys=osf1
448 ;;
449 mips-dec-mach_bsd4.3* )
450 machine=pmax opsys=mach-bsd4-3
451 ;;
453 ## Motorola Delta machines
454 m68k-motorola-sysv* | m68000-motorola-sysv* )
455 machine=delta opsys=usg5-3
456 if test -z "`type gnucc | grep 'not found'`"
457 then
458 if test -s /etc/167config
459 then CC="gnucc -m68040"
460 else CC="gnucc -m68881"
461 fi
462 else
463 if test -z "`type gcc | grep 'not found'`"
464 then CC=gcc
465 else CC=cc
466 fi
467 fi
468 ;;
469 m88k-motorola-sysv4* )
470 # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
471 # needs POSIX_SIGNALS and therefore needs usg5-4-2.
472 # I hope there are not other 4.0 versions for this machine
473 # which really need usg5-4 instead.
474 machine=delta88k opsys=usg5-4-2
475 ;;
476 m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
477 machine=delta88k opsys=usg5-3
478 ;;
480 ## Dual machines
481 m68*-dual-sysv* )
482 machine=dual opsys=usg5-2
483 ;;
484 m68*-dual-uniplus* )
485 machine=dual opsys=unipl5-2
486 ;;
488 ## Elxsi 6400
489 elxsi-elxsi-sysv* )
490 machine=elxsi opsys=usg5-2
491 ;;
493 ## Encore machines
494 ns16k-encore-bsd* )
495 machine=ns16000 opsys=umax
496 ;;
498 ## The GEC 63 - apparently, this port isn't really finished yet.
499 # I'm sure we finished off the last of the machines, though. -- fx
501 ## Gould Power Node and NP1
502 pn-gould-bsd4.2* )
503 machine=gould opsys=bsd4-2
504 ;;
505 pn-gould-bsd4.3* )
506 machine=gould opsys=bsd4-3
507 ;;
508 np1-gould-bsd* )
509 machine=gould-np1 opsys=bsd4-3
510 ;;
512 ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
513 ## as far as Emacs is concerned).
514 m88k-harris-cxux* )
515 # Build needs to be different on 7.0 and later releases
516 case "`uname -r`" in
517 [56].[0-9] ) machine=nh4000 opsys=cxux ;;
518 [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
519 esac
520 NON_GNU_CPP="/lib/cpp"
521 ;;
522 ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
523 m68k-harris-cxux* )
524 machine=nh3000 opsys=cxux
525 ;;
526 ## Harris power pc NightHawk running Power UNIX (Series 6000)
527 powerpc-harris-powerunix )
528 machine=nh6000 opsys=powerunix
529 NON_GNU_CPP="cc -Xo -E -P"
530 ;;
531 ## SR2001/SR2201 running HI-UX/MPP
532 hppa1.1-hitachi-hiuxmpp* )
533 machine=sr2k opsys=hiuxmpp
534 ;;
535 hppa1.1-hitachi-hiuxwe2* )
536 machine=sr2k opsys=hiuxwe2
537 ;;
538 ## Honeywell XPS100
539 xps*-honeywell-sysv* )
540 machine=xps100 opsys=usg5-2
541 ;;
543 ## HP 9000 series 200 or 300
544 m68*-hp-bsd* )
545 machine=hp9000s300 opsys=bsd4-3
546 ;;
547 ## HP/UX 7, 8, 9, and 10 are supported on these machines.
548 m68*-hp-hpux* )
549 case "`uname -r`" in
550 ## Someone's system reports A.B8.05 for this.
551 ## I wonder what other possibilities there are.
552 *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
553 *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
554 *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
555 *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
556 *) machine=hp9000s300 opsys=hpux ;;
557 esac
558 ;;
560 ## HP 9000 series 700 and 800, running HP/UX
561 hppa*-hp-hpux7* )
562 machine=hp800 opsys=hpux
563 ;;
564 hppa*-hp-hpux8* )
565 machine=hp800 opsys=hpux8
566 ;;
567 hppa*-hp-hpux9shr* )
568 machine=hp800 opsys=hpux9shr
569 ;;
570 hppa*-hp-hpux9* )
571 machine=hp800 opsys=hpux9
572 ;;
573 hppa*-hp-hpux10* )
574 machine=hp800 opsys=hpux10
575 ;;
576 hppa*-hp-hpux1[1-9]* )
577 machine=hp800 opsys=hpux11
578 ;;
580 hppa*-*-linux-gnu* )
581 machine=hp800 opsys=gnu-linux
582 ;;
584 ## HP 9000 series 700 and 800, running HP/UX
585 hppa*-hp-hpux* )
586 ## Cross-compilation? Nah!
587 case "`uname -r`" in
588 ## Someone's system reports A.B8.05 for this.
589 ## I wonder what other possibilities there are.
590 *.B8.* ) machine=hp800 opsys=hpux8 ;;
591 *.08.* ) machine=hp800 opsys=hpux8 ;;
592 *.09.* ) machine=hp800 opsys=hpux9 ;;
593 *) machine=hp800 opsys=hpux10 ;;
594 esac
595 ;;
596 hppa*-*-nextstep* )
597 machine=hp800 opsys=nextstep
598 ;;
600 ## Orion machines
601 orion-orion-bsd* )
602 machine=orion opsys=bsd4-2
603 ;;
604 clipper-orion-bsd* )
605 machine=orion105 opsys=bsd4-2
606 ;;
608 ## IBM machines
609 i[3456]86-ibm-aix1.1* )
610 machine=ibmps2-aix opsys=usg5-2-2
611 ;;
612 i[3456]86-ibm-aix1.[23]* | i[3456]86-ibm-aix* )
613 machine=ibmps2-aix opsys=usg5-3
614 ;;
615 i370-ibm-aix*)
616 machine=ibm370aix opsys=usg5-3
617 ;;
618 s390-*-linux-gnu)
619 machine=ibms390 opsys=gnu-linux
620 ;;
621 rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1* )
622 machine=ibmrs6000 opsys=aix3-1
623 ;;
624 rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
625 machine=ibmrs6000 opsys=aix3-2-5
626 ;;
627 rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1* )
628 machine=ibmrs6000 opsys=aix4-1
629 ;;
630 rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2* )
631 machine=ibmrs6000 opsys=aix4-2
632 ;;
633 rs6000-ibm-aix5.1* | powerpc-ibm-aix5.1* )
634 machine=ibmrs6000 opsys=aix4-2
635 ;;
636 rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0* )
637 machine=ibmrs6000 opsys=aix4
638 ;;
639 rs6000-ibm-aix4* | powerpc-ibm-aix4* )
640 machine=ibmrs6000 opsys=aix4-1
641 ;;
642 rs6000-ibm-aix* | powerpc-ibm-aix* )
643 machine=ibmrs6000 opsys=aix3-2
644 ;;
645 romp-ibm-bsd4.3* )
646 machine=ibmrt opsys=bsd4-3
647 ;;
648 romp-ibm-bsd4.2* )
649 machine=ibmrt opsys=bsd4-2
650 ;;
651 romp-ibm-aos4.3* )
652 machine=ibmrt opsys=bsd4-3
653 ;;
654 romp-ibm-aos4.2* )
655 machine=ibmrt opsys=bsd4-2
656 ;;
657 romp-ibm-aos* )
658 machine=ibmrt opsys=bsd4-3
659 ;;
660 romp-ibm-bsd* )
661 machine=ibmrt opsys=bsd4-3
662 ;;
663 romp-ibm-aix* )
664 machine=ibmrt-aix opsys=usg5-2-2
665 ;;
667 ## Integrated Solutions `Optimum V'
668 m68*-isi-bsd4.2* )
669 machine=isi-ov opsys=bsd4-2
670 ;;
671 m68*-isi-bsd4.3* )
672 machine=isi-ov opsys=bsd4-3
673 ;;
675 ## Intel 386 machines where we do care about the manufacturer
676 i[3456]86-intsys-sysv* )
677 machine=is386 opsys=usg5-2-2
678 ;;
680 ## Prime EXL
681 i[3456]86-prime-sysv* )
682 machine=i386 opsys=usg5-3
683 ;;
685 ## Sequent Symmetry running Dynix
686 i[3456]86-sequent-bsd* )
687 machine=symmetry opsys=bsd4-3
688 ;;
690 ## Sequent Symmetry running ptx 4, which is a modified SVR4.
691 i[3456]86-sequent-ptx4* | i[3456]86-sequent-sysv4* )
692 machine=sequent-ptx opsys=ptx4
693 NON_GNU_CPP=/lib/cpp
694 ;;
696 ## Sequent Symmetry running DYNIX/ptx
697 ## Use the old cpp rather than the newer ANSI one.
698 i[3456]86-sequent-ptx* )
699 machine=sequent-ptx opsys=ptx
700 NON_GNU_CPP="/lib/cpp"
701 ;;
703 ## ncr machine running svr4.3.
704 i[3456]86-ncr-sysv4.3 )
705 machine=ncr386 opsys=usg5-4-3
706 ;;
708 ## Unspecified sysv on an ncr machine defaults to svr4.2.
709 ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
710 i[3456]86-ncr-sysv* )
711 machine=ncr386 opsys=usg5-4-2
712 ;;
714 ## Intel Paragon OSF/1
715 i860-intel-osf1* )
716 machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
717 ;;
719 ## Intel 860
720 i860-*-sysv4* )
721 machine=i860 opsys=usg5-4
722 NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
723 NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
724 ;;
726 ## Macintosh PowerPC
727 powerpc*-*-linux-gnu* )
728 machine=macppc opsys=gnu-linux
729 ;;
731 ## Masscomp machines
732 m68*-masscomp-rtu* )
733 machine=masscomp opsys=rtu
734 ;;
736 ## Megatest machines
737 m68*-megatest-bsd* )
738 machine=mega68 opsys=bsd4-2
739 ;;
741 ## Workstations sold by MIPS
742 ## This is not necessarily all workstations using the MIPS processor -
743 ## Irises are produced by SGI, and DECstations by DEC.
745 ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
746 ## and usg5-2-2 and bsd4-3 as possible OS files. The only guidance
747 ## it gives for choosing between the alternatives seems to be "Use
748 ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
749 ## the BSD world." I'll assume that these are instructions for
750 ## handling two odd situations, and that every other situation
751 ## should use mips.h and usg5-2-2, they being listed first.
752 mips-mips-usg* )
753 machine=mips4
754 ## Fall through to the general code at the bottom to decide on the OS.
755 ;;
756 mips-mips-riscos4* )
757 machine=mips4 opsys=bsd4-3
758 NON_GNU_CC="cc -systype bsd43"
759 NON_GNU_CPP="cc -systype bsd43 -E"
760 ;;
761 mips-mips-riscos5* )
762 machine=mips4 opsys=riscos5
763 NON_GNU_CC="cc -systype bsd43"
764 NON_GNU_CPP="cc -systype bsd43 -E"
765 ;;
766 mips-mips-bsd* )
767 machine=mips opsys=bsd4-3
768 ;;
769 mips-mips-* )
770 machine=mips opsys=usg5-2-2
771 ;;
773 ## NeXT
774 m68*-next-* | m68k-*-nextstep* )
775 machine=m68k opsys=nextstep
776 ;;
778 ## The complete machine from National Semiconductor
779 ns32k-ns-genix* )
780 machine=ns32000 opsys=usg5-2
781 ;;
783 ## NCR machines
784 m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
785 machine=tower32 opsys=usg5-2-2
786 ;;
787 m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
788 machine=tower32v3 opsys=usg5-3
789 ;;
791 ## NEC EWS4800
792 mips-nec-sysv4*)
793 machine=ews4800 opsys=ux4800
794 ;;
796 ## Nixdorf Targon 31
797 m68*-nixdorf-sysv* )
798 machine=targon31 opsys=usg5-2-2
799 ;;
801 ## Nu (TI or LMI)
802 m68*-nu-sysv* )
803 machine=nu opsys=usg5-2
804 ;;
806 ## Plexus
807 m68*-plexus-sysv* )
808 machine=plexus opsys=usg5-2
809 ;;
811 ## Pyramid machines
812 ## I don't really have any idea what sort of processor the Pyramid has,
813 ## so I'm assuming it is its own architecture.
814 pyramid-pyramid-bsd* )
815 machine=pyramid opsys=bsd4-2
816 ;;
818 ## Sequent Balance
819 ns32k-sequent-bsd4.2* )
820 machine=sequent opsys=bsd4-2
821 ;;
822 ns32k-sequent-bsd4.3* )
823 machine=sequent opsys=bsd4-3
824 ;;
826 ## Siemens Nixdorf
827 mips-siemens-sysv* | mips-sni-sysv*)
828 machine=mips-siemens opsys=usg5-4
829 NON_GNU_CC=/usr/ccs/bin/cc
830 NON_GNU_CPP=/usr/ccs/lib/cpp
831 ;;
833 ## Silicon Graphics machines
834 ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
835 m68*-sgi-iris3.5* )
836 machine=irist opsys=iris3-5
837 ;;
838 m68*-sgi-iris3.6* | m68*-sgi-iris*)
839 machine=irist opsys=iris3-6
840 ;;
841 ## Iris 4D
842 mips-sgi-irix3* )
843 machine=iris4d opsys=irix3-3
844 ;;
845 mips-sgi-irix4* )
846 machine=iris4d opsys=irix4-0
847 ;;
848 mips-sgi-irix6.5 )
849 machine=iris4d opsys=irix6-5
850 # Without defining _LANGUAGE_C, things get masked out in the headers
851 # so that, for instance, grepping for `free' in stdlib.h fails and
852 # AC_HEADER_STD_C fails. (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
853 NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
854 NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
855 ;;
856 mips-sgi-irix6* )
857 machine=iris4d opsys=irix6-0
858 # It's not clear whether -D_LANGUAGE_C is necessary as it is for 6.5,
859 # but presumably it does no harm.
860 NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
861 # -32 probably isn't necessary in later v.6s -- anyone know which?
862 NON_GCC_TEST_OPTIONS=-32
863 ;;
864 mips-sgi-irix5.[01]* )
865 machine=iris4d opsys=irix5-0
866 ;;
867 mips-sgi-irix5* | mips-sgi-irix* )
868 machine=iris4d opsys=irix5-2
869 ;;
871 ## SONY machines
872 m68*-sony-bsd4.2* )
873 machine=news opsys=bsd4-2
874 ;;
875 m68*-sony-bsd4.3* )
876 machine=news opsys=bsd4-3
877 ;;
878 m68*-sony-newsos3* | m68*-sony-news3*)
879 machine=news opsys=bsd4-3
880 ;;
881 mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
882 machine=news-risc opsys=bsd4-3
883 ;;
884 mips-sony-newsos6* )
885 machine=news-r6 opsys=newsos6
886 ;;
887 mips-sony-news* )
888 machine=news-risc opsys=newsos5
889 ;;
891 ## Stride
892 m68*-stride-sysv* )
893 machine=stride opsys=usg5-2
894 ;;
896 ## Suns
897 sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
898 machine=sparc opsys=gnu-linux
899 ;;
901 *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
902 | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
903 | rs6000-*-solaris2*)
904 case "${canonical}" in
905 m68*-sunos1* ) machine=sun1 ;;
906 m68*-sunos2* ) machine=sun2 ;;
907 m68* ) machine=sun3 ;;
908 i[3456]86-sun-sunos[34]* ) machine=sun386 ;;
909 i[3456]86-*-* ) machine=intel386 ;;
910 powerpcle* ) machine=powerpcle ;;
911 powerpc* | rs6000* ) machine=ibmrs6000 ;;
912 sparc* ) machine=sparc ;;
913 * ) unported=yes ;;
914 esac
915 case "${canonical}" in
916 ## The Sun386 didn't get past 4.0.
917 i[3456]86-*-sunos4 ) opsys=sunos4-0 ;;
918 *-sunos4.0* ) opsys=sunos4-0 ;;
919 *-sunos4.1.[3-9]*noshare )
920 ## This name is sunos413 instead of sunos4-1-3
921 ## to avoid a file name conflict on MSDOS.
922 opsys=sunos413
923 NON_GNU_CPP=/usr/lib/cpp
924 NON_GCC_TEST_OPTIONS=-Bstatic
925 GCC_TEST_OPTIONS=-static
926 ;;
927 *-sunos4.1.[3-9]* | *-sunos4shr*)
928 opsys=sunos4shr
929 NON_GNU_CPP=/usr/lib/cpp
930 ;;
931 *-sunos4* | *-sunos )
932 opsys=sunos4-1
933 NON_GCC_TEST_OPTIONS=-Bstatic
934 GCC_TEST_OPTIONS=-static
935 ;;
936 *-sunos5.3* | *-solaris2.3* )
937 opsys=sol2-3
938 NON_GNU_CPP=/usr/ccs/lib/cpp
939 ;;
940 *-sunos5.4* | *-solaris2.4* )
941 opsys=sol2-4
942 NON_GNU_CPP=/usr/ccs/lib/cpp
943 RANLIB="ar -ts"
944 ;;
945 *-sunos5.5* | *-solaris2.5* )
946 opsys=sol2-5
947 NON_GNU_CPP=/usr/ccs/lib/cpp
948 RANLIB="ar -ts"
949 ;;
950 *-sunos5.6* | *-solaris2.6* )
951 opsys=sol2-6
952 NON_GNU_CPP=/usr/ccs/lib/cpp
953 RANLIB="ar -ts"
954 ;;
955 *-sunos5* | *-solaris* )
956 opsys=sol2-6
957 NON_GNU_CPP=/usr/ccs/lib/cpp
958 ;;
959 * ) opsys=bsd4-2 ;;
960 esac
961 ## Watch out for a compiler that we know will not work.
962 case "${canonical}" in
963 *-solaris* | *-sunos5* )
964 if [ "x$CC" = x/usr/ucb/cc ]; then
965 ## /usr/ucb/cc doesn't work;
966 ## we should find some other compiler that does work.
967 unset CC
968 fi
969 ;;
970 *) ;;
971 esac
972 ;;
973 sparc-*-nextstep* )
974 machine=sparc opsys=nextstep
975 ;;
977 ## Tadpole 68k
978 m68*-tadpole-sysv* )
979 machine=tad68k opsys=usg5-3
980 ;;
982 ## Tahoe machines
983 tahoe-tahoe-bsd4.2* )
984 machine=tahoe opsys=bsd4-2
985 ;;
986 tahoe-tahoe-bsd4.3* )
987 machine=tahoe opsys=bsd4-3
988 ;;
990 ## Tandem Integrity S2
991 mips-tandem-sysv* )
992 machine=tandem-s2 opsys=usg5-3
993 ;;
995 ## Tektronix XD88
996 m88k-tektronix-sysv3* )
997 machine=tekxd88 opsys=usg5-3
998 ;;
1000 ## Tektronix 16000 box (6130?)
1001 ns16k-tektronix-bsd* )
1002 machine=ns16000 opsys=bsd4-2
1003 ;;
1004 ## Tektronix 4300
1005 ## src/m/tek4300.h hints that this is a m68k machine.
1006 m68*-tektronix-bsd* )
1007 machine=tek4300 opsys=bsd4-3
1008 ;;
1010 ## Titan P2 or P3
1011 ## We seem to have lost the machine-description file titan.h!
1012 titan-titan-sysv* )
1013 machine=titan opsys=usg5-3
1014 ;;
1016 ## Ustation E30 (SS5E)
1017 m68*-unisys-uniplus* )
1018 machine=ustation opsystem=unipl5-2
1019 ;;
1021 ## Vaxen.
1022 vax-dec-* )
1023 machine=vax
1024 case "${canonical}" in
1025 *-bsd4.1* ) opsys=bsd4-1 ;;
1026 *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* ) opsys=bsd4-2 ;;
1027 *-bsd4.3* | *-ultrix* ) opsys=bsd4-3 ;;
1028 *-sysv[01]* | *-sysvr[01]* ) opsys=usg5-0 ;;
1029 *-sysv2* | *-sysvr2* ) opsys=usg5-2 ;;
1030 *-vms* ) opsys=vms ;;
1031 * ) unported=yes
1032 esac
1033 ;;
1035 ## Whitechapel MG1
1036 ns16k-whitechapel-* )
1037 machine=mg1
1038 ## We don't know what sort of OS runs on these; we'll let the
1039 ## operating system guessing code below try.
1040 ;;
1042 ## Wicat
1043 m68*-wicat-sysv* )
1044 machine=wicat opsys=usg5-2
1045 ;;
1047 ## IA-64
1048 ia64*-*-linux* )
1049 machine=ia64 opsys=gnu-linux
1050 ;;
1052 ## Intel 386 machines where we don't care about the manufacturer
1053 i[3456]86-*-* )
1054 machine=intel386
1055 case "${canonical}" in
1056 *-lynxos* ) opsys=lynxos ;;
1057 *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
1058 *-isc2.2* ) opsys=isc2-2 ;;
1059 *-isc4.0* ) opsys=isc4-0 ;;
1060 *-isc4.* ) opsys=isc4-1
1061 GCC_TEST_OPTIONS=-posix
1062 NON_GCC_TEST_OPTIONS=-Xp
1063 ;;
1064 *-isc* ) opsys=isc3-0 ;;
1065 *-esix5* ) opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
1066 *-esix* ) opsys=esix ;;
1067 *-xenix* ) opsys=xenix ;;
1068 *-linux-gnu* ) opsys=gnu-linux ;;
1069 *-sco3.2v4* ) opsys=sco4 ; NON_GNU_CPP=/lib/cpp ;;
1070 *-sco3.2v5* ) opsys=sco5
1071 NON_GNU_CPP=/lib/cpp
1072 # Prevent -belf from being passed to $CPP.
1073 # /lib/cpp does not accept it.
1074 OVERRIDE_CPPFLAGS=" "
1075 ;;
1076 *-sysv4.2uw* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1077 *-386bsd* ) opsys=386bsd ;;
1078 *-nextstep* ) opsys=nextstep ;;
1079 ## Otherwise, we'll fall through to the generic opsys code at the bottom.
1080 esac
1081 ;;
1083 ## m68k Linux-based GNU system
1084 m68k-*-linux-gnu* )
1085 machine=m68k opsys=gnu-linux
1086 ;;
1088 ## Mips Linux-based GNU system
1089 mips-*-linux-gnu* | mipsel-*-linux-gnu* )
1090 machine=mips opsys=gnu-linux
1091 ;;
1093 ## UXP/DS
1094 sparc-fujitsu-sysv4* )
1095 machine=sparc opsys=uxpds
1096 NON_GNU_CPP=/usr/ccs/lib/cpp
1097 RANLIB="ar -ts"
1098 ;;
1100 ## UXP/V
1101 f301-fujitsu-uxpv4.1)
1102 machine=f301 opsys=uxpv
1103 ;;
1105 ## Darwin / Mac OS X
1106 powerpc-apple-darwin* )
1107 machine=powermac opsys=darwin
1108 # Define CPP as follows to make autoconf work correctly.
1109 CPP="cc -E -traditional-cpp"
1110 ;;
1112 ## AMD x86-64 Linux-based GNU system
1113 x86_64-*-linux-gnu* )
1114 machine=amdx86-64 opsys=gnu-linux
1115 ;;
1117 * )
1118 unported=yes
1119 ;;
1120 esac
1122 ### If the code above didn't choose an operating system, just choose
1123 ### an operating system based on the configuration name. You really
1124 ### only want to use this when you have no idea what the right
1125 ### operating system is; if you know what operating systems a machine
1126 ### runs, it's cleaner to make it explicit in the case statement
1127 ### above.
1128 if test x"${opsys}" = x; then
1129 case "${canonical}" in
1130 *-gnu* ) opsys=gnu ;;
1131 *-bsd4.[01] ) opsys=bsd4-1 ;;
1132 *-bsd4.2 ) opsys=bsd4-2 ;;
1133 *-bsd4.3 ) opsys=bsd4-3 ;;
1134 *-sysv0 | *-sysvr0 ) opsys=usg5-0 ;;
1135 *-sysv2 | *-sysvr2 ) opsys=usg5-2 ;;
1136 *-sysv2.2 | *-sysvr2.2 ) opsys=usg5-2-2 ;;
1137 *-sysv3* | *-sysvr3* ) opsys=usg5-3 ;;
1138 *-sysv4.2uw* ) opsys=unixware ;;
1139 *-sysv4.1* | *-sysvr4.1* )
1140 NON_GNU_CPP=/usr/lib/cpp
1141 opsys=usg5-4 ;;
1142 *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
1143 if [ x$NON_GNU_CPP = x ]; then
1144 if [ -f /usr/ccs/lib/cpp ]; then
1145 NON_GNU_CPP=/usr/ccs/lib/cpp
1146 else
1147 NON_GNU_CPP=/lib/cpp
1148 fi
1149 fi
1150 opsys=usg5-4-2 ;;
1151 *-sysv4* | *-sysvr4* ) opsys=usg5-4 ;;
1152 * )
1153 unported=yes
1154 ;;
1155 esac
1156 fi
1158 ]
1160 if test $unported = yes; then
1161 AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
1162 Check `etc/MACHINES' for recognized configuration names.])
1163 fi
1165 machfile="m/${machine}.h"
1166 opsysfile="s/${opsys}.h"
1169 #### Choose a compiler.
1170 test -n "$CC" && cc_specified=yes
1172 # Save the value of CFLAGS that the user specified.
1173 SPECIFIED_CFLAGS="$CFLAGS"
1175 case ${with_gcc} in
1176 "yes" ) CC="gcc" GCC=yes ;;
1177 "no" ) : ${CC=cc} ;;
1178 * )
1179 esac
1180 AC_PROG_CC
1182 # On Suns, sometimes $CPP names a directory.
1183 if test -n "$CPP" && test -d "$CPP"; then
1184 CPP=
1185 fi
1187 #### Some systems specify a CPP to use unless we are using GCC.
1188 #### Now that we know whether we are using GCC, we can decide whether
1189 #### to use that one.
1190 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
1191 then
1192 CPP="$NON_GNU_CPP"
1193 fi
1195 #### Some systems specify a CC to use unless we are using GCC.
1196 #### Now that we know whether we are using GCC, we can decide whether
1197 #### to use that one.
1198 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
1199 test x$cc_specified != xyes
1200 then
1201 CC="$NON_GNU_CC"
1202 fi
1204 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
1205 then
1206 CC="$CC $GCC_TEST_OPTIONS"
1207 fi
1209 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
1210 then
1211 CC="$CC $NON_GCC_TEST_OPTIONS"
1212 fi
1214 #### Some other nice autoconf tests.
1216 dnl checks for programs
1217 AC_PROG_LN_S
1218 AC_PROG_CPP
1219 AC_PROG_INSTALL
1220 if test "x$RANLIB" = x; then
1221 AC_PROG_RANLIB
1222 fi
1223 AC_PATH_PROG(INSTALL_INFO, install-info)
1224 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
1225 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
1227 dnl Add our options to ac_link now, after it is set up.
1229 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
1230 then
1231 ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1232 fi
1234 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
1235 then
1236 ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1237 fi
1239 dnl checks for Unix variants
1240 AC_AIX
1242 #### Extract some information from the operating system and machine files.
1244 AC_CHECKING([the machine- and system-dependent files to find out
1245 - which libraries the lib-src programs will want, and
1246 - whether the GNU malloc routines are usable])
1248 ### First figure out CFLAGS (which we use for running the compiler here)
1249 ### and REAL_CFLAGS (which we use for real compilation).
1250 ### The two are the same except on a few systems, where they are made
1251 ### different to work around various lossages. For example,
1252 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
1253 ### as implying static linking.
1255 ### If the CFLAGS env var is specified, we use that value
1256 ### instead of the default.
1258 ### It's not important that this name contain the PID; you can't run
1259 ### two configures in the same directory and have anything work
1260 ### anyway.
1261 tempcname="conftest.c"
1263 echo '
1264 #include "'${srcdir}'/src/'${opsysfile}'"
1265 #include "'${srcdir}'/src/'${machfile}'"
1266 #ifndef LIBS_MACHINE
1267 #define LIBS_MACHINE
1268 #endif
1269 #ifndef LIBS_SYSTEM
1270 #define LIBS_SYSTEM
1271 #endif
1272 #ifndef C_SWITCH_SYSTEM
1273 #define C_SWITCH_SYSTEM
1274 #endif
1275 #ifndef C_SWITCH_MACHINE
1276 #define C_SWITCH_MACHINE
1277 #endif
1278 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1279 configure___ c_switch_system=C_SWITCH_SYSTEM
1280 configure___ c_switch_machine=C_SWITCH_MACHINE
1282 #ifndef LIB_X11_LIB
1283 #define LIB_X11_LIB -lX11
1284 #endif
1286 #ifndef LIBX11_MACHINE
1287 #define LIBX11_MACHINE
1288 #endif
1290 #ifndef LIBX11_SYSTEM
1291 #define LIBX11_SYSTEM
1292 #endif
1293 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1295 #ifdef UNEXEC
1296 configure___ unexec=UNEXEC
1297 #else
1298 configure___ unexec=unexec.o
1299 #endif
1301 #ifdef SYSTEM_MALLOC
1302 configure___ system_malloc=yes
1303 #else
1304 configure___ system_malloc=no
1305 #endif
1307 #ifdef USE_MMAP_FOR_BUFFERS
1308 configure___ use_mmap_for_buffers=yes
1309 #else
1310 configure___ use_mmap_for_buffers=no
1311 #endif
1313 #ifndef C_DEBUG_SWITCH
1314 #define C_DEBUG_SWITCH -g
1315 #endif
1317 #ifndef C_OPTIMIZE_SWITCH
1318 #ifdef __GNUC__
1319 #define C_OPTIMIZE_SWITCH -O2
1320 #else
1321 #define C_OPTIMIZE_SWITCH -O
1322 #endif
1323 #endif
1325 #ifndef LD_SWITCH_MACHINE
1326 #define LD_SWITCH_MACHINE
1327 #endif
1329 #ifndef LD_SWITCH_SYSTEM
1330 #define LD_SWITCH_SYSTEM
1331 #endif
1333 #ifndef LD_SWITCH_X_SITE_AUX
1334 #define LD_SWITCH_X_SITE_AUX
1335 #endif
1337 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1338 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1340 #ifdef THIS_IS_CONFIGURE
1342 /* Get the CFLAGS for tests in configure. */
1343 #ifdef __GNUC__
1344 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1345 #else
1346 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1347 #endif
1349 #else /* not THIS_IS_CONFIGURE */
1351 /* Get the CFLAGS for real compilation. */
1352 #ifdef __GNUC__
1353 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1354 #else
1355 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1356 #endif
1358 #endif /* not THIS_IS_CONFIGURE */
1359 ' > ${tempcname}
1361 # The value of CPP is a quoted variable reference, so we need to do this
1362 # to get its actual value...
1363 CPP=`eval "echo $CPP"`
1364 [eval `${CPP} -Isrc ${tempcname} \
1365 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1366 if test "x$SPECIFIED_CFLAGS" = x; then
1367 eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1368 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1369 else
1370 REAL_CFLAGS="$CFLAGS"
1371 fi]
1372 rm ${tempcname}
1374 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1376 ### Make sure subsequent tests use flags consistent with the build flags.
1378 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1379 CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1380 else
1381 CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1382 fi
1384 dnl For AC_FUNC_GETLOADAVG, at least:
1385 AC_CONFIG_LIBOBJ_DIR(src)
1387 AC_GNU_SOURCE
1389 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1390 AC_SYS_LARGEFILE
1392 if test "${with_sound}" != "no"; then
1393 # Sound support for GNU/Linux and the free BSDs.
1394 AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1395 # Emulation library used on NetBSD.
1396 AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1397 AC_SUBST(LIBSOUND)
1398 fi
1400 dnl checks for header files
1401 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1402 linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1403 termcap.h stdio_ext.h fcntl.h term.h strings.h coff.h pty.h sys/mman.h \
1404 sys/param.h sys/vlimit.h sys/resource.h)
1405 dnl On Solaris 8 there's a compilation warning for term.h because
1406 dnl it doesn't define `bool'.
1407 AC_CHECK_HEADERS(term.h, , , -)
1408 AC_HEADER_STDC
1409 AC_HEADER_TIME
1410 AC_CHECK_DECLS([sys_siglist])
1411 if test $ac_cv_have_decl_sys_siglist != yes; then
1412 # For Tru64, at least:
1413 AC_CHECK_DECLS([__sys_siglist])
1414 if test $ac_cv_have_decl___sys_siglist = yes; then
1415 AC_DEFINE(sys_siglist, __sys_siglist,
1416 [Define to any substitute for sys_siglist.])
1417 fi
1418 fi
1419 AC_HEADER_SYS_WAIT
1421 dnl Some systems have utime.h but don't declare the struct anyplace.
1422 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1423 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1424 #include <sys/time.h>
1425 #include <time.h>
1426 #else
1427 #ifdef HAVE_SYS_TIME_H
1428 #include <sys/time.h>
1429 #else
1430 #include <time.h>
1431 #endif
1432 #endif
1433 #ifdef HAVE_UTIME_H
1434 #include <utime.h>
1435 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1436 emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1437 if test $emacs_cv_struct_utimbuf = yes; then
1438 AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1439 fi
1441 dnl checks for typedefs
1442 AC_TYPE_SIGNAL
1444 dnl Check for speed_t typedef.
1445 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1446 [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1447 emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1448 if test $emacs_cv_speed_t = yes; then
1449 AC_DEFINE(HAVE_SPEED_T, 1,
1450 [Define to 1 if `speed_t' is declared by <termios.h>.])
1451 fi
1453 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1454 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1455 #include <sys/time.h>
1456 #include <time.h>
1457 #else
1458 #ifdef HAVE_SYS_TIME_H
1459 #include <sys/time.h>
1460 #else
1461 #include <time.h>
1462 #endif
1463 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1464 emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1465 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1466 if test $emacs_cv_struct_timeval = yes; then
1467 AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1468 fi
1470 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1471 AC_TRY_COMPILE([#include <math.h>],
1472 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1473 emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1474 HAVE_EXCEPTION=$emacs_cv_struct_exception
1475 if test $emacs_cv_struct_exception != yes; then
1476 AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1477 fi
1479 dnl checks for structure members
1480 AC_STRUCT_TM
1481 AC_STRUCT_TIMEZONE
1482 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1483 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1484 [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1485 [#include <time.h>])
1487 dnl checks for compiler characteristics
1489 dnl Testing __STDC__ to determine prototype support isn't good enough.
1490 dnl DEC C, for instance, doesn't define it with default options, and
1491 dnl is used on 64-bit systems (OSF Alphas). Similarly for volatile
1492 dnl and void *.
1493 AC_C_PROTOTYPES
1494 AC_C_VOLATILE
1495 AC_C_CONST
1496 dnl This isn't useful because we can't turn on use of `inline' unless
1497 dnl the compiler groks `extern inline'.
1498 dnl AC_C_INLINE
1499 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1500 [AC_TRY_COMPILE(, [void * foo;],
1501 emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1502 if test $emacs_cv_void_star = yes; then
1503 AC_DEFINE(POINTER_TYPE, void)
1504 else
1505 AC_DEFINE(POINTER_TYPE, char)
1506 fi
1507 AH_TEMPLATE(POINTER_TYPE,
1508 [Define as `void' if your compiler accepts `void *'; otherwise
1509 define as `char'.])dnl
1511 dnl This could be used for targets which can have both byte sexes.
1512 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1513 dnl AC_C_BIGENDIAN
1515 dnl check for Make feature
1516 AC_PROG_MAKE_SET
1518 dnl checks for operating system services
1519 AC_SYS_LONG_FILE_NAMES
1521 #### Choose a window system.
1523 AC_PATH_X
1524 if test "$no_x" = yes; then
1525 window_system=none
1526 else
1527 window_system=x11
1528 fi
1530 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1531 LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1532 LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1533 x_default_search_path=""
1534 for x_library in `echo ${x_libraries} | sed -e "s/:/ /g"`; do
1535 x_search_path="\
1536 ${x_library}/X11/%L/%T/%N%C%S:\
1537 ${x_library}/X11/%l/%T/%N%C%S:\
1538 ${x_library}/X11/%T/%N%C%S:\
1539 ${x_library}/X11/%L/%T/%N%S:\
1540 ${x_library}/X11/%l/%T/%N%S:\
1541 ${x_library}/X11/%T/%N%S"
1542 if test x"${x_default_search_path}" = x; then
1543 x_default_search_path=${x_search_path}
1544 else
1545 x_default_search_path="${x_search_path}:${x_default_search_path}"
1546 fi
1547 done
1548 fi
1549 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1550 C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1551 fi
1553 if test x"${x_includes}" = x; then
1554 bitmapdir=/usr/include/X11/bitmaps
1555 else
1556 # accumulate include directories that have X11 bitmap subdirectories
1557 bmd_acc="dummyval"
1558 for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1559 if test -d "${bmd}/X11/bitmaps"; then
1560 bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1561 fi
1562 if test -d "${bmd}/bitmaps"; then
1563 bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1564 fi
1565 done
1566 if test ${bmd_acc} != "dummyval"; then
1567 bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1568 fi
1569 fi
1571 case "${window_system}" in
1572 x11 )
1573 HAVE_X_WINDOWS=yes
1574 HAVE_X11=yes
1575 case "${with_x_toolkit}" in
1576 athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1577 motif ) USE_X_TOOLKIT=MOTIF ;;
1578 dnl open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
1579 gtk ) with_gtk=yes
1580 dnl Dont set this for GTK. A lot of tests below assumes Xt when
1581 dnl USE_X_TOOLKIT is set.
1582 USE_X_TOOLKIT=none ;;
1583 no ) USE_X_TOOLKIT=none ;;
1584 dnl If user did not say whether to use a toolkit,
1585 dnl make this decision later: use the toolkit if we have X11R5 or newer.
1586 * ) USE_X_TOOLKIT=maybe ;;
1587 esac
1588 ;;
1589 none )
1590 HAVE_X_WINDOWS=no
1591 HAVE_X11=no
1592 USE_X_TOOLKIT=none
1593 ;;
1594 esac
1596 ### If we're using X11, we should use the X menu package.
1597 HAVE_MENUS=no
1598 case ${HAVE_X11} in
1599 yes ) HAVE_MENUS=yes ;;
1600 esac
1602 if test "${opsys}" = "hpux9"; then
1603 case "${x_libraries}" in
1604 *X11R4* )
1605 opsysfile="s/hpux9-x11r4.h"
1606 ;;
1607 esac
1608 fi
1610 if test "${opsys}" = "hpux9shr"; then
1611 case "${x_libraries}" in
1612 *X11R4* )
1613 opsysfile="s/hpux9shxr4.h"
1614 ;;
1615 esac
1616 fi
1618 ### Compute the unexec source name from the object name.
1619 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1621 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1622 # Assume not, until told otherwise.
1623 GNU_MALLOC=yes
1624 doug_lea_malloc=yes
1625 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1626 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1627 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1628 emacs_cv_var___after_morecore_hook,
1629 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1630 emacs_cv_var___after_morecore_hook=yes,
1631 emacs_cv_var___after_morecore_hook=no)])
1632 if test $emacs_cv_var___after_morecore_hook = no; then
1633 doug_lea_malloc=no
1634 fi
1635 if test "${system_malloc}" = "yes"; then
1636 GNU_MALLOC=no
1637 GNU_MALLOC_reason="
1638 (The GNU allocators don't work with this system configuration.)"
1639 fi
1640 if test "$doug_lea_malloc" = "yes" ; then
1641 if test "$GNU_MALLOC" = yes ; then
1642 GNU_MALLOC_reason="
1643 (Using Doug Lea's new malloc from the GNU C Library.)"
1644 fi
1645 AC_DEFINE(DOUG_LEA_MALLOC, 1,
1646 [Define to 1 if you are using the GNU C Library.])
1647 fi
1649 if test x"${REL_ALLOC}" = x; then
1650 REL_ALLOC=${GNU_MALLOC}
1651 fi
1653 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1654 dnl the system configuration file (s/*.h) to turn the use of mmap
1655 dnl in the relocating allocator on.
1657 AC_FUNC_MMAP
1658 if test $use_mmap_for_buffers = yes; then
1659 REL_ALLOC=no
1660 fi
1662 LIBS="$libsrc_libs $LIBS"
1664 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1665 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1666 AC_CHECK_LIB(dnet, dnet_ntoa)
1667 dnl This causes -lresolv to get used in subsequent tests,
1668 dnl which causes failures on some systems such as HPUX 9.
1669 dnl AC_CHECK_LIB(resolv, gethostbyname)
1671 dnl FIXME replace main with a function we actually want from this library.
1672 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1674 AC_CHECK_LIB(pthreads, cma_open)
1676 AC_MSG_CHECKING(for XFree86 in /usr/X386)
1677 if test -d /usr/X386/include; then
1678 HAVE_XFREE386=yes
1679 : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1680 else
1681 HAVE_XFREE386=no
1682 fi
1683 AC_MSG_RESULT($HAVE_XFREE386)
1685 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1686 # used for the tests that follow. We set them back to REAL_CFLAGS and
1687 # REAL_CPPFLAGS later on.
1689 REAL_CPPFLAGS="$CPPFLAGS"
1691 if test "${HAVE_X11}" = "yes"; then
1692 DEFS="$C_SWITCH_X_SITE $DEFS"
1693 LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1694 LIBS="$LIBX $LIBS"
1695 CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1696 CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1698 # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1699 # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1700 # but it's more convenient here to set LD_RUN_PATH
1701 # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1702 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1703 LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1704 export LD_RUN_PATH
1705 fi
1707 if test "${opsys}" = "gnu-linux"; then
1708 AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1709 AC_TRY_LINK([],
1710 [XOpenDisplay ("foo");],
1711 [xlinux_first_failure=no],
1712 [xlinux_first_failure=yes])
1713 if test "${xlinux_first_failure}" = "yes"; then
1714 OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1715 OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1716 OLD_CPPFLAGS="$CPPFLAGS"
1717 OLD_LIBS="$LIBS"
1718 LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1719 C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1720 CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1721 LIBS="$LIBS -b i486-linuxaout"
1722 AC_TRY_LINK([],
1723 [XOpenDisplay ("foo");],
1724 [xlinux_second_failure=no],
1725 [xlinux_second_failure=yes])
1726 if test "${xlinux_second_failure}" = "yes"; then
1727 # If we get the same failure with -b, there is no use adding -b.
1728 # So take it out. This plays safe.
1729 LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1730 C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1731 CPPFLAGS="$OLD_CPPFLAGS"
1732 LIBS="$OLD_LIBS"
1733 AC_MSG_RESULT(no)
1734 else
1735 AC_MSG_RESULT(yes)
1736 fi
1737 else
1738 AC_MSG_RESULT(no)
1739 fi
1740 fi
1742 # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1743 # header files included from there.
1744 AC_MSG_CHECKING(for Xkb)
1745 AC_TRY_LINK([#include <X11/Xlib.h>
1746 #include <X11/XKBlib.h>],
1747 [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1748 emacs_xkb=yes, emacs_xkb=no)
1749 AC_MSG_RESULT($emacs_xkb)
1750 if test $emacs_xkb = yes; then
1751 AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1752 fi
1754 AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1755 XScreenNumberOfScreen XSetWMProtocols)
1756 fi
1758 if test "${window_system}" = "x11"; then
1759 AC_MSG_CHECKING(X11 version 6)
1760 AC_CACHE_VAL(emacs_cv_x11_version_6,
1761 [AC_TRY_LINK([#include <X11/Xlib.h>],
1762 [#if XlibSpecificationRelease < 6
1763 fail;
1764 #endif
1765 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1766 if test $emacs_cv_x11_version_6 = yes; then
1767 AC_MSG_RESULT(6 or newer)
1768 AC_DEFINE(HAVE_X11R6, 1,
1769 [Define to 1 if you have the X11R6 or newer version of Xlib.])
1770 else
1771 AC_MSG_RESULT(before 6)
1772 fi
1773 fi
1775 if test "${window_system}" = "x11"; then
1776 AC_MSG_CHECKING(X11 version 5)
1777 AC_CACHE_VAL(emacs_cv_x11_version_5,
1778 [AC_TRY_LINK([#include <X11/Xlib.h>],
1779 [#if XlibSpecificationRelease < 5
1780 fail;
1781 #endif
1782 ], emacs_cv_x11_version_5=yes, emacs_cv_x11_version_5=no)])
1783 if test $emacs_cv_x11_version_5 = yes; then
1784 AC_MSG_RESULT(5 or newer)
1785 HAVE_X11R5=yes
1786 AC_DEFINE(HAVE_X11R5, 1,
1787 [Define to 1 if you have the X11R5 or newer version of Xlib.])
1788 else
1789 HAVE_X11R5=no
1790 AC_MSG_RESULT(before 5)
1791 fi
1792 fi
1794 dnl This function defintion taken from Gnome 2.0
1795 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1796 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1797 dnl also defines GSTUFF_PKG_ERRORS on error
1798 AC_DEFUN(PKG_CHECK_MODULES, [
1799 succeeded=no
1801 if test -z "$PKG_CONFIG"; then
1802 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1803 fi
1805 if test "$PKG_CONFIG" = "no" ; then
1806 echo "*** The pkg-config script could not be found. Make sure it is"
1807 echo "*** in your path, or give the full path to pkg-config with"
1808 echo "*** the PKG_CONFIG environment variable or --with-pkg-config-prog."
1809 echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
1810 else
1811 PKG_CONFIG_MIN_VERSION=0.9.0
1812 if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1813 AC_MSG_CHECKING(for $2)
1815 if $PKG_CONFIG --exists "$2" ; then
1816 AC_MSG_RESULT(yes)
1817 succeeded=yes
1819 AC_MSG_CHECKING($1_CFLAGS)
1820 $1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
1821 AC_MSG_RESULT($$1_CFLAGS)
1823 AC_MSG_CHECKING($1_LIBS)
1824 $1_LIBS=`$PKG_CONFIG --libs "$2"`
1825 AC_MSG_RESULT($$1_LIBS)
1826 else
1827 $1_CFLAGS=""
1828 $1_LIBS=""
1829 ## If we have a custom action on failure, don't print errors, but
1830 ## do set a variable so people can do so.
1831 $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1832 ifelse([$4], ,echo $$1_PKG_ERRORS,)
1833 fi
1835 AC_SUBST($1_CFLAGS)
1836 AC_SUBST($1_LIBS)
1837 else
1838 echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1839 echo "*** See http://www.freedesktop.org/software/pkgconfig"
1840 fi
1841 fi
1843 if test $succeeded = yes; then
1844 ifelse([$3], , :, [$3])
1845 else
1846 ifelse([$4], , AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.]), [$4])
1847 fi
1848 ])
1850 HAVE_GTK=no
1851 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "gtk"; then
1852 if test "$USE_X_TOOLKIT" != "none" && test "$USE_X_TOOLKIT" != "maybe"; then
1853 AC_MSG_ERROR([Conflicting options, --with-gtk is incompatible with --with-x-toolkit=${with_x_toolkit}]);
1854 fi
1855 GLIB_REQUIRED=2.0.1
1856 GTK_REQUIRED=2.0.1
1857 GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1859 dnl Check if --with-pkg-config-prog has been given.
1860 if test "X${with_pkg_config_prog}" != X; then
1861 PKG_CONFIG="${with_pkg_config_prog}"
1862 fi
1863 dnl Checks for libraries.
1864 PKG_CHECK_MODULES(GTK, $GTK_MODULES)
1865 AC_SUBST(GTK_CFLAGS)
1866 AC_SUBST(GTK_LIBS)
1867 C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1868 HAVE_GTK=yes
1869 AC_DEFINE(HAVE_GTK, 1, [Define to 1 if using GTK.])
1870 USE_X_TOOLKIT=none
1872 dnl GTK scrollbars resembles toolkit scrollbars alot, so to avoid
1873 dnl a lot if #ifdef:s, say we have toolkit scrollbars.
1874 with_toolkit_scroll_bars=yes
1875 fi
1877 dnl Do not put whitespace before the #include statements below.
1878 dnl Older compilers (eg sunos4 cc) choke on it.
1879 if test x"${USE_X_TOOLKIT}" = xmaybe; then
1880 if test x"${HAVE_X11R5}" = xyes; then
1881 AC_MSG_CHECKING(X11 version 5 with Xaw)
1882 AC_CACHE_VAL(emacs_cv_x11_version_5_with_xaw,
1883 [AC_TRY_LINK([
1884 #include <X11/Intrinsic.h>
1885 #include <X11/Xaw/Simple.h>],
1886 [],
1887 emacs_cv_x11_version_5_with_xaw=yes,
1888 emacs_cv_x11_version_5_with_xaw=no)])
1889 if test $emacs_cv_x11_version_5_with_xaw = yes; then
1890 AC_MSG_RESULT([5 or newer, with Xaw; use toolkit by default])
1891 USE_X_TOOLKIT=LUCID
1892 else
1893 AC_MSG_RESULT(before 5 or no Xaw; do not use toolkit by default)
1894 USE_X_TOOLKIT=none
1895 fi
1896 else
1897 USE_X_TOOLKIT=none
1898 fi
1899 fi
1901 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1903 if test "${USE_X_TOOLKIT}" != "none"; then
1904 AC_MSG_CHECKING(X11 toolkit version)
1905 AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1906 [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1907 [#if XtSpecificationRelease < 6
1908 fail;
1909 #endif
1910 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1911 HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1912 if test $emacs_cv_x11_toolkit_version_6 = yes; then
1913 AC_MSG_RESULT(6 or newer)
1914 AC_DEFINE(HAVE_X11XTR6, 1,
1915 [Define to 1 if you have the X11R6 or newer version of Xt.])
1916 else
1917 AC_MSG_RESULT(before 6)
1918 fi
1920 dnl If using toolkit, check whether libXmu.a exists.
1921 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1922 OLDLIBS="$LIBS"
1923 if test x$HAVE_X11XTR6 = xyes; then
1924 LIBS="-lXt -lSM -lICE $LIBS"
1925 else
1926 LIBS="-lXt $LIBS"
1927 fi
1928 AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1929 test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1930 fi
1932 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1933 if test "${HAVE_X11}" = "yes"; then
1934 if test "${USE_X_TOOLKIT}" != "none"; then
1935 AC_CHECK_LIB(Xext, XShapeQueryExtension)
1936 fi
1937 fi
1939 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1940 AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1941 # We put this in CFLAGS temporarily to precede other -I options
1942 # that might be in CFLAGS temporarily.
1943 # We put this in CPPFLAGS where it precedes the other -I options.
1944 OLD_CPPFLAGS=$CPPFLAGS
1945 OLD_CFLAGS=$CFLAGS
1946 CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1947 CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1948 [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1949 [int x = 5;],
1950 emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1951 if test $emacs_cv_lesstif = yes; then
1952 # Make sure this -I option remains in CPPFLAGS after it is set
1953 # back to REAL_CPPFLAGS.
1954 # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1955 # have those other -I options anyway. Ultimately, having this
1956 # directory ultimately in CPPFLAGS will be enough.
1957 REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1958 LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1959 else
1960 CFLAGS=$OLD_CFLAGS
1961 CPPFLAGS=$OLD_CPPFLAGS
1962 fi
1963 AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1964 [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1965 [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1966 int x = 5;
1967 #else
1968 Motif version prior to 2.1.
1969 #endif],
1970 emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1971 HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1972 if test $emacs_cv_motif_version_2_1 = yes; then
1973 HAVE_LIBXP=no
1974 AC_DEFINE(HAVE_MOTIF_2_1, 1,
1975 [Define to 1 if you have Motif 2.1 or newer.])
1976 AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1977 if test ${HAVE_LIBXP} = yes; then
1978 AC_DEFINE(HAVE_LIBXP, 1,
1979 [Define to 1 if you have the Xp library (-lXp).])
1980 fi
1981 fi
1982 fi
1984 ### Is -lXaw3d available?
1985 HAVE_XAW3D=no
1986 if test "${HAVE_X11}" = "yes"; then
1987 if test "${USE_X_TOOLKIT}" != "none"; then
1988 dnl Fixme: determine what Scrollbar.h needs to avoid compilation
1989 dnl errors from the test without the `-'.
1990 AC_CHECK_HEADER(X11/Xaw3d/Scrollbar.h,
1991 [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb, HAVE_XAW3D=yes)], , -)
1992 if test "${HAVE_XAW3D}" = "yes"; then
1993 AC_DEFINE(HAVE_XAW3D, 1,
1994 [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1995 fi
1996 fi
1997 fi
1999 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2000 dnl using Motif or Xaw3d is available, and unless
2001 dnl --with-toolkit-scroll-bars=no was specified.
2003 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2004 [Define to 1 if we should use toolkit scroll bars.])dnl
2005 USE_TOOLKIT_SCROLL_BARS=no
2006 if test "${with_toolkit_scroll_bars}" != "no"; then
2007 if test "${USE_X_TOOLKIT}" != "none"; then
2008 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2009 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2010 HAVE_XAW3D=no
2011 USE_TOOLKIT_SCROLL_BARS=yes
2012 elif test "${HAVE_XAW3D}" = "yes"; then
2013 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2014 USE_TOOLKIT_SCROLL_BARS=yes
2015 fi
2016 elif test "${HAVE_GTK}" = "yes"; then
2017 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2018 USE_TOOLKIT_SCROLL_BARS=yes
2019 fi
2020 fi
2022 dnl Don't use X11 input methods if user specifies he doesn't want it
2023 dnl with `--with-xim=no'.
2025 if test "${with_xim}" != "no"; then
2026 AC_DEFINE(USE_XIM, 1,
2027 [Define to 1 if we should use XIM, if it is available.])
2028 fi
2030 ### Use -lXpm if available, unless `--with-xpm=no'.
2031 HAVE_XPM=no
2032 if test "${HAVE_X11}" = "yes"; then
2033 if test "${with_xpm}" != "no"; then
2034 AC_CHECK_HEADER(X11/xpm.h,
2035 AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11))
2036 if test "${HAVE_XPM}" = "yes"; then
2037 AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2038 AC_EGREP_CPP(no_return_alloc_pixels,
2039 [#include "X11/xpm.h"
2040 #ifndef XpmReturnAllocPixels
2041 no_return_alloc_pixels
2042 #endif
2043 ], HAVE_XPM=no, HAVE_XPM=yes)
2045 if test "${HAVE_XPM}" = "yes"; then
2046 AC_MSG_RESULT(yes)
2047 else
2048 AC_MSG_RESULT(no)
2049 fi
2050 fi
2051 fi
2053 if test "${HAVE_XPM}" = "yes"; then
2054 AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2055 fi
2056 fi
2058 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2059 HAVE_JPEG=no
2060 if test "${HAVE_X11}" = "yes"; then
2061 if test "${with_jpeg}" != "no"; then
2062 dnl Checking for jpeglib.h can lose because of a redefinition of
2063 dnl HAVE_STDLIB_H.
2064 AC_CHECK_HEADER(jerror.h,
2065 AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes))
2066 fi
2068 AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2069 if test "${HAVE_JPEG}" = "yes"; then
2070 AC_DEFINE(HAVE_JPEG)
2071 AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2072 [#include <jpeglib.h>
2073 version=JPEG_LIB_VERSION
2074 ],
2075 AC_DEFINE(HAVE_JPEG),
2076 [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2077 HAVE_JPEG=no])
2078 fi
2079 fi
2081 ### Use -lpng if available, unless `--with-png=no'.
2082 HAVE_PNG=no
2083 if test "${HAVE_X11}" = "yes"; then
2084 if test "${with_png}" != "no"; then
2085 AC_CHECK_HEADER(png.h,
2086 AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm))
2087 fi
2089 if test "${HAVE_PNG}" = "yes"; then
2090 AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2091 fi
2092 fi
2094 ### Use -ltiff if available, unless `--with-tiff=no'.
2095 HAVE_TIFF=no
2096 if test "${HAVE_X11}" = "yes"; then
2097 if test "${with_tiff}" != "no"; then
2098 AC_CHECK_HEADER(tiffio.h,
2099 tifflibs="-lz -lm"
2100 # At least one tiff package requires the jpeg library.
2101 if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2102 AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs))
2103 fi
2105 if test "${HAVE_TIFF}" = "yes"; then
2106 AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2107 fi
2108 fi
2110 ### Use -lgif if available, unless `--with-gif=no'.
2111 HAVE_GIF=no
2112 if test "${HAVE_X11}" = "yes"; then
2113 if test "${with_gif}" != "no"; then
2114 AC_CHECK_HEADER(gif_lib.h,
2115 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2116 # Earlier versions can crash Emacs.
2117 AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes))
2118 fi
2120 if test "${HAVE_GIF}" = "yes"; then
2121 AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have the ungif library (-lungif).])
2122 fi
2123 fi
2125 ### Use Mac OS X Carbon API to implement GUI.
2126 HAVE_CARBON=no
2127 if test "${with_carbon}" != "no"; then
2128 AC_CHECK_HEADER(Carbon/Carbon.h, HAVE_CARBON=yes)
2129 fi
2131 if test "${HAVE_CARBON}" = "yes"; then
2132 AC_DEFINE(HAVE_CARBON, 1, [Define to 1 if you are using the Carbon API on Mac OS X.])
2133 window_system=mac
2134 ## Specify the install directory
2135 carbon_appdir=
2136 if test "${carbon_appdir_x}" != ""; then
2137 case ${carbon_appdir_x} in
2138 y | ye | yes) carbon_appdir=/Applications ;;
2139 * ) carbon_appdir=${carbon_appdir_x} ;;
2140 esac
2141 fi
2142 fi
2144 ### Use session management (-lSM -lICE) if available
2145 HAVE_X_SM=no
2146 if test "${HAVE_X11}" = "yes"; then
2147 AC_CHECK_HEADER(X11/SM/SMlib.h,
2148 AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, -lICE))
2150 if test "${HAVE_X_SM}" = "yes"; then
2151 AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2152 case "$LIBS" in
2153 *-lSM*) ;;
2154 *) LIBS="-lSM -lICE $LIBS" ;;
2155 esac
2156 fi
2157 fi
2159 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2160 AC_CACHE_CHECK(whether netdb declares h_errno,
2161 emacs_cv_netdb_declares_h_errno,
2162 [AC_TRY_LINK([#include <netdb.h>],
2163 [return h_errno;],
2164 emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2165 if test $emacs_cv_netdb_declares_h_errno = yes; then
2166 AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2167 fi
2169 AC_FUNC_ALLOCA
2171 # fmod, logb, and frexp are found in -lm on most systems.
2172 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2173 AC_CHECK_LIB(m, sqrt)
2175 # Check for mail-locking functions in a "mail" library
2176 AC_CHECK_LIB(mail, maillock)
2177 dnl Debian, at least:
2178 dnl AC_CHECK_LIB(lockfile, maillock, [AC_DEFINE(HAVE_LIBMAIL)])
2179 AC_CHECK_LIB(lockfile, maillock)
2180 # If we have the shared liblockfile, assume we must use it for mail
2181 # locking (e.g. Debian). If we couldn't link against liblockfile
2182 # (no liblockfile.a installed), ensure that we don't need to.
2183 if test "$ac_cv_lib_lockfile_maillock" = no; then
2184 dnl This works for files generally, not just executables.
2185 dnl Should we look elsewhere for it? Maybe examine /etc/ld.so.conf?
2186 AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2187 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2188 if test $ac_cv_prog_liblockfile = yes; then
2189 AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2190 This probably means that movemail could lose mail.
2191 There may be a `development' package to install containing liblockfile.])
2192 else AC_DEFINE(LIBMAIL, -llockfile, [Define to -llockfile if it is usable.])
2193 fi
2194 else :
2195 fi
2196 AC_CHECK_FUNCS(touchlock)
2197 AC_CHECK_HEADERS(maillock.h)
2199 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2200 rename closedir mkdir rmdir sysinfo \
2201 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime res_init setsid \
2202 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2203 utimes setrlimit setpgid getcwd getwd shutdown strftime getaddrinfo \
2204 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2205 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2206 gai_strerror mkstemp getline getdelim mremap memmove fsync bzero memset)
2208 AC_CHECK_HEADERS(sys/un.h)
2210 AC_FUNC_MKTIME
2211 if test "$ac_cv_func_working_mktime" = no; then
2212 AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2213 fi
2215 AC_FUNC_GETLOADAVG
2217 AC_FUNC_FSEEKO
2219 AC_FUNC_GETPGRP
2221 # UNIX98 PTYs.
2222 AC_CHECK_FUNCS(grantpt)
2224 # PTY-related GNU extensions.
2225 AC_CHECK_FUNCS(getpt)
2227 # Check this now, so that we will NOT find the above functions in ncurses.
2228 # That is because we have not set up to link ncurses in lib-src.
2229 # It's better to believe a function is not available
2230 # than to expect to find it in ncurses.
2231 AC_CHECK_LIB(ncurses, tparm)
2233 # Do we need the Hesiod library to provide the support routines?
2234 if test "$with_hesiod" = yes ; then
2235 # Don't set $LIBS here -- see comments above.
2236 resolv=no
2237 AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2238 [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2239 [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2240 if test "$resolv" = yes ; then
2241 RESOLVLIB=-lresolv
2242 AC_DEFINE(HAVE_LIBRESOLV, 1,
2243 [Define to 1 if you have the resolv library (-lresolv).])
2244 else
2245 RESOLVLIB=
2246 fi
2247 AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2248 AC_DEFINE(HAVE_LIBHESIOD, 1,
2249 [Define to 1 if you have the hesiod library (-lhesiod).]),
2250 :, $RESOLVLIB)])
2251 fi
2253 # These tell us which Kerberos-related libraries to use.
2254 if test "${with_kerberos+set}" = set; then
2255 AC_CHECK_LIB(com_err, com_err)
2256 AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2257 AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2258 AC_CHECK_LIB(krb5, krb5_init_context)
2259 if test "${with_kerberos5+set}" != set; then
2260 AC_CHECK_LIB(des425, des_cbc_encrypt,,
2261 AC_CHECK_LIB(des, des_cbc_encrypt))
2262 AC_CHECK_LIB(krb4, krb_get_cred,,
2263 AC_CHECK_LIB(krb, krb_get_cred))
2264 fi
2266 if test "${with_kerberos5+set}" = set; then
2267 AC_CHECK_HEADERS(krb5.h)
2268 else
2269 AC_CHECK_HEADERS(des.h,,
2270 [AC_CHECK_HEADERS(kerberosIV/des.h,,
2271 [AC_CHECK_HEADERS(kerberos/des.h)])])
2272 AC_CHECK_HEADERS(krb.h,,
2273 [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2274 [AC_CHECK_HEADERS(kerberos/krb.h)])])
2275 fi
2276 AC_CHECK_HEADERS(com_err.h)
2277 fi
2279 # Solaris requires -lintl if you want strerror (which calls dgettext)
2280 # to return localized messages.
2281 AC_CHECK_LIB(intl, dgettext)
2283 AC_MSG_CHECKING(whether localtime caches TZ)
2284 AC_CACHE_VAL(emacs_cv_localtime_cache,
2285 [if test x$ac_cv_func_tzset = xyes; then
2286 AC_TRY_RUN([#include <time.h>
2287 extern char **environ;
2288 unset_TZ ()
2289 {
2290 char **from, **to;
2291 for (to = from = environ; (*to = *from); from++)
2292 if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2293 to++;
2294 }
2295 char TZ_GMT0[] = "TZ=GMT0";
2296 char TZ_PST8[] = "TZ=PST8";
2297 main()
2298 {
2299 time_t now = time ((time_t *) 0);
2300 int hour_GMT0, hour_unset;
2301 if (putenv (TZ_GMT0) != 0)
2302 exit (1);
2303 hour_GMT0 = localtime (&now)->tm_hour;
2304 unset_TZ ();
2305 hour_unset = localtime (&now)->tm_hour;
2306 if (putenv (TZ_PST8) != 0)
2307 exit (1);
2308 if (localtime (&now)->tm_hour == hour_GMT0)
2309 exit (1);
2310 unset_TZ ();
2311 if (localtime (&now)->tm_hour != hour_unset)
2312 exit (1);
2313 exit (0);
2314 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2315 [# If we have tzset, assume the worst when cross-compiling.
2316 emacs_cv_localtime_cache=yes])
2317 else
2318 # If we lack tzset, report that localtime does not cache TZ,
2319 # since we can't invalidate the cache if we don't have tzset.
2320 emacs_cv_localtime_cache=no
2321 fi])dnl
2322 AC_MSG_RESULT($emacs_cv_localtime_cache)
2323 if test $emacs_cv_localtime_cache = yes; then
2324 AC_DEFINE(LOCALTIME_CACHE, 1,
2325 [Define to 1 if localtime caches TZ.])
2326 fi
2328 if test "x$HAVE_TIMEVAL" = xyes; then
2329 AC_CHECK_FUNCS(gettimeofday)
2330 if test $ac_cv_func_gettimeofday = yes; then
2331 AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2332 emacs_cv_gettimeofday_two_arguments,
2333 [AC_TRY_COMPILE([
2334 #ifdef TIME_WITH_SYS_TIME
2335 #include <sys/time.h>
2336 #include <time.h>
2337 #else
2338 #ifdef HAVE_SYS_TIME_H
2339 #include <sys/time.h>
2340 #else
2341 #include <time.h>
2342 #endif
2343 #endif],
2344 [struct timeval time;
2345 gettimeofday (&time, 0);],
2346 emacs_cv_gettimeofday_two_arguments=yes,
2347 emacs_cv_gettimeofday_two_arguments=no)])
2348 if test $emacs_cv_gettimeofday_two_arguments = no; then
2349 AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2350 [Define to 1 if gettimeofday accepts only one argument.])
2351 fi
2352 fi
2353 fi
2355 dnl Note that AC_STRUCT_TIMEZONE doesn't do what you might expect.
2356 if test "$ac_cv_func_gettimeofday" = yes; then
2357 AC_CACHE_CHECK([for struct timezone], emacs_cv_struct_timezone,
2358 [AC_TRY_COMPILE([#include <sys/time.h>],
2359 [struct timezone tz;],
2360 dnl It may be that we can't call gettimeofday with a non-null pointer,
2361 dnl even though we have struct timezone (e.g. HPUX). In that case
2362 dnl we'll lie about struct timezone.
2363 [AC_TRY_RUN([
2364 #ifdef TIME_WITH_SYS_TIME
2365 #include <sys/time.h>
2366 #include <time.h>
2367 #else
2368 #ifdef HAVE_SYS_TIME_H
2369 #include <sys/time.h>
2370 #else
2371 #include <time.h>
2372 #endif
2373 #endif
2374 main () {
2375 struct timeval time;
2376 struct timezone dummy;
2377 exit (gettimeofday (&time, &dummy));
2378 }],
2379 emacs_cv_struct_timezone=yes,
2380 emacs_cv_struct_timezone=no, emacs_cv_struct_timezone=yes)],
2381 emacs_cv_struct_timezone=no)])
2382 fi
2384 ok_so_far=yes
2385 AC_CHECK_FUNC(socket, , ok_so_far=no)
2386 if test $ok_so_far = yes; then
2387 AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2388 fi
2389 if test $ok_so_far = yes; then
2390 AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2391 fi
2392 if test $ok_so_far = yes; then
2393 dnl Fixme: Not used. Should this be HAVE_SOCKETS?
2394 AC_DEFINE(HAVE_INET_SOCKETS, 1,
2395 [Define to 1 if you have inet sockets.])
2396 fi
2398 if test -f /usr/lpp/X11/bin/smt.exp; then
2399 AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2400 [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2401 fi
2403 AC_MSG_CHECKING(whether system supports dynamic ptys)
2404 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2405 AC_MSG_RESULT(yes)
2406 AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2407 else
2408 AC_MSG_RESULT(no)
2409 fi
2411 AC_FUNC_FORK
2413 dnl Adapted from Haible's version.
2414 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2415 [AC_TRY_LINK([#include <langinfo.h>],
2416 [char* cs = nl_langinfo(CODESET);],
2417 emacs_cv_langinfo_codeset=yes,
2418 emacs_cv_langinfo_codeset=no)
2419 ])
2420 if test $emacs_cv_langinfo_codeset = yes; then
2421 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2422 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2423 fi
2425 AC_CHECK_TYPES(size_t)
2427 dnl Restrict could probably be used effectively other than in regex.c.
2428 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2429 [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2430 emacs_cv_c_restrict=yes,
2431 [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2432 emacs_cv_c_restrict=__restrict,
2433 emacs_cv_c_restrict=no)])])
2434 case "$emacs_cv_c_restrict" in
2435 yes) emacs_restrict=restrict;;
2436 no) emacs_restrict="";;
2437 *) emacs_restrict="$emacs_cv_c_restrict";;
2438 esac
2439 if test "$emacs_restrict" != __restrict; then
2440 AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2441 [Define to compiler's equivalent of C99 restrict keyword.
2442 Don't define if equivalent is `__restrict'.])
2443 fi
2445 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2446 [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2447 emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2448 if test "$emacs_cv_c_restrict_arr" = yes; then
2449 AC_DEFINE(__restrict_arr, __restrict,
2450 [Define to compiler's equivalent of C99 restrict keyword in array
2451 declarations. Define as empty for no equivalent.])
2452 fi
2454 AC_CHECK_HEADERS(nlist.h, [AC_DEFINE(NLIST_STRUCT, 1,
2455 [Define to 1 if you have <nlist.h>.])])
2457 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2458 dnl how the tty code is related to POSIX and/or other versions of termios.
2460 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used. (Needs libobj replacement.)
2462 # Set up the CFLAGS for real compilation, so we can substitute it.
2463 CFLAGS="$REAL_CFLAGS"
2464 CPPFLAGS="$REAL_CPPFLAGS"
2466 #### Find out which version of Emacs this is.
2467 [version=`grep 'defconst[ ]*emacs-version' ${srcdir}/lisp/version.el \
2468 | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2469 if test x"${version}" = x; then
2470 AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2471 fi
2473 ### Specify what sort of things we'll be editing into Makefile and config.h.
2474 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2475 AC_SUBST(version)
2476 AC_SUBST(configuration)
2477 AC_SUBST(canonical)
2478 AC_SUBST(srcdir)
2479 AC_SUBST(prefix)
2480 AC_SUBST(exec_prefix)
2481 AC_SUBST(bindir)
2482 AC_SUBST(datadir)
2483 AC_SUBST(sharedstatedir)
2484 AC_SUBST(libexecdir)
2485 AC_SUBST(mandir)
2486 AC_SUBST(infodir)
2487 AC_SUBST(lispdir)
2488 AC_SUBST(locallisppath)
2489 AC_SUBST(lisppath)
2490 AC_SUBST(x_default_search_path)
2491 AC_SUBST(etcdir)
2492 AC_SUBST(archlibdir)
2493 AC_SUBST(docdir)
2494 AC_SUBST(bitmapdir)
2495 AC_SUBST(gamedir)
2496 AC_SUBST(gameuser)
2497 AC_SUBST(c_switch_system)
2498 AC_SUBST(c_switch_machine)
2499 AC_SUBST(LD_SWITCH_X_SITE)
2500 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2501 AC_SUBST(C_SWITCH_X_SITE)
2502 AC_SUBST(CFLAGS)
2503 AC_SUBST(X_TOOLKIT_TYPE)
2504 AC_SUBST(machfile)
2505 AC_SUBST(opsysfile)
2506 AC_SUBST(GETLOADAVG_LIBS)
2507 AC_SUBST(carbon_appdir)
2509 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "${canonical}",
2510 [Define to the canonical Emacs configuration name.])
2511 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2512 [Define to the options passed to configure.])
2513 AC_DEFINE_UNQUOTED(config_machfile, "${machfile}",
2514 [Define to the used machine dependent file.])
2515 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2516 [Define to the used os dependent file.])
2517 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2518 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2519 may need to deal with X Windows. For instance, if you've defined
2520 HAVE_X_WINDOWS above and your X libraries aren't in a place that
2521 your loader can find on its own, you might want to add "-L/..." or
2522 something similar.])
2523 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2524 [Define LD_SWITCH_X_SITE_AUX with an -R option
2525 in case it's needed (for Solaris, for example).])
2526 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE, ${C_SWITCH_X_SITE},
2527 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2528 may need to deal with X Windows. For instance, if you've defined
2529 HAVE_X_WINDOWS above and your X include files aren't in a place
2530 that your compiler can find on its own, you might want to add
2531 "-I/..." or something similar.])
2532 AC_DEFINE_UNQUOTED(UNEXEC_SRC, ${UNEXEC_SRC},
2533 [Define to the unexec source file name.])
2535 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2536 AC_DEFINE(HAVE_X_WINDOWS, 1,
2537 [Define to 1 if you want to use the X window system.])
2538 fi
2539 if test "${USE_X_TOOLKIT}" != "none" ; then
2540 AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2541 fi
2542 if test "${HAVE_X11}" = "yes" ; then
2543 AC_DEFINE(HAVE_X11, 1,
2544 [Define to 1 if you want to use version 11 of X windows.
2545 Otherwise, Emacs expects to use version 10.])
2546 fi
2547 if test "${HAVE_XFREE386}" = "yes" ; then
2548 AC_DEFINE(HAVE_XFREE386, 1, [Define to 1 if you're using XFree386.])
2549 fi
2550 if test "${HAVE_MENUS}" = "yes" ; then
2551 AC_DEFINE(HAVE_MENUS, 1,
2552 [Define to 1 if you have mouse menus.
2553 (This is automatic if you use X, but the option to specify it remains.)
2554 It is also defined with other window systems that support xmenu.c.])
2555 fi
2556 if test "${GNU_MALLOC}" = "yes" ; then
2557 AC_DEFINE(GNU_MALLOC, 1,
2558 [Define to 1 if you want to use the GNU memory allocator.])
2559 fi
2560 if test "${REL_ALLOC}" = "yes" ; then
2561 AC_DEFINE(REL_ALLOC, 1,
2562 [Define REL_ALLOC if you want to use the relocating allocator for
2563 buffer space.])
2564 fi
2566 AH_TOP([/* GNU Emacs site configuration template file.
2567 Copyright (C) 1988, 93, 94, 99, 2000, 2002 Free Software Foundation, Inc.
2569 This file is part of GNU Emacs.
2571 GNU Emacs is free software; you can redistribute it and/or modify
2572 it under the terms of the GNU General Public License as published by
2573 the Free Software Foundation; either version 2, or (at your option)
2574 any later version.
2576 GNU Emacs is distributed in the hope that it will be useful,
2577 but WITHOUT ANY WARRANTY; without even the implied warranty of
2578 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
2579 GNU General Public License for more details.
2581 You should have received a copy of the GNU General Public License
2582 along with GNU Emacs; see the file COPYING. If not, write to the
2583 Free Software Foundation, Inc., 59 Temple Place - Suite 330,
2584 Boston, MA 02111-1307, USA. */
2587 /* No code in Emacs #includes config.h twice, but some bits of code
2588 intended to work with other packages as well (like gmalloc.c)
2589 think they can include it as many times as they like. */
2590 #ifndef EMACS_CONFIG_H
2591 #define EMACS_CONFIG_H
2592 ])dnl
2594 AH_BOTTOM([
2595 /* If we're using any sort of window system, define some consequences. */
2596 #ifdef HAVE_X_WINDOWS
2597 #define HAVE_WINDOW_SYSTEM
2598 #define MULTI_KBOARD
2599 #define HAVE_MOUSE
2600 #endif
2602 /* If we're using the Carbon API on Mac OS X, define a few more
2603 variables as well. */
2604 #ifdef HAVE_CARBON
2605 #define HAVE_WINDOW_SYSTEM
2606 #define HAVE_MOUSE
2607 #define HAVE_MENUS
2608 #endif
2610 /* Define USER_FULL_NAME to return a string
2611 that is the user's full name.
2612 It can assume that the variable `pw'
2613 points to the password file entry for this user.
2615 At some sites, the pw_gecos field contains
2616 the user's full name. If neither this nor any other
2617 field contains the right thing, use pw_name,
2618 giving the user's login name, since that is better than nothing. */
2619 #define USER_FULL_NAME pw->pw_gecos
2621 /* Define AMPERSAND_FULL_NAME if you use the convention
2622 that & in the full name stands for the login id. */
2623 /* Turned on June 1996 supposing nobody will mind it. */
2624 #define AMPERSAND_FULL_NAME
2626 /* Define HAVE_SOUND if we have sound support. We know it works
2627 and compiles only on the specified platforms. For others,
2628 it probably doesn't make sense to try. */
2630 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2631 #ifdef HAVE_MACHINE_SOUNDCARD_H
2632 #define HAVE_SOUND 1
2633 #endif
2634 #ifdef HAVE_SYS_SOUNDCARD_H
2635 #define HAVE_SOUND 1
2636 #endif
2637 #ifdef HAVE_SOUNDCARD_H
2638 #define HAVE_SOUND 1
2639 #endif
2640 #endif /* __FreeBSD__ || __NetBSD__ || __linux__ */
2642 /* If using GNU, then support inline function declarations. */
2643 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2644 generally, because even if non-gcc compilers accept `inline', they
2645 may reject `extern inline'. */
2646 #ifdef __GNUC__
2647 #define INLINE __inline__
2648 #else
2649 #define INLINE
2650 #endif
2652 /* Include the os and machine dependent files. */
2653 #include config_opsysfile
2654 #include config_machfile
2656 /* Load in the conversion definitions if this system
2657 needs them and the source file being compiled has not
2658 said to inhibit this. There should be no need for you
2659 to alter these lines. */
2661 #ifdef SHORTNAMES
2662 #ifndef NO_SHORTNAMES
2663 #include "../shortnames/remap.h"
2664 #endif /* not NO_SHORTNAMES */
2665 #endif /* SHORTNAMES */
2667 /* If no remapping takes place, static variables cannot be dumped as
2668 pure, so don't worry about the `static' keyword. */
2669 #ifdef NO_REMAP
2670 #undef static
2671 #endif
2673 /* Define `subprocesses' should be defined if you want to
2674 have code for asynchronous subprocesses
2675 (as used in M-x compile and M-x shell).
2676 These do not work for some USG systems yet;
2677 for the ones where they work, the s/SYSTEM.h file defines this flag. */
2679 #ifndef VMS
2680 #ifndef USG
2681 /* #define subprocesses */
2682 #endif
2683 #endif
2685 /* SIGTYPE is the macro we actually use. */
2686 #ifndef SIGTYPE
2687 #define SIGTYPE RETSIGTYPE
2688 #endif
2690 #ifdef emacs /* Don't do this for lib-src. */
2691 /* Tell regex.c to use a type compatible with Emacs. */
2692 #define RE_TRANSLATE_TYPE Lisp_Object
2693 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2694 #define RE_TRANSLATE_P(TBL) (XFASTINT (TBL) != 0)
2695 #endif
2697 /* Avoid link-time collision with system mktime if we will use our own. */
2698 #if ! HAVE_MKTIME || BROKEN_MKTIME
2699 #define mktime emacs_mktime
2700 #endif
2702 /* The rest of the code currently tests the CPP symbol BSTRING.
2703 Override any claims made by the system-description files.
2704 Note that on some SCO version it is possible to have bcopy and not bcmp. */
2705 #undef BSTRING
2706 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2707 #define BSTRING
2708 #endif
2710 /* Some of the files of Emacs which are intended for use with other
2711 programs assume that if you have a config.h file, you must declare
2712 the type of getenv.
2714 This declaration shouldn't appear when alloca.s or Makefile.in
2715 includes config.h. */
2716 #ifndef NOT_C_CODE
2717 extern char *getenv ();
2718 #endif
2720 /* These default definitions are good for almost all machines.
2721 The exceptions override them in m/MACHINE.h. */
2723 #ifndef BITS_PER_CHAR
2724 #define BITS_PER_CHAR 8
2725 #endif
2727 #ifndef BITS_PER_SHORT
2728 #define BITS_PER_SHORT 16
2729 #endif
2731 /* Note that lisp.h uses this in a preprocessor conditional, so it
2732 would not work to use sizeof. That being so, we do all of them
2733 without sizeof, for uniformity's sake. */
2734 #ifndef BITS_PER_INT
2735 #define BITS_PER_INT 32
2736 #endif
2738 #ifndef BITS_PER_LONG
2739 #ifdef _LP64
2740 #define BITS_PER_LONG 64
2741 #else
2742 #define BITS_PER_LONG 32
2743 #endif
2744 #endif
2746 /* Define if the compiler supports function prototypes. It may do so
2747 but not define __STDC__ (e.g. DEC C by default) or may define it as
2748 zero. */
2749 #undef PROTOTYPES
2750 /* For mktime.c: */
2751 #ifndef __P
2752 # if defined PROTOTYPES
2753 # define __P(args) args
2754 # else
2755 # define __P(args) ()
2756 # endif /* GCC. */
2757 #endif /* __P */
2759 /* Don't include "string.h" or <stdlib.h> in non-C code. */
2760 #ifndef NOT_C_CODE
2761 #ifdef HAVE_STRING_H
2762 #include "string.h"
2763 #endif
2764 #ifdef HAVE_STRINGS_H
2765 #include "strings.h" /* May be needed for bcopy & al. */
2766 #endif
2767 #ifdef HAVE_STDLIB_H
2768 #include <stdlib.h>
2769 #endif
2770 #ifndef __GNUC__
2771 # ifdef HAVE_ALLOCA_H
2772 # include <alloca.h>
2773 # else /* AIX files deal with #pragma. */
2774 # ifndef alloca /* predefined by HP cc +Olibcalls */
2775 char *alloca ();
2776 # endif
2777 # endif /* HAVE_ALLOCA_H */
2778 #endif /* __GNUC__ */
2779 #ifndef HAVE_SIZE_T
2780 typedef unsigned size_t;
2781 #endif
2782 #endif /* NOT_C_CODE */
2784 /* Define HAVE_X_I18N if we have usable i18n support. */
2786 #ifdef HAVE_X11R6
2787 #define HAVE_X_I18N
2788 #elif defined HAVE_X11R5 && !defined X11R5_INHIBIT_I18N
2789 #define HAVE_X_I18N
2790 #endif
2792 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support. */
2794 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2795 #define HAVE_X11R6_XIM
2796 #endif
2798 /* Should we enable expensive run-time checking of data types? */
2799 #undef ENABLE_CHECKING
2801 #if defined __GNUC__ && (__GNUC__ > 2 \
2802 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2803 #define NO_RETURN __attribute__ ((__noreturn__))
2804 #else
2805 #define NO_RETURN /* nothing */
2806 #endif
2808 /* These won't be used automatically yet. We also need to know, at least,
2809 that the stack is continuous. */
2810 #ifdef __GNUC__
2811 # ifndef GC_SETJMP_WORKS
2812 /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2813 see NON_SAVING_SETJMP in the target descriptions. */
2814 /* Exceptions (see NON_SAVING_SETJMP in target description) are ns32k,
2815 SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2816 Fixme: Deal with ns32k, SVR3. */
2817 # define GC_SETJMP_WORKS 1
2818 # endif
2819 # ifndef GC_LISP_OBJECT_ALIGNMENT
2820 # define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2821 # endif
2822 #endif
2824 #ifndef HAVE_BCOPY
2825 #define bcopy(a,b,s) memcpy (b,a,s)
2826 #endif
2827 #ifndef HAVE_BZERO
2828 #define bzero(a,s) memset (a,0,s)
2829 #endif
2830 #ifndef HAVE_BCMP
2831 #define BCMP memcmp
2832 #endif
2834 #endif /* EMACS_CONFIG_H */
2836 /*
2837 Local Variables:
2838 mode: c
2839 End:
2840 */
2841 ])dnl
2843 #### Report on what we decided to do.
2844 #### Report GTK as a toolkit, even if it doesn't use Xt.
2845 #### It makes printing result more understandable as using GTK sets
2846 #### toolkit_scroll_bars to yes by default.
2847 if test "${HAVE_GTK}" = "yes"; then
2848 USE_X_TOOLKIT=GTK
2849 fi
2851 echo "
2852 Configured for \`${canonical}'.
2854 Where should the build process find the source code? ${srcdir}
2855 What operating system and machine description files should Emacs use?
2856 \`${opsysfile}' and \`${machfile}'
2857 What compiler should emacs be built with? ${CC} ${CFLAGS}
2858 Should Emacs use the GNU version of malloc? ${GNU_MALLOC}${GNU_MALLOC_reason}
2859 Should Emacs use a relocating allocator for buffers? ${REL_ALLOC}
2860 Should Emacs use mmap(2) for buffer allocation? $use_mmap_for_buffers
2861 What window system should Emacs use? ${window_system}
2862 What toolkit should Emacs use? ${USE_X_TOOLKIT}"
2864 if test -n "${x_includes}"; then
2865 echo " Where do we find X Windows header files? ${x_includes}"
2866 else
2867 echo " Where do we find X Windows header files? Standard dirs"
2868 fi
2869 if test -n "${x_libraries}"; then
2870 echo " Where do we find X Windows libraries? ${x_libraries}"
2871 else
2872 echo " Where do we find X Windows libraries? Standard dirs"
2873 fi
2875 echo " Does Emacs use -lXaw3d? ${HAVE_XAW3D}"
2876 echo " Does Emacs use -lXpm? ${HAVE_XPM}"
2877 echo " Does Emacs use -ljpeg? ${HAVE_JPEG}"
2878 echo " Does Emacs use -ltiff? ${HAVE_TIFF}"
2879 echo " Does Emacs use -lungif? ${HAVE_GIF}"
2880 echo " Does Emacs use -lpng? ${HAVE_PNG}"
2881 echo " Does Emacs use X toolkit scroll bars? ${USE_TOOLKIT_SCROLL_BARS}"
2882 echo
2884 # Remove any trailing slashes in these variables.
2885 [test "${prefix}" != NONE &&
2886 prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
2887 test "${exec_prefix}" != NONE &&
2888 exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
2890 ## Check if the C preprocessor will convert `..' to `. .'. If so, set
2891 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
2892 ## from Makefile.c can correctly provide the arg `-traditional' to the
2893 ## C preprocessor.
2895 AC_EGREP_CPP(yes..yes,
2896 [yes..yes],
2897 CPP_NEED_TRADITIONAL=no,
2898 CPP_NEED_TRADITIONAL=yes)
2900 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
2901 man/Makefile lwlib/Makefile src/Makefile.c:src/Makefile.in \
2902 lisp/Makefile lispref/Makefile lispintro/Makefile leim/Makefile, [
2904 ### Make the necessary directories, if they don't exist.
2905 for dir in etc lisp ; do
2906 test -d ${dir} || mkdir ${dir}
2907 done
2909 # Build src/Makefile from ${srcdir}/src/Makefile.c
2910 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
2911 # This must be done after src/config.h is built, since we rely on that file.
2913 # Now get this: Some word that is part of the ${srcdir} directory name
2914 # or the ${configuration} value might, just might, happen to be an
2915 # identifier like `sun4' or `i386' or something, and be predefined by
2916 # the C preprocessor to some helpful value like 1, or maybe the empty
2917 # string. Needless to say consequent macro substitutions are less
2918 # than conducive to the makefile finding the correct directory.
2919 [undefs="`echo $top_srcdir $configuration $canonical |
2920 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/ *$//' \
2921 -e 's/ */ -U/g' -e 's/-U[0-9][^ ]*//g' \
2922 `"]
2924 echo creating src/epaths.h
2925 ${MAKE-make} epaths-force
2927 # As of 2000-11-19, newest development versions of GNU cpp preprocess
2928 # `..' to `. .' unless invoked with -traditional
2930 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
2931 CPPFLAGS="$CPPFLAGS -traditional"
2932 fi
2934 echo creating lib-src/Makefile
2935 ( cd lib-src
2936 rm -f junk.c junk1.c junk2.c
2937 sed -e '/start of cpp stuff/q' \
2938 < Makefile.c > junk1.c
2939 sed -e '1,/start of cpp stuff/d'\
2940 -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2941 < Makefile.c > junk.c
2942 $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2943 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
2944 cat junk1.c junk2.c > Makefile.new
2945 rm -f junk.c junk1.c junk2.c
2946 chmod 444 Makefile.new
2947 mv -f Makefile.new Makefile
2948 )
2950 echo creating src/Makefile
2951 ( cd src
2952 rm -f junk.c junk1.c junk2.c
2953 sed -e '/start of cpp stuff/q' \
2954 < Makefile.c > junk1.c
2955 sed -e '1,/start of cpp stuff/d'\
2956 -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2957 < Makefile.c > junk.c
2958 $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2959 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
2960 cat junk1.c junk2.c > Makefile.new
2961 rm -f junk.c junk1.c junk2.c
2962 chmod 444 Makefile.new
2963 mv -f Makefile.new Makefile
2964 )
2966 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
2967 echo creating src/.gdbinit
2968 echo source $srcdir/src/.gdbinit > src/.gdbinit
2969 fi
2971 # This is how we know whether to re-run configure in certain cases.
2972 touch src/config.stamp
2974 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS"])