lisp/dired-x.el

   1 ;;; dired-x.el --- extra Dired functionality  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 1993-1994, 1997, 2001-2015 Free Software Foundation,
   4 ;; Inc.
   5
   6 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   7 ;;      Lawrence R. Dodd <dodd@roebling.poly.edu>
   8 ;; Maintainer: Romain Francoise <rfrancoise@gnu.org>
   9 ;; Keywords: dired extensions files
  10 ;; Package: emacs
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; This is based on Sebastian Kremer's excellent dired-x.el (Dired Extra),
  30 ;; version 1.191, adapted for GNU Emacs.  See the `dired-x' info pages.
  31
  32 ;; USAGE: In your ~/.emacs,
  33 ;;
  34 ;; (add-hook 'dired-load-hook
  35 ;;           (lambda ()
  36 ;;                       (load "dired-x")
  37 ;;                       ;; Set global variables here.  For example:
  38 ;;                       ;; (setq dired-guess-shell-gnutar "gtar")
  39 ;;                       ))
  40 ;; (add-hook 'dired-mode-hook
  41 ;;           (lambda ()
  42 ;;                       ;; Set buffer-local variables here.  For example:
  43 ;;                       ;; (dired-omit-mode 1)
  44 ;;                       ))
  45 ;;
  46 ;; At load time dired-x.el will install itself and bind some dired keys.
  47 ;; Some dired.el and dired-aux.el functions have extra features if
  48 ;; dired-x is loaded.
  49
  50 ;; User customization: M-x customize-group RET dired-x RET.
  51
  52 ;; *Please* see the `dired-x' info pages for more details.
  53
  54 \f
  55 ;;; Code:
  56
  57 ;; This is a no-op if dired-x is being loaded via `dired-load-hook',
  58 ;; but maybe not if a dired-x function is being autoloaded.
  59 (require 'dired)
  60
  61 ;;; User-defined variables.
  62
  63 (defgroup dired-x nil
  64   "Extended directory editing (dired-x)."
  65   :group 'dired)
  66
  67 (defgroup dired-keys nil
  68   "Dired keys customizations."
  69   :prefix "dired-"
  70   :group 'dired-x)
  71
  72 (defcustom dired-bind-vm nil
  73   "Non-nil means \"V\" runs `dired-vm', otherwise \"V\" runs `dired-rmail'.
  74 RMAIL files in the old Babyl format (used before before Emacs 23.1)
  75 contain \"-*- rmail -*-\" at the top, so `dired-find-file'
  76 will run `rmail' on these files.  New RMAIL files use the standard
  77 mbox format, and so cannot be distinguished in this way."
  78   :type 'boolean
  79   :group 'dired-keys)
  80
  81 (defcustom dired-bind-jump t
  82   "Non-nil means bind `dired-jump' to C-x C-j, otherwise do not.
  83 Setting this variable directly after dired-x is loaded has no effect -
  84 use \\[customize]."
  85   :type 'boolean
  86   :set (lambda (sym val)
  87          (if (set sym val)
  88              (progn
  89                (define-key ctl-x-map "\C-j" 'dired-jump)
  90                (define-key ctl-x-4-map "\C-j" 'dired-jump-other-window))
  91            (if (eq 'dired-jump (lookup-key ctl-x-map "\C-j"))
  92                (define-key ctl-x-map "\C-j" nil))
  93            (if (eq 'dired-jump-other-window (lookup-key ctl-x-4-map "\C-j"))
  94                (define-key ctl-x-4-map "\C-j" nil))))
  95   :group 'dired-keys)
  96
  97 (defcustom dired-bind-man t
  98   "Non-nil means bind `dired-man' to \"N\" in Dired, otherwise do not.
  99 Setting this variable directly after dired-x is loaded has no effect -
 100 use \\[customize]."
 101   :type 'boolean
 102   :set (lambda (sym val)
 103          (if (set sym val)
 104              (define-key dired-mode-map "N" 'dired-man)
 105            (if (eq 'dired-man (lookup-key dired-mode-map "N"))
 106                (define-key dired-mode-map "N" nil))))
 107   :group 'dired-keys)
 108
 109 (defcustom dired-bind-info t
 110   "Non-nil means bind `dired-info' to \"I\" in Dired, otherwise do not.
 111 Setting this variable directly after dired-x is loaded has no effect -
 112 use \\[customize]."
 113   :type 'boolean
 114   :set (lambda (sym val)
 115          (if (set sym val)
 116              (define-key dired-mode-map "I" 'dired-info)
 117            (if (eq 'dired-info (lookup-key dired-mode-map "I"))
 118                (define-key dired-mode-map "I" nil))))
 119   :group 'dired-keys)
 120
 121 (defcustom dired-vm-read-only-folders nil
 122   "If non-nil, \\[dired-vm] will visit all folders read-only.
 123 If neither nil nor t, e.g. the symbol `if-file-read-only', only
 124 files not writable by you are visited read-only."
 125   :type '(choice (const :tag "off" nil)
 126                  (const :tag "on" t)
 127                  (other :tag "non-writable only" if-file-read-only))
 128   :group 'dired-x)
 129
 130 (defcustom dired-omit-size-limit 30000
 131   "Maximum size for the \"omitting\" feature.
 132 If nil, there is no maximum size."
 133   :type '(choice (const :tag "no maximum" nil) integer)
 134   :group 'dired-x)
 135
 136 ;; For backward compatibility
 137 (define-obsolete-variable-alias 'dired-omit-files-p 'dired-omit-mode "22.1")
 138 (define-minor-mode dired-omit-mode
 139   "Toggle omission of uninteresting files in Dired (Dired-Omit mode).
 140 With a prefix argument ARG, enable Dired-Omit mode if ARG is
 141 positive, and disable it otherwise.  If called from Lisp, enable
 142 the mode if ARG is omitted or nil.
 143
 144 Dired-Omit mode is a buffer-local minor mode.  When enabled in a
 145 Dired buffer, Dired does not list files whose filenames match
 146 regexp `dired-omit-files', nor files ending with extensions in
 147 `dired-omit-extensions'.
 148
 149 To enable omitting in every Dired buffer, you can put this in
 150 your init file:
 151
 152   (add-hook \\='dired-mode-hook (lambda () (dired-omit-mode)))
 153
 154 See Info node `(dired-x) Omitting Variables' for more information."
 155   :group 'dired-x
 156   (if dired-omit-mode
 157       ;; This will mention how many lines were omitted:
 158       (let ((dired-omit-size-limit nil)) (dired-omit-expunge))
 159     (revert-buffer)))
 160
 161 (put 'dired-omit-mode 'safe-local-variable 'booleanp)
 162
 163 (defcustom dired-omit-files "^\\.?#\\|^\\.$\\|^\\.\\.$"
 164   "Filenames matching this regexp will not be displayed.
 165 This only has effect when `dired-omit-mode' is t.  See interactive function
 166 `dired-omit-mode' (\\[dired-omit-mode]) and variable
 167 `dired-omit-extensions'.  The default is to omit  `.', `..', auto-save
 168 files and lock files."
 169   :type 'regexp
 170   :group 'dired-x)
 171
 172 (defcustom dired-omit-verbose t
 173   "When non-nil, show messages when omitting files.
 174 When nil, don't show messages."
 175   :version "24.1"
 176   :type 'boolean
 177   :group 'dired-x)
 178
 179 (defcustom dired-find-subdir nil           ; t is pretty near to DWIM...
 180   "If non-nil, Dired always finds a directory in a buffer of its own.
 181 If nil, Dired finds the directory as a subdirectory in some other buffer
 182 if it is present as one.
 183
 184 If there are several Dired buffers for a directory, the most recently
 185 used is chosen.
 186
 187 Dired avoids switching to the current buffer, so that if you have
 188 a normal and a wildcard buffer for the same directory, \\[dired] will
 189 toggle between those two."
 190   :type 'boolean
 191   :group 'dired-x)
 192
 193 (defcustom dired-enable-local-variables t
 194   "Control use of local-variables lists in Dired.
 195 This temporarily overrides the value of `enable-local-variables' when
 196 listing a directory.  See also `dired-local-variables-file'."
 197   :risky t
 198   :type '(choice (const :tag "Query Unsafe" t)
 199                  (const :tag "Safe Only" :safe)
 200                  (const :tag "Do all" :all)
 201                  (const :tag "Ignore" nil)
 202                  (other :tag "Query" other))
 203   :group 'dired-x)
 204
 205 (make-obsolete-variable 'dired-enable-local-variables
 206                         "use a standard `dir-locals-file' instead." "24.1")
 207
 208 (defcustom dired-guess-shell-gnutar
 209   (catch 'found
 210     (dolist (exe '("tar" "gtar"))
 211       (if (with-temp-buffer
 212             (ignore-errors (call-process exe nil t nil "--version"))
 213             (and (re-search-backward "GNU tar" nil t) t))
 214           (throw 'found exe))))
 215   "If non-nil, name of GNU tar executable.
 216 \(E.g., \"tar\" or \"gtar\").  The `z' switch will be used with it for
 217 compressed or gzip'ed tar files.  If you don't have GNU tar, set this
 218 to nil: a pipe using `zcat' or `gunzip -c' will be used."
 219   ;; Changed from system-type test to testing --version output.
 220   ;; Maybe test --help for -z instead?
 221   :version "24.1"
 222   :type '(choice (const :tag "Not GNU tar" nil)
 223                  (string :tag "Command name"))
 224   :group 'dired-x)
 225
 226 (defcustom dired-guess-shell-gzip-quiet t
 227   "Non-nil says pass -q to gzip overriding verbose GZIP environment."
 228   :type 'boolean
 229   :group 'dired-x)
 230
 231 (defcustom dired-guess-shell-znew-switches nil
 232   "If non-nil, then string of switches passed to `znew', example: \"-K\"."
 233   :type '(choice (const :tag "None" nil)
 234                  (string :tag "Switches"))
 235   :group 'dired-x)
 236
 237 (defcustom dired-clean-up-buffers-too t
 238   "Non-nil means offer to kill buffers visiting files and dirs deleted in Dired."
 239   :type 'boolean
 240   :group 'dired-x)
 241
 242 ;;; KEY BINDINGS.
 243
 244 (define-key dired-mode-map "\C-x\M-o" 'dired-omit-mode)
 245 (define-key dired-mode-map "*O" 'dired-mark-omitted)
 246 (define-key dired-mode-map "\M-(" 'dired-mark-sexp)
 247 (define-key dired-mode-map "*(" 'dired-mark-sexp)
 248 (define-key dired-mode-map "*." 'dired-mark-extension)
 249 (define-key dired-mode-map "\M-!" 'dired-smart-shell-command)
 250 (define-key dired-mode-map "\M-G" 'dired-goto-subdir)
 251 (define-key dired-mode-map "F" 'dired-do-find-marked-files)
 252 (define-key dired-mode-map "Y"  'dired-do-relsymlink)
 253 (define-key dired-mode-map "%Y" 'dired-do-relsymlink-regexp)
 254 (define-key dired-mode-map "V" 'dired-do-run-mail)
 255
 256 ;;; MENU BINDINGS
 257
 258 (require 'easymenu)
 259
 260 (let ((menu (lookup-key dired-mode-map [menu-bar])))
 261   (easy-menu-add-item menu '("Operate")
 262                       ["Find Files" dired-do-find-marked-files
 263                        :help "Find current or marked files"]
 264                       "Shell Command...")
 265   (easy-menu-add-item menu '("Operate")
 266                       ["Relative Symlink to..." dired-do-relsymlink
 267                        :visible (fboundp 'make-symbolic-link)
 268                        :help "Make relative symbolic links for current or \
 269 marked files"]
 270                       "Hardlink to...")
 271   (easy-menu-add-item menu '("Mark")
 272                       ["Flag Extension..." dired-flag-extension
 273                        :help "Flag files with a certain extension for deletion"]
 274                       "Mark Executables")
 275   (easy-menu-add-item menu '("Mark")
 276                       ["Mark Extension..." dired-mark-extension
 277                        :help "Mark files with a certain extension"]
 278                       "Unmark All")
 279   (easy-menu-add-item menu '("Mark")
 280                       ["Mark Omitted" dired-mark-omitted
 281                        :help "Mark files matching `dired-omit-files' \
 282 and `dired-omit-extensions'"]
 283                       "Unmark All")
 284   (easy-menu-add-item menu '("Regexp")
 285                       ["Relative Symlink..." dired-do-relsymlink-regexp
 286                        :visible (fboundp 'make-symbolic-link)
 287                        :help "Make relative symbolic links for files \
 288 matching regexp"]
 289                       "Hardlink...")
 290   (easy-menu-add-item menu '("Immediate")
 291                       ["Omit Mode" dired-omit-mode
 292                        :style toggle :selected dired-omit-mode
 293                        :help "Enable or disable omitting \"uninteresting\" \
 294 files"]
 295                       "Refresh"))
 296
 297 \f
 298 ;; Install into appropriate hooks.
 299
 300 (add-hook 'dired-mode-hook 'dired-extra-startup)
 301 (add-hook 'dired-after-readin-hook 'dired-omit-expunge)
 302
 303 (defun dired-extra-startup ()
 304   "Automatically put on `dired-mode-hook' to get extra Dired features:
 305 \\<dired-mode-map>
 306   \\[dired-do-run-mail]\t-- run mail on folder (see `dired-bind-vm')
 307   \\[dired-info]\t-- run info on file
 308   \\[dired-man]\t-- run man on file
 309   \\[dired-do-find-marked-files]\t-- visit all marked files simultaneously
 310   \\[dired-omit-mode]\t-- toggle omitting of files
 311   \\[dired-mark-sexp]\t-- mark by Lisp expression
 312
 313 To see the options you can set, use M-x customize-group RET dired-x RET.
 314 See also the functions:
 315   `dired-flag-extension'
 316   `dired-virtual'
 317   `dired-jump'
 318   `dired-man'
 319   `dired-vm'
 320   `dired-rmail'
 321   `dired-info'
 322   `dired-do-find-marked-files'"
 323   (interactive)
 324   ;; These must be done in each new dired buffer.
 325   (dired-hack-local-variables)
 326   (dired-omit-startup))
 327
 328 \f
 329 ;;; EXTENSION MARKING FUNCTIONS.
 330
 331 ;; Mark files with some extension.
 332 (defun dired-mark-extension (extension &optional marker-char)
 333   "Mark all files with a certain EXTENSION for use in later commands.
 334 A `.' is *not* automatically prepended to the string entered.
 335 EXTENSION may also be a list of extensions instead of a single one.
 336 Optional MARKER-CHAR is marker to use."
 337   (interactive "sMarking extension: \nP")
 338   (or (listp extension)
 339       (setq extension (list extension)))
 340   (dired-mark-files-regexp
 341    (concat ".";; don't match names with nothing but an extension
 342            "\\("
 343            (mapconcat 'regexp-quote extension "\\|")
 344            "\\)$")
 345    marker-char))
 346
 347 (defun dired-flag-extension (extension)
 348   "In Dired, flag all files with a certain EXTENSION for deletion.
 349 A `.' is *not* automatically prepended to the string entered."
 350   (interactive "sFlagging extension: ")
 351   (dired-mark-extension extension dired-del-marker))
 352
 353 ;; Define some unpopular file extensions.  Used for cleaning and omitting.
 354
 355 (defvar dired-patch-unclean-extensions
 356   '(".rej" ".orig")
 357   "List of extensions of dispensable files created by the `patch' program.")
 358
 359 (defvar dired-tex-unclean-extensions
 360   '(".toc" ".log" ".aux");; these are already in completion-ignored-extensions
 361   "List of extensions of dispensable files created by TeX.")
 362
 363 (defvar dired-latex-unclean-extensions
 364   '(".idx" ".lof" ".lot" ".glo")
 365   "List of extensions of dispensable files created by LaTeX.")
 366
 367 (defvar dired-bibtex-unclean-extensions
 368   '(".blg" ".bbl")
 369   "List of extensions of dispensable files created by BibTeX.")
 370
 371 (defvar dired-texinfo-unclean-extensions
 372   '(".cp" ".cps" ".fn" ".fns" ".ky" ".kys" ".pg" ".pgs"
 373     ".tp" ".tps" ".vr" ".vrs")
 374   "List of extensions of dispensable files created by texinfo.")
 375
 376 (defun dired-clean-patch ()
 377   "Flag dispensable files created by patch for deletion.
 378 See variable `dired-patch-unclean-extensions'."
 379   (interactive)
 380   (dired-flag-extension dired-patch-unclean-extensions))
 381
 382 (defun dired-clean-tex ()
 383   "Flag dispensable files created by [La]TeX etc. for deletion.
 384 See variables `dired-tex-unclean-extensions',
 385 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 386 `dired-texinfo-unclean-extensions'."
 387   (interactive)
 388   (dired-flag-extension (append dired-texinfo-unclean-extensions
 389                                 dired-latex-unclean-extensions
 390                                 dired-bibtex-unclean-extensions
 391                                 dired-tex-unclean-extensions)))
 392
 393 (defun dired-very-clean-tex ()
 394   "Flag dispensable files created by [La]TeX *and* \".dvi\" for deletion.
 395 See variables `dired-texinfo-unclean-extensions',
 396 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 397 `dired-texinfo-unclean-extensions'."
 398   (interactive)
 399   (dired-flag-extension (append dired-texinfo-unclean-extensions
 400                                 dired-latex-unclean-extensions
 401                                 dired-bibtex-unclean-extensions
 402                                 dired-tex-unclean-extensions
 403                                 (list ".dvi"))))
 404 \f
 405 (defvar tar-superior-buffer)
 406 ;;; JUMP.
 407
 408 ;;;###autoload
 409 (defun dired-jump (&optional other-window file-name)
 410   "Jump to Dired buffer corresponding to current buffer.
 411 If in a file, Dired the current directory and move to file's line.
 412 If in Dired already, pop up a level and goto old directory's line.
 413 In case the proper Dired file line cannot be found, refresh the dired
 414 buffer and try again.
 415 When OTHER-WINDOW is non-nil, jump to Dired buffer in other window.
 416 Interactively with prefix argument, read FILE-NAME and
 417 move to its line in dired."
 418   (interactive
 419    (list nil (and current-prefix-arg
 420                   (read-file-name "Jump to Dired file: "))))
 421   (if (bound-and-true-p tar-subfile-mode)
 422       (switch-to-buffer tar-superior-buffer)
 423     (let* ((file (or file-name buffer-file-name))
 424            (dir (if file (file-name-directory file) default-directory)))
 425       (if (and (eq major-mode 'dired-mode) (null file-name))
 426           (progn
 427             (setq dir (dired-current-directory))
 428             (dired-up-directory other-window)
 429             (unless (dired-goto-file dir)
 430               ;; refresh and try again
 431               (dired-insert-subdir (file-name-directory dir))
 432               (dired-goto-file dir)))
 433         (if other-window
 434             (dired-other-window dir)
 435           (dired dir))
 436         (if file
 437             (or (dired-goto-file file)
 438                 ;; refresh and try again
 439                 (progn
 440                   (dired-insert-subdir (file-name-directory file))
 441                   (dired-goto-file file))
 442                 ;; Toggle omitting, if it is on, and try again.
 443                 (when dired-omit-mode
 444                   (dired-omit-mode)
 445                   (dired-goto-file file))))))))
 446
 447 ;;;###autoload
 448 (defun dired-jump-other-window (&optional file-name)
 449   "Like \\[dired-jump] (`dired-jump') but in other window."
 450   (interactive
 451    (list (and current-prefix-arg
 452               (read-file-name "Jump to Dired file: "))))
 453   (dired-jump t file-name))
 454 \f
 455 ;;; OMITTING.
 456
 457 ;; Enhanced omitting of lines from directory listings.
 458 ;; Marked files are never omitted.
 459
 460 ;; should probably get rid of this and always use 'no-dir.
 461 ;; sk 28-Aug-1991 09:37
 462 (defvar dired-omit-localp 'no-dir
 463   "The LOCALP argument `dired-omit-expunge' passes to `dired-get-filename'.
 464 If it is `no-dir', omitting is much faster, but you can only match
 465 against the non-directory part of the file name.  Set it to nil if you
 466 need to match the entire file name.")
 467
 468 ;; \017=^O for Omit - other packages can chose other control characters.
 469 (defvar dired-omit-marker-char ?\017
 470   "Temporary marker used by Dired-Omit.
 471 Should never be used as marker by the user or other packages.")
 472
 473 (defun dired-omit-startup ()
 474   (or (assq 'dired-omit-mode minor-mode-alist)
 475       (setq minor-mode-alist
 476             (append '((dired-omit-mode
 477                        (:eval (if (eq major-mode 'dired-mode)
 478                                   " Omit" ""))))
 479                     minor-mode-alist))))
 480
 481 (defun dired-mark-omitted ()
 482   "Mark files matching `dired-omit-files' and `dired-omit-extensions'."
 483   (interactive)
 484   (let ((dired-omit-mode nil)) (revert-buffer)) ;; Show omitted files
 485   (dired-mark-unmarked-files (dired-omit-regexp) nil nil dired-omit-localp))
 486
 487 (defcustom dired-omit-extensions
 488   (append completion-ignored-extensions
 489           dired-latex-unclean-extensions
 490           dired-bibtex-unclean-extensions
 491           dired-texinfo-unclean-extensions)
 492   "If non-nil, a list of extensions (strings) to omit from Dired listings.
 493 Defaults to elements of `completion-ignored-extensions',
 494 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions', and
 495 `dired-texinfo-unclean-extensions'.
 496
 497 See interactive function `dired-omit-mode' (\\[dired-omit-mode]) and
 498 variables `dired-omit-mode' and `dired-omit-files'."
 499   :type '(repeat string)
 500   :group 'dired-x)
 501
 502 (defun dired-omit-expunge (&optional regexp)
 503   "Erases all unmarked files matching REGEXP.
 504 Does nothing if global variable `dired-omit-mode' is nil, or if called
 505   non-interactively and buffer is bigger than `dired-omit-size-limit'.
 506 If REGEXP is nil or not specified, uses `dired-omit-files', and also omits
 507   filenames ending in `dired-omit-extensions'.
 508 If REGEXP is the empty string, this function is a no-op.
 509
 510 This functions works by temporarily binding `dired-marker-char' to
 511 `dired-omit-marker-char' and calling `dired-do-kill-lines'."
 512   (interactive "sOmit files (regexp): ")
 513   (if (and dired-omit-mode
 514            (or (called-interactively-p 'interactive)
 515                (not dired-omit-size-limit)
 516                (< (buffer-size) dired-omit-size-limit)
 517                (progn
 518                  (when dired-omit-verbose
 519                    (message "Not omitting: directory larger than %d characters."
 520                             dired-omit-size-limit))
 521                  (setq dired-omit-mode nil)
 522                  nil)))
 523       (let ((omit-re (or regexp (dired-omit-regexp)))
 524             (old-modified-p (buffer-modified-p))
 525             count)
 526         (or (string= omit-re "")
 527             (let ((dired-marker-char dired-omit-marker-char))
 528               (when dired-omit-verbose (message "Omitting..."))
 529               (if (dired-mark-unmarked-files omit-re nil nil dired-omit-localp)
 530                   (progn
 531                     (setq count (dired-do-kill-lines
 532                                  nil
 533                                  (if dired-omit-verbose "Omitted %d line%s." "")))
 534                     (force-mode-line-update))
 535                 (when dired-omit-verbose (message "(Nothing to omit)")))))
 536         ;; Try to preserve modified state of buffer.  So `%*' doesn't appear
 537         ;; in mode-line of omitted buffers.
 538         (set-buffer-modified-p (and old-modified-p
 539                                     (save-excursion
 540                                       (goto-char (point-min))
 541                                       (re-search-forward dired-re-mark nil t))))
 542         count)))
 543
 544 (defun dired-omit-regexp ()
 545   (concat (if dired-omit-files (concat "\\(" dired-omit-files "\\)") "")
 546           (if (and dired-omit-files dired-omit-extensions) "\\|" "")
 547           (if dired-omit-extensions
 548               (concat ".";; a non-extension part should exist
 549                       "\\("
 550                       (mapconcat 'regexp-quote dired-omit-extensions "\\|")
 551                       "\\)$")
 552             "")))
 553
 554 ;; Returns t if any work was done, nil otherwise.
 555 (defun dired-mark-unmarked-files (regexp msg &optional unflag-p localp)
 556   "Mark unmarked files matching REGEXP, displaying MSG.
 557 REGEXP is matched against the entire file name.  When called
 558 interactively, prompt for REGEXP.
 559 With prefix argument, unflag all those files.
 560 Optional fourth argument LOCALP is as in `dired-get-filename'."
 561   (interactive
 562    (list (read-regexp
 563           "Mark unmarked files matching regexp (default all): "
 564           nil 'dired-regexp-history)
 565          nil current-prefix-arg nil))
 566   (let ((dired-marker-char (if unflag-p ?\s dired-marker-char)))
 567     (dired-mark-if
 568      (and
 569       ;; not already marked
 570       (looking-at-p " ")
 571       ;; uninteresting
 572       (let ((fn (dired-get-filename localp t)))
 573         (and fn (string-match-p regexp fn))))
 574      msg)))
 575
 576 \f
 577 ;;; VIRTUAL DIRED MODE.
 578
 579 ;; For browsing `ls -lR' listings in a dired-like fashion.
 580
 581 (defalias 'virtual-dired 'dired-virtual)
 582 (defun dired-virtual (dirname &optional switches)
 583   "Put this buffer into Virtual Dired mode.
 584
 585 In Virtual Dired mode, all commands that do not actually consult the
 586 filesystem will work.
 587
 588 This is useful if you want to peruse and move around in an ls -lR
 589 output file, for example one you got from an ftp server.  With
 590 ange-ftp, you can even Dired a directory containing an ls-lR file,
 591 visit that file and turn on Virtual Dired mode.  But don't try to save
 592 this file, as dired-virtual indents the listing and thus changes the
 593 buffer.
 594
 595 If you have save a Dired buffer in a file you can use \\[dired-virtual] to
 596 resume it in a later session.
 597
 598 Type \\<dired-mode-map>\\[revert-buffer] \
 599 in the Virtual Dired buffer and answer `y' to convert
 600 the virtual to a real Dired buffer again.  You don't have to do this, though:
 601 you can relist single subdirs using \\[dired-do-redisplay]."
 602
 603   ;; DIRNAME is the top level directory of the buffer.  It will become
 604   ;; its `default-directory'.  If nil, the old value of
 605   ;; default-directory is used.
 606
 607   ;; Optional SWITCHES are the ls switches to use.
 608
 609   ;; Shell wildcards will be used if there already is a `wildcard'
 610   ;; line in the buffer (thus it is a saved Dired buffer), but there
 611   ;; is no other way to get wildcards.  Insert a `wildcard' line by
 612   ;; hand if you want them.
 613
 614   (interactive
 615    (list (read-string "Virtual Dired directory: " (dired-virtual-guess-dir))))
 616   (goto-char (point-min))
 617   (or (looking-at-p "  ")
 618       ;; if not already indented, do it now:
 619       (indent-region (point-min) (point-max) 2))
 620   (or dirname (setq dirname default-directory))
 621   (setq dirname (expand-file-name (file-name-as-directory dirname)))
 622   (setq default-directory dirname)      ; contains no wildcards
 623   (let ((wildcard (save-excursion
 624                     (goto-char (point-min))
 625                     (forward-line 1)
 626                     (and (looking-at "^  wildcard ")
 627                          (buffer-substring (match-end 0)
 628                                            (line-end-position))))))
 629   (if wildcard
 630         (setq dirname (expand-file-name wildcard default-directory))))
 631   ;; If raw ls listing (not a saved old dired buffer), give it a
 632   ;; decent subdir headerline:
 633   (goto-char (point-min))
 634   (or (looking-at-p dired-subdir-regexp)
 635       (insert "  "
 636               (directory-file-name (file-name-directory default-directory))
 637               ":\n"))
 638   (dired-mode dirname (or switches dired-listing-switches))
 639   (setq mode-name "Virtual Dired"
 640         revert-buffer-function 'dired-virtual-revert)
 641   (set (make-local-variable 'dired-subdir-alist) nil)
 642   (dired-build-subdir-alist)
 643   (goto-char (point-min))
 644   (dired-initial-position dirname))
 645
 646 (defun dired-virtual-guess-dir ()
 647   "Guess and return appropriate working directory of this buffer.
 648 The buffer is assumed to be in Dired or ls -lR format.  The guess is
 649 based upon buffer contents.  If nothing could be guessed, returns
 650 nil."
 651
 652   (let ((regexp "^\\(  \\)?\\([^ \n\r]*\\)\\(:\\)[\n\r]")
 653         (subexpr 2))
 654     (goto-char (point-min))
 655     (cond ((looking-at regexp)
 656            ;; If a saved dired buffer, look to which dir and
 657            ;; perhaps wildcard it belongs:
 658            (let ((dir (buffer-substring (match-beginning subexpr)
 659                                         (match-end subexpr))))
 660              (file-name-as-directory dir)))
 661           ;; Else no match for headerline found.  It's a raw ls listing.
 662           ;; In raw ls listings the directory does not have a headerline
 663           ;; try parent of first subdir, if any
 664           ((re-search-forward regexp nil t)
 665            (file-name-directory
 666             (directory-file-name
 667              (file-name-as-directory
 668               (buffer-substring (match-beginning subexpr)
 669                                 (match-end subexpr))))))
 670           (t                            ; if all else fails
 671            nil))))
 672
 673
 674 (defun dired-virtual-revert (&optional _arg _noconfirm)
 675   (if (not
 676        (y-or-n-p "Cannot revert a Virtual Dired buffer - switch to Real Dired mode? "))
 677       (error "Cannot revert a Virtual Dired buffer")
 678     (setq mode-name "Dired"
 679           revert-buffer-function 'dired-revert)
 680     (revert-buffer)))
 681
 682 ;; A zero-arg version of dired-virtual.
 683 (defun dired-virtual-mode ()
 684   "Put current buffer into Virtual Dired mode (see `dired-virtual').
 685 Useful on `magic-mode-alist' with the regexp
 686
 687   \"^  \\\\(/[^ /]+\\\\)+/?:$\"
 688
 689 to put saved Dired buffers automatically into Virtual Dired mode.
 690
 691 Also useful for `auto-mode-alist' like this:
 692
 693   (add-to-list \\='auto-mode-alist
 694                \\='(\"[^/]\\\\.dired\\\\\\='\" . dired-virtual-mode))"
 695   (interactive)
 696   (dired-virtual (dired-virtual-guess-dir)))
 697
 698 \f
 699 ;;; SMART SHELL.
 700
 701 ;; An Emacs buffer can have but one working directory, stored in the
 702 ;; buffer-local variable `default-directory'.  A Dired buffer may have
 703 ;; several subdirectories inserted, but still has but one working directory:
 704 ;; that of the top level Dired directory in that buffer.  For some commands
 705 ;; it is appropriate that they use the current Dired directory instead of
 706 ;; `default-directory', e.g., `find-file' and `compile'.  This is a general
 707 ;; mechanism is provided for special handling of the working directory in
 708 ;; special major modes.
 709
 710 (define-obsolete-variable-alias 'default-directory-alist
 711   'dired-default-directory-alist "24.1")
 712
 713 ;; It's easier to add to this alist than redefine function
 714 ;; default-directory while keeping the old information.
 715 (defconst dired-default-directory-alist
 716   '((dired-mode . (if (fboundp 'dired-current-directory)
 717                       (dired-current-directory)
 718                     default-directory)))
 719   "Alist of major modes and their opinion on `default-directory'.
 720 Each element has the form (MAJOR . EXPRESSION).
 721 The function `dired-default-directory' evaluates EXPRESSION to
 722 determine a default directory.")
 723
 724 (put 'dired-default-directory-alist 'risky-local-variable t) ; gets eval'd
 725 (make-obsolete-variable 'dired-default-directory-alist
 726                         "this feature is due to be removed." "24.1")
 727
 728 (defun dired-default-directory ()
 729   "Return the `dired-default-directory-alist' entry for the current major-mode.
 730 If none, return `default-directory'."
 731   ;; It looks like this was intended to be something of a "general"
 732   ;; feature, but it only ever seems to have been used in
 733   ;; dired-smart-shell-command, and doesn't seem worth keeping around.
 734   (declare (obsolete nil "24.1"))
 735   (or (eval (cdr (assq major-mode dired-default-directory-alist)))
 736       default-directory))
 737
 738 (defun dired-smart-shell-command (command &optional output-buffer error-buffer)
 739   "Like function `shell-command', but in the current Virtual Dired directory."
 740   (interactive
 741    (list
 742     (read-shell-command "Shell command: " nil nil
 743                         (cond
 744                          (buffer-file-name (file-relative-name buffer-file-name))
 745                          ((eq major-mode 'dired-mode) (dired-get-filename t t))))
 746     current-prefix-arg
 747     shell-command-default-error-buffer))
 748   (let ((default-directory (or (and (eq major-mode 'dired-mode)
 749                                     (dired-current-directory))
 750                                default-directory)))
 751     (shell-command command output-buffer error-buffer)))
 752
 753 \f
 754 ;;; LOCAL VARIABLES FOR DIRED BUFFERS.
 755
 756 ;; Brief Description  (This feature is obsolete as of Emacs 24.1)
 757 ;;
 758 ;; * `dired-extra-startup' is part of the `dired-mode-hook'.
 759 ;;
 760 ;; * `dired-extra-startup' calls `dired-hack-local-variables'
 761 ;;
 762 ;; * `dired-hack-local-variables' checks the value of
 763 ;;   `dired-local-variables-file'
 764 ;;
 765 ;; * Check if `dired-local-variables-file' is a non-nil string and is a
 766 ;;   filename found in the directory of the Dired Buffer being created.
 767 ;;
 768 ;; * If `dired-local-variables-file' satisfies the above, then temporarily
 769 ;;   include it in the Dired Buffer at the bottom.
 770 ;;
 771 ;; * Set `enable-local-variables' temporarily to the user variable
 772 ;;   `dired-enable-local-variables' and run `hack-local-variables' on the
 773 ;;   Dired Buffer.
 774
 775 (defcustom dired-local-variables-file (convert-standard-filename ".dired")
 776   "Filename, as string, containing local Dired buffer variables to be hacked.
 777 If this file found in current directory, then it will be inserted into dired
 778 buffer and `hack-local-variables' will be run.  See Info node
 779 `(emacs)File Variables' for more information on local variables.
 780 See also `dired-enable-local-variables'."
 781   :type 'file
 782   :group 'dired)
 783
 784 (make-obsolete-variable 'dired-local-variables-file 'dir-locals-file "24.1")
 785
 786 (defun dired-hack-local-variables ()
 787   "Evaluate local variables in `dired-local-variables-file' for Dired buffer."
 788   (declare (obsolete hack-dir-local-variables-non-file-buffer "24.1"))
 789   (and (stringp dired-local-variables-file)
 790        (file-exists-p dired-local-variables-file)
 791        (let ((opoint (point-max))
 792              (inhibit-read-only t)
 793              ;; In case user has `enable-local-variables' set to nil we
 794              ;; override it locally with dired's variable.
 795              (enable-local-variables dired-enable-local-variables))
 796          ;; Insert 'em.
 797          (save-excursion
 798            (goto-char opoint)
 799            (insert "\^L\n")
 800            (insert-file-contents dired-local-variables-file))
 801          ;; Hack 'em.
 802          (unwind-protect
 803              (let ((buffer-file-name dired-local-variables-file))
 804                (hack-local-variables))
 805            ;; Delete this stuff: `eobp' is used to find last subdir by dired.el.
 806            (delete-region opoint (point-max)))
 807          ;; Make sure that the mode line shows the proper information.
 808          (dired-sort-set-mode-line))))
 809
 810 ;; Does not seem worth a dedicated command.
 811 ;; See the more general features in files-x.el.
 812 (defun dired-omit-here-always ()
 813   "Create `dir-locals-file' setting `dired-omit-mode' to t in `dired-mode'.
 814 If in a Dired buffer, reverts it."
 815   (declare (obsolete add-dir-local-variable "24.1"))
 816   (interactive)
 817   (if (file-exists-p dired-local-variables-file)
 818       (error "Old-style dired-local-variables-file `./%s' found;
 819 replace it with a dir-locals-file `./%s'"
 820              dired-local-variables-file
 821              dir-locals-file))
 822   (if (file-exists-p dir-locals-file)
 823       (message "File `./%s' already exists." dir-locals-file)
 824     (with-temp-buffer
 825       (insert "\
 826 \((dired-mode . ((subdirs . nil)
 827                 (dired-omit-mode . t))))\n")
 828       (write-file dir-locals-file))
 829     ;; Run extra-hooks and revert directory.
 830     (when (derived-mode-p 'dired-mode)
 831       (hack-dir-local-variables-non-file-buffer)
 832       (dired-extra-startup)
 833       (dired-revert))))
 834
 835 \f
 836 ;;; GUESS SHELL COMMAND.
 837
 838 ;; Brief Description:
 839 ;;;
 840 ;; * `dired-do-shell-command' is bound to `!' by dired.el.
 841 ;;;
 842 ;; * `dired-guess-shell-command' provides smarter defaults for
 843 ;;;    dired-aux.el's `dired-read-shell-command'.
 844 ;;;
 845 ;; * `dired-guess-shell-command' calls `dired-guess-default' with list of
 846 ;;;    marked files.
 847 ;;;
 848 ;; * Parse `dired-guess-shell-alist-user' and
 849 ;;;   `dired-guess-shell-alist-default' (in that order) for the first REGEXP
 850 ;;;   that matches the first file in the file list.
 851 ;;;
 852 ;; * If the REGEXP matches all the entries of the file list then evaluate
 853 ;;;   COMMAND, which is either a string or a Lisp expression returning a
 854 ;;;   string.  COMMAND may be a list of commands.
 855 ;;;
 856 ;; * Return this command to `dired-guess-shell-command' which prompts user
 857 ;;;   with it.  The list of commands is put into the list of default values.
 858 ;;;   If a command is used successfully then it is stored permanently in
 859 ;;;   `dired-shell-command-history'.
 860
 861 ;; Guess what shell command to apply to a file.
 862 (defvar dired-shell-command-history nil
 863   "History list for commands that read dired-shell commands.")
 864
 865 ;; Default list of shell commands.
 866
 867 ;; NOTE: Use `gunzip -c' instead of `zcat' on `.gz' files.  Some do not
 868 ;; install GNU zip's version of zcat.
 869
 870 (autoload 'Man-support-local-filenames "man")
 871
 872 (defvar dired-guess-shell-alist-default
 873   (list
 874    (list "\\.tar\\'"
 875          '(if dired-guess-shell-gnutar
 876               (concat dired-guess-shell-gnutar " xvf")
 877             "tar xvf")
 878          ;; Extract files into a separate subdirectory
 879          '(if dired-guess-shell-gnutar
 880               (concat "mkdir " (file-name-sans-extension file)
 881                       "; " dired-guess-shell-gnutar " -C "
 882                       (file-name-sans-extension file) " -xvf")
 883             (concat "mkdir " (file-name-sans-extension file)
 884                     "; tar -C " (file-name-sans-extension file) " -xvf"))
 885          ;; List archive contents.
 886          '(if dired-guess-shell-gnutar
 887               (concat dired-guess-shell-gnutar " tvf")
 888             "tar tvf"))
 889
 890    ;; REGEXPS for compressed archives must come before the .Z rule to
 891    ;; be recognized:
 892    (list "\\.tar\\.Z\\'"
 893          ;; Untar it.
 894          '(if dired-guess-shell-gnutar
 895               (concat dired-guess-shell-gnutar " zxvf")
 896             (concat "zcat * | tar xvf -"))
 897          ;; Optional conversion to gzip format.
 898          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 899                   " " dired-guess-shell-znew-switches))
 900
 901    ;; gzip'ed archives
 902    (list "\\.t\\(ar\\.\\)?gz\\'"
 903          '(if dired-guess-shell-gnutar
 904               (concat dired-guess-shell-gnutar " zxvf")
 905             (concat "gunzip -qc * | tar xvf -"))
 906          ;; Extract files into a separate subdirectory
 907          '(if dired-guess-shell-gnutar
 908               (concat "mkdir " (file-name-sans-extension file)
 909                       "; " dired-guess-shell-gnutar " -C "
 910                       (file-name-sans-extension file) " -zxvf")
 911             (concat "mkdir " (file-name-sans-extension file)
 912                     "; gunzip -qc * | tar -C "
 913                     (file-name-sans-extension file) " -xvf -"))
 914          ;; Optional decompression.
 915          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q" ""))
 916          ;; List archive contents.
 917          '(if dired-guess-shell-gnutar
 918               (concat dired-guess-shell-gnutar " ztvf")
 919             (concat "gunzip -qc * | tar tvf -")))
 920
 921    ;; bzip2'ed archives
 922    (list "\\.t\\(ar\\.bz2\\|bz\\)\\'"
 923          "bunzip2 -c * | tar xvf -"
 924          ;; Extract files into a separate subdirectory
 925          '(concat "mkdir " (file-name-sans-extension file)
 926                   "; bunzip2 -c * | tar -C "
 927                   (file-name-sans-extension file) " -xvf -")
 928          ;; Optional decompression.
 929          "bunzip2")
 930
 931    ;; xz'ed archives
 932    (list "\\.t\\(ar\\.\\)?xz\\'"
 933          "unxz -c * | tar xvf -"
 934          ;; Extract files into a separate subdirectory
 935          '(concat "mkdir " (file-name-sans-extension file)
 936                   "; unxz -c * | tar -C "
 937                   (file-name-sans-extension file) " -xvf -")
 938          ;; Optional decompression.
 939          "unxz")
 940
 941    '("\\.shar\\.Z\\'" "zcat * | unshar")
 942    '("\\.shar\\.g?z\\'" "gunzip -qc * | unshar")
 943
 944    '("\\.e?ps\\'" "ghostview" "xloadimage" "lpr")
 945    (list "\\.e?ps\\.g?z\\'" "gunzip -qc * | ghostview -"
 946          ;; Optional decompression.
 947          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 948    (list "\\.e?ps\\.Z\\'" "zcat * | ghostview -"
 949          ;; Optional conversion to gzip format.
 950          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 951                   " " dired-guess-shell-znew-switches))
 952
 953    '("\\.patch\\'" "cat * | patch")
 954    (list "\\.patch\\.g?z\\'" "gunzip -qc * | patch"
 955          ;; Optional decompression.
 956          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 957    (list "\\.patch\\.Z\\'" "zcat * | patch"
 958          ;; Optional conversion to gzip format.
 959          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 960                   " " dired-guess-shell-znew-switches))
 961
 962    ;; The following four extensions are useful with dired-man ("N" key)
 963    ;; FIXME "man ./" does not work with dired-do-shell-command,
 964    ;; because there seems to be no way for us to modify the filename,
 965    ;; only the command.  Hmph.  `dired-man' works though.
 966    (list "\\.\\(?:[0-9]\\|man\\)\\'"
 967          '(let ((loc (Man-support-local-filenames)))
 968             (cond ((eq loc 'man-db) "man -l")
 969                   ((eq loc 'man) "man ./")
 970                   (t
 971                    "cat * | tbl | nroff -man -h | col -b"))))
 972    (list "\\.\\(?:[0-9]\\|man\\)\\.g?z\\'"
 973          '(let ((loc (Man-support-local-filenames)))
 974             (cond ((eq loc 'man-db)
 975                    "man -l")
 976                   ((eq loc 'man)
 977                    "man ./")
 978                   (t "gunzip -qc * | tbl | nroff -man -h | col -b")))
 979          ;; Optional decompression.
 980          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 981    (list "\\.[0-9]\\.Z\\'"
 982          '(let ((loc (Man-support-local-filenames)))
 983             (cond ((eq loc 'man-db) "man -l")
 984                   ((eq loc 'man) "man ./")
 985                   (t "zcat * | tbl | nroff -man -h | col -b")))
 986          ;; Optional conversion to gzip format.
 987          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 988                   " " dired-guess-shell-znew-switches))
 989    '("\\.pod\\'" "perldoc" "pod2man * | nroff -man")
 990
 991    '("\\.dvi\\'" "xdvi" "dvips")        ; preview and printing
 992    '("\\.au\\'" "play")                 ; play Sun audiofiles
 993    '("\\.mpe?g\\'\\|\\.avi\\'" "xine -p")
 994    '("\\.ogg\\'" "ogg123")
 995    '("\\.mp3\\'" "mpg123")
 996    '("\\.wav\\'" "play")
 997    '("\\.uu\\'" "uudecode")             ; for uudecoded files
 998    '("\\.hqx\\'" "mcvert")
 999    '("\\.sh\\'" "sh")                   ; execute shell scripts
1000    '("\\.xbm\\'" "bitmap")              ; view X11 bitmaps
1001    '("\\.gp\\'" "gnuplot")
1002    '("\\.p[bgpn]m\\'" "xloadimage")
1003    '("\\.gif\\'" "xloadimage")          ; view gif pictures
1004    '("\\.tif\\'" "xloadimage")
1005    '("\\.png\\'" "display")             ; xloadimage 4.1 doesn't grok PNG
1006    '("\\.jpe?g\\'" "xloadimage")
1007    '("\\.fig\\'" "xfig")                ; edit fig pictures
1008    '("\\.out\\'" "xgraph")              ; for plotting purposes.
1009    '("\\.tex\\'" "latex" "tex")
1010    '("\\.texi\\(nfo\\)?\\'" "makeinfo" "texi2dvi")
1011    '("\\.pdf\\'" "xpdf")
1012    '("\\.doc\\'" "antiword" "strings")
1013    '("\\.rpm\\'" "rpm -qilp" "rpm -ivh")
1014    '("\\.dia\\'" "dia")
1015    '("\\.mgp\\'" "mgp")
1016
1017    ;; Some other popular archivers.
1018    (list "\\.zip\\'" "unzip" "unzip -l"
1019          ;; Extract files into a separate subdirectory
1020          '(concat "unzip" (if dired-guess-shell-gzip-quiet " -q")
1021                   " -d " (file-name-sans-extension file)))
1022    '("\\.zoo\\'" "zoo x//")
1023    '("\\.lzh\\'" "lharc x")
1024    '("\\.arc\\'" "arc x")
1025    '("\\.shar\\'" "unshar")
1026    '("\\.rar\\'" "unrar x")
1027    '("\\.7z\\'" "7z x")
1028
1029    ;; Compression.
1030    (list "\\.g?z\\'" '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1031    (list "\\.dz\\'" "dictunzip")
1032    (list "\\.bz2\\'" "bunzip2")
1033    (list "\\.xz\\'" "unxz")
1034    (list "\\.Z\\'" "uncompress"
1035          ;; Optional conversion to gzip format.
1036          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1037                   " " dired-guess-shell-znew-switches))
1038
1039    '("\\.sign?\\'" "gpg --verify"))
1040
1041   "Default alist used for shell command guessing.
1042 See `dired-guess-shell-alist-user'.")
1043
1044 (defcustom dired-guess-shell-alist-user nil
1045   "User-defined alist of rules for suggested commands.
1046 These rules take precedence over the predefined rules in the variable
1047 `dired-guess-shell-alist-default' (to which they are prepended).
1048
1049 Each element of this list looks like
1050
1051     (REGEXP COMMAND...)
1052
1053 where each COMMAND can either be a string or a Lisp expression that evaluates
1054 to a string.  This expression can access the file name as the variable `file'.
1055 If several COMMANDs are given, the first one will be the default
1056 and the rest will be added temporarily to the history and can be retrieved
1057 with \\[previous-history-element] (M-p) .
1058
1059 The variable `dired-guess-shell-case-fold-search' controls whether
1060 REGEXP is matched case-sensitively.
1061
1062 You can set this variable in your ~/.emacs.  For example, to add rules for
1063 `.foo' and `.bar' files, write
1064
1065  (setq dired-guess-shell-alist-user
1066         '((\"\\\\.foo\\\\'\" \"FOO-COMMAND\")
1067           (\"\\\\.bar\\\\'\"
1068            (if condition
1069               \"BAR-COMMAND-1\"
1070             \"BAR-COMMAND-2\"))))"
1071   :group 'dired-x
1072   :type '(alist :key-type regexp :value-type (repeat sexp)))
1073
1074 (defcustom dired-guess-shell-case-fold-search t
1075   "If non-nil, `dired-guess-shell-alist-default' and
1076 `dired-guess-shell-alist-user' are matched case-insensitively."
1077   :group 'dired-x
1078   :type 'boolean)
1079
1080 (defun dired-guess-default (files)
1081   "Return a shell command, or a list of commands, appropriate for FILES.
1082 See `dired-guess-shell-alist-user'."
1083
1084   (let* ((case-fold-search dired-guess-shell-case-fold-search)
1085          ;; Prepend the user's alist to the default alist.
1086          (alist (append dired-guess-shell-alist-user
1087                         dired-guess-shell-alist-default))
1088          (file (car files))
1089          (flist (cdr files))
1090          elt regexp cmds)
1091
1092     ;; Find the first match in the alist for first file in FILES.
1093     (while alist
1094       (setq elt (car alist)
1095             regexp (car elt)
1096             alist (cdr alist))
1097       (if (string-match-p regexp file)
1098           (setq cmds (cdr elt)
1099                 alist nil)))
1100
1101     ;; If more than one file, see if all of FILES match regular expression.
1102     (while (and flist
1103                 (string-match-p regexp (car flist)))
1104       (setq flist (cdr flist)))
1105
1106     ;; If flist is still non-nil, then do not guess since this means that not
1107     ;; all the files in FILES were matched by the regexp.
1108     (setq cmds (and (not flist) cmds))
1109
1110     ;; Return commands or nil if flist is still non-nil.
1111     ;; Evaluate the commands in order that any logical testing will be done.
1112     (if (cdr cmds)
1113         (delete-dups (mapcar (lambda (cmd) (eval cmd `((file . ,file)))) cmds))
1114       (eval (car cmds) `((file . ,file))))))            ; single command
1115
1116 (defun dired-guess-shell-command (prompt files)
1117   "Ask user with PROMPT for a shell command, guessing a default from FILES."
1118   (let ((default (dired-guess-default files))
1119         default-list val)
1120     (if (null default)
1121         ;; Nothing to guess
1122         (read-shell-command prompt nil 'dired-shell-command-history)
1123       (setq prompt (replace-regexp-in-string ": $" " " prompt))
1124       (if (listp default)
1125           ;; More than one guess
1126           (setq default-list default
1127                 default (car default)
1128                 prompt (concat
1129                         prompt
1130                         (format "{%d guesses} " (length default-list))))
1131         ;; Just one guess
1132         (setq default-list (list default)))
1133       ;; Put the first guess in the prompt but not in the initial value.
1134       (setq prompt (concat prompt (format "[%s]: " default)))
1135       ;; All guesses can be retrieved with M-n
1136       (setq val (read-shell-command prompt nil
1137                                     'dired-shell-command-history
1138                                     default-list))
1139       ;; If we got a return, then return default.
1140       (if (equal val "") default val))))
1141
1142 \f
1143 ;;; RELATIVE SYMBOLIC LINKS.
1144
1145 (declare-function make-symbolic-link "fileio.c")
1146
1147 (defvar dired-keep-marker-relsymlink ?S
1148   "See variable `dired-keep-marker-move'.")
1149
1150 (defun dired-make-relative-symlink (file1 file2 &optional ok-if-already-exists)
1151   "Make a symbolic link (pointing to FILE1) in FILE2.
1152 The link is relative (if possible), for example
1153
1154     \"/vol/tex/bin/foo\" \"/vol/local/bin/foo\"
1155
1156 results in
1157
1158     \"../../tex/bin/foo\" \"/vol/local/bin/foo\""
1159   (interactive "FRelSymLink: \nFRelSymLink %s: \np")
1160   (let (name1 name2 len1 len2 (index 0) sub)
1161     (setq file1 (expand-file-name file1)
1162           file2 (expand-file-name file2)
1163           len1 (length file1)
1164           len2 (length file2))
1165     ;; Find common initial file name components:
1166     (let (next)
1167       (while (and (setq next (string-match "/" file1 index))
1168                   (< (setq next (1+ next)) (min len1 len2))
1169                   ;; For the comparison, both substrings must end in
1170                   ;; `/', so NEXT is *one plus* the result of the
1171                   ;; string-match.
1172                   ;; E.g., consider the case of linking "/tmp/a/abc"
1173                   ;; to "/tmp/abc" erroneously giving "/tmp/a" instead
1174                   ;; of "/tmp/" as common initial component
1175                   (string-equal (substring file1 0 next)
1176                                 (substring file2 0 next)))
1177         (setq index next))
1178       (setq name2 file2
1179             sub (substring file1 0 index)
1180             name1 (substring file1 index)))
1181     (if (string-equal sub "/")
1182         ;; No common initial file name found
1183         (setq name1 file1)
1184       ;; Else they have a common parent directory
1185       (let ((tem (substring file2 index))
1186             (start 0)
1187             (count 0))
1188         ;; Count number of slashes we must compensate for ...
1189         (while (setq start (string-match "/" tem start))
1190           (setq count (1+ count)
1191                 start (1+ start)))
1192         ;; ... and prepend a "../" for each slash found:
1193         (dotimes (_ count)
1194           (setq name1 (concat "../" name1)))))
1195     (make-symbolic-link
1196      (directory-file-name name1)        ; must not link to foo/
1197                                         ; (trailing slash!)
1198      name2 ok-if-already-exists)))
1199
1200 (autoload 'dired-do-create-files "dired-aux")
1201
1202 ;;;###autoload
1203 (defun dired-do-relsymlink (&optional arg)
1204    "Relative symlink all marked (or next ARG) files into a directory.
1205 Otherwise make a relative symbolic link to the current file.
1206 This creates relative symbolic links like
1207
1208     foo -> ../bar/foo
1209
1210 not absolute ones like
1211
1212     foo -> /ugly/file/name/that/may/change/any/day/bar/foo
1213
1214 For absolute symlinks, use \\[dired-do-symlink]."
1215   (interactive "P")
1216   (dired-do-create-files 'relsymlink #'dired-make-relative-symlink
1217                            "RelSymLink" arg dired-keep-marker-relsymlink))
1218
1219 (autoload 'dired-mark-read-regexp "dired-aux")
1220 (autoload 'dired-do-create-files-regexp "dired-aux")
1221
1222 (defun dired-do-relsymlink-regexp (regexp newname &optional arg whole-name)
1223   "RelSymlink all marked files containing REGEXP to NEWNAME.
1224 See functions `dired-do-rename-regexp' and `dired-do-relsymlink'
1225 for more info."
1226   (interactive (dired-mark-read-regexp "RelSymLink"))
1227   (dired-do-create-files-regexp
1228    #'dired-make-relative-symlink
1229    "RelSymLink" arg regexp newname whole-name dired-keep-marker-relsymlink))
1230
1231 \f
1232 ;;; VISIT ALL MARKED FILES SIMULTANEOUSLY.
1233
1234 ;; Brief Description:
1235 ;;;
1236 ;; `dired-do-find-marked-files' is bound to `F' by dired-x.el.
1237 ;;;
1238 ;; * Use `dired-get-marked-files' to collect the marked files in the current
1239 ;;;   Dired Buffer into a list of filenames `FILE-LIST'.
1240 ;;;
1241 ;; * Pass FILE-LIST to `dired-simultaneous-find-file' all with
1242 ;;;   `dired-do-find-marked-files''s prefix argument NOSELECT.
1243 ;;;
1244 ;; * `dired-simultaneous-find-file' runs through FILE-LIST decrementing the
1245 ;;;   list each time.
1246 ;;;
1247 ;; * If NOSELECT is non-nil then just run `find-file-noselect' on each
1248 ;;;   element of FILE-LIST.
1249 ;;;
1250 ;; * If NOSELECT is nil then calculate the `size' of the window for each file
1251 ;;;   by dividing the `window-height' by length of FILE-LIST.  Thus, `size' is
1252 ;;;   cognizant of the window-configuration.
1253 ;;;
1254 ;; * If `size' is too small abort, otherwise run `find-file' on each element
1255 ;;;   of FILE-LIST giving each a window of height `size'.
1256
1257 (defun dired-do-find-marked-files (&optional noselect)
1258   "Find all marked files displaying all of them simultaneously.
1259 With optional NOSELECT just find files but do not select them.
1260
1261 The current window is split across all files marked, as evenly as possible.
1262 Remaining lines go to bottom-most window.  The number of files that can be
1263 displayed this way is restricted by the height of the current window and
1264 `window-min-height'.
1265
1266 To keep Dired buffer displayed, type \\[split-window-below] first.
1267 To display just marked files, type \\[delete-other-windows] first."
1268   (interactive "P")
1269   (dired-simultaneous-find-file (dired-get-marked-files) noselect))
1270
1271 (defun dired-simultaneous-find-file (file-list noselect)
1272   "Visit all files in FILE-LIST and display them simultaneously.
1273 The current window is split across all files in FILE-LIST, as evenly as
1274 possible.  Remaining lines go to the bottom-most window.  The number of
1275 files that can be displayed this way is restricted by the height of the
1276 current window and the variable `window-min-height'.  With non-nil
1277 NOSELECT the files are merely found but not selected."
1278   ;; We don't make this function interactive because it is usually too clumsy
1279   ;; to specify FILE-LIST interactively unless via dired.
1280   (let (size)
1281     (if noselect
1282         ;; Do not select the buffer.
1283         (find-file-noselect (car file-list))
1284       ;; We will have to select the buffer.  Calculate and check window size.
1285       (setq size (/ (window-height) (length file-list)))
1286       (or (<= window-min-height size)
1287           (error "Too many files to visit simultaneously.  Try C-u prefix"))
1288       (find-file (car file-list)))
1289     ;; Decrement.
1290     (dolist (file (cdr file-list))
1291       (if noselect
1292           ;; Do not select the buffer.
1293           (find-file-noselect file)
1294         ;; Vertically split off a window of desired size.  Upper window will
1295         ;; have SIZE lines.  Select lower (larger) window.  We split it again.
1296         (select-window (split-window nil size))
1297         (find-file file)))))
1298
1299 \f
1300 ;;; MISCELLANEOUS COMMANDS.
1301
1302 ;; Run man on files.
1303
1304 (declare-function Man-getpage-in-background "man" (topic))
1305
1306 (defvar manual-program) ; from man.el
1307
1308 (defun dired-man ()
1309   "Run `man' on this file."
1310 ;; Used also to say: "Display old buffer if buffer name matches filename."
1311 ;; but I have no idea what that means.
1312   (interactive)
1313   (require 'man)
1314   (let* ((file (dired-get-filename))
1315          (manual-program (replace-regexp-in-string "\\*" "%s"
1316                           (dired-guess-shell-command
1317                            "Man command: " (list file)))))
1318     (Man-getpage-in-background file)))
1319
1320 ;; Run Info on files.
1321
1322 (defun dired-info ()
1323   "Run `info' on this file."
1324   (interactive)
1325   (info (dired-get-filename)))
1326
1327 ;; Run mail on mail folders.
1328
1329 (declare-function vm-visit-folder "ext:vm" (folder &optional read-only))
1330 (defvar vm-folder-directory)
1331
1332 (defun dired-vm (&optional read-only)
1333   "Run VM on this file.
1334 With optional prefix argument, visits the folder read-only.
1335 Otherwise obeys the value of `dired-vm-read-only-folders'."
1336   (interactive "P")
1337   (let ((dir (dired-current-directory))
1338         (fil (dired-get-filename)))
1339     (vm-visit-folder fil (or read-only
1340                              (eq t dired-vm-read-only-folders)
1341                              (and dired-vm-read-only-folders
1342                                   (not (file-writable-p fil)))))
1343     ;; So that pressing `v' inside VM does prompt within current directory:
1344     (set (make-local-variable 'vm-folder-directory) dir)))
1345
1346 (defun dired-rmail ()
1347   "Run RMAIL on this file."
1348   (interactive)
1349   (rmail (dired-get-filename)))
1350
1351 (defun dired-do-run-mail ()
1352   "Visit the current file as a mailbox, using VM or RMAIL.
1353 Prompt for confirmation first; if the user says yes, call
1354 `dired-vm' if `dired-bind-vm' is non-nil, `dired-rmail'
1355 otherwise."
1356   (interactive)
1357   (let ((file (dired-get-filename t)))
1358     (if dired-bind-vm
1359         (if (y-or-n-p (format-message
1360                        "Visit `%s' as a mail folder with VM?" file))
1361             (dired-vm))
1362       ;; Read mail folder using rmail.
1363       (if (y-or-n-p (format-message
1364                      "Visit `%s' as a mailbox with RMAIL?" file))
1365           (dired-rmail)))))
1366
1367 \f
1368 ;;; MISCELLANEOUS INTERNAL FUNCTIONS.
1369
1370 ;; This should be a builtin
1371 (defun dired-buffer-more-recently-used-p (buffer1 buffer2)
1372   "Return t if BUFFER1 is more recently used than BUFFER2.
1373 Considers buffers closer to the car of `buffer-list' to be more recent."
1374   (and (not (equal buffer1 buffer2))
1375        (memq buffer1 (buffer-list))
1376        (not (memq buffer1 (memq buffer2 (buffer-list))))))
1377
1378 ;; Same thing as `dired-buffers-for-dir' of dired.el? - lrd 11/23/93
1379 ;; (defun dired-buffers-for-dir-exact (dir)
1380 ;; ;; Return a list of buffers that dired DIR (a directory or wildcard)
1381 ;; ;; at top level, or as subdirectory.
1382 ;; ;; Top level matches must match the wildcard part too, if any.
1383 ;; ;; The list is in reverse order of buffer creation, most recent last.
1384 ;; ;; As a side effect, killed dired buffers for DIR are removed from
1385 ;; ;; dired-buffers.
1386 ;;   (let ((alist dired-buffers) result elt)
1387 ;;     (while alist
1388 ;;       (setq elt (car alist)
1389 ;;             alist (cdr alist))
1390 ;;       (let ((buf (cdr elt)))
1391 ;;         (if (buffer-name buf)
1392 ;;             ;; Top level must match exactly against dired-directory in
1393 ;;             ;; case one of them is a wildcard.
1394 ;;             (if (or (equal dir (with-current-buffer buf dired-directory))
1395 ;;                     (assoc dir (with-current-buffer buf dired-subdir-alist)))
1396 ;;                 (setq result (cons buf result)))
1397 ;;           ;; else buffer is killed - clean up:
1398 ;;           (setq dired-buffers (delq elt dired-buffers)))))
1399 ;;     result))
1400
1401 \f
1402 ;; Needed if ls -lh is supported and also for GNU ls -ls.
1403 (defun dired-x--string-to-number (str)
1404   "Like `string-to-number' but recognize a trailing unit prefix.
1405 For example, 2K is expanded to 2048.0.  The caller should make
1406 sure that a trailing letter in STR is one of BKkMGTPEZY."
1407   (let* ((val (string-to-number str))
1408          (u (unless (zerop val)
1409               (aref str (1- (length str))))))
1410     (when (and u (> u ?9))
1411       (when (= u ?k)
1412         (setq u ?K))
1413       (let ((units '(?B ?K ?M ?G ?T ?P ?E ?Z ?Y)))
1414         (while (and units (/= (pop units) u))
1415           (setq val (* 1024.0 val)))))
1416     val))
1417
1418 ;; Does anyone use this? - lrd 6/29/93.
1419 ;; Apparently people do use it. - lrd 12/22/97.
1420
1421 (defun dired-mark-sexp (predicate &optional unflag-p)
1422   "Mark files for which PREDICATE returns non-nil.
1423 With a prefix arg, unmark or unflag those files instead.
1424
1425 PREDICATE is a lisp expression that can refer to the following symbols:
1426
1427     inode  [integer] the inode of the file (only for ls -i output)
1428     s      [integer] the size of the file for ls -s output
1429                      (usually in blocks or, with -k, in KByte)
1430     mode   [string]  file permission bits, e.g. \"-rw-r--r--\"
1431     nlink  [integer] number of links to file
1432     uid    [string]  owner
1433     gid    [string]  group  (If the gid is not displayed by ls,
1434                      this will still be set (to the same as uid))
1435     size   [integer] file size in bytes
1436     time   [string]  the time that ls displays, e.g. \"Feb 12 14:17\"
1437     name   [string]  the name of the file
1438     sym    [string]  if file is a symbolic link, the linked-to name, else \"\"
1439
1440 For example, use
1441
1442         (equal 0 size)
1443
1444 to mark all zero length files.
1445
1446 There's an ambiguity when a single integer not followed by a unit
1447 prefix precedes the file mode: It is then parsed as inode number
1448 and not as block size (this always works for GNU coreutils ls).
1449
1450 Another limitation is that the uid field is needed for the
1451 function to work correctly.  In particular, the field is not
1452 present for some values of `ls-lisp-emulation'.
1453
1454 This function operates only on the buffer content and does not
1455 refer at all to the underlying file system.  Contrast this with
1456 `find-dired', which might be preferable for the task at hand."
1457   ;; Using sym="" instead of nil avoids the trap of
1458   ;; (string-match "foo" sym) into which a user would soon fall.
1459   ;; Give `equal' instead of `=' in the example, as this works on
1460   ;; integers and strings.
1461   (interactive "xMark if (lisp expr): \nP")
1462   (message "%s" predicate)
1463   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char))
1464         inode s mode nlink uid gid size time name sym)
1465     (dired-mark-if
1466      (save-excursion
1467        (and
1468         ;; Sets vars
1469         ;;                inode s mode nlink uid gid size time name sym
1470
1471         ;; according to current file line.  Returns t for success, nil if
1472         ;; there is no file line.  Upon success, all variables are set, either
1473         ;; to nil or the appropriate value, so they need not be initialized.
1474         ;; Moves point within the current line.
1475         (dired-move-to-filename)
1476         (let ((mode-len 10) ; length of mode string
1477               ;; like in dired.el, but with subexpressions \1=inode, \2=s:
1478               ;; GNU ls -hs suffixes the block count with a unit and
1479               ;; prints it as a float, FreeBSD does neither.
1480               (dired-re-inode-size "\\=\\s *\\([0-9]+\\s +\\)?\
1481 \\(?:\\([0-9]+\\(?:\\.[0-9]*\\)?[BkKMGTPEZY]?\\)? ?\\)"))
1482           (beginning-of-line)
1483           (forward-char 2)
1484           (search-forward-regexp dired-re-inode-size nil t)
1485           ;; XXX Might be a size not followed by a unit prefix.
1486           ;; We could set s to inode if it were otherwise nil,
1487           ;; with a similar reasoning as below for setting gid to uid,
1488           ;; but it would be even more whimsical.
1489           (setq inode (when (match-string 1)
1490                         (string-to-number (match-string 1))))
1491           (setq s (when (match-string 2)
1492                     (dired-x--string-to-number (match-string 2))))
1493           (setq mode (buffer-substring (point) (+ mode-len (point))))
1494           (forward-char mode-len)
1495           ;; Skip any extended attributes marker ("." or "+").
1496           (or (looking-at " ")
1497               (forward-char 1))
1498           (setq nlink (read (current-buffer)))
1499           ;; Karsten Wenger <kw@cis.uni-muenchen.de> fixed uid.
1500           ;; Another issue is that GNU ls -n right-justifies numerical
1501           ;; UIDs and GIDs, while FreeBSD left-justifies them, so
1502           ;; don't rely on a specific whitespace layout.  Both of them
1503           ;; right-justify all other numbers, though.
1504           ;; XXX Return a number if the uid or gid seems to be
1505           ;; numerical?
1506           (setq uid (buffer-substring (progn
1507                                         (skip-chars-forward " \t")
1508                                         (point))
1509                                       (progn
1510                                         (skip-chars-forward "^ \t")
1511                                         (point))))
1512           (dired-move-to-filename)
1513           (save-excursion
1514             (setq time
1515                   ;; The regexp below tries to match from the last
1516                   ;; digit of the size field through a space after the
1517                   ;; date.  Also, dates may have different formats
1518                   ;; depending on file age, so the date column need
1519                   ;; not be aligned to the right.
1520                   (buffer-substring (save-excursion
1521                                       (skip-chars-backward " \t")
1522                                       (point))
1523                                     (progn
1524                                       (re-search-backward
1525                                        directory-listing-before-filename-regexp)
1526                                       (skip-chars-forward "^ \t")
1527                                       (1+ (point))))
1528                   size (dired-x--string-to-number
1529                         ;; We know that there's some kind of number
1530                         ;; before point because the regexp search
1531                         ;; above succeeded.  I don't think it's worth
1532                         ;; doing an extra check for leading garbage.
1533                         (buffer-substring (point)
1534                                           (progn
1535                                             (skip-chars-backward "^ \t")
1536                                             (point))))
1537                   ;; If no gid is displayed, gid will be set to uid
1538                   ;; but the user will then not reference it anyway in
1539                   ;; PREDICATE.
1540                   gid (buffer-substring (progn
1541                                           (skip-chars-backward " \t")
1542                                           (point))
1543                                         (progn
1544                                           (skip-chars-backward "^ \t")
1545                                           (point)))))
1546           (setq name (buffer-substring (point)
1547                                        (or
1548                                         (dired-move-to-end-of-filename t)
1549                                         (point)))
1550                 sym (if (looking-at " -> ")
1551                         (buffer-substring (progn (forward-char 4) (point))
1552                                           (line-end-position))
1553                       ""))
1554           t)
1555         (eval predicate
1556               `((inode . ,inode)
1557                 (s . ,s)
1558                 (mode . ,mode)
1559                 (nlink . ,nlink)
1560                 (uid . ,uid)
1561                 (gid . ,gid)
1562                 (size . ,size)
1563                 (time . ,time)
1564                 (name . ,name)
1565                 (sym . ,sym)))))
1566      (format "'%s file" predicate))))
1567
1568 \f
1569 ;;; FIND FILE AT POINT.
1570
1571 (defcustom dired-x-hands-off-my-keys t
1572   "Non-nil means don't remap `find-file' to `dired-x-find-file'.
1573 Similarly for `find-file-other-window' and `dired-x-find-file-other-window'.
1574 If you change this variable without using \\[customize] after `dired-x.el'
1575 is loaded then call \\[dired-x-bind-find-file]."
1576   :type 'boolean
1577   :initialize 'custom-initialize-default
1578   :set (lambda (symbol value)
1579          (set symbol value)
1580          (dired-x-bind-find-file))
1581   :group 'dired-x)
1582
1583 (defun dired-x-bind-find-file ()
1584   "Bind `dired-x-find-file' in place of `find-file' (or vice-versa).
1585 Similarly for `dired-x-find-file-other-window' and `find-file-other-window'.
1586 Binding direction based on `dired-x-hands-off-my-keys'."
1587   (interactive)
1588   (if (called-interactively-p 'interactive)
1589       (setq dired-x-hands-off-my-keys
1590             (not (y-or-n-p "Bind dired-x-find-file over find-file? "))))
1591   (define-key (current-global-map) [remap find-file]
1592     (if (not dired-x-hands-off-my-keys) 'dired-x-find-file))
1593   (define-key (current-global-map) [remap find-file-other-window]
1594     (if (not dired-x-hands-off-my-keys) 'dired-x-find-file-other-window)))
1595
1596 ;; Now call it so binding is correct.  This could go in the :initialize
1597 ;; slot, but then dired-x-bind-find-file has to be defined before the
1598 ;; defcustom, and we get free variable warnings.
1599 (dired-x-bind-find-file)
1600
1601 (defun dired-x-find-file (filename)
1602   "Edit file FILENAME.
1603 Like `find-file', except that when called interactively with a
1604 prefix argument, it offers the filename near point as a default."
1605   (interactive (list (dired-x-read-filename-at-point "Find file: ")))
1606   (find-file filename))
1607
1608 (defun dired-x-find-file-other-window (filename)
1609   "Edit file FILENAME, in another window.
1610 Like `find-file-other-window', except that when called interactively with
1611 a prefix argument, when it offers the filename near point as a default."
1612   (interactive (list (dired-x-read-filename-at-point "Find file: ")))
1613   (find-file-other-window filename))
1614
1615 ;;; Internal functions.
1616
1617 ;; Fixme: This should probably use `thing-at-point'.  -- fx
1618 (defun dired-filename-at-point ()
1619   "Return the filename closest to point, expanded.
1620 Point should be in or after a filename."
1621   (save-excursion
1622     ;; First see if just past a filename.
1623     (or (eobp)                             ; why?
1624         (when (looking-at-p "[] \t\n[{}()]") ; whitespace or some parens
1625           (skip-chars-backward " \n\t\r({[]})")
1626           (or (bobp) (backward-char 1))))
1627     (let ((filename-chars "-.[:alnum:]_/:$+@")
1628           start prefix)
1629       (if (looking-at-p (format "[%s]" filename-chars))
1630           (progn
1631             (skip-chars-backward filename-chars)
1632             (setq start (point)
1633                   prefix
1634                   ;; This is something to do with ange-ftp filenames.
1635                   ;; It convert foo@bar to /foo@bar.
1636                   ;; But when does the former occur in dired buffers?
1637                   (and (string-match-p
1638                         "^\\w+@"
1639                         (buffer-substring start (line-end-position)))
1640                        "/"))
1641             (if (string-match-p "[/~]" (char-to-string (preceding-char)))
1642                 (setq start (1- start)))
1643             (skip-chars-forward filename-chars))
1644         (error "No file found around point!"))
1645       ;; Return string.
1646       (expand-file-name (concat prefix (buffer-substring start (point)))))))
1647
1648 (defun dired-x-read-filename-at-point (prompt)
1649   "Return filename prompting with PROMPT with completion.
1650 If `current-prefix-arg' is non-nil, uses name at point as guess."
1651   (if current-prefix-arg
1652       (let ((guess (dired-filename-at-point)))
1653         (read-file-name prompt
1654                         (file-name-directory guess)
1655                         guess
1656                         nil (file-name-nondirectory guess)))
1657     (read-file-name prompt default-directory)))
1658
1659 (define-obsolete-function-alias 'read-filename-at-point
1660   'dired-x-read-filename-at-point "24.1") ; is this even needed?
1661 \f
1662 ;;; BUG REPORTS
1663
1664 (define-obsolete-function-alias 'dired-x-submit-report 'report-emacs-bug "24.1")
1665
1666 \f
1667 ;; As Barry Warsaw would say: "This might be useful..."
1668 (provide 'dired-x)
1669
1670 ;; Local Variables:
1671 ;; byte-compile-dynamic: t
1672 ;; generated-autoload-file: "dired.el"
1673 ;; End:
1674
1675 ;;; dired-x.el ends here