test/indent/prolog.prolog

   1 %% -*- mode: prolog; coding: utf-8; fill-column: 78 -*-
   2
   3 %% Testing correct tokenizing.
   4 foo(X) :- 0'= = X.
   5 foo(X) :- 8'234 = X.
   6 foo(X) :- '\x45\' = X.
   7 foo(X) :- 'test 0'=X.
   8 foo(X) :- 'test 8'=X.
   9
  10 %% wf(+E)
  11 %% Vérifie que E est une expression syntaxiquement correcte.
  12 wf(X) :- atom(X); integer(X); var(X).         %Une variable ou un entier.
  13 wf(lambda(X, T, B)) :- atom(X), wf(T), wf(B). %Une fonction.
  14 wf(app(E1, E2)) :- wf(E1), wf(E2).            %Un appel de fonction.
  15 wf(pi(X, T, B)) :- atom(X), wf(T), wf(B).     %Le type d'une fonction.
  16
  17 %% Éléments additionnels utilisés dans le langage source.
  18 wf(lambda(X, B)) :- atom(X), wf(B).
  19 wf(let(X, E1, E2)) :- atom(X), wf(E1), wf(E2).
  20 wf(let(X, T, E1, E2)) :- atom(X), wf(T), wf(E1), wf(E2).
  21 wf((T1 -> T2)) :- wf(T1), wf(T2).
  22 wf(forall(X, T, B)) :- atom(X), wf(T), wf(B).
  23 wf(fix(X,T,E1,E2)) :- atom(X), wf(T), wf(E1), wf(E2).
  24 wf(fix(X,E1,E2)) :- atom(X), wf(E1), wf(E2).
  25 wf(app(E1,E2,E3)) :- wf(E1), wf(E2), wf(E3).
  26 wf(app(E1,E2,E3,E4)) :- wf(E1), wf(E2), wf(E3), wf(E4).
  27
  28 %% subst(+X, +V, +FV, +Ei, -Eo)
  29 %% Remplace X par V dans Ei.  Les variables qui apparaissent libres dans
  30 %% V et peuvent aussi apparaître dans Ei doivent toutes être inclues
  31 %% dans l'environnement FV.
  32 subst(X, V, _, X, E) :- !, E = V.
  33 subst(_, _, _, Y, Y) :- atom(Y); integer(Y).
  34 %% Residualize the substitution when applied to an uninstantiated variable.
  35 %% subst(X, V, _, Y, app(lambda(X,_,Y),V)) :- var(Y).
  36 %% Rather than residualize and leave us with unifications that fail, let's
  37 %% rather assume that Y will not refer to X.
  38 subst(X, V, _, Y, Y) :- var(Y).
  39 subst(X, V, FV, lambda(Y, Ti, Bi), lambda(Y1, To, Bo)) :-
  40     subst(X, V, FV, Ti, To),
  41     (X = Y ->
  42          %% If X is equal to Y, X is shadowed, so no subst can take place.
  43          Y1 = Y, Bo = Bi;
  44      (member((Y, _), FV) ->
  45           %% If Y appears in FV, it can appear in V, so we need to
  46           %% rename it to avoid name capture.
  47           new_atom(Y, Y1),
  48           subst(Y, Y1, [], Bi, Bi1);
  49       Y1 = Y, Bi1 = Bi),
  50      %% Perform substitution on the body.
  51      subst(X, V, FV, Bi1, Bo)),
  52     (   X = Y
  53      %% If X is equal to Y, X is shadowed, so no subst can take place.
  54      -> Y1 = Y, Bo = Bi
  55      ;  (member((Y, _), FV)
  56          %% If Y appears in FV, it can appear in V, so we need to
  57          %% rename it to avoid name capture.
  58          -> new_atom(Y, Y1),
  59             subst(Y, Y1, [], Bi, Bi1)
  60          ; Y1 = Y, Bi1 = Bi),
  61         %% Perform substitution on the body.
  62         subst(X, V, FV, Bi1, Bo)
  63     ).
  64 subst(X, V, FV, pi(Y, Ti, Bi), pi(Y1, To, Bo)) :-
  65     subst(X, V, FV, lambda(Y, Ti, Bi), lambda(Y1, To, Bo)).
  66 subst(X, V, FV, forall(Y, Ti, Bi), forall(Y1, To, Bo)) :-
  67     subst(X, V, FV, lambda(Y, Ti, Bi), lambda(Y1, To, Bo)).
  68 subst(X, V, FV, app(E1i, E2i), app(E1o, E2o)) :-
  69     subst(X, V, FV, E1i, E1o), subst(X, V, FV, E2i, E2o).
  70
  71 %% apply(+F, +Arg, +Env, -E)
  72 apply(lambda(X, _, B), Arg, Env, E) :- \+ var(B), subst(X, Arg, Env, B, E).
  73 apply(app(plus, N1), N2, _, N) :- integer(N1), integer(N2), N is N1 + N2.
  74 apply(app(minus, N1), N2, _, N) :- integer(N1), integer(N2), N is N1 - N2.
  75
  76
  77 %% normalize(+E1, +Env, -E2)
  78 %% Applique toutes les réductions possibles sur E1.
  79 normalize(X, _, X) :- integer(X); var(X); atom(X).
  80 %% normalize(X, Env, E) :- atom(X), member((X, E), Env).
  81 normalize(lambda(X, T, B), Env, lambda(X, Tn, Bn)) :-
  82     normalize(T, [(X,T)|Env], Tn), normalize(B, [(X,T)|Env], Bn).
  83 normalize(pi(X, T, B), Env, pi(X, Tn, Bn)) :-
  84     normalize(T, [(X,T)|Env], Tn), normalize(B, [(X,T)|Env], Bn).
  85 normalize(forall(X, T, B), Env, forall(X, Tn, Bn)) :-
  86     normalize(T, [(X,T)|Env], Tn), normalize(B, [(X,T)|Env], Bn).
  87 normalize(app(E1, E2), Env, En) :-
  88     normalize(E1, Env, E1n),
  89     normalize(E2, Env, E2n),
  90     (apply(E1n, E2n, Env, E) ->
  91          normalize(E, Env, En);
  92      En = app(E1n, E2n)).
  93
  94 %% infer(+E, +Env, -T)
  95 %% Infère le type de E dans Env.  On essaie d'être permissif, dans le sens
  96 %% que l'on présume que l'expression est typée correctement.
  97 infer(X, _, int) :- integer(X).
  98 infer(X, _, _) :- var(X).            %Une expression encore inconnue.
  99 infer(X, Env, T) :-
 100     atom(X),
 101     (member((X, T1), Env) ->
 102          %% X est déjà dans Env: vérifie que le type est correct.
 103          T = T1;
 104      %% X est une variable libre.
 105      true).
 106 infer(lambda(X,T,B), Env, pi(Y,T,TB)) :-
 107     infer(B, [(X,T)|Env], TBx),
 108     (var(Y) ->
 109          Y = X, TB = TBx;
 110      subst(X, Y, Env, TBx, TB)).
 111 infer(app(E1, E2), Env, Tn) :-
 112     infer(E1, Env, T1),
 113     (T1 = pi(X,T2,B); T1 = forall(X,T2,B)),
 114     infer(E2, Env, T2),
 115     subst(X, E2, Env, B, T),
 116     normalize(T, Env, Tn).
 117 infer(pi(X,T1,T2), Env, type) :-
 118     infer(T1, Env, type),
 119     infer(T2, [(X,T1)|Env], type).
 120 infer(forall(X,T1,T2), Env, type) :-
 121     infer(T1, Env, type),
 122     infer(T2, [(X,T1)|Env], type).
 123
 124 %% freevars(+E, +Env, -Vs)
 125 %% Renvoie les variables libres de E.  Vs est une liste associative
 126 %% où chaque élément est de la forme (X,T) où X est une variable et T est
 127 %% son type.
 128 freevars(X, _, []) :- integer(X).
 129 freevars(X, Env, Vs) :-
 130     atom(X),
 131     (member((X,_), Env) ->
 132          %% Variable liée.
 133          Vs = [];
 134      %% Variable libre.  Type inconnu :-(
 135      Vs = [(X,_)]).
 136 %% Les variables non-instanciées peuvent être remplacées par des paramètres
 137 %% qui seront liés par `closetype' selon le principe de Hindley-Milner.
 138 freevars(X, _, [(X, _)]) :- var(X), new_atom(X).
 139 freevars(app(E1, E2), Env, Vs) :-
 140     freevars(E1, Env, Vs1),
 141     append(Vs1, Env, Env1),
 142     freevars(E2, Env1, Vs2),
 143     append(Vs1, Vs2, Vs).
 144 freevars(lambda(X, T, B), Env, Vs) :-
 145     freevars(T, Env, TVs),
 146     append(TVs, Env, Env1),
 147     freevars(B, [(X,T)|Env1], BVs),
 148     append(TVs, BVs, Vs).
 149 freevars(pi(X, T, B), Env, Vs)     :- freevars(lambda(X, T, B), Env, Vs).
 150 freevars(forall(X, T, B), Env, Vs) :- freevars(lambda(X, T, B), Env, Vs).
 151
 152 %% close(+Eo, +To, +Vs, -Ec, -Tc)
 153 %% Ferme un type ouvert To en liant chaque variable libre (listées dans Vs)
 154 %% avec `forall'.
 155 closetype(E, T, [], E, T).
 156 closetype(Eo, To, [(X,T)|Vs], lambda(X, T, Ec), forall(X, T, Tc)) :-
 157     closetype(Eo, To, Vs, Ec, Tc).
 158
 159 %% elab_type(+Ee, +Te, +Env, -Eg, -Tg)
 160 %% Ajoute les arguments implicites de E:T.
 161 generalize(Ee, Te, Env, Eg, Tg) :-
 162     freevars(Te, Env, Vs),
 163     append(Vs, Env, EnvX),
 164     %% Essaie d'instancier les types des paramètres que `generalize' vient
 165     %% d'ajouter.
 166     infer(Te, EnvX, type),
 167     closetype(Ee, Te, Vs, Eg, Tg).
 168
 169 %% instantiate(+X, +T, -E)
 170 %% Utilise la variable X de type T.  Le résultat E est X auquel on ajoute
 171 %% tous les arguments implicites (de valeur inconnue).
 172 instantiate(X, T, X) :- var(T), !.
 173 instantiate(X, forall(_, _, T), app(E, _)) :- !, instantiate(X, T, E).
 174 instantiate(X, _, X).
 175
 176 %% elaborate(+E1, +Env, -E2)
 177 %% Transforme E1 en une expression E2 où le sucre syntaxique a été éliminé
 178 %% et où les arguments implicites ont été rendus explicites.
 179 elaborate(X, _, X) :- integer(X); var(X).
 180 elaborate(X, Env, E) :-
 181     atom(X),
 182     (member((X, T), Env) ->
 183          instantiate(X, T, E);
 184      %% Si X n'est pas dans l'environnement, c'est une variable libre que
 185      %% l'on voudra probablement généraliser.
 186      X = E).
 187 elaborate(lambda(X, T, B), Env, lambda(X, Te, Be)) :-
 188     elaborate(T, Env, Te),
 189     elaborate(B, [(X,Te)|Env], Be).
 190 elaborate(pi(X, T, B), Env, pi(X, Te, Be)) :-
 191     elaborate(T, Env, Te),
 192     elaborate(B, [(X,Te)|Env], Be).
 193 elaborate(app(E1, E2), Env, app(E1e, E2e)) :-
 194     elaborate(E1, Env, E1e),
 195     elaborate(E2, Env, E2e).
 196 elaborate(let(X, T, E1, E2), Env, app(lambda(X, Tg, E2e), E1g)) :-
 197     elaborate(E1, Env, E1e),
 198     elaborate(T, Env, Te),
 199     infer(E1e, Env, Te),
 200     generalize(E1e, Te, Env, E1g, Tg),
 201     elaborate(E2, [(X,Te)|Env], E2e).
 202 %% Expansion du sucre syntaxique.
 203 elaborate((T1 -> T2), Env, Ee) :-
 204     new_atom(X), elaborate(pi(X, T1, T2), Env, Ee).
 205 elaborate(app(E1, E2, E3, E4), Env, Ee) :-
 206     elaborate(app(app(E1,E2,E3),E4), Env, Ee).
 207 elaborate(app(E1, E2, E3), Env, Ee) :- elaborate(app(app(E1,E2),E3), Env, Ee).
 208 elaborate(lambda(X, B), Env, Ee) :- elaborate(lambda(X, _, B), Env, Ee).
 209 elaborate(let(X, E1, E2), Env, Ee) :- elaborate(let(X, _, E1, E2), Env, Ee).
 210 elaborate(fix(F,B,E), Env, Ee) :- elaborate(fix(F,_,B,E), Env, Ee).
 211 elaborate(fix(F,T,B,E), Env, Ee) :-
 212     elaborate(let(F,T,app(fix,lambda(F,T,B)),E), Env, Ee).
 213
 214 %% elab_bindings(+TS, +Env, -TS).
 215 %% Applique `elaborate' sur l'environnement de type TS.
 216 elab_tenv([], _, []).
 217 elab_tenv([(X,T)|TS], Env, [(X, Tg)|TSe]) :-
 218     elaborate(T, Env, Te),
 219     infer(Te, Env, type),
 220     generalize(_, Te, Env, _, Tg),
 221     elab_tenv(TS, [(X, Tg)|Env], TSe).
 222
 223
 224 %% elaborate(+E1, -E2)
 225 %% Comme le `elaborate' ci-dessus, mais avec un environnement par défaut.
 226 elaborate(SRC, E) :-
 227     elab_tenv([(int, type),
 228                (fix, ((t -> t) -> t)),
 229                %% list: type → int → type
 230                (list, (type -> int -> type)),
 231                %% plus: int → int → int
 232                (plus, (int -> int -> int)),
 233                %% minus: int → int → int
 234                (minus, (int -> int -> int)),
 235                %% nil: list t 0
 236                (nil, app(app(list,t),0)),
 237                %% cons: t -> list t n → list t (n + 1)
 238                (cons, (t -> app(app(list,t),n) ->
 239                             app(app(list,t), app(app(plus,n),1)))) %fixindent
 240               ],
 241               [(type,type)],
 242               Env),
 243     elaborate(SRC, Env, E).