lisp/type-break.el

   1 ;;; type-break.el --- encourage rests from typing at appropriate intervals  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 1994-1995, 1997, 2000-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Noah Friedman
   6 ;; Maintainer: Noah Friedman <friedman@splode.com>
   7 ;; Keywords: extensions, timers
   8 ;; Created: 1994-07-13
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; The docstring for the function `type-break-mode' summarizes most of the
  28 ;; details of the interface.
  29
  30 ;; This package relies on the assumption that you live entirely in Emacs,
  31 ;; as the author does.  If that's not the case for you (e.g. you often
  32 ;; suspend Emacs or work in other windows) then this won't help very much;
  33 ;; it will depend on just how often you switch back to Emacs.  At the very
  34 ;; least, you will want to turn off the keystroke thresholds and rest
  35 ;; interval tracking.
  36
  37 ;; If you prefer not to be queried about taking breaks, but instead just
  38 ;; want to be reminded, do the following:
  39 ;;
  40 ;;   (setq type-break-query-mode nil)
  41 ;;
  42 ;; Or call the command `type-break-query-mode' with a negative prefix
  43 ;; argument.
  44
  45 ;; If you find echo area messages annoying and would prefer to see messages
  46 ;; in the mode line instead, do M-x type-break-mode-line-message-mode
  47 ;; or set the variable of the same name to `t'.
  48
  49 ;; This program can truly cons up a storm because of all the calls to
  50 ;; `current-time' (which always returns fresh conses).  I'm dismayed by
  51 ;; this, but I think the health of my hands is far more important than a
  52 ;; few pages of virtual memory.
  53
  54 ;; This program has no hope of working in Emacs 18.
  55
  56 ;; This package was inspired by Roland McGrath's hanoi-break.el.
  57 ;; Several people contributed feedback and ideas, including
  58 ;;      Roland McGrath <roland@gnu.org>
  59 ;;      Kleanthes Koniaris <kgk@koniaris.com>
  60 ;;      Mark Ashton <mpashton@gnu.org>
  61 ;;      Matt Wilding <wilding@cli.com>
  62 ;;      Robert S. Boyer <boyer@cs.utexas.edu>
  63
  64 ;;; Code:
  65
  66 \f
  67 (defgroup type-break nil
  68   "Encourage the user to take a rest from typing at suitable intervals."
  69   :prefix "type-break"
  70   :group 'keyboard)
  71
  72 (defcustom type-break-interval (* 60 60)
  73   "Number of seconds between scheduled typing breaks."
  74   :type 'integer
  75   :group 'type-break)
  76
  77 (defcustom type-break-good-rest-interval (/ type-break-interval 6)
  78   "Number of seconds of idle time considered to be an adequate typing rest.
  79
  80 When this variable is non-nil, Emacs checks the idle time between
  81 keystrokes.  If this idle time is long enough to be considered a \"good\"
  82 rest from typing, then the next typing break is simply rescheduled for later.
  83
  84 If a break is interrupted before this much time elapses, the user will be
  85 asked whether or not really to interrupt the break."
  86   :set-after '(type-break-interval)
  87   :type 'integer
  88   :group 'type-break)
  89
  90 (defcustom type-break-good-break-interval nil
  91   "Number of seconds considered to be an adequate explicit typing rest.
  92
  93 When this variable is non-nil, its value is considered to be a \"good\"
  94 length (in seconds) for a break initiated by the command `type-break',
  95 overriding `type-break-good-rest-interval'.  This provides querying of
  96 break interruptions when `type-break-good-rest-interval' is nil."
  97   :type '(choice (const nil) integer)
  98   :group 'type-break)
  99
 100 (defcustom type-break-keystroke-threshold
 101   ;; Assuming typing speed is 35wpm (on the average, do you really
 102   ;; type more than that in a minute?  I spend a lot of time reading mail
 103   ;; and simply studying code in buffers) and average word length is
 104   ;; about 5 letters, default upper threshold to the average number of
 105   ;; keystrokes one is likely to type in a break interval.  That way if the
 106   ;; user goes through a furious burst of typing activity, cause a typing
 107   ;; break to be required sooner than originally scheduled.
 108   ;; Conversely, the minimum threshold should be about a fifth of this.
 109   (let* ((wpm 35)
 110          (avg-word-length 5)
 111          (upper (* wpm avg-word-length (/ type-break-interval 60)))
 112          (lower (/ upper 5)))
 113     (cons lower upper))
 114   "Upper and lower bound on number of keystrokes for considering typing break.
 115 This structure is a pair of numbers (MIN . MAX).
 116
 117 The first number is the minimum number of keystrokes that must have been
 118 entered since the last typing break before considering another one, even if
 119 the scheduled time has elapsed; the break is simply rescheduled until later
 120 if the minimum threshold hasn't been reached.  If this first value is nil,
 121 then there is no minimum threshold; as soon as the scheduled time has
 122 elapsed, the user will always be queried.
 123
 124 The second number is the maximum number of keystrokes that can be entered
 125 before a typing break is requested immediately, pre-empting the originally
 126 scheduled break.  If this second value is nil, then no pre-emptive breaks
 127 will occur; only scheduled ones will.
 128
 129 Keys with bucky bits (shift, control, meta, etc) are counted as only one
 130 keystroke even though they really require multiple keys to generate them.
 131
 132 The command `type-break-guesstimate-keystroke-threshold' can be used to
 133 guess a reasonably good pair of values for this variable."
 134   :set-after '(type-break-interval)
 135   :type 'sexp
 136   :group 'type-break)
 137
 138 (defcustom type-break-query-function 'yes-or-no-p
 139   "Function to use for making query for a typing break.
 140 It should take a string as an argument, the prompt.
 141 Usually this should be set to `yes-or-no-p' or `y-or-n-p'.
 142
 143 To avoid being queried at all, set `type-break-query-mode' to nil."
 144   :type '(radio function
 145                 (function-item yes-or-no-p)
 146                 (function-item y-or-n-p))
 147   :group 'type-break)
 148
 149 (defcustom type-break-query-interval 60
 150   "Number of seconds between queries to take a break, if put off.
 151 The user will continue to be prompted at this interval until he or she
 152 finally submits to taking a typing break."
 153   :type 'integer
 154   :group 'type-break)
 155
 156 (defcustom type-break-time-warning-intervals '(300 120 60 30)
 157   "List of time intervals for warnings about upcoming typing break.
 158 At each of the intervals (specified in seconds) away from a scheduled
 159 typing break, print a warning in the echo area."
 160   :type '(repeat integer)
 161   :group 'type-break)
 162
 163 (defcustom type-break-keystroke-warning-intervals '(300 200 100 50)
 164   "List of keystroke measurements for warnings about upcoming typing break.
 165 At each of the intervals (specified in keystrokes) away from the upper
 166 keystroke threshold, print a warning in the echo area.
 167 If either this variable or the upper threshold is set, then no warnings
 168 will occur."
 169   :type '(repeat integer)
 170   :group 'type-break)
 171
 172 (defcustom type-break-warning-repeat 40
 173   "Number of keystrokes for which warnings should be repeated.
 174 That is, for each of this many keystrokes the warning is redisplayed
 175 in the echo area to make sure it's really seen."
 176   :type 'integer
 177   :group 'type-break)
 178
 179 (defcustom type-break-time-stamp-format "[%H:%M] "
 180   "Timestamp format used to prefix messages.
 181 Format specifiers are as used by `format-time-string'."
 182   :type 'string
 183   :group 'type-break)
 184
 185 (defcustom type-break-demo-functions
 186   '(type-break-demo-boring type-break-demo-life type-break-demo-hanoi)
 187   "List of functions to consider running as demos during typing breaks.
 188 When a typing break begins, one of these functions is selected randomly
 189 to have Emacs do something interesting.
 190
 191 Any function in this list should start a demo which ceases as soon as a
 192 key is pressed."
 193   :type '(repeat function)
 194   :group 'type-break)
 195
 196 (defcustom type-break-demo-boring-stats nil
 197   "Show word per minute and keystroke figures in the Boring demo."
 198   :type 'boolean
 199   :group 'type-break)
 200
 201 (defcustom type-break-terse-messages nil
 202   "Use slightly terser messages."
 203   :type 'boolean
 204   :group 'type-break)
 205
 206 (defcustom type-break-file-name
 207   (locate-user-emacs-file "type-break" ".type-break")
 208   "Name of file used to save state across sessions.
 209 If this is nil, no data will be saved across sessions."
 210   :version "24.4"                       ; added locate-user
 211   :type 'file)
 212
 213 (defvar type-break-post-command-hook '(type-break-check)
 214   "Hook run indirectly by `post-command-hook' for typing break functions.
 215 This is not really intended to be set by the user, but it's probably
 216 harmless to do so.  Mainly it is used by various parts of the typing break
 217 program to delay actions until after the user has completed some command.
 218 It exists because `post-command-hook' itself is inaccessible while its
 219 functions are being run, and some type-break--related functions want to
 220 remove themselves after running.")
 221
 222 \f
 223 ;; Mode line frobs
 224
 225 (defvar type-break-mode-line-format
 226   '(type-break-mode-line-message-mode
 227     (""
 228      type-break-mode-line-break-message
 229      type-break-mode-line-warning))
 230   "Format of messages in the mode line concerning typing breaks.")
 231
 232 (defvar type-break-mode-line-break-message
 233   '(type-break-mode-line-break-message-p
 234     type-break-mode-line-break-string))
 235
 236 (defvar type-break-mode-line-break-message-p nil)
 237 (defvar type-break-mode-line-break-string " *** TAKE A TYPING BREAK NOW ***")
 238
 239 (defvar type-break-mode-line-warning
 240       '(type-break-mode-line-break-message-p
 241         ("")
 242         (type-break-warning-countdown-string
 243          (" *** "
 244           "Break in "
 245           type-break-warning-countdown-string
 246           " "
 247           type-break-warning-countdown-string-type
 248           "***"))))
 249
 250 (defvar type-break-warning-countdown-string nil
 251   "If non-nil, this is a countdown for the next typing break.
 252
 253 This variable, in conjunction with `type-break-warning-countdown-string-type'
 254 \(which indicates whether this value is a number of keystrokes or seconds)
 255 is installed in `mode-line-format' to notify of imminent typing breaks.")
 256
 257 (defvar type-break-warning-countdown-string-type nil
 258   "Indicates the unit type of `type-break-warning-countdown-string'.
 259 It will be either \"seconds\" or \"keystrokes\".")
 260
 261 \f
 262 ;; These are internal variables.  Do not set them yourself.
 263
 264 (defvar type-break-alarm-p nil)
 265 (defvar type-break-keystroke-count 0)
 266 (defvar type-break-time-last-break nil)
 267 (defvar type-break-time-next-break nil)
 268 (defvar type-break-time-last-command (current-time))
 269 (defvar type-break-current-time-warning-interval nil)
 270 (defvar type-break-current-keystroke-warning-interval nil)
 271 (defvar type-break-time-warning-count 0)
 272 (defvar type-break-keystroke-warning-count 0)
 273 (defvar type-break-interval-start nil)
 274
 275 \f
 276 ;;;###autoload
 277 (define-minor-mode type-break-mode
 278   "Enable or disable typing-break mode.
 279 This is a minor mode, but it is global to all buffers by default.
 280
 281 When this mode is enabled, the user is encouraged to take typing breaks at
 282 appropriate intervals; either after a specified amount of time or when the
 283 user has exceeded a keystroke threshold.  When the time arrives, the user
 284 is asked to take a break.  If the user refuses at that time, Emacs will ask
 285 again in a short period of time.  The idea is to give the user enough time
 286 to find a good breaking point in his or her work, but be sufficiently
 287 annoying to discourage putting typing breaks off indefinitely.
 288
 289 A negative prefix argument disables this mode.
 290 No argument or any non-negative argument enables it.
 291
 292 The user may enable or disable this mode by setting the variable of the
 293 same name, though setting it in that way doesn't reschedule a break or
 294 reset the keystroke counter.
 295
 296 If the mode was previously disabled and is enabled as a consequence of
 297 calling this function, it schedules a break with `type-break-schedule' to
 298 make sure one occurs (the user can call that command to reschedule the
 299 break at any time).  It also initializes the keystroke counter.
 300
 301 The variable `type-break-interval' specifies the number of seconds to
 302 schedule between regular typing breaks.  This variable doesn't directly
 303 affect the time schedule; it simply provides a default for the
 304 `type-break-schedule' command.
 305
 306 If set, the variable `type-break-good-rest-interval' specifies the minimum
 307 amount of time which is considered a reasonable typing break.  Whenever
 308 that time has elapsed, typing breaks are automatically rescheduled for
 309 later even if Emacs didn't prompt you to take one first.  Also, if a break
 310 is ended before this much time has elapsed, the user will be asked whether
 311 or not to continue.  A nil value for this variable prevents automatic
 312 break rescheduling, making `type-break-interval' an upper bound on the time
 313 between breaks.  In this case breaks will be prompted for as usual before
 314 the upper bound if the keystroke threshold is reached.
 315
 316 If `type-break-good-rest-interval' is nil and
 317 `type-break-good-break-interval' is set, then confirmation is required to
 318 interrupt a break before `type-break-good-break-interval' seconds
 319 have passed.  This provides for an upper bound on the time between breaks
 320 together with confirmation of interruptions to these breaks.
 321
 322 The variable `type-break-keystroke-threshold' is used to determine the
 323 thresholds at which typing breaks should be considered.  You can use
 324 the command `type-break-guesstimate-keystroke-threshold' to try to
 325 approximate good values for this.
 326
 327 There are several variables that affect how or when warning messages about
 328 imminent typing breaks are displayed.  They include:
 329
 330         `type-break-mode-line-message-mode'
 331         `type-break-time-warning-intervals'
 332         `type-break-keystroke-warning-intervals'
 333         `type-break-warning-repeat'
 334         `type-break-warning-countdown-string'
 335         `type-break-warning-countdown-string-type'
 336
 337 There are several variables that affect if, how, and when queries to begin
 338 a typing break occur.  They include:
 339
 340         `type-break-query-mode'
 341         `type-break-query-function'
 342         `type-break-query-interval'
 343
 344 The command `type-break-statistics' prints interesting things.
 345
 346 Finally, a file (named `type-break-file-name') is used to store information
 347 across Emacs sessions.  This provides recovery of the break status between
 348 sessions and after a crash.  Manual changes to the file may result in
 349 problems."
 350   :lighter type-break-mode-line-format
 351   :global t
 352
 353   (type-break-check-post-command-hook)
 354
 355   (cond
 356    ;; ((and already-enabled type-break-mode)
 357    ;;  (and (called-interactively-p 'interactive)
 358    ;;       (message "Type Break mode is already enabled")))
 359    (type-break-mode
 360     (when type-break-file-name
 361       (with-current-buffer (find-file-noselect type-break-file-name 'nowarn)
 362         (setq buffer-save-without-query t)))
 363
 364     (or global-mode-string (setq global-mode-string '(""))) ;FIXME: Why?
 365     (type-break-keystroke-reset)
 366     (type-break-mode-line-countdown-or-break nil)
 367
 368     (setq type-break-time-last-break
 369           (or (type-break-get-previous-time)
 370               (current-time)))
 371
 372     ;; Schedule according to break time from session file.
 373     (type-break-schedule
 374      (let (diff)
 375        (if (and type-break-time-last-break
 376                 (< (setq diff (type-break-time-difference
 377                                type-break-time-last-break
 378                                (current-time)))
 379                    type-break-interval))
 380            ;; Use the file's value.
 381            (progn
 382              (setq type-break-keystroke-count
 383                    (type-break-get-previous-count))
 384              ;; File the time, in case it was read from the auto-save file.
 385              (type-break-file-time type-break-interval-start)
 386              (setq type-break-interval-start type-break-time-last-break)
 387              (- type-break-interval diff))
 388          ;; Schedule from now.
 389          (setq type-break-interval-start (current-time))
 390          (type-break-file-time type-break-interval-start)
 391          type-break-interval))
 392      type-break-interval-start
 393      type-break-interval))
 394    (t
 395     (type-break-keystroke-reset)
 396     (type-break-mode-line-countdown-or-break nil)
 397     (type-break-cancel-schedule)
 398     (do-auto-save)
 399     (when type-break-file-name
 400       (with-current-buffer (find-file-noselect type-break-file-name
 401                                                'nowarn)
 402         (set-buffer-modified-p nil)
 403         (unlock-buffer)
 404         (kill-this-buffer))))))
 405
 406 (define-minor-mode type-break-mode-line-message-mode
 407   "Toggle warnings about typing breaks in the mode line.
 408 With a prefix argument ARG, enable these warnings if ARG is
 409 positive, and disable them otherwise.  If called from Lisp,
 410 enable them if ARG is omitted or nil.
 411
 412 The user may also enable or disable this mode simply by setting
 413 the variable of the same name.
 414
 415 Variables controlling the display of messages in the mode line include:
 416
 417         `mode-line-format'
 418         `global-mode-string'
 419         `type-break-mode-line-break-message'
 420         `type-break-mode-line-warning'"
 421   :global t :group 'type-break)
 422
 423 (define-minor-mode type-break-query-mode
 424   "Toggle typing break queries.
 425 With a prefix argument ARG, enable these queries if ARG is
 426 positive, and disable them otherwise.  If called from Lisp,
 427 enable them if ARG is omitted or nil.
 428
 429 The user may also enable or disable this mode simply by setting
 430 the variable of the same name."
 431   :global t :group 'type-break)
 432
 433 \f
 434 ;;; session file functions
 435
 436 (defvar type-break-auto-save-file-name
 437   (let ((buffer-file-name type-break-file-name))
 438     (make-auto-save-file-name))
 439   "Auto-save name of `type-break-file-name'.")
 440
 441 (defun type-break-file-time (&optional time)
 442   "File break time in `type-break-file-name', unless the file is locked."
 443   (if (and type-break-file-name
 444            (not (stringp (file-locked-p type-break-file-name))))
 445       (with-current-buffer (find-file-noselect type-break-file-name
 446                                                'nowarn)
 447         (let ((inhibit-read-only t))
 448           (erase-buffer)
 449           (insert (format "%s\n\n" (or time type-break-interval-start)))
 450           ;; file saving is left to auto-save
 451           ))))
 452
 453 (defun type-break-file-keystroke-count ()
 454   "File keystroke count in `type-break-file-name', unless the file is locked."
 455   (if (and type-break-file-name
 456            (not (stringp (file-locked-p type-break-file-name))))
 457       ;; Prevent deactivation of the mark in some other buffer.
 458       (let (deactivate-mark)
 459         (with-current-buffer (find-file-noselect type-break-file-name
 460                                                  'nowarn)
 461           (save-excursion
 462             (let ((inhibit-read-only t))
 463               (goto-char (point-min))
 464               (forward-line)
 465               (delete-region (point) (line-end-position))
 466               (insert (format "%s" type-break-keystroke-count))
 467               ;; file saving is left to auto-save
 468               ))))))
 469
 470 (defun timep (time)
 471   "If TIME is in the format returned by `current-time' then
 472 return TIME, else return nil."
 473   (condition-case nil
 474       (and (float-time time) time)
 475     (error nil)))
 476
 477 (defun type-break-choose-file ()
 478   "Return file to read from."
 479   (cond
 480    ((not type-break-file-name)
 481     nil)
 482    ((and (file-exists-p type-break-auto-save-file-name)
 483          (file-readable-p type-break-auto-save-file-name))
 484     type-break-auto-save-file-name)
 485    ((and (file-exists-p type-break-file-name)
 486          (file-readable-p type-break-file-name))
 487     type-break-file-name)
 488    (t nil)))
 489
 490 (defun type-break-get-previous-time ()
 491   "Get previous break time from `type-break-file-name'.
 492 Returns nil if the file is missing or if the time breaks with the
 493 `current-time' format."
 494   (let ((file (type-break-choose-file)))
 495     (if file
 496         (timep ;; returns expected format, else nil
 497          (with-current-buffer (find-file-noselect file 'nowarn)
 498            (condition-case nil
 499                (save-excursion
 500                  (goto-char (point-min))
 501                  (read (current-buffer)))
 502              (end-of-file
 503               (error "End of file in `%s'" file))))))))
 504
 505 (defun type-break-get-previous-count ()
 506   "Get previous keystroke count from `type-break-file-name'.
 507 Return 0 if the file is missing or if the form read is not an
 508 integer."
 509   (let ((file (type-break-choose-file)))
 510     (if (and file
 511              (integerp
 512               (setq file
 513                     (with-current-buffer
 514                         (find-file-noselect file 'nowarn)
 515                     (condition-case nil
 516                         (save-excursion
 517                           (goto-char (point-min))
 518                           (forward-line 1)
 519                           (read (current-buffer)))
 520                       (end-of-file
 521                        (error "End of file in `%s'" file)))))))
 522         file
 523       0)))
 524
 525 \f
 526 ;;;###autoload
 527 (defun type-break ()
 528   "Take a typing break.
 529
 530 During the break, a demo selected from the functions listed in
 531 `type-break-demo-functions' is run.
 532
 533 After the typing break is finished, the next break is scheduled
 534 as per the function `type-break-schedule'."
 535   (interactive)
 536   (do-auto-save)
 537   (type-break-cancel-schedule)
 538   ;; remove any query scheduled during interactive invocation
 539   (remove-hook 'type-break-post-command-hook 'type-break-do-query)
 540   (let ((continue t)
 541         (start-time (current-time)))
 542     (setq type-break-time-last-break start-time)
 543     (while continue
 544       (save-window-excursion
 545         ;; Eat the screen.
 546         (and (eq (selected-window) (minibuffer-window))
 547              (other-window 1))
 548         (delete-other-windows)
 549         (scroll-right (window-width))
 550         (unless type-break-terse-messages
 551           (message "Press any key to resume from typing break."))
 552
 553         (let* ((len (length type-break-demo-functions))
 554                (idx (random len))
 555                (fn (nth idx type-break-demo-functions)))
 556           (condition-case ()
 557               (funcall fn)
 558             (error nil))))
 559
 560       (let ((good-interval (or type-break-good-rest-interval
 561                                type-break-good-break-interval)))
 562         (cond
 563          (good-interval
 564           (let ((break-secs (type-break-time-difference
 565                              start-time (current-time))))
 566             (cond
 567              ((>= break-secs good-interval)
 568               (setq continue nil))
 569              ;; 60 seconds may be too much leeway if the break is only 3
 570              ;; minutes to begin with.  You can just say "no" to the query
 571              ;; below if you're in that much of a hurry.
 572              ;;((> 60 (abs (- break-secs good-interval)))
 573              ;; (setq continue nil))
 574              ((funcall
 575                type-break-query-function
 576                (format
 577                 (if type-break-terse-messages
 578                     "%s%s remaining.  Continue break? "
 579                   "%sYou really ought to rest %s more.  Continue break? ")
 580                 (type-break-time-stamp)
 581                 (type-break-format-time (- good-interval
 582                                            break-secs)))))
 583              (t
 584               (setq continue nil)))))
 585          (t (setq continue nil))))))
 586
 587   (type-break-keystroke-reset)
 588   (type-break-file-time)
 589   (type-break-mode-line-countdown-or-break nil)
 590   (type-break-schedule))
 591
 592 \f
 593 (defun type-break-schedule (&optional time start interval)
 594   "Schedule a typing break for TIME seconds from now.
 595 If time is not specified it defaults to `type-break-interval'.
 596 START and INTERVAL are used when recovering a break.
 597 START is the start of the break (defaults to now).
 598 INTERVAL is the full length of an interval (defaults to TIME)."
 599   (interactive (list (and current-prefix-arg
 600                           (prefix-numeric-value current-prefix-arg))))
 601   (or time (setq time type-break-interval))
 602   (type-break-check-post-command-hook)
 603   (type-break-cancel-schedule)
 604   (type-break-time-warning-schedule time 'reset)
 605   (type-break-run-at-time (max 1 time) nil 'type-break-alarm)
 606   (setq type-break-time-next-break
 607         (type-break-time-sum start (or interval time))))
 608
 609 (defun type-break-cancel-schedule ()
 610   (type-break-cancel-time-warning-schedule)
 611   (type-break-cancel-function-timers 'type-break-alarm)
 612   (setq type-break-alarm-p nil)
 613   (setq type-break-time-next-break nil))
 614
 615 (defun type-break-time-warning-schedule (&optional time resetp)
 616   (let ((type-break-current-time-warning-interval nil))
 617     (type-break-cancel-time-warning-schedule))
 618   (add-hook 'type-break-post-command-hook 'type-break-time-warning 'append)
 619   (cond
 620    (type-break-time-warning-intervals
 621     (and resetp
 622          (setq type-break-current-time-warning-interval
 623                type-break-time-warning-intervals))
 624
 625     (or time
 626         (setq time (type-break-time-difference (current-time)
 627                                                type-break-time-next-break)))
 628
 629     (while (and type-break-current-time-warning-interval
 630                 (> (car type-break-current-time-warning-interval) time))
 631       (setq type-break-current-time-warning-interval
 632             (cdr type-break-current-time-warning-interval)))
 633
 634     (cond
 635      (type-break-current-time-warning-interval
 636       (setq time (- time (car type-break-current-time-warning-interval)))
 637       (setq type-break-current-time-warning-interval
 638             (cdr type-break-current-time-warning-interval))
 639
 640       ;(let (type-break-current-time-warning-interval)
 641       ;  (type-break-cancel-time-warning-schedule))
 642       (type-break-run-at-time (max 1 time) nil 'type-break-time-warning-alarm)
 643
 644       (cond
 645        (resetp
 646         (setq type-break-warning-countdown-string nil))
 647        (t
 648         (setq type-break-warning-countdown-string (number-to-string time))
 649         (setq type-break-warning-countdown-string-type "seconds"))))))))
 650
 651 (defun type-break-cancel-time-warning-schedule ()
 652   (type-break-cancel-function-timers 'type-break-time-warning-alarm)
 653   (remove-hook 'type-break-post-command-hook 'type-break-time-warning)
 654   (setq type-break-current-time-warning-interval
 655         type-break-time-warning-intervals)
 656   (setq type-break-time-warning-count 0) ; avoid warnings after break
 657   (setq type-break-warning-countdown-string nil))
 658
 659 (defun type-break-alarm ()
 660   (type-break-check-post-command-hook)
 661   (setq type-break-alarm-p t)
 662   (type-break-mode-line-countdown-or-break 'break))
 663
 664 (defun type-break-time-warning-alarm ()
 665   (type-break-check-post-command-hook)
 666   (type-break-time-warning-schedule)
 667   (setq type-break-time-warning-count type-break-warning-repeat)
 668   (type-break-time-warning)
 669   (type-break-mode-line-countdown-or-break 'countdown))
 670
 671 \f
 672 (defun type-break-run-tb-post-command-hook ()
 673   (and type-break-mode
 674        (run-hooks 'type-break-post-command-hook)))
 675
 676 (defun type-break-check ()
 677   "Ask to take a typing break if appropriate.
 678 This may be the case either because the scheduled time has come \(and the
 679 minimum keystroke threshold has been reached\) or because the maximum
 680 keystroke threshold has been exceeded."
 681   (type-break-file-keystroke-count)
 682   (let* ((min-threshold (car type-break-keystroke-threshold))
 683          (max-threshold (cdr type-break-keystroke-threshold)))
 684     (and type-break-good-rest-interval
 685          (progn
 686            (and (> (type-break-time-difference
 687                     type-break-time-last-command (current-time))
 688                    type-break-good-rest-interval)
 689                 (progn
 690                   (type-break-keystroke-reset)
 691                   (type-break-mode-line-countdown-or-break nil)
 692                   (setq type-break-time-last-break (current-time))
 693                   (type-break-schedule)))
 694            (setq type-break-time-last-command (current-time))))
 695
 696     (and type-break-keystroke-threshold
 697          (let ((keys (this-command-keys)))
 698            (cond
 699             ;; Ignore mouse motion
 700             ((and (vectorp keys)
 701                   (consp (aref keys 0))
 702                   (memq (car (aref keys 0)) '(mouse-movement))))
 703             (t
 704              (setq type-break-keystroke-count
 705                    (+ type-break-keystroke-count (length keys)))))))
 706
 707     (cond
 708      (type-break-alarm-p
 709       (cond
 710        ((input-pending-p))
 711        ((eq (selected-window) (minibuffer-window)))
 712        ((and min-threshold
 713              (< type-break-keystroke-count min-threshold))
 714         (type-break-schedule))
 715        (t
 716         ;; If keystroke count is within min-threshold of
 717         ;; max-threshold, lower it to reduce the likelihood of an
 718         ;; immediate subsequent query.
 719         (and max-threshold
 720              min-threshold
 721              (< (- max-threshold type-break-keystroke-count) min-threshold)
 722              (progn
 723                (type-break-keystroke-reset)
 724                (setq type-break-keystroke-count min-threshold)))
 725         (type-break-query))))
 726      ((and type-break-keystroke-warning-intervals
 727            max-threshold
 728            (= type-break-keystroke-warning-count 0)
 729            (type-break-check-keystroke-warning)))
 730      ((and max-threshold
 731            (> type-break-keystroke-count max-threshold)
 732            (not (input-pending-p))
 733            (not (eq (selected-window) (minibuffer-window))))
 734       (type-break-keystroke-reset)
 735       (setq type-break-keystroke-count (or min-threshold 0))
 736       (type-break-query)))))
 737
 738 ;; This should return t if warnings were enabled, nil otherwise.
 739 (defun type-break-check-keystroke-warning ()
 740   ;; This is safe because the caller should have checked that the cdr was
 741   ;; non-nil already.
 742   (let ((left (- (cdr type-break-keystroke-threshold)
 743                  type-break-keystroke-count)))
 744     (cond
 745      ((null (car type-break-current-keystroke-warning-interval))
 746       nil)
 747      ((> left (car type-break-current-keystroke-warning-interval))
 748       nil)
 749      (t
 750       (while (and (car type-break-current-keystroke-warning-interval)
 751                   (< left (car type-break-current-keystroke-warning-interval)))
 752         (setq type-break-current-keystroke-warning-interval
 753               (cdr type-break-current-keystroke-warning-interval)))
 754       (setq type-break-keystroke-warning-count type-break-warning-repeat)
 755       (add-hook 'type-break-post-command-hook 'type-break-keystroke-warning)
 756       (setq type-break-warning-countdown-string (number-to-string left))
 757       (setq type-break-warning-countdown-string-type "keystrokes")
 758       (type-break-mode-line-countdown-or-break 'countdown)
 759       t))))
 760
 761 ;; Arrange for a break query to be made, when the user stops typing furiously.
 762 (defun type-break-query ()
 763   (add-hook 'type-break-post-command-hook 'type-break-do-query))
 764
 765 (defun type-break-do-query ()
 766   (cond
 767    ((not type-break-query-mode)
 768     (type-break-noninteractive-query)
 769     (type-break-schedule type-break-query-interval)
 770     (remove-hook 'type-break-post-command-hook 'type-break-do-query))
 771    ((sit-for 2)
 772     (condition-case ()
 773         (cond
 774          ((let ((type-break-mode nil)
 775                 ;; yes-or-no-p sets this-command to exit-minibuffer,
 776                 ;; which hoses undo or yank-pop (if you happened to be
 777                 ;; yanking just when the query occurred).
 778                 (this-command this-command))
 779             ;; Cancel schedule to prevent possibility of a second query
 780             ;; from taking place before this one has even returned.
 781             ;; The condition-case wrapper will reschedule on quit.
 782             (type-break-cancel-schedule)
 783             ;; Also prevent a second query when the break is interrupted.
 784             (remove-hook 'type-break-post-command-hook 'type-break-do-query)
 785             (funcall type-break-query-function
 786                      (format "%s%s"
 787                              (type-break-time-stamp)
 788                              (if type-break-terse-messages
 789                                  "Break now? "
 790                                "Take a break from typing now? "))))
 791           (type-break))
 792          (t
 793           (type-break-schedule type-break-query-interval)))
 794       (quit
 795        (type-break-schedule type-break-query-interval))))))
 796
 797 (defun type-break-noninteractive-query (&optional _ignored-args)
 798   "Null query function which doesn't interrupt user and assumes `no'.
 799 It prints a reminder in the echo area to take a break, but doesn't enforce
 800 this or ask the user to start one right now."
 801   (cond
 802    (type-break-mode-line-message-mode)
 803    (t
 804     (beep t)
 805     (message "%sYou should take a typing break now.  Do `M-x type-break'."
 806              (type-break-time-stamp))
 807     (sit-for 1)
 808     (beep t)
 809     ;; return nil so query caller knows to reset reminder, as if user
 810     ;; said "no" in response to yes-or-no-p.
 811     nil)))
 812
 813 (defun type-break-time-warning ()
 814   (cond
 815    ((and (car type-break-keystroke-threshold)
 816          (< type-break-keystroke-count (car type-break-keystroke-threshold))))
 817    ((> type-break-time-warning-count 0)
 818     (let ((timeleft (type-break-time-difference (current-time)
 819                                                 type-break-time-next-break)))
 820       (setq type-break-warning-countdown-string (number-to-string timeleft))
 821       (cond
 822        ((eq (selected-window) (minibuffer-window)))
 823        ;; Do nothing if the command was just a prefix arg, since that will
 824        ;; immediately be followed by some other interactive command.
 825        ;; Otherwise, it is particularly annoying for the sit-for below to
 826        ;; delay redisplay when one types sequences like `C-u -1 C-l'.
 827        ((memq this-command '(digit-argument universal-argument)))
 828        ((not type-break-mode-line-message-mode)
 829         ;; Pause for a moment so any previous message can be seen.
 830         (sit-for 2)
 831         (message "%sWarning: typing break due in %s."
 832                  (type-break-time-stamp)
 833                  (type-break-format-time timeleft))
 834         (setq type-break-time-warning-count
 835               (1- type-break-time-warning-count))))))
 836    (t
 837     (remove-hook 'type-break-post-command-hook 'type-break-time-warning)
 838     (setq type-break-warning-countdown-string nil))))
 839
 840 (defun type-break-keystroke-warning ()
 841   (cond
 842    ((> type-break-keystroke-warning-count 0)
 843     (setq type-break-warning-countdown-string
 844           (number-to-string (- (cdr type-break-keystroke-threshold)
 845                                type-break-keystroke-count)))
 846     (cond
 847      ((eq (selected-window) (minibuffer-window)))
 848      ;; Do nothing if the command was just a prefix arg, since that will
 849      ;; immediately be followed by some other interactive command.
 850      ;; Otherwise, it is particularly annoying for the sit-for below to
 851      ;; delay redisplay when one types sequences like `C-u -1 C-l'.
 852      ((memq this-command '(digit-argument universal-argument)))
 853      ((not type-break-mode-line-message-mode)
 854       (sit-for 2)
 855       (message "%sWarning: typing break due in %s keystrokes."
 856                (type-break-time-stamp)
 857                (- (cdr type-break-keystroke-threshold)
 858                   type-break-keystroke-count))
 859       (setq type-break-keystroke-warning-count
 860             (1- type-break-keystroke-warning-count)))))
 861    (t
 862     (remove-hook 'type-break-post-command-hook
 863                  'type-break-keystroke-warning)
 864     (setq type-break-warning-countdown-string nil))))
 865
 866 (defun type-break-mode-line-countdown-or-break (&optional type)
 867   (cond
 868    ((not type-break-mode-line-message-mode))
 869    ((eq type 'countdown)
 870     ;(setq type-break-mode-line-break-message-p nil)
 871     (add-hook 'type-break-post-command-hook
 872               'type-break-force-mode-line-update 'append))
 873    ((eq type 'break)
 874     ;; Alternate
 875     (setq type-break-mode-line-break-message-p
 876           (not type-break-mode-line-break-message-p))
 877     (remove-hook 'type-break-post-command-hook
 878                  'type-break-force-mode-line-update))
 879    (t
 880     (setq type-break-mode-line-break-message-p nil)
 881     (setq type-break-warning-countdown-string nil)
 882     (remove-hook 'type-break-post-command-hook
 883                  'type-break-force-mode-line-update)))
 884   (type-break-force-mode-line-update))
 885
 886 \f
 887 ;;;###autoload
 888 (defun type-break-statistics ()
 889   "Print statistics about typing breaks in a temporary buffer.
 890 This includes the last time a typing break was taken, when the next one is
 891 scheduled, the keystroke thresholds and the current keystroke count, etc."
 892   (interactive)
 893   (with-output-to-temp-buffer "*Typing Break Statistics*"
 894     (princ (format "Typing break statistics\n-----------------------\n
 895 Typing break mode is currently %s.
 896 Interactive query for breaks is %s.
 897 Warnings of imminent typing breaks in mode line is %s.
 898
 899 Last typing break ended     : %s
 900 Next scheduled typing break : %s\n
 901 Minimum keystroke threshold : %s
 902 Maximum keystroke threshold : %s
 903 Current keystroke count     : %s"
 904                    (if type-break-mode "enabled" "disabled")
 905                    (if type-break-query-mode "enabled" "disabled")
 906                    (if type-break-mode-line-message-mode "enabled" "disabled")
 907                    (if type-break-time-last-break
 908                        (current-time-string type-break-time-last-break)
 909                      "never")
 910                    (if (and type-break-mode type-break-time-next-break)
 911                        (format "%s\t(%s from now)"
 912                                (current-time-string type-break-time-next-break)
 913                                (type-break-format-time
 914                                 (type-break-time-difference
 915                                 (current-time)
 916                                 type-break-time-next-break)))
 917                      "none scheduled")
 918                    (or (car type-break-keystroke-threshold) "none")
 919                    (or (cdr type-break-keystroke-threshold) "none")
 920                    type-break-keystroke-count))))
 921
 922 ;;;###autoload
 923 (defun type-break-guesstimate-keystroke-threshold (wpm &optional wordlen frac)
 924   "Guess values for the minimum/maximum keystroke threshold for typing breaks.
 925
 926 If called interactively, the user is prompted for their guess as to how
 927 many words per minute they usually type.  This value should not be your
 928 maximum WPM, but your average.  Of course, this is harder to gauge since it
 929 can vary considerably depending on what you are doing.  For example, one
 930 tends to type less when debugging a program as opposed to writing
 931 documentation.  (Perhaps a separate program should be written to estimate
 932 average typing speed.)
 933
 934 From that, this command sets the values in `type-break-keystroke-threshold'
 935 based on a fairly simple algorithm involving assumptions about the average
 936 length of words (5).  For the minimum threshold, it uses about a fifth of
 937 the computed maximum threshold.
 938
 939 When called from Lisp programs, the optional args WORDLEN and FRAC can be
 940 used to override the default assumption about average word length and the
 941 fraction of the maximum threshold to which to set the minimum threshold.
 942 FRAC should be the inverse of the fractional value; for example, a value of
 943 2 would mean to use one half, a value of 4 would mean to use one quarter, etc."
 944   (interactive "NOn average, how many words per minute do you type? ")
 945   (let* ((upper (* wpm (or wordlen 5) (/ type-break-interval 60)))
 946          (lower (/ upper (or frac 5))))
 947     (or type-break-keystroke-threshold
 948         (setq type-break-keystroke-threshold (cons nil nil)))
 949     (setcar type-break-keystroke-threshold lower)
 950     (setcdr type-break-keystroke-threshold upper)
 951     (if (called-interactively-p 'interactive)
 952         (message "min threshold: %d\tmax threshold: %d" lower upper))
 953     type-break-keystroke-threshold))
 954
 955 \f
 956 ;;; misc functions
 957
 958 ;; Compute the difference, in seconds, between a and b, two structures
 959 ;; similar to those returned by `current-time'.
 960 (defun type-break-time-difference (a b)
 961   (round (float-time (time-subtract b a))))
 962
 963 ;; Return a time value that is the sum of the time-value arguments.
 964 (defun type-break-time-sum (&rest tmlist)
 965   (let ((sum '(0 0)))
 966     (dolist (tem tmlist)
 967       (setq sum (time-add sum tem)))
 968     sum))
 969
 970 (defun type-break-time-stamp (&optional when)
 971   (if (fboundp 'format-time-string)
 972       (format-time-string type-break-time-stamp-format when)
 973     ;; Emacs 19.28 and prior do not have format-time-string.
 974     ;; In that case, result is not customizable.  Upgrade today!
 975     (format "[%s] " (substring (current-time-string when) 11 16))))
 976
 977 (defun type-break-format-time (secs)
 978   (let ((mins (/ secs 60)))
 979     (cond
 980      ((= mins 1) (format "%d minute" mins))
 981      ((> mins 0) (format "%d minutes" mins))
 982      ((= secs 1) (format "%d second" secs))
 983      (t (format "%d seconds" secs)))))
 984
 985 (defun type-break-keystroke-reset ()
 986   (setq type-break-interval-start (current-time)) ; not a keystroke
 987   (setq type-break-keystroke-count 0)
 988   (setq type-break-keystroke-warning-count 0)
 989   (setq type-break-current-keystroke-warning-interval
 990         type-break-keystroke-warning-intervals)
 991   (remove-hook 'type-break-post-command-hook 'type-break-keystroke-warning))
 992
 993 (defun type-break-force-mode-line-update (&optional all)
 994   "Force the mode-line of the current buffer to be redisplayed.
 995 With optional non-nil ALL, force redisplay of all mode-lines."
 996   (and all (with-current-buffer (other-buffer)))
 997   (set-buffer-modified-p (buffer-modified-p)))
 998
 999 ;; If an exception occurs in Emacs while running the post command hook, the
1000 ;; value of that hook is clobbered.  This is because the value of the
1001 ;; variable is temporarily set to nil while it's running to prevent
1002 ;; recursive application, but it also means an exception aborts the routine
1003 ;; of restoring it.  This function is called from the timers to restore it,
1004 ;; just in case.
1005 (defun type-break-check-post-command-hook ()
1006   (add-hook 'post-command-hook 'type-break-run-tb-post-command-hook 'append))
1007
1008 \f
1009 ;;; Timer wrapper functions
1010 ;;
1011 ;; These shield type-break from variations in the interval timer packages
1012 ;; for different versions of Emacs.
1013
1014 (defun type-break-run-at-time (time repeat function)
1015   (condition-case nil (or (require 'timer) (require 'itimer)) (error nil))
1016   (run-at-time time repeat function))
1017
1018 (defvar timer-dont-exit)
1019 (defun type-break-cancel-function-timers (function)
1020   (let ((timer-dont-exit t))
1021     (cancel-function-timers function)))
1022
1023 \f
1024 ;;; Demo wrappers
1025
1026 (defun type-break-catch-up-event ()
1027   ;; If the last input event is a down-event, read and discard the
1028   ;; corresponding up-event too, to avoid triggering another prompt.
1029   (and (eventp last-input-event)
1030        (memq 'down (event-modifiers last-input-event))
1031        (read-event)))
1032
1033 ;; This is a wrapper around hanoi that calls it with an arg large enough to
1034 ;; make the largest discs possible that will fit in the window.
1035 ;; Also, clean up the *Hanoi* buffer after we're done.
1036 (defun type-break-demo-hanoi ()
1037   "Take a hanoiing typing break."
1038   (and (get-buffer "*Hanoi*")
1039        (kill-buffer "*Hanoi*"))
1040   (condition-case ()
1041       (progn
1042         (hanoi (/ (window-width) 8))
1043         ;; Wait for user to come back.
1044         (read-event)
1045         (type-break-catch-up-event)
1046         (kill-buffer "*Hanoi*"))
1047     (quit
1048      (read-event)
1049      (type-break-catch-up-event)
1050      (and (get-buffer "*Hanoi*")
1051           (kill-buffer "*Hanoi*")))))
1052
1053 ;; This is a wrapper around life that calls it with a `sleep' arg to make
1054 ;; it run a little more leisurely.
1055 ;; Also, clean up the *Life* buffer after we're done.
1056 (defun type-break-demo-life ()
1057   "Take a typing break and get a life."
1058   (let ((continue t))
1059     (while continue
1060       (setq continue nil)
1061       (and (get-buffer "*Life*")
1062            (kill-buffer "*Life*"))
1063       (condition-case ()
1064           (progn
1065             (life 3)
1066             ;; wait for user to return
1067             (read-event)
1068             (type-break-catch-up-event)
1069             (kill-buffer "*Life*"))
1070         (life-extinct
1071          (message "%s" (get 'life-extinct 'error-message))
1072          ;; restart demo
1073          (setq continue t))
1074         (quit
1075          (type-break-catch-up-event)
1076          (and (get-buffer "*Life*")
1077               (kill-buffer "*Life*")))))))
1078
1079 ;; Boring demo, but doesn't use many cycles
1080 (defun type-break-demo-boring ()
1081   "Boring typing break demo."
1082   (let ((rmsg (if type-break-terse-messages
1083                   ""
1084                 "Press any key to resume from typing break"))
1085         (buffer-name "*Typing Break Buffer*")
1086         lines elapsed timeleft tmsg)
1087     (condition-case ()
1088         (progn
1089           (switch-to-buffer (get-buffer-create buffer-name))
1090           (buffer-disable-undo (current-buffer))
1091           (setq lines (/ (window-body-height) 2))
1092           (unless type-break-terse-messages (setq lines (1- lines)))
1093           (if type-break-demo-boring-stats
1094               (setq lines (- lines 2)))
1095           (setq lines (make-string lines ?\C-j))
1096           (while (not (input-pending-p))
1097             (erase-buffer)
1098             (setq elapsed (type-break-time-difference
1099                            type-break-time-last-break
1100                            (current-time)))
1101             (let ((good-interval (or type-break-good-rest-interval
1102                                      type-break-good-break-interval)))
1103               (cond
1104                (good-interval
1105                 (setq timeleft (- good-interval elapsed))
1106                 (if (> timeleft 0)
1107                     (setq tmsg
1108                           (format (if type-break-terse-messages
1109                                       "Break remaining: %s"
1110                                     "You should rest for %s more")
1111                                   (type-break-format-time timeleft)))
1112                   (setq tmsg
1113                         (format (if type-break-terse-messages
1114                                     "Break complete (%s elapsed in total)"
1115                                   "Typing break has lasted %s")
1116                                 (type-break-format-time elapsed)))))
1117                (t
1118                 (setq tmsg
1119                       (format (if type-break-terse-messages
1120                                   "Break has lasted %s"
1121                                 "Typing break has lasted %s")
1122                               (type-break-format-time elapsed))))))
1123             (insert lines
1124                     (make-string (/ (- (window-width) (length tmsg)) 2) ?\ )
1125                     tmsg)
1126             (if (> (length rmsg) 0)
1127                 (insert "\n"
1128                         (make-string (/ (- (window-width) (length rmsg)) 2)
1129                                      ?\ )
1130                         rmsg))
1131             (if type-break-demo-boring-stats
1132                 (let*
1133                     ((message
1134                       (format
1135                        (if type-break-terse-messages
1136                            "Since last break: %s keystrokes\n"
1137                          "Since your last break you've typed %s keystrokes\n")
1138                        type-break-keystroke-count))
1139                      (column-spaces
1140                       (make-string (/ (- (window-width) (length message)) 2)
1141                                    ?\ ))
1142                      (wpm (/ (/ (float type-break-keystroke-count) 5)
1143                              (/ (type-break-time-difference
1144                                  type-break-interval-start
1145                                  type-break-time-last-break)
1146                                 60.0))))
1147                   (insert "\n\n" column-spaces message)
1148                   (if type-break-terse-messages
1149                       (insert (format "                  %s%.2f wpm"
1150                                       column-spaces
1151                                       wpm))
1152                     (setq message
1153                           (format "at an average of %.2f words per minute"
1154                                   wpm))
1155                     (insert
1156                      (make-string (/ (- (window-width) (length message)) 2)
1157                                   ?\ )
1158                      message))))
1159             (goto-char (point-min))
1160             (sit-for 60))
1161           (read-event)
1162           (type-break-catch-up-event)
1163           (kill-buffer buffer-name))
1164       (quit
1165        (and (get-buffer buffer-name)
1166             (kill-buffer buffer-name))))))
1167
1168 \f
1169 (provide 'type-break)
1170
1171 (if type-break-mode
1172     (type-break-mode 1))
1173
1174 ;;; type-break.el ends here