lisp/avoid.el

   1 ;;; avoid.el --- make mouse pointer stay out of the way of editing
   2
   3 ;; Copyright (C) 1993, 1994, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Boris Goldowsky <boris@gnu.org>
   7 ;; Keywords: mouse
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; For those who are annoyed by the mouse pointer obscuring text,
  27 ;; this mode moves the mouse pointer - either just a little out of
  28 ;; the way, or all the way to the corner of the frame.
  29 ;; To use, load or evaluate this file and type M-x mouse-avoidance-mode .
  30 ;; To set up permanently, put the following in your .emacs:
  31 ;;
  32 ;; (if (display-mouse-p) (mouse-avoidance-mode 'animate))
  33 ;;
  34 ;; Other legitimate alternatives include
  35 ;; `banish', `exile', `jump', `cat-and-mouse', and `proteus'.
  36 ;; They do somewhat different things.
  37 ;; See the documentation for function `mouse-avoidance-mode' for
  38 ;; details of the different modes.
  39 ;;
  40 ;; For added silliness, make the animatee animate...
  41 ;; put something similar to the following into your .emacs:
  42 ;;
  43 ;; (if (eq window-system 'x)
  44 ;;     (mouse-avoidance-set-pointer-shape
  45 ;;           (eval (nth (random 4)
  46 ;;                      '(x-pointer-man x-pointer-spider
  47 ;;                        x-pointer-gobbler x-pointer-gumby)))))
  48 ;;
  49 ;; For completely random pointer shape, replace the setq above with:
  50 ;; (setq x-pointer-shape (mouse-avoidance-random-shape))
  51 ;;
  52 ;; Bugs / Warnings / To-Do:
  53 ;;
  54 ;; - Using this code does slow Emacs down.  "banish" mode shouldn't
  55 ;;   be too bad, and on my workstation even "animate" is reasonable.
  56 ;;
  57 ;; - It ought to find out where any overlapping frames are and avoid them,
  58 ;;   rather than always raising the frame.
  59
  60 ;; Credits:
  61 ;; This code was helped by all those who contributed suggestions,
  62 ;;   fixes, and additions
  63 ;; Joe Harrington (and his advisor), for the original inspiration.
  64 ;; Ken Manheimer, for dreaming up the Protean mode.
  65 ;; Richard Stallman, for the awful cat-and-mouse pun, among other things.
  66 ;; Mike Williams, Denis Howe, Bill Benedetto, Chris Moore, Don Morris,
  67 ;; Simon Marshall, and M.S. Ashton, for their feedback.
  68
  69 ;;; Code:
  70
  71 (provide 'avoid)
  72
  73 (defgroup avoid nil
  74   "Make mouse pointer stay out of the way of editing."
  75   :prefix "mouse-avoidance-"
  76   :group 'mouse)
  77
  78 ;;;###autoload
  79 (defcustom mouse-avoidance-mode nil
  80   "Activate mouse avoidance mode.
  81 See function `mouse-avoidance-mode' for possible values.
  82 Setting this variable directly does not take effect;
  83 use either \\[customize] or the function `mouse-avoidance-mode'."
  84   :set (lambda (symbol value)
  85          ;; 'none below prevents toggling when value is nil.
  86          (mouse-avoidance-mode (or value 'none)))
  87   :initialize 'custom-initialize-default
  88   :type '(choice (const :tag "none" nil) (const banish) (const jump)
  89                  (const animate) (const exile) (const proteus)
  90                  )
  91   :group 'avoid
  92   :require 'avoid
  93   :version "20.3")
  94
  95
  96 (defcustom mouse-avoidance-nudge-dist 15
  97   "Average distance that mouse will be moved when approached by cursor.
  98 Only applies in Mouse-Avoidance mode `jump' and its derivatives.
  99 For best results make this larger than `mouse-avoidance-threshold'."
 100   :type 'integer
 101   :group 'avoid)
 102
 103 (defcustom mouse-avoidance-nudge-var 10
 104   "Variability of `mouse-avoidance-nudge-dist' (which see)."
 105   :type 'integer
 106   :group 'avoid)
 107
 108 (defcustom mouse-avoidance-animation-delay .01
 109   "Delay between animation steps, in seconds."
 110   :type 'number
 111   :group 'avoid)
 112
 113 (defcustom mouse-avoidance-threshold 5
 114   "Mouse-pointer's flight distance.
 115 If the cursor gets closer than this, the mouse pointer will move away.
 116 Only applies in mouse-avoidance-modes `animate' and `jump'."
 117   :type 'integer
 118   :group 'avoid)
 119
 120 ;; Internal variables
 121 (defvar mouse-avoidance-state nil)
 122 (defvar mouse-avoidance-pointer-shapes nil)
 123 (defvar mouse-avoidance-n-pointer-shapes 0)
 124 (defvar mouse-avoidance-old-pointer-shape nil)
 125 (defvar mouse-avoidance-animating-pointer nil)
 126
 127 ;; This timer is used to run something when Emacs is idle.
 128 (defvar mouse-avoidance-timer nil)
 129
 130 ;;; Functions:
 131
 132 (defsubst mouse-avoidance-set-pointer-shape (shape)
 133   "Set the shape of the mouse pointer to SHAPE."
 134   (when (boundp 'x-pointer-shape)
 135     (setq x-pointer-shape shape)
 136     (set-mouse-color nil)))
 137
 138 (defun mouse-avoidance-point-position ()
 139   "Return the position of point as (FRAME X . Y).
 140 Analogous to `mouse-position'."
 141   (let ((edges (window-inside-edges))
 142         (x-y (posn-x-y (posn-at-point))))
 143     (cons (selected-frame)
 144           (cons (+ (car edges)
 145                    (/ (car x-y) (frame-char-width)))
 146                 (+ (car (cdr edges))
 147                    (/ (cdr x-y) (frame-char-height)))))))
 148
 149 ;(defun mouse-avoidance-point-position-test ()
 150 ;  (interactive)
 151 ;  (message (format "point=%s mouse=%s"
 152 ;                  (cdr (mouse-avoidance-point-position))
 153 ;                  (cdr (mouse-position)))))
 154
 155 (defun mouse-avoidance-set-mouse-position (pos)
 156   ;; Carefully set mouse position to given position (X . Y)
 157   ;; Ideally, should check if X,Y is in the current frame, and if not,
 158   ;; leave the mouse where it was.  However, this is currently
 159   ;; difficult to do, so we just raise the frame to avoid frame switches.
 160   ;; Returns t if it moved the mouse.
 161   (let ((f (selected-frame)))
 162     (raise-frame f)
 163     (set-mouse-position f (car pos) (cdr pos))
 164     t))
 165
 166 (defun mouse-avoidance-too-close-p (mouse)
 167   "Return t if mouse pointer and point cursor are too close.
 168 MOUSE is the current mouse position as returned by `mouse-position'.
 169 Acceptable distance is defined by `mouse-avoidance-threshold'."
 170   (let* ((frame (car mouse))
 171          (mouse-y (cdr (cdr mouse)))
 172          (tool-bar-lines (frame-parameter nil 'tool-bar-lines)))
 173     (or tool-bar-lines
 174         (setq tool-bar-lines 0))
 175     (if (and mouse-y (< mouse-y tool-bar-lines))
 176         nil
 177       (let ((point (mouse-avoidance-point-position))
 178             (mouse-x (car (cdr mouse))))
 179         (and (eq frame (car point))
 180              (not (null mouse-x))
 181              (< (abs (- mouse-x (car (cdr point))))
 182                 mouse-avoidance-threshold)
 183              (< (abs (- mouse-y (cdr (cdr point))))
 184                 mouse-avoidance-threshold))))))
 185
 186 (defun mouse-avoidance-banish-destination ()
 187   "The position to which Mouse-Avoidance mode `banish' moves the mouse.
 188 You can redefine this if you want the mouse banished to a different corner."
 189   (let* ((pos (window-edges)))
 190     (cons (- (nth 2 pos) 2)
 191           (nth 1 pos))))
 192
 193 (defun mouse-avoidance-banish-mouse ()
 194   ;; Put the mouse pointer in the upper-right corner of the current frame.
 195   (mouse-avoidance-set-mouse-position (mouse-avoidance-banish-destination)))
 196
 197 (defsubst mouse-avoidance-delta (cur delta dist var min max)
 198   ;; Decide how far to move in either dimension.
 199   ;; Args are the CURRENT location, the desired DELTA for
 200   ;; warp-conservation, the DISTANCE we like to move, the VARIABILITY
 201   ;; in distance allowed, and the MIN and MAX possible window positions.
 202   ;; Returns something as close to DELTA as possible within the constraints.
 203   (let ((L1 (max (- min cur) (+ (- dist) (- var))))
 204         (R1                  (+ (- dist)    var ))
 205         (L2                  (+    dist  (- var)))
 206         (R2 (min (- max cur) (+    dist     var))))
 207     (if (< R1 (- min cur)) (setq L1 nil R1 nil))
 208     (if (> L2 (- max cur)) (setq L2 nil R2 nil))
 209     (cond ((and L1 (< delta L1)) L1)
 210           ((and R1 (< delta R1)) delta)
 211           ((and R1 (< delta 0)) R1)
 212           ((and L2 (< delta L2)) L2)
 213           ((and R2 (< delta R2)) delta)
 214           (R2)
 215           ((or R1 L2))
 216           (t 0))))
 217
 218 (defun mouse-avoidance-nudge-mouse ()
 219   ;; Push the mouse a little way away, possibly animating the move.
 220   ;; For these modes, state keeps track of the total offset that we've
 221   ;; accumulated, and tries to keep it close to zero.
 222   (let* ((cur (mouse-position))
 223          (cur-frame (car cur))
 224          (cur-pos (cdr cur))
 225          (pos (window-edges))
 226          (wleft (pop pos))
 227          (wtop (pop pos))
 228          (wright (pop pos))
 229          (wbot (pop pos))
 230          (deltax (mouse-avoidance-delta
 231                   (car cur-pos) (- (random mouse-avoidance-nudge-var)
 232                                    (car mouse-avoidance-state))
 233                   mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
 234                   wleft (1- wright)))
 235          (deltay (mouse-avoidance-delta
 236                   (cdr cur-pos) (- (random mouse-avoidance-nudge-var)
 237                                    (cdr mouse-avoidance-state))
 238                   mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
 239                   wtop (1- wbot))))
 240     (setq mouse-avoidance-state
 241           (cons (+ (car mouse-avoidance-state) deltax)
 242                 (+ (cdr mouse-avoidance-state) deltay)))
 243     (if (or (eq mouse-avoidance-mode 'animate)
 244             (eq mouse-avoidance-mode 'proteus))
 245         (let ((i 0.0)
 246               (incr (max .1 (/ 1.0 mouse-avoidance-nudge-dist))))
 247           (setq mouse-avoidance-animating-pointer t)
 248           (while (<= i 1)
 249             (mouse-avoidance-set-mouse-position
 250              (cons (+ (car cur-pos) (round (* i deltax)))
 251                    (+ (cdr cur-pos) (round (* i deltay)))))
 252             (setq i (+ i incr))
 253             (if (eq mouse-avoidance-mode 'proteus)
 254                 (mouse-avoidance-set-pointer-shape
 255                  (mouse-avoidance-random-shape)))
 256             (sit-for mouse-avoidance-animation-delay))
 257           (setq mouse-avoidance-animating-pointer nil))
 258       (mouse-avoidance-set-mouse-position (cons (+ (car (cdr cur)) deltax)
 259                                                 (+ (cdr (cdr cur)) deltay))))))
 260
 261 (defun mouse-avoidance-random-shape ()
 262   "Return a random cursor shape.
 263 This assumes that any variable whose name begins with x-pointer- and
 264 has an integer value is a valid cursor shape.  You might want to
 265 redefine this function to suit your own tastes."
 266   (if (null mouse-avoidance-pointer-shapes)
 267       (progn
 268         (setq mouse-avoidance-pointer-shapes
 269               (mapcar (lambda (x) (symbol-value (intern x)))
 270                       (all-completions "x-pointer-" obarray
 271                                        (lambda (x)
 272                                           (and (boundp x)
 273                                                (integerp (symbol-value x)))))))
 274         (setq mouse-avoidance-n-pointer-shapes
 275               (length mouse-avoidance-pointer-shapes))))
 276   (nth (random mouse-avoidance-n-pointer-shapes)
 277        mouse-avoidance-pointer-shapes))
 278
 279 (defun mouse-avoidance-ignore-p ()
 280   (let ((mp (mouse-position)))
 281     (or (not (frame-pointer-visible-p)) ; The pointer is hidden
 282         executing-kbd-macro            ; don't check inside macro
 283         (null (cadr mp))               ; don't move unless in an Emacs frame
 284         (not (eq (car mp) (selected-frame)))
 285         ;; Don't do anything if last event was a mouse event.
 286         ;; FIXME: this code fails in the case where the mouse was moved
 287         ;; since the last key-press but without generating any event.
 288         (and (consp last-input-event)
 289              (symbolp (car last-input-event))
 290              (let ((modifiers (event-modifiers (car last-input-event))))
 291                (or (memq (car last-input-event)
 292                          '(mouse-movement scroll-bar-movement
 293                            select-window switch-frame))
 294                    (memq 'click modifiers)
 295                    (memq 'double modifiers)
 296                    (memq 'triple modifiers)
 297                    (memq 'drag modifiers)
 298                    (memq 'down modifiers)))))))
 299
 300 (defun mouse-avoidance-banish ()
 301   (if (not (mouse-avoidance-ignore-p))
 302       (mouse-avoidance-banish-mouse)))
 303
 304 (defun mouse-avoidance-exile ()
 305   ;; For exile mode, the state is nil when the mouse is in its normal
 306   ;; position, and set to the old mouse-position when the mouse is in exile.
 307   (if (not (mouse-avoidance-ignore-p))
 308       (let ((mp (mouse-position)))
 309         (cond ((and (not mouse-avoidance-state)
 310                     (mouse-avoidance-too-close-p mp))
 311                (setq mouse-avoidance-state mp)
 312                (mouse-avoidance-banish-mouse))
 313               ((and mouse-avoidance-state
 314                     (not (mouse-avoidance-too-close-p mouse-avoidance-state)))
 315                (if (and (eq (car mp) (selected-frame))
 316                         (equal (cdr mp) (mouse-avoidance-banish-destination)))
 317                    (mouse-avoidance-set-mouse-position
 318                     ;; move back only if user has not moved mouse
 319                     (cdr mouse-avoidance-state)))
 320                ;; but clear state anyway, to be ready for another move
 321                (setq mouse-avoidance-state nil))))))
 322
 323 (defun mouse-avoidance-fancy ()
 324   ;; Used for the "fancy" modes, ie jump et al.
 325   (if (and (not mouse-avoidance-animating-pointer)
 326            (not (mouse-avoidance-ignore-p))
 327            (mouse-avoidance-too-close-p (mouse-position)))
 328       (let ((old-pos (mouse-position)))
 329         (mouse-avoidance-nudge-mouse)
 330         (if (not (eq (selected-frame) (car old-pos)))
 331             ;; This should never happen.
 332             (apply 'set-mouse-position old-pos)))))
 333
 334 ;;;###autoload
 335 (defun mouse-avoidance-mode (&optional mode)
 336   "Set cursor avoidance mode to MODE.
 337 MODE should be one of the symbols `banish', `exile', `jump', `animate',
 338 `cat-and-mouse', `proteus', or `none'.
 339
 340 If MODE is nil, toggle mouse avoidance between `none' and `banish'
 341 modes.  Positive numbers and symbols other than the above are treated
 342 as equivalent to `banish'; negative numbers and `-' are equivalent to `none'.
 343
 344 Effects of the different modes:
 345  * banish: Move the mouse to the upper-right corner on any keypress.
 346  * exile: Move the mouse to the corner only if the cursor gets too close,
 347      and allow it to return once the cursor is out of the way.
 348  * jump: If the cursor gets too close to the mouse, displace the mouse
 349      a random distance & direction.
 350  * animate: As `jump', but shows steps along the way for illusion of motion.
 351  * cat-and-mouse: Same as `animate'.
 352  * proteus: As `animate', but changes the shape of the mouse pointer too.
 353
 354 Whenever the mouse is moved, the frame is also raised.
 355
 356 \(see `mouse-avoidance-threshold' for definition of \"too close\",
 357 and `mouse-avoidance-nudge-dist' and `mouse-avoidance-nudge-var' for
 358 definition of \"random distance\".)"
 359   (interactive
 360    (list (intern (completing-read
 361                   "Select cursor avoidance technique (SPACE for list): "
 362                   '(("banish") ("exile") ("jump") ("animate")
 363                     ("cat-and-mouse") ("proteus") ("none"))
 364                   nil t))))
 365   (if (eq mode 'cat-and-mouse)
 366       (setq mode 'animate))
 367   (if mouse-avoidance-timer
 368       (cancel-timer mouse-avoidance-timer))
 369   (setq mouse-avoidance-timer nil)
 370
 371   ;; Restore pointer shape if necessary
 372   (if (eq mouse-avoidance-mode 'proteus)
 373       (mouse-avoidance-set-pointer-shape mouse-avoidance-old-pointer-shape))
 374
 375   ;; Do additional setup depending on version of mode requested
 376   (cond ((eq mode 'none)
 377          (setq mouse-avoidance-mode nil))
 378         ((or (eq mode 'jump)
 379              (eq mode 'animate)
 380              (eq mode 'proteus))
 381          (setq mouse-avoidance-timer
 382                (run-with-idle-timer 0.1 t 'mouse-avoidance-fancy))
 383          (setq mouse-avoidance-mode mode
 384                mouse-avoidance-state (cons 0 0)
 385                mouse-avoidance-old-pointer-shape
 386                (and (boundp 'x-pointer-shape) x-pointer-shape)))
 387         ((eq mode 'exile)
 388          (setq mouse-avoidance-timer
 389                (run-with-idle-timer 0.1 t 'mouse-avoidance-exile))
 390          (setq mouse-avoidance-mode mode
 391                mouse-avoidance-state nil))
 392         ((or (eq mode 'banish)
 393              (eq mode t)
 394              (and (null mode) (null mouse-avoidance-mode))
 395              (and mode (> (prefix-numeric-value mode) 0)))
 396          (setq mouse-avoidance-timer
 397                (run-with-idle-timer 0.1 t 'mouse-avoidance-banish))
 398          (setq mouse-avoidance-mode 'banish))
 399         (t (setq mouse-avoidance-mode nil)))
 400   (force-mode-line-update))
 401
 402 ;; Most people who use avoid mode leave it on all the time, so it's not
 403 ;; very informative to announce it in the mode line.
 404 ;;(or (assq 'mouse-avoidance-mode minor-mode-alist)
 405 ;;    (setq minor-mode-alist (cons '(mouse-avoidance-mode " Avoid")
 406 ;;                               minor-mode-alist)))
 407
 408 ;; Needed for custom.
 409 (if mouse-avoidance-mode
 410     (mouse-avoidance-mode mouse-avoidance-mode))
 411
 412 ;; arch-tag: 64ad4ef8-a870-4183-8d96-3aa93b7a6800
 413 ;;; avoid.el ends here