lisp/view.el

   1 ;;; view.el --- peruse file or buffer without editing
   2
   3 ;; Copyright (C) 1985, 1989, 1994, 1995, 1997, 2000, 2001, 2002,
   4 ;;   2003, 2004, 2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; Author: K. Shane Hartman
   7 ;; Maintainer: Inge Frick <inge@nada.kth.se>
   8 ;; Keywords: files
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This package provides the `view' minor mode documented in the Emacs
  28 ;; user's manual.
  29 ;; View mode entry and exit is done through the functions view-mode-enter
  30 ;; and view-mode-exit.  Use these functions to enter or exit view-mode from
  31 ;; emacs lisp programs.
  32 ;; We use both view- and View- as prefix for symbols.  View- is used as
  33 ;; prefix for commands that have a key binding.  view- is used for commands
  34 ;; without key binding.  The purpose of this is to make it easier for a
  35 ;; user to use command name completion.
  36
  37 ;;; Suggested key bindings:
  38 ;;
  39 ;; (define-key ctl-x-4-map "v" 'view-file-other-window)  ; ^x4v
  40 ;; (define-key ctl-x-5-map "v" 'view-file-other-frame)  ; ^x5v
  41 ;;
  42 ;; You could also bind view-file, view-buffer, view-buffer-other-window and
  43 ;; view-buffer-other-frame to keys.
  44 \f
  45 ;;; Code:
  46
  47 (defgroup view nil
  48   "Peruse file or buffer without editing."
  49   :link '(function-link view-mode)
  50   :link '(custom-manual "(emacs)Misc File Ops")
  51   :group 'wp
  52   :group 'editing)
  53
  54 (defcustom view-highlight-face 'highlight
  55    "The face used for highlighting the match found by View mode search."
  56    :type 'face
  57    :group 'view)
  58
  59 ;; `view-mode-auto-exit' is replaced by the following option variable which
  60 ;; only says if scrolling past buffer end should leave view mode or not, it
  61 ;; doesn't say if leaving view mode should restore windows or not.  The latter
  62 ;; is now controlled by the presence of a value in `view-return-to-alist'.
  63 (defcustom view-scroll-auto-exit nil
  64   "Non-nil means scrolling past the end of buffer exits View mode.
  65 A value of nil means attempting to scroll past the end of the buffer,
  66 only rings the bell and gives a message on how to leave."
  67   :type 'boolean
  68   :group 'view)
  69
  70 (defcustom view-try-extend-at-buffer-end nil
  71  "Non-nil means try to load more of file when reaching end of buffer.
  72 This variable is mainly intended to be temporarily set to non-nil by
  73 the F command in view-mode, but you can set it to t if you want the action
  74 for all scroll commands in view mode."
  75   :type 'boolean
  76   :group 'view)
  77
  78 ;;;###autoload
  79 (defcustom view-remove-frame-by-deleting t
  80   "Determine how View mode removes a frame no longer needed.
  81 If nil, make an icon of the frame.  If non-nil, delete the frame."
  82   :type 'boolean
  83   :group 'view
  84   ;; Changed the default of this to t for Emacs 23.  Users consider
  85   ;; frame iconification annoying.
  86   :version "23.1")
  87
  88 (defcustom view-exits-all-viewing-windows nil
  89   "Non-nil means restore all windows used to view buffer.
  90 Commands that restore windows when finished viewing a buffer, apply to all
  91 windows that display the buffer and have restore information in
  92 `view-return-to-alist'.
  93 If `view-exits-all-viewing-windows' is nil, only the selected window is
  94 considered for restoring."
  95   :type 'boolean
  96   :group 'view)
  97
  98 (defcustom view-inhibit-help-message nil
  99   "Non-nil inhibits the help message shown upon entering View mode."
 100   :type 'boolean
 101   :group 'view
 102   :version "22.1")
 103
 104 ;;;###autoload
 105 (defvar view-mode nil
 106   "Non-nil if View mode is enabled.
 107 Don't change this variable directly, you must change it by one of the
 108 functions that enable or disable view mode.")
 109 ;;;###autoload
 110 (make-variable-buffer-local 'view-mode)
 111
 112 (defcustom view-mode-hook nil
 113   "Normal hook run when starting to view a buffer or file."
 114   :type 'hook
 115   :group 'view)
 116 \f
 117 (defvar view-old-buffer-read-only nil)
 118 (make-variable-buffer-local 'view-old-buffer-read-only)
 119
 120 (defvar view-old-Helper-return-blurb)
 121 (make-variable-buffer-local 'view-old-Helper-return-blurb)
 122
 123 ;; Just to avoid warnings.
 124 (defvar Helper-return-blurb)
 125
 126 (defvar view-page-size nil
 127   "Default number of lines to scroll by View page commands.
 128 If nil that means use the window size.")
 129 (make-variable-buffer-local 'view-page-size)
 130
 131 (defvar view-half-page-size nil
 132   "Default number of lines to scroll by View half page commands.
 133 If nil that means use half the window size.")
 134 (make-variable-buffer-local 'view-half-page-size)
 135
 136 (defvar view-last-regexp nil)
 137 (make-variable-buffer-local 'view-last-regexp) ; Global is better???
 138
 139 (defvar view-return-to-alist nil
 140   "What to do with used windows and where to go when finished viewing buffer.
 141 This is local in each buffer being viewed.
 142 It is added to by `view-mode-enter' when starting to view a buffer and
 143 subtracted from by `view-mode-exit' when finished viewing the buffer.
 144
 145 See RETURN-TO-ALIST argument of function `view-mode-exit' for the format of
 146 `view-return-to-alist'.")
 147 (make-variable-buffer-local 'view-return-to-alist)
 148 (put 'view-return-to-alist 'permanent-local t)
 149
 150 (defvar view-exit-action nil
 151   "If non-nil, a function with one argument (a buffer) called when finished viewing.
 152 Commands like \\[view-file] and \\[view-file-other-window] may
 153 set this to bury or kill the viewed buffer.
 154 Observe that the buffer viewed might not appear in any window at
 155 the time this function is called.")
 156 (make-variable-buffer-local 'view-exit-action)
 157
 158 (defvar view-no-disable-on-exit nil
 159   "If non-nil, View mode \"exit\" commands don't actually disable View mode.
 160 Instead, these commands just switch buffers or windows.
 161 This is set in certain buffers by specialized features such as help commands
 162 that use View mode automatically.")
 163
 164 (defvar view-overlay nil
 165   "Overlay used to display where a search operation found its match.
 166 This is local in each buffer, once it is used.")
 167 (make-variable-buffer-local 'view-overlay)
 168
 169 (unless (assq 'view-mode minor-mode-alist)
 170   (setq minor-mode-alist
 171         (cons (list 'view-mode
 172                     (propertize " View"
 173                                 'local-map mode-line-minor-mode-keymap
 174                                 'help-echo "mouse-3: minor mode menu"))
 175               minor-mode-alist)))
 176 \f
 177 ;; Define keymap inside defvar to make it easier to load changes.
 178 ;; Some redundant "less"-like key bindings below have been commented out.
 179 (defvar view-mode-map
 180   (let ((map (make-sparse-keymap)))
 181     (define-key map "C" 'View-kill-and-leave)
 182     (define-key map "c" 'View-leave)
 183     (define-key map "Q" 'View-quit-all)
 184     (define-key map "E" 'View-exit-and-edit)
 185     ;; (define-key map "v" 'View-exit)
 186     (define-key map "e" 'View-exit)
 187     (define-key map "q" 'View-quit)
 188     ;; (define-key map "N" 'View-search-last-regexp-backward)
 189     (define-key map "p" 'View-search-last-regexp-backward)
 190     (define-key map "n" 'View-search-last-regexp-forward)
 191     ;; (define-key map "?" 'View-search-regexp-backward) ; Less does this.
 192     (define-key map "\\" 'View-search-regexp-backward)
 193     (define-key map "/" 'View-search-regexp-forward)
 194     (define-key map "r" 'isearch-backward)
 195     (define-key map "s" 'isearch-forward)
 196     (define-key map "m" 'point-to-register)
 197     (define-key map "'" 'register-to-point)
 198     (define-key map "x" 'exchange-point-and-mark)
 199     (define-key map "@" 'View-back-to-mark)
 200     (define-key map "." 'set-mark-command)
 201     (define-key map "%" 'View-goto-percent)
 202     ;; (define-key map "G" 'View-goto-line-last)
 203     (define-key map "g" 'View-goto-line)
 204     (define-key map "=" 'what-line)
 205     (define-key map "F" 'View-revert-buffer-scroll-page-forward)
 206     ;; (define-key map "k" 'View-scroll-line-backward)
 207     (define-key map "y" 'View-scroll-line-backward)
 208     ;; (define-key map "j" 'View-scroll-line-forward)
 209     (define-key map "\n" 'View-scroll-line-forward)
 210     (define-key map "\r" 'View-scroll-line-forward)
 211     (define-key map "u" 'View-scroll-half-page-backward)
 212     (define-key map "d" 'View-scroll-half-page-forward)
 213     (define-key map "z" 'View-scroll-page-forward-set-page-size)
 214     (define-key map "w" 'View-scroll-page-backward-set-page-size)
 215     ;; (define-key map "b" 'View-scroll-page-backward)
 216     (define-key map "\C-?" 'View-scroll-page-backward)
 217     ;; (define-key map "f" 'View-scroll-page-forward)
 218     (define-key map " " 'View-scroll-page-forward)
 219     (define-key map "o" 'View-scroll-to-buffer-end)
 220     (define-key map ">" 'end-of-buffer)
 221     (define-key map "<" 'beginning-of-buffer)
 222     (define-key map "-" 'negative-argument)
 223     (define-key map "9" 'digit-argument)
 224     (define-key map "8" 'digit-argument)
 225     (define-key map "7" 'digit-argument)
 226     (define-key map "6" 'digit-argument)
 227     (define-key map "5" 'digit-argument)
 228     (define-key map "4" 'digit-argument)
 229     (define-key map "3" 'digit-argument)
 230     (define-key map "2" 'digit-argument)
 231     (define-key map "1" 'digit-argument)
 232     (define-key map "0" 'digit-argument)
 233     (define-key map "H" 'describe-mode)
 234     (define-key map "?" 'describe-mode) ; Maybe do as less instead? See above.
 235     (define-key map "h" 'describe-mode)
 236     map))
 237
 238 (or (assq 'view-mode minor-mode-map-alist)
 239     (setq minor-mode-map-alist
 240           (cons (cons 'view-mode view-mode-map) minor-mode-map-alist)))
 241 \f
 242 ;;; Commands that enter or exit view mode.
 243
 244 ;; This is used when view mode is exited, to make sure we don't try to
 245 ;; kill a buffer modified by the user.  A buffer in view mode can
 246 ;; become modified if the user types C-x C-q, edits the buffer, then
 247 ;; types C-x C-q again to return to view mode.
 248 ;;;###autoload
 249 (defun kill-buffer-if-not-modified (buf)
 250   "Like `kill-buffer', but does nothing if the buffer is modified."
 251   (let ((buf (get-buffer buf)))
 252     (and buf (not (buffer-modified-p buf))
 253          (kill-buffer buf))))
 254
 255 ;;;###autoload
 256 (defun view-file (file)
 257   "View FILE in View mode, returning to previous buffer when done.
 258 Emacs commands editing the buffer contents are not available; instead, a
 259 special set of commands (mostly letters and punctuation) are defined for
 260 moving around in the buffer.
 261 Space scrolls forward, Delete scrolls backward.
 262 For a list of all View commands, type H or h while viewing.
 263
 264 This command runs the normal hook `view-mode-hook'."
 265   (interactive "fView file: ")
 266   (unless (file-exists-p file) (error "%s does not exist" file))
 267   (let ((had-a-buf (get-file-buffer file))
 268         (buffer (find-file-noselect file)))
 269     (if (eq (with-current-buffer buffer
 270               (get major-mode 'mode-class))
 271             'special)
 272         (progn
 273           (switch-to-buffer buffer)
 274           (message "Not using View mode because the major mode is special"))
 275       (view-buffer buffer (and (not had-a-buf) 'kill-buffer-if-not-modified)))))
 276
 277 ;;;###autoload
 278 (defun view-file-other-window (file)
 279   "View FILE in View mode in another window.
 280 When done, return that window to its previous buffer, and kill the
 281 buffer visiting FILE if unmodified and if it wasn't visited before.
 282
 283 Emacs commands editing the buffer contents are not available; instead,
 284 a special set of commands (mostly letters and punctuation)
 285 are defined for moving around in the buffer.
 286 Space scrolls forward, Delete scrolls backward.
 287 For a list of all View commands, type H or h while viewing.
 288
 289 This command runs the normal hook `view-mode-hook'."
 290   (interactive "fIn other window view file: ")
 291   (unless (file-exists-p file) (error "%s does not exist" file))
 292   (let ((had-a-buf (get-file-buffer file))
 293         (buf-to-view (find-file-noselect file)))
 294     (view-buffer-other-window buf-to-view nil
 295                               (and (not had-a-buf)
 296                                    'kill-buffer-if-not-modified))))
 297
 298 ;;;###autoload
 299 (defun view-file-other-frame (file)
 300   "View FILE in View mode in another frame.
 301 When done, kill the buffer visiting FILE if unmodified and if it wasn't
 302 visited before; also, maybe delete other frame and/or return to previous
 303 buffer.
 304
 305 Emacs commands editing the buffer contents are not available; instead,
 306 a special set of commands (mostly letters and punctuation)
 307 are defined for moving around in the buffer.
 308 Space scrolls forward, Delete scrolls backward.
 309 For a list of all View commands, type H or h while viewing.
 310
 311 This command runs the normal hook `view-mode-hook'."
 312   (interactive "fIn other frame view file: ")
 313   (unless (file-exists-p file) (error "%s does not exist" file))
 314   (let ((had-a-buf (get-file-buffer file))
 315         (buf-to-view (find-file-noselect file)))
 316     (view-buffer-other-frame buf-to-view nil
 317                              (and (not had-a-buf)
 318                                   'kill-buffer-if-not-modified))))
 319
 320
 321 ;;;###autoload
 322 (defun view-buffer (buffer &optional exit-action)
 323   "View BUFFER in View mode, returning to previous buffer when done.
 324 Emacs commands editing the buffer contents are not available; instead, a
 325 special set of commands (mostly letters and punctuation) are defined for
 326 moving around in the buffer.
 327 Space scrolls forward, Delete scrolls backward.
 328 For a list of all View commands, type H or h while viewing.
 329
 330 This command runs the normal hook `view-mode-hook'.
 331
 332 Optional argument EXIT-ACTION is either nil or a function with buffer as
 333 argument.  This function is called when finished viewing buffer.  Use
 334 this argument instead of explicitly setting `view-exit-action'.
 335
 336 Do not set EXIT-ACTION to `kill-buffer' when BUFFER visits a
 337 file: Users may suspend viewing in order to modify the buffer.
 338 Exiting View mode will then discard the user's edits.  Setting
 339 EXIT-ACTION to `kill-buffer-if-not-modified' avoids this."
 340   (interactive "bView buffer: ")
 341   (let ((undo-window (list (window-buffer) (window-start) (window-point))))
 342     (switch-to-buffer buffer)
 343     (view-mode-enter (cons (selected-window) (cons nil undo-window))
 344                      exit-action)))
 345
 346 ;;;###autoload
 347 (defun view-buffer-other-window (buffer &optional not-return exit-action)
 348   "View BUFFER in View mode in another window.
 349 Return to previous buffer when done, unless optional NOT-RETURN is
 350 non-nil.  Emacs commands editing the buffer contents are not available;
 351 instead, a special set of commands (mostly letters and punctuation) are
 352 defined for moving around in the buffer.
 353 Space scrolls forward, Delete scrolls backward.
 354 For a list of all View commands, type H or h while viewing.
 355
 356 This command runs the normal hook `view-mode-hook'.
 357
 358 Optional argument EXIT-ACTION is either nil or a function with buffer as
 359 argument.  This function is called when finished viewing buffer.  Use
 360 this argument instead of explicitly setting `view-exit-action'."
 361   (interactive "bIn other window view buffer:\nP")
 362   (let* ((win                           ; This window will be selected by
 363           (get-lru-window))             ; switch-to-buffer-other-window below.
 364          (return-to
 365           (and (not not-return)
 366                (cons (selected-window)
 367                      (if (eq win (selected-window))
 368                          t                      ; Has to make new window.
 369                        (list
 370                         (window-buffer win)     ; Other windows old buffer.
 371                         (window-start win)
 372                         (window-point win)))))))
 373     (switch-to-buffer-other-window buffer)
 374     (view-mode-enter (and return-to (cons (selected-window) return-to))
 375                      exit-action)))
 376
 377 ;;;###autoload
 378 (defun view-buffer-other-frame (buffer &optional not-return exit-action)
 379   "View BUFFER in View mode in another frame.
 380 Return to previous buffer when done, unless optional NOT-RETURN is
 381 non-nil.  Emacs commands editing the buffer contents are not available;
 382 instead, a special set of commands (mostly letters and punctuation) are
 383 defined for moving around in the buffer.
 384 Space scrolls forward, Delete scrolls backward.
 385 For a list of all View commands, type H or h while viewing.
 386
 387 This command runs the normal hook `view-mode-hook'.
 388
 389 Optional argument EXIT-ACTION is either nil or a function with buffer as
 390 argument.  This function is called when finished viewing buffer.  Use
 391 this argument instead of explicitly setting `view-exit-action'."
 392   (interactive "bView buffer in other frame: \nP")
 393   (let ((return-to
 394          (and (not not-return) (cons (selected-window) t)))) ; Old window.
 395     (switch-to-buffer-other-frame buffer)
 396     (view-mode-enter (and return-to (cons (selected-window) return-to))
 397                      exit-action)))
 398 \f
 399 ;;;###autoload
 400 (defun view-mode (&optional arg)
 401   ;; In the following documentation string we have to use some explicit key
 402   ;; bindings instead of using the \\[] construction.  The reason for this
 403   ;; is that most commands have more than one key binding.
 404   "Toggle View mode, a minor mode for viewing text but not editing it.
 405 With prefix argument ARG, turn View mode on if ARG is positive, otherwise
 406 turn it off.
 407
 408 Emacs commands that do not change the buffer contents are available as usual.
 409 Kill commands insert text in kill buffers but do not delete.  Other commands
 410 \(among them most letters and punctuation) beep and tell that the buffer is
 411 read-only.
 412 \\<view-mode-map>
 413 The following additional commands are provided.  Most commands take prefix
 414 arguments.  Page commands default to \"page size\" lines which is almost a whole
 415 window full, or number of lines set by \\[View-scroll-page-forward-set-page-size] or \\[View-scroll-page-backward-set-page-size].  Half page commands default to
 416 and set \"half page size\" lines which initially is half a window full.  Search
 417 commands default to a repeat count of one.
 418
 419 H, h, ?  This message.
 420 Digits  provide prefix arguments.
 421 \\[negative-argument]   negative prefix argument.
 422 \\[beginning-of-buffer] move to the beginning of buffer.
 423 >       move to the end of buffer.
 424 \\[View-scroll-to-buffer-end]   scroll so that buffer end is at last line of window.
 425 SPC     scroll forward \"page size\" lines.
 426           With prefix scroll forward prefix lines.
 427 DEL     scroll backward \"page size\" lines.
 428           With prefix scroll backward prefix lines.
 429 \\[View-scroll-page-forward-set-page-size]      like  \\[View-scroll-page-forward]  but with prefix sets \"page size\" to prefix.
 430 \\[View-scroll-page-backward-set-page-size]     like  \\[View-scroll-page-backward]  but with prefix sets \"page size\" to prefix.
 431 \\[View-scroll-half-page-forward]       scroll forward \"half page size\" lines.  With prefix, sets
 432           \"half page size\" to prefix lines and scrolls forward that much.
 433 \\[View-scroll-half-page-backward]      scroll backward \"half page size\" lines.  With prefix, sets
 434           \"half page size\" to prefix lines and scrolls backward that much.
 435 RET, LFD  scroll forward one line.  With prefix scroll forward prefix line(s).
 436 y       scroll backward one line.  With prefix scroll backward prefix line(s).
 437 \\[View-revert-buffer-scroll-page-forward]      revert-buffer if necessary and scroll forward.
 438           Use this to view a changing file.
 439 \\[what-line]   prints the current line number.
 440 \\[View-goto-percent]   goes prefix argument (default 100) percent into buffer.
 441 \\[View-goto-line]      goes to line given by prefix argument (default first line).
 442 .       set the mark.
 443 x       exchanges point and mark.
 444 \\[View-back-to-mark]   return to mark and pops mark ring.
 445           Mark ring is pushed at start of every successful search and when
 446           jump to line occurs.  The mark is set on jump to buffer start or end.
 447 \\[point-to-register]   save current position in character register.
 448 '       go to position saved in character register.
 449 s       do forward incremental search.
 450 r       do reverse incremental search.
 451 \\[View-search-regexp-forward]  searches forward for regular expression, starting after current page.
 452           ! and @ have a special meaning at the beginning of the regexp.
 453           ! means search for a line with no match for regexp.  @ means start
 454           search at beginning (end for backward search) of buffer.
 455 \\      searches backward for regular expression, starting before current page.
 456 \\[View-search-last-regexp-forward]     searches forward for last regular expression.
 457 p       searches backward for last regular expression.
 458 \\[View-quit]   quit View mode, restoring this window and buffer to previous state.
 459           \\[View-quit] is the normal way to leave view mode.
 460 \\[View-exit]   exit View mode but stay in current buffer.  Use this if you started
 461           viewing a buffer (file) and find out you want to edit it.
 462           This command restores the previous read-only status of the buffer.
 463 \\[View-exit-and-edit]  exit View mode, and make the current buffer editable
 464           even if it was not editable before entry to View mode.
 465 \\[View-quit-all]       quit View mode, restoring all windows to previous state.
 466 \\[View-leave]  quit View mode and maybe switch buffers, but don't kill this buffer.
 467 \\[View-kill-and-leave] quit View mode, kill current buffer and go back to other buffer.
 468
 469 The effect of \\[View-leave], \\[View-quit] and \\[View-kill-and-leave] depends on how view-mode was entered.  If it was
 470 entered by view-file, view-file-other-window, view-file-other-frame, or
 471 \\[dired-view-file] \(\\[view-file], \\[view-file-other-window],
 472 \\[view-file-other-frame], or the Dired mode v command),
 473 then \\[View-quit] will try to kill the current buffer.
 474 If view-mode was entered from another buffer, by \\[view-buffer],
 475 \\[view-buffer-other-window], \\[view-buffer-other frame], \\[view-file],
 476 \\[view-file-other-window], or \\[view-file-other-frame],
 477 then \\[View-leave], \\[View-quit] and \\[View-kill-and-leave] will return to that buffer.
 478
 479 Entry to view-mode runs the normal hook `view-mode-hook'."
 480   (interactive "P")
 481   (unless (and arg                      ; Do nothing if already OK.
 482                (if (> (prefix-numeric-value arg) 0) view-mode (not view-mode)))
 483     (if view-mode (view-mode-disable)
 484       (view-mode-enable))))
 485 \f
 486 (defun view-mode-enable ()
 487   "Turn on View mode."
 488   ;; Always leave view mode before changing major mode.
 489   ;; This is to guarantee that the buffer-read-only variable is restored.
 490   (add-hook 'change-major-mode-hook 'view-mode-disable nil t)
 491   (setq view-mode t
 492         view-page-size nil
 493         view-half-page-size nil
 494         view-old-buffer-read-only buffer-read-only
 495         buffer-read-only t
 496         view-old-Helper-return-blurb (and (boundp 'Helper-return-blurb)
 497                                           Helper-return-blurb)
 498         Helper-return-blurb
 499         (format "continue viewing %s"
 500                 (if (buffer-file-name)
 501                     (file-name-nondirectory (buffer-file-name))
 502                   (buffer-name))))
 503   (force-mode-line-update)
 504   (run-hooks 'view-mode-hook))
 505
 506 (defun view-mode-disable ()
 507   "Turn off View mode."
 508   (remove-hook 'change-major-mode-hook 'view-mode-disable t)
 509   (and view-overlay (delete-overlay view-overlay))
 510   (force-mode-line-update)
 511   ;; Calling toggle-read-only while View mode is enabled
 512   ;; sets view-read-only to t as a buffer-local variable
 513   ;; after exiting View mode.  That arranges that the next toggle-read-only
 514   ;; will reenable View mode.
 515   ;; Cancelling View mode in any other way should cancel that, too,
 516   ;; so that View mode stays off if toggle-read-only is called.
 517   (if (local-variable-p 'view-read-only)
 518       (kill-local-variable 'view-read-only))
 519   (setq view-mode nil
 520         Helper-return-blurb view-old-Helper-return-blurb)
 521   (if buffer-read-only
 522       (setq buffer-read-only view-old-buffer-read-only)))
 523
 524 ;;;###autoload
 525 (defun view-return-to-alist-update (buffer &optional item)
 526   "Update `view-return-to-alist' of buffer BUFFER.
 527 Remove from `view-return-to-alist' all entries referencing dead
 528 windows.  Optional argument ITEM non-nil means add ITEM to
 529 `view-return-to-alist' after purging.  For a decsription of items
 530 that can be added see the RETURN-TO-ALIST argument of the
 531 function `view-mode-exit'.  If `view-return-to-alist' contains an
 532 entry for the selected window, purge that entry from
 533 `view-return-to-alist' before adding ITEM."
 534   (with-current-buffer buffer
 535     (when view-return-to-alist
 536       (let* ((list view-return-to-alist)
 537              entry entry-window last)
 538         (while list
 539           (setq entry (car list))
 540           (setq entry-window (car entry))
 541           (if (and (windowp entry-window)
 542                    (or (and item (eq entry-window (selected-window)))
 543                        (not (window-live-p entry-window))))
 544               ;; Remove that entry.
 545               (if last
 546                   (setcdr last (cdr list))
 547                 (setq view-return-to-alist
 548                       (cdr view-return-to-alist)))
 549             ;; Leave entry alone.
 550             (setq last entry))
 551           (setq list (cdr list)))))
 552     ;; Add ITEM.
 553     (when item
 554       (setq view-return-to-alist
 555             (cons item view-return-to-alist)))))
 556
 557 ;;;###autoload
 558 (defun view-mode-enter (&optional return-to exit-action)
 559   "Enter View mode and set up exit from view mode depending on optional arguments.
 560 RETURN-TO non-nil means add RETURN-TO as an element to the buffer
 561 local alist `view-return-to-alist'.  Save EXIT-ACTION in buffer
 562 local variable `view-exit-action'.  It should be either nil or a
 563 function that takes a buffer as argument.  This function will be
 564 called by `view-mode-exit'.
 565
 566 RETURN-TO is either nil, meaning do nothing when exiting view
 567 mode, or must have the format (WINDOW OLD-WINDOW . OLD-BUF-INFO).
 568 WINDOW is the window used for viewing.  OLD-WINDOW is nil or the
 569 window to select after viewing.  OLD-BUF-INFO tells what to do
 570 with WINDOW when exiting.  It is one of:
 571 1) nil            Do nothing.
 572 2) t              Delete WINDOW or, if it is the only window and
 573                   `view-remove-frame-by-deleting' is non-nil, its
 574                   frame.
 575 3) (OLD-BUFF START POINT)  Display buffer OLD-BUFF with displayed text
 576                   starting at START and point at POINT in WINDOW.
 577 4) quit-window    Do `quit-window' in WINDOW.
 578 5) keep-frame     Like case 2) but do not delete the frame.
 579
 580 For a list of all View commands, type H or h while viewing.
 581
 582 This function runs the normal hook `view-mode-hook'."
 583   (when return-to
 584     (let ((entry (assq (car return-to) view-return-to-alist)))
 585       (if entry
 586           (setcdr entry (cdr return-to))
 587         (setq view-return-to-alist (cons return-to view-return-to-alist)))))
 588   (when exit-action
 589     (setq view-exit-action exit-action))
 590
 591   (unless view-mode
 592     (view-mode-enable)
 593     (force-mode-line-update)
 594     (unless view-inhibit-help-message
 595       (message "%s"
 596                (substitute-command-keys "\
 597 View mode: type \\[help-command] for help, \\[describe-mode] for commands, \\[View-quit] to quit.")))))
 598 \f
 599 (defun view-mode-exit (&optional return-to-alist exit-action all-win)
 600   "Exit View mode in various ways, depending on optional arguments.
 601 RETURN-TO-ALIST, EXIT-ACTION and ALL-WIN determine what to do
 602 after exit.  EXIT-ACTION is nil or a function that is called with
 603 current buffer as argument.
 604
 605 RETURN-TO-ALIST is an alist that, for some of the windows
 606 displaying the current buffer, maintains information on what to
 607 do when exiting those windows.  If ALL-WIN is non-nil or the
 608 variable `view-exits-all-viewing-windows' is non-nil,
 609 view-mode-exit attempts to restore all windows showing the
 610 current buffer to their old state.  Otherwise, only the selected
 611 window is affected (provided it is on RETURN-TO-ALIST).
 612
 613 Elements of RETURN-TO-ALIST must have the format
 614   (WINDOW OLD-WINDOW . OLD-BUF-INFO) where
 615
 616 WINDOW is a window displaying the current buffer and OLD-WINDOW
 617 is either nil or a window to select after viewing.  OLD-BUF-INFO
 618 provides information on what to do with WINDOW and may be one of:
 619 1) nil            Do nothing.
 620 2) t              Delete WINDOW and, if it is the only window and
 621                   `view-remove-frame-by-deleting' is non-nil, its
 622                   frame.
 623 3) (OLD-BUF START POINT)  Display buffer OLD-BUF with displayed text
 624                   starting at START and point at POINT in WINDOW.
 625 4) quit-window    Do `quit-window' in WINDOW.
 626 5) keep-frame     Like case 2) but do not delete the frame.
 627
 628 If one of the WINDOW in RETURN-TO-ALIST is the selected window
 629 and the corresponding OLD-WINDOW is a live window, then select
 630 OLD-WINDOW."
 631   (when view-mode                   ; Only do something if in view mode.
 632     (setq all-win
 633           (and return-to-alist
 634                (or all-win view-exits-all-viewing-windows)))
 635     (let* ((buffer (current-buffer))
 636            window notlost
 637            (sel-old (assq (selected-window) return-to-alist))
 638            (alist (cond
 639                    (all-win                ; Try to restore all windows.
 640                     (append return-to-alist nil)) ; Copy.
 641                    (sel-old                     ; Only selected window.
 642                     (list sel-old))))
 643            (old-window (if sel-old (car (cdr sel-old)))))
 644       (if all-win                        ; Follow chains of old-windows.
 645           (let ((c (length alist)) a)
 646             (while (and (> c 0)   ; Safety if mutually refering windows.
 647                         (or (not (window-live-p old-window))
 648                             (eq buffer (window-buffer old-window)))
 649                         (setq a (assq old-window alist)))
 650               (setq c (1- c))
 651               (setq old-window (car (cdr a))))
 652             (if (or (zerop c) (not (window-live-p old-window)))
 653                 (setq old-window (selected-window)))))
 654       (unless view-no-disable-on-exit
 655         (view-mode-disable))
 656       (while alist                          ; Restore windows with info.
 657         (setq notlost nil)
 658         (when (and (window-live-p (setq window (car (car alist))))
 659                    (eq buffer (window-buffer window)))
 660           (let ((frame (window-frame window))
 661                 (old-buf-info (cdr (cdr (car alist)))))
 662             (if all-win (select-window window))
 663             (cond
 664              ((and (consp old-buf-info)         ; Case 3.
 665                    (buffer-live-p (car old-buf-info)))
 666               (set-window-buffer window (car old-buf-info)) ; old-buf
 667               (set-window-start window (car (cdr old-buf-info)))
 668               (set-window-point window (car (cdr (cdr old-buf-info)))))
 669              ((eq old-buf-info 'quit-window)
 670               (quit-window))                    ; Case 4.
 671              (old-buf-info                      ; Case 2 or 5.
 672               (cond
 673                ((not (one-window-p t))          ; Not only window.
 674                 (delete-window))
 675                ((eq old-buf-info 'keep-frame)   ; Case 5.
 676                 (bury-buffer))
 677                ((not (eq frame (next-frame)))  ; Case 2 and only window.
 678                 ;; Not the only frame, so can safely be removed.
 679                 (if view-remove-frame-by-deleting
 680                     (delete-frame frame)
 681                   (setq notlost t)         ; Keep the window. See below.
 682                   (iconify-frame frame))))))))
 683         ;; If a frame is removed by iconifying it, the window is not
 684         ;; really lost.  In this case we keep the entry in
 685         ;; `view-return-to-alist' so that if the user deiconifies the
 686         ;; frame and then hits q, the frame is iconified again.
 687         (unless notlost
 688           (with-current-buffer buffer
 689             (setq view-return-to-alist
 690                   (delete (car alist) view-return-to-alist))))
 691         (setq alist (cdr alist)))
 692       (when (window-live-p old-window)
 693         ;; old-window is still alive => select it.
 694         (select-window old-window))
 695       (when exit-action
 696         ;; Don't do that: If the user wants to quit the *Help* buffer a
 697         ;; second time it won't have any effect.
 698         ;;(setq view-exit-action nil)
 699         (funcall exit-action buffer))
 700       (force-mode-line-update))))
 701 \f
 702 (defun View-exit ()
 703   "Exit View mode but stay in current buffer."
 704   (interactive)
 705   (view-mode-exit))
 706
 707 ;;;###autoload
 708 (defun View-exit-and-edit ()
 709   "Exit View mode and make the current buffer editable."
 710   (interactive)
 711   (let ((view-old-buffer-read-only nil)
 712         (view-no-disable-on-exit nil))
 713     (view-mode-exit)))
 714
 715 (defun View-leave ()
 716   "Quit View mode and maybe switch buffers, but don't kill this buffer."
 717   (interactive)
 718   (view-mode-exit view-return-to-alist))
 719
 720 (defun View-quit ()
 721   "Quit View mode, trying to restore window and buffer to previous state.
 722 Maybe kill this buffer.  Try to restore selected window to previous state
 723 and go to previous buffer or window."
 724   (interactive)
 725   (view-mode-exit view-return-to-alist view-exit-action))
 726
 727 (defun View-quit-all ()
 728   "Quit View mode, trying to restore windows and buffers to previous state.
 729 Maybe kill current buffer.  Try to restore all windows viewing buffer to
 730 previous state and go to previous buffer or window."
 731   (interactive)
 732   (view-mode-exit view-return-to-alist view-exit-action t))
 733
 734 (defun View-kill-and-leave ()
 735   "Quit View mode, kill current buffer and return to previous buffer."
 736   (interactive)
 737   (view-mode-exit view-return-to-alist (or view-exit-action 'kill-buffer) t))
 738 \f
 739
 740 ;;; Some help routines.
 741
 742 (defun view-window-size ()
 743   ;; Return the height of the current window, excluding the mode line.
 744   ;; Using `window-line-height' accounts for variable-height fonts.
 745   (let ((h (window-line-height -1)))
 746     (if h
 747         (1+ (nth 1 h))
 748       ;; This should not happen, but if `window-line-height' returns
 749       ;; nil, fall back on `window-height'.
 750       (1- (window-height)))))
 751
 752 ;; (defun view-last-command (&optional who what)
 753 ;;  (setq view-last-command-entry this-command)
 754 ;;  (setq view-last-command who)
 755 ;;  (setq view-last-command-argument what))
 756
 757 ;; (defun View-repeat-last-command ()
 758 ;;  "Repeat last command issued in View mode."
 759 ;;  (interactive)
 760 ;;  (if (and view-last-command
 761 ;;         (eq view-last-command-entry last-command))
 762 ;;      (funcall view-last-command view-last-command-argument))
 763 ;;  (setq this-command view-last-command-entry))
 764
 765 (defun view-recenter ()
 766   ;; Recenter point in window and redisplay normally.
 767   (recenter '(1)))
 768
 769 (defun view-page-size-default (lines)
 770   ;; If LINES is nil, 0, or larger than `view-window-size', return nil.
 771   ;; Otherwise, return LINES.
 772   (and lines
 773        (not (zerop (setq lines (prefix-numeric-value lines))))
 774        (<= (abs lines)
 775            (abs (- (view-window-size) next-screen-context-lines)))
 776        (abs lines)))
 777
 778 (defun view-set-half-page-size-default (lines)
 779   ;; Get and maybe set half page size.
 780   (if (not lines) (or view-half-page-size
 781                       (/ (view-window-size) 2))
 782     (setq view-half-page-size
 783           (if (zerop (setq lines (prefix-numeric-value lines)))
 784               (/ (view-window-size) 2)
 785             (view-page-size-default lines)))))
 786
 787
 788 ;;; Commands for moving around in the buffer.
 789
 790 (defun View-goto-percent (&optional percent)
 791   "Move to end (or prefix PERCENT) of buffer in View mode.
 792 Display is centered at point.
 793 Also set the mark at the position where point was."
 794   (interactive "P")
 795   (push-mark)
 796   (goto-char
 797    (if percent
 798        (+ (point-min)
 799           (floor (* (- (point-max) (point-min)) 0.01
 800                     (max 0 (min 100 (prefix-numeric-value percent))))))
 801      (point-max)))
 802   (view-recenter))
 803
 804 ;; (defun View-goto-line-last (&optional line)
 805 ;; "Move to last (or prefix LINE) line in View mode.
 806 ;; Display is centered at LINE.
 807 ;; Sets mark at starting position and pushes mark ring."
 808 ;;  (interactive "P")
 809 ;;  (push-mark)
 810 ;;  (if line (goto-line (prefix-numeric-value line))
 811 ;;    (goto-char (point-max))
 812 ;;    (beginning-of-line))
 813 ;;  (view-recenter))
 814
 815 (defun View-goto-line (&optional line)
 816   "Move to first (or prefix LINE) line in View mode.
 817 Display is centered at LINE.
 818 Also set the mark at the position where point was."
 819   (interactive "p")
 820   (push-mark)
 821   (goto-line line)
 822   (view-recenter))
 823
 824 (defun View-back-to-mark (&optional ignore)
 825   "Return to last mark set in View mode, else beginning of file.
 826 Display that line at the center of the window.
 827 This command pops the mark ring, so that successive
 828 invocations return to earlier marks."
 829   (interactive)
 830   (goto-char (or (mark t) (point-min)))
 831   (pop-mark)
 832   (view-recenter))
 833 \f
 834 (defun view-scroll-lines (lines backward default maxdefault)
 835   ;; This function does the job for all the scrolling commands.
 836   ;; Scroll forward LINES lines.  If BACKWARD is non-nil, scroll backwards.
 837   ;; If LINES is negative scroll in the other direction.
 838   ;; If LINES is 0 or nil, scroll DEFAULT lines (if DEFAULT is nil, scroll
 839   ;; by one page). If MAXDEFAULT is non-nil, scroll no more than a window.
 840   (if (or (null lines) (zerop (setq lines (prefix-numeric-value lines))))
 841       (setq lines default))
 842   (when (and lines (< lines 0))
 843     (setq backward (not backward) lines (- lines)))
 844   (when (and maxdefault lines (> lines (view-window-size)))
 845     (setq lines nil))
 846   (cond (backward (scroll-down lines))
 847         ((view-really-at-end)
 848          (if view-scroll-auto-exit
 849              (View-quit)
 850            (ding)
 851            (view-end-message)))
 852         (t (scroll-up lines)
 853            (if (view-really-at-end) (view-end-message)))))
 854
 855 (defun view-really-at-end ()
 856   ;; Return true if buffer end visible.  Maybe revert buffer and test.
 857   (and (pos-visible-in-window-p (point-max))
 858        (let ((buf (current-buffer))
 859              (bufname (buffer-name))
 860              (file (buffer-file-name)))
 861          (or (not view-try-extend-at-buffer-end)
 862              (null file)
 863              (verify-visited-file-modtime buf)
 864              (not (file-exists-p file))
 865              (when (buffer-modified-p buf)
 866                (setq file (file-name-nondirectory file))
 867                (not (yes-or-no-p
 868                      (format
 869                       "File %s changed on disk.  Discard your edits%s? "
 870                       file
 871                       (if (string= bufname file) ""
 872                         (concat " in " bufname))))))
 873              (progn
 874                (revert-buffer t t t)
 875                (pos-visible-in-window-p (point-max)))))))
 876
 877 (defun view-end-message ()
 878   ;; Tell that we are at end of buffer.
 879   (goto-char (point-max))
 880   (if view-return-to-alist
 881       (message "End of buffer.  Type %s to quit viewing."
 882                (substitute-command-keys
 883                 (if view-scroll-auto-exit "\\[View-scroll-page-forward]"
 884                   "\\[View-quit]")))
 885     (message "End of buffer")))
 886 \f
 887 (defun View-scroll-to-buffer-end ()
 888   "Scroll backward or forward so that buffer end is at last line of window."
 889   (interactive)
 890   (let ((p (if (pos-visible-in-window-p (point-max)) (point))))
 891     (goto-char (point-max))
 892     (recenter -1)
 893     (and p (goto-char p))))
 894
 895 (defun View-scroll-page-forward (&optional lines)
 896   "Scroll \"page size\" or prefix LINES lines forward in View mode.
 897 Exit if end of text is visible and `view-scroll-auto-exit' is non-nil.
 898 \"page size\" is whole window full, or number of lines set by
 899 \\[View-scroll-page-forward-set-page-size] or
 900 \\[View-scroll-page-backward-set-page-size].
 901 If LINES is more than a window-full, only the last window-full is shown."
 902   (interactive "P")
 903   (view-scroll-lines lines nil (view-page-size-default view-page-size) nil))
 904
 905 (defun View-scroll-page-backward (&optional lines)
 906   "Scroll \"page size\" or prefix LINES lines backward in View mode.
 907 See also `View-scroll-page-forward'."
 908   (interactive "P")
 909   (view-scroll-lines lines t (view-page-size-default view-page-size) nil))
 910
 911 (defun View-scroll-page-forward-set-page-size (&optional lines)
 912   "Scroll forward LINES lines in View mode, setting the \"page size\".
 913 This is the number of lines which \\[View-scroll-page-forward] and
 914 \\[View-scroll-page-backward] scroll by default.
 915 If LINES is omitted or = 0, sets \"page size\" to window height and
 916 scrolls forward that much, otherwise scrolls forward LINES lines and sets
 917 \"page size\" to the minimum of window height and the absolute value of LINES.
 918 See also `View-scroll-page-forward'."
 919   (interactive "P")
 920   (view-scroll-lines lines nil
 921                      (setq view-page-size (view-page-size-default lines))
 922                      nil))
 923
 924 (defun View-scroll-page-backward-set-page-size (&optional lines)
 925   "Scroll backward prefix LINES lines in View mode, setting the \"page size\".
 926 See also `View-scroll-page-forward-set-page-size'."
 927   (interactive "P")
 928   (view-scroll-lines lines t
 929                      (setq view-page-size (view-page-size-default lines))
 930                      nil))
 931
 932 (defun View-scroll-line-forward (&optional lines)
 933   "Scroll forward one line (or prefix LINES lines) in View mode.
 934 See also `View-scroll-page-forward,' but note that scrolling is limited
 935 to minimum of LINES and one window-full."
 936   (interactive "P")
 937   (view-scroll-lines lines nil 1 t))
 938
 939 (defun View-scroll-line-backward (&optional lines)
 940   "Scroll backward one line (or prefix LINES lines) in View mode.
 941 See also `View-scroll-line-forward'."
 942   (interactive "P")
 943   (view-scroll-lines lines t 1 t))
 944
 945 (defun View-scroll-half-page-forward (&optional lines)
 946   "Scroll forward a \"half page\" (or prefix LINES) lines in View mode.
 947 If LINES is not omitted, the \"half page size\" is set to the minimum of
 948 window height and the absolute value of LINES.
 949 LINES=0 resets \"half page size\" to half window height."
 950   (interactive "P")
 951   (view-scroll-lines lines nil (view-set-half-page-size-default lines) t))
 952
 953 (defun View-scroll-half-page-backward (&optional lines)
 954   "Scroll backward a \"half page\" (or prefix LINES) lines in View mode.
 955 See also `View-scroll-half-page-forward'."
 956   (interactive "P")
 957   (view-scroll-lines lines t (view-set-half-page-size-default lines) t))
 958
 959 (defun View-revert-buffer-scroll-page-forward (&optional lines)
 960   "Scroll forward, reverting buffer if needed, in View mode.
 961 If buffer has not been changed and the corresponding file is newer, first
 962 revert the buffer, then scroll.
 963 This command is useful if you are viewing a changing file.
 964
 965 The prefix argument LINES says how many lines to scroll.
 966 If you don't specify a prefix argument, it uses the number of lines set by
 967 \\[View-scroll-page-forward-set-page-size] or
 968 \\[View-scroll-page-backward-set-page-size].
 969 If LINES is more than a window-full, only the last window-full is shown."
 970   (interactive "P")
 971   (let ((view-scroll-auto-exit nil)
 972         (view-try-extend-at-buffer-end t))
 973     (view-scroll-lines lines nil (view-page-size-default view-page-size) nil)))
 974 \f
 975 (defun View-search-regexp-forward (n regexp)
 976   "Search forward for first (or prefix Nth) occurrence of REGEXP in View mode.
 977
 978 Displays line found at center of window.  Sets mark at starting position and
 979 pushes mark ring.
 980
 981 Characters @ and ! are special at the beginning of REGEXP.  They modify
 982 the search rather than become part of the pattern searched for.
 983 @ means search all the buffer i.e. start search at the beginning of buffer.
 984 ! means search for a line that contains no match for the pattern.
 985 If REGEXP is empty or only consist of these control characters, then
 986 an earlier remembered REGEXP is used, otherwise REGEXP is remembered
 987 for use by later search commands.
 988
 989 The variable `view-highlight-face' controls the face that is used
 990 for highlighting the match that is found."
 991   (interactive "p\nsSearch forward (regexp): ")
 992   (view-search n regexp))
 993
 994 (defun View-search-regexp-backward (n regexp)
 995   "Search backward for first (or prefix Nth) occurrence of REGEXP in View mode.
 996
 997 Displays line found at center of window.  Sets mark at starting position and
 998 pushes mark ring.
 999
1000 Characters @ and ! are special at the beginning of REGEXP.  They modify
1001 the search rather than become part of the pattern searched for.
1002 @ means search all the buffer i.e. start search at the end of buffer.
1003 ! means search for a line that contains no match for the pattern.
1004 If REGEXP is empty or only consist of these control characters, then
1005 an earlier remembered REGEXP is used, otherwise REGEXP is remembered
1006 for use by later search commands.
1007
1008 The variable `view-highlight-face' controls the face that is used
1009 for highlighting the match that is found."
1010   (interactive "p\nsSearch backward (regexp): ")
1011   (view-search (- n) regexp))
1012
1013 (defun View-search-last-regexp-forward (n) "\
1014 Search forward for first (or prefix Nth) instance of last regexp in View mode.
1015 Displays line found at center of window.  Sets mark at starting position and
1016 pushes mark ring.
1017
1018 The variable `view-highlight-face' controls the face that is used
1019 for highlighting the match that is found."
1020   (interactive "p")
1021   (view-search n nil))
1022
1023 (defun View-search-last-regexp-backward (n) "\
1024 Search backward for first (or prefix Nth) instance of last regexp in View mode.
1025 Displays line found at center of window.  Sets mark at starting position and
1026 pushes mark ring.
1027
1028 The variable `view-highlight-face' controls the face that is used
1029 for highlighting the match that is found."
1030   (interactive "p")
1031   (view-search (- n) nil))
1032
1033 (defun view-search (times regexp)
1034   ;; This function does the job for all the View-search- commands.
1035   ;; Search for the TIMESt match for REGEXP. If TIMES is negative
1036   ;; search backwards. If REGEXP is nil use `view-last-regexp'.
1037   ;; Characters "!" and "@" have a special meaning at the beginning of
1038   ;; REGEXP and are removed from REGEXP before the search "!" means
1039   ;; search for lines with no match for REGEXP.  "@" means search in
1040   ;; the whole buffer, don't start searching from the present point.
1041   (let (where no end ln)
1042     (cond
1043      ((and regexp (> (length regexp) 0)
1044            (or (not (memq (string-to-char regexp) '(?! ?@)))
1045                (progn
1046                  (if (member (substring regexp 0 2) '("!@" "@!"))
1047                      (setq end t no t ln 2)
1048                    (setq no (not (setq end (eq ?@ (string-to-char regexp))))
1049                          ln 1))
1050                  (> (length (setq regexp (substring regexp ln))) 0))))
1051       (setq view-last-regexp (if no (list regexp) regexp)))
1052      ((consp view-last-regexp)
1053       (setq regexp (car view-last-regexp))
1054       (unless (setq no (not no)) (setq view-last-regexp regexp)))
1055      (view-last-regexp (setq regexp view-last-regexp)
1056                        (if no (setq view-last-regexp (list regexp))))
1057      (t (error "No previous View-mode search")))
1058     (save-excursion
1059       (if end (goto-char (if (< times 0) (point-max) (point-min)))
1060         (move-to-window-line (if (< times 0) 0 -1)))
1061       (if (if no (view-search-no-match-lines times regexp)
1062             (re-search-forward regexp nil t times))
1063           (setq where (point))))
1064     (if where
1065         (progn
1066           (push-mark)
1067           (goto-char where)
1068           (if view-overlay
1069               (move-overlay view-overlay (match-beginning 0) (match-end 0))
1070             (setq view-overlay
1071                   (make-overlay (match-beginning 0) (match-end 0))))
1072           (overlay-put view-overlay 'face view-highlight-face)
1073           (beginning-of-line)
1074           (view-recenter))
1075       (message "Can't find occurrence %d of %s%s"
1076                times (if no "no " "") regexp)
1077       (sit-for 4))))
1078
1079 ;; This is the dumb approach, looking at each line.  The original
1080 ;; version of this function looked like it might have been trying to
1081 ;; do something clever, but not succeeding:
1082 ;; http://lists.gnu.org/archive/html/bug-gnu-emacs/2007-09/msg00073.html
1083 (defun view-search-no-match-lines (times regexp)
1084   "Search for the TIMESth occurrence of a line with no match for REGEXP.
1085 If such a line is found, return non-nil and set the match-data to that line.
1086 If TIMES is negative, search backwards."
1087   (let ((step (if (>= times 0) 1
1088                 (setq times (- times))
1089                 -1)))
1090     ;; Note that we do not check the current line.
1091     (while (and (> times 0)
1092                 (zerop (forward-line step)))
1093       ;; (forward-line 1) returns 0 on moving within the last line.
1094       (if (eobp)
1095           (setq times -1)
1096         (or (re-search-forward regexp (line-end-position) t)
1097             (setq times (1- times))))))
1098   (and (zerop times)
1099        (looking-at ".*")))
1100
1101 (provide 'view)
1102
1103 ;; arch-tag: 6d0ace36-1d12-4de3-8de3-1fa3231636d7
1104 ;;; view.el ends here